src/code/run-program.lisp

   1 ;;;; RUN-PROGRAM and friends, a facility for running Unix programs
   2 ;;;; from inside SBCL
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB-IMPL") ;(SB-IMPL, not SB!IMPL, since we're built in warm load.)
  14 \f
  15 ;;;; hacking the Unix environment
  16 ;;;;
  17 ;;;; In the original CMU CL code that LOAD-FOREIGN is derived from, the
  18 ;;;; Unix environment (as in "man environ") was represented as an
  19 ;;;; alist from keywords to strings, so that e.g. the Unix environment
  20 ;;;;   "SHELL=/bin/bash" "HOME=/root" "PAGER=less"
  21 ;;;; was represented as
  22 ;;;;   ((:SHELL . "/bin/bash") (:HOME . "/root") (:PAGER "less"))
  23 ;;;; This had a few problems in principle: the mapping into
  24 ;;;; keyword symbols smashed the case of environment
  25 ;;;; variables, and the whole mapping depended on the presence of
  26 ;;;; #\= characters in the environment strings. In practice these
  27 ;;;; problems weren't hugely important, since conventionally environment
  28 ;;;; variables are uppercase strings followed by #\= followed by
  29 ;;;; arbitrary data. However, since it's so manifestly not The Right
  30 ;;;; Thing to make code which breaks unnecessarily on input which
  31 ;;;; doesn't follow what is, after all, only a tradition, we've switched
  32 ;;;; formats in SBCL, so that the fundamental environment list
  33 ;;;; is just a list of strings, with a one-to-one-correspondence
  34 ;;;; to the C-level representation. I.e., in the example above,
  35 ;;;; the SBCL representation is
  36 ;;;;   '("SHELL=/bin/bash" "HOME=/root" "PAGER=less")
  37 ;;;; CMU CL's implementation is currently supported to help with porting.
  38 ;;;;
  39 ;;;; It's not obvious that this code belongs here (instead of e.g. in
  40 ;;;; unix.lisp), since it has only a weak logical connection with
  41 ;;;; RUN-PROGRAM. However, physically it's convenient to put it here.
  42 ;;;; It's not needed at cold init, so we *can* put it in this
  43 ;;;; warm-loaded file. And by putting it in this warm-loaded file, we
  44 ;;;; make it easy for it to get to the C-level 'environ' variable.
  45 ;;;; which (at least in sbcl-0.6.10 on Red Hat Linux 6.2) is not
  46 ;;;; visible at GENESIS time.
  47
  48 #-win32
  49 (progn
  50   (define-alien-routine wrapped-environ (* c-string))
  51   (defun posix-environ ()
  52     "Return the Unix environment (\"man environ\") as a list of SIMPLE-STRINGs."
  53     (c-strings->string-list (wrapped-environ))))
  54
  55 ;#+win32 (sb-alien:define-alien-routine msvcrt-environ (* c-string))
  56
  57 ;;; Convert as best we can from an SBCL representation of a Unix
  58 ;;; environment to a CMU CL representation.
  59 ;;;
  60 ;;; * (UNIX-ENVIRONMENT-CMUCL-FROM-SBCL '("Bletch=fub" "Noggin" "YES=No!"))
  61 ;;; WARNING:
  62 ;;;   smashing case of "Bletch=fub" in conversion to CMU-CL-style
  63 ;;;     environment alist
  64 ;;; WARNING:
  65 ;;;   no #\= in "Noggin", eliding it in CMU-CL-style environment alist
  66 ;;; ((:BLETCH . "fub") (:YES . "No!"))
  67 (defun unix-environment-cmucl-from-sbcl (sbcl)
  68   (mapcan
  69    (lambda (string)
  70      (declare (type simple-base-string string))
  71      (let ((=-pos (position #\= string :test #'equal)))
  72        (if =-pos
  73            (list
  74             (let* ((key-as-string (subseq string 0 =-pos))
  75                    (key-as-upcase-string (string-upcase key-as-string))
  76                    (key (keywordicate key-as-upcase-string))
  77                    (val (subseq string (1+ =-pos))))
  78               (unless (string= key-as-string key-as-upcase-string)
  79                 (warn "smashing case of ~S in conversion to CMU-CL-style ~
  80                       environment alist"
  81                       string))
  82               (cons key val)))
  83            (warn "no #\\= in ~S, eliding it in CMU-CL-style environment alist"
  84                  string))))
  85    sbcl))
  86
  87 ;;; Convert from a CMU CL representation of a Unix environment to a
  88 ;;; SBCL representation.
  89 (defun unix-environment-sbcl-from-cmucl (cmucl)
  90   (mapcar
  91    (lambda (cons)
  92      (destructuring-bind (key . val) cons
  93        (declare (type keyword key) (type simple-base-string val))
  94        (concatenate 'simple-base-string (symbol-name key) "=" val)))
  95    cmucl))
  96 \f
  97 ;;;; Import wait3(2) from Unix.
  98
  99 #-win32
 100 (define-alien-routine ("wait3" c-wait3) sb-alien:int
 101   (status sb-alien:int :out)
 102   (options sb-alien:int)
 103   (rusage sb-alien:int))
 104
 105 #-win32
 106 (defun wait3 (&optional do-not-hang check-for-stopped)
 107   #+sb-doc
 108   "Return any available status information on child process. "
 109   (multiple-value-bind (pid status)
 110       (c-wait3 (logior (if do-not-hang
 111                            sb-unix:wnohang
 112                            0)
 113                        (if check-for-stopped
 114                            sb-unix:wuntraced
 115                            0))
 116                0)
 117     (cond ((or (minusp pid)
 118                (zerop pid))
 119            nil)
 120           ((eql (ldb (byte 8 0) status)
 121                 sb-unix:wstopped)
 122            (values pid
 123                    :stopped
 124                    (ldb (byte 8 8) status)))
 125           ((zerop (ldb (byte 7 0) status))
 126            (values pid
 127                    :exited
 128                    (ldb (byte 8 8) status)))
 129           (t
 130            (let ((signal (ldb (byte 7 0) status)))
 131              (values pid
 132                      (if (position signal
 133                                    #.(vector
 134                                       sb-unix:sigstop
 135                                       sb-unix:sigtstp
 136                                       sb-unix:sigttin
 137                                       sb-unix:sigttou))
 138                          :stopped
 139                          :signaled)
 140                      signal
 141                      (not (zerop (ldb (byte 1 7) status)))))))))
 142 \f
 143 ;;;; process control stuff
 144 (defvar *active-processes* nil
 145   #+sb-doc
 146   "List of process structures for all active processes.")
 147
 148 #-win32
 149 (defvar *active-processes-lock*
 150   (sb-thread:make-mutex :name "Lock for active processes."))
 151
 152 ;;; *ACTIVE-PROCESSES* can be accessed from multiple threads so a
 153 ;;; mutex is needed. More importantly the sigchld signal handler also
 154 ;;; accesses it, that's why we need without-interrupts.
 155 (defmacro with-active-processes-lock (() &body body)
 156   #-win32
 157   `(without-interrupts
 158     (sb-thread:with-mutex (*active-processes-lock*)
 159       ,@body))
 160   #+win32
 161   `(progn ,@body))
 162
 163 (defstruct (process (:copier nil))
 164   pid                 ; PID of child process
 165   %status             ; either :RUNNING, :STOPPED, :EXITED, or :SIGNALED
 166   exit-code           ; either exit code or signal
 167   core-dumped         ; T if a core image was dumped
 168   #-win32 pty                 ; stream to child's pty, or NIL
 169   input               ; stream to child's input, or NIL
 170   output              ; stream from child's output, or NIL
 171   error               ; stream from child's error output, or NIL
 172   status-hook         ; closure to call when PROC changes status
 173   plist               ; a place for clients to stash things
 174   cookie)             ; list of the number of pipes from the subproc
 175
 176 (defmethod print-object ((process process) stream)
 177   (print-unreadable-object (process stream :type t)
 178     (let ((status (process-status process)))
 179      (if (eq :exited status)
 180          (format stream "~S ~S" status (process-exit-code process))
 181          (format stream "~S ~S" (process-pid process) status)))
 182     process))
 183
 184 #+sb-doc
 185 (setf (documentation 'process-p 'function)
 186       "T if OBJECT is a PROCESS, NIL otherwise.")
 187
 188 #+sb-doc
 189 (setf (documentation 'process-pid 'function) "The pid of the child process.")
 190
 191 #+win32
 192 (define-alien-routine ("GetExitCodeProcess@8" get-exit-code-process)
 193     int
 194   (handle unsigned) (exit-code unsigned :out))
 195
 196 (defun process-status (process)
 197   #+sb-doc
 198   "Return the current status of PROCESS.  The result is one of :RUNNING,
 199    :STOPPED, :EXITED, or :SIGNALED."
 200   (get-processes-status-changes)
 201   (process-%status process))
 202
 203 #+sb-doc
 204 (setf (documentation 'process-exit-code 'function)
 205       "The exit code or the signal of a stopped process.")
 206
 207 #+sb-doc
 208 (setf (documentation 'process-core-dumped 'function)
 209       "T if a core image was dumped by the process.")
 210
 211 #+sb-doc
 212 (setf (documentation 'process-pty 'function)
 213       "The pty stream of the process or NIL.")
 214
 215 #+sb-doc
 216 (setf (documentation 'process-input 'function)
 217       "The input stream of the process or NIL.")
 218
 219 #+sb-doc
 220 (setf (documentation 'process-output 'function)
 221       "The output stream of the process or NIL.")
 222
 223 #+sb-doc
 224 (setf (documentation 'process-error 'function)
 225       "The error stream of the process or NIL.")
 226
 227 #+sb-doc
 228 (setf (documentation 'process-status-hook  'function)
 229       "A function that is called when PROCESS changes its status.
 230 The function is called with PROCESS as its only argument.")
 231
 232 #+sb-doc
 233 (setf (documentation 'process-plist  'function)
 234       "A place for clients to stash things.")
 235
 236 (defun process-wait (process &optional check-for-stopped)
 237   #+sb-doc
 238   "Wait for PROCESS to quit running for some reason. When
 239 CHECK-FOR-STOPPED is T, also returns when PROCESS is stopped. Returns
 240 PROCESS."
 241   (loop
 242       (case (process-status process)
 243         (:running)
 244         (:stopped
 245          (when check-for-stopped
 246            (return)))
 247         (t
 248          (when (zerop (car (process-cookie process)))
 249            (return))))
 250       (sb-sys:serve-all-events 1))
 251   process)
 252
 253 #-(or hpux win32)
 254 ;;; Find the current foreground process group id.
 255 (defun find-current-foreground-process (proc)
 256   (with-alien ((result sb-alien:int))
 257     (multiple-value-bind
 258           (wonp error)
 259         (sb-unix:unix-ioctl (sb-sys:fd-stream-fd (process-pty proc))
 260                             sb-unix:TIOCGPGRP
 261                             (alien-sap (sb-alien:addr result)))
 262       (unless wonp
 263         (error "TIOCPGRP ioctl failed: ~S" (strerror error)))
 264       result))
 265   (process-pid proc))
 266
 267 #-win32
 268 (defun process-kill (process signal &optional (whom :pid))
 269   #+sb-doc
 270   "Hand SIGNAL to PROCESS. If WHOM is :PID, use the kill Unix system call. If
 271    WHOM is :PROCESS-GROUP, use the killpg Unix system call. If WHOM is
 272    :PTY-PROCESS-GROUP deliver the signal to whichever process group is
 273    currently in the foreground."
 274   (let ((pid (ecase whom
 275                ((:pid :process-group)
 276                 (process-pid process))
 277                (:pty-process-group
 278                 #-hpux
 279                 (find-current-foreground-process process)))))
 280     (multiple-value-bind
 281           (okay errno)
 282         (case whom
 283           #+hpux
 284           (:pty-process-group
 285            (sb-unix:unix-ioctl (sb-sys:fd-stream-fd (process-pty process))
 286                                sb-unix:TIOCSIGSEND
 287                                (sb-sys:int-sap
 288                                 signal)))
 289           ((:process-group #-hpux :pty-process-group)
 290            (sb-unix:unix-killpg pid signal))
 291           (t
 292            (sb-unix:unix-kill pid signal)))
 293       (cond ((not okay)
 294              (values nil errno))
 295             ((and (eql pid (process-pid process))
 296                   (= signal sb-unix:sigcont))
 297              (setf (process-%status process) :running)
 298              (setf (process-exit-code process) nil)
 299              (when (process-status-hook process)
 300                (funcall (process-status-hook process) process))
 301              t)
 302             (t
 303              t)))))
 304
 305 (defun process-alive-p (process)
 306   #+sb-doc
 307   "Return T if PROCESS is still alive, NIL otherwise."
 308   (let ((status (process-status process)))
 309     (if (or (eq status :running)
 310             (eq status :stopped))
 311         t
 312         nil)))
 313
 314 (defun process-close (process)
 315   #+sb-doc
 316   "Close all streams connected to PROCESS and stop maintaining the
 317 status slot."
 318   (macrolet ((frob (stream abort)
 319                `(when ,stream (close ,stream :abort ,abort))))
 320     #-win32
 321     (frob (process-pty process) t)   ; Don't FLUSH-OUTPUT to dead process,
 322     (frob (process-input process) t) ; .. 'cause it will generate SIGPIPE.
 323     (frob (process-output process) nil)
 324     (frob (process-error process) nil))
 325   ;; FIXME: Given that the status-slot is no longer updated,
 326   ;; maybe it should be set to :CLOSED, or similar?
 327   (with-active-processes-lock ()
 328    (setf *active-processes* (delete process *active-processes*)))
 329   process)
 330
 331 ;;; the handler for SIGCHLD signals that RUN-PROGRAM establishes
 332 #-win32
 333 (defun sigchld-handler (ignore1 ignore2 ignore3)
 334   (declare (ignore ignore1 ignore2 ignore3))
 335   (get-processes-status-changes))
 336
 337 (defun get-processes-status-changes ()
 338   #-win32
 339   (loop
 340    (multiple-value-bind (pid what code core)
 341        (wait3 t t)
 342      (unless pid
 343        (return))
 344      (let ((proc (with-active-processes-lock ()
 345                    (find pid *active-processes* :key #'process-pid))))
 346        (when proc
 347          (setf (process-%status proc) what)
 348          (setf (process-exit-code proc) code)
 349          (setf (process-core-dumped proc) core)
 350          (when (process-status-hook proc)
 351            (funcall (process-status-hook proc) proc))
 352          (when (position what #(:exited :signaled))
 353            (with-active-processes-lock ()
 354              (setf *active-processes*
 355                    (delete proc *active-processes*))))))))
 356   #+win32
 357   (let (exited)
 358     (with-active-processes-lock ()
 359       (setf *active-processes*
 360             (delete-if (lambda (proc)
 361                          (multiple-value-bind (ok code)
 362                              (get-exit-code-process (process-pid proc))
 363                            (when (and (plusp ok) (/= code 259))
 364                              (setf (process-%status proc) :exited
 365                                    (process-exit-code proc) code)
 366                              (when (process-status-hook proc)
 367                                (push proc exited))
 368                              t)))
 369                        *active-processes*)))
 370     ;; Can't call the hooks before all the processes have been deal
 371     ;; with, as calling a hook may cause re-entry to
 372     ;; GET-PROCESS-STATUS-CHANGES. That may be OK when using wait3,
 373     ;; but in the Windows implementation is would be deeply bad.
 374     (dolist (proc exited)
 375       (let ((hook (process-status-hook proc)))
 376         (when hook
 377           (funcall hook proc))))))
 378 \f
 379 ;;;; RUN-PROGRAM and close friends
 380
 381 ;;; list of file descriptors to close when RUN-PROGRAM exits due to an error
 382 (defvar *close-on-error* nil)
 383
 384 ;;; list of file descriptors to close when RUN-PROGRAM returns in the parent
 385 (defvar *close-in-parent* nil)
 386
 387 ;;; list of handlers installed by RUN-PROGRAM
 388 #-win32
 389 (defvar *handlers-installed* nil)
 390
 391 ;;; Find an unused pty. Return three values: the file descriptor for
 392 ;;; the master side of the pty, the file descriptor for the slave side
 393 ;;; of the pty, and the name of the tty device for the slave side.
 394 #-win32
 395 (defun find-a-pty ()
 396   (dolist (char '(#\p #\q))
 397     (dotimes (digit 16)
 398       (let* ((master-name (coerce (format nil "/dev/pty~C~X" char digit) 'base-string))
 399              (master-fd (sb-unix:unix-open master-name
 400                                            sb-unix:o_rdwr
 401                                            #o666)))
 402         (when master-fd
 403           (let* ((slave-name (coerce (format nil "/dev/tty~C~X" char digit) 'base-string))
 404                  (slave-fd (sb-unix:unix-open slave-name
 405                                               sb-unix:o_rdwr
 406                                               #o666)))
 407             (when slave-fd
 408               (return-from find-a-pty
 409                 (values master-fd
 410                         slave-fd
 411                         slave-name)))
 412             (sb-unix:unix-close master-fd))))))
 413   (error "could not find a pty"))
 414
 415 #-win32
 416 (defun open-pty (pty cookie)
 417   (when pty
 418     (multiple-value-bind
 419           (master slave name)
 420         (find-a-pty)
 421       (push master *close-on-error*)
 422       (push slave *close-in-parent*)
 423       (when (streamp pty)
 424         (multiple-value-bind (new-fd errno) (sb-unix:unix-dup master)
 425           (unless new-fd
 426             (error "couldn't SB-UNIX:UNIX-DUP ~W: ~A" master (strerror errno)))
 427           (push new-fd *close-on-error*)
 428           (copy-descriptor-to-stream new-fd pty cookie)))
 429       (values name
 430               (sb-sys:make-fd-stream master :input t :output t
 431                                      :element-type :default
 432                                      :dual-channel-p t)))))
 433
 434 (defmacro round-bytes-to-words (n)
 435   `(logand (the fixnum (+ (the fixnum ,n) 3)) (lognot 3)))
 436
 437 (defun string-list-to-c-strvec (string-list)
 438   ;; Make a pass over STRING-LIST to calculate the amount of memory
 439   ;; needed to hold the strvec.
 440   (let ((string-bytes 0)
 441         ;; We need an extra for the null, and an extra 'cause exect
 442         ;; clobbers argv[-1].
 443         (vec-bytes (* #.(/ sb-vm::n-machine-word-bits sb-vm::n-byte-bits)
 444                       (+ (length string-list) 2))))
 445     (declare (fixnum string-bytes vec-bytes))
 446     (dolist (s string-list)
 447       (enforce-type s simple-string)
 448       (incf string-bytes (round-bytes-to-words (1+ (length s)))))
 449     ;; Now allocate the memory and fill it in.
 450     (let* ((total-bytes (+ string-bytes vec-bytes))
 451            (vec-sap (sb-sys:allocate-system-memory total-bytes))
 452            (string-sap (sap+ vec-sap vec-bytes))
 453            (i #.(/ sb-vm::n-machine-word-bits sb-vm::n-byte-bits)))
 454       (declare (type (and unsigned-byte fixnum) total-bytes i)
 455                (type sb-sys:system-area-pointer vec-sap string-sap))
 456       (dolist (s string-list)
 457         (declare (simple-string s))
 458         (let ((n (length s)))
 459           ;; Blast the string into place.
 460           (sb-kernel:copy-ub8-to-system-area (the simple-base-string
 461                                                ;; FIXME
 462                                                (coerce s 'simple-base-string))
 463                                              0
 464                                              string-sap 0
 465                                              (1+ n))
 466           ;; Blast the pointer to the string into place.
 467           (setf (sap-ref-sap vec-sap i) string-sap)
 468           (setf string-sap (sap+ string-sap (round-bytes-to-words (1+ n))))
 469           (incf i #.(/ sb-vm::n-machine-word-bits sb-vm::n-byte-bits))))
 470       ;; Blast in the last null pointer.
 471       (setf (sap-ref-sap vec-sap i) (int-sap 0))
 472       (values vec-sap (sap+ vec-sap #.(/ sb-vm::n-machine-word-bits
 473                                          sb-vm::n-byte-bits))
 474               total-bytes))))
 475
 476 (defmacro with-c-strvec ((var str-list) &body body)
 477   (with-unique-names (sap size)
 478     `(multiple-value-bind
 479       (,sap ,var ,size)
 480       (string-list-to-c-strvec ,str-list)
 481       (unwind-protect
 482            (progn
 483              ,@body)
 484         (sb-sys:deallocate-system-memory ,sap ,size)))))
 485
 486 #-win32
 487 (sb-alien:define-alien-routine spawn sb-alien:int
 488   (program sb-alien:c-string)
 489   (argv (* sb-alien:c-string))
 490   (envp (* sb-alien:c-string))
 491   (pty-name sb-alien:c-string)
 492   (stdin sb-alien:int)
 493   (stdout sb-alien:int)
 494   (stderr sb-alien:int))
 495
 496 #+win32
 497 (sb-alien:define-alien-routine spawn sb-win32::handle
 498   (program sb-alien:c-string)
 499   (argv (* sb-alien:c-string))
 500   (stdin sb-alien:int)
 501   (stdout sb-alien:int)
 502   (stderr sb-alien:int)
 503   (wait sb-alien:int))
 504
 505 ;;; Is UNIX-FILENAME the name of a file that we can execute?
 506 (defun unix-filename-is-executable-p (unix-filename)
 507   (let ((filename (coerce unix-filename 'base-string)))
 508     (values (and (eq (sb-unix:unix-file-kind filename) :file)
 509                  #-win32
 510                  (sb-unix:unix-access filename sb-unix:x_ok)))))
 511
 512 (defun find-executable-in-search-path (pathname &optional
 513                                        (search-path (posix-getenv "PATH")))
 514   #+sb-doc
 515   "Find the first executable file matching PATHNAME in any of the
 516 colon-separated list of pathnames SEARCH-PATH"
 517   (let ((program #-win32 pathname
 518                  #+win32 (merge-pathnames pathname (make-pathname :type "exe"))))
 519    (loop for end =  (position #-win32 #\: #+win32 #\; search-path
 520                               :start (if end (1+ end) 0))
 521          and start = 0 then (and end (1+ end))
 522          while start
 523          ;; <Krystof> the truename of a file naming a directory is the
 524          ;; directory, at least until pfdietz comes along and says why
 525          ;; that's noncompliant  -- CSR, c. 2003-08-10
 526          for truename = (probe-file (subseq search-path start end))
 527          for fullpath = (when truename
 528                           (unix-namestring (merge-pathnames program truename)))
 529          when (and fullpath (unix-filename-is-executable-p fullpath))
 530          return fullpath)))
 531
 532 ;;; FIXME: There shouldn't be two semiredundant versions of the
 533 ;;; documentation. Since this is a public extension function, the
 534 ;;; documentation should be in the doc string. So all information from
 535 ;;; this comment should be merged into the doc string, and then this
 536 ;;; comment can go away.
 537 ;;;
 538 ;;; RUN-PROGRAM uses fork() and execve() to run a different program.
 539 ;;; Strange stuff happens to keep the Unix state of the world
 540 ;;; coherent.
 541 ;;;
 542 ;;; The child process needs to get its input from somewhere, and send
 543 ;;; its output (both standard and error) to somewhere. We have to do
 544 ;;; different things depending on where these somewheres really are.
 545 ;;;
 546 ;;; For input, there are five options:
 547 ;;;  -- T: Just leave fd 0 alone. Pretty simple.
 548 ;;;  -- "file": Read from the file. We need to open the file and
 549 ;;;     pull the descriptor out of the stream. The parent should close
 550 ;;;     this stream after the child is up and running to free any
 551 ;;;     storage used in the parent.
 552 ;;;  -- NIL: Same as "file", but use "/dev/null" as the file.
 553 ;;;  -- :STREAM: Use Unix pipe() to create two descriptors. Use
 554 ;;;     SB-SYS:MAKE-FD-STREAM to create the output stream on the
 555 ;;;     writeable descriptor, and pass the readable descriptor to
 556 ;;;     the child. The parent must close the readable descriptor for
 557 ;;;     EOF to be passed up correctly.
 558 ;;;  -- a stream: If it's a fd-stream, just pull the descriptor out
 559 ;;;     of it. Otherwise make a pipe as in :STREAM, and copy
 560 ;;;     everything across.
 561 ;;;
 562 ;;; For output, there are five options:
 563 ;;;  -- T: Leave descriptor 1 alone.
 564 ;;;  -- "file": dump output to the file.
 565 ;;;  -- NIL: dump output to /dev/null.
 566 ;;;  -- :STREAM: return a stream that can be read from.
 567 ;;;  -- a stream: if it's a fd-stream, use the descriptor in it.
 568 ;;;     Otherwise, copy stuff from output to stream.
 569 ;;;
 570 ;;; For error, there are all the same options as output plus:
 571 ;;;  -- :OUTPUT: redirect to the same place as output.
 572 ;;;
 573 ;;; RUN-PROGRAM returns a PROCESS structure for the process if
 574 ;;; the fork worked, and NIL if it did not.
 575
 576 #-win32
 577 (defun run-program (program args
 578                     &key
 579                     (env nil env-p)
 580                     (environment (if env-p
 581                                      (unix-environment-sbcl-from-cmucl env)
 582                                      (posix-environ))
 583                                  environment-p)
 584                     (wait t)
 585                     search
 586                     pty
 587                     input
 588                     if-input-does-not-exist
 589                     output
 590                     (if-output-exists :error)
 591                     (error :output)
 592                     (if-error-exists :error)
 593                     status-hook)
 594   #+sb-doc
 595   "RUN-PROGRAM creates a new Unix process running the Unix program
 596 found in the file specified by the PROGRAM argument. ARGS are the
 597 standard arguments that can be passed to a Unix program. For no
 598 arguments, use NIL (which means that just the name of the program is
 599 passed as arg 0).
 600
 601 RUN-PROGRAM will return a PROCESS structure. See the CMU Common Lisp
 602 Users Manual for details about the PROCESS structure.
 603
 604    Notes about Unix environments (as in the :ENVIRONMENT and :ENV args):
 605
 606    - The SBCL implementation of RUN-PROGRAM, like Perl and many other
 607      programs, but unlike the original CMU CL implementation, copies
 608      the Unix environment by default.
 609
 610    - Running Unix programs from a setuid process, or in any other
 611      situation where the Unix environment is under the control of someone
 612      else, is a mother lode of security problems. If you are contemplating
 613      doing this, read about it first. (The Perl community has a lot of good
 614      documentation about this and other security issues in script-like
 615      programs.)
 616
 617    The &KEY arguments have the following meanings:
 618
 619    :ENVIRONMENT
 620       a list of SIMPLE-BASE-STRINGs describing the new Unix environment
 621       (as in \"man environ\"). The default is to copy the environment of
 622       the current process.
 623    :ENV
 624       an alternative lossy representation of the new Unix environment,
 625       for compatibility with CMU CL
 626    :SEARCH
 627       Look for PROGRAM in each of the directories along the $PATH
 628       environment variable.  Otherwise an absolute pathname is required.
 629       (See also FIND-EXECUTABLE-IN-SEARCH-PATH)
 630    :WAIT
 631       If non-NIL (default), wait until the created process finishes.  If
 632       NIL, continue running Lisp until the program finishes.
 633    :PTY
 634       Either T, NIL, or a stream.  Unless NIL, the subprocess is established
 635       under a PTY.  If :pty is a stream, all output to this pty is sent to
 636       this stream, otherwise the PROCESS-PTY slot is filled in with a stream
 637       connected to pty that can read output and write input.
 638    :INPUT
 639       Either T, NIL, a pathname, a stream, or :STREAM.  If T, the standard
 640       input for the current process is inherited.  If NIL, /dev/null
 641       is used.  If a pathname, the file so specified is used.  If a stream,
 642       all the input is read from that stream and send to the subprocess.  If
 643       :STREAM, the PROCESS-INPUT slot is filled in with a stream that sends
 644       its output to the process. Defaults to NIL.
 645    :IF-INPUT-DOES-NOT-EXIST (when :INPUT is the name of a file)
 646       can be one of:
 647          :ERROR to generate an error
 648          :CREATE to create an empty file
 649          NIL (the default) to return NIL from RUN-PROGRAM
 650    :OUTPUT
 651       Either T, NIL, a pathname, a stream, or :STREAM.  If T, the standard
 652       output for the current process is inherited.  If NIL, /dev/null
 653       is used.  If a pathname, the file so specified is used.  If a stream,
 654       all the output from the process is written to this stream. If
 655       :STREAM, the PROCESS-OUTPUT slot is filled in with a stream that can
 656       be read to get the output. Defaults to NIL.
 657    :IF-OUTPUT-EXISTS (when :OUTPUT is the name of a file)
 658       can be one of:
 659          :ERROR (the default) to generate an error
 660          :SUPERSEDE to supersede the file with output from the program
 661          :APPEND to append output from the program to the file
 662          NIL to return NIL from RUN-PROGRAM, without doing anything
 663    :ERROR and :IF-ERROR-EXISTS
 664       Same as :OUTPUT and :IF-OUTPUT-EXISTS, except that :ERROR can also be
 665       specified as :OUTPUT in which case all error output is routed to the
 666       same place as normal output.
 667    :STATUS-HOOK
 668       This is a function the system calls whenever the status of the
 669       process changes.  The function takes the process as an argument."
 670   (when (and env-p environment-p)
 671     (error "can't specify :ENV and :ENVIRONMENT simultaneously"))
 672   ;; Make sure that the interrupt handler is installed.
 673   (sb-sys:enable-interrupt sb-unix:sigchld #'sigchld-handler)
 674   ;; Prepend the program to the argument list.
 675   (push (namestring program) args)
 676   (let (;; Clear various specials used by GET-DESCRIPTOR-FOR to
 677         ;; communicate cleanup info.
 678         *close-on-error*
 679         *close-in-parent*
 680         *handlers-installed*
 681         ;; Establish PROC at this level so that we can return it.
 682         proc
 683         ;; It's friendly to allow the caller to pass any string
 684         ;; designator, but internally we'd like SIMPLE-STRINGs.
 685         (simple-args (mapcar (lambda (x) (coerce x 'simple-string)) args)))
 686     (unwind-protect
 687          (let ((pfile
 688                 (if search
 689                     (find-executable-in-search-path program)
 690                     (unix-namestring program)))
 691                (cookie (list 0)))
 692            (unless pfile
 693              (error "no such program: ~S" program))
 694            (unless (unix-filename-is-executable-p pfile)
 695              (error "not executable: ~S" program))
 696            (multiple-value-bind (stdin input-stream)
 697                (get-descriptor-for input cookie
 698                                    :direction :input
 699                                    :if-does-not-exist if-input-does-not-exist)
 700              (multiple-value-bind (stdout output-stream)
 701                  (get-descriptor-for output cookie
 702                                      :direction :output
 703                                      :if-exists if-output-exists)
 704                (multiple-value-bind (stderr error-stream)
 705                    (if (eq error :output)
 706                        (values stdout output-stream)
 707                        (get-descriptor-for error cookie
 708                                            :direction :output
 709                                            :if-exists if-error-exists))
 710                  (multiple-value-bind (pty-name pty-stream)
 711                      (open-pty pty cookie)
 712                    ;; Make sure we are not notified about the child
 713                    ;; death before we have installed the PROCESS
 714                    ;; structure in *ACTIVE-PROCESSES*.
 715                    (with-active-processes-lock ()
 716                     (with-c-strvec (args-vec simple-args)
 717                       (with-c-strvec (environment-vec environment)
 718                         (let ((child-pid
 719                                (without-gcing
 720                                 (spawn pfile args-vec environment-vec pty-name
 721                                        stdin stdout stderr))))
 722                           (when (< child-pid 0)
 723                             (error "couldn't fork child process: ~A"
 724                                    (strerror)))
 725                           (setf proc (make-process :pid child-pid
 726                                                    :%status :running
 727                                                    :pty pty-stream
 728                                                    :input input-stream
 729                                                    :output output-stream
 730                                                    :error error-stream
 731                                                    :status-hook status-hook
 732                                                    :cookie cookie))
 733                           (push proc *active-processes*))))))))))
 734       (dolist (fd *close-in-parent*)
 735         (sb-unix:unix-close fd))
 736       (unless proc
 737         (dolist (fd *close-on-error*)
 738           (sb-unix:unix-close fd))
 739         (dolist (handler *handlers-installed*)
 740           (sb-sys:remove-fd-handler handler))))
 741     (when (and wait proc)
 742       (process-wait proc))
 743     proc))
 744
 745 #+win32
 746 (defun run-program (program args
 747                     &key
 748                     (wait t)
 749                     search
 750                     input
 751                     if-input-does-not-exist
 752                     output
 753                     (if-output-exists :error)
 754                     (error :output)
 755                     (if-error-exists :error)
 756                     status-hook)
 757   "RUN-PROGRAM creates a new process specified by the PROGRAM
 758 argument. ARGS are the standard arguments that can be passed to a
 759 program. For no arguments, use NIL (which means that just the name of
 760 the program is passed as arg 0).
 761
 762 RUN-PROGRAM will either return a PROCESS structure. See the CMU
 763 Common Lisp Users Manual for details about the PROCESS structure.
 764
 765    The &KEY arguments have the following meanings:
 766      :SEARCH
 767         Look for PROGRAM in each of the directories along the $PATH
 768         environment variable.  Otherwise an absolute pathname is required.
 769         (See also FIND-EXECUTABLE-IN-SEARCH-PATH)
 770      :WAIT
 771         If non-NIL (default), wait until the created process finishes.  If
 772         NIL, continue running Lisp until the program finishes.
 773      :INPUT
 774         Either T, NIL, a pathname, a stream, or :STREAM.  If T, the standard
 775         input for the current process is inherited.  If NIL, /dev/null
 776         is used.  If a pathname, the file so specified is used.  If a stream,
 777         all the input is read from that stream and send to the subprocess.  If
 778         :STREAM, the PROCESS-INPUT slot is filled in with a stream that sends
 779         its output to the process. Defaults to NIL.
 780      :IF-INPUT-DOES-NOT-EXIST (when :INPUT is the name of a file)
 781         can be one of:
 782            :ERROR to generate an error
 783            :CREATE to create an empty file
 784            NIL (the default) to return NIL from RUN-PROGRAM
 785      :OUTPUT
 786         Either T, NIL, a pathname, a stream, or :STREAM.  If T, the standard
 787         output for the current process is inherited.  If NIL, /dev/null
 788         is used.  If a pathname, the file so specified is used.  If a stream,
 789         all the output from the process is written to this stream. If
 790         :STREAM, the PROCESS-OUTPUT slot is filled in with a stream that can
 791         be read to get the output. Defaults to NIL.
 792      :IF-OUTPUT-EXISTS (when :OUTPUT is the name of a file)
 793         can be one of:
 794            :ERROR (the default) to generate an error
 795            :SUPERSEDE to supersede the file with output from the program
 796            :APPEND to append output from the program to the file
 797            NIL to return NIL from RUN-PROGRAM, without doing anything
 798      :ERROR and :IF-ERROR-EXISTS
 799         Same as :OUTPUT and :IF-OUTPUT-EXISTS, except that :ERROR can also be
 800         specified as :OUTPUT in which case all error output is routed to the
 801         same place as normal output.
 802      :STATUS-HOOK
 803         This is a function the system calls whenever the status of the
 804         process changes.  The function takes the process as an argument."
 805   ;; Prepend the program to the argument list.
 806   (push (namestring program) args)
 807   (let (;; Clear various specials used by GET-DESCRIPTOR-FOR to
 808         ;; communicate cleanup info.
 809         *close-on-error*
 810         *close-in-parent*
 811         ;; Establish PROC at this level so that we can return it.
 812         proc
 813         ;; It's friendly to allow the caller to pass any string
 814         ;; designator, but internally we'd like SIMPLE-STRINGs.
 815         (simple-args (mapcar (lambda (x) (coerce x 'simple-string)) args)))
 816     (unwind-protect
 817          (let ((pfile
 818                 (if search
 819                     (find-executable-in-search-path program)
 820                     (unix-namestring program)))
 821                (cookie (list 0)))
 822            (unless pfile
 823              (error "No such program: ~S" program))
 824            (unless (unix-filename-is-executable-p pfile)
 825              (error "Not an executable: ~S" program))
 826            (multiple-value-bind (stdin input-stream)
 827                (get-descriptor-for input cookie
 828                                    :direction :input
 829                                    :if-does-not-exist if-input-does-not-exist)
 830              (multiple-value-bind (stdout output-stream)
 831                  (get-descriptor-for output cookie
 832                                      :direction :output
 833                                      :if-exists if-output-exists)
 834                (multiple-value-bind (stderr error-stream)
 835                    (if (eq error :output)
 836                        (values stdout output-stream)
 837                        (get-descriptor-for error cookie
 838                                            :direction :output
 839                                            :if-exists if-error-exists))
 840                     (with-c-strvec (args-vec simple-args)
 841                           (let ((handle (without-gcing
 842                                          (spawn pfile args-vec
 843                                                 stdin stdout stderr
 844                                                 (if wait 1 0)))))
 845                             (when (< handle 0)
 846                               (error "Couldn't spawn program: ~A" (strerror)))
 847                             (setf proc
 848                                   (if wait
 849                                       (make-process :%status :exited
 850                                                     :exit-code handle)
 851                                       (make-process :pid handle
 852                                                     :%status :running
 853                                                     :input input-stream
 854                                                     :output output-stream
 855                                                     :error error-stream
 856                                                     :status-hook status-hook
 857                                                     :cookie cookie))))))))))
 858     ;; FIXME: this should probably use PROCESS-WAIT instead instead
 859     ;; of special argument to SPAWN.
 860     (unless wait
 861       (push proc *active-processes*))
 862     (when (and wait status-hook)
 863       (funcall status-hook proc))
 864     proc))
 865
 866 ;;; Install a handler for any input that shows up on the file
 867 ;;; descriptor. The handler reads the data and writes it to the
 868 ;;; stream.
 869 (defun copy-descriptor-to-stream (descriptor stream cookie)
 870   (incf (car cookie))
 871   (let ((string (make-string 256 :element-type 'base-char))
 872         handler)
 873     (setf handler
 874           (sb-sys:add-fd-handler
 875            descriptor
 876            :input (lambda (fd)
 877                     (declare (ignore fd))
 878                     (loop
 879                      (unless handler
 880                        (return))
 881                      (multiple-value-bind
 882                          (result readable/errno)
 883                          (sb-unix:unix-select (1+ descriptor)
 884                                               (ash 1 descriptor)
 885                                               0 0 0)
 886                        (cond ((null result)
 887                               (error "~@<couldn't select on sub-process: ~
 888                                            ~2I~_~A~:>"
 889                                      (strerror readable/errno)))
 890                              ((zerop result)
 891                               (return))))
 892                      (sb-alien:with-alien ((buf (sb-alien:array
 893                                                  sb-alien:char
 894                                                  256)))
 895                        (multiple-value-bind
 896                            (count errno)
 897                            (sb-unix:unix-read descriptor
 898                                               (alien-sap buf)
 899                                               256)
 900                            (cond (#-win32(or (and (null count)
 901                                                   (eql errno sb-unix:eio))
 902                                              (eql count 0))
 903                                          #+win32(<= count 0)
 904                                 (sb-sys:remove-fd-handler handler)
 905                                 (setf handler nil)
 906                                 (decf (car cookie))
 907                                 (sb-unix:unix-close descriptor)
 908                                 (return))
 909                                ((null count)
 910                                 (sb-sys:remove-fd-handler handler)
 911                                 (setf handler nil)
 912                                 (decf (car cookie))
 913                                 (error
 914                                  "~@<couldn't read input from sub-process: ~
 915                                      ~2I~_~A~:>"
 916                                  (strerror errno)))
 917                                (t
 918                                 (sb-kernel:copy-ub8-from-system-area
 919                                  (alien-sap buf) 0
 920                                  string 0
 921                                  count)
 922                                 (write-string string stream
 923                                               :end count)))))))))))
 924
 925 ;;; Find a file descriptor to use for object given the direction.
 926 ;;; Returns the descriptor. If object is :STREAM, returns the created
 927 ;;; stream as the second value.
 928 (defun get-descriptor-for (object
 929                            cookie
 930                            &rest keys
 931                            &key direction
 932                            &allow-other-keys)
 933   (cond ((eq object t)
 934          ;; No new descriptor is needed.
 935          (values -1 nil))
 936         ((eq object nil)
 937          ;; Use /dev/null.
 938          (multiple-value-bind
 939                (fd errno)
 940              (sb-unix:unix-open #-win32 #.(coerce "/dev/null" 'base-string)
 941                                 #+win32 #.(coerce "nul" 'base-string)
 942                                 (case direction
 943                                   (:input sb-unix:o_rdonly)
 944                                   (:output sb-unix:o_wronly)
 945                                   (t sb-unix:o_rdwr))
 946                                 #o666)
 947            (unless fd
 948              (error "~@<couldn't open \"/dev/null\": ~2I~_~A~:>"
 949                     (strerror errno)))
 950            (push fd *close-in-parent*)
 951            (values fd nil)))
 952         ((eq object :stream)
 953          (multiple-value-bind (read-fd write-fd) (sb-unix:unix-pipe)
 954            (unless read-fd
 955              (error "couldn't create pipe: ~A" (strerror write-fd)))
 956            (case direction
 957              (:input
 958               (push read-fd *close-in-parent*)
 959               (push write-fd *close-on-error*)
 960               (let ((stream (sb-sys:make-fd-stream write-fd :output t
 961                                                    :element-type :default)))
 962                 (values read-fd stream)))
 963              (:output
 964               (push read-fd *close-on-error*)
 965               (push write-fd *close-in-parent*)
 966               (let ((stream (sb-sys:make-fd-stream read-fd :input t
 967                                                    :element-type :default)))
 968                 (values write-fd stream)))
 969              (t
 970               (sb-unix:unix-close read-fd)
 971               (sb-unix:unix-close write-fd)
 972               (error "Direction must be either :INPUT or :OUTPUT, not ~S."
 973                      direction)))))
 974         ((or (pathnamep object) (stringp object))
 975          (with-open-stream (file (apply #'open object keys))
 976            (multiple-value-bind
 977                  (fd errno)
 978                (sb-unix:unix-dup (sb-sys:fd-stream-fd file))
 979              (cond (fd
 980                     (push fd *close-in-parent*)
 981                     (values fd nil))
 982                    (t
 983                     (error "couldn't duplicate file descriptor: ~A"
 984                            (strerror errno)))))))
 985         ((sb-sys:fd-stream-p object)
 986          (values (sb-sys:fd-stream-fd object) nil))
 987         ((streamp object)
 988          (ecase direction
 989            (:input
 990             ;; FIXME: We could use a better way of setting up
 991             ;; temporary files, both here and in LOAD-FOREIGN.
 992             (dotimes (count
 993                        256
 994                       (error "could not open a temporary file in /tmp"))
 995               (let* ((name (coerce (format nil "/tmp/.run-program-~D" count)
 996                                    'base-string))
 997                      (fd (sb-unix:unix-open name
 998                                             (logior sb-unix:o_rdwr
 999                                                     sb-unix:o_creat
1000                                                     sb-unix:o_excl)
1001                                             #o666)))
1002                 (sb-unix:unix-unlink name)
1003                 (when fd
1004                   (let ((newline (string #\Newline)))
1005                     (loop
1006                         (multiple-value-bind
1007                               (line no-cr)
1008                             (read-line object nil nil)
1009                           (unless line
1010                             (return))
1011                           (sb-unix:unix-write
1012                            fd
1013                            ;; FIXME: this really should be
1014                            ;; (STRING-TO-OCTETS :EXTERNAL-FORMAT ...).
1015                            ;; RUN-PROGRAM should take an
1016                            ;; external-format argument, which should
1017                            ;; be passed down to here.  Something
1018                            ;; similar should happen on :OUTPUT, too.
1019                            (map '(vector (unsigned-byte 8)) #'char-code line)
1020                            0 (length line))
1021                           (if no-cr
1022                               (return)
1023                               (sb-unix:unix-write fd newline 0 1)))))
1024                   (sb-unix:unix-lseek fd 0 sb-unix:l_set)
1025                   (push fd *close-in-parent*)
1026                   (return (values fd nil))))))
1027            (:output
1028             (multiple-value-bind (read-fd write-fd)
1029                 (sb-unix:unix-pipe)
1030               (unless read-fd
1031                 (error "couldn't create pipe: ~S" (strerror write-fd)))
1032               (copy-descriptor-to-stream read-fd object cookie)
1033               (push read-fd *close-on-error*)
1034               (push write-fd *close-in-parent*)
1035               (values write-fd nil)))))
1036         (t
1037          (error "invalid option to RUN-PROGRAM: ~S" object))))