src/code/run-program.lisp

   1 ;;;; RUN-PROGRAM and friends, a facility for running Unix programs
   2 ;;;; from inside SBCL
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB-IMPL") ;(SB-IMPL, not SB!IMPL, since we're built in warm load.)
  14 \f
  15 ;;;; hacking the Unix environment
  16 ;;;;
  17 ;;;; In the original CMU CL code that LOAD-FOREIGN is derived from, the
  18 ;;;; Unix environment (as in "man environ") was represented as an
  19 ;;;; alist from keywords to strings, so that e.g. the Unix environment
  20 ;;;;   "SHELL=/bin/bash" "HOME=/root" "PAGER=less"
  21 ;;;; was represented as
  22 ;;;;   ((:SHELL . "/bin/bash") (:HOME . "/root") (:PAGER "less"))
  23 ;;;; This had a few problems in principle: the mapping into
  24 ;;;; keyword symbols smashed the case of environment
  25 ;;;; variables, and the whole mapping depended on the presence of
  26 ;;;; #\= characters in the environment strings. In practice these
  27 ;;;; problems weren't hugely important, since conventionally environment
  28 ;;;; variables are uppercase strings followed by #\= followed by
  29 ;;;; arbitrary data. However, since it's so manifestly not The Right
  30 ;;;; Thing to make code which breaks unnecessarily on input which
  31 ;;;; doesn't follow what is, after all, only a tradition, we've switched
  32 ;;;; formats in SBCL, so that the fundamental environment list
  33 ;;;; is just a list of strings, with a one-to-one-correspondence
  34 ;;;; to the C-level representation. I.e., in the example above,
  35 ;;;; the SBCL representation is
  36 ;;;;   '("SHELL=/bin/bash" "HOME=/root" "PAGER=less")
  37 ;;;; CMU CL's implementation is currently supported to help with porting.
  38 ;;;;
  39 ;;;; It's not obvious that this code belongs here (instead of e.g. in
  40 ;;;; unix.lisp), since it has only a weak logical connection with
  41 ;;;; RUN-PROGRAM. However, physically it's convenient to put it here.
  42 ;;;; It's not needed at cold init, so we *can* put it in this
  43 ;;;; warm-loaded file. And by putting it in this warm-loaded file, we
  44 ;;;; make it easy for it to get to the C-level 'environ' variable.
  45 ;;;; which (at least in sbcl-0.6.10 on Red Hat Linux 6.2) is not
  46 ;;;; visible at GENESIS time.
  47
  48 (define-alien-routine wrapped-environ (* c-string))
  49 (defun posix-environ ()
  50   "Return the Unix environment (\"man environ\") as a list of SIMPLE-STRINGs."
  51   (c-strings->string-list (wrapped-environ)))
  52
  53 ;;; Convert as best we can from an SBCL representation of a Unix
  54 ;;; environment to a CMU CL representation.
  55 ;;;
  56 ;;; * (UNIX-ENVIRONMENT-CMUCL-FROM-SBCL '("Bletch=fub" "Noggin" "YES=No!"))
  57 ;;; WARNING:
  58 ;;;   smashing case of "Bletch=fub" in conversion to CMU-CL-style
  59 ;;;     environment alist
  60 ;;; WARNING:
  61 ;;;   no #\= in "Noggin", eliding it in CMU-CL-style environment alist
  62 ;;; ((:BLETCH . "fub") (:YES . "No!"))
  63 (defun unix-environment-cmucl-from-sbcl (sbcl)
  64   (mapcan
  65    (lambda (string)
  66      (declare (type simple-base-string string))
  67      (let ((=-pos (position #\= string :test #'equal)))
  68        (if =-pos
  69            (list
  70             (let* ((key-as-string (subseq string 0 =-pos))
  71                    (key-as-upcase-string (string-upcase key-as-string))
  72                    (key (keywordicate key-as-upcase-string))
  73                    (val (subseq string (1+ =-pos))))
  74               (unless (string= key-as-string key-as-upcase-string)
  75                 (warn "smashing case of ~S in conversion to CMU-CL-style ~
  76                       environment alist"
  77                       string))
  78               (cons key val)))
  79            (warn "no #\\= in ~S, eliding it in CMU-CL-style environment alist"
  80                  string))))
  81    sbcl))
  82
  83 ;;; Convert from a CMU CL representation of a Unix environment to a
  84 ;;; SBCL representation.
  85 (defun unix-environment-sbcl-from-cmucl (cmucl)
  86   (mapcar
  87    (lambda (cons)
  88      (destructuring-bind (key . val) cons
  89        (declare (type keyword key) (type simple-base-string val))
  90        (concatenate 'simple-base-string (symbol-name key) "=" val)))
  91    cmucl))
  92 \f
  93 ;;;; Import wait3(2) from Unix.
  94
  95 (define-alien-routine ("wait3" c-wait3) sb-alien:int
  96   (status sb-alien:int :out)
  97   (options sb-alien:int)
  98   (rusage sb-alien:int))
  99
 100 (defun wait3 (&optional do-not-hang check-for-stopped)
 101   "Return any available status information on child process. "
 102   (multiple-value-bind (pid status)
 103       (c-wait3 (logior (if do-not-hang
 104                            sb-unix:wnohang
 105                            0)
 106                        (if check-for-stopped
 107                            sb-unix:wuntraced
 108                            0))
 109                0)
 110     (cond ((or (minusp pid)
 111                (zerop pid))
 112            nil)
 113           ((eql (ldb (byte 8 0) status)
 114                 sb-unix:wstopped)
 115            (values pid
 116                    :stopped
 117                    (ldb (byte 8 8) status)))
 118           ((zerop (ldb (byte 7 0) status))
 119            (values pid
 120                    :exited
 121                    (ldb (byte 8 8) status)))
 122           (t
 123            (let ((signal (ldb (byte 7 0) status)))
 124              (values pid
 125                      (if (position signal
 126                                    #.(vector
 127                                       sb-unix:sigstop
 128                                       sb-unix:sigtstp
 129                                       sb-unix:sigttin
 130                                       sb-unix:sigttou))
 131                          :stopped
 132                          :signaled)
 133                      signal
 134                      (not (zerop (ldb (byte 1 7) status)))))))))
 135 \f
 136 ;;;; process control stuff
 137
 138 (defvar *active-processes* nil
 139   "List of process structures for all active processes.")
 140
 141 (defstruct (process (:copier nil))
 142   pid                 ; PID of child process
 143   %status             ; either :RUNNING, :STOPPED, :EXITED, or :SIGNALED
 144   exit-code           ; either exit code or signal
 145   core-dumped         ; T if a core image was dumped
 146   pty                 ; stream to child's pty, or NIL
 147   input               ; stream to child's input, or NIL
 148   output              ; stream from child's output, or NIL
 149   error               ; stream from child's error output, or NIL
 150   status-hook         ; closure to call when PROC changes status
 151   plist               ; a place for clients to stash things
 152   cookie)             ; list of the number of pipes from the subproc
 153
 154 (defmethod print-object ((process process) stream)
 155   (print-unreadable-object (process stream :type t)
 156     (format stream
 157             "~W ~S"
 158             (process-pid process)
 159             (process-status process)))
 160   process)
 161
 162 (defun process-status (proc)
 163   "Return the current status of process.  The result is one of :RUNNING,
 164    :STOPPED, :EXITED, or :SIGNALED."
 165   (get-processes-status-changes)
 166   (process-%status proc))
 167
 168 (defun process-wait (proc &optional check-for-stopped)
 169   "Wait for PROC to quit running for some reason.  Returns PROC."
 170   (loop
 171       (case (process-status proc)
 172         (:running)
 173         (:stopped
 174          (when check-for-stopped
 175            (return)))
 176         (t
 177          (when (zerop (car (process-cookie proc)))
 178            (return))))
 179       (sb-sys:serve-all-events 1))
 180   proc)
 181
 182 #-hpux
 183 ;;; Find the current foreground process group id.
 184 (defun find-current-foreground-process (proc)
 185   (with-alien ((result sb-alien:int))
 186     (multiple-value-bind
 187           (wonp error)
 188         (sb-unix:unix-ioctl (sb-sys:fd-stream-fd (process-pty proc))
 189                             sb-unix:TIOCGPGRP
 190                             (alien-sap (sb-alien:addr result)))
 191       (unless wonp
 192         (error "TIOCPGRP ioctl failed: ~S" (strerror error)))
 193       result))
 194   (process-pid proc))
 195
 196 (defun process-kill (proc signal &optional (whom :pid))
 197   "Hand SIGNAL to PROC. If WHOM is :PID, use the kill Unix system call. If
 198    WHOM is :PROCESS-GROUP, use the killpg Unix system call. If WHOM is
 199    :PTY-PROCESS-GROUP deliver the signal to whichever process group is
 200    currently in the foreground."
 201   (let ((pid (ecase whom
 202                ((:pid :process-group)
 203                 (process-pid proc))
 204                (:pty-process-group
 205                 #-hpux
 206                 (find-current-foreground-process proc)))))
 207     (multiple-value-bind
 208           (okay errno)
 209         (case whom
 210           #+hpux
 211           (:pty-process-group
 212            (sb-unix:unix-ioctl (sb-sys:fd-stream-fd (process-pty proc))
 213                                sb-unix:TIOCSIGSEND
 214                                (sb-sys:int-sap
 215                                 signal)))
 216           ((:process-group #-hpux :pty-process-group)
 217            (sb-unix:unix-killpg pid signal))
 218           (t
 219            (sb-unix:unix-kill pid signal)))
 220       (cond ((not okay)
 221              (values nil errno))
 222             ((and (eql pid (process-pid proc))
 223                   (= signal sb-unix:sigcont))
 224              (setf (process-%status proc) :running)
 225              (setf (process-exit-code proc) nil)
 226              (when (process-status-hook proc)
 227                (funcall (process-status-hook proc) proc))
 228              t)
 229             (t
 230              t)))))
 231
 232 (defun process-alive-p (proc)
 233   "Return T if the process is still alive, NIL otherwise."
 234   (let ((status (process-status proc)))
 235     (if (or (eq status :running)
 236             (eq status :stopped))
 237         t
 238         nil)))
 239
 240 (defun process-close (proc)
 241   "Close all streams connected to PROC and stop maintaining the status slot."
 242   (macrolet ((frob (stream abort)
 243                `(when ,stream (close ,stream :abort ,abort))))
 244     (frob (process-pty    proc)   t) ; Don't FLUSH-OUTPUT to dead process, ..
 245     (frob (process-input  proc)   t) ; .. 'cause it will generate SIGPIPE.
 246     (frob (process-output proc) nil)
 247     (frob (process-error  proc) nil))
 248   (sb-sys:without-interrupts
 249    (setf *active-processes* (delete proc *active-processes*)))
 250   proc)
 251
 252 ;;; the handler for SIGCHLD signals that RUN-PROGRAM establishes
 253 (defun sigchld-handler (ignore1 ignore2 ignore3)
 254   (declare (ignore ignore1 ignore2 ignore3))
 255   (get-processes-status-changes))
 256
 257 (defun get-processes-status-changes ()
 258   (loop
 259       (multiple-value-bind (pid what code core)
 260           (wait3 t t)
 261         (unless pid
 262           (return))
 263         (let ((proc (find pid *active-processes* :key #'process-pid)))
 264           (when proc
 265             (setf (process-%status proc) what)
 266             (setf (process-exit-code proc) code)
 267             (setf (process-core-dumped proc) core)
 268             (when (process-status-hook proc)
 269               (funcall (process-status-hook proc) proc))
 270             (when (position what #(:exited :signaled))
 271               (sb-sys:without-interrupts
 272                (setf *active-processes*
 273                      (delete proc *active-processes*)))))))))
 274 \f
 275 ;;;; RUN-PROGRAM and close friends
 276
 277 ;;; list of file descriptors to close when RUN-PROGRAM exits due to an error
 278 (defvar *close-on-error* nil)
 279
 280 ;;; list of file descriptors to close when RUN-PROGRAM returns in the parent
 281 (defvar *close-in-parent* nil)
 282
 283 ;;; list of handlers installed by RUN-PROGRAM
 284 (defvar *handlers-installed* nil)
 285
 286 ;;; Find an unused pty. Return three values: the file descriptor for
 287 ;;; the master side of the pty, the file descriptor for the slave side
 288 ;;; of the pty, and the name of the tty device for the slave side.
 289 (defun find-a-pty ()
 290   (dolist (char '(#\p #\q))
 291     (dotimes (digit 16)
 292       (let* ((master-name (format nil "/dev/pty~C~X" char digit))
 293              (master-fd (sb-unix:unix-open master-name
 294                                            sb-unix:o_rdwr
 295                                            #o666)))
 296         (when master-fd
 297           (let* ((slave-name (format nil "/dev/tty~C~X" char digit))
 298                  (slave-fd (sb-unix:unix-open slave-name
 299                                               sb-unix:o_rdwr
 300                                               #o666)))
 301             (when slave-fd
 302               (return-from find-a-pty
 303                 (values master-fd
 304                         slave-fd
 305                         slave-name)))
 306             (sb-unix:unix-close master-fd))))))
 307   (error "could not find a pty"))
 308
 309 (defun open-pty (pty cookie)
 310   (when pty
 311     (multiple-value-bind
 312           (master slave name)
 313         (find-a-pty)
 314       (push master *close-on-error*)
 315       (push slave *close-in-parent*)
 316       (when (streamp pty)
 317         (multiple-value-bind (new-fd errno) (sb-unix:unix-dup master)
 318           (unless new-fd
 319             (error "couldn't SB-UNIX:UNIX-DUP ~W: ~A" master (strerror errno)))
 320           (push new-fd *close-on-error*)
 321           (copy-descriptor-to-stream new-fd pty cookie)))
 322       (values name
 323               (sb-sys:make-fd-stream master :input t :output t)))))
 324
 325 (defmacro round-bytes-to-words (n)
 326   `(logand (the fixnum (+ (the fixnum ,n) 3)) (lognot 3)))
 327
 328 (defun string-list-to-c-strvec (string-list)
 329   ;; Make a pass over STRING-LIST to calculate the amount of memory
 330   ;; needed to hold the strvec.
 331   (let ((string-bytes 0)
 332         ;; We need an extra for the null, and an extra 'cause exect
 333         ;; clobbers argv[-1].
 334         (vec-bytes (* #-alpha 4 #+alpha 8 (+ (length string-list) 2))))
 335     (declare (fixnum string-bytes vec-bytes))
 336     (dolist (s string-list)
 337       (enforce-type s simple-string)
 338       (incf string-bytes (round-bytes-to-words (1+ (length s)))))
 339     ;; Now allocate the memory and fill it in.
 340     (let* ((total-bytes (+ string-bytes vec-bytes))
 341            (vec-sap (sb-sys:allocate-system-memory total-bytes))
 342            (string-sap (sap+ vec-sap vec-bytes))
 343            (i #-alpha 4 #+alpha 8))
 344       (declare (type (and unsigned-byte fixnum) total-bytes i)
 345                (type sb-sys:system-area-pointer vec-sap string-sap))
 346       (dolist (s string-list)
 347         (declare (simple-string s))
 348         (let ((n (length s)))
 349           ;; Blast the string into place.
 350           (sb-kernel:copy-to-system-area (the simple-string s)
 351                                          (* sb-vm:vector-data-offset
 352                                             sb-vm:n-word-bits)
 353                                          string-sap 0
 354                                          (* (1+ n) sb-vm:n-byte-bits))
 355           ;; Blast the pointer to the string into place.
 356           (setf (sap-ref-sap vec-sap i) string-sap)
 357           (setf string-sap (sap+ string-sap (round-bytes-to-words (1+ n))))
 358           (incf i #-alpha 4 #+alpha 8)))
 359       ;; Blast in the last null pointer.
 360       (setf (sap-ref-sap vec-sap i) (int-sap 0))
 361       (values vec-sap (sap+ vec-sap #-alpha 4 #+alpha 8) total-bytes))))
 362
 363 (defmacro with-c-strvec ((var str-list) &body body)
 364   (with-unique-names (sap size)
 365     `(multiple-value-bind
 366       (,sap ,var ,size)
 367       (string-list-to-c-strvec ,str-list)
 368       (unwind-protect
 369            (progn
 370              ,@body)
 371         (sb-sys:deallocate-system-memory ,sap ,size)))))
 372
 373 (sb-alien:define-alien-routine spawn sb-alien:int
 374   (program sb-alien:c-string)
 375   (argv (* sb-alien:c-string))
 376   (envp (* sb-alien:c-string))
 377   (pty-name sb-alien:c-string)
 378   (stdin sb-alien:int)
 379   (stdout sb-alien:int)
 380   (stderr sb-alien:int))
 381
 382 ;;; Is UNIX-FILENAME the name of a file that we can execute?
 383 (defun unix-filename-is-executable-p (unix-filename)
 384   (declare (type simple-string unix-filename))
 385   (values (and (eq (sb-unix:unix-file-kind unix-filename) :file)
 386                (sb-unix:unix-access unix-filename sb-unix:x_ok))))
 387
 388 (defun find-executable-in-search-path (pathname
 389                                        &optional
 390                                        (search-path (posix-getenv "PATH")))
 391   "Find the first executable file matching PATHNAME in any of the colon-separated list of pathnames SEARCH-PATH"
 392   (loop for end =  (position #\: search-path :start (if end (1+ end) 0))
 393         and start = 0 then (and end (1+ end))
 394         while start
 395         ;; <Krystof> the truename of a file naming a directory is the
 396         ;; directory, at least until pfdietz comes along and says why
 397         ;; that's noncompliant  -- CSR, c. 2003-08-10
 398         for truename = (probe-file (subseq search-path start end))
 399         for fullpath = (when truename (merge-pathnames pathname truename))
 400         when (and fullpath
 401                   (unix-filename-is-executable-p (namestring fullpath)))
 402         return fullpath))
 403
 404 ;;; FIXME: There shouldn't be two semiredundant versions of the
 405 ;;; documentation. Since this is a public extension function, the
 406 ;;; documentation should be in the doc string. So all information from
 407 ;;; this comment should be merged into the doc string, and then this
 408 ;;; comment can go away.
 409 ;;;
 410 ;;; RUN-PROGRAM uses fork() and execve() to run a different program.
 411 ;;; Strange stuff happens to keep the Unix state of the world
 412 ;;; coherent.
 413 ;;;
 414 ;;; The child process needs to get its input from somewhere, and send
 415 ;;; its output (both standard and error) to somewhere. We have to do
 416 ;;; different things depending on where these somewheres really are.
 417 ;;;
 418 ;;; For input, there are five options:
 419 ;;;  -- T: Just leave fd 0 alone. Pretty simple.
 420 ;;;  -- "file": Read from the file. We need to open the file and
 421 ;;;     pull the descriptor out of the stream. The parent should close
 422 ;;;     this stream after the child is up and running to free any
 423 ;;;     storage used in the parent.
 424 ;;;  -- NIL: Same as "file", but use "/dev/null" as the file.
 425 ;;;  -- :STREAM: Use Unix pipe() to create two descriptors. Use
 426 ;;;     SB-SYS:MAKE-FD-STREAM to create the output stream on the
 427 ;;;     writeable descriptor, and pass the readable descriptor to
 428 ;;;     the child. The parent must close the readable descriptor for
 429 ;;;     EOF to be passed up correctly.
 430 ;;;  -- a stream: If it's a fd-stream, just pull the descriptor out
 431 ;;;     of it. Otherwise make a pipe as in :STREAM, and copy
 432 ;;;     everything across.
 433 ;;;
 434 ;;; For output, there are five options:
 435 ;;;  -- T: Leave descriptor 1 alone.
 436 ;;;  -- "file": dump output to the file.
 437 ;;;  -- NIL: dump output to /dev/null.
 438 ;;;  -- :STREAM: return a stream that can be read from.
 439 ;;;  -- a stream: if it's a fd-stream, use the descriptor in it.
 440 ;;;     Otherwise, copy stuff from output to stream.
 441 ;;;
 442 ;;; For error, there are all the same options as output plus:
 443 ;;;  -- :OUTPUT: redirect to the same place as output.
 444 ;;;
 445 ;;; RUN-PROGRAM returns a PROCESS structure for the process if
 446 ;;; the fork worked, and NIL if it did not.
 447 (defun run-program (program args
 448                     &key
 449                     (env nil env-p)
 450                     (environment (if env-p
 451                                      (unix-environment-sbcl-from-cmucl env)
 452                                      (posix-environ))
 453                                  environment-p)
 454                     (wait t)
 455                     search
 456                     pty
 457                     input
 458                     if-input-does-not-exist
 459                     output
 460                     (if-output-exists :error)
 461                     (error :output)
 462                     (if-error-exists :error)
 463                     status-hook)
 464   "RUN-PROGRAM creates a new Unix process running the Unix program found in
 465    the file specified by the PROGRAM argument.  ARGS are the standard
 466    arguments that can be passed to a Unix program. For no arguments, use NIL
 467    (which means that just the name of the program is passed as arg 0).
 468
 469    RUN-PROGRAM will either return NIL or a PROCESS structure.  See the CMU
 470    Common Lisp Users Manual for details about the PROCESS structure.
 471
 472    notes about Unix environments (as in the :ENVIRONMENT and :ENV args):
 473      1. The SBCL implementation of RUN-PROGRAM, like Perl and many other
 474         programs, but unlike the original CMU CL implementation, copies
 475         the Unix environment by default.
 476      2. Running Unix programs from a setuid process, or in any other
 477         situation where the Unix environment is under the control of someone
 478         else, is a mother lode of security problems. If you are contemplating
 479         doing this, read about it first. (The Perl community has a lot of good
 480         documentation about this and other security issues in script-like
 481         programs.)
 482
 483    The &KEY arguments have the following meanings:
 484      :ENVIRONMENT
 485         a list of SIMPLE-BASE-STRINGs describing the new Unix environment
 486         (as in \"man environ\"). The default is to copy the environment of
 487         the current process.
 488      :ENV
 489         an alternative lossy representation of the new Unix environment,
 490         for compatibility with CMU CL
 491      :SEARCH
 492         Look for PROGRAM in each of the directories along the $PATH
 493         environment variable.  Otherwise an absolute pathname is required.
 494         (See also FIND-EXECUTABLE-IN-SEARCH-PATH)
 495      :WAIT
 496         If non-NIL (default), wait until the created process finishes.  If
 497         NIL, continue running Lisp until the program finishes.
 498      :PTY
 499         Either T, NIL, or a stream.  Unless NIL, the subprocess is established
 500         under a PTY.  If :pty is a stream, all output to this pty is sent to
 501         this stream, otherwise the PROCESS-PTY slot is filled in with a stream
 502         connected to pty that can read output and write input.
 503      :INPUT
 504         Either T, NIL, a pathname, a stream, or :STREAM.  If T, the standard
 505         input for the current process is inherited.  If NIL, /dev/null
 506         is used.  If a pathname, the file so specified is used.  If a stream,
 507         all the input is read from that stream and send to the subprocess.  If
 508         :STREAM, the PROCESS-INPUT slot is filled in with a stream that sends
 509         its output to the process. Defaults to NIL.
 510      :IF-INPUT-DOES-NOT-EXIST (when :INPUT is the name of a file)
 511         can be one of:
 512            :ERROR to generate an error
 513            :CREATE to create an empty file
 514            NIL (the default) to return NIL from RUN-PROGRAM
 515      :OUTPUT
 516         Either T, NIL, a pathname, a stream, or :STREAM.  If T, the standard
 517         output for the current process is inherited.  If NIL, /dev/null
 518         is used.  If a pathname, the file so specified is used.  If a stream,
 519         all the output from the process is written to this stream. If
 520         :STREAM, the PROCESS-OUTPUT slot is filled in with a stream that can
 521         be read to get the output. Defaults to NIL.
 522      :IF-OUTPUT-EXISTS (when :OUTPUT is the name of a file)
 523         can be one of:
 524            :ERROR (the default) to generate an error
 525            :SUPERSEDE to supersede the file with output from the program
 526            :APPEND to append output from the program to the file
 527            NIL to return NIL from RUN-PROGRAM, without doing anything
 528      :ERROR and :IF-ERROR-EXISTS
 529         Same as :OUTPUT and :IF-OUTPUT-EXISTS, except that :ERROR can also be
 530         specified as :OUTPUT in which case all error output is routed to the
 531         same place as normal output.
 532      :STATUS-HOOK
 533         This is a function the system calls whenever the status of the
 534         process changes.  The function takes the process as an argument."
 535
 536   (when (and env-p environment-p)
 537     (error "can't specify :ENV and :ENVIRONMENT simultaneously"))
 538   ;; Make sure that the interrupt handler is installed.
 539   (sb-sys:enable-interrupt sb-unix:sigchld #'sigchld-handler)
 540   ;; Prepend the program to the argument list.
 541   (push (namestring program) args)
 542   (let (;; Clear various specials used by GET-DESCRIPTOR-FOR to
 543         ;; communicate cleanup info.
 544         *close-on-error*
 545         *close-in-parent*
 546         *handlers-installed*
 547         ;; Establish PROC at this level so that we can return it.
 548         proc
 549         ;; It's friendly to allow the caller to pass any string
 550         ;; designator, but internally we'd like SIMPLE-STRINGs.
 551         (simple-args (mapcar (lambda (x) (coerce x 'simple-string)) args)))
 552     (unwind-protect
 553          (let ((pfile
 554                 (if search
 555                     (let ((p (find-executable-in-search-path program)))
 556                       (and p (unix-namestring p t)))
 557                     (unix-namestring program t)))
 558                (cookie (list 0)))
 559            (unless pfile
 560              (error "no such program: ~S" program))
 561            (unless (unix-filename-is-executable-p pfile)
 562              (error "not executable: ~S" program))
 563            (multiple-value-bind (stdin input-stream)
 564                (get-descriptor-for input cookie
 565                                    :direction :input
 566                                    :if-does-not-exist if-input-does-not-exist)
 567              (multiple-value-bind (stdout output-stream)
 568                  (get-descriptor-for output cookie
 569                                      :direction :output
 570                                      :if-exists if-output-exists)
 571                (multiple-value-bind (stderr error-stream)
 572                    (if (eq error :output)
 573                        (values stdout output-stream)
 574                        (get-descriptor-for error cookie
 575                                            :direction :output
 576                                            :if-exists if-error-exists))
 577                  (multiple-value-bind (pty-name pty-stream)
 578                      (open-pty pty cookie)
 579                    ;; Make sure we are not notified about the child
 580                    ;; death before we have installed the PROCESS
 581                    ;; structure in *ACTIVE-PROCESSES*.
 582                    (sb-sys:without-interrupts
 583                     (with-c-strvec (args-vec simple-args)
 584                       (with-c-strvec (environment-vec environment)
 585                         (let ((child-pid
 586                                (without-gcing
 587                                 (spawn pfile args-vec environment-vec pty-name
 588                                        stdin stdout stderr))))
 589                           (when (< child-pid 0)
 590                             (error "couldn't fork child process: ~A"
 591                                    (strerror)))
 592                           (setf proc (make-process :pid child-pid
 593                                                    :%status :running
 594                                                    :pty pty-stream
 595                                                    :input input-stream
 596                                                    :output output-stream
 597                                                    :error error-stream
 598                                                    :status-hook status-hook
 599                                                    :cookie cookie))
 600                           (push proc *active-processes*))))))))))
 601       (dolist (fd *close-in-parent*)
 602         (sb-unix:unix-close fd))
 603       (unless proc
 604         (dolist (fd *close-on-error*)
 605           (sb-unix:unix-close fd))
 606         (dolist (handler *handlers-installed*)
 607           (sb-sys:remove-fd-handler handler))))
 608     (when (and wait proc)
 609       (process-wait proc))
 610     proc))
 611
 612 ;;; Install a handler for any input that shows up on the file
 613 ;;; descriptor. The handler reads the data and writes it to the
 614 ;;; stream.
 615 (defun copy-descriptor-to-stream (descriptor stream cookie)
 616   (incf (car cookie))
 617   (let ((string (make-string 256))
 618         handler)
 619     (setf handler
 620           (sb-sys:add-fd-handler
 621            descriptor
 622            :input (lambda (fd)
 623                     (declare (ignore fd))
 624                     (loop
 625                      (unless handler
 626                        (return))
 627                      (multiple-value-bind
 628                          (result readable/errno)
 629                          (sb-unix:unix-select (1+ descriptor)
 630                                               (ash 1 descriptor)
 631                                               0 0 0)
 632                        (cond ((null result)
 633                               (error "~@<couldn't select on sub-process: ~
 634                                            ~2I~_~A~:>"
 635                                      (strerror readable/errno)))
 636                              ((zerop result)
 637                               (return))))
 638                      (sb-alien:with-alien ((buf (sb-alien:array
 639                                                  sb-alien:char
 640                                                  256)))
 641                        (multiple-value-bind
 642                            (count errno)
 643                            (sb-unix:unix-read descriptor
 644                                               (alien-sap buf)
 645                                               256)
 646                          (cond ((or (and (null count)
 647                                          (eql errno sb-unix:eio))
 648                                     (eql count 0))
 649                                 (sb-sys:remove-fd-handler handler)
 650                                 (setf handler nil)
 651                                 (decf (car cookie))
 652                                 (sb-unix:unix-close descriptor)
 653                                 (return))
 654                                ((null count)
 655                                 (sb-sys:remove-fd-handler handler)
 656                                 (setf handler nil)
 657                                 (decf (car cookie))
 658                                 (error
 659                                  "~@<couldn't read input from sub-process: ~
 660                                      ~2I~_~A~:>"
 661                                  (strerror errno)))
 662                                (t
 663                                 (sb-kernel:copy-from-system-area
 664                                  (alien-sap buf) 0
 665                                  string (* sb-vm:vector-data-offset
 666                                            sb-vm:n-word-bits)
 667                                  (* count sb-vm:n-byte-bits))
 668                                 (write-string string stream
 669                                               :end count)))))))))))
 670
 671 ;;; Find a file descriptor to use for object given the direction.
 672 ;;; Returns the descriptor. If object is :STREAM, returns the created
 673 ;;; stream as the second value.
 674 (defun get-descriptor-for (object
 675                            cookie
 676                            &rest keys
 677                            &key direction
 678                            &allow-other-keys)
 679   (cond ((eq object t)
 680          ;; No new descriptor is needed.
 681          (values -1 nil))
 682         ((eq object nil)
 683          ;; Use /dev/null.
 684          (multiple-value-bind
 685                (fd errno)
 686              (sb-unix:unix-open "/dev/null"
 687                                 (case direction
 688                                   (:input sb-unix:o_rdonly)
 689                                   (:output sb-unix:o_wronly)
 690                                   (t sb-unix:o_rdwr))
 691                                 #o666)
 692            (unless fd
 693              (error "~@<couldn't open \"/dev/null\": ~2I~_~A~:>"
 694                     (strerror errno)))
 695            (push fd *close-in-parent*)
 696            (values fd nil)))
 697         ((eq object :stream)
 698          (multiple-value-bind (read-fd write-fd) (sb-unix:unix-pipe)
 699            (unless read-fd
 700              (error "couldn't create pipe: ~A" (strerror write-fd)))
 701            (case direction
 702              (:input
 703               (push read-fd *close-in-parent*)
 704               (push write-fd *close-on-error*)
 705               (let ((stream (sb-sys:make-fd-stream write-fd :output t)))
 706                 (values read-fd stream)))
 707              (:output
 708               (push read-fd *close-on-error*)
 709               (push write-fd *close-in-parent*)
 710               (let ((stream (sb-sys:make-fd-stream read-fd :input t)))
 711                 (values write-fd stream)))
 712              (t
 713               (sb-unix:unix-close read-fd)
 714               (sb-unix:unix-close write-fd)
 715               (error "Direction must be either :INPUT or :OUTPUT, not ~S."
 716                      direction)))))
 717         ((or (pathnamep object) (stringp object))
 718          (with-open-stream (file (apply #'open object keys))
 719            (multiple-value-bind
 720                  (fd errno)
 721                (sb-unix:unix-dup (sb-sys:fd-stream-fd file))
 722              (cond (fd
 723                     (push fd *close-in-parent*)
 724                     (values fd nil))
 725                    (t
 726                     (error "couldn't duplicate file descriptor: ~A"
 727                            (strerror errno)))))))
 728         ((sb-sys:fd-stream-p object)
 729          (values (sb-sys:fd-stream-fd object) nil))
 730         ((streamp object)
 731          (ecase direction
 732            (:input
 733             ;; FIXME: We could use a better way of setting up
 734             ;; temporary files, both here and in LOAD-FOREIGN.
 735             (dotimes (count
 736                        256
 737                       (error "could not open a temporary file in /tmp"))
 738               (let* ((name (format nil "/tmp/.run-program-~D" count))
 739                      (fd (sb-unix:unix-open name
 740                                             (logior sb-unix:o_rdwr
 741                                                     sb-unix:o_creat
 742                                                     sb-unix:o_excl)
 743                                             #o666)))
 744                 (sb-unix:unix-unlink name)
 745                 (when fd
 746                   (let ((newline (string #\Newline)))
 747                     (loop
 748                         (multiple-value-bind
 749                               (line no-cr)
 750                             (read-line object nil nil)
 751                           (unless line
 752                             (return))
 753                           (sb-unix:unix-write fd line 0 (length line))
 754                           (if no-cr
 755                               (return)
 756                               (sb-unix:unix-write fd newline 0 1)))))
 757                   (sb-unix:unix-lseek fd 0 sb-unix:l_set)
 758                   (push fd *close-in-parent*)
 759                   (return (values fd nil))))))
 760            (:output
 761             (multiple-value-bind (read-fd write-fd)
 762                 (sb-unix:unix-pipe)
 763               (unless read-fd
 764                 (error "couldn't create pipe: ~S" (strerror write-fd)))
 765               (copy-descriptor-to-stream read-fd object cookie)
 766               (push read-fd *close-on-error*)
 767               (push write-fd *close-in-parent*)
 768               (values write-fd nil)))))
 769         (t
 770          (error "invalid option to RUN-PROGRAM: ~S" object))))