src/code/run-program.lisp

   1 ;;;; RUN-PROGRAM and friends, a facility for running Unix programs
   2 ;;;; from inside SBCL
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB-IMPL") ;(SB-IMPL, not SB!IMPL, since we're built in warm load.)
  14 \f
  15 ;;;; hacking the Unix environment
  16 ;;;;
  17 ;;;; In the original CMU CL code that LOAD-FOREIGN is derived from, the
  18 ;;;; Unix environment (as in "man environ") was represented as an
  19 ;;;; alist from keywords to strings, so that e.g. the Unix environment
  20 ;;;;   "SHELL=/bin/bash" "HOME=/root" "PAGER=less"
  21 ;;;; was represented as
  22 ;;;;   ((:SHELL . "/bin/bash") (:HOME . "/root") (:PAGER "less"))
  23 ;;;; This had a few problems in principle: the mapping into
  24 ;;;; keyword symbols smashed the case of environment
  25 ;;;; variables, and the whole mapping depended on the presence of
  26 ;;;; #\= characters in the environment strings. In practice these
  27 ;;;; problems weren't hugely important, since conventionally environment
  28 ;;;; variables are uppercase strings followed by #\= followed by
  29 ;;;; arbitrary data. However, since it's so manifestly not The Right
  30 ;;;; Thing to make code which breaks unnecessarily on input which
  31 ;;;; doesn't follow what is, after all, only a tradition, we've switched
  32 ;;;; formats in SBCL, so that the fundamental environment list
  33 ;;;; is just a list of strings, with a one-to-one-correspondence
  34 ;;;; to the C-level representation. I.e., in the example above,
  35 ;;;; the SBCL representation is
  36 ;;;;   '("SHELL=/bin/bash" "HOME=/root" "PAGER=less")
  37 ;;;; CMU CL's implementation is currently supported to help with porting.
  38 ;;;;
  39 ;;;; It's not obvious that this code belongs here (instead of e.g. in
  40 ;;;; unix.lisp), since it has only a weak logical connection with
  41 ;;;; RUN-PROGRAM. However, physically it's convenient to put it here.
  42 ;;;; It's not needed at cold init, so we *can* put it in this
  43 ;;;; warm-loaded file. And by putting it in this warm-loaded file, we
  44 ;;;; make it easy for it to get to the C-level 'environ' variable.
  45 ;;;; which (at least in sbcl-0.6.10 on Red Hat Linux 6.2) is not
  46 ;;;; visible at GENESIS time.
  47
  48 (define-alien-routine wrapped-environ (* c-string))
  49 (defun posix-environ ()
  50   "Return the Unix environment (\"man environ\") as a list of SIMPLE-STRINGs."
  51   (c-strings->string-list (wrapped-environ)))
  52
  53 ;;; Convert as best we can from an SBCL representation of a Unix
  54 ;;; environment to a CMU CL representation.
  55 ;;;
  56 ;;; * (UNIX-ENVIRONMENT-CMUCL-FROM-SBCL '("Bletch=fub" "Noggin" "YES=No!"))
  57 ;;; WARNING:
  58 ;;;   smashing case of "Bletch=fub" in conversion to CMU-CL-style
  59 ;;;     environment alist
  60 ;;; WARNING:
  61 ;;;   no #\= in "Noggin", eliding it in CMU-CL-style environment alist
  62 ;;; ((:BLETCH . "fub") (:YES . "No!"))
  63 (defun unix-environment-cmucl-from-sbcl (sbcl)
  64   (mapcan
  65    (lambda (string)
  66      (declare (type simple-string string))
  67      (let ((=-pos (position #\= string :test #'equal)))
  68        (if =-pos
  69            (list
  70             (let* ((key-as-string (subseq string 0 =-pos))
  71                    (key-as-upcase-string (string-upcase key-as-string))
  72                    (key (keywordicate key-as-upcase-string))
  73                    (val (subseq string (1+ =-pos))))
  74               (unless (string= key-as-string key-as-upcase-string)
  75                 (warn "smashing case of ~S in conversion to CMU-CL-style ~
  76                       environment alist"
  77                       string))
  78               (cons key val)))
  79            (warn "no #\\= in ~S, eliding it in CMU-CL-style environment alist"
  80                  string))))
  81    sbcl))
  82
  83 ;;; Convert from a CMU CL representation of a Unix environment to a
  84 ;;; SBCL representation.
  85 (defun unix-environment-sbcl-from-cmucl (cmucl)
  86   (mapcar
  87    (lambda (cons)
  88      (destructuring-bind (key . val) cons
  89        (declare (type keyword key) (type simple-string val))
  90        (concatenate 'simple-string (symbol-name key) "=" val)))
  91    cmucl))
  92 \f
  93 ;;;; Import wait3(2) from Unix.
  94
  95 (define-alien-routine ("wait3" c-wait3) sb-alien:int
  96   (status sb-alien:int :out)
  97   (options sb-alien:int)
  98   (rusage sb-alien:int))
  99
 100 (defun wait3 (&optional do-not-hang check-for-stopped)
 101   "Return any available status information on child process. "
 102   (multiple-value-bind (pid status)
 103       (c-wait3 (logior (if do-not-hang
 104                            sb-unix:wnohang
 105                            0)
 106                        (if check-for-stopped
 107                            sb-unix:wuntraced
 108                            0))
 109                0)
 110     (cond ((or (minusp pid)
 111                (zerop pid))
 112            nil)
 113           ((eql (ldb (byte 8 0) status)
 114                 sb-unix:wstopped)
 115            (values pid
 116                    :stopped
 117                    (ldb (byte 8 8) status)))
 118           ((zerop (ldb (byte 7 0) status))
 119            (values pid
 120                    :exited
 121                    (ldb (byte 8 8) status)))
 122           (t
 123            (let ((signal (ldb (byte 7 0) status)))
 124              (values pid
 125                      (if (position signal
 126                                    #.(vector
 127                                       (sb-unix:unix-signal-number :sigstop)
 128                                       (sb-unix:unix-signal-number :sigtstp)
 129                                       (sb-unix:unix-signal-number :sigttin)
 130                                       (sb-unix:unix-signal-number :sigttou)))
 131                          :stopped
 132                          :signaled)
 133                      signal
 134                      (not (zerop (ldb (byte 1 7) status)))))))))
 135 \f
 136 ;;;; process control stuff
 137
 138 (defvar *active-processes* nil
 139   "List of process structures for all active processes.")
 140
 141 (defstruct (process (:copier nil))
 142   pid                 ; PID of child process
 143   %status             ; either :RUNNING, :STOPPED, :EXITED, or :SIGNALED
 144   exit-code           ; either exit code or signal
 145   core-dumped         ; T if a core image was dumped
 146   pty                 ; stream to child's pty, or NIL
 147   input               ; stream to child's input, or NIL
 148   output              ; stream from child's output, or NIL
 149   error               ; stream from child's error output, or NIL
 150   status-hook         ; closure to call when PROC changes status
 151   plist               ; a place for clients to stash things
 152   cookie)             ; list of the number of pipes from the subproc
 153
 154 (defmethod print-object ((process process) stream)
 155   (print-unreadable-object (process stream :type t)
 156     (format stream
 157             "~W ~S"
 158             (process-pid process)
 159             (process-status process)))
 160   process)
 161
 162 (defun process-status (proc)
 163   "Return the current status of process.  The result is one of :RUNNING,
 164    :STOPPED, :EXITED, or :SIGNALED."
 165   (get-processes-status-changes)
 166   (process-%status proc))
 167
 168 (defun process-wait (proc &optional check-for-stopped)
 169   "Wait for PROC to quit running for some reason.  Returns PROC."
 170   (loop
 171       (case (process-status proc)
 172         (:running)
 173         (:stopped
 174          (when check-for-stopped
 175            (return)))
 176         (t
 177          (when (zerop (car (process-cookie proc)))
 178            (return))))
 179       (sb-sys:serve-all-events 1))
 180   proc)
 181
 182 #-hpux
 183 ;;; Find the current foreground process group id.
 184 (defun find-current-foreground-process (proc)
 185   (with-alien ((result sb-alien:int))
 186     (multiple-value-bind
 187           (wonp error)
 188         (sb-unix:unix-ioctl (sb-sys:fd-stream-fd (process-pty proc))
 189                             sb-unix:TIOCGPGRP
 190                             (alien-sap (sb-alien:addr result)))
 191       (unless wonp
 192         (error "TIOCPGRP ioctl failed: ~S" (strerror error)))
 193       result))
 194   (process-pid proc))
 195
 196 (defun process-kill (proc signal &optional (whom :pid))
 197   "Hand SIGNAL to PROC. If WHOM is :PID, use the kill Unix system call. If
 198    WHOM is :PROCESS-GROUP, use the killpg Unix system call. If WHOM is
 199    :PTY-PROCESS-GROUP deliver the signal to whichever process group is
 200    currently in the foreground."
 201   (let ((pid (ecase whom
 202                ((:pid :process-group)
 203                 (process-pid proc))
 204                (:pty-process-group
 205                 #-hpux
 206                 (find-current-foreground-process proc)))))
 207     (multiple-value-bind
 208           (okay errno)
 209         (case whom
 210           #+hpux
 211           (:pty-process-group
 212            (sb-unix:unix-ioctl (sb-sys:fd-stream-fd (process-pty proc))
 213                                sb-unix:TIOCSIGSEND
 214                                (sb-sys:int-sap
 215                                 (sb-unix:unix-signal-number signal))))
 216           ((:process-group #-hpux :pty-process-group)
 217            (sb-unix:unix-killpg pid signal))
 218           (t
 219            (sb-unix:unix-kill pid signal)))
 220       (cond ((not okay)
 221              (values nil errno))
 222             ((and (eql pid (process-pid proc))
 223                   (= (sb-unix:unix-signal-number signal)
 224                      (sb-unix:unix-signal-number :sigcont)))
 225              (setf (process-%status proc) :running)
 226              (setf (process-exit-code proc) nil)
 227              (when (process-status-hook proc)
 228                (funcall (process-status-hook proc) proc))
 229              t)
 230             (t
 231              t)))))
 232
 233 (defun process-alive-p (proc)
 234   "Return T if the process is still alive, NIL otherwise."
 235   (let ((status (process-status proc)))
 236     (if (or (eq status :running)
 237             (eq status :stopped))
 238         t
 239         nil)))
 240
 241 (defun process-close (proc)
 242   "Close all streams connected to PROC and stop maintaining the status slot."
 243   (macrolet ((frob (stream abort)
 244                `(when ,stream (close ,stream :abort ,abort))))
 245     (frob (process-pty    proc)   t) ; Don't FLUSH-OUTPUT to dead process, ..
 246     (frob (process-input  proc)   t) ; .. 'cause it will generate SIGPIPE.
 247     (frob (process-output proc) nil)
 248     (frob (process-error  proc) nil))
 249   (sb-sys:without-interrupts
 250    (setf *active-processes* (delete proc *active-processes*)))
 251   proc)
 252
 253 ;;; the handler for SIGCHLD signals that RUN-PROGRAM establishes
 254 (defun sigchld-handler (ignore1 ignore2 ignore3)
 255   (declare (ignore ignore1 ignore2 ignore3))
 256   (get-processes-status-changes))
 257
 258 (defun get-processes-status-changes ()
 259   (loop
 260       (multiple-value-bind (pid what code core)
 261           (wait3 t t)
 262         (unless pid
 263           (return))
 264         (let ((proc (find pid *active-processes* :key #'process-pid)))
 265           (when proc
 266             (setf (process-%status proc) what)
 267             (setf (process-exit-code proc) code)
 268             (setf (process-core-dumped proc) core)
 269             (when (process-status-hook proc)
 270               (funcall (process-status-hook proc) proc))
 271             (when (position what #(:exited :signaled))
 272               (sb-sys:without-interrupts
 273                (setf *active-processes*
 274                      (delete proc *active-processes*)))))))))
 275 \f
 276 ;;;; RUN-PROGRAM and close friends
 277
 278 ;;; list of file descriptors to close when RUN-PROGRAM exits due to an error
 279 (defvar *close-on-error* nil)
 280
 281 ;;; list of file descriptors to close when RUN-PROGRAM returns in the parent
 282 (defvar *close-in-parent* nil)
 283
 284 ;;; list of handlers installed by RUN-PROGRAM
 285 (defvar *handlers-installed* nil)
 286
 287 #+FreeBSD
 288 (define-alien-type nil
 289   (struct sgttyb
 290           (sg-ispeed sb-alien:char)     ; input speed
 291           (sg-ospeed sb-alien:char)     ; output speed
 292           (sg-erase sb-alien:char)      ; erase character
 293           (sg-kill sb-alien:char)       ; kill character
 294           (sg-flags sb-alien:short)))   ; mode flags
 295 #+OpenBSD
 296 (define-alien-type nil
 297   (struct sgttyb
 298           (sg-four sb-alien:int)
 299           (sg-chars (array sb-alien:char 4))
 300           (sg-flags sb-alien:int)))
 301
 302 ;;; Find an unused pty. Return three values: the file descriptor for
 303 ;;; the master side of the pty, the file descriptor for the slave side
 304 ;;; of the pty, and the name of the tty device for the slave side.
 305 (defun find-a-pty ()
 306   (dolist (char '(#\p #\q))
 307     (dotimes (digit 16)
 308       (let* ((master-name (format nil "/dev/pty~C~X" char digit))
 309              (master-fd (sb-unix:unix-open master-name
 310                                            sb-unix:o_rdwr
 311                                            #o666)))
 312         (when master-fd
 313           (let* ((slave-name (format nil "/dev/tty~C~X" char digit))
 314                  (slave-fd (sb-unix:unix-open slave-name
 315                                               sb-unix:o_rdwr
 316                                               #o666)))
 317             (when slave-fd
 318               ;; comment from classic CMU CL:
 319               ;;   Maybe put a vhangup here?
 320               ;;
 321               ;; FIXME: It seems as though this logic should be in
 322               ;; OPEN-PTY, not FIND-A-PTY (both from the comments
 323               ;; documenting DEFUN FIND-A-PTY, and from the
 324               ;; connotations of the function names).
 325               ;;
 326               ;; FIXME: It would be nice to have a note, and/or a pointer
 327               ;; to some reference material somewhere, explaining
 328               ;; why we need this on *BSD and not on Linux.
 329               #+bsd
 330               (sb-alien:with-alien ((stuff (sb-alien:struct sgttyb)))
 331                 (let ((sap (sb-alien:alien-sap stuff)))
 332                   (sb-unix:unix-ioctl slave-fd sb-unix:TIOCGETP sap)
 333                   (setf (sb-alien:slot stuff 'sg-flags)
 334                         ;; This is EVENP|ODDP, the same numeric code
 335                         ;; both on FreeBSD and on OpenBSD. -- WHN 20000929
 336                         #o300) ; EVENP|ODDP
 337                   (sb-unix:unix-ioctl slave-fd sb-unix:TIOCSETP sap)
 338                   (sb-unix:unix-ioctl master-fd sb-unix:TIOCGETP sap)
 339                   (setf (sb-alien:slot stuff 'sg-flags)
 340                         (logand (sb-alien:slot stuff 'sg-flags)
 341                                 ;; This is ~ECHO, the same numeric
 342                                 ;; code both on FreeBSD and on OpenBSD.
 343                                 ;; -- WHN 20000929
 344                                 (lognot 8))) ; ~ECHO
 345                   (sb-unix:unix-ioctl master-fd sb-unix:TIOCSETP sap)))
 346               (return-from find-a-pty
 347                 (values master-fd
 348                         slave-fd
 349                         slave-name)))
 350             (sb-unix:unix-close master-fd))))))
 351   (error "could not find a pty"))
 352
 353 (defun open-pty (pty cookie)
 354   (when pty
 355     (multiple-value-bind
 356           (master slave name)
 357         (find-a-pty)
 358       (push master *close-on-error*)
 359       (push slave *close-in-parent*)
 360       (when (streamp pty)
 361         (multiple-value-bind (new-fd errno) (sb-unix:unix-dup master)
 362           (unless new-fd
 363             (error "couldn't SB-UNIX:UNIX-DUP ~W: ~A" master (strerror errno)))
 364           (push new-fd *close-on-error*)
 365           (copy-descriptor-to-stream new-fd pty cookie)))
 366       (values name
 367               (sb-sys:make-fd-stream master :input t :output t)))))
 368
 369 (defmacro round-bytes-to-words (n)
 370   `(logand (the fixnum (+ (the fixnum ,n) 3)) (lognot 3)))
 371
 372 (defun string-list-to-c-strvec (string-list)
 373   ;; Make a pass over STRING-LIST to calculate the amount of memory
 374   ;; needed to hold the strvec.
 375   (let ((string-bytes 0)
 376         ;; We need an extra for the null, and an extra 'cause exect
 377         ;; clobbers argv[-1].
 378         (vec-bytes (* #-alpha 4 #+alpha 8 (+ (length string-list) 2))))
 379     (declare (fixnum string-bytes vec-bytes))
 380     (dolist (s string-list)
 381       (enforce-type s simple-string)
 382       (incf string-bytes (round-bytes-to-words (1+ (length s)))))
 383     ;; Now allocate the memory and fill it in.
 384     (let* ((total-bytes (+ string-bytes vec-bytes))
 385            (vec-sap (sb-sys:allocate-system-memory total-bytes))
 386            (string-sap (sap+ vec-sap vec-bytes))
 387            (i #-alpha 4 #+alpha 8))
 388       (declare (type (and unsigned-byte fixnum) total-bytes i)
 389                (type sb-sys:system-area-pointer vec-sap string-sap))
 390       (dolist (s string-list)
 391         (declare (simple-string s))
 392         (let ((n (length s)))
 393           ;; Blast the string into place.
 394           (sb-kernel:copy-to-system-area (the simple-string s)
 395                                          (* sb-vm:vector-data-offset
 396                                             sb-vm:n-word-bits)
 397                                          string-sap 0
 398                                          (* (1+ n) sb-vm:n-byte-bits))
 399           ;; Blast the pointer to the string into place.
 400           (setf (sap-ref-sap vec-sap i) string-sap)
 401           (setf string-sap (sap+ string-sap (round-bytes-to-words (1+ n))))
 402           (incf i #-alpha 4 #+alpha 8)))
 403       ;; Blast in the last null pointer.
 404       (setf (sap-ref-sap vec-sap i) (int-sap 0))
 405       (values vec-sap (sap+ vec-sap #-alpha 4 #+alpha 8) total-bytes))))
 406
 407 (defmacro with-c-strvec ((var str-list) &body body)
 408   (let ((sap (gensym "SAP-"))
 409         (size (gensym "SIZE-")))
 410     `(multiple-value-bind
 411       (,sap ,var ,size)
 412       (string-list-to-c-strvec ,str-list)
 413       (unwind-protect
 414            (progn
 415              ,@body)
 416         (sb-sys:deallocate-system-memory ,sap ,size)))))
 417
 418 (sb-alien:define-alien-routine spawn sb-alien:int
 419   (program sb-alien:c-string)
 420   (argv (* sb-alien:c-string))
 421   (envp (* sb-alien:c-string))
 422   (pty-name sb-alien:c-string)
 423   (stdin sb-alien:int)
 424   (stdout sb-alien:int)
 425   (stderr sb-alien:int))
 426
 427 ;;; Is UNIX-FILENAME the name of a file that we can execute?
 428 ;;; XXX does this actually work for symlinks?
 429 (defun unix-filename-is-executable-p (unix-filename)
 430   (declare (type simple-string unix-filename))
 431   (values (and (eq (sb-unix:unix-file-kind unix-filename) :file)
 432                (sb-unix:unix-access unix-filename sb-unix:x_ok))))
 433
 434 ;;; FIXME: There shouldn't be two semiredundant versions of the
 435 ;;; documentation. Since this is a public extension function, the
 436 ;;; documentation should be in the doc string. So all information from
 437 ;;; this comment should be merged into the doc string, and then this
 438 ;;; comment can go away.
 439 ;;;
 440 ;;; RUN-PROGRAM uses fork() and execve() to run a different program.
 441 ;;; Strange stuff happens to keep the Unix state of the world
 442 ;;; coherent.
 443 ;;;
 444 ;;; The child process needs to get its input from somewhere, and send
 445 ;;; its output (both standard and error) to somewhere. We have to do
 446 ;;; different things depending on where these somewheres really are.
 447 ;;;
 448 ;;; For input, there are five options:
 449 ;;;  -- T: Just leave fd 0 alone. Pretty simple.
 450 ;;;  -- "file": Read from the file. We need to open the file and
 451 ;;;     pull the descriptor out of the stream. The parent should close
 452 ;;;     this stream after the child is up and running to free any
 453 ;;;     storage used in the parent.
 454 ;;;  -- NIL: Same as "file", but use "/dev/null" as the file.
 455 ;;;  -- :STREAM: Use Unix pipe() to create two descriptors. Use
 456 ;;;     SB-SYS:MAKE-FD-STREAM to create the output stream on the
 457 ;;;     writeable descriptor, and pass the readable descriptor to
 458 ;;;     the child. The parent must close the readable descriptor for
 459 ;;;     EOF to be passed up correctly.
 460 ;;;  -- a stream: If it's a fd-stream, just pull the descriptor out
 461 ;;;     of it. Otherwise make a pipe as in :STREAM, and copy
 462 ;;;     everything across.
 463 ;;;
 464 ;;; For output, there are five options:
 465 ;;;  -- T: Leave descriptor 1 alone.
 466 ;;;  -- "file": dump output to the file.
 467 ;;;  -- NIL: dump output to /dev/null.
 468 ;;;  -- :STREAM: return a stream that can be read from.
 469 ;;;  -- a stream: if it's a fd-stream, use the descriptor in it.
 470 ;;;     Otherwise, copy stuff from output to stream.
 471 ;;;
 472 ;;; For error, there are all the same options as output plus:
 473 ;;;  -- :OUTPUT: redirect to the same place as output.
 474 ;;;
 475 ;;; RUN-PROGRAM returns a PROCESS structure for the process if
 476 ;;; the fork worked, and NIL if it did not.
 477 (defun run-program (program args
 478                     &key
 479                     (env nil env-p)
 480                     (environment (if env-p
 481                                      (unix-environment-sbcl-from-cmucl env)
 482                                      (posix-environ))
 483                                  environment-p)
 484                     (wait t)
 485                     pty
 486                     input
 487                     if-input-does-not-exist
 488                     output
 489                     (if-output-exists :error)
 490                     (error :output)
 491                     (if-error-exists :error)
 492                     status-hook)
 493   "RUN-PROGRAM creates a new Unix process running the Unix program found in
 494    the file specified by the PROGRAM argument.  ARGS are the standard
 495    arguments that can be passed to a Unix program. For no arguments, use NIL
 496    (which means that just the name of the program is passed as arg 0).
 497
 498    RUN-PROGRAM will either return NIL or a PROCESS structure.  See the CMU
 499    Common Lisp Users Manual for details about the PROCESS structure.
 500
 501    notes about Unix environments (as in the :ENVIRONMENT and :ENV args):
 502      1. The SBCL implementation of RUN-PROGRAM, like Perl and many other
 503         programs, but unlike the original CMU CL implementation, copies
 504         the Unix environment by default.
 505      2. Running Unix programs from a setuid process, or in any other
 506         situation where the Unix environment is under the control of someone
 507         else, is a mother lode of security problems. If you are contemplating
 508         doing this, read about it first. (The Perl community has a lot of good
 509         documentation about this and other security issues in script-like
 510         programs.)
 511
 512    The &KEY arguments have the following meanings:
 513      :ENVIRONMENT
 514         a list of SIMPLE-STRINGs describing the new Unix environment (as
 515         in \"man environ\"). The default is to copy the environment of
 516         the current process.
 517      :ENV
 518         an alternative lossy representation of the new Unix environment,
 519         for compatibility with CMU CL
 520      :WAIT
 521         If non-NIL (default), wait until the created process finishes.  If
 522         NIL, continue running Lisp until the program finishes.
 523      :PTY
 524         Either T, NIL, or a stream.  Unless NIL, the subprocess is established
 525         under a PTY.  If :pty is a stream, all output to this pty is sent to
 526         this stream, otherwise the PROCESS-PTY slot is filled in with a stream
 527         connected to pty that can read output and write input.
 528      :INPUT
 529         Either T, NIL, a pathname, a stream, or :STREAM.  If T, the standard
 530         input for the current process is inherited.  If NIL, /dev/null
 531         is used.  If a pathname, the file so specified is used.  If a stream,
 532         all the input is read from that stream and send to the subprocess.  If
 533         :STREAM, the PROCESS-INPUT slot is filled in with a stream that sends
 534         its output to the process. Defaults to NIL.
 535      :IF-INPUT-DOES-NOT-EXIST (when :INPUT is the name of a file)
 536         can be one of:
 537            :ERROR to generate an error
 538            :CREATE to create an empty file
 539            NIL (the default) to return NIL from RUN-PROGRAM
 540      :OUTPUT
 541         Either T, NIL, a pathname, a stream, or :STREAM.  If T, the standard
 542         output for the current process is inherited.  If NIL, /dev/null
 543         is used.  If a pathname, the file so specified is used.  If a stream,
 544         all the output from the process is written to this stream. If
 545         :STREAM, the PROCESS-OUTPUT slot is filled in with a stream that can
 546         be read to get the output. Defaults to NIL.
 547      :IF-OUTPUT-EXISTS (when :OUTPUT is the name of a file)
 548         can be one of:
 549            :ERROR (the default) to generate an error
 550            :SUPERSEDE to supersede the file with output from the program
 551            :APPEND to append output from the program to the file
 552            NIL to return NIL from RUN-PROGRAM, without doing anything
 553      :ERROR and :IF-ERROR-EXISTS
 554         Same as :OUTPUT and :IF-OUTPUT-EXISTS, except that :ERROR can also be
 555         specified as :OUTPUT in which case all error output is routed to the
 556         same place as normal output.
 557      :STATUS-HOOK
 558         This is a function the system calls whenever the status of the
 559         process changes.  The function takes the process as an argument."
 560
 561   (when (and env-p environment-p)
 562     (error "can't specify :ENV and :ENVIRONMENT simultaneously"))
 563   ;; Make sure that the interrupt handler is installed.
 564   (sb-sys:enable-interrupt :sigchld #'sigchld-handler)
 565   ;; Prepend the program to the argument list.
 566   (push (namestring program) args)
 567   (let (;; Clear various specials used by GET-DESCRIPTOR-FOR to
 568         ;; communicate cleanup info.
 569         *close-on-error*
 570         *close-in-parent*
 571         *handlers-installed*
 572         ;; Establish PROC at this level so that we can return it.
 573         proc
 574         ;; It's friendly to allow the caller to pass any string
 575         ;; designator, but internally we'd like SIMPLE-STRINGs.
 576         (simple-args (mapcar (lambda (x) (coerce x 'simple-string)) args)))
 577     (unwind-protect
 578          (let (;; FIXME: The old code here used to do
 579                ;;   (MERGE-PATHNAMES PROGRAM "path:"),
 580                ;; which is the right idea (searching through the Unix
 581                ;; PATH). Unfortunately, there is no logical pathname
 582                ;; "path:" defined in sbcl-0.6.10. It would probably be
 583                ;; reasonable to restore Unix PATH searching in SBCL, e.g.
 584                ;; with a function FIND-EXECUTABLE-FILE-IN-POSIX-PATH.
 585                ;; CMU CL did it with a "PATH:" search list, but CMU CL
 586                ;; search lists are a non-ANSI extension that SBCL
 587                ;; doesn't support. -- WHN)
 588                (pfile (unix-namestring program t))
 589                (cookie (list 0)))
 590            (unless pfile
 591              (error "no such program: ~S" program))
 592            (unless (unix-filename-is-executable-p pfile)
 593              (error "not executable: ~S" program))
 594            (multiple-value-bind (stdin input-stream)
 595                (get-descriptor-for input cookie
 596                                    :direction :input
 597                                    :if-does-not-exist if-input-does-not-exist)
 598              (multiple-value-bind (stdout output-stream)
 599                  (get-descriptor-for output cookie
 600                                      :direction :output
 601                                      :if-exists if-output-exists)
 602                (multiple-value-bind (stderr error-stream)
 603                    (if (eq error :output)
 604                        (values stdout output-stream)
 605                        (get-descriptor-for error cookie
 606                                            :direction :output
 607                                            :if-exists if-error-exists))
 608                  (multiple-value-bind (pty-name pty-stream)
 609                      (open-pty pty cookie)
 610                    ;; Make sure we are not notified about the child
 611                    ;; death before we have installed the PROCESS
 612                    ;; structure in *ACTIVE-PROCESSES*.
 613                    (sb-sys:without-interrupts
 614                     (with-c-strvec (args-vec simple-args)
 615                       (with-c-strvec (environment-vec environment)
 616                         (let ((child-pid
 617                                (without-gcing
 618                                 (spawn pfile args-vec environment-vec pty-name
 619                                        stdin stdout stderr))))
 620                           (when (< child-pid 0)
 621                             (error "couldn't fork child process: ~A"
 622                                    (strerror)))
 623                           (setf proc (make-process :pid child-pid
 624                                                    :%status :running
 625                                                    :pty pty-stream
 626                                                    :input input-stream
 627                                                    :output output-stream
 628                                                    :error error-stream
 629                                                    :status-hook status-hook
 630                                                    :cookie cookie))
 631                           (push proc *active-processes*))))))))))
 632       (dolist (fd *close-in-parent*)
 633         (sb-unix:unix-close fd))
 634       (unless proc
 635         (dolist (fd *close-on-error*)
 636           (sb-unix:unix-close fd))
 637         (dolist (handler *handlers-installed*)
 638           (sb-sys:remove-fd-handler handler))))
 639     (when (and wait proc)
 640       (process-wait proc))
 641     proc))
 642
 643 ;;; Install a handler for any input that shows up on the file
 644 ;;; descriptor. The handler reads the data and writes it to the
 645 ;;; stream.
 646 (defun copy-descriptor-to-stream (descriptor stream cookie)
 647   (incf (car cookie))
 648   (let ((string (make-string 256))
 649         handler)
 650     (setf handler
 651           (sb-sys:add-fd-handler
 652            descriptor
 653            :input (lambda (fd)
 654                     (declare (ignore fd))
 655                     (loop
 656                      (unless handler
 657                        (return))
 658                      (multiple-value-bind
 659                          (result readable/errno)
 660                          (sb-unix:unix-select (1+ descriptor)
 661                                               (ash 1 descriptor)
 662                                               0 0 0)
 663                        (cond ((null result)
 664                               (error "~@<couldn't select on sub-process: ~
 665                                            ~2I~_~A~:>"
 666                                      (strerror readable/errno)))
 667                              ((zerop result)
 668                               (return))))
 669                      (sb-alien:with-alien ((buf (sb-alien:array
 670                                                  sb-alien:char
 671                                                  256)))
 672                        (multiple-value-bind
 673                            (count errno)
 674                            (sb-unix:unix-read descriptor
 675                                               (alien-sap buf)
 676                                               256)
 677                          (cond ((or (and (null count)
 678                                          (eql errno sb-unix:eio))
 679                                     (eql count 0))
 680                                 (sb-sys:remove-fd-handler handler)
 681                                 (setf handler nil)
 682                                 (decf (car cookie))
 683                                 (sb-unix:unix-close descriptor)
 684                                 (return))
 685                                ((null count)
 686                                 (sb-sys:remove-fd-handler handler)
 687                                 (setf handler nil)
 688                                 (decf (car cookie))
 689                                 (error
 690                                  "~@<couldn't read input from sub-process: ~
 691                                      ~2I~_~A~:>"
 692                                  (strerror errno)))
 693                                (t
 694                                 (sb-kernel:copy-from-system-area
 695                                  (alien-sap buf) 0
 696                                  string (* sb-vm:vector-data-offset
 697                                            sb-vm:n-word-bits)
 698                                  (* count sb-vm:n-byte-bits))
 699                                 (write-string string stream
 700                                               :end count)))))))))))
 701
 702 ;;; Find a file descriptor to use for object given the direction.
 703 ;;; Returns the descriptor. If object is :STREAM, returns the created
 704 ;;; stream as the second value.
 705 (defun get-descriptor-for (object
 706                            cookie
 707                            &rest keys
 708                            &key direction
 709                            &allow-other-keys)
 710   (cond ((eq object t)
 711          ;; No new descriptor is needed.
 712          (values -1 nil))
 713         ((eq object nil)
 714          ;; Use /dev/null.
 715          (multiple-value-bind
 716                (fd errno)
 717              (sb-unix:unix-open "/dev/null"
 718                                 (case direction
 719                                   (:input sb-unix:o_rdonly)
 720                                   (:output sb-unix:o_wronly)
 721                                   (t sb-unix:o_rdwr))
 722                                 #o666)
 723            (unless fd
 724              (error "~@<couldn't open \"/dev/null\": ~2I~_~A~:>"
 725                     (strerror errno)))
 726            (push fd *close-in-parent*)
 727            (values fd nil)))
 728         ((eq object :stream)
 729          (multiple-value-bind (read-fd write-fd) (sb-unix:unix-pipe)
 730            (unless read-fd
 731              (error "couldn't create pipe: ~A" (strerror write-fd)))
 732            (case direction
 733              (:input
 734               (push read-fd *close-in-parent*)
 735               (push write-fd *close-on-error*)
 736               (let ((stream (sb-sys:make-fd-stream write-fd :output t)))
 737                 (values read-fd stream)))
 738              (:output
 739               (push read-fd *close-on-error*)
 740               (push write-fd *close-in-parent*)
 741               (let ((stream (sb-sys:make-fd-stream read-fd :input t)))
 742                 (values write-fd stream)))
 743              (t
 744               (sb-unix:unix-close read-fd)
 745               (sb-unix:unix-close write-fd)
 746               (error "Direction must be either :INPUT or :OUTPUT, not ~S."
 747                      direction)))))
 748         ((or (pathnamep object) (stringp object))
 749          (with-open-stream (file (apply #'open object keys))
 750            (multiple-value-bind
 751                  (fd errno)
 752                (sb-unix:unix-dup (sb-sys:fd-stream-fd file))
 753              (cond (fd
 754                     (push fd *close-in-parent*)
 755                     (values fd nil))
 756                    (t
 757                     (error "couldn't duplicate file descriptor: ~A"
 758                            (strerror errno)))))))
 759         ((sb-sys:fd-stream-p object)
 760          (values (sb-sys:fd-stream-fd object) nil))
 761         ((streamp object)
 762          (ecase direction
 763            (:input
 764             ;; FIXME: We could use a better way of setting up
 765             ;; temporary files, both here and in LOAD-FOREIGN.
 766             (dotimes (count
 767                        256
 768                       (error "could not open a temporary file in /tmp"))
 769               (let* ((name (format nil "/tmp/.run-program-~D" count))
 770                      (fd (sb-unix:unix-open name
 771                                             (logior sb-unix:o_rdwr
 772                                                     sb-unix:o_creat
 773                                                     sb-unix:o_excl)
 774                                             #o666)))
 775                 (sb-unix:unix-unlink name)
 776                 (when fd
 777                   (let ((newline (string #\Newline)))
 778                     (loop
 779                         (multiple-value-bind
 780                               (line no-cr)
 781                             (read-line object nil nil)
 782                           (unless line
 783                             (return))
 784                           (sb-unix:unix-write fd line 0 (length line))
 785                           (if no-cr
 786                               (return)
 787                               (sb-unix:unix-write fd newline 0 1)))))
 788                   (sb-unix:unix-lseek fd 0 sb-unix:l_set)
 789                   (push fd *close-in-parent*)
 790                   (return (values fd nil))))))
 791            (:output
 792             (multiple-value-bind (read-fd write-fd)
 793                 (sb-unix:unix-pipe)
 794               (unless read-fd
 795                 (error "couldn't create pipe: ~S" (strerror write-fd)))
 796               (copy-descriptor-to-stream read-fd object cookie)
 797               (push read-fd *close-on-error*)
 798               (push write-fd *close-in-parent*)
 799               (values write-fd nil)))))
 800         (t
 801          (error "invalid option to RUN-PROGRAM: ~S" object))))