src/code/run-program.lisp

   1 ;;;; RUN-PROGRAM and friends, a facility for running Unix programs
   2 ;;;; from inside SBCL
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB-IMPL") ;(SB-IMPL, not SB!IMPL, since we're built in warm load.)
  14 \f
  15 ;;;; hacking the Unix environment
  16 ;;;;
  17 ;;;; In the original CMU CL code that LOAD-FOREIGN is derived from, the
  18 ;;;; Unix environment (as in "man environ") was represented as an
  19 ;;;; alist from keywords to strings, so that e.g. the Unix environment
  20 ;;;;   "SHELL=/bin/bash" "HOME=/root" "PAGER=less"
  21 ;;;; was represented as
  22 ;;;;   ((:SHELL . "/bin/bash") (:HOME . "/root") (:PAGER "less"))
  23 ;;;; This had a few problems in principle: the mapping into
  24 ;;;; keyword symbols smashed the case of environment
  25 ;;;; variables, and the whole mapping depended on the presence of
  26 ;;;; #\= characters in the environment strings. In practice these
  27 ;;;; problems weren't hugely important, since conventionally environment
  28 ;;;; variables are uppercase strings followed by #\= followed by
  29 ;;;; arbitrary data. However, since it's so manifestly not The Right
  30 ;;;; Thing to make code which breaks unnecessarily on input which
  31 ;;;; doesn't follow what is, after all, only a tradition, we've switched
  32 ;;;; formats in SBCL, so that the fundamental environment list
  33 ;;;; is just a list of strings, with a one-to-one-correspondence
  34 ;;;; to the C-level representation. I.e., in the example above,
  35 ;;;; the SBCL representation is
  36 ;;;;   '("SHELL=/bin/bash" "HOME=/root" "PAGER=less")
  37 ;;;; CMU CL's implementation is currently supported to help with porting.
  38 ;;;;
  39 ;;;; It's not obvious that this code belongs here (instead of e.g. in
  40 ;;;; unix.lisp), since it has only a weak logical connection with
  41 ;;;; RUN-PROGRAM. However, physically it's convenient to put it here.
  42 ;;;; It's not needed at cold init, so we *can* put it in this
  43 ;;;; warm-loaded file. And by putting it in this warm-loaded file, we
  44 ;;;; make it easy for it to get to the C-level 'environ' variable.
  45 ;;;; which (at least in sbcl-0.6.10 on Red Hat Linux 6.2) is not
  46 ;;;; visible at GENESIS time.
  47
  48 #-win32
  49 (progn
  50   (define-alien-routine wrapped-environ (* c-string))
  51   (defun posix-environ ()
  52     "Return the Unix environment (\"man environ\") as a list of SIMPLE-STRINGs."
  53     (c-strings->string-list (wrapped-environ))))
  54
  55 ;#+win32 (sb-alien:define-alien-routine msvcrt-environ (* c-string))
  56
  57 ;;; Convert as best we can from an SBCL representation of a Unix
  58 ;;; environment to a CMU CL representation.
  59 ;;;
  60 ;;; * (UNIX-ENVIRONMENT-CMUCL-FROM-SBCL '("Bletch=fub" "Noggin" "YES=No!"))
  61 ;;; WARNING:
  62 ;;;   smashing case of "Bletch=fub" in conversion to CMU-CL-style
  63 ;;;     environment alist
  64 ;;; WARNING:
  65 ;;;   no #\= in "Noggin", eliding it in CMU-CL-style environment alist
  66 ;;; ((:BLETCH . "fub") (:YES . "No!"))
  67 (defun unix-environment-cmucl-from-sbcl (sbcl)
  68   (mapcan
  69    (lambda (string)
  70      (declare (string string))
  71      (let ((=-pos (position #\= string :test #'equal)))
  72        (if =-pos
  73            (list
  74             (let* ((key-as-string (subseq string 0 =-pos))
  75                    (key-as-upcase-string (string-upcase key-as-string))
  76                    (key (keywordicate key-as-upcase-string))
  77                    (val (subseq string (1+ =-pos))))
  78               (unless (string= key-as-string key-as-upcase-string)
  79                 (warn "smashing case of ~S in conversion to CMU-CL-style ~
  80                       environment alist"
  81                       string))
  82               (cons key val)))
  83            (warn "no #\\= in ~S, eliding it in CMU-CL-style environment alist"
  84                  string))))
  85    sbcl))
  86
  87 ;;; Convert from a CMU CL representation of a Unix environment to a
  88 ;;; SBCL representation.
  89 (defun unix-environment-sbcl-from-cmucl (cmucl)
  90   (mapcar
  91    (lambda (cons)
  92      (destructuring-bind (key . val) cons
  93        (declare (type keyword key) (string val))
  94        (concatenate 'simple-string (symbol-name key) "=" val)))
  95    cmucl))
  96 \f
  97 ;;;; Import wait3(2) from Unix.
  98
  99 #-win32
 100 (define-alien-routine ("waitpid" c-waitpid) sb-alien:int
 101   (pid sb-alien:int)
 102   (status sb-alien:int :out)
 103   (options sb-alien:int))
 104
 105 #-win32
 106 (defun waitpid (pid &optional do-not-hang check-for-stopped)
 107   #+sb-doc
 108   "Return any available status information on child process with PID."
 109   (multiple-value-bind (pid status)
 110       (c-waitpid pid
 111                  (logior (if do-not-hang
 112                              sb-unix:wnohang
 113                              0)
 114                          (if check-for-stopped
 115                              sb-unix:wuntraced
 116                              0)))
 117     (cond ((or (minusp pid)
 118                (zerop pid))
 119            nil)
 120           ((eql (ldb (byte 8 0) status)
 121                 sb-unix:wstopped)
 122            (values pid
 123                    :stopped
 124                    (ldb (byte 8 8) status)))
 125           ((zerop (ldb (byte 7 0) status))
 126            (values pid
 127                    :exited
 128                    (ldb (byte 8 8) status)))
 129           (t
 130            (let ((signal (ldb (byte 7 0) status)))
 131              (values pid
 132                      (if (position signal
 133                                    #.(vector
 134                                       sb-unix:sigstop
 135                                       sb-unix:sigtstp
 136                                       sb-unix:sigttin
 137                                       sb-unix:sigttou))
 138                          :stopped
 139                          :signaled)
 140                      signal
 141                      (not (zerop (ldb (byte 1 7) status)))))))))
 142 \f
 143 ;;;; process control stuff
 144 (defvar *active-processes* nil
 145   #+sb-doc
 146   "List of process structures for all active processes.")
 147
 148 #-win32
 149 (defvar *active-processes-lock*
 150   (sb-thread:make-mutex :name "Lock for active processes."))
 151
 152 ;;; *ACTIVE-PROCESSES* can be accessed from multiple threads so a
 153 ;;; mutex is needed. More importantly the sigchld signal handler also
 154 ;;; accesses it, that's why we need without-interrupts.
 155 (defmacro with-active-processes-lock (() &body body)
 156   #-win32
 157   `(sb-thread::with-system-mutex (*active-processes-lock*)
 158      ,@body)
 159   #+win32
 160   `(progn ,@body))
 161
 162 (defstruct (process (:copier nil))
 163   pid                 ; PID of child process
 164   %status             ; either :RUNNING, :STOPPED, :EXITED, or :SIGNALED
 165   exit-code           ; either exit code or signal
 166   core-dumped         ; T if a core image was dumped
 167   #-win32 pty                 ; stream to child's pty, or NIL
 168   input               ; stream to child's input, or NIL
 169   output              ; stream from child's output, or NIL
 170   error               ; stream from child's error output, or NIL
 171   status-hook         ; closure to call when PROC changes status
 172   plist               ; a place for clients to stash things
 173   cookie)             ; list of the number of pipes from the subproc
 174
 175 (defmethod print-object ((process process) stream)
 176   (print-unreadable-object (process stream :type t)
 177     (let ((status (process-status process)))
 178      (if (eq :exited status)
 179          (format stream "~S ~S" status (process-exit-code process))
 180          (format stream "~S ~S" (process-pid process) status)))
 181     process))
 182
 183 #+sb-doc
 184 (setf (documentation 'process-p 'function)
 185       "T if OBJECT is a PROCESS, NIL otherwise.")
 186
 187 #+sb-doc
 188 (setf (documentation 'process-pid 'function) "The pid of the child process.")
 189
 190 #+win32
 191 (define-alien-routine ("GetExitCodeProcess@8" get-exit-code-process)
 192     int
 193   (handle unsigned) (exit-code unsigned :out))
 194
 195 (defun process-status (process)
 196   #+sb-doc
 197   "Return the current status of PROCESS.  The result is one of :RUNNING,
 198    :STOPPED, :EXITED, or :SIGNALED."
 199   (get-processes-status-changes)
 200   (process-%status process))
 201
 202 #+sb-doc
 203 (setf (documentation 'process-exit-code 'function)
 204       "The exit code or the signal of a stopped process.")
 205
 206 #+sb-doc
 207 (setf (documentation 'process-core-dumped 'function)
 208       "T if a core image was dumped by the process.")
 209
 210 #+sb-doc
 211 (setf (documentation 'process-pty 'function)
 212       "The pty stream of the process or NIL.")
 213
 214 #+sb-doc
 215 (setf (documentation 'process-input 'function)
 216       "The input stream of the process or NIL.")
 217
 218 #+sb-doc
 219 (setf (documentation 'process-output 'function)
 220       "The output stream of the process or NIL.")
 221
 222 #+sb-doc
 223 (setf (documentation 'process-error 'function)
 224       "The error stream of the process or NIL.")
 225
 226 #+sb-doc
 227 (setf (documentation 'process-status-hook  'function)
 228       "A function that is called when PROCESS changes its status.
 229 The function is called with PROCESS as its only argument.")
 230
 231 #+sb-doc
 232 (setf (documentation 'process-plist  'function)
 233       "A place for clients to stash things.")
 234
 235 (defun process-wait (process &optional check-for-stopped)
 236   #+sb-doc
 237   "Wait for PROCESS to quit running for some reason. When
 238 CHECK-FOR-STOPPED is T, also returns when PROCESS is stopped. Returns
 239 PROCESS."
 240   (loop
 241       (case (process-status process)
 242         (:running)
 243         (:stopped
 244          (when check-for-stopped
 245            (return)))
 246         (t
 247          (when (zerop (car (process-cookie process)))
 248            (return))))
 249       (sb-sys:serve-all-events 1))
 250   process)
 251
 252 #-win32
 253 ;;; Find the current foreground process group id.
 254 (defun find-current-foreground-process (proc)
 255   (with-alien ((result sb-alien:int))
 256     (multiple-value-bind
 257           (wonp error)
 258         (sb-unix:unix-ioctl (sb-sys:fd-stream-fd (process-pty proc))
 259                             sb-unix:TIOCGPGRP
 260                             (alien-sap (sb-alien:addr result)))
 261       (unless wonp
 262         (error "TIOCPGRP ioctl failed: ~S" (strerror error)))
 263       result))
 264   (process-pid proc))
 265
 266 #-win32
 267 (defun process-kill (process signal &optional (whom :pid))
 268   #+sb-doc
 269   "Hand SIGNAL to PROCESS. If WHOM is :PID, use the kill Unix system call. If
 270    WHOM is :PROCESS-GROUP, use the killpg Unix system call. If WHOM is
 271    :PTY-PROCESS-GROUP deliver the signal to whichever process group is
 272    currently in the foreground."
 273   (let ((pid (ecase whom
 274                ((:pid :process-group)
 275                 (process-pid process))
 276                (:pty-process-group
 277                 (find-current-foreground-process process)))))
 278     (multiple-value-bind
 279           (okay errno)
 280         (case whom
 281           ((:process-group)
 282            (sb-unix:unix-killpg pid signal))
 283           (t
 284            (sb-unix:unix-kill pid signal)))
 285       (cond ((not okay)
 286              (values nil errno))
 287             ((and (eql pid (process-pid process))
 288                   (= signal sb-unix:sigcont))
 289              (setf (process-%status process) :running)
 290              (setf (process-exit-code process) nil)
 291              (when (process-status-hook process)
 292                (funcall (process-status-hook process) process))
 293              t)
 294             (t
 295              t)))))
 296
 297 (defun process-alive-p (process)
 298   #+sb-doc
 299   "Return T if PROCESS is still alive, NIL otherwise."
 300   (let ((status (process-status process)))
 301     (if (or (eq status :running)
 302             (eq status :stopped))
 303         t
 304         nil)))
 305
 306 (defun process-close (process)
 307   #+sb-doc
 308   "Close all streams connected to PROCESS and stop maintaining the
 309 status slot."
 310   (macrolet ((frob (stream abort)
 311                `(when ,stream (close ,stream :abort ,abort))))
 312     #-win32
 313     (frob (process-pty process) t)   ; Don't FLUSH-OUTPUT to dead process,
 314     (frob (process-input process) t) ; .. 'cause it will generate SIGPIPE.
 315     (frob (process-output process) nil)
 316     (frob (process-error process) nil))
 317   ;; FIXME: Given that the status-slot is no longer updated,
 318   ;; maybe it should be set to :CLOSED, or similar?
 319   (with-active-processes-lock ()
 320    (setf *active-processes* (delete process *active-processes*)))
 321   process)
 322
 323 (defun get-processes-status-changes ()
 324   (let (exited)
 325     (with-active-processes-lock ()
 326       (setf *active-processes*
 327             (delete-if #-win32
 328                        (lambda (proc)
 329                          ;; Wait only on pids belonging to processes
 330                          ;; started by RUN-PROGRAM. There used to be a
 331                          ;; WAIT3 call here, but that makes direct
 332                          ;; WAIT, WAITPID usage impossible due to the
 333                          ;; race with the SIGCHLD signal handler.
 334                          (multiple-value-bind (pid what code core)
 335                              (waitpid (process-pid proc) t t)
 336                            (when pid
 337                              (setf (process-%status proc) what)
 338                              (setf (process-exit-code proc) code)
 339                              (setf (process-core-dumped proc) core)
 340                              (when (process-status-hook proc)
 341                                (push proc exited))
 342                              t)))
 343                        #+win32
 344                        (lambda (proc)
 345                          (multiple-value-bind (ok code)
 346                              (get-exit-code-process (process-pid proc))
 347                            (when (and (plusp ok) (/= code 259))
 348                              (setf (process-%status proc) :exited
 349                                    (process-exit-code proc) code)
 350                              (when (process-status-hook proc)
 351                                (push proc exited))
 352                              t)))
 353                        *active-processes*)))
 354     ;; Can't call the hooks before all the processes have been deal
 355     ;; with, as calling a hook may cause re-entry to
 356     ;; GET-PROCESS-STATUS-CHANGES. That may be OK when using waitpid,
 357     ;; but in the Windows implementation it would be deeply bad.
 358     (dolist (proc exited)
 359       (let ((hook (process-status-hook proc)))
 360         (when hook
 361           (funcall hook proc))))))
 362 \f
 363 ;;;; RUN-PROGRAM and close friends
 364
 365 ;;; list of file descriptors to close when RUN-PROGRAM exits due to an error
 366 (defvar *close-on-error* nil)
 367
 368 ;;; list of file descriptors to close when RUN-PROGRAM returns in the parent
 369 (defvar *close-in-parent* nil)
 370
 371 ;;; list of handlers installed by RUN-PROGRAM.  FIXME: nothing seems
 372 ;;; to set this.
 373 #-win32
 374 (defvar *handlers-installed* nil)
 375
 376 ;;; Find an unused pty. Return three values: the file descriptor for
 377 ;;; the master side of the pty, the file descriptor for the slave side
 378 ;;; of the pty, and the name of the tty device for the slave side.
 379 #-(or win32 openbsd)
 380 (progn
 381   (define-alien-routine ptsname c-string (fd int))
 382   (define-alien-routine grantpt boolean (fd int))
 383   (define-alien-routine unlockpt boolean (fd int))
 384
 385   (defun find-a-pty ()
 386     ;; First try to use the Unix98 pty api.
 387     (let* ((master-name (coerce (format nil "/dev/ptmx") 'base-string))
 388            (master-fd (sb-unix:unix-open master-name
 389                                          sb-unix:o_rdwr
 390                                          #o666)))
 391       (when master-fd
 392         (grantpt master-fd)
 393         (unlockpt master-fd)
 394         (let* ((slave-name (ptsname master-fd))
 395                (slave-fd (sb-unix:unix-open slave-name
 396                                             sb-unix:o_rdwr
 397                                             #o666)))
 398           (when slave-fd
 399             (return-from find-a-pty
 400               (values master-fd
 401                       slave-fd
 402                       slave-name)))
 403           (sb-unix:unix-close master-fd))
 404         (error "could not find a pty")))
 405     ;; No dice, try using the old-school method.
 406     (dolist (char '(#\p #\q))
 407       (dotimes (digit 16)
 408         (let* ((master-name (coerce (format nil "/dev/pty~C~X" char digit)
 409                                     'base-string))
 410                (master-fd (sb-unix:unix-open master-name
 411                                              sb-unix:o_rdwr
 412                                              #o666)))
 413           (when master-fd
 414             (let* ((slave-name (coerce (format nil "/dev/tty~C~X" char digit)
 415                                        'base-string))
 416                    (slave-fd (sb-unix:unix-open slave-name
 417                                                 sb-unix:o_rdwr
 418                                                 #o666)))
 419               (when slave-fd
 420                 (return-from find-a-pty
 421                   (values master-fd
 422                           slave-fd
 423                           slave-name)))
 424               (sb-unix:unix-close master-fd))))))
 425     (error "could not find a pty")))
 426 #+openbsd
 427 (progn
 428   (define-alien-routine openpty int (amaster int :out) (aslave int :out)
 429                         (name (* char)) (termp (* t)) (winp (* t)))
 430   (defun find-a-pty ()
 431     (with-alien ((name-buf (array char 16)))
 432       (multiple-value-bind (return-val master-fd slave-fd)
 433           (openpty (cast name-buf (* char)) nil nil)
 434         (if (zerop return-val)
 435             (values master-fd
 436                     slave-fd
 437                     (sb-alien::c-string-to-string (alien-sap name-buf)
 438                                                   (sb-impl::default-external-format)
 439                                                   'character))
 440             (error "could not find a pty"))))))
 441
 442 #-win32
 443 (defun open-pty (pty cookie &key (external-format :default))
 444   (when pty
 445     (multiple-value-bind
 446           (master slave name)
 447         (find-a-pty)
 448       (push master *close-on-error*)
 449       (push slave *close-in-parent*)
 450       (when (streamp pty)
 451         (multiple-value-bind (new-fd errno) (sb-unix:unix-dup master)
 452           (unless new-fd
 453             (error "couldn't SB-UNIX:UNIX-DUP ~W: ~A" master (strerror errno)))
 454           (push new-fd *close-on-error*)
 455           (copy-descriptor-to-stream new-fd pty cookie external-format)))
 456       (values name
 457               (sb-sys:make-fd-stream master :input t :output t
 458                                      :external-format external-format
 459                                      :element-type :default
 460                                      :dual-channel-p t)))))
 461
 462 ;; Null terminate strings only C-side: otherwise we can run into
 463 ;; A-T-S-L even for simple encodings like ASCII.  Multibyte encodings
 464 ;; may need more than a single byte of zeros; assume 4 byte is enough
 465 ;; for everyone.
 466 (defmacro round-null-terminated-bytes-to-words (n)
 467   (let ((bytes-per-word (/ sb-vm:n-machine-word-bits sb-vm:n-byte-bits)))
 468     `(logandc2 (the sb-vm:signed-word (+ (the fixnum ,n)
 469                                          4 (1- ,bytes-per-word)))
 470                (1- ,bytes-per-word))))
 471
 472 (defun string-list-to-c-strvec (string-list)
 473   (let* ((bytes-per-word (/ sb-vm:n-machine-word-bits sb-vm:n-byte-bits))
 474          ;; We need an extra for the null, and an extra 'cause exect
 475          ;; clobbers argv[-1].
 476          (vec-bytes (* bytes-per-word (+ (length string-list) 2)))
 477          (octet-vector-list (mapcar (lambda (s)
 478                                       (string-to-octets s))
 479                                     string-list))
 480          (string-bytes (reduce #'+ octet-vector-list
 481                                :key (lambda (s)
 482                                       (round-null-terminated-bytes-to-words
 483                                        (length s)))))
 484          (total-bytes (+ string-bytes vec-bytes))
 485          ;; Memory to hold the vector of pointers and all the strings.
 486          (vec-sap (sb-sys:allocate-system-memory total-bytes))
 487          (string-sap (sap+ vec-sap vec-bytes))
 488          ;; Index starts from [1]!
 489          (vec-index-offset bytes-per-word))
 490     (declare (sb-vm:signed-word vec-bytes)
 491              (sb-vm:word string-bytes total-bytes)
 492              (sb-sys:system-area-pointer vec-sap string-sap))
 493     (dolist (octets octet-vector-list)
 494       (declare (type (simple-array (unsigned-byte 8) (*)) octets))
 495       (let ((size (length octets)))
 496         ;; Copy string.
 497         (sb-kernel:copy-ub8-to-system-area octets 0 string-sap 0 size)
 498         ;; NULL-terminate it
 499         (sb-kernel:system-area-ub8-fill 0 string-sap size 4)
 500         ;; Put the pointer in the vector.
 501         (setf (sap-ref-sap vec-sap vec-index-offset) string-sap)
 502         ;; Advance string-sap for the next string.
 503         (setf string-sap (sap+ string-sap
 504                                (round-null-terminated-bytes-to-words size)))
 505         (incf vec-index-offset bytes-per-word)))
 506     ;; Final null pointer.
 507     (setf (sap-ref-sap vec-sap vec-index-offset) (int-sap 0))
 508     (values vec-sap (sap+ vec-sap bytes-per-word) total-bytes)))
 509
 510 (defmacro with-c-strvec ((var str-list) &body body)
 511   (with-unique-names (sap size)
 512     `(multiple-value-bind (,sap ,var ,size)
 513          (string-list-to-c-strvec ,str-list)
 514        (unwind-protect
 515             (progn
 516               ,@body)
 517          (sb-sys:deallocate-system-memory ,sap ,size)))))
 518
 519 (sb-alien:define-alien-routine spawn
 520     #-win32 sb-alien:int
 521     #+win32 sb-win32::handle
 522   (program sb-alien:c-string)
 523   (argv (* sb-alien:c-string))
 524   (stdin sb-alien:int)
 525   (stdout sb-alien:int)
 526   (stderr sb-alien:int)
 527   (search sb-alien:int)
 528   (envp (* sb-alien:c-string))
 529   (pty-name sb-alien:c-string)
 530   (wait sb-alien:int))
 531
 532 ;;; FIXME: There shouldn't be two semiredundant versions of the
 533 ;;; documentation. Since this is a public extension function, the
 534 ;;; documentation should be in the doc string. So all information from
 535 ;;; this comment should be merged into the doc string, and then this
 536 ;;; comment can go away.
 537 ;;;
 538 ;;; RUN-PROGRAM uses fork() and execve() to run a different program.
 539 ;;; Strange stuff happens to keep the Unix state of the world
 540 ;;; coherent.
 541 ;;;
 542 ;;; The child process needs to get its input from somewhere, and send
 543 ;;; its output (both standard and error) to somewhere. We have to do
 544 ;;; different things depending on where these somewheres really are.
 545 ;;;
 546 ;;; For input, there are five options:
 547 ;;;  -- T: Just leave fd 0 alone. Pretty simple.
 548 ;;;  -- "file": Read from the file. We need to open the file and
 549 ;;;     pull the descriptor out of the stream. The parent should close
 550 ;;;     this stream after the child is up and running to free any
 551 ;;;     storage used in the parent.
 552 ;;;  -- NIL: Same as "file", but use "/dev/null" as the file.
 553 ;;;  -- :STREAM: Use Unix pipe() to create two descriptors. Use
 554 ;;;     SB-SYS:MAKE-FD-STREAM to create the output stream on the
 555 ;;;     writeable descriptor, and pass the readable descriptor to
 556 ;;;     the child. The parent must close the readable descriptor for
 557 ;;;     EOF to be passed up correctly.
 558 ;;;  -- a stream: If it's a fd-stream, just pull the descriptor out
 559 ;;;     of it. Otherwise make a pipe as in :STREAM, and copy
 560 ;;;     everything across.
 561 ;;;
 562 ;;; For output, there are five options:
 563 ;;;  -- T: Leave descriptor 1 alone.
 564 ;;;  -- "file": dump output to the file.
 565 ;;;  -- NIL: dump output to /dev/null.
 566 ;;;  -- :STREAM: return a stream that can be read from.
 567 ;;;  -- a stream: if it's a fd-stream, use the descriptor in it.
 568 ;;;     Otherwise, copy stuff from output to stream.
 569 ;;;
 570 ;;; For error, there are all the same options as output plus:
 571 ;;;  -- :OUTPUT: redirect to the same place as output.
 572 ;;;
 573 ;;; RUN-PROGRAM returns a PROCESS structure for the process if
 574 ;;; the fork worked, and NIL if it did not.
 575 (defun run-program (program args
 576                     &key
 577                     #-win32 (env nil env-p)
 578                     #-win32 (environment
 579                              (if env-p
 580                                  (unix-environment-sbcl-from-cmucl env)
 581                                  (posix-environ))
 582                              environment-p)
 583                     (wait t)
 584                     search
 585                     #-win32 pty
 586                     input
 587                     if-input-does-not-exist
 588                     output
 589                     (if-output-exists :error)
 590                     (error :output)
 591                     (if-error-exists :error)
 592                     status-hook
 593                     (external-format :default))
 594   #+sb-doc
 595   #.(concatenate
 596      'string
 597      ;; The Texinfoizer is sensitive to whitespace, so mind the
 598      ;; placement of the #-win32 pseudosplicings.
 599      "RUN-PROGRAM creates a new process specified by the PROGRAM
 600 argument. ARGS are the standard arguments that can be passed to a
 601 program. For no arguments, use NIL (which means that just the
 602 name of the program is passed as arg 0).
 603
 604 The program arguments and the environment are encoded using the
 605 default external format for streams.
 606
 607 RUN-PROGRAM will return a PROCESS structure. See the CMU Common Lisp
 608 Users Manual for details about the PROCESS structure."#-win32"
 609
 610    Notes about Unix environments (as in the :ENVIRONMENT and :ENV args):
 611
 612    - The SBCL implementation of RUN-PROGRAM, like Perl and many other
 613      programs, but unlike the original CMU CL implementation, copies
 614      the Unix environment by default.
 615
 616    - Running Unix programs from a setuid process, or in any other
 617      situation where the Unix environment is under the control of someone
 618      else, is a mother lode of security problems. If you are contemplating
 619      doing this, read about it first. (The Perl community has a lot of good
 620      documentation about this and other security issues in script-like
 621      programs.)""
 622
 623    The &KEY arguments have the following meanings:
 624 "#-win32"
 625    :ENVIRONMENT
 626       a list of STRINGs describing the new Unix environment
 627       (as in \"man environ\"). The default is to copy the environment of
 628       the current process.
 629    :ENV
 630       an alternative lossy representation of the new Unix environment,
 631       for compatibility with CMU CL""
 632    :SEARCH
 633       Look for PROGRAM in each of the directories in the child's $PATH
 634       environment variable.  Otherwise an absolute pathname is required.
 635    :WAIT
 636       If non-NIL (default), wait until the created process finishes.  If
 637       NIL, continue running Lisp until the program finishes."#-win32"
 638    :PTY
 639       Either T, NIL, or a stream.  Unless NIL, the subprocess is established
 640       under a PTY.  If :pty is a stream, all output to this pty is sent to
 641       this stream, otherwise the PROCESS-PTY slot is filled in with a stream
 642       connected to pty that can read output and write input.""
 643    :INPUT
 644       Either T, NIL, a pathname, a stream, or :STREAM.  If T, the standard
 645       input for the current process is inherited.  If NIL, "
 646       #-win32"/dev/null"#+win32"nul""
 647       is used.  If a pathname, the file so specified is used.  If a stream,
 648       all the input is read from that stream and sent to the subprocess.  If
 649       :STREAM, the PROCESS-INPUT slot is filled in with a stream that sends
 650       its output to the process. Defaults to NIL.
 651    :IF-INPUT-DOES-NOT-EXIST (when :INPUT is the name of a file)
 652       can be one of:
 653          :ERROR to generate an error
 654          :CREATE to create an empty file
 655          NIL (the default) to return NIL from RUN-PROGRAM
 656    :OUTPUT
 657       Either T, NIL, a pathname, a stream, or :STREAM.  If T, the standard
 658       output for the current process is inherited.  If NIL, "
 659       #-win32"/dev/null"#+win32"nul""
 660       is used.  If a pathname, the file so specified is used.  If a stream,
 661       all the output from the process is written to this stream. If
 662       :STREAM, the PROCESS-OUTPUT slot is filled in with a stream that can
 663       be read to get the output. Defaults to NIL.
 664    :IF-OUTPUT-EXISTS (when :OUTPUT is the name of a file)
 665       can be one of:
 666          :ERROR (the default) to generate an error
 667          :SUPERSEDE to supersede the file with output from the program
 668          :APPEND to append output from the program to the file
 669          NIL to return NIL from RUN-PROGRAM, without doing anything
 670    :ERROR and :IF-ERROR-EXISTS
 671       Same as :OUTPUT and :IF-OUTPUT-EXISTS, except that :ERROR can also be
 672       specified as :OUTPUT in which case all error output is routed to the
 673       same place as normal output.
 674    :STATUS-HOOK
 675       This is a function the system calls whenever the status of the
 676       process changes.  The function takes the process as an argument.
 677    :EXTERNAL-FORMAT
 678       The external-format to use for :INPUT, :OUTPUT, and :ERROR :STREAMs.")
 679   #-win32
 680   (when (and env-p environment-p)
 681     (error "can't specify :ENV and :ENVIRONMENT simultaneously"))
 682   ;; Prepend the program to the argument list.
 683   (push (namestring program) args)
 684   (labels (;; It's friendly to allow the caller to pass any string
 685            ;; designator, but internally we'd like SIMPLE-STRINGs.
 686            ;;
 687            ;; Huh?  We let users pass in symbols and characters for
 688            ;; the arguments, but call NAMESTRING on the program
 689            ;; name... -- RMK
 690            (simplify-args (args)
 691              (loop for arg in args
 692                    as escaped-arg = (escape-arg arg)
 693                    collect (coerce escaped-arg 'simple-string)))
 694            (escape-arg (arg)
 695              #-win32 arg
 696              ;; Apparently any spaces or double quotes in the arguments
 697              ;; need to be escaped on win32.
 698              #+win32 (if (position-if
 699                           (lambda (c) (find c '(#\" #\Space))) arg)
 700                          (write-to-string arg)
 701                          arg)))
 702     (let (;; Clear various specials used by GET-DESCRIPTOR-FOR to
 703           ;; communicate cleanup info.
 704           *close-on-error*
 705           *close-in-parent*
 706           ;; Some other binding used only on non-Win32.  FIXME:
 707           ;; nothing seems to set this.
 708           #-win32 *handlers-installed*
 709           ;; Establish PROC at this level so that we can return it.
 710           proc
 711           (simple-args (simplify-args args))
 712           (progname (native-namestring program))
 713           ;; Gag.
 714           (cookie (list 0)))
 715       (unwind-protect
 716            ;; Note: despite the WITH-* names, these macros don't
 717            ;; expand into UNWIND-PROTECT forms.  They're just
 718            ;; syntactic sugar to make the rest of the routine slightly
 719            ;; easier to read.
 720            (macrolet ((with-fd-and-stream-for (((fd stream) which &rest args)
 721                                                &body body)
 722                         `(multiple-value-bind (,fd ,stream)
 723                              ,(ecase which
 724                                 ((:input :output)
 725                                  `(get-descriptor-for ,@args))
 726                                 (:error
 727                                  `(if (eq ,(first args) :output)
 728                                       ;; kludge: we expand into
 729                                       ;; hard-coded symbols here.
 730                                       (values stdout output-stream)
 731                                       (get-descriptor-for ,@args))))
 732                            ,@body))
 733                       (with-open-pty (((pty-name pty-stream) (pty cookie))
 734                                       &body body)
 735                         #+win32 `(declare (ignore ,pty ,cookie))
 736                         #+win32 `(let (,pty-name ,pty-stream) ,@body)
 737                         #-win32 `(multiple-value-bind (,pty-name ,pty-stream)
 738                                      (open-pty ,pty ,cookie :external-format external-format)
 739                                    ,@body))
 740                       (with-args-vec ((vec args) &body body)
 741                         `(with-c-strvec (,vec ,args)
 742                            ,@body))
 743                       (with-environment-vec ((vec env) &body body)
 744                         #+win32 `(let (,vec) ,@body)
 745                         #-win32 `(with-c-strvec (,vec ,env) ,@body)))
 746              (with-fd-and-stream-for ((stdin input-stream) :input
 747                                       input cookie
 748                                       :direction :input
 749                                       :if-does-not-exist if-input-does-not-exist
 750                                       :external-format external-format
 751                                       :wait wait)
 752                (with-fd-and-stream-for ((stdout output-stream) :output
 753                                         output cookie
 754                                         :direction :output
 755                                         :if-exists if-output-exists
 756                                         :external-format external-format)
 757                  (with-fd-and-stream-for ((stderr error-stream)  :error
 758                                           error cookie
 759                                           :direction :output
 760                                           :if-exists if-error-exists
 761                                           :external-format external-format)
 762                    (with-open-pty ((pty-name pty-stream) (pty cookie))
 763                      ;; Make sure we are not notified about the child
 764                      ;; death before we have installed the PROCESS
 765                      ;; structure in *ACTIVE-PROCESSES*.
 766                      (let (child)
 767                        (with-active-processes-lock ()
 768                          (with-args-vec (args-vec simple-args)
 769                            (with-environment-vec (environment-vec environment)
 770                              (setq child (without-gcing
 771                                            (spawn progname args-vec
 772                                                   stdin stdout stderr
 773                                                   (if search 1 0)
 774                                                   environment-vec pty-name
 775                                                   (if wait 1 0))))
 776                              (unless (minusp child)
 777                                (setf proc
 778                                      (apply
 779                                       #'make-process
 780                                       :pid child
 781                                       :input input-stream
 782                                       :output output-stream
 783                                       :error error-stream
 784                                       :status-hook status-hook
 785                                       :cookie cookie
 786                                       #-win32 (list :pty pty-stream
 787                                                     :%status :running)
 788                                       #+win32 (if wait
 789                                                   (list :%status :exited
 790                                                         :exit-code child)
 791                                                   (list :%status :running))))
 792                                (push proc *active-processes*)))))
 793                        ;; Report the error outside the lock.
 794                        #+win32
 795                        (when (minusp child)
 796                          (error "Couldn't execute ~S: ~A" progname (strerror)))
 797                        #-win32
 798                        (case child
 799                          (-2
 800                           (error "Couldn't execute ~S: ~A" progname (strerror)))
 801                          (-1
 802                           (error "Couldn't fork child process: ~A" (strerror))))))))))
 803         (dolist (fd *close-in-parent*)
 804           (sb-unix:unix-close fd))
 805         (unless proc
 806           (dolist (fd *close-on-error*)
 807             (sb-unix:unix-close fd))
 808           #-win32
 809           (dolist (handler *handlers-installed*)
 810             (sb-sys:remove-fd-handler handler)))
 811         #-win32
 812         (when (and wait proc)
 813           (unwind-protect
 814                (process-wait proc)
 815             (dolist (handler *handlers-installed*)
 816               (sb-sys:remove-fd-handler handler)))))
 817       proc)))
 818
 819 ;;; Install a handler for any input that shows up on the file
 820 ;;; descriptor. The handler reads the data and writes it to the
 821 ;;; stream.
 822 (defun copy-descriptor-to-stream (descriptor stream cookie external-format)
 823   (incf (car cookie))
 824   (let* ((handler nil)
 825          (buf (make-array 256 :element-type '(unsigned-byte 8)))
 826          (read-end 0)
 827          (et (stream-element-type stream))
 828          (copy-fun
 829           (cond
 830             ((member et '(character base-char))
 831              (lambda ()
 832                (let* ((decode-end read-end)
 833                       (string (handler-case
 834                                   (octets-to-string
 835                                    buf :end read-end
 836                                    :external-format external-format)
 837                                 (end-of-input-in-character (e)
 838                                   (setf decode-end
 839                                         (octet-decoding-error-start e))
 840                                   (octets-to-string
 841                                    buf :end decode-end
 842                                    :external-format external-format)))))
 843                  (unless (zerop (length string))
 844                    (write-string string stream)
 845                    (when (/= decode-end (length buf))
 846                      (replace buf buf :start2 decode-end :end2 read-end))
 847                    (decf read-end decode-end)))))
 848             ((member et '(:default (unsigned-byte 8)) :test #'equal)
 849              (lambda ()
 850                (write-sequence buf stream :end read-end)
 851                (setf read-end 0)))
 852             (t
 853              ;; FIXME.
 854              (error "Don't know how to copy to stream of element-type ~S"
 855                     et)))))
 856     (setf handler
 857           (sb-sys:add-fd-handler
 858            descriptor
 859            :input
 860            (lambda (fd)
 861              (declare (ignore fd))
 862              (loop
 863                 (unless handler
 864                   (return))
 865                 (multiple-value-bind
 866                       (result readable/errno)
 867                     (sb-unix:unix-select (1+ descriptor)
 868                                          (ash 1 descriptor)
 869                                          0 0 0)
 870                   (cond ((null result)
 871                          (if (eql sb-unix:eintr readable/errno)
 872                              (return)
 873                              (error "~@<Couldn't select on sub-process: ~
 874                                         ~2I~_~A~:>"
 875                                     (strerror readable/errno))))
 876                         ((zerop result)
 877                          (return))))
 878                 (multiple-value-bind (count errno)
 879                     (with-pinned-objects (buf)
 880                       (sb-unix:unix-read descriptor
 881                                          (sap+ (vector-sap buf) read-end)
 882                                          (- (length buf) read-end)))
 883                   (cond
 884                     ((and #-win32 (or (and (null count)
 885                                            (eql errno sb-unix:eio))
 886                                       (eql count 0))
 887                           #+win32 (<= count 0))
 888                      (sb-sys:remove-fd-handler handler)
 889                      (setf handler nil)
 890                      (decf (car cookie))
 891                      (sb-unix:unix-close descriptor)
 892                      (unless (zerop read-end)
 893                        ;; Should this be an END-OF-FILE?
 894                        (error "~@<non-empty buffer when EOF reached ~
 895                                while reading from child: ~S~:>" buf))
 896                      (return))
 897                     ((null count)
 898                      (sb-sys:remove-fd-handler handler)
 899                      (setf handler nil)
 900                      (decf (car cookie))
 901                      (error
 902                       "~@<couldn't read input from sub-process: ~
 903                                      ~2I~_~A~:>"
 904                       (strerror errno)))
 905                     (t
 906                      (incf read-end count)
 907                      (funcall copy-fun))))))))
 908     #-win32
 909     (push handler *handlers-installed*)))
 910
 911 ;;; FIXME: something very like this is done in SB-POSIX to treat
 912 ;;; streams as file descriptor designators; maybe we can combine these
 913 ;;; two?  Additionally, as we have a couple of user-defined streams
 914 ;;; libraries, maybe we should have a generic function for doing this,
 915 ;;; so user-defined streams can play nicely with RUN-PROGRAM (and
 916 ;;; maybe also with SB-POSIX)?
 917 (defun get-stream-fd-and-external-format (stream direction)
 918   (typecase stream
 919     (sb-sys:fd-stream
 920      (values (sb-sys:fd-stream-fd stream) nil (stream-external-format stream)))
 921     (synonym-stream
 922      (get-stream-fd-and-external-format
 923       (symbol-value (synonym-stream-symbol stream)) direction))
 924     (two-way-stream
 925      (ecase direction
 926        (:input
 927         (get-stream-fd-and-external-format
 928          (two-way-stream-input-stream stream) direction))
 929        (:output
 930         (get-stream-fd-and-external-format
 931          (two-way-stream-output-stream stream) direction))))))
 932
 933 \f
 934 ;;; Find a file descriptor to use for object given the direction.
 935 ;;; Returns the descriptor. If object is :STREAM, returns the created
 936 ;;; stream as the second value.
 937 (defun get-descriptor-for (object
 938                            cookie
 939                            &rest keys
 940                            &key direction (external-format :default) wait
 941                            &allow-other-keys)
 942   (declare (ignore wait)) ;This is explained below.
 943   ;; Our use of a temporary file dates back to very old CMUCLs, and
 944   ;; was probably only ever intended for use with STRING-STREAMs,
 945   ;; which are ordinarily smallish.  However, as we've got
 946   ;; user-defined stream classes, we can end up trying to copy
 947   ;; arbitrarily much data into the temp file, and so are liable to
 948   ;; run afoul of disk quotas or to choke on small /tmp file systems.
 949   (flet ((make-temp-fd ()
 950            (multiple-value-bind (fd name/errno)
 951                (sb-unix:sb-mkstemp "/tmp/.run-program-XXXXXX" #o0600)
 952              (unless fd
 953                (error "could not open a temporary file: ~A"
 954                       (strerror name/errno)))
 955              (unless (sb-unix:unix-unlink name/errno)
 956                (sb-unix:unix-close fd)
 957                (error "failed to unlink ~A" name/errno))
 958              fd)))
 959     (cond ((eq object t)
 960            ;; No new descriptor is needed.
 961            (values -1 nil))
 962           ((or (eq object nil)
 963                (and (typep object 'broadcast-stream)
 964                     (not (broadcast-stream-streams object))))
 965            ;; Use /dev/null.
 966            (multiple-value-bind
 967                  (fd errno)
 968                (sb-unix:unix-open #-win32 #.(coerce "/dev/null" 'base-string)
 969                                   #+win32 #.(coerce "nul" 'base-string)
 970                                   (case direction
 971                                     (:input sb-unix:o_rdonly)
 972                                     (:output sb-unix:o_wronly)
 973                                     (t sb-unix:o_rdwr))
 974                                   #o666)
 975              (unless fd
 976                (error #-win32 "~@<couldn't open \"/dev/null\": ~2I~_~A~:>"
 977                       #+win32 "~@<couldn't open \"nul\" device: ~2I~_~A~:>"
 978                       (strerror errno)))
 979              (push fd *close-in-parent*)
 980              (values fd nil)))
 981           ((eq object :stream)
 982            (multiple-value-bind (read-fd write-fd) (sb-unix:unix-pipe)
 983              (unless read-fd
 984                (error "couldn't create pipe: ~A" (strerror write-fd)))
 985              (case direction
 986                (:input
 987                 (push read-fd *close-in-parent*)
 988                 (push write-fd *close-on-error*)
 989                 (let ((stream (sb-sys:make-fd-stream write-fd :output t
 990                                                      :element-type :default
 991                                                      :external-format
 992                                                      external-format)))
 993                   (values read-fd stream)))
 994                (:output
 995                 (push read-fd *close-on-error*)
 996                 (push write-fd *close-in-parent*)
 997                 (let ((stream (sb-sys:make-fd-stream read-fd :input t
 998                                                      :element-type :default
 999                                                      :external-format
1000                                                      external-format)))
1001                   (values write-fd stream)))
1002                (t
1003                 (sb-unix:unix-close read-fd)
1004                 (sb-unix:unix-close write-fd)
1005                 (error "Direction must be either :INPUT or :OUTPUT, not ~S."
1006                        direction)))))
1007           ((or (pathnamep object) (stringp object))
1008            ;; GET-DESCRIPTOR-FOR uses &allow-other-keys, so rather
1009            ;; than munge the &rest list for OPEN, just disable keyword
1010            ;; validation there.
1011            (with-open-stream (file (apply #'open object :allow-other-keys t
1012                                           keys))
1013              (multiple-value-bind
1014                    (fd errno)
1015                  (sb-unix:unix-dup (sb-sys:fd-stream-fd file))
1016                (cond (fd
1017                       (push fd *close-in-parent*)
1018                       (values fd nil))
1019                      (t
1020                       (error "couldn't duplicate file descriptor: ~A"
1021                              (strerror errno)))))))
1022           ((streamp object)
1023            (ecase direction
1024              (:input
1025               (block nil
1026                 ;; If we can get an fd for the stream, let the child
1027                 ;; process use the fd for its descriptor.  Otherwise,
1028                 ;; we copy data from the stream into a temp file, and
1029                 ;; give the temp file's descriptor to the
1030                 ;; child.
1031                 (multiple-value-bind (fd stream format)
1032                     (get-stream-fd-and-external-format object :input)
1033                   (declare (ignore format))
1034                   (when fd
1035                     (return (values fd stream))))
1036                 ;; FIXME: if we can't get the file descriptor, since
1037                 ;; the stream might be interactive or otherwise
1038                 ;; block-y, we can't know whether we can copy the
1039                 ;; stream's data to a temp file, so if RUN-PROGRAM was
1040                 ;; called with :WAIT NIL, we should probably error.
1041                 ;; However, STRING-STREAMs aren't fd-streams, but
1042                 ;; they're not prone to blocking; any user-defined
1043                 ;; streams that "read" from some in-memory data will
1044                 ;; probably be similar to STRING-STREAMs.  So maybe we
1045                 ;; should add a STREAM-INTERACTIVE-P generic function
1046                 ;; for problems like this?  Anyway, the machinery is
1047                 ;; here, if you feel like filling in the details.
1048                 #|
1049                 (when (and (null wait) #<some undetermined criterion>)
1050                   (error "~@<don't know how to get an fd for ~A, and so ~
1051                              can't ensure that copying its data to the ~
1052                              child process won't hang~:>" object))
1053                 |#
1054                 (let ((fd (make-temp-fd))
1055                       (et (stream-element-type object)))
1056                   (cond ((member et '(character base-char))
1057                          (loop
1058                            (multiple-value-bind
1059                                  (line no-cr)
1060                                (read-line object nil nil)
1061                              (unless line
1062                                (return))
1063                              (let ((vector (string-to-octets
1064                                             line
1065                                             :external-format external-format)))
1066                                (sb-unix:unix-write
1067                                 fd vector 0 (length vector)))
1068                              (if no-cr
1069                                (return)
1070                                (sb-unix:unix-write
1071                                 fd #.(string #\Newline) 0 1)))))
1072                         ((member et '(:default (unsigned-byte 8))
1073                                  :test 'equal)
1074                          (loop with buf = (make-array 256 :element-type '(unsigned-byte 8))
1075                                for p = (read-sequence buf object)
1076                                until (zerop p)
1077                                do (sb-unix:unix-write fd buf 0 p)))
1078                         (t
1079                          (error "Don't know how to copy from stream of element-type ~S"
1080                                 et)))
1081                   (sb-unix:unix-lseek fd 0 sb-unix:l_set)
1082                   (push fd *close-in-parent*)
1083                   (return (values fd nil)))))
1084              (:output
1085               (block nil
1086                 ;; Similar to the :input trick above, except we
1087                 ;; arrange to copy data from the stream.  This is
1088                 ;; slightly saner than the input case, since we don't
1089                 ;; buffer to a file, but I think we may still lose if
1090                 ;; there's unflushed data in the stream buffer and we
1091                 ;; give the file descriptor to the child.
1092                 (multiple-value-bind (fd stream format)
1093                     (get-stream-fd-and-external-format object :output)
1094                   (declare (ignore format))
1095                   (when fd
1096                     (return (values fd stream))))
1097                 (multiple-value-bind (read-fd write-fd)
1098                     (sb-unix:unix-pipe)
1099                   (unless read-fd
1100                     (error "couldn't create pipe: ~S" (strerror write-fd)))
1101                   (copy-descriptor-to-stream read-fd object cookie
1102                                              external-format)
1103                   (push read-fd *close-on-error*)
1104                   (push write-fd *close-in-parent*)
1105                   (return (values write-fd nil)))))))
1106           (t
1107            (error "invalid option to RUN-PROGRAM: ~S" object)))))