src/code/run-program.lisp

   1 ;;;; RUN-PROGRAM and friends, a facility for running Unix programs
   2 ;;;; from inside SBCL
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB-IMPL") ;(SB-IMPL, not SB!IMPL, since we're built in warm load.)
  14 \f
  15 ;;;; hacking the Unix environment
  16 ;;;;
  17 ;;;; In the original CMU CL code that LOAD-FOREIGN is derived from, the
  18 ;;;; Unix environment (as in "man environ") was represented as an
  19 ;;;; alist from keywords to strings, so that e.g. the Unix environment
  20 ;;;;   "SHELL=/bin/bash" "HOME=/root" "PAGER=less"
  21 ;;;; was represented as
  22 ;;;;   ((:SHELL . "/bin/bash") (:HOME . "/root") (:PAGER "less"))
  23 ;;;; This had a few problems in principle: the mapping into
  24 ;;;; keyword symbols smashed the case of environment
  25 ;;;; variables, and the whole mapping depended on the presence of
  26 ;;;; #\= characters in the environment strings. In practice these
  27 ;;;; problems weren't hugely important, since conventionally environment
  28 ;;;; variables are uppercase strings followed by #\= followed by
  29 ;;;; arbitrary data. However, since it's so manifestly not The Right
  30 ;;;; Thing to make code which breaks unnecessarily on input which
  31 ;;;; doesn't follow what is, after all, only a tradition, we've switched
  32 ;;;; formats in SBCL, so that the fundamental environment list
  33 ;;;; is just a list of strings, with a one-to-one-correspondence
  34 ;;;; to the C-level representation. I.e., in the example above,
  35 ;;;; the SBCL representation is
  36 ;;;;   '("SHELL=/bin/bash" "HOME=/root" "PAGER=less")
  37 ;;;; CMU CL's implementation is currently supported to help with porting.
  38 ;;;;
  39 ;;;; It's not obvious that this code belongs here (instead of e.g. in
  40 ;;;; unix.lisp), since it has only a weak logical connection with
  41 ;;;; RUN-PROGRAM. However, physically it's convenient to put it here.
  42 ;;;; It's not needed at cold init, so we *can* put it in this
  43 ;;;; warm-loaded file. And by putting it in this warm-loaded file, we
  44 ;;;; make it easy for it to get to the C-level 'environ' variable.
  45 ;;;; which (at least in sbcl-0.6.10 on Red Hat Linux 6.2) is not
  46 ;;;; visible at GENESIS time.
  47
  48 #-win32
  49 (progn
  50   (define-alien-routine wrapped-environ (* c-string))
  51   (defun posix-environ ()
  52     "Return the Unix environment (\"man environ\") as a list of SIMPLE-STRINGs."
  53     (c-strings->string-list (wrapped-environ))))
  54
  55 ;#+win32 (sb-alien:define-alien-routine msvcrt-environ (* c-string))
  56
  57 ;;; Convert as best we can from an SBCL representation of a Unix
  58 ;;; environment to a CMU CL representation.
  59 ;;;
  60 ;;; * (UNIX-ENVIRONMENT-CMUCL-FROM-SBCL '("Bletch=fub" "Noggin" "YES=No!"))
  61 ;;; WARNING:
  62 ;;;   smashing case of "Bletch=fub" in conversion to CMU-CL-style
  63 ;;;     environment alist
  64 ;;; WARNING:
  65 ;;;   no #\= in "Noggin", eliding it in CMU-CL-style environment alist
  66 ;;; ((:BLETCH . "fub") (:YES . "No!"))
  67 (defun unix-environment-cmucl-from-sbcl (sbcl)
  68   (mapcan
  69    (lambda (string)
  70      (declare (string string))
  71      (let ((=-pos (position #\= string :test #'equal)))
  72        (if =-pos
  73            (list
  74             (let* ((key-as-string (subseq string 0 =-pos))
  75                    (key-as-upcase-string (string-upcase key-as-string))
  76                    (key (keywordicate key-as-upcase-string))
  77                    (val (subseq string (1+ =-pos))))
  78               (unless (string= key-as-string key-as-upcase-string)
  79                 (warn "smashing case of ~S in conversion to CMU-CL-style ~
  80                       environment alist"
  81                       string))
  82               (cons key val)))
  83            (warn "no #\\= in ~S, eliding it in CMU-CL-style environment alist"
  84                  string))))
  85    sbcl))
  86
  87 ;;; Convert from a CMU CL representation of a Unix environment to a
  88 ;;; SBCL representation.
  89 (defun unix-environment-sbcl-from-cmucl (cmucl)
  90   (mapcar
  91    (lambda (cons)
  92      (destructuring-bind (key . val) cons
  93        (declare (type keyword key) (string val))
  94        (concatenate 'simple-string (symbol-name key) "=" val)))
  95    cmucl))
  96 \f
  97 ;;;; Import wait3(2) from Unix.
  98
  99 #-win32
 100 (define-alien-routine ("waitpid" c-waitpid) sb-alien:int
 101   (pid sb-alien:int)
 102   (status sb-alien:int :out)
 103   (options sb-alien:int))
 104
 105 #-win32
 106 (defun waitpid (pid &optional do-not-hang check-for-stopped)
 107   #+sb-doc
 108   "Return any available status information on child process with PID."
 109   (multiple-value-bind (pid status)
 110       (c-waitpid pid
 111                  (logior (if do-not-hang
 112                              sb-unix:wnohang
 113                              0)
 114                          (if check-for-stopped
 115                              sb-unix:wuntraced
 116                              0)))
 117     (cond ((or (minusp pid)
 118                (zerop pid))
 119            nil)
 120           ((eql (ldb (byte 8 0) status)
 121                 sb-unix:wstopped)
 122            (values pid
 123                    :stopped
 124                    (ldb (byte 8 8) status)))
 125           ((zerop (ldb (byte 7 0) status))
 126            (values pid
 127                    :exited
 128                    (ldb (byte 8 8) status)))
 129           (t
 130            (let ((signal (ldb (byte 7 0) status)))
 131              (values pid
 132                      (if (position signal
 133                                    #.(vector
 134                                       sb-unix:sigstop
 135                                       sb-unix:sigtstp
 136                                       sb-unix:sigttin
 137                                       sb-unix:sigttou))
 138                          :stopped
 139                          :signaled)
 140                      signal
 141                      (not (zerop (ldb (byte 1 7) status)))))))))
 142 \f
 143 ;;;; process control stuff
 144 (defvar *active-processes* nil
 145   #+sb-doc
 146   "List of process structures for all active processes.")
 147
 148 #-win32
 149 (defvar *active-processes-lock*
 150   (sb-thread:make-mutex :name "Lock for active processes."))
 151
 152 ;;; *ACTIVE-PROCESSES* can be accessed from multiple threads so a
 153 ;;; mutex is needed. More importantly the sigchld signal handler also
 154 ;;; accesses it, that's why we need without-interrupts.
 155 (defmacro with-active-processes-lock (() &body body)
 156   #-win32
 157   `(sb-thread::with-system-mutex (*active-processes-lock*)
 158      ,@body)
 159   #+win32
 160   `(progn ,@body))
 161
 162 (defstruct (process (:copier nil))
 163   pid                 ; PID of child process
 164   %status             ; either :RUNNING, :STOPPED, :EXITED, or :SIGNALED
 165   exit-code           ; either exit code or signal
 166   core-dumped         ; T if a core image was dumped
 167   #-win32 pty                 ; stream to child's pty, or NIL
 168   input               ; stream to child's input, or NIL
 169   output              ; stream from child's output, or NIL
 170   error               ; stream from child's error output, or NIL
 171   status-hook         ; closure to call when PROC changes status
 172   plist               ; a place for clients to stash things
 173   cookie)             ; list of the number of pipes from the subproc
 174
 175 (defmethod print-object ((process process) stream)
 176   (print-unreadable-object (process stream :type t)
 177     (let ((status (process-status process)))
 178      (if (eq :exited status)
 179          (format stream "~S ~S" status (process-exit-code process))
 180          (format stream "~S ~S" (process-pid process) status)))
 181     process))
 182
 183 #+sb-doc
 184 (setf (documentation 'process-p 'function)
 185       "T if OBJECT is a PROCESS, NIL otherwise.")
 186
 187 #+sb-doc
 188 (setf (documentation 'process-pid 'function) "The pid of the child process.")
 189
 190 #+win32
 191 (define-alien-routine ("GetExitCodeProcess@8" get-exit-code-process)
 192     int
 193   (handle unsigned) (exit-code unsigned :out))
 194
 195 (defun process-status (process)
 196   #+sb-doc
 197   "Return the current status of PROCESS.  The result is one of :RUNNING,
 198    :STOPPED, :EXITED, or :SIGNALED."
 199   (get-processes-status-changes)
 200   (process-%status process))
 201
 202 #+sb-doc
 203 (setf (documentation 'process-exit-code 'function)
 204       "The exit code or the signal of a stopped process.")
 205
 206 #+sb-doc
 207 (setf (documentation 'process-core-dumped 'function)
 208       "T if a core image was dumped by the process.")
 209
 210 #+sb-doc
 211 (setf (documentation 'process-pty 'function)
 212       "The pty stream of the process or NIL.")
 213
 214 #+sb-doc
 215 (setf (documentation 'process-input 'function)
 216       "The input stream of the process or NIL.")
 217
 218 #+sb-doc
 219 (setf (documentation 'process-output 'function)
 220       "The output stream of the process or NIL.")
 221
 222 #+sb-doc
 223 (setf (documentation 'process-error 'function)
 224       "The error stream of the process or NIL.")
 225
 226 #+sb-doc
 227 (setf (documentation 'process-status-hook  'function)
 228       "A function that is called when PROCESS changes its status.
 229 The function is called with PROCESS as its only argument.")
 230
 231 #+sb-doc
 232 (setf (documentation 'process-plist  'function)
 233       "A place for clients to stash things.")
 234
 235 (defun process-wait (process &optional check-for-stopped)
 236   #+sb-doc
 237   "Wait for PROCESS to quit running for some reason. When
 238 CHECK-FOR-STOPPED is T, also returns when PROCESS is stopped. Returns
 239 PROCESS."
 240   (loop
 241       (case (process-status process)
 242         (:running)
 243         (:stopped
 244          (when check-for-stopped
 245            (return)))
 246         (t
 247          (when (zerop (car (process-cookie process)))
 248            (return))))
 249       (sb-sys:serve-all-events 1))
 250   process)
 251
 252 #-win32
 253 ;;; Find the current foreground process group id.
 254 (defun find-current-foreground-process (proc)
 255   (with-alien ((result sb-alien:int))
 256     (multiple-value-bind
 257           (wonp error)
 258         (sb-unix:unix-ioctl (sb-sys:fd-stream-fd (process-pty proc))
 259                             sb-unix:TIOCGPGRP
 260                             (alien-sap (sb-alien:addr result)))
 261       (unless wonp
 262         (error "TIOCPGRP ioctl failed: ~S" (strerror error)))
 263       result))
 264   (process-pid proc))
 265
 266 #-win32
 267 (defun process-kill (process signal &optional (whom :pid))
 268   #+sb-doc
 269   "Hand SIGNAL to PROCESS. If WHOM is :PID, use the kill Unix system call. If
 270    WHOM is :PROCESS-GROUP, use the killpg Unix system call. If WHOM is
 271    :PTY-PROCESS-GROUP deliver the signal to whichever process group is
 272    currently in the foreground."
 273   (let ((pid (ecase whom
 274                ((:pid :process-group)
 275                 (process-pid process))
 276                (:pty-process-group
 277                 (find-current-foreground-process process)))))
 278     (multiple-value-bind
 279           (okay errno)
 280         (case whom
 281           ((:process-group)
 282            (sb-unix:unix-killpg pid signal))
 283           (t
 284            (sb-unix:unix-kill pid signal)))
 285       (cond ((not okay)
 286              (values nil errno))
 287             ((and (eql pid (process-pid process))
 288                   (= signal sb-unix:sigcont))
 289              (setf (process-%status process) :running)
 290              (setf (process-exit-code process) nil)
 291              (when (process-status-hook process)
 292                (funcall (process-status-hook process) process))
 293              t)
 294             (t
 295              t)))))
 296
 297 (defun process-alive-p (process)
 298   #+sb-doc
 299   "Return T if PROCESS is still alive, NIL otherwise."
 300   (let ((status (process-status process)))
 301     (if (or (eq status :running)
 302             (eq status :stopped))
 303         t
 304         nil)))
 305
 306 (defun process-close (process)
 307   #+sb-doc
 308   "Close all streams connected to PROCESS and stop maintaining the
 309 status slot."
 310   (macrolet ((frob (stream abort)
 311                `(when ,stream (close ,stream :abort ,abort))))
 312     #-win32
 313     (frob (process-pty process) t)   ; Don't FLUSH-OUTPUT to dead process,
 314     (frob (process-input process) t) ; .. 'cause it will generate SIGPIPE.
 315     (frob (process-output process) nil)
 316     (frob (process-error process) nil))
 317   ;; FIXME: Given that the status-slot is no longer updated,
 318   ;; maybe it should be set to :CLOSED, or similar?
 319   (with-active-processes-lock ()
 320    (setf *active-processes* (delete process *active-processes*)))
 321   process)
 322
 323 (defun get-processes-status-changes ()
 324   (let (exited)
 325     (with-active-processes-lock ()
 326       (setf *active-processes*
 327             (delete-if #-win32
 328                        (lambda (proc)
 329                          ;; Wait only on pids belonging to processes
 330                          ;; started by RUN-PROGRAM. There used to be a
 331                          ;; WAIT3 call here, but that makes direct
 332                          ;; WAIT, WAITPID usage impossible due to the
 333                          ;; race with the SIGCHLD signal handler.
 334                          (multiple-value-bind (pid what code core)
 335                              (waitpid (process-pid proc) t t)
 336                            (when pid
 337                              (setf (process-%status proc) what)
 338                              (setf (process-exit-code proc) code)
 339                              (setf (process-core-dumped proc) core)
 340                              (when (process-status-hook proc)
 341                                (push proc exited))
 342                              t)))
 343                        #+win32
 344                        (lambda (proc)
 345                          (multiple-value-bind (ok code)
 346                              (get-exit-code-process (process-pid proc))
 347                            (when (and (plusp ok) (/= code 259))
 348                              (setf (process-%status proc) :exited
 349                                    (process-exit-code proc) code)
 350                              (when (process-status-hook proc)
 351                                (push proc exited))
 352                              t)))
 353                        *active-processes*)))
 354     ;; Can't call the hooks before all the processes have been deal
 355     ;; with, as calling a hook may cause re-entry to
 356     ;; GET-PROCESS-STATUS-CHANGES. That may be OK when using waitpid,
 357     ;; but in the Windows implementation it would be deeply bad.
 358     (dolist (proc exited)
 359       (let ((hook (process-status-hook proc)))
 360         (when hook
 361           (funcall hook proc))))))
 362 \f
 363 ;;;; RUN-PROGRAM and close friends
 364
 365 ;;; list of file descriptors to close when RUN-PROGRAM exits due to an error
 366 (defvar *close-on-error* nil)
 367
 368 ;;; list of file descriptors to close when RUN-PROGRAM returns in the parent
 369 (defvar *close-in-parent* nil)
 370
 371 ;;; list of handlers installed by RUN-PROGRAM.  FIXME: nothing seems
 372 ;;; to set this.
 373 #-win32
 374 (defvar *handlers-installed* nil)
 375
 376 ;;; Find an unused pty. Return three values: the file descriptor for
 377 ;;; the master side of the pty, the file descriptor for the slave side
 378 ;;; of the pty, and the name of the tty device for the slave side.
 379 #-(or win32 openbsd)
 380 (progn
 381   (define-alien-routine ptsname c-string (fd int))
 382   (define-alien-routine grantpt boolean (fd int))
 383   (define-alien-routine unlockpt boolean (fd int))
 384
 385   (defun find-a-pty ()
 386     ;; First try to use the Unix98 pty api.
 387     (let* ((master-name (coerce (format nil "/dev/ptmx") 'base-string))
 388            (master-fd (sb-unix:unix-open master-name
 389                                          sb-unix:o_rdwr
 390                                          #o666)))
 391       (when master-fd
 392         (grantpt master-fd)
 393         (unlockpt master-fd)
 394         (let* ((slave-name (ptsname master-fd))
 395                (slave-fd (sb-unix:unix-open slave-name
 396                                             sb-unix:o_rdwr
 397                                             #o666)))
 398           (when slave-fd
 399             (return-from find-a-pty
 400               (values master-fd
 401                       slave-fd
 402                       slave-name)))
 403           (sb-unix:unix-close master-fd))
 404         (error "could not find a pty")))
 405     ;; No dice, try using the old-school method.
 406     (dolist (char '(#\p #\q))
 407       (dotimes (digit 16)
 408         (let* ((master-name (coerce (format nil "/dev/pty~C~X" char digit)
 409                                     'base-string))
 410                (master-fd (sb-unix:unix-open master-name
 411                                              sb-unix:o_rdwr
 412                                              #o666)))
 413           (when master-fd
 414             (let* ((slave-name (coerce (format nil "/dev/tty~C~X" char digit)
 415                                        'base-string))
 416                    (slave-fd (sb-unix:unix-open slave-name
 417                                                 sb-unix:o_rdwr
 418                                                 #o666)))
 419               (when slave-fd
 420                 (return-from find-a-pty
 421                   (values master-fd
 422                           slave-fd
 423                           slave-name)))
 424               (sb-unix:unix-close master-fd))))))
 425     (error "could not find a pty")))
 426 #+openbsd
 427 (progn
 428   (define-alien-routine openpty int (amaster int :out) (aslave int :out)
 429                         (name (* char)) (termp (* t)) (winp (* t)))
 430   (defun find-a-pty ()
 431     (with-alien ((name-buf (array char 16)))
 432       (multiple-value-bind (return-val master-fd slave-fd)
 433           (openpty (cast name-buf (* char)) nil nil)
 434         (if (zerop return-val)
 435             (values master-fd
 436                     slave-fd
 437                     (sb-alien::c-string-to-string (alien-sap name-buf)
 438                                                   (sb-impl::default-external-format)
 439                                                   'character))
 440             (error "could not find a pty"))))))
 441
 442 #-win32
 443 (defun open-pty (pty cookie &key (external-format :default))
 444   (when pty
 445     (multiple-value-bind
 446           (master slave name)
 447         (find-a-pty)
 448       (push master *close-on-error*)
 449       (push slave *close-in-parent*)
 450       (when (streamp pty)
 451         (multiple-value-bind (new-fd errno) (sb-unix:unix-dup master)
 452           (unless new-fd
 453             (error "couldn't SB-UNIX:UNIX-DUP ~W: ~A" master (strerror errno)))
 454           (push new-fd *close-on-error*)
 455           (copy-descriptor-to-stream new-fd pty cookie external-format)))
 456       (values name
 457               (sb-sys:make-fd-stream master :input t :output t
 458                                      :external-format external-format
 459                                      :element-type :default
 460                                      :dual-channel-p t)))))
 461
 462 ;; Null terminate strings only C-side: otherwise we can run into
 463 ;; A-T-S-L even for simple encodings like ASCII.  Multibyte encodings
 464 ;; may need more than a single byte of zeros; assume 4 byte is enough
 465 ;; for everyone.
 466 (defmacro round-null-terminated-bytes-to-words (n)
 467   (let ((bytes-per-word (/ sb-vm:n-machine-word-bits sb-vm:n-byte-bits)))
 468     `(logandc2 (the sb-vm:signed-word (+ (the fixnum ,n)
 469                                          4 (1- ,bytes-per-word)))
 470                (1- ,bytes-per-word))))
 471
 472 (defun string-list-to-c-strvec (string-list)
 473   (let* ((bytes-per-word (/ sb-vm:n-machine-word-bits sb-vm:n-byte-bits))
 474          ;; We need an extra for the null, and an extra 'cause exect
 475          ;; clobbers argv[-1].
 476          (vec-bytes (* bytes-per-word (+ (length string-list) 2)))
 477          (octet-vector-list (mapcar (lambda (s)
 478                                       (string-to-octets s))
 479                                     string-list))
 480          (string-bytes (reduce #'+ octet-vector-list
 481                                :key (lambda (s)
 482                                       (round-null-terminated-bytes-to-words
 483                                        (length s)))))
 484          (total-bytes (+ string-bytes vec-bytes))
 485          ;; Memory to hold the vector of pointers and all the strings.
 486          (vec-sap (sb-sys:allocate-system-memory total-bytes))
 487          (string-sap (sap+ vec-sap vec-bytes))
 488          ;; Index starts from [1]!
 489          (vec-index-offset bytes-per-word))
 490     (declare (sb-vm:signed-word vec-bytes)
 491              (sb-vm:word string-bytes total-bytes)
 492              (sb-sys:system-area-pointer vec-sap string-sap))
 493     (dolist (octets octet-vector-list)
 494       (declare (type (simple-array (unsigned-byte 8) (*)) octets))
 495       (let ((size (length octets)))
 496         ;; Copy string.
 497         (sb-kernel:copy-ub8-to-system-area octets 0 string-sap 0 size)
 498         ;; NULL-terminate it
 499         (sb-kernel:system-area-ub8-fill 0 string-sap size 4)
 500         ;; Put the pointer in the vector.
 501         (setf (sap-ref-sap vec-sap vec-index-offset) string-sap)
 502         ;; Advance string-sap for the next string.
 503         (setf string-sap (sap+ string-sap
 504                                (round-null-terminated-bytes-to-words size)))
 505         (incf vec-index-offset bytes-per-word)))
 506     ;; Final null pointer.
 507     (setf (sap-ref-sap vec-sap vec-index-offset) (int-sap 0))
 508     (values vec-sap (sap+ vec-sap bytes-per-word) total-bytes)))
 509
 510 (defmacro with-c-strvec ((var str-list &key null) &body body)
 511   (once-only ((null null))
 512     (with-unique-names (sap size)
 513       `(multiple-value-bind (,sap ,var ,size)
 514            (if ,null
 515                (values nil (sb-sys:int-sap 0))
 516                (string-list-to-c-strvec ,str-list))
 517          (unwind-protect
 518               (progn
 519                 ,@body)
 520            (unless ,null
 521              (sb-sys:deallocate-system-memory ,sap ,size)))))))
 522
 523 (sb-alien:define-alien-routine spawn
 524     #-win32 sb-alien:int
 525     #+win32 sb-win32::handle
 526   (program sb-alien:c-string)
 527   (argv (* sb-alien:c-string))
 528   (stdin sb-alien:int)
 529   (stdout sb-alien:int)
 530   (stderr sb-alien:int)
 531   (search sb-alien:int)
 532   (envp (* sb-alien:c-string))
 533   (pty-name sb-alien:c-string)
 534   (wait sb-alien:int))
 535
 536 ;;; FIXME: There shouldn't be two semiredundant versions of the
 537 ;;; documentation. Since this is a public extension function, the
 538 ;;; documentation should be in the doc string. So all information from
 539 ;;; this comment should be merged into the doc string, and then this
 540 ;;; comment can go away.
 541 ;;;
 542 ;;; RUN-PROGRAM uses fork() and execve() to run a different program.
 543 ;;; Strange stuff happens to keep the Unix state of the world
 544 ;;; coherent.
 545 ;;;
 546 ;;; The child process needs to get its input from somewhere, and send
 547 ;;; its output (both standard and error) to somewhere. We have to do
 548 ;;; different things depending on where these somewheres really are.
 549 ;;;
 550 ;;; For input, there are five options:
 551 ;;;  -- T: Just leave fd 0 alone. Pretty simple.
 552 ;;;  -- "file": Read from the file. We need to open the file and
 553 ;;;     pull the descriptor out of the stream. The parent should close
 554 ;;;     this stream after the child is up and running to free any
 555 ;;;     storage used in the parent.
 556 ;;;  -- NIL: Same as "file", but use "/dev/null" as the file.
 557 ;;;  -- :STREAM: Use Unix pipe() to create two descriptors. Use
 558 ;;;     SB-SYS:MAKE-FD-STREAM to create the output stream on the
 559 ;;;     writeable descriptor, and pass the readable descriptor to
 560 ;;;     the child. The parent must close the readable descriptor for
 561 ;;;     EOF to be passed up correctly.
 562 ;;;  -- a stream: If it's a fd-stream, just pull the descriptor out
 563 ;;;     of it. Otherwise make a pipe as in :STREAM, and copy
 564 ;;;     everything across.
 565 ;;;
 566 ;;; For output, there are five options:
 567 ;;;  -- T: Leave descriptor 1 alone.
 568 ;;;  -- "file": dump output to the file.
 569 ;;;  -- NIL: dump output to /dev/null.
 570 ;;;  -- :STREAM: return a stream that can be read from.
 571 ;;;  -- a stream: if it's a fd-stream, use the descriptor in it.
 572 ;;;     Otherwise, copy stuff from output to stream.
 573 ;;;
 574 ;;; For error, there are all the same options as output plus:
 575 ;;;  -- :OUTPUT: redirect to the same place as output.
 576 ;;;
 577 ;;; RUN-PROGRAM returns a PROCESS structure for the process if
 578 ;;; the fork worked, and NIL if it did not.
 579 (defun run-program (program args
 580                     &key
 581                     #-win32 (env nil env-p)
 582                     #-win32 (environment
 583                              (when env-p
 584                                (unix-environment-sbcl-from-cmucl env))
 585                              environment-p)
 586                     (wait t)
 587                     search
 588                     #-win32 pty
 589                     input
 590                     if-input-does-not-exist
 591                     output
 592                     (if-output-exists :error)
 593                     (error :output)
 594                     (if-error-exists :error)
 595                     status-hook
 596                     (external-format :default))
 597   #+sb-doc
 598   #.(concatenate
 599      'string
 600      ;; The Texinfoizer is sensitive to whitespace, so mind the
 601      ;; placement of the #-win32 pseudosplicings.
 602      "RUN-PROGRAM creates a new process specified by the PROGRAM
 603 argument. ARGS are the standard arguments that can be passed to a
 604 program. For no arguments, use NIL (which means that just the
 605 name of the program is passed as arg 0).
 606
 607 The program arguments and the environment are encoded using the
 608 default external format for streams.
 609
 610 RUN-PROGRAM will return a PROCESS structure. See the CMU Common Lisp
 611 Users Manual for details about the PROCESS structure."#-win32"
 612
 613    Notes about Unix environments (as in the :ENVIRONMENT and :ENV args):
 614
 615    - The SBCL implementation of RUN-PROGRAM, like Perl and many other
 616      programs, but unlike the original CMU CL implementation, copies
 617      the Unix environment by default.
 618
 619    - Running Unix programs from a setuid process, or in any other
 620      situation where the Unix environment is under the control of someone
 621      else, is a mother lode of security problems. If you are contemplating
 622      doing this, read about it first. (The Perl community has a lot of good
 623      documentation about this and other security issues in script-like
 624      programs.)""
 625
 626    The &KEY arguments have the following meanings:
 627 "#-win32"
 628    :ENVIRONMENT
 629       a list of STRINGs describing the new Unix environment
 630       (as in \"man environ\"). The default is to copy the environment of
 631       the current process.
 632    :ENV
 633       an alternative lossy representation of the new Unix environment,
 634       for compatibility with CMU CL""
 635    :SEARCH
 636       Look for PROGRAM in each of the directories in the child's $PATH
 637       environment variable.  Otherwise an absolute pathname is required.
 638    :WAIT
 639       If non-NIL (default), wait until the created process finishes.  If
 640       NIL, continue running Lisp until the program finishes."#-win32"
 641    :PTY
 642       Either T, NIL, or a stream.  Unless NIL, the subprocess is established
 643       under a PTY.  If :pty is a stream, all output to this pty is sent to
 644       this stream, otherwise the PROCESS-PTY slot is filled in with a stream
 645       connected to pty that can read output and write input.""
 646    :INPUT
 647       Either T, NIL, a pathname, a stream, or :STREAM.  If T, the standard
 648       input for the current process is inherited.  If NIL, "
 649       #-win32"/dev/null"#+win32"nul""
 650       is used.  If a pathname, the file so specified is used.  If a stream,
 651       all the input is read from that stream and sent to the subprocess.  If
 652       :STREAM, the PROCESS-INPUT slot is filled in with a stream that sends
 653       its output to the process. Defaults to NIL.
 654    :IF-INPUT-DOES-NOT-EXIST (when :INPUT is the name of a file)
 655       can be one of:
 656          :ERROR to generate an error
 657          :CREATE to create an empty file
 658          NIL (the default) to return NIL from RUN-PROGRAM
 659    :OUTPUT
 660       Either T, NIL, a pathname, a stream, or :STREAM.  If T, the standard
 661       output for the current process is inherited.  If NIL, "
 662       #-win32"/dev/null"#+win32"nul""
 663       is used.  If a pathname, the file so specified is used.  If a stream,
 664       all the output from the process is written to this stream. If
 665       :STREAM, the PROCESS-OUTPUT slot is filled in with a stream that can
 666       be read to get the output. Defaults to NIL.
 667    :IF-OUTPUT-EXISTS (when :OUTPUT is the name of a file)
 668       can be one of:
 669          :ERROR (the default) to generate an error
 670          :SUPERSEDE to supersede the file with output from the program
 671          :APPEND to append output from the program to the file
 672          NIL to return NIL from RUN-PROGRAM, without doing anything
 673    :ERROR and :IF-ERROR-EXISTS
 674       Same as :OUTPUT and :IF-OUTPUT-EXISTS, except that :ERROR can also be
 675       specified as :OUTPUT in which case all error output is routed to the
 676       same place as normal output.
 677    :STATUS-HOOK
 678       This is a function the system calls whenever the status of the
 679       process changes.  The function takes the process as an argument.
 680    :EXTERNAL-FORMAT
 681       The external-format to use for :INPUT, :OUTPUT, and :ERROR :STREAMs.")
 682   #-win32
 683   (when (and env-p environment-p)
 684     (error "can't specify :ENV and :ENVIRONMENT simultaneously"))
 685   ;; Prepend the program to the argument list.
 686   (push (namestring program) args)
 687   (labels (;; It's friendly to allow the caller to pass any string
 688            ;; designator, but internally we'd like SIMPLE-STRINGs.
 689            ;;
 690            ;; Huh?  We let users pass in symbols and characters for
 691            ;; the arguments, but call NAMESTRING on the program
 692            ;; name... -- RMK
 693            (simplify-args (args)
 694              (loop for arg in args
 695                    as escaped-arg = (escape-arg arg)
 696                    collect (coerce escaped-arg 'simple-string)))
 697            (escape-arg (arg)
 698              #-win32 arg
 699              ;; Apparently any spaces or double quotes in the arguments
 700              ;; need to be escaped on win32.
 701              #+win32 (if (position-if
 702                           (lambda (c) (find c '(#\" #\Space))) arg)
 703                          (write-to-string arg)
 704                          arg)))
 705     (let (;; Clear various specials used by GET-DESCRIPTOR-FOR to
 706           ;; communicate cleanup info.
 707           *close-on-error*
 708           *close-in-parent*
 709           ;; Some other binding used only on non-Win32.  FIXME:
 710           ;; nothing seems to set this.
 711           #-win32 *handlers-installed*
 712           ;; Establish PROC at this level so that we can return it.
 713           proc
 714           (simple-args (simplify-args args))
 715           (progname (native-namestring program))
 716           ;; Gag.
 717           (cookie (list 0)))
 718       (unwind-protect
 719            ;; Note: despite the WITH-* names, these macros don't
 720            ;; expand into UNWIND-PROTECT forms.  They're just
 721            ;; syntactic sugar to make the rest of the routine slightly
 722            ;; easier to read.
 723            (macrolet ((with-fd-and-stream-for (((fd stream) which &rest args)
 724                                                &body body)
 725                         `(multiple-value-bind (,fd ,stream)
 726                              ,(ecase which
 727                                 ((:input :output)
 728                                  `(get-descriptor-for ,@args))
 729                                 (:error
 730                                  `(if (eq ,(first args) :output)
 731                                       ;; kludge: we expand into
 732                                       ;; hard-coded symbols here.
 733                                       (values stdout output-stream)
 734                                       (get-descriptor-for ,@args))))
 735                            (unless ,fd
 736                              (return-from run-program))
 737                            ,@body))
 738                       (with-open-pty (((pty-name pty-stream) (pty cookie))
 739                                       &body body)
 740                         #+win32 `(declare (ignore ,pty ,cookie))
 741                         #+win32 `(let (,pty-name ,pty-stream) ,@body)
 742                         #-win32 `(multiple-value-bind (,pty-name ,pty-stream)
 743                                      (open-pty ,pty ,cookie :external-format external-format)
 744                                    ,@body))
 745                       (with-args-vec ((vec args) &body body)
 746                         `(with-c-strvec (,vec ,args)
 747                            ,@body))
 748                       (with-environment-vec ((vec) &body body)
 749                         #+win32 `(let (,vec) ,@body)
 750                         #-win32
 751                         `(with-c-strvec
 752                              (,vec environment
 753                               :null (not (or environment environment-p)))
 754                            ,@body)))
 755              (with-fd-and-stream-for ((stdin input-stream) :input
 756                                       input cookie
 757                                       :direction :input
 758                                       :if-does-not-exist if-input-does-not-exist
 759                                       :external-format external-format
 760                                       :wait wait)
 761                (with-fd-and-stream-for ((stdout output-stream) :output
 762                                         output cookie
 763                                         :direction :output
 764                                         :if-exists if-output-exists
 765                                         :external-format external-format)
 766                  (with-fd-and-stream-for ((stderr error-stream)  :error
 767                                           error cookie
 768                                           :direction :output
 769                                           :if-exists if-error-exists
 770                                           :external-format external-format)
 771                    (with-open-pty ((pty-name pty-stream) (pty cookie))
 772                      ;; Make sure we are not notified about the child
 773                      ;; death before we have installed the PROCESS
 774                      ;; structure in *ACTIVE-PROCESSES*.
 775                      (let (child)
 776                        (with-active-processes-lock ()
 777                          (with-args-vec (args-vec simple-args)
 778                            (with-environment-vec (environment-vec)
 779                              (setq child (without-gcing
 780                                            (spawn progname args-vec
 781                                                   stdin stdout stderr
 782                                                   (if search 1 0)
 783                                                   environment-vec pty-name
 784                                                   (if wait 1 0))))))
 785                          (unless (minusp child)
 786                            (setf proc
 787                                  (apply
 788                                   #'make-process
 789                                   :pid child
 790                                   :input input-stream
 791                                   :output output-stream
 792                                   :error error-stream
 793                                   :status-hook status-hook
 794                                   :cookie cookie
 795                                   #-win32 (list :pty pty-stream
 796                                                 :%status :running)
 797                                   #+win32 (if wait
 798                                               (list :%status :exited
 799                                                     :exit-code child)
 800                                               (list :%status :running))))
 801                            (push proc *active-processes*)))
 802                        ;; Report the error outside the lock.
 803                        #+win32
 804                        (when (minusp child)
 805                          (error "Couldn't execute ~S: ~A" progname (strerror)))
 806                        #-win32
 807                        (case child
 808                          (-2
 809                           (error "Couldn't execute ~S: ~A" progname (strerror)))
 810                          (-1
 811                           (error "Couldn't fork child process: ~A" (strerror))))))))))
 812         (dolist (fd *close-in-parent*)
 813           (sb-unix:unix-close fd))
 814         (unless proc
 815           (dolist (fd *close-on-error*)
 816             (sb-unix:unix-close fd))
 817           #-win32
 818           (dolist (handler *handlers-installed*)
 819             (sb-sys:remove-fd-handler handler)))
 820         #-win32
 821         (when (and wait proc)
 822           (unwind-protect
 823                (process-wait proc)
 824             (dolist (handler *handlers-installed*)
 825               (sb-sys:remove-fd-handler handler)))))
 826       proc)))
 827
 828 ;;; Install a handler for any input that shows up on the file
 829 ;;; descriptor. The handler reads the data and writes it to the
 830 ;;; stream.
 831 (defun copy-descriptor-to-stream (descriptor stream cookie external-format)
 832   (incf (car cookie))
 833   (let* ((handler nil)
 834          (buf (make-array 256 :element-type '(unsigned-byte 8)))
 835          (read-end 0)
 836          (et (stream-element-type stream))
 837          (copy-fun
 838           (cond
 839             ((member et '(character base-char))
 840              (lambda ()
 841                (let* ((decode-end read-end)
 842                       (string (handler-case
 843                                   (octets-to-string
 844                                    buf :end read-end
 845                                    :external-format external-format)
 846                                 (end-of-input-in-character (e)
 847                                   (setf decode-end
 848                                         (octet-decoding-error-start e))
 849                                   (octets-to-string
 850                                    buf :end decode-end
 851                                    :external-format external-format)))))
 852                  (unless (zerop (length string))
 853                    (write-string string stream)
 854                    (when (/= decode-end (length buf))
 855                      (replace buf buf :start2 decode-end :end2 read-end))
 856                    (decf read-end decode-end)))))
 857             ((member et '(:default (unsigned-byte 8)) :test #'equal)
 858              (lambda ()
 859                (write-sequence buf stream :end read-end)
 860                (setf read-end 0)))
 861             (t
 862              ;; FIXME.
 863              (error "Don't know how to copy to stream of element-type ~S"
 864                     et)))))
 865     (setf handler
 866           (sb-sys:add-fd-handler
 867            descriptor
 868            :input
 869            (lambda (fd)
 870              (declare (ignore fd))
 871              (loop
 872                 (unless handler
 873                   (return))
 874                 (multiple-value-bind
 875                       (result readable/errno)
 876                     (sb-unix:unix-select (1+ descriptor)
 877                                          (ash 1 descriptor)
 878                                          0 0 0)
 879                   (cond ((null result)
 880                          (if (eql sb-unix:eintr readable/errno)
 881                              (return)
 882                              (error "~@<Couldn't select on sub-process: ~
 883                                         ~2I~_~A~:>"
 884                                     (strerror readable/errno))))
 885                         ((zerop result)
 886                          (return))))
 887                 (multiple-value-bind (count errno)
 888                     (with-pinned-objects (buf)
 889                       (sb-unix:unix-read descriptor
 890                                          (sap+ (vector-sap buf) read-end)
 891                                          (- (length buf) read-end)))
 892                   (cond
 893                     ((and #-win32 (or (and (null count)
 894                                            (eql errno sb-unix:eio))
 895                                       (eql count 0))
 896                           #+win32 (<= count 0))
 897                      (sb-sys:remove-fd-handler handler)
 898                      (setf handler nil)
 899                      (decf (car cookie))
 900                      (sb-unix:unix-close descriptor)
 901                      (unless (zerop read-end)
 902                        ;; Should this be an END-OF-FILE?
 903                        (error "~@<non-empty buffer when EOF reached ~
 904                                while reading from child: ~S~:>" buf))
 905                      (return))
 906                     ((null count)
 907                      (sb-sys:remove-fd-handler handler)
 908                      (setf handler nil)
 909                      (decf (car cookie))
 910                      (error
 911                       "~@<couldn't read input from sub-process: ~
 912                                      ~2I~_~A~:>"
 913                       (strerror errno)))
 914                     (t
 915                      (incf read-end count)
 916                      (funcall copy-fun))))))))
 917     #-win32
 918     (push handler *handlers-installed*)))
 919
 920 ;;; FIXME: something very like this is done in SB-POSIX to treat
 921 ;;; streams as file descriptor designators; maybe we can combine these
 922 ;;; two?  Additionally, as we have a couple of user-defined streams
 923 ;;; libraries, maybe we should have a generic function for doing this,
 924 ;;; so user-defined streams can play nicely with RUN-PROGRAM (and
 925 ;;; maybe also with SB-POSIX)?
 926 (defun get-stream-fd-and-external-format (stream direction)
 927   (typecase stream
 928     (sb-sys:fd-stream
 929      (values (sb-sys:fd-stream-fd stream) nil (stream-external-format stream)))
 930     (synonym-stream
 931      (get-stream-fd-and-external-format
 932       (symbol-value (synonym-stream-symbol stream)) direction))
 933     (two-way-stream
 934      (ecase direction
 935        (:input
 936         (get-stream-fd-and-external-format
 937          (two-way-stream-input-stream stream) direction))
 938        (:output
 939         (get-stream-fd-and-external-format
 940          (two-way-stream-output-stream stream) direction))))))
 941
 942 (defun get-temporary-directory ()
 943   #-win32 (or (sb-ext:posix-getenv "TMPDIR")
 944               "/tmp")
 945   #+win32 (or (sb-ext:posix-getenv "TEMP")
 946               "C:/Temp"))
 947
 948 \f
 949 ;;; Find a file descriptor to use for object given the direction.
 950 ;;; Returns the descriptor. If object is :STREAM, returns the created
 951 ;;; stream as the second value.
 952 (defun get-descriptor-for (object
 953                            cookie
 954                            &rest keys
 955                            &key direction (external-format :default) wait
 956                            &allow-other-keys)
 957   (declare (ignore wait)) ;This is explained below.
 958   ;; Our use of a temporary file dates back to very old CMUCLs, and
 959   ;; was probably only ever intended for use with STRING-STREAMs,
 960   ;; which are ordinarily smallish.  However, as we've got
 961   ;; user-defined stream classes, we can end up trying to copy
 962   ;; arbitrarily much data into the temp file, and so are liable to
 963   ;; run afoul of disk quotas or to choke on small /tmp file systems.
 964   (flet ((make-temp-fd ()
 965            (multiple-value-bind (fd name/errno)
 966                (sb-unix:sb-mkstemp (format nil "~a/.run-program-XXXXXX"
 967                                            (get-temporary-directory))
 968                                    #o0600)
 969              (unless fd
 970                (error "could not open a temporary file: ~A"
 971                       (strerror name/errno)))
 972              ;; Can't unlink an opened file on Windows
 973              #-win32
 974              (unless (sb-unix:unix-unlink name/errno)
 975                (sb-unix:unix-close fd)
 976                (error "failed to unlink ~A" name/errno))
 977              fd)))
 978     (cond ((eq object t)
 979            ;; No new descriptor is needed.
 980            (values -1 nil))
 981           ((or (eq object nil)
 982                (and (typep object 'broadcast-stream)
 983                     (not (broadcast-stream-streams object))))
 984            ;; Use /dev/null.
 985            (multiple-value-bind
 986                  (fd errno)
 987                (sb-unix:unix-open #-win32 #.(coerce "/dev/null" 'base-string)
 988                                   #+win32 #.(coerce "nul" 'base-string)
 989                                   (case direction
 990                                     (:input sb-unix:o_rdonly)
 991                                     (:output sb-unix:o_wronly)
 992                                     (t sb-unix:o_rdwr))
 993                                   #o666)
 994              (unless fd
 995                (error #-win32 "~@<couldn't open \"/dev/null\": ~2I~_~A~:>"
 996                       #+win32 "~@<couldn't open \"nul\" device: ~2I~_~A~:>"
 997                       (strerror errno)))
 998              (push fd *close-in-parent*)
 999              (values fd nil)))
1000           ((eq object :stream)
1001            (multiple-value-bind (read-fd write-fd) (sb-unix:unix-pipe)
1002              (unless read-fd
1003                (error "couldn't create pipe: ~A" (strerror write-fd)))
1004              (case direction
1005                (:input
1006                 (push read-fd *close-in-parent*)
1007                 (push write-fd *close-on-error*)
1008                 (let ((stream (sb-sys:make-fd-stream write-fd :output t
1009                                                      :element-type :default
1010                                                      :external-format
1011                                                      external-format)))
1012                   (values read-fd stream)))
1013                (:output
1014                 (push read-fd *close-on-error*)
1015                 (push write-fd *close-in-parent*)
1016                 (let ((stream (sb-sys:make-fd-stream read-fd :input t
1017                                                      :element-type :default
1018                                                      :external-format
1019                                                      external-format)))
1020                   (values write-fd stream)))
1021                (t
1022                 (sb-unix:unix-close read-fd)
1023                 (sb-unix:unix-close write-fd)
1024                 (error "Direction must be either :INPUT or :OUTPUT, not ~S."
1025                        direction)))))
1026           ((or (pathnamep object) (stringp object))
1027            ;; GET-DESCRIPTOR-FOR uses &allow-other-keys, so rather
1028            ;; than munge the &rest list for OPEN, just disable keyword
1029            ;; validation there.
1030            (with-open-stream (file (apply #'open object :allow-other-keys t
1031                                           keys))
1032              (when file
1033                (multiple-value-bind
1034                      (fd errno)
1035                    (sb-unix:unix-dup (sb-sys:fd-stream-fd file))
1036                  (cond (fd
1037                         (push fd *close-in-parent*)
1038                         (values fd nil))
1039                        (t
1040                         (error "couldn't duplicate file descriptor: ~A"
1041                                (strerror errno))))))))
1042           ((streamp object)
1043            (ecase direction
1044              (:input
1045               (block nil
1046                 ;; If we can get an fd for the stream, let the child
1047                 ;; process use the fd for its descriptor.  Otherwise,
1048                 ;; we copy data from the stream into a temp file, and
1049                 ;; give the temp file's descriptor to the
1050                 ;; child.
1051                 (multiple-value-bind (fd stream format)
1052                     (get-stream-fd-and-external-format object :input)
1053                   (declare (ignore format))
1054                   (when fd
1055                     (return (values fd stream))))
1056                 ;; FIXME: if we can't get the file descriptor, since
1057                 ;; the stream might be interactive or otherwise
1058                 ;; block-y, we can't know whether we can copy the
1059                 ;; stream's data to a temp file, so if RUN-PROGRAM was
1060                 ;; called with :WAIT NIL, we should probably error.
1061                 ;; However, STRING-STREAMs aren't fd-streams, but
1062                 ;; they're not prone to blocking; any user-defined
1063                 ;; streams that "read" from some in-memory data will
1064                 ;; probably be similar to STRING-STREAMs.  So maybe we
1065                 ;; should add a STREAM-INTERACTIVE-P generic function
1066                 ;; for problems like this?  Anyway, the machinery is
1067                 ;; here, if you feel like filling in the details.
1068                 #|
1069                 (when (and (null wait) #<some undetermined criterion>)
1070                   (error "~@<don't know how to get an fd for ~A, and so ~
1071                              can't ensure that copying its data to the ~
1072                              child process won't hang~:>" object))
1073                 |#
1074                 (let ((fd (make-temp-fd))
1075                       (et (stream-element-type object)))
1076                   (cond ((member et '(character base-char))
1077                          (loop
1078                            (multiple-value-bind
1079                                  (line no-cr)
1080                                (read-line object nil nil)
1081                              (unless line
1082                                (return))
1083                              (let ((vector (string-to-octets
1084                                             line
1085                                             :external-format external-format)))
1086                                (sb-unix:unix-write
1087                                 fd vector 0 (length vector)))
1088                              (if no-cr
1089                                (return)
1090                                (sb-unix:unix-write
1091                                 fd #.(string #\Newline) 0 1)))))
1092                         ((member et '(:default (unsigned-byte 8))
1093                                  :test 'equal)
1094                          (loop with buf = (make-array 256 :element-type '(unsigned-byte 8))
1095                                for p = (read-sequence buf object)
1096                                until (zerop p)
1097                                do (sb-unix:unix-write fd buf 0 p)))
1098                         (t
1099                          (error "Don't know how to copy from stream of element-type ~S"
1100                                 et)))
1101                   (sb-unix:unix-lseek fd 0 sb-unix:l_set)
1102                   (push fd *close-in-parent*)
1103                   (return (values fd nil)))))
1104              (:output
1105               (block nil
1106                 ;; Similar to the :input trick above, except we
1107                 ;; arrange to copy data from the stream.  This is
1108                 ;; slightly saner than the input case, since we don't
1109                 ;; buffer to a file, but I think we may still lose if
1110                 ;; there's unflushed data in the stream buffer and we
1111                 ;; give the file descriptor to the child.
1112                 (multiple-value-bind (fd stream format)
1113                     (get-stream-fd-and-external-format object :output)
1114                   (declare (ignore format))
1115                   (when fd
1116                     (return (values fd stream))))
1117                 (multiple-value-bind (read-fd write-fd)
1118                     (sb-unix:unix-pipe)
1119                   (unless read-fd
1120                     (error "couldn't create pipe: ~S" (strerror write-fd)))
1121                   (copy-descriptor-to-stream read-fd object cookie
1122                                              external-format)
1123                   (push read-fd *close-on-error*)
1124                   (push write-fd *close-in-parent*)
1125                   (return (values write-fd nil)))))))
1126           (t
1127            (error "invalid option to RUN-PROGRAM: ~S" object)))))