src/code/run-program.lisp

   1 ;;;; RUN-PROGRAM and friends, a facility for running Unix programs
   2 ;;;; from inside SBCL
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB-IMPL") ;(SB-IMPL, not SB!IMPL, since we're built in warm load.)
  14 \f
  15 ;;;; hacking the Unix environment
  16 ;;;;
  17 ;;;; In the original CMU CL code that LOAD-FOREIGN is derived from, the
  18 ;;;; Unix environment (as in "man environ") was represented as an
  19 ;;;; alist from keywords to strings, so that e.g. the Unix environment
  20 ;;;;   "SHELL=/bin/bash" "HOME=/root" "PAGER=less"
  21 ;;;; was represented as
  22 ;;;;   ((:SHELL . "/bin/bash") (:HOME . "/root") (:PAGER "less"))
  23 ;;;; This had a few problems in principle: the mapping into
  24 ;;;; keyword symbols smashed the case of environment
  25 ;;;; variables, and the whole mapping depended on the presence of
  26 ;;;; #\= characters in the environment strings. In practice these
  27 ;;;; problems weren't hugely important, since conventionally environment
  28 ;;;; variables are uppercase strings followed by #\= followed by
  29 ;;;; arbitrary data. However, since it's so manifestly not The Right
  30 ;;;; Thing to make code which breaks unnecessarily on input which
  31 ;;;; doesn't follow what is, after all, only a tradition, we've switched
  32 ;;;; formats in SBCL, so that the fundamental environment list
  33 ;;;; is just a list of strings, with a one-to-one-correspondence
  34 ;;;; to the C-level representation. I.e., in the example above,
  35 ;;;; the SBCL representation is
  36 ;;;;   '("SHELL=/bin/bash" "HOME=/root" "PAGER=less")
  37 ;;;; CMU CL's implementation is currently supported to help with porting.
  38 ;;;;
  39 ;;;; It's not obvious that this code belongs here (instead of e.g. in
  40 ;;;; unix.lisp), since it has only a weak logical connection with
  41 ;;;; RUN-PROGRAM. However, physically it's convenient to put it here.
  42 ;;;; It's not needed at cold init, so we *can* put it in this
  43 ;;;; warm-loaded file. And by putting it in this warm-loaded file, we
  44 ;;;; make it easy for it to get to the C-level 'environ' variable.
  45 ;;;; which (at least in sbcl-0.6.10 on Red Hat Linux 6.2) is not
  46 ;;;; visible at GENESIS time.
  47
  48 (define-alien-routine wrapped-environ (* c-string))
  49 (defun posix-environ ()
  50   "Return the Unix environment (\"man environ\") as a list of SIMPLE-STRINGs."
  51   (c-strings->string-list (wrapped-environ)))
  52
  53 ;;; Convert as best we can from an SBCL representation of a Unix
  54 ;;; environment to a CMU CL representation.
  55 ;;;
  56 ;;; * (UNIX-ENVIRONMENT-CMUCL-FROM-SBCL '("Bletch=fub" "Noggin" "YES=No!"))
  57 ;;; WARNING:
  58 ;;;   smashing case of "Bletch=fub" in conversion to CMU-CL-style
  59 ;;;     environment alist
  60 ;;; WARNING:
  61 ;;;   no #\= in "Noggin", eliding it in CMU-CL-style environment alist
  62 ;;; ((:BLETCH . "fub") (:YES . "No!"))
  63 (defun unix-environment-cmucl-from-sbcl (sbcl)
  64   (mapcan
  65    (lambda (string)
  66      (declare (type simple-string string))
  67      (let ((=-pos (position #\= string :test #'equal)))
  68        (if =-pos
  69            (list
  70             (let* ((key-as-string (subseq string 0 =-pos))
  71                    (key-as-upcase-string (string-upcase key-as-string))
  72                    (key (keywordicate key-as-upcase-string))
  73                    (val (subseq string (1+ =-pos))))
  74               (unless (string= key-as-string key-as-upcase-string)
  75                 (warn "smashing case of ~S in conversion to CMU-CL-style ~
  76                       environment alist"
  77                       string))
  78               (cons key val)))
  79            (warn "no #\\= in ~S, eliding it in CMU-CL-style environment alist"
  80                  string))))
  81    sbcl))
  82
  83 ;;; Convert from a CMU CL representation of a Unix environment to a
  84 ;;; SBCL representation.
  85 (defun unix-environment-sbcl-from-cmucl (cmucl)
  86   (mapcar
  87    (lambda (cons)
  88      (destructuring-bind (key . val) cons
  89        (declare (type keyword key) (type simple-string val))
  90        (concatenate 'simple-string (symbol-name key) "=" val)))
  91    cmucl))
  92 \f
  93 ;;;; Import wait3(2) from Unix.
  94
  95 (define-alien-routine ("wait3" c-wait3) sb-alien:int
  96   (status sb-alien:int :out)
  97   (options sb-alien:int)
  98   (rusage sb-alien:int))
  99
 100 (defun wait3 (&optional do-not-hang check-for-stopped)
 101   "Return any available status information on child process. "
 102   (multiple-value-bind (pid status)
 103       (c-wait3 (logior (if do-not-hang
 104                            sb-unix:wnohang
 105                            0)
 106                        (if check-for-stopped
 107                            sb-unix:wuntraced
 108                            0))
 109                0)
 110     (cond ((or (minusp pid)
 111                (zerop pid))
 112            nil)
 113           ((eql (ldb (byte 8 0) status)
 114                 sb-unix:wstopped)
 115            (values pid
 116                    :stopped
 117                    (ldb (byte 8 8) status)))
 118           ((zerop (ldb (byte 7 0) status))
 119            (values pid
 120                    :exited
 121                    (ldb (byte 8 8) status)))
 122           (t
 123            (let ((signal (ldb (byte 7 0) status)))
 124              (values pid
 125                      (if (position signal
 126                                    #.(vector
 127                                       (sb-unix:unix-signal-number :sigstop)
 128                                       (sb-unix:unix-signal-number :sigtstp)
 129                                       (sb-unix:unix-signal-number :sigttin)
 130                                       (sb-unix:unix-signal-number :sigttou)))
 131                          :stopped
 132                          :signaled)
 133                      signal
 134                      (not (zerop (ldb (byte 1 7) status)))))))))
 135 \f
 136 ;;;; process control stuff
 137
 138 (defvar *active-processes* nil
 139   "List of process structures for all active processes.")
 140
 141 (defstruct (process (:copier nil))
 142   pid                 ; PID of child process
 143   %status             ; either :RUNNING, :STOPPED, :EXITED, or :SIGNALED
 144   exit-code           ; either exit code or signal
 145   core-dumped         ; T if a core image was dumped
 146   pty                 ; stream to child's pty, or NIL
 147   input               ; stream to child's input, or NIL
 148   output              ; stream from child's output, or NIL
 149   error               ; stream from child's error output, or NIL
 150   status-hook         ; closure to call when PROC changes status
 151   plist               ; a place for clients to stash things
 152   cookie)             ; list of the number of pipes from the subproc
 153
 154 (defmethod print-object ((process process) stream)
 155   (print-unreadable-object (process stream :type t)
 156     (format stream
 157             "~W ~S"
 158             (process-pid process)
 159             (process-status process)))
 160   process)
 161
 162 (defun process-status (proc)
 163   "Return the current status of process.  The result is one of :RUNNING,
 164    :STOPPED, :EXITED, or :SIGNALED."
 165   (get-processes-status-changes)
 166   (process-%status proc))
 167
 168 (defun process-wait (proc &optional check-for-stopped)
 169   "Wait for PROC to quit running for some reason.  Returns PROC."
 170   (loop
 171       (case (process-status proc)
 172         (:running)
 173         (:stopped
 174          (when check-for-stopped
 175            (return)))
 176         (t
 177          (when (zerop (car (process-cookie proc)))
 178            (return))))
 179       (sb-sys:serve-all-events 1))
 180   proc)
 181
 182 #-hpux
 183 ;;; Find the current foreground process group id.
 184 (defun find-current-foreground-process (proc)
 185   (with-alien ((result sb-alien:int))
 186     (multiple-value-bind
 187           (wonp error)
 188         (sb-unix:unix-ioctl (sb-sys:fd-stream-fd (process-pty proc))
 189                             sb-unix:TIOCGPGRP
 190                             (alien-sap (sb-alien:addr result)))
 191       (unless wonp
 192         (error "TIOCPGRP ioctl failed: ~S" (strerror error)))
 193       result))
 194   (process-pid proc))
 195
 196 (defun process-kill (proc signal &optional (whom :pid))
 197   "Hand SIGNAL to PROC. If WHOM is :PID, use the kill Unix system call. If
 198    WHOM is :PROCESS-GROUP, use the killpg Unix system call. If WHOM is
 199    :PTY-PROCESS-GROUP deliver the signal to whichever process group is
 200    currently in the foreground."
 201   (let ((pid (ecase whom
 202                ((:pid :process-group)
 203                 (process-pid proc))
 204                (:pty-process-group
 205                 #-hpux
 206                 (find-current-foreground-process proc)))))
 207     (multiple-value-bind
 208           (okay errno)
 209         (case whom
 210           #+hpux
 211           (:pty-process-group
 212            (sb-unix:unix-ioctl (sb-sys:fd-stream-fd (process-pty proc))
 213                                sb-unix:TIOCSIGSEND
 214                                (sb-sys:int-sap
 215                                 (sb-unix:unix-signal-number signal))))
 216           ((:process-group #-hpux :pty-process-group)
 217            (sb-unix:unix-killpg pid signal))
 218           (t
 219            (sb-unix:unix-kill pid signal)))
 220       (cond ((not okay)
 221              (values nil errno))
 222             ((and (eql pid (process-pid proc))
 223                   (= (sb-unix:unix-signal-number signal)
 224                      (sb-unix:unix-signal-number :sigcont)))
 225              (setf (process-%status proc) :running)
 226              (setf (process-exit-code proc) nil)
 227              (when (process-status-hook proc)
 228                (funcall (process-status-hook proc) proc))
 229              t)
 230             (t
 231              t)))))
 232
 233 (defun process-alive-p (proc)
 234   "Return T if the process is still alive, NIL otherwise."
 235   (let ((status (process-status proc)))
 236     (if (or (eq status :running)
 237             (eq status :stopped))
 238         t
 239         nil)))
 240
 241 (defun process-close (proc)
 242   "Close all streams connected to PROC and stop maintaining the status slot."
 243   (macrolet ((frob (stream abort)
 244                `(when ,stream (close ,stream :abort ,abort))))
 245     (frob (process-pty    proc)   t) ; Don't FLUSH-OUTPUT to dead process, ..
 246     (frob (process-input  proc)   t) ; .. 'cause it will generate SIGPIPE.
 247     (frob (process-output proc) nil)
 248     (frob (process-error  proc) nil))
 249   (sb-sys:without-interrupts
 250    (setf *active-processes* (delete proc *active-processes*)))
 251   proc)
 252
 253 ;;; the handler for SIGCHLD signals that RUN-PROGRAM establishes
 254 (defun sigchld-handler (ignore1 ignore2 ignore3)
 255   (declare (ignore ignore1 ignore2 ignore3))
 256   (get-processes-status-changes))
 257
 258 (defun get-processes-status-changes ()
 259   (loop
 260       (multiple-value-bind (pid what code core)
 261           (wait3 t t)
 262         (unless pid
 263           (return))
 264         (let ((proc (find pid *active-processes* :key #'process-pid)))
 265           (when proc
 266             (setf (process-%status proc) what)
 267             (setf (process-exit-code proc) code)
 268             (setf (process-core-dumped proc) core)
 269             (when (process-status-hook proc)
 270               (funcall (process-status-hook proc) proc))
 271             (when (position what #(:exited :signaled))
 272               (sb-sys:without-interrupts
 273                (setf *active-processes*
 274                      (delete proc *active-processes*)))))))))
 275 \f
 276 ;;;; RUN-PROGRAM and close friends
 277
 278 ;;; list of file descriptors to close when RUN-PROGRAM exits due to an error
 279 (defvar *close-on-error* nil)
 280
 281 ;;; list of file descriptors to close when RUN-PROGRAM returns in the parent
 282 (defvar *close-in-parent* nil)
 283
 284 ;;; list of handlers installed by RUN-PROGRAM
 285 (defvar *handlers-installed* nil)
 286
 287 ;;; Find an unused pty. Return three values: the file descriptor for
 288 ;;; the master side of the pty, the file descriptor for the slave side
 289 ;;; of the pty, and the name of the tty device for the slave side.
 290 (defun find-a-pty ()
 291   (dolist (char '(#\p #\q))
 292     (dotimes (digit 16)
 293       (let* ((master-name (format nil "/dev/pty~C~X" char digit))
 294              (master-fd (sb-unix:unix-open master-name
 295                                            sb-unix:o_rdwr
 296                                            #o666)))
 297         (when master-fd
 298           (let* ((slave-name (format nil "/dev/tty~C~X" char digit))
 299                  (slave-fd (sb-unix:unix-open slave-name
 300                                               sb-unix:o_rdwr
 301                                               #o666)))
 302             (when slave-fd
 303               (return-from find-a-pty
 304                 (values master-fd
 305                         slave-fd
 306                         slave-name)))
 307             (sb-unix:unix-close master-fd))))))
 308   (error "could not find a pty"))
 309
 310 (defun open-pty (pty cookie)
 311   (when pty
 312     (multiple-value-bind
 313           (master slave name)
 314         (find-a-pty)
 315       (push master *close-on-error*)
 316       (push slave *close-in-parent*)
 317       (when (streamp pty)
 318         (multiple-value-bind (new-fd errno) (sb-unix:unix-dup master)
 319           (unless new-fd
 320             (error "couldn't SB-UNIX:UNIX-DUP ~W: ~A" master (strerror errno)))
 321           (push new-fd *close-on-error*)
 322           (copy-descriptor-to-stream new-fd pty cookie)))
 323       (values name
 324               (sb-sys:make-fd-stream master :input t :output t)))))
 325
 326 (defmacro round-bytes-to-words (n)
 327   `(logand (the fixnum (+ (the fixnum ,n) 3)) (lognot 3)))
 328
 329 (defun string-list-to-c-strvec (string-list)
 330   ;; Make a pass over STRING-LIST to calculate the amount of memory
 331   ;; needed to hold the strvec.
 332   (let ((string-bytes 0)
 333         ;; We need an extra for the null, and an extra 'cause exect
 334         ;; clobbers argv[-1].
 335         (vec-bytes (* #-alpha 4 #+alpha 8 (+ (length string-list) 2))))
 336     (declare (fixnum string-bytes vec-bytes))
 337     (dolist (s string-list)
 338       (enforce-type s simple-string)
 339       (incf string-bytes (round-bytes-to-words (1+ (length s)))))
 340     ;; Now allocate the memory and fill it in.
 341     (let* ((total-bytes (+ string-bytes vec-bytes))
 342            (vec-sap (sb-sys:allocate-system-memory total-bytes))
 343            (string-sap (sap+ vec-sap vec-bytes))
 344            (i #-alpha 4 #+alpha 8))
 345       (declare (type (and unsigned-byte fixnum) total-bytes i)
 346                (type sb-sys:system-area-pointer vec-sap string-sap))
 347       (dolist (s string-list)
 348         (declare (simple-string s))
 349         (let ((n (length s)))
 350           ;; Blast the string into place.
 351           (sb-kernel:copy-to-system-area (the simple-string s)
 352                                          (* sb-vm:vector-data-offset
 353                                             sb-vm:n-word-bits)
 354                                          string-sap 0
 355                                          (* (1+ n) sb-vm:n-byte-bits))
 356           ;; Blast the pointer to the string into place.
 357           (setf (sap-ref-sap vec-sap i) string-sap)
 358           (setf string-sap (sap+ string-sap (round-bytes-to-words (1+ n))))
 359           (incf i #-alpha 4 #+alpha 8)))
 360       ;; Blast in the last null pointer.
 361       (setf (sap-ref-sap vec-sap i) (int-sap 0))
 362       (values vec-sap (sap+ vec-sap #-alpha 4 #+alpha 8) total-bytes))))
 363
 364 (defmacro with-c-strvec ((var str-list) &body body)
 365   (with-unique-names (sap size)
 366     `(multiple-value-bind
 367       (,sap ,var ,size)
 368       (string-list-to-c-strvec ,str-list)
 369       (unwind-protect
 370            (progn
 371              ,@body)
 372         (sb-sys:deallocate-system-memory ,sap ,size)))))
 373
 374 (sb-alien:define-alien-routine spawn sb-alien:int
 375   (program sb-alien:c-string)
 376   (argv (* sb-alien:c-string))
 377   (envp (* sb-alien:c-string))
 378   (pty-name sb-alien:c-string)
 379   (stdin sb-alien:int)
 380   (stdout sb-alien:int)
 381   (stderr sb-alien:int))
 382
 383 ;;; Is UNIX-FILENAME the name of a file that we can execute?
 384 (defun unix-filename-is-executable-p (unix-filename)
 385   (declare (type simple-string unix-filename))
 386   (values (and (eq (sb-unix:unix-file-kind unix-filename) :file)
 387                (sb-unix:unix-access unix-filename sb-unix:x_ok))))
 388
 389 (defun find-executable-in-search-path (pathname
 390                                        &optional
 391                                        (search-path (posix-getenv "PATH")))
 392   "Find the first executable file matching PATHNAME in any of the colon-separated list of pathnames SEARCH-PATH"
 393   (loop for end =  (position #\: search-path :start (if end (1+ end) 0))
 394         and start = 0 then (and end (1+ end))
 395         while start
 396         ;; <Krystof> the truename of a file naming a directory is the
 397         ;; directory, at least until pfdietz comes along and says why
 398         ;; that's noncompliant
 399         for fullpath = (merge-pathnames
 400                         pathname (truename
 401                                   (subseq search-path start end)))
 402         when (unix-filename-is-executable-p (namestring fullpath))
 403         return fullpath))
 404
 405 ;;; FIXME: There shouldn't be two semiredundant versions of the
 406 ;;; documentation. Since this is a public extension function, the
 407 ;;; documentation should be in the doc string. So all information from
 408 ;;; this comment should be merged into the doc string, and then this
 409 ;;; comment can go away.
 410 ;;;
 411 ;;; RUN-PROGRAM uses fork() and execve() to run a different program.
 412 ;;; Strange stuff happens to keep the Unix state of the world
 413 ;;; coherent.
 414 ;;;
 415 ;;; The child process needs to get its input from somewhere, and send
 416 ;;; its output (both standard and error) to somewhere. We have to do
 417 ;;; different things depending on where these somewheres really are.
 418 ;;;
 419 ;;; For input, there are five options:
 420 ;;;  -- T: Just leave fd 0 alone. Pretty simple.
 421 ;;;  -- "file": Read from the file. We need to open the file and
 422 ;;;     pull the descriptor out of the stream. The parent should close
 423 ;;;     this stream after the child is up and running to free any
 424 ;;;     storage used in the parent.
 425 ;;;  -- NIL: Same as "file", but use "/dev/null" as the file.
 426 ;;;  -- :STREAM: Use Unix pipe() to create two descriptors. Use
 427 ;;;     SB-SYS:MAKE-FD-STREAM to create the output stream on the
 428 ;;;     writeable descriptor, and pass the readable descriptor to
 429 ;;;     the child. The parent must close the readable descriptor for
 430 ;;;     EOF to be passed up correctly.
 431 ;;;  -- a stream: If it's a fd-stream, just pull the descriptor out
 432 ;;;     of it. Otherwise make a pipe as in :STREAM, and copy
 433 ;;;     everything across.
 434 ;;;
 435 ;;; For output, there are five options:
 436 ;;;  -- T: Leave descriptor 1 alone.
 437 ;;;  -- "file": dump output to the file.
 438 ;;;  -- NIL: dump output to /dev/null.
 439 ;;;  -- :STREAM: return a stream that can be read from.
 440 ;;;  -- a stream: if it's a fd-stream, use the descriptor in it.
 441 ;;;     Otherwise, copy stuff from output to stream.
 442 ;;;
 443 ;;; For error, there are all the same options as output plus:
 444 ;;;  -- :OUTPUT: redirect to the same place as output.
 445 ;;;
 446 ;;; RUN-PROGRAM returns a PROCESS structure for the process if
 447 ;;; the fork worked, and NIL if it did not.
 448 (defun run-program (program args
 449                     &key
 450                     (env nil env-p)
 451                     (environment (if env-p
 452                                      (unix-environment-sbcl-from-cmucl env)
 453                                      (posix-environ))
 454                                  environment-p)
 455                     (wait t)
 456                     search
 457                     pty
 458                     input
 459                     if-input-does-not-exist
 460                     output
 461                     (if-output-exists :error)
 462                     (error :output)
 463                     (if-error-exists :error)
 464                     status-hook)
 465   "RUN-PROGRAM creates a new Unix process running the Unix program found in
 466    the file specified by the PROGRAM argument.  ARGS are the standard
 467    arguments that can be passed to a Unix program. For no arguments, use NIL
 468    (which means that just the name of the program is passed as arg 0).
 469
 470    RUN-PROGRAM will either return NIL or a PROCESS structure.  See the CMU
 471    Common Lisp Users Manual for details about the PROCESS structure.
 472
 473    notes about Unix environments (as in the :ENVIRONMENT and :ENV args):
 474      1. The SBCL implementation of RUN-PROGRAM, like Perl and many other
 475         programs, but unlike the original CMU CL implementation, copies
 476         the Unix environment by default.
 477      2. Running Unix programs from a setuid process, or in any other
 478         situation where the Unix environment is under the control of someone
 479         else, is a mother lode of security problems. If you are contemplating
 480         doing this, read about it first. (The Perl community has a lot of good
 481         documentation about this and other security issues in script-like
 482         programs.)
 483
 484    The &KEY arguments have the following meanings:
 485      :ENVIRONMENT
 486         a list of SIMPLE-STRINGs describing the new Unix environment (as
 487         in \"man environ\"). The default is to copy the environment of
 488         the current process.
 489      :ENV
 490         an alternative lossy representation of the new Unix environment,
 491         for compatibility with CMU CL
 492      :SEARCH
 493         Look for PROGRAM in each of the directories along the $PATH
 494         environment variable.  Otherwise an absolute pathname is required.
 495         (See also FIND-EXECUTABLE-IN-SEARCH-PATH)
 496      :WAIT
 497         If non-NIL (default), wait until the created process finishes.  If
 498         NIL, continue running Lisp until the program finishes.
 499      :PTY
 500         Either T, NIL, or a stream.  Unless NIL, the subprocess is established
 501         under a PTY.  If :pty is a stream, all output to this pty is sent to
 502         this stream, otherwise the PROCESS-PTY slot is filled in with a stream
 503         connected to pty that can read output and write input.
 504      :INPUT
 505         Either T, NIL, a pathname, a stream, or :STREAM.  If T, the standard
 506         input for the current process is inherited.  If NIL, /dev/null
 507         is used.  If a pathname, the file so specified is used.  If a stream,
 508         all the input is read from that stream and send to the subprocess.  If
 509         :STREAM, the PROCESS-INPUT slot is filled in with a stream that sends
 510         its output to the process. Defaults to NIL.
 511      :IF-INPUT-DOES-NOT-EXIST (when :INPUT is the name of a file)
 512         can be one of:
 513            :ERROR to generate an error
 514            :CREATE to create an empty file
 515            NIL (the default) to return NIL from RUN-PROGRAM
 516      :OUTPUT
 517         Either T, NIL, a pathname, a stream, or :STREAM.  If T, the standard
 518         output for the current process is inherited.  If NIL, /dev/null
 519         is used.  If a pathname, the file so specified is used.  If a stream,
 520         all the output from the process is written to this stream. If
 521         :STREAM, the PROCESS-OUTPUT slot is filled in with a stream that can
 522         be read to get the output. Defaults to NIL.
 523      :IF-OUTPUT-EXISTS (when :OUTPUT is the name of a file)
 524         can be one of:
 525            :ERROR (the default) to generate an error
 526            :SUPERSEDE to supersede the file with output from the program
 527            :APPEND to append output from the program to the file
 528            NIL to return NIL from RUN-PROGRAM, without doing anything
 529      :ERROR and :IF-ERROR-EXISTS
 530         Same as :OUTPUT and :IF-OUTPUT-EXISTS, except that :ERROR can also be
 531         specified as :OUTPUT in which case all error output is routed to the
 532         same place as normal output.
 533      :STATUS-HOOK
 534         This is a function the system calls whenever the status of the
 535         process changes.  The function takes the process as an argument."
 536
 537   (when (and env-p environment-p)
 538     (error "can't specify :ENV and :ENVIRONMENT simultaneously"))
 539   ;; Make sure that the interrupt handler is installed.
 540   (sb-sys:enable-interrupt :sigchld #'sigchld-handler)
 541   ;; Prepend the program to the argument list.
 542   (push (namestring program) args)
 543   (let (;; Clear various specials used by GET-DESCRIPTOR-FOR to
 544         ;; communicate cleanup info.
 545         *close-on-error*
 546         *close-in-parent*
 547         *handlers-installed*
 548         ;; Establish PROC at this level so that we can return it.
 549         proc
 550         ;; It's friendly to allow the caller to pass any string
 551         ;; designator, but internally we'd like SIMPLE-STRINGs.
 552         (simple-args (mapcar (lambda (x) (coerce x 'simple-string)) args)))
 553     (unwind-protect
 554          (let ((pfile
 555                 (if search
 556                     (let ((p (find-executable-in-search-path program)))
 557                       (and p (unix-namestring p t)))
 558                     (unix-namestring program t)))
 559                (cookie (list 0)))
 560            (unless pfile
 561              (error "no such program: ~S" program))
 562            (unless (unix-filename-is-executable-p pfile)
 563              (error "not executable: ~S" program))
 564            (multiple-value-bind (stdin input-stream)
 565                (get-descriptor-for input cookie
 566                                    :direction :input
 567                                    :if-does-not-exist if-input-does-not-exist)
 568              (multiple-value-bind (stdout output-stream)
 569                  (get-descriptor-for output cookie
 570                                      :direction :output
 571                                      :if-exists if-output-exists)
 572                (multiple-value-bind (stderr error-stream)
 573                    (if (eq error :output)
 574                        (values stdout output-stream)
 575                        (get-descriptor-for error cookie
 576                                            :direction :output
 577                                            :if-exists if-error-exists))
 578                  (multiple-value-bind (pty-name pty-stream)
 579                      (open-pty pty cookie)
 580                    ;; Make sure we are not notified about the child
 581                    ;; death before we have installed the PROCESS
 582                    ;; structure in *ACTIVE-PROCESSES*.
 583                    (sb-sys:without-interrupts
 584                     (with-c-strvec (args-vec simple-args)
 585                       (with-c-strvec (environment-vec environment)
 586                         (let ((child-pid
 587                                (without-gcing
 588                                 (spawn pfile args-vec environment-vec pty-name
 589                                        stdin stdout stderr))))
 590                           (when (< child-pid 0)
 591                             (error "couldn't fork child process: ~A"
 592                                    (strerror)))
 593                           (setf proc (make-process :pid child-pid
 594                                                    :%status :running
 595                                                    :pty pty-stream
 596                                                    :input input-stream
 597                                                    :output output-stream
 598                                                    :error error-stream
 599                                                    :status-hook status-hook
 600                                                    :cookie cookie))
 601                           (push proc *active-processes*))))))))))
 602       (dolist (fd *close-in-parent*)
 603         (sb-unix:unix-close fd))
 604       (unless proc
 605         (dolist (fd *close-on-error*)
 606           (sb-unix:unix-close fd))
 607         (dolist (handler *handlers-installed*)
 608           (sb-sys:remove-fd-handler handler))))
 609     (when (and wait proc)
 610       (process-wait proc))
 611     proc))
 612
 613 ;;; Install a handler for any input that shows up on the file
 614 ;;; descriptor. The handler reads the data and writes it to the
 615 ;;; stream.
 616 (defun copy-descriptor-to-stream (descriptor stream cookie)
 617   (incf (car cookie))
 618   (let ((string (make-string 256))
 619         handler)
 620     (setf handler
 621           (sb-sys:add-fd-handler
 622            descriptor
 623            :input (lambda (fd)
 624                     (declare (ignore fd))
 625                     (loop
 626                      (unless handler
 627                        (return))
 628                      (multiple-value-bind
 629                          (result readable/errno)
 630                          (sb-unix:unix-select (1+ descriptor)
 631                                               (ash 1 descriptor)
 632                                               0 0 0)
 633                        (cond ((null result)
 634                               (error "~@<couldn't select on sub-process: ~
 635                                            ~2I~_~A~:>"
 636                                      (strerror readable/errno)))
 637                              ((zerop result)
 638                               (return))))
 639                      (sb-alien:with-alien ((buf (sb-alien:array
 640                                                  sb-alien:char
 641                                                  256)))
 642                        (multiple-value-bind
 643                            (count errno)
 644                            (sb-unix:unix-read descriptor
 645                                               (alien-sap buf)
 646                                               256)
 647                          (cond ((or (and (null count)
 648                                          (eql errno sb-unix:eio))
 649                                     (eql count 0))
 650                                 (sb-sys:remove-fd-handler handler)
 651                                 (setf handler nil)
 652                                 (decf (car cookie))
 653                                 (sb-unix:unix-close descriptor)
 654                                 (return))
 655                                ((null count)
 656                                 (sb-sys:remove-fd-handler handler)
 657                                 (setf handler nil)
 658                                 (decf (car cookie))
 659                                 (error
 660                                  "~@<couldn't read input from sub-process: ~
 661                                      ~2I~_~A~:>"
 662                                  (strerror errno)))
 663                                (t
 664                                 (sb-kernel:copy-from-system-area
 665                                  (alien-sap buf) 0
 666                                  string (* sb-vm:vector-data-offset
 667                                            sb-vm:n-word-bits)
 668                                  (* count sb-vm:n-byte-bits))
 669                                 (write-string string stream
 670                                               :end count)))))))))))
 671
 672 ;;; Find a file descriptor to use for object given the direction.
 673 ;;; Returns the descriptor. If object is :STREAM, returns the created
 674 ;;; stream as the second value.
 675 (defun get-descriptor-for (object
 676                            cookie
 677                            &rest keys
 678                            &key direction
 679                            &allow-other-keys)
 680   (cond ((eq object t)
 681          ;; No new descriptor is needed.
 682          (values -1 nil))
 683         ((eq object nil)
 684          ;; Use /dev/null.
 685          (multiple-value-bind
 686                (fd errno)
 687              (sb-unix:unix-open "/dev/null"
 688                                 (case direction
 689                                   (:input sb-unix:o_rdonly)
 690                                   (:output sb-unix:o_wronly)
 691                                   (t sb-unix:o_rdwr))
 692                                 #o666)
 693            (unless fd
 694              (error "~@<couldn't open \"/dev/null\": ~2I~_~A~:>"
 695                     (strerror errno)))
 696            (push fd *close-in-parent*)
 697            (values fd nil)))
 698         ((eq object :stream)
 699          (multiple-value-bind (read-fd write-fd) (sb-unix:unix-pipe)
 700            (unless read-fd
 701              (error "couldn't create pipe: ~A" (strerror write-fd)))
 702            (case direction
 703              (:input
 704               (push read-fd *close-in-parent*)
 705               (push write-fd *close-on-error*)
 706               (let ((stream (sb-sys:make-fd-stream write-fd :output t)))
 707                 (values read-fd stream)))
 708              (:output
 709               (push read-fd *close-on-error*)
 710               (push write-fd *close-in-parent*)
 711               (let ((stream (sb-sys:make-fd-stream read-fd :input t)))
 712                 (values write-fd stream)))
 713              (t
 714               (sb-unix:unix-close read-fd)
 715               (sb-unix:unix-close write-fd)
 716               (error "Direction must be either :INPUT or :OUTPUT, not ~S."
 717                      direction)))))
 718         ((or (pathnamep object) (stringp object))
 719          (with-open-stream (file (apply #'open object keys))
 720            (multiple-value-bind
 721                  (fd errno)
 722                (sb-unix:unix-dup (sb-sys:fd-stream-fd file))
 723              (cond (fd
 724                     (push fd *close-in-parent*)
 725                     (values fd nil))
 726                    (t
 727                     (error "couldn't duplicate file descriptor: ~A"
 728                            (strerror errno)))))))
 729         ((sb-sys:fd-stream-p object)
 730          (values (sb-sys:fd-stream-fd object) nil))
 731         ((streamp object)
 732          (ecase direction
 733            (:input
 734             ;; FIXME: We could use a better way of setting up
 735             ;; temporary files, both here and in LOAD-FOREIGN.
 736             (dotimes (count
 737                        256
 738                       (error "could not open a temporary file in /tmp"))
 739               (let* ((name (format nil "/tmp/.run-program-~D" count))
 740                      (fd (sb-unix:unix-open name
 741                                             (logior sb-unix:o_rdwr
 742                                                     sb-unix:o_creat
 743                                                     sb-unix:o_excl)
 744                                             #o666)))
 745                 (sb-unix:unix-unlink name)
 746                 (when fd
 747                   (let ((newline (string #\Newline)))
 748                     (loop
 749                         (multiple-value-bind
 750                               (line no-cr)
 751                             (read-line object nil nil)
 752                           (unless line
 753                             (return))
 754                           (sb-unix:unix-write fd line 0 (length line))
 755                           (if no-cr
 756                               (return)
 757                               (sb-unix:unix-write fd newline 0 1)))))
 758                   (sb-unix:unix-lseek fd 0 sb-unix:l_set)
 759                   (push fd *close-in-parent*)
 760                   (return (values fd nil))))))
 761            (:output
 762             (multiple-value-bind (read-fd write-fd)
 763                 (sb-unix:unix-pipe)
 764               (unless read-fd
 765                 (error "couldn't create pipe: ~S" (strerror write-fd)))
 766               (copy-descriptor-to-stream read-fd object cookie)
 767               (push read-fd *close-on-error*)
 768               (push write-fd *close-in-parent*)
 769               (values write-fd nil)))))
 770         (t
 771          (error "invalid option to RUN-PROGRAM: ~S" object))))