src/code/print.lisp

   1 ;;;; the printer
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13 \f
  14 ;;;; exported printer control variables
  15
  16 ;;; FIXME: Many of these have nontrivial types, e.g. *PRINT-LEVEL*,
  17 ;;; *PRINT-LENGTH*, and *PRINT-LINES* are (OR NULL UNSIGNED-BYTE).
  18
  19 (defvar *print-readably* nil
  20   #!+sb-doc
  21   "If true, all objects will printed readably. If readable printing is
  22   impossible, an error will be signalled. This overrides the value of
  23   *PRINT-ESCAPE*.")
  24 (defvar *print-escape* t
  25   #!+sb-doc
  26   "Should we print in a reasonably machine-readable way? (possibly
  27   overridden by *PRINT-READABLY*)")
  28 (defvar *print-pretty* nil ; (set later when pretty-printer is initialized)
  29   #!+sb-doc
  30   "Should pretty printing be used?")
  31 (defvar *print-base* 10.
  32   #!+sb-doc
  33   "the output base for RATIONALs (including integers)")
  34 (defvar *print-radix* nil
  35   #!+sb-doc
  36   "Should base be verified when printing RATIONALs?")
  37 (defvar *print-level* nil
  38   #!+sb-doc
  39   "How many levels should be printed before abbreviating with \"#\"?")
  40 (defvar *print-length* nil
  41   #!+sb-doc
  42   "How many elements at any level should be printed before abbreviating
  43   with \"...\"?")
  44 (defvar *print-circle* nil
  45   #!+sb-doc
  46   "Should we use #n= and #n# notation to preserve uniqueness in general (and
  47   circularity in particular) when printing?")
  48 (defvar *print-case* :upcase
  49   #!+sb-doc
  50   "What case should the printer should use default?")
  51 (defvar *print-array* t
  52   #!+sb-doc
  53   "Should the contents of arrays be printed?")
  54 (defvar *print-gensym* t
  55   #!+sb-doc
  56   "Should #: prefixes be used when printing symbols with null SYMBOL-PACKAGE?")
  57 (defvar *print-lines* nil
  58   #!+sb-doc
  59   "the maximum number of lines to print per object")
  60 (defvar *print-right-margin* nil
  61   #!+sb-doc
  62   "the position of the right margin in ems (for pretty-printing)")
  63 (defvar *print-miser-width* nil
  64   #!+sb-doc
  65   "If the remaining space between the current column and the right margin
  66    is less than this, then print using ``miser-style'' output. Miser
  67    style conditional newlines are turned on, and all indentations are
  68    turned off. If NIL, never use miser mode.")
  69 (defvar *print-pprint-dispatch*)
  70 #!+sb-doc
  71 (setf (fdocumentation '*print-pprint-dispatch* 'variable)
  72       "the pprint-dispatch-table that controls how to pretty-print objects")
  73
  74 (defmacro with-standard-io-syntax (&body body)
  75   #!+sb-doc
  76   "Bind the reader and printer control variables to values that enable READ
  77    to reliably read the results of PRINT. These values are:
  78        *PACKAGE*                        the COMMON-LISP-USER package
  79        *PRINT-ARRAY*                    T
  80        *PRINT-BASE*                     10
  81        *PRINT-CASE*                     :UPCASE
  82        *PRINT-CIRCLE*                   NIL
  83        *PRINT-ESCAPE*                   T
  84        *PRINT-GENSYM*                   T
  85        *PRINT-LENGTH*                   NIL
  86        *PRINT-LEVEL*                    NIL
  87        *PRINT-LINES*                    NIL
  88        *PRINT-MISER-WIDTH*              NIL
  89        *PRINT-PRETTY*                   NIL
  90        *PRINT-RADIX*                    NIL
  91        *PRINT-READABLY*                 T
  92        *PRINT-RIGHT-MARGIN*             NIL
  93        *READ-BASE*                      10
  94        *READ-DEFAULT-FLOAT-FORMAT*      SINGLE-FLOAT
  95        *READ-EVAL*                      T
  96        *READ-SUPPRESS*                  NIL
  97        *READTABLE*                      the standard readtable"
  98   `(%with-standard-io-syntax (lambda () ,@body)))
  99
 100 (defun %with-standard-io-syntax (function)
 101   (declare (type function function))
 102   (let ((*package* (find-package "COMMON-LISP-USER"))
 103         (*print-array* t)
 104         (*print-base* 10)
 105         (*print-case* :upcase)
 106         (*print-circle* nil)
 107         (*print-escape* t)
 108         (*print-gensym* t)
 109         (*print-length* nil)
 110         (*print-level* nil)
 111         (*print-lines* nil)
 112         (*print-miser-width* nil)
 113         (*print-pretty* nil)
 114         (*print-radix* nil)
 115         (*print-readably* t)
 116         (*print-right-margin* nil)
 117         (*read-base* 10)
 118         (*read-default-float-format* 'single-float)
 119         (*read-eval* t)
 120         (*read-suppress* nil)
 121         ;; FIXME: It doesn't seem like a good idea to expose our
 122         ;; disaster-recovery *STANDARD-READTABLE* here. What if some
 123         ;; enterprising user corrupts the disaster-recovery readtable
 124         ;; by doing destructive readtable operations within
 125         ;; WITH-STANDARD-IO-SYNTAX? Perhaps we should do a
 126         ;; COPY-READTABLE? The consing would be unfortunate, though.
 127         (*readtable* *standard-readtable*))
 128     (funcall function)))
 129 \f
 130 ;;;; routines to print objects
 131
 132 (defun write (object &key
 133                      ((:stream stream) *standard-output*)
 134                      ((:escape *print-escape*) *print-escape*)
 135                      ((:radix *print-radix*) *print-radix*)
 136                      ((:base *print-base*) *print-base*)
 137                      ((:circle *print-circle*) *print-circle*)
 138                      ((:pretty *print-pretty*) *print-pretty*)
 139                      ((:level *print-level*) *print-level*)
 140                      ((:length *print-length*) *print-length*)
 141                      ((:case *print-case*) *print-case*)
 142                      ((:array *print-array*) *print-array*)
 143                      ((:gensym *print-gensym*) *print-gensym*)
 144                      ((:readably *print-readably*) *print-readably*)
 145                      ((:right-margin *print-right-margin*)
 146                       *print-right-margin*)
 147                      ((:miser-width *print-miser-width*)
 148                       *print-miser-width*)
 149                      ((:lines *print-lines*) *print-lines*)
 150                      ((:pprint-dispatch *print-pprint-dispatch*)
 151                       *print-pprint-dispatch*))
 152   #!+sb-doc
 153   "Output OBJECT to the specified stream, defaulting to *STANDARD-OUTPUT*"
 154   (output-object object (out-synonym-of stream))
 155   object)
 156
 157 (defun prin1 (object &optional stream)
 158   #!+sb-doc
 159   "Output a mostly READable printed representation of OBJECT on the specified
 160   STREAM."
 161   (let ((*print-escape* t))
 162     (output-object object (out-synonym-of stream)))
 163   object)
 164
 165 (defun princ (object &optional stream)
 166   #!+sb-doc
 167   "Output an aesthetic but not necessarily READable printed representation
 168   of OBJECT on the specified STREAM."
 169   (let ((*print-escape* nil)
 170         (*print-readably* nil))
 171     (output-object object (out-synonym-of stream)))
 172   object)
 173
 174 (defun print (object &optional stream)
 175   #!+sb-doc
 176   "Output a newline, the mostly READable printed representation of OBJECT, and
 177   space to the specified STREAM."
 178   (let ((stream (out-synonym-of stream)))
 179     (terpri stream)
 180     (prin1 object stream)
 181     (write-char #\space stream)
 182     object))
 183
 184 (defun pprint (object &optional stream)
 185   #!+sb-doc
 186   "Prettily output OBJECT preceded by a newline."
 187   (let ((*print-pretty* t)
 188         (*print-escape* t)
 189         (stream (out-synonym-of stream)))
 190     (terpri stream)
 191     (output-object object stream))
 192   (values))
 193
 194 (defun write-to-string
 195        (object &key
 196                ((:escape *print-escape*) *print-escape*)
 197                ((:radix *print-radix*) *print-radix*)
 198                ((:base *print-base*) *print-base*)
 199                ((:circle *print-circle*) *print-circle*)
 200                ((:pretty *print-pretty*) *print-pretty*)
 201                ((:level *print-level*) *print-level*)
 202                ((:length *print-length*) *print-length*)
 203                ((:case *print-case*) *print-case*)
 204                ((:array *print-array*) *print-array*)
 205                ((:gensym *print-gensym*) *print-gensym*)
 206                ((:readably *print-readably*) *print-readably*)
 207                ((:right-margin *print-right-margin*) *print-right-margin*)
 208                ((:miser-width *print-miser-width*) *print-miser-width*)
 209                ((:lines *print-lines*) *print-lines*)
 210                ((:pprint-dispatch *print-pprint-dispatch*)
 211                 *print-pprint-dispatch*))
 212   #!+sb-doc
 213   "Return the printed representation of OBJECT as a string."
 214   (stringify-object object))
 215
 216 (defun prin1-to-string (object)
 217   #!+sb-doc
 218   "Return the printed representation of OBJECT as a string with
 219    slashification on."
 220   (let ((*print-escape* t))
 221     (stringify-object object)))
 222
 223 (defun princ-to-string (object)
 224   #!+sb-doc
 225   "Return the printed representation of OBJECT as a string with
 226   slashification off."
 227   (let ((*print-escape* nil)
 228         (*print-readably* nil))
 229     (stringify-object object)))
 230
 231 ;;; This produces the printed representation of an object as a string.
 232 ;;; The few ...-TO-STRING functions above call this.
 233 (defun stringify-object (object)
 234   (let ((stream (make-string-output-stream)))
 235     (setup-printer-state)
 236     (output-object object stream)
 237     (get-output-stream-string stream)))
 238 \f
 239 ;;;; support for the PRINT-UNREADABLE-OBJECT macro
 240
 241 ;;; guts of PRINT-UNREADABLE-OBJECT
 242 (defun %print-unreadable-object (object stream type identity body)
 243   (declare (type (or null function) body))
 244   (when *print-readably*
 245     (error 'print-not-readable :object object))
 246   (flet ((print-description ()
 247            (when type
 248              (write (type-of object) :stream stream :circle nil
 249                     :level nil :length nil)
 250              (write-char #\space stream))
 251            (when body
 252              (funcall body))
 253            (when identity
 254              (when (or body (not type))
 255                (write-char #\space stream))
 256              (write-char #\{ stream)
 257              (write (get-lisp-obj-address object) :stream stream
 258                     :radix nil :base 16)
 259              (write-char #\} stream))))
 260     (cond ((print-pretty-on-stream-p stream)
 261            ;; Since we're printing prettily on STREAM, format the
 262            ;; object within a logical block. PPRINT-LOGICAL-BLOCK does
 263            ;; not rebind the stream when it is already a pretty stream,
 264            ;; so output from the body will go to the same stream.
 265            (pprint-logical-block (stream nil :prefix "#<" :suffix ">")
 266              (print-description)))
 267           (t
 268             (write-string "#<" stream)
 269             (print-description)
 270             (write-char #\> stream))))
 271   nil)
 272 \f
 273 ;;;; OUTPUT-OBJECT -- the main entry point
 274
 275 ;;; Objects whose print representation identifies them EQLly don't
 276 ;;; need to be checked for circularity.
 277 (defun uniquely-identified-by-print-p (x)
 278   (or (numberp x)
 279       (characterp x)
 280       (and (symbolp x)
 281            (symbol-package x))))
 282
 283 ;;; Output OBJECT to STREAM observing all printer control variables.
 284 (defun output-object (object stream)
 285   (labels ((print-it (stream)
 286              (if *print-pretty*
 287                  (sb!pretty:output-pretty-object object stream)
 288                  (output-ugly-object object stream)))
 289            (check-it (stream)
 290              (multiple-value-bind (marker initiate)
 291                  (check-for-circularity object t)
 292                (if (eq initiate :initiate)
 293                    (let ((*circularity-hash-table*
 294                           (make-hash-table :test 'eq)))
 295                      (check-it (make-broadcast-stream))
 296                      (let ((*circularity-counter* 0))
 297                        (check-it stream)))
 298                    ;; otherwise
 299                    (if marker
 300                        (when (handle-circularity marker stream)
 301                          (print-it stream))
 302                        (print-it stream))))))
 303     (cond (;; Maybe we don't need to bother with circularity detection.
 304            (or (not *print-circle*)
 305                (uniquely-identified-by-print-p object))
 306            (print-it stream))
 307           (;; If we have already started circularity detection, this
 308            ;; object might be a shared reference. If we have not, then
 309            ;; if it is a compound object it might contain a circular
 310            ;; reference to itself or multiple shared references.
 311            (or *circularity-hash-table*
 312                (compound-object-p object))
 313            (check-it stream))
 314           (t
 315            (print-it stream)))))
 316
 317 ;;; a hack to work around recurring gotchas with printing while
 318 ;;; DEFGENERIC PRINT-OBJECT is being built
 319 ;;;
 320 ;;; (hopefully will go away naturally when CLOS moves into cold init)
 321 (defvar *print-object-is-disabled-p*)
 322
 323 ;;; Output OBJECT to STREAM observing all printer control variables
 324 ;;; except for *PRINT-PRETTY*. Note: if *PRINT-PRETTY* is non-NIL,
 325 ;;; then the pretty printer will be used for any components of OBJECT,
 326 ;;; just not for OBJECT itself.
 327 (defun output-ugly-object (object stream)
 328   (typecase object
 329     ;; KLUDGE: The TYPECASE approach here is non-ANSI; the ANSI definition of
 330     ;; PRINT-OBJECT says it provides printing and we're supposed to provide
 331     ;; PRINT-OBJECT methods covering all classes. We deviate from this
 332     ;; by using PRINT-OBJECT only when we print instance values. However,
 333     ;; ANSI makes it hard to tell that we're deviating from this:
 334     ;;   (1) ANSI specifies that the user isn't supposed to call PRINT-OBJECT
 335     ;;       directly.
 336     ;;   (2) ANSI (section 11.1.2.1.2) says it's undefined to define
 337     ;;       a method on an external symbol in the CL package which is
 338     ;;       applicable to arg lists containing only direct instances of
 339     ;;       standardized classes.
 340     ;; Thus, in order for the user to detect our sleaziness in conforming
 341     ;; code, he has to do something relatively obscure like
 342     ;;   (1) actually use tools like FIND-METHOD to look for PRINT-OBJECT
 343     ;;       methods, or
 344     ;;   (2) define a PRINT-OBJECT method which is specialized on the stream
 345     ;;       value (e.g. a Gray stream object).
 346     ;; As long as no one comes up with a non-obscure way of detecting this
 347     ;; sleaziness, fixing this nonconformity will probably have a low
 348     ;; priority. -- WHN 2001-11-25
 349     (list
 350      (if (null object)
 351          (output-symbol object stream)
 352          (output-list object stream)))
 353     (instance
 354      (cond ((not (and (boundp '*print-object-is-disabled-p*)
 355                       *print-object-is-disabled-p*))
 356             (print-object object stream))
 357            ((typep object 'structure-object)
 358             (default-structure-print object stream *current-level-in-print*))
 359            (t
 360             (write-string "#<INSTANCE but not STRUCTURE-OBJECT>" stream))))
 361     (funcallable-instance
 362      (cond
 363        ((not (and (boundp '*print-object-is-disabled-p*)
 364                   *print-object-is-disabled-p*))
 365         (print-object object stream))
 366        (t (output-fun object stream))))
 367     (function
 368      (output-fun object stream))
 369     (symbol
 370      (output-symbol object stream))
 371     (number
 372      (etypecase object
 373        (integer
 374         (output-integer object stream))
 375        (float
 376         (output-float object stream))
 377        (ratio
 378         (output-ratio object stream))
 379        (ratio
 380         (output-ratio object stream))
 381        (complex
 382         (output-complex object stream))))
 383     (character
 384      (output-character object stream))
 385     (vector
 386      (output-vector object stream))
 387     (array
 388      (output-array object stream))
 389     (system-area-pointer
 390      (output-sap object stream))
 391     (weak-pointer
 392      (output-weak-pointer object stream))
 393     (lra
 394      (output-lra object stream))
 395     (code-component
 396      (output-code-component object stream))
 397     (fdefn
 398      (output-fdefn object stream))
 399     (t
 400      (output-random object stream))))
 401 \f
 402 ;;;; symbols
 403
 404 ;;; values of *PRINT-CASE* and (READTABLE-CASE *READTABLE*) the last
 405 ;;; time the printer was called
 406 (defvar *previous-case* nil)
 407 (defvar *previous-readtable-case* nil)
 408
 409 ;;; This variable contains the current definition of one of three
 410 ;;; symbol printers. SETUP-PRINTER-STATE sets this variable.
 411 (defvar *internal-symbol-output-fun* nil)
 412
 413 ;;; This function sets the internal global symbol
 414 ;;; *INTERNAL-SYMBOL-OUTPUT-FUN* to the right function depending on
 415 ;;; the value of *PRINT-CASE*. See the manual for details. The print
 416 ;;; buffer stream is also reset.
 417 (defun setup-printer-state ()
 418   (unless (and (eq *print-case* *previous-case*)
 419                (eq (readtable-case *readtable*) *previous-readtable-case*))
 420     (setq *previous-case* *print-case*)
 421     (setq *previous-readtable-case* (readtable-case *readtable*))
 422     (unless (member *print-case* '(:upcase :downcase :capitalize))
 423       (setq *print-case* :upcase)
 424       (error "invalid *PRINT-CASE* value: ~S" *previous-case*))
 425     (unless (member *previous-readtable-case*
 426                     '(:upcase :downcase :invert :preserve))
 427       (setf (readtable-case *readtable*) :upcase)
 428       (error "invalid READTABLE-CASE value: ~S" *previous-readtable-case*))
 429
 430     (setq *internal-symbol-output-fun*
 431           (case *previous-readtable-case*
 432             (:upcase
 433              (case *print-case*
 434                (:upcase #'output-preserve-symbol)
 435                (:downcase #'output-lowercase-symbol)
 436                (:capitalize #'output-capitalize-symbol)))
 437             (:downcase
 438              (case *print-case*
 439                (:upcase #'output-uppercase-symbol)
 440                (:downcase #'output-preserve-symbol)
 441                (:capitalize #'output-capitalize-symbol)))
 442             (:preserve #'output-preserve-symbol)
 443             (:invert #'output-invert-symbol)))))
 444
 445 ;;; Output PNAME (a symbol-name or package-name) surrounded with |'s,
 446 ;;; and with any embedded |'s or \'s escaped.
 447 (defun output-quoted-symbol-name (pname stream)
 448   (write-char #\| stream)
 449   (dotimes (index (length pname))
 450     (let ((char (schar pname index)))
 451       (when (or (char= char #\\) (char= char #\|))
 452         (write-char #\\ stream))
 453       (write-char char stream)))
 454   (write-char #\| stream))
 455
 456 (defun output-symbol (object stream)
 457   (if (or *print-escape* *print-readably*)
 458       (let ((package (symbol-package object))
 459             (name (symbol-name object)))
 460         (cond
 461          ;; The ANSI spec "22.1.3.3.1 Package Prefixes for Symbols"
 462          ;; requires that keywords be printed with preceding colons
 463          ;; always, regardless of the value of *PACKAGE*.
 464          ((eq package *keyword-package*)
 465           (write-char #\: stream))
 466          ;; Otherwise, if the symbol's home package is the current
 467          ;; one, then a prefix is never necessary.
 468          ((eq package (sane-package)))
 469          ;; Uninterned symbols print with a leading #:.
 470          ((null package)
 471           (when (or *print-gensym* *print-readably*)
 472             (write-string "#:" stream)))
 473          (t
 474           (multiple-value-bind (symbol accessible)
 475               (find-symbol name (sane-package))
 476             ;; If we can find the symbol by looking it up, it need not
 477             ;; be qualified. This can happen if the symbol has been
 478             ;; inherited from a package other than its home package.
 479             (unless (and accessible (eq symbol object))
 480               (output-symbol-name (package-name package) stream)
 481               (multiple-value-bind (symbol externalp)
 482                   (find-external-symbol name package)
 483                 (declare (ignore symbol))
 484                 (if externalp
 485                     (write-char #\: stream)
 486                     (write-string "::" stream)))))))
 487         (output-symbol-name name stream))
 488       (output-symbol-name (symbol-name object) stream nil)))
 489
 490 ;;; Output the string NAME as if it were a symbol name. In other
 491 ;;; words, diddle its case according to *PRINT-CASE* and
 492 ;;; READTABLE-CASE.
 493 (defun output-symbol-name (name stream &optional (maybe-quote t))
 494   (declare (type simple-string name))
 495   (let ((*readtable* (if *print-readably* *standard-readtable* *readtable*)))
 496     (setup-printer-state)
 497     (if (and maybe-quote (symbol-quotep name))
 498         (output-quoted-symbol-name name stream)
 499         (funcall *internal-symbol-output-fun* name stream))))
 500 \f
 501 ;;;; escaping symbols
 502
 503 ;;; When we print symbols we have to figure out if they need to be
 504 ;;; printed with escape characters. This isn't a whole lot easier than
 505 ;;; reading symbols in the first place.
 506 ;;;
 507 ;;; For each character, the value of the corresponding element is a
 508 ;;; fixnum with bits set corresponding to attributes that the
 509 ;;; character has. At characters have at least one bit set, so we can
 510 ;;; search for any character with a positive test.
 511 (defvar *character-attributes*
 512   (make-array 160 ; FIXME
 513               :element-type '(unsigned-byte 16)
 514               :initial-element 0))
 515 (declaim (type (simple-array (unsigned-byte 16) (#.160)) ; FIXME
 516                *character-attributes*))
 517
 518 ;;; constants which are a bit-mask for each interesting character attribute
 519 (defconstant other-attribute            (ash 1 0)) ; Anything else legal.
 520 (defconstant number-attribute           (ash 1 1)) ; A numeric digit.
 521 (defconstant uppercase-attribute        (ash 1 2)) ; An uppercase letter.
 522 (defconstant lowercase-attribute        (ash 1 3)) ; A lowercase letter.
 523 (defconstant sign-attribute             (ash 1 4)) ; +-
 524 (defconstant extension-attribute        (ash 1 5)) ; ^_
 525 (defconstant dot-attribute              (ash 1 6)) ; .
 526 (defconstant slash-attribute            (ash 1 7)) ; /
 527 (defconstant funny-attribute            (ash 1 8)) ; Anything illegal.
 528
 529 (eval-when (:compile-toplevel :load-toplevel :execute)
 530
 531 ;;; LETTER-ATTRIBUTE is a local of SYMBOL-QUOTEP. It matches letters
 532 ;;; that don't need to be escaped (according to READTABLE-CASE.)
 533 (defparameter *attribute-names*
 534   `((number . number-attribute) (lowercase . lowercase-attribute)
 535     (uppercase . uppercase-attribute) (letter . letter-attribute)
 536     (sign . sign-attribute) (extension . extension-attribute)
 537     (dot . dot-attribute) (slash . slash-attribute)
 538     (other . other-attribute) (funny . funny-attribute)))
 539
 540 ) ; EVAL-WHEN
 541
 542 (flet ((set-bit (char bit)
 543          (let ((code (char-code char)))
 544            (setf (aref *character-attributes* code)
 545                  (logior bit (aref *character-attributes* code))))))
 546
 547   (dolist (char '(#\! #\@ #\$ #\% #\& #\* #\= #\~ #\[ #\] #\{ #\}
 548                   #\? #\< #\>))
 549     (set-bit char other-attribute))
 550
 551   (dotimes (i 10)
 552     (set-bit (digit-char i) number-attribute))
 553
 554   (do ((code (char-code #\A) (1+ code))
 555        (end (char-code #\Z)))
 556       ((> code end))
 557     (declare (fixnum code end))
 558     (set-bit (code-char code) uppercase-attribute)
 559     (set-bit (char-downcase (code-char code)) lowercase-attribute))
 560
 561   (set-bit #\- sign-attribute)
 562   (set-bit #\+ sign-attribute)
 563   (set-bit #\^ extension-attribute)
 564   (set-bit #\_ extension-attribute)
 565   (set-bit #\. dot-attribute)
 566   (set-bit #\/ slash-attribute)
 567
 568   ;; Mark anything not explicitly allowed as funny.
 569   (dotimes (i 160) ; FIXME
 570     (when (zerop (aref *character-attributes* i))
 571       (setf (aref *character-attributes* i) funny-attribute))))
 572
 573 ;;; For each character, the value of the corresponding element is the
 574 ;;; lowest base in which that character is a digit.
 575 (defvar *digit-bases*
 576   (make-array 128 ; FIXME
 577               :element-type '(unsigned-byte 8)
 578               :initial-element 36))
 579 (declaim (type (simple-array (unsigned-byte 8) (#.128)) ; FIXME
 580                *digit-bases*))
 581 (dotimes (i 36)
 582   (let ((char (digit-char i 36)))
 583     (setf (aref *digit-bases* (char-code char)) i)))
 584
 585 ;;; A FSM-like thingie that determines whether a symbol is a potential
 586 ;;; number or has evil characters in it.
 587 (defun symbol-quotep (name)
 588   (declare (simple-string name))
 589   (macrolet ((advance (tag &optional (at-end t))
 590                `(progn
 591                  (when (= index len)
 592                    ,(if at-end '(go TEST-SIGN) '(return nil)))
 593                  (setq current (schar name index)
 594                        code (char-code current)
 595                        bits (cond ; FIXME
 596                               ((< code 160) (aref attributes code))
 597                               ((upper-case-p current) uppercase-attribute)
 598                               ((lower-case-p current) lowercase-attribute)
 599                               (t other-attribute)))
 600                  (incf index)
 601                  (go ,tag)))
 602              (test (&rest attributes)
 603                 `(not (zerop
 604                        (the fixnum
 605                             (logand
 606                              (logior ,@(mapcar
 607                                         (lambda (x)
 608                                           (or (cdr (assoc x
 609                                                           *attribute-names*))
 610                                               (error "Blast!")))
 611                                         attributes))
 612                              bits)))))
 613              (digitp ()
 614                `(and (< code 128) ; FIXME
 615                      (< (the fixnum (aref bases code)) base))))
 616
 617     (prog ((len (length name))
 618            (attributes *character-attributes*)
 619            (bases *digit-bases*)
 620            (base *print-base*)
 621            (letter-attribute
 622             (case (readtable-case *readtable*)
 623               (:upcase uppercase-attribute)
 624               (:downcase lowercase-attribute)
 625               (t (logior lowercase-attribute uppercase-attribute))))
 626            (index 0)
 627            (bits 0)
 628            (code 0)
 629            current)
 630       (declare (fixnum len base index bits code))
 631       (advance START t)
 632
 633      TEST-SIGN ; At end, see whether it is a sign...
 634       (return (not (test sign)))
 635
 636      OTHER ; not potential number, see whether funny chars...
 637       (let ((mask (logxor (logior lowercase-attribute uppercase-attribute
 638                                   funny-attribute)
 639                           letter-attribute)))
 640         (do ((i (1- index) (1+ i)))
 641             ((= i len) (return-from symbol-quotep nil))
 642           (unless (zerop (logand (let* ((char (schar name i))
 643                                         (code (char-code char)))
 644                                    (cond
 645                                      ((< code 160) (aref attributes code))
 646                                      ((upper-case-p char) uppercase-attribute)
 647                                      ((lower-case-p char) lowercase-attribute)
 648                                      (t other-attribute)))
 649                                  mask))
 650             (return-from symbol-quotep t))))
 651
 652      START
 653       (when (digitp)
 654         (if (test letter)
 655             (advance LAST-DIGIT-ALPHA)
 656             (advance DIGIT)))
 657       (when (test letter number other slash) (advance OTHER nil))
 658       (when (char= current #\.) (advance DOT-FOUND))
 659       (when (test sign extension) (advance START-STUFF nil))
 660       (return t)
 661
 662      DOT-FOUND ; leading dots...
 663       (when (test letter) (advance START-DOT-MARKER nil))
 664       (when (digitp) (advance DOT-DIGIT))
 665       (when (test number other) (advance OTHER nil))
 666       (when (test extension slash sign) (advance START-DOT-STUFF nil))
 667       (when (char= current #\.) (advance DOT-FOUND))
 668       (return t)
 669
 670      START-STUFF ; leading stuff before any dot or digit
 671       (when (digitp)
 672         (if (test letter)
 673             (advance LAST-DIGIT-ALPHA)
 674             (advance DIGIT)))
 675       (when (test number other) (advance OTHER nil))
 676       (when (test letter) (advance START-MARKER nil))
 677       (when (char= current #\.) (advance START-DOT-STUFF nil))
 678       (when (test sign extension slash) (advance START-STUFF nil))
 679       (return t)
 680
 681      START-MARKER ; number marker in leading stuff...
 682       (when (test letter) (advance OTHER nil))
 683       (go START-STUFF)
 684
 685      START-DOT-STUFF ; leading stuff containing dot without digit...
 686       (when (test letter) (advance START-DOT-STUFF nil))
 687       (when (digitp) (advance DOT-DIGIT))
 688       (when (test sign extension dot slash) (advance START-DOT-STUFF nil))
 689       (when (test number other) (advance OTHER nil))
 690       (return t)
 691
 692      START-DOT-MARKER ; number marker in leading stuff with dot..
 693       ;; leading stuff containing dot without digit followed by letter...
 694       (when (test letter) (advance OTHER nil))
 695       (go START-DOT-STUFF)
 696
 697      DOT-DIGIT ; in a thing with dots...
 698       (when (test letter) (advance DOT-MARKER))
 699       (when (digitp) (advance DOT-DIGIT))
 700       (when (test number other) (advance OTHER nil))
 701       (when (test sign extension dot slash) (advance DOT-DIGIT))
 702       (return t)
 703
 704      DOT-MARKER ; number marker in number with dot...
 705       (when (test letter) (advance OTHER nil))
 706       (go DOT-DIGIT)
 707
 708      LAST-DIGIT-ALPHA ; previous char is a letter digit...
 709       (when (or (digitp) (test sign slash))
 710         (advance ALPHA-DIGIT))
 711       (when (test letter number other dot) (advance OTHER nil))
 712       (return t)
 713
 714      ALPHA-DIGIT ; seen a digit which is a letter...
 715       (when (or (digitp) (test sign slash))
 716         (if (test letter)
 717             (advance LAST-DIGIT-ALPHA)
 718             (advance ALPHA-DIGIT)))
 719       (when (test letter) (advance ALPHA-MARKER))
 720       (when (test number other dot) (advance OTHER nil))
 721       (return t)
 722
 723      ALPHA-MARKER ; number marker in number with alpha digit...
 724       (when (test letter) (advance OTHER nil))
 725       (go ALPHA-DIGIT)
 726
 727      DIGIT ; seen only ordinary (non-alphabetic) numeric digits...
 728       (when (digitp)
 729         (if (test letter)
 730             (advance ALPHA-DIGIT)
 731             (advance DIGIT)))
 732       (when (test number other) (advance OTHER nil))
 733       (when (test letter) (advance MARKER))
 734       (when (test extension slash sign) (advance DIGIT))
 735       (when (char= current #\.) (advance DOT-DIGIT))
 736       (return t)
 737
 738      MARKER ; number marker in a numeric number...
 739       ;; ("What," you may ask, "is a 'number marker'?" It's something
 740       ;; that a conforming implementation might use in number syntax.
 741       ;; See ANSI 2.3.1.1 "Potential Numbers as Tokens".)
 742       (when (test letter) (advance OTHER nil))
 743       (go DIGIT))))
 744 \f
 745 ;;;; *INTERNAL-SYMBOL-OUTPUT-FUN*
 746 ;;;;
 747 ;;;; case hackery: These functions are stored in
 748 ;;;; *INTERNAL-SYMBOL-OUTPUT-FUN* according to the values of
 749 ;;;; *PRINT-CASE* and READTABLE-CASE.
 750
 751 ;;; called when:
 752 ;;; READTABLE-CASE      *PRINT-CASE*
 753 ;;; :UPCASE             :UPCASE
 754 ;;; :DOWNCASE           :DOWNCASE
 755 ;;; :PRESERVE           any
 756 (defun output-preserve-symbol (pname stream)
 757   (declare (simple-string pname))
 758   (write-string pname stream))
 759
 760 ;;; called when:
 761 ;;; READTABLE-CASE      *PRINT-CASE*
 762 ;;; :UPCASE             :DOWNCASE
 763 (defun output-lowercase-symbol (pname stream)
 764   (declare (simple-string pname))
 765   (dotimes (index (length pname))
 766     (let ((char (schar pname index)))
 767       (write-char (char-downcase char) stream))))
 768
 769 ;;; called when:
 770 ;;; READTABLE-CASE      *PRINT-CASE*
 771 ;;; :DOWNCASE           :UPCASE
 772 (defun output-uppercase-symbol (pname stream)
 773   (declare (simple-string pname))
 774   (dotimes (index (length pname))
 775     (let ((char (schar pname index)))
 776       (write-char (char-upcase char) stream))))
 777
 778 ;;; called when:
 779 ;;; READTABLE-CASE      *PRINT-CASE*
 780 ;;; :UPCASE             :CAPITALIZE
 781 ;;; :DOWNCASE           :CAPITALIZE
 782 (defun output-capitalize-symbol (pname stream)
 783   (declare (simple-string pname))
 784   (let ((prev-not-alphanum t)
 785         (up (eq (readtable-case *readtable*) :upcase)))
 786     (dotimes (i (length pname))
 787       (let ((char (char pname i)))
 788         (write-char (if up
 789                         (if (or prev-not-alphanum (lower-case-p char))
 790                             char
 791                             (char-downcase char))
 792                         (if prev-not-alphanum
 793                             (char-upcase char)
 794                             char))
 795                     stream)
 796         (setq prev-not-alphanum (not (alphanumericp char)))))))
 797
 798 ;;; called when:
 799 ;;; READTABLE-CASE      *PRINT-CASE*
 800 ;;; :INVERT             any
 801 (defun output-invert-symbol (pname stream)
 802   (declare (simple-string pname))
 803   (let ((all-upper t)
 804         (all-lower t))
 805     (dotimes (i (length pname))
 806       (let ((ch (schar pname i)))
 807         (when (both-case-p ch)
 808           (if (upper-case-p ch)
 809               (setq all-lower nil)
 810               (setq all-upper nil)))))
 811     (cond (all-upper (output-lowercase-symbol pname stream))
 812           (all-lower (output-uppercase-symbol pname stream))
 813           (t
 814            (write-string pname stream)))))
 815
 816 #|
 817 (defun test1 ()
 818   (let ((*readtable* (copy-readtable nil)))
 819     (format t "READTABLE-CASE  Input   Symbol-name~@
 820                ----------------------------------~%")
 821     (dolist (readtable-case '(:upcase :downcase :preserve :invert))
 822       (setf (readtable-case *readtable*) readtable-case)
 823       (dolist (input '("ZEBRA" "Zebra" "zebra"))
 824         (format t "~&:~A~16T~A~24T~A"
 825                 (string-upcase readtable-case)
 826                 input
 827                 (symbol-name (read-from-string input)))))))
 828
 829 (defun test2 ()
 830   (let ((*readtable* (copy-readtable nil)))
 831     (format t "READTABLE-CASE  *PRINT-CASE*  Symbol-name  Output  Princ~@
 832                --------------------------------------------------------~%")
 833     (dolist (readtable-case '(:upcase :downcase :preserve :invert))
 834       (setf (readtable-case *readtable*) readtable-case)
 835       (dolist (*print-case* '(:upcase :downcase :capitalize))
 836         (dolist (symbol '(|ZEBRA| |Zebra| |zebra|))
 837           (format t "~&:~A~15T:~A~29T~A~42T~A~50T~A"
 838                   (string-upcase readtable-case)
 839                   (string-upcase *print-case*)
 840                   (symbol-name symbol)
 841                   (prin1-to-string symbol)
 842                   (princ-to-string symbol)))))))
 843 |#
 844 \f
 845 ;;;; recursive objects
 846
 847 (defun output-list (list stream)
 848   (descend-into (stream)
 849     (write-char #\( stream)
 850     (let ((length 0)
 851           (list list))
 852       (loop
 853         (punt-print-if-too-long length stream)
 854         (output-object (pop list) stream)
 855         (unless list
 856           (return))
 857         (when (or (atom list)
 858                   (check-for-circularity list))
 859           (write-string " . " stream)
 860           (output-object list stream)
 861           (return))
 862         (write-char #\space stream)
 863         (incf length)))
 864     (write-char #\) stream)))
 865
 866 (defun output-vector (vector stream)
 867   (declare (vector vector))
 868   (cond ((stringp vector)
 869          (cond ((and *print-readably*
 870                      (not (eq (array-element-type vector)
 871                               (load-time-value
 872                                (array-element-type
 873                                 (make-array 0 :element-type 'character))))))
 874                 (error 'print-not-readable :object vector))
 875                ((or *print-escape* *print-readably*)
 876                 (write-char #\" stream)
 877                 (quote-string vector stream)
 878                 (write-char #\" stream))
 879                (t
 880                 (write-string vector stream))))
 881         ((not (or *print-array* *print-readably*))
 882          (output-terse-array vector stream))
 883         ((bit-vector-p vector)
 884          (write-string "#*" stream)
 885          (dovector (bit vector)
 886            ;; (Don't use OUTPUT-OBJECT here, since this code
 887            ;; has to work for all possible *PRINT-BASE* values.)
 888            (write-char (if (zerop bit) #\0 #\1) stream)))
 889         (t
 890          (when (and *print-readably*
 891                     (not (array-readably-printable-p vector)))
 892            (error 'print-not-readable :object vector))
 893          (descend-into (stream)
 894                        (write-string "#(" stream)
 895                        (dotimes (i (length vector))
 896                          (unless (zerop i)
 897                            (write-char #\space stream))
 898                          (punt-print-if-too-long i stream)
 899                          (output-object (aref vector i) stream))
 900                        (write-string ")" stream)))))
 901
 902 ;;; This function outputs a string quoting characters sufficiently
 903 ;;; so that someone can read it in again. Basically, put a slash in
 904 ;;; front of an character satisfying NEEDS-SLASH-P.
 905 (defun quote-string (string stream)
 906   (macrolet ((needs-slash-p (char)
 907                ;; KLUDGE: We probably should look at the readtable, but just do
 908                ;; this for now. [noted by anonymous long ago] -- WHN 19991130
 909                `(or (char= ,char #\\)
 910                  (char= ,char #\"))))
 911     (with-array-data ((data string) (start) (end (length string)))
 912       (do ((index start (1+ index)))
 913           ((>= index end))
 914         (let ((char (schar data index)))
 915           (when (needs-slash-p char) (write-char #\\ stream))
 916           (write-char char stream))))))
 917
 918 (defun array-readably-printable-p (array)
 919   (and (eq (array-element-type array) t)
 920        (let ((zero (position 0 (array-dimensions array)))
 921              (number (position 0 (array-dimensions array)
 922                                :test (complement #'eql)
 923                                :from-end t)))
 924          (or (null zero) (null number) (> zero number)))))
 925
 926 ;;; Output the printed representation of any array in either the #< or #A
 927 ;;; form.
 928 (defun output-array (array stream)
 929   (if (or *print-array* *print-readably*)
 930       (output-array-guts array stream)
 931       (output-terse-array array stream)))
 932
 933 ;;; Output the abbreviated #< form of an array.
 934 (defun output-terse-array (array stream)
 935   (let ((*print-level* nil)
 936         (*print-length* nil))
 937     (print-unreadable-object (array stream :type t :identity t))))
 938
 939 ;;; Output the readable #A form of an array.
 940 (defun output-array-guts (array stream)
 941   (when (and *print-readably*
 942              (not (array-readably-printable-p array)))
 943     (error 'print-not-readable :object array))
 944   (write-char #\# stream)
 945   (let ((*print-base* 10)
 946         (*print-radix* nil))
 947     (output-integer (array-rank array) stream))
 948   (write-char #\A stream)
 949   (with-array-data ((data array) (start) (end))
 950     (declare (ignore end))
 951     (sub-output-array-guts data (array-dimensions array) stream start)))
 952
 953 (defun sub-output-array-guts (array dimensions stream index)
 954   (declare (type (simple-array * (*)) array) (fixnum index))
 955   (cond ((null dimensions)
 956          (output-object (aref array index) stream))
 957         (t
 958          (descend-into (stream)
 959            (write-char #\( stream)
 960            (let* ((dimension (car dimensions))
 961                   (dimensions (cdr dimensions))
 962                   (count (reduce #'* dimensions)))
 963              (dotimes (i dimension)
 964                (unless (zerop i)
 965                  (write-char #\space stream))
 966                (punt-print-if-too-long i stream)
 967                (sub-output-array-guts array dimensions stream index)
 968                (incf index count)))
 969            (write-char #\) stream)))))
 970
 971 ;;; a trivial non-generic-function placeholder for PRINT-OBJECT, for
 972 ;;; use until CLOS is set up (at which time it will be replaced with
 973 ;;; the real generic function implementation)
 974 (defun print-object (instance stream)
 975   (default-structure-print instance stream *current-level-in-print*))
 976 \f
 977 ;;;; integer, ratio, and complex printing (i.e. everything but floats)
 978
 979 (defun %output-radix (base stream)
 980   (write-char #\# stream)
 981   (write-char (case base
 982                 (2 #\b)
 983                 (8 #\o)
 984                 (16 #\x)
 985                 (t (%output-fixnum-in-base base 10 stream)
 986                    #\r))
 987               stream))
 988
 989 (defun %output-fixnum-in-base (n base stream)
 990   (multiple-value-bind (q r)
 991       (truncate n base)
 992     ;; Recurse until you have all the digits pushed on
 993     ;; the stack.
 994     (unless (zerop q)
 995       (%output-fixnum-in-base q base stream))
 996     ;; Then as each recursive call unwinds, turn the
 997     ;; digit (in remainder) into a character and output
 998     ;; the character.
 999     (write-char
1000      (schar "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ" r)
1001      stream)))
1002
1003 ;; Algorithm by Harald Hanche-Olsen, sbcl-devel 2005-02-05
1004 (defun %output-bignum-in-base (n base stream)
1005   (declare (type bignum n) (type fixnum base))
1006   (let ((power (make-array 10 :adjustable t :fill-pointer 0)))
1007     ;; Here there be the bottleneck for big bignums, in the (* p p).
1008     ;; A special purpose SQUARE-BIGNUM might help a bit. See eg: Dan
1009     ;; Zuras, "On Squaring and Multiplying Large Integers", ARITH-11:
1010     ;; IEEE Symposium on Computer Arithmetic, 1993, pp. 260 to 271.
1011     ;; Reprinted as "More on Multiplying and Squaring Large Integers",
1012     ;; IEEE Transactions on Computers, volume 43, number 8, August
1013     ;; 1994, pp. 899-908.
1014     (do ((p base (* p p)))
1015         ((> p n))
1016       (vector-push-extend p power))
1017     ;; (aref power k) == (expt base (expt 2 k))
1018     (labels ((bisect (n k exactp)
1019                (declare (fixnum k))
1020                ;; N is the number to bisect
1021                ;; K on initial entry BASE^(2^K) > N
1022                ;; EXACTP is true if 2^K is the exact number of digits
1023                (cond ((zerop n)
1024                       (when exactp
1025                         (loop repeat (ash 1 k) do (write-char #\0 stream))))
1026                      ((zerop k)
1027                       (write-char
1028                        (schar "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ" n)
1029                        stream))
1030                      (t
1031                       (setf k (1- k))
1032                       (multiple-value-bind (q r) (truncate n (aref power k))
1033                         ;; EXACTP is NIL only at the head of the
1034                         ;; initial number, as we don't know the number
1035                         ;; of digits there, but we do know that it
1036                         ;; doesn't get any leading zeros.
1037                         (bisect q k exactp)
1038                         (bisect r k (or exactp (plusp q))))))))
1039       (bisect n (fill-pointer power) nil))))
1040
1041 (defun %output-integer-in-base (integer base stream)
1042   (when (minusp integer)
1043     (write-char #\- stream)
1044     (setf integer (- integer)))
1045   (if (fixnump integer)
1046       (%output-fixnum-in-base integer base stream)
1047       (%output-bignum-in-base integer base stream)))
1048
1049 (defun output-integer (integer stream)
1050   (let ((base *print-base*))
1051     (when (and (/= base 10) *print-radix*)
1052       (%output-radix base stream))
1053     (%output-integer-in-base integer base stream)
1054     (when (and *print-radix* (= base 10))
1055       (write-char #\. stream))))
1056
1057 (defun output-ratio (ratio stream)
1058   (let ((base *print-base*))
1059     (when *print-radix*
1060       (%output-radix base stream))
1061     (%output-integer-in-base (numerator ratio) base stream)
1062     (write-char #\/ stream)
1063     (%output-integer-in-base (denominator ratio) base stream)))
1064
1065 (defun output-complex (complex stream)
1066   (write-string "#C(" stream)
1067   ;; FIXME: Could this just be OUTPUT-NUMBER?
1068   (output-object (realpart complex) stream)
1069   (write-char #\space stream)
1070   (output-object (imagpart complex) stream)
1071   (write-char #\) stream))
1072 \f
1073 ;;;; float printing
1074
1075 ;;; FLONUM-TO-STRING (and its subsidiary function FLOAT-STRING) does
1076 ;;; most of the work for all printing of floating point numbers in
1077 ;;; FORMAT.  It converts a floating point number to a string in a free
1078 ;;; or fixed format with no exponent. The interpretation of the
1079 ;;; arguments is as follows:
1080 ;;;
1081 ;;;     X       - The floating point number to convert, which must not be
1082 ;;;             negative.
1083 ;;;     WIDTH    - The preferred field width, used to determine the number
1084 ;;;             of fraction digits to produce if the FDIGITS parameter
1085 ;;;             is unspecified or NIL. If the non-fraction digits and the
1086 ;;;             decimal point alone exceed this width, no fraction digits
1087 ;;;             will be produced unless a non-NIL value of FDIGITS has been
1088 ;;;             specified. Field overflow is not considerd an error at this
1089 ;;;             level.
1090 ;;;     FDIGITS  - The number of fractional digits to produce. Insignificant
1091 ;;;             trailing zeroes may be introduced as needed. May be
1092 ;;;             unspecified or NIL, in which case as many digits as possible
1093 ;;;             are generated, subject to the constraint that there are no
1094 ;;;             trailing zeroes.
1095 ;;;     SCALE    - If this parameter is specified or non-NIL, then the number
1096 ;;;             printed is (* x (expt 10 scale)). This scaling is exact,
1097 ;;;             and cannot lose precision.
1098 ;;;     FMIN     - This parameter, if specified or non-NIL, is the minimum
1099 ;;;             number of fraction digits which will be produced, regardless
1100 ;;;             of the value of WIDTH or FDIGITS. This feature is used by
1101 ;;;             the ~E format directive to prevent complete loss of
1102 ;;;             significance in the printed value due to a bogus choice of
1103 ;;;             scale factor.
1104 ;;;
1105 ;;; Returns:
1106 ;;; (VALUES DIGIT-STRING DIGIT-LENGTH LEADING-POINT TRAILING-POINT DECPNT)
1107 ;;; where the results have the following interpretation:
1108 ;;;
1109 ;;;     DIGIT-STRING    - The decimal representation of X, with decimal point.
1110 ;;;     DIGIT-LENGTH    - The length of the string DIGIT-STRING.
1111 ;;;     LEADING-POINT   - True if the first character of DIGIT-STRING is the
1112 ;;;                    decimal point.
1113 ;;;     TRAILING-POINT  - True if the last character of DIGIT-STRING is the
1114 ;;;                    decimal point.
1115 ;;;     POINT-POS       - The position of the digit preceding the decimal
1116 ;;;                    point. Zero indicates point before first digit.
1117 ;;;
1118 ;;; NOTE: FLONUM-TO-STRING goes to a lot of trouble to guarantee
1119 ;;; accuracy. Specifically, the decimal number printed is the closest
1120 ;;; possible approximation to the true value of the binary number to
1121 ;;; be printed from among all decimal representations with the same
1122 ;;; number of digits. In free-format output, i.e. with the number of
1123 ;;; digits unconstrained, it is guaranteed that all the information is
1124 ;;; preserved, so that a properly- rounding reader can reconstruct the
1125 ;;; original binary number, bit-for-bit, from its printed decimal
1126 ;;; representation. Furthermore, only as many digits as necessary to
1127 ;;; satisfy this condition will be printed.
1128 ;;;
1129 ;;; FLOAT-DIGITS actually generates the digits for positive numbers;
1130 ;;; see below for comments.
1131
1132 (defun flonum-to-string (x &optional width fdigits scale fmin)
1133   (declare (type float x))
1134   ;; FIXME: I think only FORMAT-DOLLARS calls FLONUM-TO-STRING with
1135   ;; possibly-negative X.
1136   (setf x (abs x))
1137   (cond ((zerop x)
1138          ;; Zero is a special case which FLOAT-STRING cannot handle.
1139          (if fdigits
1140              (let ((s (make-string (1+ fdigits) :initial-element #\0)))
1141                (setf (schar s 0) #\.)
1142                (values s (length s) t (zerop fdigits) 0))
1143              (values "." 1 t t 0)))
1144         (t
1145          (multiple-value-bind (e string)
1146              (if fdigits
1147                  (flonum-to-digits x (min (- (+ fdigits (or scale 0)))
1148                                           (- (or fmin 0))))
1149                  (if (and width (> width 1))
1150                      (let ((w (multiple-value-list
1151                                (flonum-to-digits x
1152                                                  (max 1
1153                                                       (+ (1- width)
1154                                                          (if (and scale (minusp scale))
1155                                                              scale 0)))
1156                                                  t)))
1157                            (f (multiple-value-list
1158                                (flonum-to-digits x (- (+ (or fmin 0)
1159                                                          (if scale scale 0)))))))
1160                        (cond
1161                          ((>= (length (cadr w)) (length (cadr f)))
1162                           (values-list w))
1163                          (t (values-list f))))
1164                      (flonum-to-digits x)))
1165            (let ((e (+ e (or scale 0)))
1166                  (stream (make-string-output-stream)))
1167              (if (plusp e)
1168                  (progn
1169                    (write-string string stream :end (min (length string)
1170                                                          e))
1171                    (dotimes (i (- e (length string)))
1172                      (write-char #\0 stream))
1173                    (write-char #\. stream)
1174                    (write-string string stream :start (min (length
1175                                                             string) e))
1176                    (when fdigits
1177                      (dotimes (i (- fdigits
1178                                     (- (length string)
1179                                        (min (length string) e))))
1180                        (write-char #\0 stream))))
1181                  (progn
1182                    (write-string "." stream)
1183                    (dotimes (i (- e))
1184                      (write-char #\0 stream))
1185                    (write-string string stream)
1186                    (when fdigits
1187                      (dotimes (i (+ fdigits e (- (length string))))
1188                        (write-char #\0 stream)))))
1189              (let ((string (get-output-stream-string stream)))
1190                (values string (length string)
1191                        (char= (char string 0) #\.)
1192                        (char= (char string (1- (length string))) #\.)
1193                        (position #\. string))))))))
1194
1195 ;;; implementation of figure 1 from Burger and Dybvig, 1996.  As the
1196 ;;; implementation of the Dragon from Classic CMUCL (and previously in
1197 ;;; SBCL above FLONUM-TO-STRING) says: "DO NOT EVEN THINK OF
1198 ;;; ATTEMPTING TO UNDERSTAND THIS CODE WITHOUT READING THE PAPER!",
1199 ;;; and in this case we have to add that even reading the paper might
1200 ;;; not bring immediate illumination as CSR has attempted to turn
1201 ;;; idiomatic Scheme into idiomatic Lisp.
1202 ;;;
1203 ;;; FIXME: figure 1 from Burger and Dybvig is the unoptimized
1204 ;;; algorithm, noticeably slow at finding the exponent.  Figure 2 has
1205 ;;; an improved algorithm, but CSR ran out of energy.
1206 ;;;
1207 ;;; possible extension for the enthusiastic: printing floats in bases
1208 ;;; other than base 10.
1209 (defconstant single-float-min-e
1210   (nth-value 1 (decode-float least-positive-single-float)))
1211 (defconstant double-float-min-e
1212   (nth-value 1 (decode-float least-positive-double-float)))
1213 #!+long-float
1214 (defconstant long-float-min-e
1215   (nth-value 1 (decode-float least-positive-long-float)))
1216
1217 (defun flonum-to-digits (v &optional position relativep)
1218   (let ((print-base 10) ; B
1219         (float-radix 2) ; b
1220         (float-digits (float-digits v)) ; p
1221         (digit-characters "0123456789")
1222         (min-e
1223          (etypecase v
1224            (single-float single-float-min-e)
1225            (double-float double-float-min-e)
1226            #!+long-float
1227            (long-float long-float-min-e))))
1228     (multiple-value-bind (f e)
1229         (integer-decode-float v)
1230       (let (;; FIXME: these even tests assume normal IEEE rounding
1231             ;; mode.  I wonder if we should cater for non-normal?
1232             (high-ok (evenp f))
1233             (low-ok (evenp f)))
1234         (with-push-char (:element-type base-char)
1235           (labels ((scale (r s m+ m-)
1236                      (do ((k 0 (1+ k))
1237                           (s s (* s print-base)))
1238                          ((not (or (> (+ r m+) s)
1239                                    (and high-ok (= (+ r m+) s))))
1240                           (do ((k k (1- k))
1241                                (r r (* r print-base))
1242                                (m+ m+ (* m+ print-base))
1243                                (m- m- (* m- print-base)))
1244                               ((not (or (< (* (+ r m+) print-base) s)
1245                                         (and (not high-ok)
1246                                              (= (* (+ r m+) print-base) s))))
1247                                (values k (generate r s m+ m-)))))))
1248                    (generate (r s m+ m-)
1249                      (let (d tc1 tc2)
1250                        (tagbody
1251                         loop
1252                           (setf (values d r) (truncate (* r print-base) s))
1253                           (setf m+ (* m+ print-base))
1254                           (setf m- (* m- print-base))
1255                           (setf tc1 (or (< r m-) (and low-ok (= r m-))))
1256                           (setf tc2 (or (> (+ r m+) s)
1257                                         (and high-ok (= (+ r m+) s))))
1258                           (when (or tc1 tc2)
1259                             (go end))
1260                           (push-char (char digit-characters d))
1261                           (go loop)
1262                         end
1263                           (let ((d (cond
1264                                      ((and (not tc1) tc2) (1+ d))
1265                                      ((and tc1 (not tc2)) d)
1266                                      (t ; (and tc1 tc2)
1267                                       (if (< (* r 2) s) d (1+ d))))))
1268                             (push-char (char digit-characters d))
1269                             (return-from generate (get-pushed-string))))))
1270                    (initialize ()
1271                      (let (r s m+ m-)
1272                        (if (>= e 0)
1273                            (let* ((be (expt float-radix e))
1274                                   (be1 (* be float-radix)))
1275                              (if (/= f (expt float-radix (1- float-digits)))
1276                                  (setf r (* f be 2)
1277                                        s 2
1278                                        m+ be
1279                                        m- be)
1280                                  (setf r (* f be1 2)
1281                                        s (* float-radix 2)
1282                                        m+ be1
1283                                        m- be)))
1284                            (if (or (= e min-e)
1285                                    (/= f (expt float-radix (1- float-digits))))
1286                                (setf r (* f 2)
1287                                      s (* (expt float-radix (- e)) 2)
1288                                      m+ 1
1289                                      m- 1)
1290                                (setf r (* f float-radix 2)
1291                                      s (* (expt float-radix (- 1 e)) 2)
1292                                      m+ float-radix
1293                                      m- 1)))
1294                        (when position
1295                          (when relativep
1296                            (aver (> position 0))
1297                            (do ((k 0 (1+ k))
1298                                 ;; running out of letters here
1299                                 (l 1 (* l print-base)))
1300                                ((>= (* s l) (+ r m+))
1301                                 ;; k is now \hat{k}
1302                                 (if (< (+ r (* s (/ (expt print-base (- k position)) 2)))
1303                                        (* s (expt print-base k)))
1304                                     (setf position (- k position))
1305                                     (setf position (- k position 1))))))
1306                          (let ((low (max m- (/ (* s (expt print-base position)) 2)))
1307                                (high (max m+ (/ (* s (expt print-base position)) 2))))
1308                            (when (<= m- low)
1309                              (setf m- low)
1310                              (setf low-ok t))
1311                            (when (<= m+ high)
1312                              (setf m+ high)
1313                              (setf high-ok t))))
1314                        (values r s m+ m-))))
1315             (multiple-value-bind (r s m+ m-) (initialize)
1316               (scale r s m+ m-))))))))
1317 \f
1318 ;;; Given a non-negative floating point number, SCALE-EXPONENT returns
1319 ;;; a new floating point number Z in the range (0.1, 1.0] and an
1320 ;;; exponent E such that Z * 10^E is (approximately) equal to the
1321 ;;; original number. There may be some loss of precision due the
1322 ;;; floating point representation. The scaling is always done with
1323 ;;; long float arithmetic, which helps printing of lesser precisions
1324 ;;; as well as avoiding generic arithmetic.
1325 ;;;
1326 ;;; When computing our initial scale factor using EXPT, we pull out
1327 ;;; part of the computation to avoid over/under flow. When
1328 ;;; denormalized, we must pull out a large factor, since there is more
1329 ;;; negative exponent range than positive range.
1330
1331 (eval-when (:compile-toplevel :execute)
1332   (setf *read-default-float-format*
1333         #!+long-float 'long-float #!-long-float 'double-float))
1334 (defun scale-exponent (original-x)
1335   (let* ((x (coerce original-x 'long-float)))
1336     (multiple-value-bind (sig exponent) (decode-float x)
1337       (declare (ignore sig))
1338       (if (= x 0.0e0)
1339           (values (float 0.0e0 original-x) 1)
1340           (let* ((ex (locally (declare (optimize (safety 0)))
1341                        (the fixnum
1342                          (round (* exponent (log 2e0 10))))))
1343                  (x (if (minusp ex)
1344                         (if (float-denormalized-p x)
1345                             #!-long-float
1346                             (* x 1.0e16 (expt 10.0e0 (- (- ex) 16)))
1347                             #!+long-float
1348                             (* x 1.0e18 (expt 10.0e0 (- (- ex) 18)))
1349                             (* x 10.0e0 (expt 10.0e0 (- (- ex) 1))))
1350                         (/ x 10.0e0 (expt 10.0e0 (1- ex))))))
1351             (do ((d 10.0e0 (* d 10.0e0))
1352                  (y x (/ x d))
1353                  (ex ex (1+ ex)))
1354                 ((< y 1.0e0)
1355                  (do ((m 10.0e0 (* m 10.0e0))
1356                       (z y (* y m))
1357                       (ex ex (1- ex)))
1358                      ((>= z 0.1e0)
1359                       (values (float z original-x) ex))
1360                    (declare (long-float m) (integer ex))))
1361               (declare (long-float d))))))))
1362 (eval-when (:compile-toplevel :execute)
1363   (setf *read-default-float-format* 'single-float))
1364 \f
1365 ;;;; entry point for the float printer
1366
1367 ;;; the float printer as called by PRINT, PRIN1, PRINC, etc. The
1368 ;;; argument is printed free-format, in either exponential or
1369 ;;; non-exponential notation, depending on its magnitude.
1370 ;;;
1371 ;;; NOTE: When a number is to be printed in exponential format, it is
1372 ;;; scaled in floating point. Since precision may be lost in this
1373 ;;; process, the guaranteed accuracy properties of FLONUM-TO-STRING
1374 ;;; are lost. The difficulty is that FLONUM-TO-STRING performs
1375 ;;; extensive computations with integers of similar magnitude to that
1376 ;;; of the number being printed. For large exponents, the bignums
1377 ;;; really get out of hand. If bignum arithmetic becomes reasonably
1378 ;;; fast and the exponent range is not too large, then it might become
1379 ;;; attractive to handle exponential notation with the same accuracy
1380 ;;; as non-exponential notation, using the method described in the
1381 ;;; Steele and White paper.
1382 ;;;
1383 ;;; NOTE II: this has been bypassed slightly by implementing Burger
1384 ;;; and Dybvig, 1996.  When someone has time (KLUDGE) they can
1385 ;;; probably (a) implement the optimizations suggested by Burger and
1386 ;;; Dyvbig, and (b) remove all vestiges of Dragon4, including from
1387 ;;; fixed-format printing.
1388
1389 ;;; Print the appropriate exponent marker for X and the specified exponent.
1390 (defun print-float-exponent (x exp stream)
1391   (declare (type float x) (type integer exp) (type stream stream))
1392   (let ((*print-radix* nil))
1393     (if (typep x *read-default-float-format*)
1394         (unless (eql exp 0)
1395           (format stream "e~D" exp))
1396         (format stream "~C~D"
1397                 (etypecase x
1398                   (single-float #\f)
1399                   (double-float #\d)
1400                   (short-float #\s)
1401                   (long-float #\L))
1402                 exp))))
1403
1404 (defun output-float-infinity (x stream)
1405   (declare (float x) (stream stream))
1406   (cond (*read-eval*
1407          (write-string "#." stream))
1408         (*print-readably*
1409          (error 'print-not-readable :object x))
1410         (t
1411          (write-string "#<" stream)))
1412   (write-string "SB-EXT:" stream)
1413   (write-string (symbol-name (float-format-name x)) stream)
1414   (write-string (if (plusp x) "-POSITIVE-" "-NEGATIVE-")
1415                 stream)
1416   (write-string "INFINITY" stream)
1417   (unless *read-eval*
1418     (write-string ">" stream)))
1419
1420 (defun output-float-nan (x stream)
1421   (print-unreadable-object (x stream)
1422     (princ (float-format-name x) stream)
1423     (write-string (if (float-trapping-nan-p x) " trapping" " quiet") stream)
1424     (write-string " NaN" stream)))
1425
1426 ;;; the function called by OUTPUT-OBJECT to handle floats
1427 (defun output-float (x stream)
1428   (cond
1429    ((float-infinity-p x)
1430     (output-float-infinity x stream))
1431    ((float-nan-p x)
1432     (output-float-nan x stream))
1433    (t
1434     (let ((x (cond ((minusp (float-sign x))
1435                     (write-char #\- stream)
1436                     (- x))
1437                    (t
1438                     x))))
1439       (cond
1440        ((zerop x)
1441         (write-string "0.0" stream)
1442         (print-float-exponent x 0 stream))
1443        (t
1444         (output-float-aux x stream -3 8)))))))
1445
1446 (defun output-float-aux (x stream e-min e-max)
1447   (multiple-value-bind (e string)
1448       (flonum-to-digits x)
1449     (cond
1450       ((< e-min e e-max)
1451        (if (plusp e)
1452            (progn
1453              (write-string string stream :end (min (length string) e))
1454              (dotimes (i (- e (length string)))
1455                (write-char #\0 stream))
1456              (write-char #\. stream)
1457              (write-string string stream :start (min (length string) e))
1458              (when (<= (length string) e)
1459                (write-char #\0 stream))
1460              (print-float-exponent x 0 stream))
1461            (progn
1462              (write-string "0." stream)
1463              (dotimes (i (- e))
1464                (write-char #\0 stream))
1465              (write-string string stream)
1466              (print-float-exponent x 0 stream))))
1467       (t (write-string string stream :end 1)
1468          (write-char #\. stream)
1469          (write-string string stream :start 1)
1470          (print-float-exponent x (1- e) stream)))))
1471 \f
1472 ;;;; other leaf objects
1473
1474 ;;; If *PRINT-ESCAPE* is false, just do a WRITE-CHAR, otherwise output
1475 ;;; the character name or the character in the #\char format.
1476 (defun output-character (char stream)
1477   (if (or *print-escape* *print-readably*)
1478       (let ((graphicp (and (graphic-char-p char)
1479                            (standard-char-p char)))
1480             (name (char-name char)))
1481         (write-string "#\\" stream)
1482         (if (and name (not graphicp))
1483             (quote-string name stream)
1484             (write-char char stream)))
1485       (write-char char stream)))
1486
1487 (defun output-sap (sap stream)
1488   (declare (type system-area-pointer sap))
1489   (cond (*read-eval*
1490          (format stream "#.(~S #X~8,'0X)" 'int-sap (sap-int sap)))
1491         (t
1492          (print-unreadable-object (sap stream)
1493            (format stream "system area pointer: #X~8,'0X" (sap-int sap))))))
1494
1495 (defun output-weak-pointer (weak-pointer stream)
1496   (declare (type weak-pointer weak-pointer))
1497   (print-unreadable-object (weak-pointer stream)
1498     (multiple-value-bind (value validp) (weak-pointer-value weak-pointer)
1499       (cond (validp
1500              (write-string "weak pointer: " stream)
1501              (write value :stream stream))
1502             (t
1503              (write-string "broken weak pointer" stream))))))
1504
1505 (defun output-code-component (component stream)
1506   (print-unreadable-object (component stream :identity t)
1507     (let ((dinfo (%code-debug-info component)))
1508       (cond ((eq dinfo :bogus-lra)
1509              (write-string "bogus code object" stream))
1510             (t
1511              (write-string "code object" stream)
1512              (when dinfo
1513                (write-char #\space stream)
1514                (output-object (sb!c::debug-info-name dinfo) stream)))))))
1515
1516 (defun output-lra (lra stream)
1517   (print-unreadable-object (lra stream :identity t)
1518     (write-string "return PC object" stream)))
1519
1520 (defun output-fdefn (fdefn stream)
1521   (print-unreadable-object (fdefn stream)
1522     (write-string "FDEFINITION object for " stream)
1523     (output-object (fdefn-name fdefn) stream)))
1524 \f
1525 ;;;; functions
1526
1527 ;;; Output OBJECT as using PRINT-OBJECT if it's a
1528 ;;; FUNCALLABLE-STANDARD-CLASS, or return NIL otherwise.
1529 ;;;
1530 ;;; The definition here is a simple temporary placeholder. It will be
1531 ;;; overwritten by a smarter version (capable of calling generic
1532 ;;; PRINT-OBJECT when appropriate) when CLOS is installed.
1533 (defun printed-as-funcallable-standard-class (object stream)
1534   (declare (ignore object stream))
1535   nil)
1536
1537 (defun output-fun (object stream)
1538     (let* ((*print-length* 3)  ; in case we have to..
1539            (*print-level* 3)  ; ..print an interpreted function definition
1540            (name (%fun-name object))
1541            (proper-name-p (and (legal-fun-name-p name) (fboundp name)
1542                                (eq (fdefinition name) object))))
1543       (print-unreadable-object (object stream :identity (not proper-name-p))
1544         (format stream "~:[FUNCTION~;CLOSURE~]~@[ ~S~]"
1545                 (closurep object)
1546                 name))))
1547 \f
1548 ;;;; catch-all for unknown things
1549
1550 (defun output-random (object stream)
1551   (print-unreadable-object (object stream :identity t)
1552     (let ((lowtag (lowtag-of object)))
1553       (case lowtag
1554         (#.sb!vm:other-pointer-lowtag
1555           (let ((widetag (widetag-of object)))
1556             (case widetag
1557               (#.sb!vm:value-cell-header-widetag
1558                (write-string "value cell " stream)
1559                (output-object (value-cell-ref object) stream))
1560               (t
1561                (write-string "unknown pointer object, widetag=" stream)
1562                (let ((*print-base* 16) (*print-radix* t))
1563                  (output-integer widetag stream))))))
1564         ((#.sb!vm:fun-pointer-lowtag
1565           #.sb!vm:instance-pointer-lowtag
1566           #.sb!vm:list-pointer-lowtag)
1567          (write-string "unknown pointer object, lowtag=" stream)
1568          (let ((*print-base* 16) (*print-radix* t))
1569            (output-integer lowtag stream)))
1570         (t
1571          (case (widetag-of object)
1572            (#.sb!vm:unbound-marker-widetag
1573             (write-string "unbound marker" stream))
1574            (t
1575             (write-string "unknown immediate object, lowtag=" stream)
1576             (let ((*print-base* 2) (*print-radix* t))
1577               (output-integer lowtag stream))
1578             (write-string ", widetag=" stream)
1579             (let ((*print-base* 16) (*print-radix* t))
1580               (output-integer (widetag-of object) stream)))))))))