src/code/run-program.lisp

   1 ;;;; RUN-PROGRAM and friends, a facility for running Unix programs
   2 ;;;; from inside SBCL
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB-IMPL") ;(SB-IMPL, not SB!IMPL, since we're built in warm load.)
  14 \f
  15 ;;;; hacking the Unix environment
  16 ;;;;
  17 ;;;; In the original CMU CL code that LOAD-FOREIGN is derived from, the
  18 ;;;; Unix environment (as in "man environ") was represented as an
  19 ;;;; alist from keywords to strings, so that e.g. the Unix environment
  20 ;;;;   "SHELL=/bin/bash" "HOME=/root" "PAGER=less"
  21 ;;;; was represented as
  22 ;;;;   ((:SHELL . "/bin/bash") (:HOME . "/root") (:PAGER "less"))
  23 ;;;; This had a few problems in principle: the mapping into
  24 ;;;; keyword symbols smashed the case of environment
  25 ;;;; variables, and the whole mapping depended on the presence of
  26 ;;;; #\= characters in the environment strings. In practice these
  27 ;;;; problems weren't hugely important, since conventionally environment
  28 ;;;; variables are uppercase strings followed by #\= followed by
  29 ;;;; arbitrary data. However, since it's so manifestly not The Right
  30 ;;;; Thing to make code which breaks unnecessarily on input which
  31 ;;;; doesn't follow what is, after all, only a tradition, we've switched
  32 ;;;; formats in SBCL, so that the fundamental environment list
  33 ;;;; is just a list of strings, with a one-to-one-correspondence
  34 ;;;; to the C-level representation. I.e., in the example above,
  35 ;;;; the SBCL representation is
  36 ;;;;   '("SHELL=/bin/bash" "HOME=/root" "PAGER=less")
  37 ;;;; CMU CL's implementation is currently supported to help with porting.
  38 ;;;;
  39 ;;;; It's not obvious that this code belongs here (instead of e.g. in
  40 ;;;; unix.lisp), since it has only a weak logical connection with
  41 ;;;; RUN-PROGRAM. However, physically it's convenient to put it here.
  42 ;;;; It's not needed at cold init, so we *can* put it in this
  43 ;;;; warm-loaded file. And by putting it in this warm-loaded file, we
  44 ;;;; make it easy for it to get to the C-level 'environ' variable.
  45 ;;;; which (at least in sbcl-0.6.10 on Red Hat Linux 6.2) is not
  46 ;;;; visible at GENESIS time.
  47
  48 #-win32
  49 (progn
  50   (define-alien-routine wrapped-environ (* c-string))
  51   (defun posix-environ ()
  52     "Return the Unix environment (\"man environ\") as a list of SIMPLE-STRINGs."
  53     (c-strings->string-list (wrapped-environ))))
  54
  55 ;#+win32 (sb-alien:define-alien-routine msvcrt-environ (* c-string))
  56
  57 ;;; Convert as best we can from an SBCL representation of a Unix
  58 ;;; environment to a CMU CL representation.
  59 ;;;
  60 ;;; * (UNIX-ENVIRONMENT-CMUCL-FROM-SBCL '("Bletch=fub" "Noggin" "YES=No!"))
  61 ;;; WARNING:
  62 ;;;   smashing case of "Bletch=fub" in conversion to CMU-CL-style
  63 ;;;     environment alist
  64 ;;; WARNING:
  65 ;;;   no #\= in "Noggin", eliding it in CMU-CL-style environment alist
  66 ;;; ((:BLETCH . "fub") (:YES . "No!"))
  67 (defun unix-environment-cmucl-from-sbcl (sbcl)
  68   (mapcan
  69    (lambda (string)
  70      (declare (string string))
  71      (let ((=-pos (position #\= string :test #'equal)))
  72        (if =-pos
  73            (list
  74             (let* ((key-as-string (subseq string 0 =-pos))
  75                    (key-as-upcase-string (string-upcase key-as-string))
  76                    (key (keywordicate key-as-upcase-string))
  77                    (val (subseq string (1+ =-pos))))
  78               (unless (string= key-as-string key-as-upcase-string)
  79                 (warn "smashing case of ~S in conversion to CMU-CL-style ~
  80                       environment alist"
  81                       string))
  82               (cons key val)))
  83            (warn "no #\\= in ~S, eliding it in CMU-CL-style environment alist"
  84                  string))))
  85    sbcl))
  86
  87 ;;; Convert from a CMU CL representation of a Unix environment to a
  88 ;;; SBCL representation.
  89 (defun unix-environment-sbcl-from-cmucl (cmucl)
  90   (mapcar
  91    (lambda (cons)
  92      (destructuring-bind (key . val) cons
  93        (declare (type keyword key) (string val))
  94        (concatenate 'simple-string (symbol-name key) "=" val)))
  95    cmucl))
  96 \f
  97 ;;;; Import wait3(2) from Unix.
  98
  99 #-win32
 100 (define-alien-routine ("waitpid" c-waitpid) sb-alien:int
 101   (pid sb-alien:int)
 102   (status sb-alien:int :out)
 103   (options sb-alien:int))
 104
 105 #-win32
 106 (defun waitpid (pid &optional do-not-hang check-for-stopped)
 107   #+sb-doc
 108   "Return any available status information on child process with PID."
 109   (multiple-value-bind (pid status)
 110       (c-waitpid pid
 111                  (logior (if do-not-hang
 112                              sb-unix:wnohang
 113                              0)
 114                          (if check-for-stopped
 115                              sb-unix:wuntraced
 116                              0)))
 117     (cond ((or (minusp pid)
 118                (zerop pid))
 119            nil)
 120           ((eql (ldb (byte 8 0) status)
 121                 sb-unix:wstopped)
 122            (values pid
 123                    :stopped
 124                    (ldb (byte 8 8) status)))
 125           ((zerop (ldb (byte 7 0) status))
 126            (values pid
 127                    :exited
 128                    (ldb (byte 8 8) status)))
 129           (t
 130            (let ((signal (ldb (byte 7 0) status)))
 131              (values pid
 132                      (if (position signal
 133                                    #.(vector
 134                                       sb-unix:sigstop
 135                                       sb-unix:sigtstp
 136                                       sb-unix:sigttin
 137                                       sb-unix:sigttou))
 138                          :stopped
 139                          :signaled)
 140                      signal
 141                      (not (zerop (ldb (byte 1 7) status)))))))))
 142 \f
 143 ;;;; process control stuff
 144 (defvar *active-processes* nil
 145   #+sb-doc
 146   "List of process structures for all active processes.")
 147
 148 (defvar *active-processes-lock*
 149   (sb-thread:make-mutex :name "Lock for active processes."))
 150
 151 ;;; *ACTIVE-PROCESSES* can be accessed from multiple threads so a
 152 ;;; mutex is needed. More importantly the sigchld signal handler also
 153 ;;; accesses it, that's why we need without-interrupts.
 154 (defmacro with-active-processes-lock (() &body body)
 155   `(sb-thread::with-system-mutex (*active-processes-lock*)
 156      ,@body))
 157
 158 (defstruct (process (:copier nil))
 159   pid                 ; PID of child process
 160   %status             ; either :RUNNING, :STOPPED, :EXITED, or :SIGNALED
 161   %exit-code          ; either exit code or signal
 162   core-dumped         ; T if a core image was dumped
 163   #-win32 pty                 ; stream to child's pty, or NIL
 164   input               ; stream to child's input, or NIL
 165   output              ; stream from child's output, or NIL
 166   error               ; stream from child's error output, or NIL
 167   status-hook         ; closure to call when PROC changes status
 168   plist               ; a place for clients to stash things
 169   cookie)             ; list of the number of pipes from the subproc
 170
 171 (defmethod print-object ((process process) stream)
 172   (print-unreadable-object (process stream :type t)
 173     (let ((status (process-status process)))
 174      (if (eq :exited status)
 175          (format stream "~S ~S" status (process-%exit-code process))
 176          (format stream "~S ~S" (process-pid process) status)))
 177     process))
 178
 179 #+sb-doc
 180 (setf (documentation 'process-p 'function)
 181       "T if OBJECT is a PROCESS, NIL otherwise.")
 182
 183 #+sb-doc
 184 (setf (documentation 'process-pid 'function) "The pid of the child process.")
 185
 186 #+win32
 187 (define-alien-routine ("GetExitCodeProcess" get-exit-code-process)
 188     int
 189   (handle unsigned) (exit-code unsigned :out))
 190
 191 (defun process-exit-code (process)
 192   #+sb-doc
 193   "Return the exit code of PROCESS."
 194   (or (process-%exit-code process)
 195       (progn (get-processes-status-changes)
 196              (process-%exit-code process))))
 197
 198 (defun process-status (process)
 199   #+sb-doc
 200   "Return the current status of PROCESS.  The result is one of :RUNNING,
 201    :STOPPED, :EXITED, or :SIGNALED."
 202   (get-processes-status-changes)
 203   (process-%status process))
 204
 205 #+sb-doc
 206 (setf (documentation 'process-exit-code 'function)
 207       "The exit code or the signal of a stopped process.")
 208
 209 #+sb-doc
 210 (setf (documentation 'process-core-dumped 'function)
 211       "T if a core image was dumped by the process.")
 212
 213 #+sb-doc
 214 (setf (documentation 'process-pty 'function)
 215       "The pty stream of the process or NIL.")
 216
 217 #+sb-doc
 218 (setf (documentation 'process-input 'function)
 219       "The input stream of the process or NIL.")
 220
 221 #+sb-doc
 222 (setf (documentation 'process-output 'function)
 223       "The output stream of the process or NIL.")
 224
 225 #+sb-doc
 226 (setf (documentation 'process-error 'function)
 227       "The error stream of the process or NIL.")
 228
 229 #+sb-doc
 230 (setf (documentation 'process-status-hook  'function)
 231       "A function that is called when PROCESS changes its status.
 232 The function is called with PROCESS as its only argument.")
 233
 234 #+sb-doc
 235 (setf (documentation 'process-plist  'function)
 236       "A place for clients to stash things.")
 237
 238 (defun process-wait (process &optional check-for-stopped)
 239   #+sb-doc
 240   "Wait for PROCESS to quit running for some reason. When
 241 CHECK-FOR-STOPPED is T, also returns when PROCESS is stopped. Returns
 242 PROCESS."
 243   (declare (ignorable check-for-stopped))
 244   #+win32
 245   (let ((pid (process-pid process)))
 246     (when (and pid (plusp pid))
 247       (without-interrupts
 248         (do ()
 249             ((= 0
 250                 (with-local-interrupts
 251                   (sb-win32:wait-object-or-signal pid))))))))
 252   #-win32
 253   (loop
 254       (case (process-status process)
 255         (:running)
 256         (:stopped
 257          (when check-for-stopped
 258            (return)))
 259         (t
 260          (when (zerop (car (process-cookie process)))
 261            (return))))
 262       (sb-sys:serve-all-events 1))
 263   process)
 264
 265 #-win32
 266 ;;; Find the current foreground process group id.
 267 (defun find-current-foreground-process (proc)
 268   (with-alien ((result sb-alien:int))
 269     (multiple-value-bind
 270           (wonp error)
 271         (sb-unix:unix-ioctl (sb-sys:fd-stream-fd (process-pty proc))
 272                             sb-unix:TIOCGPGRP
 273                             (alien-sap (sb-alien:addr result)))
 274       (unless wonp
 275         (error "TIOCPGRP ioctl failed: ~S" (strerror error)))
 276       result))
 277   (process-pid proc))
 278
 279 #-win32
 280 (defun process-kill (process signal &optional (whom :pid))
 281   #+sb-doc
 282   "Hand SIGNAL to PROCESS. If WHOM is :PID, use the kill Unix system call. If
 283    WHOM is :PROCESS-GROUP, use the killpg Unix system call. If WHOM is
 284    :PTY-PROCESS-GROUP deliver the signal to whichever process group is
 285    currently in the foreground."
 286   (let ((pid (ecase whom
 287                ((:pid :process-group)
 288                 (process-pid process))
 289                (:pty-process-group
 290                 (find-current-foreground-process process)))))
 291     (multiple-value-bind
 292           (okay errno)
 293         (case whom
 294           ((:process-group)
 295            (sb-unix:unix-killpg pid signal))
 296           (t
 297            (sb-unix:unix-kill pid signal)))
 298       (cond ((not okay)
 299              (values nil errno))
 300             ((and (eql pid (process-pid process))
 301                   (= signal sb-unix:sigcont))
 302              (setf (process-%status process) :running)
 303              (setf (process-%exit-code process) nil)
 304              (when (process-status-hook process)
 305                (funcall (process-status-hook process) process))
 306              t)
 307             (t
 308              t)))))
 309
 310 (defun process-alive-p (process)
 311   #+sb-doc
 312   "Return T if PROCESS is still alive, NIL otherwise."
 313   (let ((status (process-status process)))
 314     (if (or (eq status :running)
 315             (eq status :stopped))
 316         t
 317         nil)))
 318
 319 (defun process-close (process)
 320   #+sb-doc
 321   "Close all streams connected to PROCESS and stop maintaining the
 322 status slot."
 323   (macrolet ((frob (stream abort)
 324                `(when ,stream (close ,stream :abort ,abort))))
 325     #-win32
 326     (frob (process-pty process) t)   ; Don't FLUSH-OUTPUT to dead process,
 327     (frob (process-input process) t) ; .. 'cause it will generate SIGPIPE.
 328     (frob (process-output process) nil)
 329     (frob (process-error process) nil))
 330   ;; FIXME: Given that the status-slot is no longer updated,
 331   ;; maybe it should be set to :CLOSED, or similar?
 332   (with-active-processes-lock ()
 333    (setf *active-processes* (delete process *active-processes*)))
 334   #+win32
 335   (let ((handle (shiftf (process-pid process) nil)))
 336     (when (and handle (plusp handle))
 337       (or (sb-win32:close-handle handle)
 338           (sb-win32::win32-error 'process-close))))
 339   process)
 340
 341 (defun get-processes-status-changes ()
 342   (let (exited)
 343     (with-active-processes-lock ()
 344       (setf *active-processes*
 345             (delete-if #-win32
 346                        (lambda (proc)
 347                          ;; Wait only on pids belonging to processes
 348                          ;; started by RUN-PROGRAM. There used to be a
 349                          ;; WAIT3 call here, but that makes direct
 350                          ;; WAIT, WAITPID usage impossible due to the
 351                          ;; race with the SIGCHLD signal handler.
 352                          (multiple-value-bind (pid what code core)
 353                              (waitpid (process-pid proc) t t)
 354                            (when pid
 355                              (setf (process-%status proc) what)
 356                              (setf (process-%exit-code proc) code)
 357                              (setf (process-core-dumped proc) core)
 358                              (when (process-status-hook proc)
 359                                (push proc exited))
 360                              t)))
 361                        #+win32
 362                        (lambda (proc)
 363                          (let ((pid (process-pid proc)))
 364                            (when pid
 365                              (multiple-value-bind (ok code)
 366                                  (sb-win32::get-exit-code-process pid)
 367                                (when (and (plusp ok) (/= code 259))
 368                                  (setf (process-%status proc) :exited
 369                                        (process-%exit-code proc) code)
 370                                  (when (process-status-hook proc)
 371                                    (push proc exited))
 372                                  t)))))
 373                        *active-processes*)))
 374     ;; Can't call the hooks before all the processes have been deal
 375     ;; with, as calling a hook may cause re-entry to
 376     ;; GET-PROCESS-STATUS-CHANGES. That may be OK when using waitpid,
 377     ;; but in the Windows implementation it would be deeply bad.
 378     (dolist (proc exited)
 379       (let ((hook (process-status-hook proc)))
 380         (when hook
 381           (funcall hook proc))))))
 382 \f
 383 ;;;; RUN-PROGRAM and close friends
 384
 385 ;;; list of file descriptors to close when RUN-PROGRAM exits due to an error
 386 (defvar *close-on-error* nil)
 387
 388 ;;; list of file descriptors to close when RUN-PROGRAM returns in the parent
 389 (defvar *close-in-parent* nil)
 390
 391 ;;; list of handlers installed by RUN-PROGRAM.  FIXME: nothing seems
 392 ;;; to set this.
 393 #-win32
 394 (defvar *handlers-installed* nil)
 395
 396 ;;; Find an unused pty. Return three values: the file descriptor for
 397 ;;; the master side of the pty, the file descriptor for the slave side
 398 ;;; of the pty, and the name of the tty device for the slave side.
 399 #-(or win32 openbsd)
 400 (progn
 401   (define-alien-routine ptsname c-string (fd int))
 402   (define-alien-routine grantpt boolean (fd int))
 403   (define-alien-routine unlockpt boolean (fd int))
 404
 405   (defun find-a-pty ()
 406     ;; First try to use the Unix98 pty api.
 407     (let* ((master-name (coerce (format nil "/dev/ptmx") 'base-string))
 408            (master-fd (sb-unix:unix-open master-name
 409                                          (logior sb-unix:o_rdwr
 410                                                  sb-unix:o_noctty)
 411                                          #o666)))
 412       (when master-fd
 413         (grantpt master-fd)
 414         (unlockpt master-fd)
 415         (let* ((slave-name (ptsname master-fd))
 416                (slave-fd (sb-unix:unix-open slave-name
 417                                             (logior sb-unix:o_rdwr
 418                                                     sb-unix:o_noctty)
 419                                             #o666)))
 420           (when slave-fd
 421             (return-from find-a-pty
 422               (values master-fd
 423                       slave-fd
 424                       slave-name)))
 425           (sb-unix:unix-close master-fd))
 426         (error "could not find a pty")))
 427     ;; No dice, try using the old-school method.
 428     (dolist (char '(#\p #\q))
 429       (dotimes (digit 16)
 430         (let* ((master-name (coerce (format nil "/dev/pty~C~X" char digit)
 431                                     'base-string))
 432                (master-fd (sb-unix:unix-open master-name
 433                                              (logior sb-unix:o_rdwr
 434                                                      sb-unix:o_noctty)
 435                                              #o666)))
 436           (when master-fd
 437             (let* ((slave-name (coerce (format nil "/dev/tty~C~X" char digit)
 438                                        'base-string))
 439                    (slave-fd (sb-unix:unix-open slave-name
 440                                                 (logior sb-unix:o_rdwr
 441                                                         sb-unix:o_noctty)
 442                                                 #o666)))
 443               (when slave-fd
 444                 (return-from find-a-pty
 445                   (values master-fd
 446                           slave-fd
 447                           slave-name)))
 448               (sb-unix:unix-close master-fd))))))
 449     (error "could not find a pty")))
 450 #+openbsd
 451 (progn
 452   (define-alien-routine openpty int (amaster int :out) (aslave int :out)
 453                         (name (* char)) (termp (* t)) (winp (* t)))
 454   (defun find-a-pty ()
 455     (with-alien ((name-buf (array char 16)))
 456       (multiple-value-bind (return-val master-fd slave-fd)
 457           (openpty (cast name-buf (* char)) nil nil)
 458         (if (zerop return-val)
 459             (values master-fd
 460                     slave-fd
 461                     (sb-alien::c-string-to-string (alien-sap name-buf)
 462                                                   (sb-impl::default-external-format)
 463                                                   'character))
 464             (error "could not find a pty"))))))
 465
 466 #-win32
 467 (defun open-pty (pty cookie &key (external-format :default))
 468   (when pty
 469     (multiple-value-bind
 470           (master slave name)
 471         (find-a-pty)
 472       (push master *close-on-error*)
 473       (push slave *close-in-parent*)
 474       (when (streamp pty)
 475         (multiple-value-bind (new-fd errno) (sb-unix:unix-dup master)
 476           (unless new-fd
 477             (error "couldn't SB-UNIX:UNIX-DUP ~W: ~A" master (strerror errno)))
 478           (push new-fd *close-on-error*)
 479           (copy-descriptor-to-stream new-fd pty cookie external-format)))
 480       (values name
 481               (sb-sys:make-fd-stream master :input t :output t
 482                                      :external-format external-format
 483                                      :element-type :default
 484                                      :dual-channel-p t)))))
 485
 486 ;; Null terminate strings only C-side: otherwise we can run into
 487 ;; A-T-S-L even for simple encodings like ASCII.  Multibyte encodings
 488 ;; may need more than a single byte of zeros; assume 4 byte is enough
 489 ;; for everyone.
 490 (defmacro round-null-terminated-bytes-to-words (n)
 491   (let ((bytes-per-word (/ sb-vm:n-machine-word-bits sb-vm:n-byte-bits)))
 492     `(logandc2 (the sb-vm:signed-word (+ (the fixnum ,n)
 493                                          4 (1- ,bytes-per-word)))
 494                (1- ,bytes-per-word))))
 495
 496 (defun string-list-to-c-strvec (string-list)
 497   (let* ((bytes-per-word (/ sb-vm:n-machine-word-bits sb-vm:n-byte-bits))
 498          ;; We need an extra for the null, and an extra 'cause exect
 499          ;; clobbers argv[-1].
 500          (vec-bytes (* bytes-per-word (+ (length string-list) 2)))
 501          (octet-vector-list (mapcar (lambda (s)
 502                                       (string-to-octets s))
 503                                     string-list))
 504          (string-bytes (reduce #'+ octet-vector-list
 505                                :key (lambda (s)
 506                                       (round-null-terminated-bytes-to-words
 507                                        (length s)))))
 508          (total-bytes (+ string-bytes vec-bytes))
 509          ;; Memory to hold the vector of pointers and all the strings.
 510          (vec-sap (sb-sys:allocate-system-memory total-bytes))
 511          (string-sap (sap+ vec-sap vec-bytes))
 512          ;; Index starts from [1]!
 513          (vec-index-offset bytes-per-word))
 514     (declare (sb-vm:signed-word vec-bytes)
 515              (sb-vm:word string-bytes total-bytes)
 516              (sb-sys:system-area-pointer vec-sap string-sap))
 517     (dolist (octets octet-vector-list)
 518       (declare (type (simple-array (unsigned-byte 8) (*)) octets))
 519       (let ((size (length octets)))
 520         ;; Copy string.
 521         (sb-kernel:copy-ub8-to-system-area octets 0 string-sap 0 size)
 522         ;; NULL-terminate it
 523         (sb-kernel:system-area-ub8-fill 0 string-sap size 4)
 524         ;; Put the pointer in the vector.
 525         (setf (sap-ref-sap vec-sap vec-index-offset) string-sap)
 526         ;; Advance string-sap for the next string.
 527         (setf string-sap (sap+ string-sap
 528                                (round-null-terminated-bytes-to-words size)))
 529         (incf vec-index-offset bytes-per-word)))
 530     ;; Final null pointer.
 531     (setf (sap-ref-sap vec-sap vec-index-offset) (int-sap 0))
 532     (values vec-sap (sap+ vec-sap bytes-per-word) total-bytes)))
 533
 534 (defmacro with-c-strvec ((var str-list &key null) &body body)
 535   (once-only ((null null))
 536     (with-unique-names (sap size)
 537       `(multiple-value-bind (,sap ,var ,size)
 538            (if ,null
 539                (values nil (sb-sys:int-sap 0))
 540                (string-list-to-c-strvec ,str-list))
 541          (unwind-protect
 542               (progn
 543                 ,@body)
 544            (unless ,null
 545              (sb-sys:deallocate-system-memory ,sap ,size)))))))
 546
 547 (sb-alien:define-alien-routine spawn
 548     #-win32 sb-alien:int
 549     #+win32 sb-win32::handle
 550   (program sb-alien:c-string)
 551   (argv (* sb-alien:c-string))
 552   (stdin sb-alien:int)
 553   (stdout sb-alien:int)
 554   (stderr sb-alien:int)
 555   (search sb-alien:int)
 556   (envp (* sb-alien:c-string))
 557   (pty-name sb-alien:c-string)
 558   (wait sb-alien:int)
 559   (pwd sb-alien:c-string))
 560
 561 ;;; FIXME: There shouldn't be two semiredundant versions of the
 562 ;;; documentation. Since this is a public extension function, the
 563 ;;; documentation should be in the doc string. So all information from
 564 ;;; this comment should be merged into the doc string, and then this
 565 ;;; comment can go away.
 566 ;;;
 567 ;;; RUN-PROGRAM uses fork() and execve() to run a different program.
 568 ;;; Strange stuff happens to keep the Unix state of the world
 569 ;;; coherent.
 570 ;;;
 571 ;;; The child process needs to get its input from somewhere, and send
 572 ;;; its output (both standard and error) to somewhere. We have to do
 573 ;;; different things depending on where these somewheres really are.
 574 ;;;
 575 ;;; For input, there are five options:
 576 ;;;  -- T: Just leave fd 0 alone. Pretty simple.
 577 ;;;  -- "file": Read from the file. We need to open the file and
 578 ;;;     pull the descriptor out of the stream. The parent should close
 579 ;;;     this stream after the child is up and running to free any
 580 ;;;     storage used in the parent.
 581 ;;;  -- NIL: Same as "file", but use "/dev/null" as the file.
 582 ;;;  -- :STREAM: Use Unix pipe() to create two descriptors. Use
 583 ;;;     SB-SYS:MAKE-FD-STREAM to create the output stream on the
 584 ;;;     writeable descriptor, and pass the readable descriptor to
 585 ;;;     the child. The parent must close the readable descriptor for
 586 ;;;     EOF to be passed up correctly.
 587 ;;;  -- a stream: If it's a fd-stream, just pull the descriptor out
 588 ;;;     of it. Otherwise make a pipe as in :STREAM, and copy
 589 ;;;     everything across.
 590 ;;;
 591 ;;; For output, there are five options:
 592 ;;;  -- T: Leave descriptor 1 alone.
 593 ;;;  -- "file": dump output to the file.
 594 ;;;  -- NIL: dump output to /dev/null.
 595 ;;;  -- :STREAM: return a stream that can be read from.
 596 ;;;  -- a stream: if it's a fd-stream, use the descriptor in it.
 597 ;;;     Otherwise, copy stuff from output to stream.
 598 ;;;
 599 ;;; For error, there are all the same options as output plus:
 600 ;;;  -- :OUTPUT: redirect to the same place as output.
 601 ;;;
 602 ;;; RUN-PROGRAM returns a PROCESS structure for the process if
 603 ;;; the fork worked, and NIL if it did not.
 604 (defun run-program (program args
 605                     &key
 606                     #-win32 (env nil env-p)
 607                     #-win32 (environment
 608                              (when env-p
 609                                (unix-environment-sbcl-from-cmucl env))
 610                              environment-p)
 611                     (wait t)
 612                     search
 613                     #-win32 pty
 614                     input
 615                     if-input-does-not-exist
 616                     output
 617                     (if-output-exists :error)
 618                     (error :output)
 619                     (if-error-exists :error)
 620                     status-hook
 621                     (external-format :default)
 622                     (directory nil directory-p))
 623   #+sb-doc
 624   #.(concatenate
 625      'string
 626      ;; The Texinfoizer is sensitive to whitespace, so mind the
 627      ;; placement of the #-win32 pseudosplicings.
 628      "RUN-PROGRAM creates a new process specified by the PROGRAM
 629 argument. ARGS are the standard arguments that can be passed to a
 630 program. For no arguments, use NIL (which means that just the
 631 name of the program is passed as arg 0).
 632
 633 The program arguments and the environment are encoded using the
 634 default external format for streams.
 635
 636 RUN-PROGRAM will return a PROCESS structure. See the CMU Common Lisp
 637 Users Manual for details about the PROCESS structure."#-win32"
 638
 639    Notes about Unix environments (as in the :ENVIRONMENT and :ENV args):
 640
 641    - The SBCL implementation of RUN-PROGRAM, like Perl and many other
 642      programs, but unlike the original CMU CL implementation, copies
 643      the Unix environment by default.
 644
 645    - Running Unix programs from a setuid process, or in any other
 646      situation where the Unix environment is under the control of someone
 647      else, is a mother lode of security problems. If you are contemplating
 648      doing this, read about it first. (The Perl community has a lot of good
 649      documentation about this and other security issues in script-like
 650      programs.)""
 651
 652    The &KEY arguments have the following meanings:
 653 "#-win32"
 654    :ENVIRONMENT
 655       a list of STRINGs describing the new Unix environment
 656       (as in \"man environ\"). The default is to copy the environment of
 657       the current process.
 658    :ENV
 659       an alternative lossy representation of the new Unix environment,
 660       for compatibility with CMU CL""
 661    :SEARCH
 662       Look for PROGRAM in each of the directories in the child's $PATH
 663       environment variable.  Otherwise an absolute pathname is required.
 664    :WAIT
 665       If non-NIL (default), wait until the created process finishes.  If
 666       NIL, continue running Lisp until the program finishes."#-win32"
 667    :PTY
 668       Either T, NIL, or a stream.  Unless NIL, the subprocess is established
 669       under a PTY.  If :pty is a stream, all output to this pty is sent to
 670       this stream, otherwise the PROCESS-PTY slot is filled in with a stream
 671       connected to pty that can read output and write input.""
 672    :INPUT
 673       Either T, NIL, a pathname, a stream, or :STREAM.  If T, the standard
 674       input for the current process is inherited.  If NIL, "
 675       #-win32"/dev/null"#+win32"nul""
 676       is used.  If a pathname, the file so specified is used.  If a stream,
 677       all the input is read from that stream and sent to the subprocess.  If
 678       :STREAM, the PROCESS-INPUT slot is filled in with a stream that sends
 679       its output to the process. Defaults to NIL.
 680    :IF-INPUT-DOES-NOT-EXIST (when :INPUT is the name of a file)
 681       can be one of:
 682          :ERROR to generate an error
 683          :CREATE to create an empty file
 684          NIL (the default) to return NIL from RUN-PROGRAM
 685    :OUTPUT
 686       Either T, NIL, a pathname, a stream, or :STREAM.  If T, the standard
 687       output for the current process is inherited.  If NIL, "
 688       #-win32"/dev/null"#+win32"nul""
 689       is used.  If a pathname, the file so specified is used.  If a stream,
 690       all the output from the process is written to this stream. If
 691       :STREAM, the PROCESS-OUTPUT slot is filled in with a stream that can
 692       be read to get the output. Defaults to NIL.
 693    :IF-OUTPUT-EXISTS (when :OUTPUT is the name of a file)
 694       can be one of:
 695          :ERROR (the default) to generate an error
 696          :SUPERSEDE to supersede the file with output from the program
 697          :APPEND to append output from the program to the file
 698          NIL to return NIL from RUN-PROGRAM, without doing anything
 699    :ERROR and :IF-ERROR-EXISTS
 700       Same as :OUTPUT and :IF-OUTPUT-EXISTS, except that :ERROR can also be
 701       specified as :OUTPUT in which case all error output is routed to the
 702       same place as normal output.
 703    :STATUS-HOOK
 704       This is a function the system calls whenever the status of the
 705       process changes.  The function takes the process as an argument.
 706    :EXTERNAL-FORMAT
 707       The external-format to use for :INPUT, :OUTPUT, and :ERROR :STREAMs.")
 708   #-win32
 709   (when (and env-p environment-p)
 710     (error "can't specify :ENV and :ENVIRONMENT simultaneously"))
 711   ;; Prepend the program to the argument list.
 712   (push (namestring program) args)
 713   (labels (;; It's friendly to allow the caller to pass any string
 714            ;; designator, but internally we'd like SIMPLE-STRINGs.
 715            ;;
 716            ;; Huh?  We let users pass in symbols and characters for
 717            ;; the arguments, but call NAMESTRING on the program
 718            ;; name... -- RMK
 719            (simplify-args (args)
 720              (loop for arg in args
 721                    as escaped-arg = (escape-arg arg)
 722                    collect (coerce escaped-arg 'simple-string)))
 723            (escape-arg (arg)
 724              #-win32 arg
 725              ;; Apparently any spaces or double quotes in the arguments
 726              ;; need to be escaped on win32.
 727              #+win32 (if (position-if
 728                           (lambda (c) (find c '(#\" #\Space))) arg)
 729                          (write-to-string arg)
 730                          arg)))
 731     (let (;; Clear various specials used by GET-DESCRIPTOR-FOR to
 732           ;; communicate cleanup info.
 733           *close-on-error*
 734           *close-in-parent*
 735           ;; Some other binding used only on non-Win32.  FIXME:
 736           ;; nothing seems to set this.
 737           #-win32 *handlers-installed*
 738           ;; Establish PROC at this level so that we can return it.
 739           proc
 740           (simple-args (simplify-args args))
 741           (progname (native-namestring program))
 742           ;; Gag.
 743           (cookie (list 0)))
 744       (unwind-protect
 745            ;; Note: despite the WITH-* names, these macros don't
 746            ;; expand into UNWIND-PROTECT forms.  They're just
 747            ;; syntactic sugar to make the rest of the routine slightly
 748            ;; easier to read.
 749            (macrolet ((with-no-with
 750                           ((&optional no)
 751                            (&whole form with-something parameters &body body))
 752                         (declare (ignore with-something parameters))
 753                         (typecase no
 754                           (keyword `(progn ,@body))
 755                           (null form)
 756                           (t `(let ,no (declare (ignorable ,@no)) ,@body))))
 757                       (with-fd-and-stream-for (((fd stream) which &rest args)
 758                                                &body body)
 759                         `(multiple-value-bind (,fd ,stream)
 760                              ,(ecase which
 761                                 ((:input :output)
 762                                  `(get-descriptor-for ,@args))
 763                                 (:error
 764                                  `(if (eq ,(first args) :output)
 765                                       ;; kludge: we expand into
 766                                       ;; hard-coded symbols here.
 767                                       (values stdout output-stream)
 768                                       (get-descriptor-for ,@args))))
 769                            (unless ,fd
 770                              (return-from run-program))
 771                            ,@body))
 772                       (with-open-pty (((pty-name pty-stream) (pty cookie))
 773                                       &body body)
 774                         `(multiple-value-bind (,pty-name ,pty-stream)
 775                              (open-pty ,pty ,cookie :external-format external-format)
 776                            ,@body))
 777                       (with-args-vec ((vec args) &body body)
 778                         `(with-c-strvec (,vec ,args)
 779                            ,@body))
 780                       (with-environment-vec ((vec) &body body)
 781                         #+win32 `(let (,vec) ,@body)
 782                         #-win32
 783                         `(with-c-strvec
 784                              (,vec environment
 785                               :null (not (or environment environment-p)))
 786                            ,@body)))
 787              (with-fd-and-stream-for ((stdin input-stream) :input
 788                                       input cookie
 789                                       :direction :input
 790                                       :if-does-not-exist if-input-does-not-exist
 791                                       :external-format external-format
 792                                       :wait wait)
 793                (with-fd-and-stream-for ((stdout output-stream) :output
 794                                         output cookie
 795                                         :direction :output
 796                                         :if-exists if-output-exists
 797                                         :external-format external-format)
 798                  (with-fd-and-stream-for ((stderr error-stream)  :error
 799                                           error cookie
 800                                           :direction :output
 801                                           :if-exists if-error-exists
 802                                           :external-format external-format)
 803                    (with-no-with (#+win32 (pty-name pty-stream))
 804                      (with-open-pty ((pty-name pty-stream) (pty cookie))
 805                        ;; Make sure we are not notified about the child
 806                        ;; death before we have installed the PROCESS
 807                        ;; structure in *ACTIVE-PROCESSES*.
 808                        (let (child)
 809                          (with-active-processes-lock ()
 810                            (with-no-with (#+win32 (args-vec))
 811                              (with-args-vec (args-vec simple-args)
 812                                (with-no-with (#+win32 (environment-vec))
 813                                  (with-environment-vec (environment-vec)
 814                                    (let ((pwd-string
 815                                            (and directory-p (native-namestring directory))))
 816                                      (setq child
 817                                            #+win32
 818                                            (sb-win32::mswin-spawn
 819                                             progname
 820                                             (with-output-to-string (argv)
 821                                               (dolist (arg simple-args)
 822                                                 (write-string arg argv)
 823                                                 (write-char #\Space argv)))
 824                                             stdin stdout stderr
 825                                             search nil wait pwd-string)
 826                                            #-win32
 827                                            (without-gcing
 828                                              (spawn progname args-vec
 829                                                     stdin stdout stderr
 830                                                     (if search 1 0)
 831                                                     environment-vec pty-name
 832                                                     (if wait 1 0)
 833                                                     pwd-string))))
 834                                    (unless (minusp child)
 835                                      (setf proc
 836                                            (apply
 837                                             #'make-process
 838                                             :input input-stream
 839                                             :output output-stream
 840                                             :error error-stream
 841                                             :status-hook status-hook
 842                                             :cookie cookie
 843                                             #-win32 (list :pty pty-stream
 844                                                           :%status :running
 845                                                           :pid child)
 846                                             #+win32 (if wait
 847                                                         (list :%status :exited
 848                                                               :%exit-code child)
 849                                                         (list :%status :running
 850                                                               :pid child))))
 851                                      (push proc *active-processes*)))))))
 852                          ;; Report the error outside the lock.
 853                          (case child
 854                            (-1
 855                             (error "Couldn't fork child process: ~A"
 856                                    (strerror)))
 857                            (-2
 858                             (error "Couldn't execute ~S: ~A"
 859                                    progname (strerror)))
 860                            (-3
 861                             (error "Couldn't change directory to ~S: ~A"
 862                                    directory (strerror)))))))))))
 863         (dolist (fd *close-in-parent*)
 864           (sb-unix:unix-close fd))
 865         (unless proc
 866           (dolist (fd *close-on-error*)
 867             (sb-unix:unix-close fd))
 868           #-win32
 869           (dolist (handler *handlers-installed*)
 870             (sb-sys:remove-fd-handler handler)))
 871         #-win32
 872         (when (and wait proc)
 873           (unwind-protect
 874                (process-wait proc)
 875             (dolist (handler *handlers-installed*)
 876               (sb-sys:remove-fd-handler handler)))))
 877       proc)))
 878
 879 ;;; Install a handler for any input that shows up on the file
 880 ;;; descriptor. The handler reads the data and writes it to the
 881 ;;; stream.
 882 (defun copy-descriptor-to-stream (descriptor stream cookie external-format)
 883   (incf (car cookie))
 884   (let* ((handler nil)
 885          (buf (make-array 256 :element-type '(unsigned-byte 8)))
 886          (read-end 0)
 887          (et (stream-element-type stream))
 888          (copy-fun
 889           (cond
 890             ((member et '(character base-char))
 891              (lambda ()
 892                (let* ((decode-end read-end)
 893                       (string (handler-case
 894                                   (octets-to-string
 895                                    buf :end read-end
 896                                    :external-format external-format)
 897                                 (end-of-input-in-character (e)
 898                                   (setf decode-end
 899                                         (octet-decoding-error-start e))
 900                                   (octets-to-string
 901                                    buf :end decode-end
 902                                    :external-format external-format)))))
 903                  (unless (zerop (length string))
 904                    (write-string string stream)
 905                    (when (/= decode-end (length buf))
 906                      (replace buf buf :start2 decode-end :end2 read-end))
 907                    (decf read-end decode-end)))))
 908             ((member et '(:default (unsigned-byte 8)) :test #'equal)
 909              (lambda ()
 910                (write-sequence buf stream :end read-end)
 911                (setf read-end 0)))
 912             (t
 913              ;; FIXME.
 914              (error "Don't know how to copy to stream of element-type ~S"
 915                     et)))))
 916     (setf handler
 917           (sb-sys:add-fd-handler
 918            descriptor
 919            :input
 920            (lambda (fd)
 921              (declare (ignore fd))
 922              (loop
 923                 (unless handler
 924                   (return))
 925                 (multiple-value-bind
 926                       (result readable/errno)
 927                     (sb-unix:unix-select (1+ descriptor)
 928                                          (ash 1 descriptor)
 929                                          0 0 0)
 930                   (cond ((null result)
 931                          (if (eql sb-unix:eintr readable/errno)
 932                              (return)
 933                              (error "~@<Couldn't select on sub-process: ~
 934                                         ~2I~_~A~:>"
 935                                     (strerror readable/errno))))
 936                         ((zerop result)
 937                          (return))))
 938                 (multiple-value-bind (count errno)
 939                     (with-pinned-objects (buf)
 940                       (sb-unix:unix-read descriptor
 941                                          (sap+ (vector-sap buf) read-end)
 942                                          (- (length buf) read-end)))
 943                   (cond
 944                     ((and #-win32 (or (and (null count)
 945                                            (eql errno sb-unix:eio))
 946                                       (eql count 0))
 947                           #+win32 (<= count 0))
 948                      (sb-sys:remove-fd-handler handler)
 949                      (setf handler nil)
 950                      (decf (car cookie))
 951                      (sb-unix:unix-close descriptor)
 952                      (unless (zerop read-end)
 953                        ;; Should this be an END-OF-FILE?
 954                        (error "~@<non-empty buffer when EOF reached ~
 955                                while reading from child: ~S~:>" buf))
 956                      (return))
 957                     ((null count)
 958                      (sb-sys:remove-fd-handler handler)
 959                      (setf handler nil)
 960                      (decf (car cookie))
 961                      (error
 962                       "~@<couldn't read input from sub-process: ~
 963                                      ~2I~_~A~:>"
 964                       (strerror errno)))
 965                     (t
 966                      (incf read-end count)
 967                      (funcall copy-fun))))))))
 968     #-win32
 969     (push handler *handlers-installed*)))
 970
 971 ;;; FIXME: something very like this is done in SB-POSIX to treat
 972 ;;; streams as file descriptor designators; maybe we can combine these
 973 ;;; two?  Additionally, as we have a couple of user-defined streams
 974 ;;; libraries, maybe we should have a generic function for doing this,
 975 ;;; so user-defined streams can play nicely with RUN-PROGRAM (and
 976 ;;; maybe also with SB-POSIX)?
 977 (defun get-stream-fd-and-external-format (stream direction)
 978   (typecase stream
 979     (sb-sys:fd-stream
 980      (values (sb-sys:fd-stream-fd stream) nil (stream-external-format stream)))
 981     (synonym-stream
 982      (get-stream-fd-and-external-format
 983       (symbol-value (synonym-stream-symbol stream)) direction))
 984     (two-way-stream
 985      (ecase direction
 986        (:input
 987         (get-stream-fd-and-external-format
 988          (two-way-stream-input-stream stream) direction))
 989        (:output
 990         (get-stream-fd-and-external-format
 991          (two-way-stream-output-stream stream) direction))))))
 992
 993 (defun get-temporary-directory ()
 994   #-win32 (or (sb-ext:posix-getenv "TMPDIR")
 995               "/tmp")
 996   #+win32 (or (sb-ext:posix-getenv "TEMP")
 997               "C:/Temp"))
 998
 999 \f
1000 ;;; Find a file descriptor to use for object given the direction.
1001 ;;; Returns the descriptor. If object is :STREAM, returns the created
1002 ;;; stream as the second value.
1003 (defun get-descriptor-for (object
1004                            cookie
1005                            &rest keys
1006                            &key direction (external-format :default) wait
1007                            &allow-other-keys)
1008   (declare (ignore wait)) ;This is explained below.
1009   ;; Our use of a temporary file dates back to very old CMUCLs, and
1010   ;; was probably only ever intended for use with STRING-STREAMs,
1011   ;; which are ordinarily smallish.  However, as we've got
1012   ;; user-defined stream classes, we can end up trying to copy
1013   ;; arbitrarily much data into the temp file, and so are liable to
1014   ;; run afoul of disk quotas or to choke on small /tmp file systems.
1015   (flet ((make-temp-fd ()
1016            (multiple-value-bind (fd name/errno)
1017                (sb-unix:sb-mkstemp (format nil "~a/.run-program-XXXXXX"
1018                                            (get-temporary-directory))
1019                                    #o0600)
1020              (unless fd
1021                (error "could not open a temporary file: ~A"
1022                       (strerror name/errno)))
1023              ;; Can't unlink an opened file on Windows
1024              #-win32
1025              (unless (sb-unix:unix-unlink name/errno)
1026                (sb-unix:unix-close fd)
1027                (error "failed to unlink ~A" name/errno))
1028              fd)))
1029     (let ((dev-null #.(coerce #-win32 "/dev/null" #+win32 "nul" 'base-string)))
1030       (cond ((eq object t)
1031              ;; No new descriptor is needed.
1032              (values -1 nil))
1033             ((or (eq object nil)
1034                  (and (typep object 'broadcast-stream)
1035                       (not (broadcast-stream-streams object))))
1036              ;; Use /dev/null.
1037              (multiple-value-bind
1038                    (fd errno)
1039                  (sb-unix:unix-open dev-null
1040                                     (case direction
1041                                       (:input sb-unix:o_rdonly)
1042                                       (:output sb-unix:o_wronly)
1043                                       (t sb-unix:o_rdwr))
1044                                     #o666)
1045                (unless fd
1046                  (error "~@<couldn't open ~S: ~2I~_~A~:>"
1047                         dev-null (strerror errno)))
1048                #+win32
1049                (setf (sb-win32::inheritable-handle-p fd) t)
1050                (push fd *close-in-parent*)
1051                (values fd nil)))
1052             ((eq object :stream)
1053              (multiple-value-bind (read-fd write-fd) (sb-unix:unix-pipe)
1054                (unless read-fd
1055                  (error "couldn't create pipe: ~A" (strerror write-fd)))
1056                #+win32
1057                (setf (sb-win32::inheritable-handle-p read-fd)
1058                      (eq direction :input)
1059                      (sb-win32::inheritable-handle-p write-fd)
1060                      (eq direction :output))
1061                (case direction
1062                  (:input
1063                     (push read-fd *close-in-parent*)
1064                     (push write-fd *close-on-error*)
1065                     (let ((stream (sb-sys:make-fd-stream write-fd :output t
1066                                                          :element-type :default
1067                                                          :external-format
1068                                                          external-format)))
1069                       (values read-fd stream)))
1070                  (:output
1071                     (push read-fd *close-on-error*)
1072                     (push write-fd *close-in-parent*)
1073                     (let ((stream (sb-sys:make-fd-stream read-fd :input t
1074                                                          :element-type :default
1075                                                          :external-format
1076                                                          external-format)))
1077                       (values write-fd stream)))
1078                  (t
1079                     (sb-unix:unix-close read-fd)
1080                     (sb-unix:unix-close write-fd)
1081                     (error "Direction must be either :INPUT or :OUTPUT, not ~S."
1082                            direction)))))
1083             ((or (pathnamep object) (stringp object))
1084              ;; GET-DESCRIPTOR-FOR uses &allow-other-keys, so rather
1085              ;; than munge the &rest list for OPEN, just disable keyword
1086              ;; validation there.
1087              (with-open-stream (file (apply #'open object :allow-other-keys t
1088                                             keys))
1089                (when file
1090                  (multiple-value-bind
1091                        (fd errno)
1092                      (sb-unix:unix-dup (sb-sys:fd-stream-fd file))
1093                    (cond (fd
1094                           (push fd *close-in-parent*)
1095                           (values fd nil))
1096                          (t
1097                           (error "couldn't duplicate file descriptor: ~A"
1098                                  (strerror errno))))))))
1099           ((streamp object)
1100            (ecase direction
1101              (:input
1102               (block nil
1103                 ;; If we can get an fd for the stream, let the child
1104                 ;; process use the fd for its descriptor.  Otherwise,
1105                 ;; we copy data from the stream into a temp file, and
1106                 ;; give the temp file's descriptor to the
1107                 ;; child.
1108                 (multiple-value-bind (fd stream format)
1109                     (get-stream-fd-and-external-format object :input)
1110                   (declare (ignore format))
1111                   (when fd
1112                     (return (values fd stream))))
1113                 ;; FIXME: if we can't get the file descriptor, since
1114                 ;; the stream might be interactive or otherwise
1115                 ;; block-y, we can't know whether we can copy the
1116                 ;; stream's data to a temp file, so if RUN-PROGRAM was
1117                 ;; called with :WAIT NIL, we should probably error.
1118                 ;; However, STRING-STREAMs aren't fd-streams, but
1119                 ;; they're not prone to blocking; any user-defined
1120                 ;; streams that "read" from some in-memory data will
1121                 ;; probably be similar to STRING-STREAMs.  So maybe we
1122                 ;; should add a STREAM-INTERACTIVE-P generic function
1123                 ;; for problems like this?  Anyway, the machinery is
1124                 ;; here, if you feel like filling in the details.
1125                 #|
1126                 (when (and (null wait) #<some undetermined criterion>)
1127                   (error "~@<don't know how to get an fd for ~A, and so ~
1128                              can't ensure that copying its data to the ~
1129                              child process won't hang~:>" object))
1130                 |#
1131                 (let ((fd (make-temp-fd))
1132                       (et (stream-element-type object)))
1133                   (cond ((member et '(character base-char))
1134                          (loop
1135                            (multiple-value-bind
1136                                  (line no-cr)
1137                                (read-line object nil nil)
1138                              (unless line
1139                                (return))
1140                              (let ((vector (string-to-octets
1141                                             line
1142                                             :external-format external-format)))
1143                                (sb-unix:unix-write
1144                                 fd vector 0 (length vector)))
1145                              (if no-cr
1146                                (return)
1147                                (sb-unix:unix-write
1148                                 fd #.(string #\Newline) 0 1)))))
1149                         ((member et '(:default (unsigned-byte 8))
1150                                  :test 'equal)
1151                          (loop with buf = (make-array 256 :element-type '(unsigned-byte 8))
1152                                for p = (read-sequence buf object)
1153                                until (zerop p)
1154                                do (sb-unix:unix-write fd buf 0 p)))
1155                         (t
1156                          (error "Don't know how to copy from stream of element-type ~S"
1157                                 et)))
1158                   (sb-unix:unix-lseek fd 0 sb-unix:l_set)
1159                   (push fd *close-in-parent*)
1160                   (return (values fd nil)))))
1161              (:output
1162               (block nil
1163                 ;; Similar to the :input trick above, except we
1164                 ;; arrange to copy data from the stream.  This is
1165                 ;; slightly saner than the input case, since we don't
1166                 ;; buffer to a file, but I think we may still lose if
1167                 ;; there's unflushed data in the stream buffer and we
1168                 ;; give the file descriptor to the child.
1169                 (multiple-value-bind (fd stream format)
1170                     (get-stream-fd-and-external-format object :output)
1171                   (declare (ignore format))
1172                   (when fd
1173                     (return (values fd stream))))
1174                 (multiple-value-bind (read-fd write-fd)
1175                     (sb-unix:unix-pipe)
1176                   (unless read-fd
1177                     (error "couldn't create pipe: ~S" (strerror write-fd)))
1178                   (copy-descriptor-to-stream read-fd object cookie
1179                                              external-format)
1180                   (push read-fd *close-on-error*)
1181                   (push write-fd *close-in-parent*)
1182                   (return (values write-fd nil)))))
1183              (t
1184               (error "invalid option to RUN-PROGRAM: ~S" object))))))))