src/code/run-program.lisp

   1 ;;;; RUN-PROGRAM and friends, a facility for running Unix programs
   2 ;;;; from inside SBCL
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB-IMPL") ;(SB-IMPL, not SB!IMPL, since we're built in warm load.)
  14 \f
  15 ;;;; hacking the Unix environment
  16 ;;;;
  17 ;;;; In the original CMU CL code that LOAD-FOREIGN is derived from, the
  18 ;;;; Unix environment (as in "man environ") was represented as an
  19 ;;;; alist from keywords to strings, so that e.g. the Unix environment
  20 ;;;;   "SHELL=/bin/bash" "HOME=/root" "PAGER=less"
  21 ;;;; was represented as
  22 ;;;;   ((:SHELL . "/bin/bash") (:HOME . "/root") (:PAGER "less"))
  23 ;;;; This had a few problems in principle: the mapping into
  24 ;;;; keyword symbols smashed the case of environment
  25 ;;;; variables, and the whole mapping depended on the presence of
  26 ;;;; #\= characters in the environment strings. In practice these
  27 ;;;; problems weren't hugely important, since conventionally environment
  28 ;;;; variables are uppercase strings followed by #\= followed by
  29 ;;;; arbitrary data. However, since it's so manifestly not The Right
  30 ;;;; Thing to make code which breaks unnecessarily on input which
  31 ;;;; doesn't follow what is, after all, only a tradition, we've switched
  32 ;;;; formats in SBCL, so that the fundamental environment list
  33 ;;;; is just a list of strings, with a one-to-one-correspondence
  34 ;;;; to the C-level representation. I.e., in the example above,
  35 ;;;; the SBCL representation is
  36 ;;;;   '("SHELL=/bin/bash" "HOME=/root" "PAGER=less")
  37 ;;;; CMU CL's implementation is currently supported to help with porting.
  38 ;;;;
  39 ;;;; It's not obvious that this code belongs here (instead of e.g. in
  40 ;;;; unix.lisp), since it has only a weak logical connection with
  41 ;;;; RUN-PROGRAM. However, physically it's convenient to put it here.
  42 ;;;; It's not needed at cold init, so we *can* put it in this
  43 ;;;; warm-loaded file. And by putting it in this warm-loaded file, we
  44 ;;;; make it easy for it to get to the C-level 'environ' variable.
  45 ;;;; which (at least in sbcl-0.6.10 on Red Hat Linux 6.2) is not
  46 ;;;; visible at GENESIS time.
  47
  48 #-win32
  49 (progn
  50   (define-alien-routine wrapped-environ (* c-string))
  51   (defun posix-environ ()
  52     "Return the Unix environment (\"man environ\") as a list of SIMPLE-STRINGs."
  53     (c-strings->string-list (wrapped-environ))))
  54
  55 ;#+win32 (sb-alien:define-alien-routine msvcrt-environ (* c-string))
  56
  57 ;;; Convert as best we can from an SBCL representation of a Unix
  58 ;;; environment to a CMU CL representation.
  59 ;;;
  60 ;;; * (UNIX-ENVIRONMENT-CMUCL-FROM-SBCL '("Bletch=fub" "Noggin" "YES=No!"))
  61 ;;; WARNING:
  62 ;;;   smashing case of "Bletch=fub" in conversion to CMU-CL-style
  63 ;;;     environment alist
  64 ;;; WARNING:
  65 ;;;   no #\= in "Noggin", eliding it in CMU-CL-style environment alist
  66 ;;; ((:BLETCH . "fub") (:YES . "No!"))
  67 (defun unix-environment-cmucl-from-sbcl (sbcl)
  68   (mapcan
  69    (lambda (string)
  70      (declare (string string))
  71      (let ((=-pos (position #\= string :test #'equal)))
  72        (if =-pos
  73            (list
  74             (let* ((key-as-string (subseq string 0 =-pos))
  75                    (key-as-upcase-string (string-upcase key-as-string))
  76                    (key (keywordicate key-as-upcase-string))
  77                    (val (subseq string (1+ =-pos))))
  78               (unless (string= key-as-string key-as-upcase-string)
  79                 (warn "smashing case of ~S in conversion to CMU-CL-style ~
  80                       environment alist"
  81                       string))
  82               (cons key val)))
  83            (warn "no #\\= in ~S, eliding it in CMU-CL-style environment alist"
  84                  string))))
  85    sbcl))
  86
  87 ;;; Convert from a CMU CL representation of a Unix environment to a
  88 ;;; SBCL representation.
  89 (defun unix-environment-sbcl-from-cmucl (cmucl)
  90   (mapcar
  91    (lambda (cons)
  92      (destructuring-bind (key . val) cons
  93        (declare (type keyword key) (string val))
  94        (concatenate 'simple-string (symbol-name key) "=" val)))
  95    cmucl))
  96 \f
  97 ;;;; Import wait3(2) from Unix.
  98
  99 #-win32
 100 (define-alien-routine ("waitpid" c-waitpid) sb-alien:int
 101   (pid sb-alien:int)
 102   (status sb-alien:int :out)
 103   (options sb-alien:int))
 104
 105 #-win32
 106 (defun waitpid (pid &optional do-not-hang check-for-stopped)
 107   #+sb-doc
 108   "Return any available status information on child process with PID."
 109   (multiple-value-bind (pid status)
 110       (c-waitpid pid
 111                  (logior (if do-not-hang
 112                              sb-unix:wnohang
 113                              0)
 114                          (if check-for-stopped
 115                              sb-unix:wuntraced
 116                              0)))
 117     (cond ((or (minusp pid)
 118                (zerop pid))
 119            nil)
 120           ((eql (ldb (byte 8 0) status)
 121                 sb-unix:wstopped)
 122            (values pid
 123                    :stopped
 124                    (ldb (byte 8 8) status)))
 125           ((zerop (ldb (byte 7 0) status))
 126            (values pid
 127                    :exited
 128                    (ldb (byte 8 8) status)))
 129           (t
 130            (let ((signal (ldb (byte 7 0) status)))
 131              (values pid
 132                      (if (position signal
 133                                    #.(vector
 134                                       sb-unix:sigstop
 135                                       sb-unix:sigtstp
 136                                       sb-unix:sigttin
 137                                       sb-unix:sigttou))
 138                          :stopped
 139                          :signaled)
 140                      signal
 141                      (not (zerop (ldb (byte 1 7) status)))))))))
 142 \f
 143 ;;;; process control stuff
 144 (defvar *active-processes* nil
 145   #+sb-doc
 146   "List of process structures for all active processes.")
 147
 148 #-win32
 149 (defvar *active-processes-lock*
 150   (sb-thread:make-mutex :name "Lock for active processes."))
 151
 152 ;;; *ACTIVE-PROCESSES* can be accessed from multiple threads so a
 153 ;;; mutex is needed. More importantly the sigchld signal handler also
 154 ;;; accesses it, that's why we need without-interrupts.
 155 (defmacro with-active-processes-lock (() &body body)
 156   #-win32
 157   `(sb-thread::with-system-mutex (*active-processes-lock*)
 158      ,@body)
 159   #+win32
 160   `(progn ,@body))
 161
 162 (defstruct (process (:copier nil))
 163   pid                 ; PID of child process
 164   %status             ; either :RUNNING, :STOPPED, :EXITED, or :SIGNALED
 165   exit-code           ; either exit code or signal
 166   core-dumped         ; T if a core image was dumped
 167   #-win32 pty                 ; stream to child's pty, or NIL
 168   input               ; stream to child's input, or NIL
 169   output              ; stream from child's output, or NIL
 170   error               ; stream from child's error output, or NIL
 171   status-hook         ; closure to call when PROC changes status
 172   plist               ; a place for clients to stash things
 173   cookie)             ; list of the number of pipes from the subproc
 174
 175 (defmethod print-object ((process process) stream)
 176   (print-unreadable-object (process stream :type t)
 177     (let ((status (process-status process)))
 178      (if (eq :exited status)
 179          (format stream "~S ~S" status (process-exit-code process))
 180          (format stream "~S ~S" (process-pid process) status)))
 181     process))
 182
 183 #+sb-doc
 184 (setf (documentation 'process-p 'function)
 185       "T if OBJECT is a PROCESS, NIL otherwise.")
 186
 187 #+sb-doc
 188 (setf (documentation 'process-pid 'function) "The pid of the child process.")
 189
 190 #+win32
 191 (define-alien-routine ("GetExitCodeProcess@8" get-exit-code-process)
 192     int
 193   (handle unsigned) (exit-code unsigned :out))
 194
 195 (defun process-status (process)
 196   #+sb-doc
 197   "Return the current status of PROCESS.  The result is one of :RUNNING,
 198    :STOPPED, :EXITED, or :SIGNALED."
 199   (get-processes-status-changes)
 200   (process-%status process))
 201
 202 #+sb-doc
 203 (setf (documentation 'process-exit-code 'function)
 204       "The exit code or the signal of a stopped process.")
 205
 206 #+sb-doc
 207 (setf (documentation 'process-core-dumped 'function)
 208       "T if a core image was dumped by the process.")
 209
 210 #+sb-doc
 211 (setf (documentation 'process-pty 'function)
 212       "The pty stream of the process or NIL.")
 213
 214 #+sb-doc
 215 (setf (documentation 'process-input 'function)
 216       "The input stream of the process or NIL.")
 217
 218 #+sb-doc
 219 (setf (documentation 'process-output 'function)
 220       "The output stream of the process or NIL.")
 221
 222 #+sb-doc
 223 (setf (documentation 'process-error 'function)
 224       "The error stream of the process or NIL.")
 225
 226 #+sb-doc
 227 (setf (documentation 'process-status-hook  'function)
 228       "A function that is called when PROCESS changes its status.
 229 The function is called with PROCESS as its only argument.")
 230
 231 #+sb-doc
 232 (setf (documentation 'process-plist  'function)
 233       "A place for clients to stash things.")
 234
 235 (defun process-wait (process &optional check-for-stopped)
 236   #+sb-doc
 237   "Wait for PROCESS to quit running for some reason. When
 238 CHECK-FOR-STOPPED is T, also returns when PROCESS is stopped. Returns
 239 PROCESS."
 240   (loop
 241       (case (process-status process)
 242         (:running)
 243         (:stopped
 244          (when check-for-stopped
 245            (return)))
 246         (t
 247          (when (zerop (car (process-cookie process)))
 248            (return))))
 249       (sb-sys:serve-all-events 1))
 250   process)
 251
 252 #-win32
 253 ;;; Find the current foreground process group id.
 254 (defun find-current-foreground-process (proc)
 255   (with-alien ((result sb-alien:int))
 256     (multiple-value-bind
 257           (wonp error)
 258         (sb-unix:unix-ioctl (sb-sys:fd-stream-fd (process-pty proc))
 259                             sb-unix:TIOCGPGRP
 260                             (alien-sap (sb-alien:addr result)))
 261       (unless wonp
 262         (error "TIOCPGRP ioctl failed: ~S" (strerror error)))
 263       result))
 264   (process-pid proc))
 265
 266 #-win32
 267 (defun process-kill (process signal &optional (whom :pid))
 268   #+sb-doc
 269   "Hand SIGNAL to PROCESS. If WHOM is :PID, use the kill Unix system call. If
 270    WHOM is :PROCESS-GROUP, use the killpg Unix system call. If WHOM is
 271    :PTY-PROCESS-GROUP deliver the signal to whichever process group is
 272    currently in the foreground."
 273   (let ((pid (ecase whom
 274                ((:pid :process-group)
 275                 (process-pid process))
 276                (:pty-process-group
 277                 (find-current-foreground-process process)))))
 278     (multiple-value-bind
 279           (okay errno)
 280         (case whom
 281           ((:process-group)
 282            (sb-unix:unix-killpg pid signal))
 283           (t
 284            (sb-unix:unix-kill pid signal)))
 285       (cond ((not okay)
 286              (values nil errno))
 287             ((and (eql pid (process-pid process))
 288                   (= signal sb-unix:sigcont))
 289              (setf (process-%status process) :running)
 290              (setf (process-exit-code process) nil)
 291              (when (process-status-hook process)
 292                (funcall (process-status-hook process) process))
 293              t)
 294             (t
 295              t)))))
 296
 297 (defun process-alive-p (process)
 298   #+sb-doc
 299   "Return T if PROCESS is still alive, NIL otherwise."
 300   (let ((status (process-status process)))
 301     (if (or (eq status :running)
 302             (eq status :stopped))
 303         t
 304         nil)))
 305
 306 (defun process-close (process)
 307   #+sb-doc
 308   "Close all streams connected to PROCESS and stop maintaining the
 309 status slot."
 310   (macrolet ((frob (stream abort)
 311                `(when ,stream (close ,stream :abort ,abort))))
 312     #-win32
 313     (frob (process-pty process) t)   ; Don't FLUSH-OUTPUT to dead process,
 314     (frob (process-input process) t) ; .. 'cause it will generate SIGPIPE.
 315     (frob (process-output process) nil)
 316     (frob (process-error process) nil))
 317   ;; FIXME: Given that the status-slot is no longer updated,
 318   ;; maybe it should be set to :CLOSED, or similar?
 319   (with-active-processes-lock ()
 320    (setf *active-processes* (delete process *active-processes*)))
 321   process)
 322
 323 (defun get-processes-status-changes ()
 324   (let (exited)
 325     (with-active-processes-lock ()
 326       (setf *active-processes*
 327             (delete-if #-win32
 328                        (lambda (proc)
 329                          ;; Wait only on pids belonging to processes
 330                          ;; started by RUN-PROGRAM. There used to be a
 331                          ;; WAIT3 call here, but that makes direct
 332                          ;; WAIT, WAITPID usage impossible due to the
 333                          ;; race with the SIGCHLD signal handler.
 334                          (multiple-value-bind (pid what code core)
 335                              (waitpid (process-pid proc) t t)
 336                            (when pid
 337                              (setf (process-%status proc) what)
 338                              (setf (process-exit-code proc) code)
 339                              (setf (process-core-dumped proc) core)
 340                              (when (process-status-hook proc)
 341                                (push proc exited))
 342                              t)))
 343                        #+win32
 344                        (lambda (proc)
 345                          (multiple-value-bind (ok code)
 346                              (get-exit-code-process (process-pid proc))
 347                            (when (and (plusp ok) (/= code 259))
 348                              (setf (process-%status proc) :exited
 349                                    (process-exit-code proc) code)
 350                              (when (process-status-hook proc)
 351                                (push proc exited))
 352                              t)))
 353                        *active-processes*)))
 354     ;; Can't call the hooks before all the processes have been deal
 355     ;; with, as calling a hook may cause re-entry to
 356     ;; GET-PROCESS-STATUS-CHANGES. That may be OK when using waitpid,
 357     ;; but in the Windows implementation it would be deeply bad.
 358     (dolist (proc exited)
 359       (let ((hook (process-status-hook proc)))
 360         (when hook
 361           (funcall hook proc))))))
 362 \f
 363 ;;;; RUN-PROGRAM and close friends
 364
 365 ;;; list of file descriptors to close when RUN-PROGRAM exits due to an error
 366 (defvar *close-on-error* nil)
 367
 368 ;;; list of file descriptors to close when RUN-PROGRAM returns in the parent
 369 (defvar *close-in-parent* nil)
 370
 371 ;;; list of handlers installed by RUN-PROGRAM.  FIXME: nothing seems
 372 ;;; to set this.
 373 #-win32
 374 (defvar *handlers-installed* nil)
 375
 376 ;;; Find an unused pty. Return three values: the file descriptor for
 377 ;;; the master side of the pty, the file descriptor for the slave side
 378 ;;; of the pty, and the name of the tty device for the slave side.
 379 #-(or win32 openbsd)
 380 (progn
 381   (define-alien-routine ptsname c-string (fd int))
 382   (define-alien-routine grantpt boolean (fd int))
 383   (define-alien-routine unlockpt boolean (fd int))
 384
 385   (defun find-a-pty ()
 386     ;; First try to use the Unix98 pty api.
 387     (let* ((master-name (coerce (format nil "/dev/ptmx") 'base-string))
 388            (master-fd (sb-unix:unix-open master-name
 389                                          sb-unix:o_rdwr
 390                                          #o666)))
 391       (when master-fd
 392         (grantpt master-fd)
 393         (unlockpt master-fd)
 394         (let* ((slave-name (ptsname master-fd))
 395                (slave-fd (sb-unix:unix-open slave-name
 396                                             sb-unix:o_rdwr
 397                                             #o666)))
 398           (when slave-fd
 399             (return-from find-a-pty
 400               (values master-fd
 401                       slave-fd
 402                       slave-name)))
 403           (sb-unix:unix-close master-fd))
 404         (error "could not find a pty")))
 405     ;; No dice, try using the old-school method.
 406     (dolist (char '(#\p #\q))
 407       (dotimes (digit 16)
 408         (let* ((master-name (coerce (format nil "/dev/pty~C~X" char digit)
 409                                     'base-string))
 410                (master-fd (sb-unix:unix-open master-name
 411                                              sb-unix:o_rdwr
 412                                              #o666)))
 413           (when master-fd
 414             (let* ((slave-name (coerce (format nil "/dev/tty~C~X" char digit)
 415                                        'base-string))
 416                    (slave-fd (sb-unix:unix-open slave-name
 417                                                 sb-unix:o_rdwr
 418                                                 #o666)))
 419               (when slave-fd
 420                 (return-from find-a-pty
 421                   (values master-fd
 422                           slave-fd
 423                           slave-name)))
 424               (sb-unix:unix-close master-fd))))))
 425     (error "could not find a pty")))
 426 #+openbsd
 427 (progn
 428   (define-alien-routine openpty int (amaster int :out) (aslave int :out)
 429                         (name (* char)) (termp (* t)) (winp (* t)))
 430   (defun find-a-pty ()
 431     (with-alien ((name-buf (array char 16)))
 432       (multiple-value-bind (return-val master-fd slave-fd)
 433           (openpty (cast name-buf (* char)) nil nil)
 434         (if (zerop return-val)
 435             (values master-fd
 436                     slave-fd
 437                     (sb-alien::c-string-to-string (alien-sap name-buf)
 438                                                   (sb-impl::default-external-format)
 439                                                   'character))
 440             (error "could not find a pty"))))))
 441
 442 #-win32
 443 (defun open-pty (pty cookie &key (external-format :default))
 444   (when pty
 445     (multiple-value-bind
 446           (master slave name)
 447         (find-a-pty)
 448       (push master *close-on-error*)
 449       (push slave *close-in-parent*)
 450       (when (streamp pty)
 451         (multiple-value-bind (new-fd errno) (sb-unix:unix-dup master)
 452           (unless new-fd
 453             (error "couldn't SB-UNIX:UNIX-DUP ~W: ~A" master (strerror errno)))
 454           (push new-fd *close-on-error*)
 455           (copy-descriptor-to-stream new-fd pty cookie external-format)))
 456       (values name
 457               (sb-sys:make-fd-stream master :input t :output t
 458                                      :element-type :default
 459                                      :dual-channel-p t)))))
 460
 461 (defmacro round-bytes-to-words (n)
 462   (let ((bytes-per-word (/ sb-vm:n-machine-word-bits sb-vm:n-byte-bits)))
 463     `(logandc2 (the fixnum (+ (the fixnum ,n)
 464                               (1- ,bytes-per-word))) (1- ,bytes-per-word))))
 465
 466 (defun string-list-to-c-strvec (string-list)
 467   (let* ((bytes-per-word (/ sb-vm:n-machine-word-bits sb-vm:n-byte-bits))
 468          ;; We need an extra for the null, and an extra 'cause exect
 469          ;; clobbers argv[-1].
 470          (vec-bytes (* bytes-per-word (+ (length string-list) 2)))
 471          (octet-vector-list (mapcar (lambda (s)
 472                                       (string-to-octets s :null-terminate t))
 473                                     string-list))
 474          (string-bytes (reduce #'+ octet-vector-list
 475                                :key (lambda (s)
 476                                       (round-bytes-to-words (length s)))))
 477          (total-bytes (+ string-bytes vec-bytes))
 478          ;; Memory to hold the vector of pointers and all the strings.
 479          (vec-sap (sb-sys:allocate-system-memory total-bytes))
 480          (string-sap (sap+ vec-sap vec-bytes))
 481          ;; Index starts from [1]!
 482          (vec-index-offset bytes-per-word))
 483     (declare (index string-bytes vec-bytes total-bytes)
 484              (sb-sys:system-area-pointer vec-sap string-sap))
 485     (dolist (octets octet-vector-list)
 486       (declare (type (simple-array (unsigned-byte 8) (*)) octets))
 487       (let ((size (length octets)))
 488         ;; Copy string.
 489         (sb-kernel:copy-ub8-to-system-area octets 0 string-sap 0 size)
 490         ;; Put the pointer in the vector.
 491         (setf (sap-ref-sap vec-sap vec-index-offset) string-sap)
 492         ;; Advance string-sap for the next string.
 493         (setf string-sap (sap+ string-sap (round-bytes-to-words size)))
 494         (incf vec-index-offset bytes-per-word)))
 495     ;; Final null pointer.
 496     (setf (sap-ref-sap vec-sap vec-index-offset) (int-sap 0))
 497     (values vec-sap (sap+ vec-sap bytes-per-word) total-bytes)))
 498
 499 (defmacro with-c-strvec ((var str-list) &body body)
 500   (with-unique-names (sap size)
 501     `(multiple-value-bind (,sap ,var ,size)
 502          (string-list-to-c-strvec ,str-list)
 503        (unwind-protect
 504             (progn
 505               ,@body)
 506          (sb-sys:deallocate-system-memory ,sap ,size)))))
 507
 508 (sb-alien:define-alien-routine spawn
 509     #-win32 sb-alien:int
 510     #+win32 sb-win32::handle
 511   (program sb-alien:c-string)
 512   (argv (* sb-alien:c-string))
 513   (stdin sb-alien:int)
 514   (stdout sb-alien:int)
 515   (stderr sb-alien:int)
 516   (search sb-alien:int)
 517   (envp (* sb-alien:c-string))
 518   (pty-name sb-alien:c-string)
 519   (wait sb-alien:int))
 520
 521 ;;; FIXME: There shouldn't be two semiredundant versions of the
 522 ;;; documentation. Since this is a public extension function, the
 523 ;;; documentation should be in the doc string. So all information from
 524 ;;; this comment should be merged into the doc string, and then this
 525 ;;; comment can go away.
 526 ;;;
 527 ;;; RUN-PROGRAM uses fork() and execve() to run a different program.
 528 ;;; Strange stuff happens to keep the Unix state of the world
 529 ;;; coherent.
 530 ;;;
 531 ;;; The child process needs to get its input from somewhere, and send
 532 ;;; its output (both standard and error) to somewhere. We have to do
 533 ;;; different things depending on where these somewheres really are.
 534 ;;;
 535 ;;; For input, there are five options:
 536 ;;;  -- T: Just leave fd 0 alone. Pretty simple.
 537 ;;;  -- "file": Read from the file. We need to open the file and
 538 ;;;     pull the descriptor out of the stream. The parent should close
 539 ;;;     this stream after the child is up and running to free any
 540 ;;;     storage used in the parent.
 541 ;;;  -- NIL: Same as "file", but use "/dev/null" as the file.
 542 ;;;  -- :STREAM: Use Unix pipe() to create two descriptors. Use
 543 ;;;     SB-SYS:MAKE-FD-STREAM to create the output stream on the
 544 ;;;     writeable descriptor, and pass the readable descriptor to
 545 ;;;     the child. The parent must close the readable descriptor for
 546 ;;;     EOF to be passed up correctly.
 547 ;;;  -- a stream: If it's a fd-stream, just pull the descriptor out
 548 ;;;     of it. Otherwise make a pipe as in :STREAM, and copy
 549 ;;;     everything across.
 550 ;;;
 551 ;;; For output, there are five options:
 552 ;;;  -- T: Leave descriptor 1 alone.
 553 ;;;  -- "file": dump output to the file.
 554 ;;;  -- NIL: dump output to /dev/null.
 555 ;;;  -- :STREAM: return a stream that can be read from.
 556 ;;;  -- a stream: if it's a fd-stream, use the descriptor in it.
 557 ;;;     Otherwise, copy stuff from output to stream.
 558 ;;;
 559 ;;; For error, there are all the same options as output plus:
 560 ;;;  -- :OUTPUT: redirect to the same place as output.
 561 ;;;
 562 ;;; RUN-PROGRAM returns a PROCESS structure for the process if
 563 ;;; the fork worked, and NIL if it did not.
 564 (defun run-program (program args
 565                     &key
 566                     #-win32 (env nil env-p)
 567                     #-win32 (environment
 568                              (if env-p
 569                                  (unix-environment-sbcl-from-cmucl env)
 570                                  (posix-environ))
 571                              environment-p)
 572                     (wait t)
 573                     search
 574                     #-win32 pty
 575                     input
 576                     if-input-does-not-exist
 577                     output
 578                     (if-output-exists :error)
 579                     (error :output)
 580                     (if-error-exists :error)
 581                     status-hook
 582                     (external-format :default))
 583   #+sb-doc
 584   #.(concatenate
 585      'string
 586      ;; The Texinfoizer is sensitive to whitespace, so mind the
 587      ;; placement of the #-win32 pseudosplicings.
 588      "RUN-PROGRAM creates a new process specified by the PROGRAM
 589 argument. ARGS are the standard arguments that can be passed to a
 590 program. For no arguments, use NIL (which means that just the
 591 name of the program is passed as arg 0).
 592
 593 The program arguments and the environment are encoded using the
 594 default external format for streams.
 595
 596 RUN-PROGRAM will return a PROCESS structure. See the CMU Common Lisp
 597 Users Manual for details about the PROCESS structure."#-win32"
 598
 599    Notes about Unix environments (as in the :ENVIRONMENT and :ENV args):
 600
 601    - The SBCL implementation of RUN-PROGRAM, like Perl and many other
 602      programs, but unlike the original CMU CL implementation, copies
 603      the Unix environment by default.
 604
 605    - Running Unix programs from a setuid process, or in any other
 606      situation where the Unix environment is under the control of someone
 607      else, is a mother lode of security problems. If you are contemplating
 608      doing this, read about it first. (The Perl community has a lot of good
 609      documentation about this and other security issues in script-like
 610      programs.)""
 611
 612    The &KEY arguments have the following meanings:
 613 "#-win32"
 614    :ENVIRONMENT
 615       a list of STRINGs describing the new Unix environment
 616       (as in \"man environ\"). The default is to copy the environment of
 617       the current process.
 618    :ENV
 619       an alternative lossy representation of the new Unix environment,
 620       for compatibility with CMU CL""
 621    :SEARCH
 622       Look for PROGRAM in each of the directories in the child's $PATH
 623       environment variable.  Otherwise an absolute pathname is required.
 624    :WAIT
 625       If non-NIL (default), wait until the created process finishes.  If
 626       NIL, continue running Lisp until the program finishes."#-win32"
 627    :PTY
 628       Either T, NIL, or a stream.  Unless NIL, the subprocess is established
 629       under a PTY.  If :pty is a stream, all output to this pty is sent to
 630       this stream, otherwise the PROCESS-PTY slot is filled in with a stream
 631       connected to pty that can read output and write input.""
 632    :INPUT
 633       Either T, NIL, a pathname, a stream, or :STREAM.  If T, the standard
 634       input for the current process is inherited.  If NIL, "
 635       #-win32"/dev/null"#+win32"nul""
 636       is used.  If a pathname, the file so specified is used.  If a stream,
 637       all the input is read from that stream and sent to the subprocess.  If
 638       :STREAM, the PROCESS-INPUT slot is filled in with a stream that sends
 639       its output to the process. Defaults to NIL.
 640    :IF-INPUT-DOES-NOT-EXIST (when :INPUT is the name of a file)
 641       can be one of:
 642          :ERROR to generate an error
 643          :CREATE to create an empty file
 644          NIL (the default) to return NIL from RUN-PROGRAM
 645    :OUTPUT
 646       Either T, NIL, a pathname, a stream, or :STREAM.  If T, the standard
 647       output for the current process is inherited.  If NIL, "
 648       #-win32"/dev/null"#+win32"nul""
 649       is used.  If a pathname, the file so specified is used.  If a stream,
 650       all the output from the process is written to this stream. If
 651       :STREAM, the PROCESS-OUTPUT slot is filled in with a stream that can
 652       be read to get the output. Defaults to NIL.
 653    :IF-OUTPUT-EXISTS (when :OUTPUT is the name of a file)
 654       can be one of:
 655          :ERROR (the default) to generate an error
 656          :SUPERSEDE to supersede the file with output from the program
 657          :APPEND to append output from the program to the file
 658          NIL to return NIL from RUN-PROGRAM, without doing anything
 659    :ERROR and :IF-ERROR-EXISTS
 660       Same as :OUTPUT and :IF-OUTPUT-EXISTS, except that :ERROR can also be
 661       specified as :OUTPUT in which case all error output is routed to the
 662       same place as normal output.
 663    :STATUS-HOOK
 664       This is a function the system calls whenever the status of the
 665       process changes.  The function takes the process as an argument.
 666    :EXTERNAL-FORMAT
 667       The external-format to use for :INPUT, :OUTPUT, and :ERROR :STREAMs.")
 668   #-win32
 669   (when (and env-p environment-p)
 670     (error "can't specify :ENV and :ENVIRONMENT simultaneously"))
 671   ;; Prepend the program to the argument list.
 672   (push (namestring program) args)
 673   (labels (;; It's friendly to allow the caller to pass any string
 674            ;; designator, but internally we'd like SIMPLE-STRINGs.
 675            ;;
 676            ;; Huh?  We let users pass in symbols and characters for
 677            ;; the arguments, but call NAMESTRING on the program
 678            ;; name... -- RMK
 679            (simplify-args (args)
 680              (loop for arg in args
 681                    as escaped-arg = (escape-arg arg)
 682                    collect (coerce escaped-arg 'simple-string)))
 683            (escape-arg (arg)
 684              #-win32 arg
 685              ;; Apparently any spaces or double quotes in the arguments
 686              ;; need to be escaped on win32.
 687              #+win32 (if (position-if
 688                           (lambda (c) (find c '(#\" #\Space))) arg)
 689                          (write-to-string arg)
 690                          arg)))
 691     (let (;; Clear various specials used by GET-DESCRIPTOR-FOR to
 692           ;; communicate cleanup info.
 693           *close-on-error*
 694           *close-in-parent*
 695           ;; Some other binding used only on non-Win32.  FIXME:
 696           ;; nothing seems to set this.
 697           #-win32 *handlers-installed*
 698           ;; Establish PROC at this level so that we can return it.
 699           proc
 700           (simple-args (simplify-args args))
 701           (progname (native-namestring program))
 702           ;; Gag.
 703           (cookie (list 0)))
 704       (unwind-protect
 705            ;; Note: despite the WITH-* names, these macros don't
 706            ;; expand into UNWIND-PROTECT forms.  They're just
 707            ;; syntactic sugar to make the rest of the routine slightly
 708            ;; easier to read.
 709            (macrolet ((with-fd-and-stream-for (((fd stream) which &rest args)
 710                                                &body body)
 711                         `(multiple-value-bind (,fd ,stream)
 712                              ,(ecase which
 713                                 ((:input :output)
 714                                  `(get-descriptor-for ,@args))
 715                                 (:error
 716                                  `(if (eq ,(first args) :output)
 717                                       ;; kludge: we expand into
 718                                       ;; hard-coded symbols here.
 719                                       (values stdout output-stream)
 720                                       (get-descriptor-for ,@args))))
 721                            ,@body))
 722                       (with-open-pty (((pty-name pty-stream) (pty cookie))
 723                                       &body body)
 724                         #+win32 `(declare (ignore ,pty ,cookie))
 725                         #+win32 `(let (,pty-name ,pty-stream) ,@body)
 726                         #-win32 `(multiple-value-bind (,pty-name ,pty-stream)
 727                                      (open-pty ,pty ,cookie)
 728                                    ,@body))
 729                       (with-args-vec ((vec args) &body body)
 730                         `(with-c-strvec (,vec ,args)
 731                            ,@body))
 732                       (with-environment-vec ((vec env) &body body)
 733                         #+win32 `(let (,vec) ,@body)
 734                         #-win32 `(with-c-strvec (,vec ,env) ,@body)))
 735              (with-fd-and-stream-for ((stdin input-stream) :input
 736                                       input cookie
 737                                       :direction :input
 738                                       :if-does-not-exist if-input-does-not-exist
 739                                       :external-format external-format
 740                                       :wait wait)
 741                (with-fd-and-stream-for ((stdout output-stream) :output
 742                                         output cookie
 743                                         :direction :output
 744                                         :if-exists if-output-exists
 745                                         :external-format external-format)
 746                  (with-fd-and-stream-for ((stderr error-stream)  :error
 747                                           error cookie
 748                                           :direction :output
 749                                           :if-exists if-error-exists
 750                                           :external-format external-format)
 751                    (with-open-pty ((pty-name pty-stream) (pty cookie))
 752                      ;; Make sure we are not notified about the child
 753                      ;; death before we have installed the PROCESS
 754                      ;; structure in *ACTIVE-PROCESSES*.
 755                      (let (child)
 756                        (with-active-processes-lock ()
 757                          (with-args-vec (args-vec simple-args)
 758                            (with-environment-vec (environment-vec environment)
 759                              (setq child (without-gcing
 760                                            (spawn progname args-vec
 761                                                   stdin stdout stderr
 762                                                   (if search 1 0)
 763                                                   environment-vec pty-name
 764                                                   (if wait 1 0))))
 765                              (unless (= child -1)
 766                                (setf proc
 767                                      (apply
 768                                       #'make-process
 769                                       :pid child
 770                                       :input input-stream
 771                                       :output output-stream
 772                                       :error error-stream
 773                                       :status-hook status-hook
 774                                       :cookie cookie
 775                                       #-win32 (list :pty pty-stream
 776                                                     :%status :running)
 777                                       #+win32 (if wait
 778                                                   (list :%status :exited
 779                                                         :exit-code child)
 780                                                   (list :%status :running))))
 781                                (push proc *active-processes*)))))
 782                        ;; Report the error outside the lock.
 783                        (when (= child -1)
 784                          (error "couldn't fork child process: ~A"
 785                                 (strerror)))))))))
 786         (dolist (fd *close-in-parent*)
 787           (sb-unix:unix-close fd))
 788         (unless proc
 789           (dolist (fd *close-on-error*)
 790             (sb-unix:unix-close fd))
 791           ;; FIXME: nothing seems to set this.
 792           #-win32
 793           (dolist (handler *handlers-installed*)
 794             (sb-sys:remove-fd-handler handler))))
 795       #-win32
 796       (when (and wait proc)
 797         (process-wait proc))
 798       proc)))
 799
 800 ;;; Install a handler for any input that shows up on the file
 801 ;;; descriptor. The handler reads the data and writes it to the
 802 ;;; stream.
 803 (defun copy-descriptor-to-stream (descriptor stream cookie external-format)
 804   (incf (car cookie))
 805   (let* ((handler nil)
 806          (buf (make-array 256 :element-type '(unsigned-byte 8)))
 807          (read-end 0)
 808          (et (stream-element-type stream))
 809          (copy-fun
 810           (cond
 811             ((member et '(character base-char))
 812              (lambda ()
 813                (let* ((decode-end read-end)
 814                       (string (handler-case
 815                                   (octets-to-string
 816                                    buf :end read-end
 817                                    :external-format external-format)
 818                                 (end-of-input-in-character (e)
 819                                   (setf decode-end
 820                                         (octet-decoding-error-start e))
 821                                   (octets-to-string
 822                                    buf :end decode-end
 823                                    :external-format external-format)))))
 824                  (unless (zerop (length string))
 825                    (write-string string stream)
 826                    (when (/= decode-end (length buf))
 827                      (replace buf buf :start2 decode-end :end2 read-end))
 828                    (decf read-end decode-end)))))
 829             ((member et '(:default (unsigned-byte 8)) :test #'equal)
 830              (lambda ()
 831                (write-sequence buf stream :end read-end)
 832                (setf read-end 0)))
 833             (t
 834              ;; FIXME.
 835              (error "Don't know how to copy to stream of element-type ~S"
 836                     et)))))
 837     (setf handler
 838           (sb-sys:add-fd-handler
 839            descriptor
 840            :input
 841            (lambda (fd)
 842              (declare (ignore fd))
 843              (loop
 844                 (unless handler
 845                   (return))
 846                 (multiple-value-bind
 847                       (result readable/errno)
 848                     (sb-unix:unix-select (1+ descriptor)
 849                                          (ash 1 descriptor)
 850                                          0 0 0)
 851                   (cond ((null result)
 852                          (if (eql sb-unix:eintr readable/errno)
 853                              (return)
 854                              (error "~@<Couldn't select on sub-process: ~
 855                                         ~2I~_~A~:>"
 856                                     (strerror readable/errno))))
 857                         ((zerop result)
 858                          (return))))
 859                 (multiple-value-bind (count errno)
 860                     (with-pinned-objects (buf)
 861                       (sb-unix:unix-read descriptor
 862                                          (sap+ (vector-sap buf) read-end)
 863                                          (- (length buf) read-end)))
 864                   (cond
 865                     ((and #-win32 (or (and (null count)
 866                                            (eql errno sb-unix:eio))
 867                                       (eql count 0))
 868                           #+win32 (<= count 0))
 869                      (sb-sys:remove-fd-handler handler)
 870                      (setf handler nil)
 871                      (decf (car cookie))
 872                      (sb-unix:unix-close descriptor)
 873                      (unless (zerop read-end)
 874                        ;; Should this be an END-OF-FILE?
 875                        (error "~@<non-empty buffer when EOF reached ~
 876                                while reading from child: ~S~:>" buf))
 877                      (return))
 878                     ((null count)
 879                      (sb-sys:remove-fd-handler handler)
 880                      (setf handler nil)
 881                      (decf (car cookie))
 882                      (error
 883                       "~@<couldn't read input from sub-process: ~
 884                                      ~2I~_~A~:>"
 885                       (strerror errno)))
 886                     (t
 887                      (incf read-end count)
 888                      (funcall copy-fun))))))))))
 889
 890 ;;; FIXME: something very like this is done in SB-POSIX to treat
 891 ;;; streams as file descriptor designators; maybe we can combine these
 892 ;;; two?  Additionally, as we have a couple of user-defined streams
 893 ;;; libraries, maybe we should have a generic function for doing this,
 894 ;;; so user-defined streams can play nicely with RUN-PROGRAM (and
 895 ;;; maybe also with SB-POSIX)?
 896 (defun get-stream-fd-and-external-format (stream direction)
 897   (typecase stream
 898     (sb-sys:fd-stream
 899      (values (sb-sys:fd-stream-fd stream) nil (stream-external-format stream)))
 900     (synonym-stream
 901      (get-stream-fd-and-external-format
 902       (symbol-value (synonym-stream-symbol stream)) direction))
 903     (two-way-stream
 904      (ecase direction
 905        (:input
 906         (get-stream-fd-and-external-format
 907          (two-way-stream-input-stream stream) direction))
 908        (:output
 909         (get-stream-fd-and-external-format
 910          (two-way-stream-output-stream stream) direction))))))
 911
 912 \f
 913 ;;; Find a file descriptor to use for object given the direction.
 914 ;;; Returns the descriptor. If object is :STREAM, returns the created
 915 ;;; stream as the second value.
 916 (defun get-descriptor-for (object
 917                            cookie
 918                            &rest keys
 919                            &key direction (external-format :default) wait
 920                            &allow-other-keys)
 921   (declare (ignore wait)) ;This is explained below.
 922   ;; Our use of a temporary file dates back to very old CMUCLs, and
 923   ;; was probably only ever intended for use with STRING-STREAMs,
 924   ;; which are ordinarily smallish.  However, as we've got
 925   ;; user-defined stream classes, we can end up trying to copy
 926   ;; arbitrarily much data into the temp file, and so are liable to
 927   ;; run afoul of disk quotas or to choke on small /tmp file systems.
 928   (flet ((make-temp-fd ()
 929            (multiple-value-bind (fd name/errno)
 930                (sb-unix:sb-mkstemp "/tmp/.run-program-XXXXXX" #o0600)
 931              (unless fd
 932                (error "could not open a temporary file: ~A"
 933                       (strerror name/errno)))
 934              (unless (sb-unix:unix-unlink name/errno)
 935                (sb-unix:unix-close fd)
 936                (error "failed to unlink ~A" name/errno))
 937              fd)))
 938     (cond ((eq object t)
 939            ;; No new descriptor is needed.
 940            (values -1 nil))
 941           ((eq object nil)
 942            ;; Use /dev/null.
 943            (multiple-value-bind
 944                  (fd errno)
 945                (sb-unix:unix-open #-win32 #.(coerce "/dev/null" 'base-string)
 946                                   #+win32 #.(coerce "nul" 'base-string)
 947                                   (case direction
 948                                     (:input sb-unix:o_rdonly)
 949                                     (:output sb-unix:o_wronly)
 950                                     (t sb-unix:o_rdwr))
 951                                   #o666)
 952              (unless fd
 953                (error #-win32 "~@<couldn't open \"/dev/null\": ~2I~_~A~:>"
 954                       #+win32 "~@<couldn't open \"nul\" device: ~2I~_~A~:>"
 955                       (strerror errno)))
 956              (push fd *close-in-parent*)
 957              (values fd nil)))
 958           ((eq object :stream)
 959            (multiple-value-bind (read-fd write-fd) (sb-unix:unix-pipe)
 960              (unless read-fd
 961                (error "couldn't create pipe: ~A" (strerror write-fd)))
 962              (case direction
 963                (:input
 964                 (push read-fd *close-in-parent*)
 965                 (push write-fd *close-on-error*)
 966                 (let ((stream (sb-sys:make-fd-stream write-fd :output t
 967                                                      :element-type :default
 968                                                      :external-format
 969                                                      external-format)))
 970                   (values read-fd stream)))
 971                (:output
 972                 (push read-fd *close-on-error*)
 973                 (push write-fd *close-in-parent*)
 974                 (let ((stream (sb-sys:make-fd-stream read-fd :input t
 975                                                      :element-type :default
 976                                                      :external-format
 977                                                      external-format)))
 978                   (values write-fd stream)))
 979                (t
 980                 (sb-unix:unix-close read-fd)
 981                 (sb-unix:unix-close write-fd)
 982                 (error "Direction must be either :INPUT or :OUTPUT, not ~S."
 983                        direction)))))
 984           ((or (pathnamep object) (stringp object))
 985            ;; GET-DESCRIPTOR-FOR uses &allow-other-keys, so rather
 986            ;; than munge the &rest list for OPEN, just disable keyword
 987            ;; validation there.
 988            (with-open-stream (file (apply #'open object :allow-other-keys t
 989                                           keys))
 990              (multiple-value-bind
 991                    (fd errno)
 992                  (sb-unix:unix-dup (sb-sys:fd-stream-fd file))
 993                (cond (fd
 994                       (push fd *close-in-parent*)
 995                       (values fd nil))
 996                      (t
 997                       (error "couldn't duplicate file descriptor: ~A"
 998                              (strerror errno)))))))
 999           ((streamp object)
1000            (ecase direction
1001              (:input
1002               (block nil
1003                 ;; If we can get an fd for the stream, let the child
1004                 ;; process use the fd for its descriptor.  Otherwise,
1005                 ;; we copy data from the stream into a temp file, and
1006                 ;; give the temp file's descriptor to the
1007                 ;; child.
1008                 (multiple-value-bind (fd stream format)
1009                     (get-stream-fd-and-external-format object :input)
1010                   (declare (ignore format))
1011                   (when fd
1012                     (return (values fd stream))))
1013                 ;; FIXME: if we can't get the file descriptor, since
1014                 ;; the stream might be interactive or otherwise
1015                 ;; block-y, we can't know whether we can copy the
1016                 ;; stream's data to a temp file, so if RUN-PROGRAM was
1017                 ;; called with :WAIT NIL, we should probably error.
1018                 ;; However, STRING-STREAMs aren't fd-streams, but
1019                 ;; they're not prone to blocking; any user-defined
1020                 ;; streams that "read" from some in-memory data will
1021                 ;; probably be similar to STRING-STREAMs.  So maybe we
1022                 ;; should add a STREAM-INTERACTIVE-P generic function
1023                 ;; for problems like this?  Anyway, the machinery is
1024                 ;; here, if you feel like filling in the details.
1025                 #|
1026                 (when (and (null wait) #<some undetermined criterion>)
1027                   (error "~@<don't know how to get an fd for ~A, and so ~
1028                              can't ensure that copying its data to the ~
1029                              child process won't hang~:>" object))
1030                 |#
1031                 (let ((fd (make-temp-fd))
1032                       (et (stream-element-type object)))
1033                   (cond ((member et '(character base-char))
1034                          (loop
1035                            (multiple-value-bind
1036                                  (line no-cr)
1037                                (read-line object nil nil)
1038                              (unless line
1039                                (return))
1040                              (let ((vector (string-to-octets
1041                                             line
1042                                             :external-format external-format)))
1043                                (sb-unix:unix-write
1044                                 fd vector 0 (length vector)))
1045                              (if no-cr
1046                                (return)
1047                                (sb-unix:unix-write
1048                                 fd #.(string #\Newline) 0 1)))))
1049                         ((member et '(:default (unsigned-byte 8))
1050                                  :test 'equal)
1051                          (loop with buf = (make-array 256 :element-type '(unsigned-byte 8))
1052                                for p = (read-sequence buf object)
1053                                until (zerop p)
1054                                do (sb-unix:unix-write fd buf 0 p))))
1055                   (sb-unix:unix-lseek fd 0 sb-unix:l_set)
1056                   (push fd *close-in-parent*)
1057                   (return (values fd nil)))))
1058              (:output
1059               (block nil
1060                 ;; Similar to the :input trick above, except we
1061                 ;; arrange to copy data from the stream.  This is
1062                 ;; slightly saner than the input case, since we don't
1063                 ;; buffer to a file, but I think we may still lose if
1064                 ;; there's unflushed data in the stream buffer and we
1065                 ;; give the file descriptor to the child.
1066                 (multiple-value-bind (fd stream format)
1067                     (get-stream-fd-and-external-format object :output)
1068                   (declare (ignore format))
1069                   (when fd
1070                     (return (values fd stream))))
1071                 (multiple-value-bind (read-fd write-fd)
1072                     (sb-unix:unix-pipe)
1073                   (unless read-fd
1074                     (error "couldn't create pipe: ~S" (strerror write-fd)))
1075                   (copy-descriptor-to-stream read-fd object cookie
1076                                              external-format)
1077                   (push read-fd *close-on-error*)
1078                   (push write-fd *close-in-parent*)
1079                   (return (values write-fd nil)))))))
1080           (t
1081            (error "invalid option to RUN-PROGRAM: ~S" object)))))