src/code/run-program.lisp

   1 ;;;; RUN-PROGRAM and friends, a facility for running Unix programs
   2 ;;;; from inside SBCL
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB-IMPL") ;(SB-IMPL, not SB!IMPL, since we're built in warm load.)
  14 \f
  15 ;;;; hacking the Unix environment
  16 ;;;;
  17 ;;;; In the original CMU CL code that LOAD-FOREIGN is derived from, the
  18 ;;;; Unix environment (as in "man environ") was represented as an
  19 ;;;; alist from keywords to strings, so that e.g. the Unix environment
  20 ;;;;   "SHELL=/bin/bash" "HOME=/root" "PAGER=less"
  21 ;;;; was represented as
  22 ;;;;   ((:SHELL . "/bin/bash") (:HOME . "/root") (:PAGER "less"))
  23 ;;;; This had a few problems in principle: the mapping into
  24 ;;;; keyword symbols smashed the case of environment
  25 ;;;; variables, and the whole mapping depended on the presence of
  26 ;;;; #\= characters in the environment strings. In practice these
  27 ;;;; problems weren't hugely important, since conventionally environment
  28 ;;;; variables are uppercase strings followed by #\= followed by
  29 ;;;; arbitrary data. However, since it's so manifestly not The Right
  30 ;;;; Thing to make code which breaks unnecessarily on input which
  31 ;;;; doesn't follow what is, after all, only a tradition, we've switched
  32 ;;;; formats in SBCL, so that the fundamental environment list
  33 ;;;; is just a list of strings, with a one-to-one-correspondence
  34 ;;;; to the C-level representation. I.e., in the example above,
  35 ;;;; the SBCL representation is
  36 ;;;;   '("SHELL=/bin/bash" "HOME=/root" "PAGER=less")
  37 ;;;; CMU CL's implementation is currently supported to help with porting.
  38 ;;;;
  39 ;;;; It's not obvious that this code belongs here (instead of e.g. in
  40 ;;;; unix.lisp), since it has only a weak logical connection with
  41 ;;;; RUN-PROGRAM. However, physically it's convenient to put it here.
  42 ;;;; It's not needed at cold init, so we *can* put it in this
  43 ;;;; warm-loaded file. And by putting it in this warm-loaded file, we
  44 ;;;; make it easy for it to get to the C-level 'environ' variable.
  45 ;;;; which (at least in sbcl-0.6.10 on Red Hat Linux 6.2) is not
  46 ;;;; visible at GENESIS time.
  47
  48 #-win32
  49 (progn
  50   (define-alien-routine wrapped-environ (* c-string))
  51   (defun posix-environ ()
  52     "Return the Unix environment (\"man environ\") as a list of SIMPLE-STRINGs."
  53     (c-strings->string-list (wrapped-environ))))
  54
  55 ;#+win32 (sb-alien:define-alien-routine msvcrt-environ (* c-string))
  56
  57 ;;; Convert as best we can from an SBCL representation of a Unix
  58 ;;; environment to a CMU CL representation.
  59 ;;;
  60 ;;; * (UNIX-ENVIRONMENT-CMUCL-FROM-SBCL '("Bletch=fub" "Noggin" "YES=No!"))
  61 ;;; WARNING:
  62 ;;;   smashing case of "Bletch=fub" in conversion to CMU-CL-style
  63 ;;;     environment alist
  64 ;;; WARNING:
  65 ;;;   no #\= in "Noggin", eliding it in CMU-CL-style environment alist
  66 ;;; ((:BLETCH . "fub") (:YES . "No!"))
  67 (defun unix-environment-cmucl-from-sbcl (sbcl)
  68   (mapcan
  69    (lambda (string)
  70      (declare (string string))
  71      (let ((=-pos (position #\= string :test #'equal)))
  72        (if =-pos
  73            (list
  74             (let* ((key-as-string (subseq string 0 =-pos))
  75                    (key-as-upcase-string (string-upcase key-as-string))
  76                    (key (keywordicate key-as-upcase-string))
  77                    (val (subseq string (1+ =-pos))))
  78               (unless (string= key-as-string key-as-upcase-string)
  79                 (warn "smashing case of ~S in conversion to CMU-CL-style ~
  80                       environment alist"
  81                       string))
  82               (cons key val)))
  83            (warn "no #\\= in ~S, eliding it in CMU-CL-style environment alist"
  84                  string))))
  85    sbcl))
  86
  87 ;;; Convert from a CMU CL representation of a Unix environment to a
  88 ;;; SBCL representation.
  89 (defun unix-environment-sbcl-from-cmucl (cmucl)
  90   (mapcar
  91    (lambda (cons)
  92      (destructuring-bind (key . val) cons
  93        (declare (type keyword key) (string val))
  94        (concatenate 'simple-string (symbol-name key) "=" val)))
  95    cmucl))
  96 \f
  97 ;;;; Import wait3(2) from Unix.
  98
  99 #-win32
 100 (define-alien-routine ("wait3" c-wait3) sb-alien:int
 101   (status sb-alien:int :out)
 102   (options sb-alien:int)
 103   (rusage sb-alien:int))
 104
 105 #-win32
 106 (defun wait3 (&optional do-not-hang check-for-stopped)
 107   #+sb-doc
 108   "Return any available status information on child process. "
 109   (multiple-value-bind (pid status)
 110       (c-wait3 (logior (if do-not-hang
 111                            sb-unix:wnohang
 112                            0)
 113                        (if check-for-stopped
 114                            sb-unix:wuntraced
 115                            0))
 116                0)
 117     (cond ((or (minusp pid)
 118                (zerop pid))
 119            nil)
 120           ((eql (ldb (byte 8 0) status)
 121                 sb-unix:wstopped)
 122            (values pid
 123                    :stopped
 124                    (ldb (byte 8 8) status)))
 125           ((zerop (ldb (byte 7 0) status))
 126            (values pid
 127                    :exited
 128                    (ldb (byte 8 8) status)))
 129           (t
 130            (let ((signal (ldb (byte 7 0) status)))
 131              (values pid
 132                      (if (position signal
 133                                    #.(vector
 134                                       sb-unix:sigstop
 135                                       sb-unix:sigtstp
 136                                       sb-unix:sigttin
 137                                       sb-unix:sigttou))
 138                          :stopped
 139                          :signaled)
 140                      signal
 141                      (not (zerop (ldb (byte 1 7) status)))))))))
 142 \f
 143 ;;;; process control stuff
 144 (defvar *active-processes* nil
 145   #+sb-doc
 146   "List of process structures for all active processes.")
 147
 148 #-win32
 149 (defvar *active-processes-lock*
 150   (sb-thread:make-mutex :name "Lock for active processes."))
 151
 152 ;;; *ACTIVE-PROCESSES* can be accessed from multiple threads so a
 153 ;;; mutex is needed. More importantly the sigchld signal handler also
 154 ;;; accesses it, that's why we need without-interrupts.
 155 (defmacro with-active-processes-lock (() &body body)
 156   #-win32
 157   `(sb-thread::call-with-system-mutex (lambda () ,@body) *active-processes-lock*)
 158   #+win32
 159   `(progn ,@body))
 160
 161 (defstruct (process (:copier nil))
 162   pid                 ; PID of child process
 163   %status             ; either :RUNNING, :STOPPED, :EXITED, or :SIGNALED
 164   exit-code           ; either exit code or signal
 165   core-dumped         ; T if a core image was dumped
 166   #-win32 pty                 ; stream to child's pty, or NIL
 167   input               ; stream to child's input, or NIL
 168   output              ; stream from child's output, or NIL
 169   error               ; stream from child's error output, or NIL
 170   status-hook         ; closure to call when PROC changes status
 171   plist               ; a place for clients to stash things
 172   cookie)             ; list of the number of pipes from the subproc
 173
 174 (defmethod print-object ((process process) stream)
 175   (print-unreadable-object (process stream :type t)
 176     (let ((status (process-status process)))
 177      (if (eq :exited status)
 178          (format stream "~S ~S" status (process-exit-code process))
 179          (format stream "~S ~S" (process-pid process) status)))
 180     process))
 181
 182 #+sb-doc
 183 (setf (documentation 'process-p 'function)
 184       "T if OBJECT is a PROCESS, NIL otherwise.")
 185
 186 #+sb-doc
 187 (setf (documentation 'process-pid 'function) "The pid of the child process.")
 188
 189 #+win32
 190 (define-alien-routine ("GetExitCodeProcess@8" get-exit-code-process)
 191     int
 192   (handle unsigned) (exit-code unsigned :out))
 193
 194 (defun process-status (process)
 195   #+sb-doc
 196   "Return the current status of PROCESS.  The result is one of :RUNNING,
 197    :STOPPED, :EXITED, or :SIGNALED."
 198   (get-processes-status-changes)
 199   (process-%status process))
 200
 201 #+sb-doc
 202 (setf (documentation 'process-exit-code 'function)
 203       "The exit code or the signal of a stopped process.")
 204
 205 #+sb-doc
 206 (setf (documentation 'process-core-dumped 'function)
 207       "T if a core image was dumped by the process.")
 208
 209 #+sb-doc
 210 (setf (documentation 'process-pty 'function)
 211       "The pty stream of the process or NIL.")
 212
 213 #+sb-doc
 214 (setf (documentation 'process-input 'function)
 215       "The input stream of the process or NIL.")
 216
 217 #+sb-doc
 218 (setf (documentation 'process-output 'function)
 219       "The output stream of the process or NIL.")
 220
 221 #+sb-doc
 222 (setf (documentation 'process-error 'function)
 223       "The error stream of the process or NIL.")
 224
 225 #+sb-doc
 226 (setf (documentation 'process-status-hook  'function)
 227       "A function that is called when PROCESS changes its status.
 228 The function is called with PROCESS as its only argument.")
 229
 230 #+sb-doc
 231 (setf (documentation 'process-plist  'function)
 232       "A place for clients to stash things.")
 233
 234 (defun process-wait (process &optional check-for-stopped)
 235   #+sb-doc
 236   "Wait for PROCESS to quit running for some reason. When
 237 CHECK-FOR-STOPPED is T, also returns when PROCESS is stopped. Returns
 238 PROCESS."
 239   (loop
 240       (case (process-status process)
 241         (:running)
 242         (:stopped
 243          (when check-for-stopped
 244            (return)))
 245         (t
 246          (when (zerop (car (process-cookie process)))
 247            (return))))
 248       (sb-sys:serve-all-events 1))
 249   process)
 250
 251 #-(or hpux win32)
 252 ;;; Find the current foreground process group id.
 253 (defun find-current-foreground-process (proc)
 254   (with-alien ((result sb-alien:int))
 255     (multiple-value-bind
 256           (wonp error)
 257         (sb-unix:unix-ioctl (sb-sys:fd-stream-fd (process-pty proc))
 258                             sb-unix:TIOCGPGRP
 259                             (alien-sap (sb-alien:addr result)))
 260       (unless wonp
 261         (error "TIOCPGRP ioctl failed: ~S" (strerror error)))
 262       result))
 263   (process-pid proc))
 264
 265 #-win32
 266 (defun process-kill (process signal &optional (whom :pid))
 267   #+sb-doc
 268   "Hand SIGNAL to PROCESS. If WHOM is :PID, use the kill Unix system call. If
 269    WHOM is :PROCESS-GROUP, use the killpg Unix system call. If WHOM is
 270    :PTY-PROCESS-GROUP deliver the signal to whichever process group is
 271    currently in the foreground."
 272   (let ((pid (ecase whom
 273                ((:pid :process-group)
 274                 (process-pid process))
 275                (:pty-process-group
 276                 #-hpux
 277                 (find-current-foreground-process process)))))
 278     (multiple-value-bind
 279           (okay errno)
 280         (case whom
 281           #+hpux
 282           (:pty-process-group
 283            (sb-unix:unix-ioctl (sb-sys:fd-stream-fd (process-pty process))
 284                                sb-unix:TIOCSIGSEND
 285                                (sb-sys:int-sap
 286                                 signal)))
 287           ((:process-group #-hpux :pty-process-group)
 288            (sb-unix:unix-killpg pid signal))
 289           (t
 290            (sb-unix:unix-kill pid signal)))
 291       (cond ((not okay)
 292              (values nil errno))
 293             ((and (eql pid (process-pid process))
 294                   (= signal sb-unix:sigcont))
 295              (setf (process-%status process) :running)
 296              (setf (process-exit-code process) nil)
 297              (when (process-status-hook process)
 298                (funcall (process-status-hook process) process))
 299              t)
 300             (t
 301              t)))))
 302
 303 (defun process-alive-p (process)
 304   #+sb-doc
 305   "Return T if PROCESS is still alive, NIL otherwise."
 306   (let ((status (process-status process)))
 307     (if (or (eq status :running)
 308             (eq status :stopped))
 309         t
 310         nil)))
 311
 312 (defun process-close (process)
 313   #+sb-doc
 314   "Close all streams connected to PROCESS and stop maintaining the
 315 status slot."
 316   (macrolet ((frob (stream abort)
 317                `(when ,stream (close ,stream :abort ,abort))))
 318     #-win32
 319     (frob (process-pty process) t)   ; Don't FLUSH-OUTPUT to dead process,
 320     (frob (process-input process) t) ; .. 'cause it will generate SIGPIPE.
 321     (frob (process-output process) nil)
 322     (frob (process-error process) nil))
 323   ;; FIXME: Given that the status-slot is no longer updated,
 324   ;; maybe it should be set to :CLOSED, or similar?
 325   (with-active-processes-lock ()
 326    (setf *active-processes* (delete process *active-processes*)))
 327   process)
 328
 329 ;;; the handler for SIGCHLD signals that RUN-PROGRAM establishes
 330 #-win32
 331 (defun sigchld-handler (ignore1 ignore2 ignore3)
 332   (declare (ignore ignore1 ignore2 ignore3))
 333   (get-processes-status-changes))
 334
 335 (defun get-processes-status-changes ()
 336   #-win32
 337   (loop
 338    (multiple-value-bind (pid what code core)
 339        (wait3 t t)
 340      (unless pid
 341        (return))
 342      (let ((proc (with-active-processes-lock ()
 343                    (find pid *active-processes* :key #'process-pid))))
 344        (when proc
 345          (setf (process-%status proc) what)
 346          (setf (process-exit-code proc) code)
 347          (setf (process-core-dumped proc) core)
 348          (when (process-status-hook proc)
 349            (funcall (process-status-hook proc) proc))
 350          (when (position what #(:exited :signaled))
 351            (with-active-processes-lock ()
 352              (setf *active-processes*
 353                    (delete proc *active-processes*))))))))
 354   #+win32
 355   (let (exited)
 356     (with-active-processes-lock ()
 357       (setf *active-processes*
 358             (delete-if (lambda (proc)
 359                          (multiple-value-bind (ok code)
 360                              (get-exit-code-process (process-pid proc))
 361                            (when (and (plusp ok) (/= code 259))
 362                              (setf (process-%status proc) :exited
 363                                    (process-exit-code proc) code)
 364                              (when (process-status-hook proc)
 365                                (push proc exited))
 366                              t)))
 367                        *active-processes*)))
 368     ;; Can't call the hooks before all the processes have been deal
 369     ;; with, as calling a hook may cause re-entry to
 370     ;; GET-PROCESS-STATUS-CHANGES. That may be OK when using wait3,
 371     ;; but in the Windows implementation is would be deeply bad.
 372     (dolist (proc exited)
 373       (let ((hook (process-status-hook proc)))
 374         (when hook
 375           (funcall hook proc))))))
 376 \f
 377 ;;;; RUN-PROGRAM and close friends
 378
 379 ;;; list of file descriptors to close when RUN-PROGRAM exits due to an error
 380 (defvar *close-on-error* nil)
 381
 382 ;;; list of file descriptors to close when RUN-PROGRAM returns in the parent
 383 (defvar *close-in-parent* nil)
 384
 385 ;;; list of handlers installed by RUN-PROGRAM.  FIXME: nothing seems
 386 ;;; to set this.
 387 #-win32
 388 (defvar *handlers-installed* nil)
 389
 390 ;;; Find an unused pty. Return three values: the file descriptor for
 391 ;;; the master side of the pty, the file descriptor for the slave side
 392 ;;; of the pty, and the name of the tty device for the slave side.
 393 #-win32
 394 (progn
 395   (define-alien-routine ptsname c-string (fd int))
 396   (define-alien-routine grantpt boolean (fd int))
 397   (define-alien-routine unlockpt boolean (fd int))
 398
 399   (defun find-a-pty ()
 400     ;; First try to use the Unix98 pty api.
 401     (let* ((master-name (coerce (format nil "/dev/ptmx") 'base-string))
 402            (master-fd (sb-unix:unix-open master-name
 403                                          sb-unix:o_rdwr
 404                                          #o666)))
 405       (when master-fd
 406         (grantpt master-fd)
 407         (unlockpt master-fd)
 408         (let* ((slave-name (ptsname master-fd))
 409                (slave-fd (sb-unix:unix-open slave-name
 410                                             sb-unix:o_rdwr
 411                                             #o666)))
 412           (when slave-fd
 413             (return-from find-a-pty
 414               (values master-fd
 415                       slave-fd
 416                       slave-name)))
 417           (sb-unix:unix-close master-fd))
 418         (error "could not find a pty")))
 419     ;; No dice, try using the old-school method.
 420     (dolist (char '(#\p #\q))
 421       (dotimes (digit 16)
 422         (let* ((master-name (coerce (format nil "/dev/pty~C~X" char digit)
 423                                     'base-string))
 424                (master-fd (sb-unix:unix-open master-name
 425                                              sb-unix:o_rdwr
 426                                              #o666)))
 427           (when master-fd
 428             (let* ((slave-name (coerce (format nil "/dev/tty~C~X" char digit)
 429                                        'base-string))
 430                    (slave-fd (sb-unix:unix-open slave-name
 431                                                 sb-unix:o_rdwr
 432                                                 #o666)))
 433               (when slave-fd
 434                 (return-from find-a-pty
 435                   (values master-fd
 436                           slave-fd
 437                           slave-name)))
 438               (sb-unix:unix-close master-fd))))))
 439     (error "could not find a pty")))
 440
 441 #-win32
 442 (defun open-pty (pty cookie)
 443   (when pty
 444     (multiple-value-bind
 445           (master slave name)
 446         (find-a-pty)
 447       (push master *close-on-error*)
 448       (push slave *close-in-parent*)
 449       (when (streamp pty)
 450         (multiple-value-bind (new-fd errno) (sb-unix:unix-dup master)
 451           (unless new-fd
 452             (error "couldn't SB-UNIX:UNIX-DUP ~W: ~A" master (strerror errno)))
 453           (push new-fd *close-on-error*)
 454           (copy-descriptor-to-stream new-fd pty cookie)))
 455       (values name
 456               (sb-sys:make-fd-stream master :input t :output t
 457                                      :element-type :default
 458                                      :dual-channel-p t)))))
 459
 460 (defmacro round-bytes-to-words (n)
 461   (let ((bytes-per-word (/ sb-vm:n-machine-word-bits sb-vm:n-byte-bits)))
 462     `(logandc2 (the fixnum (+ (the fixnum ,n)
 463                               (1- ,bytes-per-word))) (1- ,bytes-per-word))))
 464
 465 (defun string-list-to-c-strvec (string-list)
 466   (let* ((bytes-per-word (/ sb-vm:n-machine-word-bits sb-vm:n-byte-bits))
 467          ;; We need an extra for the null, and an extra 'cause exect
 468          ;; clobbers argv[-1].
 469          (vec-bytes (* bytes-per-word (+ (length string-list) 2)))
 470          (octet-vector-list (mapcar (lambda (s)
 471                                       (string-to-octets s :null-terminate t))
 472                                     string-list))
 473          (string-bytes (reduce #'+ octet-vector-list
 474                                :key (lambda (s)
 475                                       (round-bytes-to-words (length s)))))
 476          (total-bytes (+ string-bytes vec-bytes))
 477          ;; Memory to hold the vector of pointers and all the strings.
 478          (vec-sap (sb-sys:allocate-system-memory total-bytes))
 479          (string-sap (sap+ vec-sap vec-bytes))
 480          ;; Index starts from [1]!
 481          (vec-index-offset bytes-per-word))
 482     (declare (index string-bytes vec-bytes total-bytes)
 483              (sb-sys:system-area-pointer vec-sap string-sap))
 484     (dolist (octets octet-vector-list)
 485       (declare (type (simple-array (unsigned-byte 8) (*)) octets))
 486       (let ((size (length octets)))
 487         ;; Copy string.
 488         (sb-kernel:copy-ub8-to-system-area octets 0 string-sap 0 size)
 489         ;; Put the pointer in the vector.
 490         (setf (sap-ref-sap vec-sap vec-index-offset) string-sap)
 491         ;; Advance string-sap for the next string.
 492         (setf string-sap (sap+ string-sap (round-bytes-to-words size)))
 493         (incf vec-index-offset bytes-per-word)))
 494     ;; Final null pointer.
 495     (setf (sap-ref-sap vec-sap vec-index-offset) (int-sap 0))
 496     (values vec-sap (sap+ vec-sap bytes-per-word) total-bytes)))
 497
 498 (defmacro with-c-strvec ((var str-list) &body body)
 499   (with-unique-names (sap size)
 500     `(multiple-value-bind (,sap ,var ,size)
 501          (string-list-to-c-strvec ,str-list)
 502        (unwind-protect
 503             (progn
 504               ,@body)
 505          (sb-sys:deallocate-system-memory ,sap ,size)))))
 506
 507 (sb-alien:define-alien-routine spawn
 508     #-win32 sb-alien:int
 509     #+win32 sb-win32::handle
 510   (program sb-alien:c-string)
 511   (argv (* sb-alien:c-string))
 512   (stdin sb-alien:int)
 513   (stdout sb-alien:int)
 514   (stderr sb-alien:int)
 515   (search sb-alien:int)
 516   (envp (* sb-alien:c-string))
 517   (pty-name sb-alien:c-string)
 518   (wait sb-alien:int))
 519
 520 ;;; FIXME: There shouldn't be two semiredundant versions of the
 521 ;;; documentation. Since this is a public extension function, the
 522 ;;; documentation should be in the doc string. So all information from
 523 ;;; this comment should be merged into the doc string, and then this
 524 ;;; comment can go away.
 525 ;;;
 526 ;;; RUN-PROGRAM uses fork() and execve() to run a different program.
 527 ;;; Strange stuff happens to keep the Unix state of the world
 528 ;;; coherent.
 529 ;;;
 530 ;;; The child process needs to get its input from somewhere, and send
 531 ;;; its output (both standard and error) to somewhere. We have to do
 532 ;;; different things depending on where these somewheres really are.
 533 ;;;
 534 ;;; For input, there are five options:
 535 ;;;  -- T: Just leave fd 0 alone. Pretty simple.
 536 ;;;  -- "file": Read from the file. We need to open the file and
 537 ;;;     pull the descriptor out of the stream. The parent should close
 538 ;;;     this stream after the child is up and running to free any
 539 ;;;     storage used in the parent.
 540 ;;;  -- NIL: Same as "file", but use "/dev/null" as the file.
 541 ;;;  -- :STREAM: Use Unix pipe() to create two descriptors. Use
 542 ;;;     SB-SYS:MAKE-FD-STREAM to create the output stream on the
 543 ;;;     writeable descriptor, and pass the readable descriptor to
 544 ;;;     the child. The parent must close the readable descriptor for
 545 ;;;     EOF to be passed up correctly.
 546 ;;;  -- a stream: If it's a fd-stream, just pull the descriptor out
 547 ;;;     of it. Otherwise make a pipe as in :STREAM, and copy
 548 ;;;     everything across.
 549 ;;;
 550 ;;; For output, there are five options:
 551 ;;;  -- T: Leave descriptor 1 alone.
 552 ;;;  -- "file": dump output to the file.
 553 ;;;  -- NIL: dump output to /dev/null.
 554 ;;;  -- :STREAM: return a stream that can be read from.
 555 ;;;  -- a stream: if it's a fd-stream, use the descriptor in it.
 556 ;;;     Otherwise, copy stuff from output to stream.
 557 ;;;
 558 ;;; For error, there are all the same options as output plus:
 559 ;;;  -- :OUTPUT: redirect to the same place as output.
 560 ;;;
 561 ;;; RUN-PROGRAM returns a PROCESS structure for the process if
 562 ;;; the fork worked, and NIL if it did not.
 563 (defun run-program (program args
 564                     &key
 565                     #-win32 (env nil env-p)
 566                     #-win32 (environment
 567                              (if env-p
 568                                  (unix-environment-sbcl-from-cmucl env)
 569                                  (posix-environ))
 570                              environment-p)
 571                     (wait t)
 572                     search
 573                     #-win32 pty
 574                     input
 575                     if-input-does-not-exist
 576                     output
 577                     (if-output-exists :error)
 578                     (error :output)
 579                     (if-error-exists :error)
 580                     status-hook)
 581   #+sb-doc
 582   #.(concatenate
 583      'string
 584      ;; The Texinfoizer is sensitive to whitespace, so mind the
 585      ;; placement of the #-win32 pseudosplicings.
 586      "RUN-PROGRAM creates a new process specified by the PROGRAM
 587 argument. ARGS are the standard arguments that can be passed to a
 588 program. For no arguments, use NIL (which means that just the
 589 name of the program is passed as arg 0).
 590
 591 The program arguments and the environment are encoded using the
 592 default external format for streams.
 593
 594 RUN-PROGRAM will return a PROCESS structure. See the CMU Common Lisp
 595 Users Manual for details about the PROCESS structure."#-win32"
 596
 597    Notes about Unix environments (as in the :ENVIRONMENT and :ENV args):
 598
 599    - The SBCL implementation of RUN-PROGRAM, like Perl and many other
 600      programs, but unlike the original CMU CL implementation, copies
 601      the Unix environment by default.
 602
 603    - Running Unix programs from a setuid process, or in any other
 604      situation where the Unix environment is under the control of someone
 605      else, is a mother lode of security problems. If you are contemplating
 606      doing this, read about it first. (The Perl community has a lot of good
 607      documentation about this and other security issues in script-like
 608      programs.)""
 609
 610    The &KEY arguments have the following meanings:
 611 "#-win32"
 612    :ENVIRONMENT
 613       a list of STRINGs describing the new Unix environment
 614       (as in \"man environ\"). The default is to copy the environment of
 615       the current process.
 616    :ENV
 617       an alternative lossy representation of the new Unix environment,
 618       for compatibility with CMU CL""
 619    :SEARCH
 620       Look for PROGRAM in each of the directories in the child's $PATH
 621       environment variable.  Otherwise an absolute pathname is required.
 622    :WAIT
 623       If non-NIL (default), wait until the created process finishes.  If
 624       NIL, continue running Lisp until the program finishes."#-win32"
 625    :PTY
 626       Either T, NIL, or a stream.  Unless NIL, the subprocess is established
 627       under a PTY.  If :pty is a stream, all output to this pty is sent to
 628       this stream, otherwise the PROCESS-PTY slot is filled in with a stream
 629       connected to pty that can read output and write input.""
 630    :INPUT
 631       Either T, NIL, a pathname, a stream, or :STREAM.  If T, the standard
 632       input for the current process is inherited.  If NIL, "
 633       #-win32"/dev/null"#+win32"nul""
 634       is used.  If a pathname, the file so specified is used.  If a stream,
 635       all the input is read from that stream and sent to the subprocess.  If
 636       :STREAM, the PROCESS-INPUT slot is filled in with a stream that sends
 637       its output to the process. Defaults to NIL.
 638    :IF-INPUT-DOES-NOT-EXIST (when :INPUT is the name of a file)
 639       can be one of:
 640          :ERROR to generate an error
 641          :CREATE to create an empty file
 642          NIL (the default) to return NIL from RUN-PROGRAM
 643    :OUTPUT
 644       Either T, NIL, a pathname, a stream, or :STREAM.  If T, the standard
 645       output for the current process is inherited.  If NIL, "
 646       #-win32"/dev/null"#+win32"nul""
 647       is used.  If a pathname, the file so specified is used.  If a stream,
 648       all the output from the process is written to this stream. If
 649       :STREAM, the PROCESS-OUTPUT slot is filled in with a stream that can
 650       be read to get the output. Defaults to NIL.
 651    :IF-OUTPUT-EXISTS (when :OUTPUT is the name of a file)
 652       can be one of:
 653          :ERROR (the default) to generate an error
 654          :SUPERSEDE to supersede the file with output from the program
 655          :APPEND to append output from the program to the file
 656          NIL to return NIL from RUN-PROGRAM, without doing anything
 657    :ERROR and :IF-ERROR-EXISTS
 658       Same as :OUTPUT and :IF-OUTPUT-EXISTS, except that :ERROR can also be
 659       specified as :OUTPUT in which case all error output is routed to the
 660       same place as normal output.
 661    :STATUS-HOOK
 662       This is a function the system calls whenever the status of the
 663       process changes.  The function takes the process as an argument.")
 664   #-win32
 665   (when (and env-p environment-p)
 666     (error "can't specify :ENV and :ENVIRONMENT simultaneously"))
 667   ;; Make sure that the interrupt handler is installed.
 668   #-win32
 669   (sb-sys:enable-interrupt sb-unix:sigchld #'sigchld-handler)
 670   ;; Prepend the program to the argument list.
 671   (push (namestring program) args)
 672   (labels (;; It's friendly to allow the caller to pass any string
 673            ;; designator, but internally we'd like SIMPLE-STRINGs.
 674            ;;
 675            ;; Huh?  We let users pass in symbols and characters for
 676            ;; the arguments, but call NAMESTRING on the program
 677            ;; name... -- RMK
 678            (simplify-args (args)
 679              (loop for arg in args
 680                    as escaped-arg = (escape-arg arg)
 681                    collect (coerce escaped-arg 'simple-string)))
 682            (escape-arg (arg)
 683              #-win32 arg
 684              ;; Apparently any spaces or double quotes in the arguments
 685              ;; need to be escaped on win32.
 686              #+win32 (if (position-if
 687                           (lambda (c) (find c '(#\" #\Space))) arg)
 688                          (write-to-string arg)
 689                          arg)))
 690     (let (;; Clear various specials used by GET-DESCRIPTOR-FOR to
 691           ;; communicate cleanup info.
 692           *close-on-error*
 693           *close-in-parent*
 694           ;; Some other binding used only on non-Win32.  FIXME:
 695           ;; nothing seems to set this.
 696           #-win32 *handlers-installed*
 697           ;; Establish PROC at this level so that we can return it.
 698           proc
 699           (simple-args (simplify-args args))
 700           (progname (native-namestring program))
 701           ;; Gag.
 702           (cookie (list 0)))
 703       (unwind-protect
 704            ;; Note: despite the WITH-* names, these macros don't
 705            ;; expand into UNWIND-PROTECT forms.  They're just
 706            ;; syntactic sugar to make the rest of the routine slightly
 707            ;; easier to read.
 708            (macrolet ((with-fd-and-stream-for (((fd stream) which &rest args)
 709                                                &body body)
 710                         `(multiple-value-bind (,fd ,stream)
 711                              ,(ecase which
 712                                 ((:input :output)
 713                                  `(get-descriptor-for ,@args))
 714                                 (:error
 715                                  `(if (eq ,(first args) :output)
 716                                       ;; kludge: we expand into
 717                                       ;; hard-coded symbols here.
 718                                       (values stdout output-stream)
 719                                       (get-descriptor-for ,@args))))
 720                            ,@body))
 721                       (with-open-pty (((pty-name pty-stream) (pty cookie)) &body body)
 722                         #+win32 `(declare (ignore ,pty ,cookie))
 723                         #+win32 `(let (,pty-name ,pty-stream) ,@body)
 724                         #-win32 `(multiple-value-bind (,pty-name ,pty-stream)
 725                                      (open-pty ,pty ,cookie)
 726                                    ,@body))
 727                       (with-args-vec ((vec args) &body body)
 728                         `(with-c-strvec (,vec ,args)
 729                            ,@body))
 730                       (with-environment-vec ((vec env) &body body)
 731                         #+win32 `(let (,vec) ,@body)
 732                         #-win32 `(with-c-strvec (,vec ,env) ,@body)))
 733              (with-fd-and-stream-for ((stdin input-stream) :input
 734                                       input cookie
 735                                       :direction :input
 736                                       :if-does-not-exist if-input-does-not-exist
 737                                       :external-format :default
 738                                       :wait wait)
 739                (with-fd-and-stream-for ((stdout output-stream) :output
 740                                         output cookie
 741                                         :direction :output
 742                                         :if-exists if-output-exists
 743                                         :external-format :default)
 744                  (with-fd-and-stream-for ((stderr error-stream)  :error
 745                                           error cookie
 746                                           :direction :output
 747                                           :if-exists if-error-exists
 748                                           :external-format :default)
 749                    (with-open-pty ((pty-name pty-stream) (pty cookie))
 750                      ;; Make sure we are not notified about the child
 751                      ;; death before we have installed the PROCESS
 752                      ;; structure in *ACTIVE-PROCESSES*.
 753                      (with-active-processes-lock ()
 754                        (with-args-vec (args-vec simple-args)
 755                          (with-environment-vec (environment-vec environment)
 756                            (let ((child
 757                                   (without-gcing
 758                                     (spawn progname args-vec
 759                                            stdin stdout stderr
 760                                            (if search 1 0)
 761                                            environment-vec pty-name
 762                                            (if wait 1 0)))))
 763                              (when (= child -1)
 764                                (error "couldn't fork child process: ~A"
 765                                       (strerror)))
 766                              (setf proc (apply
 767                                          #'make-process
 768                                          :pid child
 769                                          :input input-stream
 770                                          :output output-stream
 771                                          :error error-stream
 772                                          :status-hook status-hook
 773                                          :cookie cookie
 774                                          #-win32 (list :pty pty-stream
 775                                                        :%status :running)
 776                                          #+win32 (if wait
 777                                                      (list :%status :exited
 778                                                            :exit-code child)
 779                                                      (list :%status :running))))
 780                              (push proc *active-processes*))))))))))
 781         (dolist (fd *close-in-parent*)
 782           (sb-unix:unix-close fd))
 783         (unless proc
 784           (dolist (fd *close-on-error*)
 785             (sb-unix:unix-close fd))
 786           ;; FIXME: nothing seems to set this.
 787           #-win32
 788           (dolist (handler *handlers-installed*)
 789             (sb-sys:remove-fd-handler handler))))
 790       #-win32
 791       (when (and wait proc)
 792         (process-wait proc))
 793       proc)))
 794
 795 ;;; Install a handler for any input that shows up on the file
 796 ;;; descriptor. The handler reads the data and writes it to the
 797 ;;; stream.
 798 (defun copy-descriptor-to-stream (descriptor stream cookie external-format)
 799   (incf (car cookie))
 800   (let* (handler
 801          (buf (make-array 256 :element-type '(unsigned-byte 8)))
 802          (read-end 0))
 803     (setf handler
 804           (sb-sys:add-fd-handler
 805            descriptor
 806            :input
 807            (lambda (fd)
 808              (declare (ignore fd))
 809              (loop
 810                 (unless handler
 811                   (return))
 812                 (multiple-value-bind
 813                       (result readable/errno)
 814                     (sb-unix:unix-select (1+ descriptor)
 815                                          (ash 1 descriptor)
 816                                          0 0 0)
 817                   (cond ((null result)
 818                          (error "~@<couldn't select on sub-process: ~
 819                                            ~2I~_~A~:>"
 820                                 (strerror readable/errno)))
 821                         ((zerop result)
 822                          (return))))
 823                 (multiple-value-bind (count errno)
 824                     (with-pinned-objects (buf)
 825                       (sb-unix:unix-read descriptor
 826                                          (sap+ (vector-sap buf) read-end)
 827                                          (- (length buf) read-end)))
 828                   (cond
 829                     ((and #-win32 (or (and (null count)
 830                                            (eql errno sb-unix:eio))
 831                                       (eql count 0))
 832                           #+win32 (<= count 0))
 833                      (sb-sys:remove-fd-handler handler)
 834                      (setf handler nil)
 835                      (decf (car cookie))
 836                      (sb-unix:unix-close descriptor)
 837                      (unless (zerop read-end)
 838                        ;; Should this be an END-OF-FILE?
 839                        (error "~@<non-empty buffer when EOF reached ~
 840                                while reading from child: ~S~:>" buf))
 841                      (return))
 842                     ((null count)
 843                      (sb-sys:remove-fd-handler handler)
 844                      (setf handler nil)
 845                      (decf (car cookie))
 846                      (error
 847                       "~@<couldn't read input from sub-process: ~
 848                                      ~2I~_~A~:>"
 849                       (strerror errno)))
 850                     (t
 851                      (incf read-end count)
 852                      (let* ((decode-end read-end)
 853                             (string (handler-case
 854                                         (octets-to-string
 855                                          buf :end read-end
 856                                          :external-format external-format)
 857                                       (end-of-input-in-character (e)
 858                                         (setf decode-end
 859                                               (octet-decoding-error-start e))
 860                                         (octets-to-string
 861                                          buf :end decode-end
 862                                          :external-format external-format)))))
 863                        (unless (zerop (length string))
 864                          (write-string string stream)
 865                          (when (/= decode-end (length buf))
 866                            (replace buf buf :start2 decode-end :end2 read-end))
 867                          (decf read-end decode-end))))))))))))
 868
 869 ;;; FIXME: something very like this is done in SB-POSIX to treat
 870 ;;; streams as file descriptor designators; maybe we can combine these
 871 ;;; two?  Additionally, as we have a couple of user-defined streams
 872 ;;; libraries, maybe we should have a generic function for doing this,
 873 ;;; so user-defined streams can play nicely with RUN-PROGRAM (and
 874 ;;; maybe also with SB-POSIX)?
 875 (defun get-stream-fd-and-external-format (stream direction)
 876   (typecase stream
 877     (sb-sys:fd-stream
 878      (values (sb-sys:fd-stream-fd stream) nil (stream-external-format stream)))
 879     (synonym-stream
 880      (get-stream-fd-and-external-format
 881       (symbol-value (synonym-stream-symbol stream)) direction))
 882     (two-way-stream
 883      (ecase direction
 884        (:input
 885         (get-stream-fd-and-external-format
 886          (two-way-stream-input-stream stream) direction))
 887        (:output
 888         (get-stream-fd-and-external-format
 889          (two-way-stream-output-stream stream) direction))))))
 890
 891 \f
 892 ;;; Find a file descriptor to use for object given the direction.
 893 ;;; Returns the descriptor. If object is :STREAM, returns the created
 894 ;;; stream as the second value.
 895 (defun get-descriptor-for (object
 896                            cookie
 897                            &rest keys
 898                            &key direction (external-format :default) wait
 899                            &allow-other-keys)
 900   (declare (ignore wait)) ;This is explained below.
 901   ;; Our use of a temporary file dates back to very old CMUCLs, and
 902   ;; was probably only ever intended for use with STRING-STREAMs,
 903   ;; which are ordinarily smallish.  However, as we've got
 904   ;; user-defined stream classes, we can end up trying to copy
 905   ;; arbitrarily much data into the temp file, and so are liable to
 906   ;; run afoul of disk quotas or to choke on small /tmp file systems.
 907   (flet ((make-temp-fd ()
 908            (multiple-value-bind (fd name/errno)
 909                (sb-unix:unix-mkstemp "/tmp/.run-program-XXXXXX")
 910              (unless fd
 911                (error "could not open a temporary file: ~A"
 912                       (strerror name/errno)))
 913              #-win32 #|FIXME: should say (logior s_irusr s_iwusr)|#
 914              (unless (sb-unix:unix-chmod name/errno #o600)
 915                (sb-unix:unix-close fd)
 916                (error "failed to chmod the temporary file?!"))
 917              (unless (sb-unix:unix-unlink name/errno)
 918                (sb-unix:unix-close fd)
 919                (error "failed to unlink ~A" name/errno))
 920              fd)))
 921     (cond ((eq object t)
 922            ;; No new descriptor is needed.
 923            (values -1 nil))
 924           ((eq object nil)
 925            ;; Use /dev/null.
 926            (multiple-value-bind
 927                  (fd errno)
 928                (sb-unix:unix-open #-win32 #.(coerce "/dev/null" 'base-string)
 929                                   #+win32 #.(coerce "nul" 'base-string)
 930                                   (case direction
 931                                     (:input sb-unix:o_rdonly)
 932                                     (:output sb-unix:o_wronly)
 933                                     (t sb-unix:o_rdwr))
 934                                   #o666)
 935              (unless fd
 936                (error #-win32 "~@<couldn't open \"/dev/null\": ~2I~_~A~:>"
 937                       #+win32 "~@<couldn't open \"nul\" device: ~2I~_~A~:>"
 938                       (strerror errno)))
 939              (push fd *close-in-parent*)
 940              (values fd nil)))
 941           ((eq object :stream)
 942            (multiple-value-bind (read-fd write-fd) (sb-unix:unix-pipe)
 943              (unless read-fd
 944                (error "couldn't create pipe: ~A" (strerror write-fd)))
 945              (case direction
 946                (:input
 947                 (push read-fd *close-in-parent*)
 948                 (push write-fd *close-on-error*)
 949                 (let ((stream (sb-sys:make-fd-stream write-fd :output t
 950                                                      :element-type :default
 951                                                      :external-format
 952                                                      external-format)))
 953                   (values read-fd stream)))
 954                (:output
 955                 (push read-fd *close-on-error*)
 956                 (push write-fd *close-in-parent*)
 957                 (let ((stream (sb-sys:make-fd-stream read-fd :input t
 958                                                      :element-type :default
 959                                                      :external-format
 960                                                      external-format)))
 961                   (values write-fd stream)))
 962                (t
 963                 (sb-unix:unix-close read-fd)
 964                 (sb-unix:unix-close write-fd)
 965                 (error "Direction must be either :INPUT or :OUTPUT, not ~S."
 966                        direction)))))
 967           ((or (pathnamep object) (stringp object))
 968            (with-open-stream (file (apply #'open object keys))
 969              (multiple-value-bind
 970                    (fd errno)
 971                  (sb-unix:unix-dup (sb-sys:fd-stream-fd file))
 972                (cond (fd
 973                       (push fd *close-in-parent*)
 974                       (values fd nil))
 975                      (t
 976                       (error "couldn't duplicate file descriptor: ~A"
 977                              (strerror errno)))))))
 978           ((streamp object)
 979            (ecase direction
 980              (:input
 981               (block nil
 982                 ;; If we can get an fd for the stream, let the child
 983                 ;; process use the fd for its descriptor.  Otherwise,
 984                 ;; we copy data from the stream into a temp file, and
 985                 ;; give the temp file's descriptor to the
 986                 ;; child.
 987                 (multiple-value-bind (fd stream format)
 988                     (get-stream-fd-and-external-format object :input)
 989                   (declare (ignore format))
 990                   (when fd
 991                     (return (values fd stream))))
 992                 ;; FIXME: if we can't get the file descriptor, since
 993                 ;; the stream might be interactive or otherwise
 994                 ;; block-y, we can't know whether we can copy the
 995                 ;; stream's data to a temp file, so if RUN-PROGRAM was
 996                 ;; called with :WAIT NIL, we should probably error.
 997                 ;; However, STRING-STREAMs aren't fd-streams, but
 998                 ;; they're not prone to blocking; any user-defined
 999                 ;; streams that "read" from some in-memory data will
1000                 ;; probably be similar to STRING-STREAMs.  So maybe we
1001                 ;; should add a STREAM-INTERACTIVE-P generic function
1002                 ;; for problems like this?  Anyway, the machinery is
1003                 ;; here, if you feel like filling in the details.
1004                 #|
1005                 (when (and (null wait) #<some undetermined criterion>)
1006                   (error "~@<don't know how to get an fd for ~A, and so ~
1007                              can't ensure that copying its data to the ~
1008                              child process won't hang~:>" object))
1009                 |#
1010                 (let ((fd (make-temp-fd))
1011                       (newline (string #\Newline)))
1012                   (loop
1013                      (multiple-value-bind
1014                            (line no-cr)
1015                          (read-line object nil nil)
1016                        (unless line
1017                          (return))
1018                        (let ((vector (string-to-octets line)))
1019                          (sb-unix:unix-write
1020                           fd vector 0 (length vector)))
1021                        (if no-cr
1022                            (return)
1023                            (sb-unix:unix-write fd newline 0 1))))
1024                   (sb-unix:unix-lseek fd 0 sb-unix:l_set)
1025                   (push fd *close-in-parent*)
1026                   (return (values fd nil)))))
1027              (:output
1028               (block nil
1029                 ;; Similar to the :input trick above, except we
1030                 ;; arrange to copy data from the stream.  This is
1031                 ;; slightly saner than the input case, since we don't
1032                 ;; buffer to a file, but I think we may still lose if
1033                 ;; there's unflushed data in the stream buffer and we
1034                 ;; give the file descriptor to the child.
1035                 (multiple-value-bind (fd stream format)
1036                     (get-stream-fd-and-external-format object :output)
1037                   (declare (ignore format))
1038                   (when fd
1039                     (return (values fd stream))))
1040                 (multiple-value-bind (read-fd write-fd)
1041                     (sb-unix:unix-pipe)
1042                   (unless read-fd
1043                     (error "couldn't create pipe: ~S" (strerror write-fd)))
1044                   (copy-descriptor-to-stream read-fd object cookie
1045                                              external-format)
1046                   (push read-fd *close-on-error*)
1047                   (push write-fd *close-in-parent*)
1048                   (return (values write-fd nil)))))))
1049           (t
1050            (error "invalid option to RUN-PROGRAM: ~S" object)))))