src/code/run-program.lisp

   1 ;;;; RUN-PROGRAM and friends, a facility for running Unix programs
   2 ;;;; from inside SBCL
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB-IMPL")
  14 \f
  15 ;;;; hacking the Unix environment
  16 ;;;;
  17 ;;;; In the original CMU CL code that LOAD-FOREIGN is derived from, the
  18 ;;;; Unix environment (as in "man environ") was represented as an
  19 ;;;; alist from keywords to strings, so that e.g. the Unix environment
  20 ;;;;   "SHELL=/bin/bash" "HOME=/root" "PAGER=less"
  21 ;;;; was represented as
  22 ;;;;   ((:SHELL . "/bin/bash") (:HOME . "/root") (:PAGER "less"))
  23 ;;;; This had a few problems in principle: the mapping into
  24 ;;;; keyword symbols smashed the case of environment
  25 ;;;; variables, and the whole mapping depended on the presence of
  26 ;;;; #\= characters in the environment strings. In practice these
  27 ;;;; problems weren't hugely important, since conventionally environment
  28 ;;;; variables are uppercase strings followed by #\= followed by
  29 ;;;; arbitrary data. However, since it's so manifestly not The Right
  30 ;;;; Thing to make code which breaks unnecessarily on input which
  31 ;;;; doesn't follow what is, after all, only a tradition, we've switched
  32 ;;;; formats in SBCL, so that the fundamental environment list
  33 ;;;; is just a list of strings, with a one-to-one-correspondence
  34 ;;;; to the C-level representation. I.e., in the example above,
  35 ;;;; the SBCL representation is
  36 ;;;;   '("SHELL=/bin/bash" "HOME=/root" "PAGER=less")
  37 ;;;; CMU CL's implementation is currently supported to help with porting.
  38 ;;;;
  39 ;;;; It's not obvious that this code belongs here (instead of e.g. in
  40 ;;;; unix.lisp), since it has only a weak logical connection with
  41 ;;;; RUN-PROGRAM. However, physically it's convenient to put it here.
  42 ;;;; It's not needed at cold init, so we *can* put it in this
  43 ;;;; warm-loaded file. And by putting it in this warm-loaded file, we
  44 ;;;; make it easy for it to get to the C-level 'environ' variable.
  45 ;;;; which (at least in sbcl-0.6.10 on Red Hat Linux 6.2) is not
  46 ;;;; visible at GENESIS time.
  47
  48 (def-alien-variable "environ" (* c-string))
  49
  50 (defun posix-environ ()
  51   "Return the Unix environment (\"man environ\") as a list of SIMPLE-STRINGs."
  52   (c-strings->string-list environ))
  53
  54 ;;; Convert as best we can from a SBCL representation of a Unix
  55 ;;; environment to a CMU CL representation.
  56 ;;;
  57 ;;; * (UNIX-ENVIRONMENT-CMUCL-FROM-SBCL '("Bletch=fub" "Noggin" "YES=No!"))
  58 ;;; WARNING:
  59 ;;;   smashing case of "Bletch=fub" in conversion to CMU-CL-style
  60 ;;;     environment alist
  61 ;;; WARNING:
  62 ;;;   no #\= in "Noggin", eliding it in CMU-CL-style environment alist
  63 ;;; ((:BLETCH . "fub") (:YES . "No!"))
  64 (defun unix-environment-cmucl-from-sbcl (sbcl)
  65   (mapcan
  66    (lambda (string)
  67      (declare (type simple-string string))
  68      (let ((=-pos (position #\= string :test #'equal)))
  69        (if =-pos
  70            (list
  71             (let* ((key-as-string (subseq string 0 =-pos))
  72                    (key-as-upcase-string (string-upcase key-as-string))
  73                    (key (keywordicate key-as-upcase-string))
  74                    (val (subseq string (1+ =-pos))))
  75               (unless (string= key-as-string key-as-upcase-string)
  76                 (warn "smashing case of ~S in conversion to CMU-CL-style ~
  77                       environment alist"
  78                       string))
  79               (cons key val)))
  80            (warn "no #\\= in ~S, eliding it in CMU-CL-style environment alist"
  81                  string))))
  82    sbcl))
  83
  84 ;;; Convert from a CMU CL representation of a Unix environment to a
  85 ;;; SBCL representation.
  86 (defun unix-environment-sbcl-from-cmucl (cmucl)
  87   (mapcar
  88    (lambda (cons)
  89      (destructuring-bind (key . val) cons
  90        (declare (type keyword key) (type simple-string val))
  91        (concatenate 'simple-string (symbol-name key) "=" val)))
  92    cmucl))
  93 \f
  94 ;;;; Import wait3(2) from Unix.
  95
  96 (sb-alien:def-alien-routine ("wait3" c-wait3) sb-c-call:int
  97   (status sb-c-call:int :out)
  98   (options sb-c-call:int)
  99   (rusage sb-c-call:int))
 100
 101 (defconstant wait-wnohang #-svr4 1 #+svr4 #o100)
 102 (defconstant wait-wuntraced #-svr4 2 #+svr4 4)
 103 (defconstant wait-wstopped #-svr4 #o177 #+svr4 wait-wuntraced)
 104
 105 (defun wait3 (&optional do-not-hang check-for-stopped)
 106   "Return any available status information on child process. "
 107   (multiple-value-bind (pid status)
 108       (c-wait3 (logior (if do-not-hang
 109                            wait-wnohang
 110                            0)
 111                        (if check-for-stopped
 112                            wait-wuntraced
 113                            0))
 114                0)
 115     (cond ((or (minusp pid)
 116                (zerop pid))
 117            nil)
 118           ((eql (ldb (byte 8 0) status)
 119                 wait-wstopped)
 120            (values pid
 121                    :stopped
 122                    (ldb (byte 8 8) status)))
 123           ((zerop (ldb (byte 7 0) status))
 124            (values pid
 125                    :exited
 126                    (ldb (byte 8 8) status)))
 127           (t
 128            (let ((signal (ldb (byte 7 0) status)))
 129              (values pid
 130                      (if (position signal
 131                                    #.(vector
 132                                       (sb-unix:unix-signal-number :sigstop)
 133                                       (sb-unix:unix-signal-number :sigtstp)
 134                                       (sb-unix:unix-signal-number :sigttin)
 135                                       (sb-unix:unix-signal-number :sigttou)))
 136                          :stopped
 137                          :signaled)
 138                      signal
 139                      (not (zerop (ldb (byte 1 7) status)))))))))
 140 \f
 141 ;;;; process control stuff
 142
 143 (defvar *active-processes* nil
 144   "List of process structures for all active processes.")
 145
 146 (defstruct (process (:copier nil))
 147   pid                 ; PID of child process
 148   %status             ; either :RUNNING, :STOPPED, :EXITED, or :SIGNALED
 149   exit-code           ; either exit code or signal
 150   core-dumped         ; T if a core image was dumped
 151   pty                 ; stream to child's pty, or NIL
 152   input               ; stream to child's input, or NIL
 153   output              ; stream from child's output, or NIL
 154   error               ; stream from child's error output, or NIL
 155   status-hook         ; closure to call when PROC changes status
 156   plist               ; a place for clients to stash things
 157   cookie)             ; list of the number of pipes from the subproc
 158
 159 (defmethod print-object ((process process) stream)
 160   (print-unreadable-object (process stream :type t)
 161     (format stream
 162             "~D ~S"
 163             (process-pid process)
 164             (process-status process)))
 165   process)
 166
 167 (defun process-status (proc)
 168   "Return the current status of process.  The result is one of :RUNNING,
 169    :STOPPED, :EXITED, or :SIGNALED."
 170   (get-processes-status-changes)
 171   (process-%status proc))
 172
 173 (defun process-wait (proc &optional check-for-stopped)
 174   "Wait for PROC to quit running for some reason.  Returns PROC."
 175   (loop
 176       (case (process-status proc)
 177         (:running)
 178         (:stopped
 179          (when check-for-stopped
 180            (return)))
 181         (t
 182          (when (zerop (car (process-cookie proc)))
 183            (return))))
 184       (sb-sys:serve-all-events 1))
 185   proc)
 186
 187 #-hpux
 188 ;;; Find the current foreground process group id.
 189 (defun find-current-foreground-process (proc)
 190   (sb-alien:with-alien ((result sb-c-call:int))
 191     (multiple-value-bind
 192           (wonp error)
 193         (sb-unix:unix-ioctl (sb-sys:fd-stream-fd (process-pty proc))
 194                             sb-unix:TIOCGPGRP
 195                             (sb-alien:alien-sap (sb-alien:addr result)))
 196       (unless wonp
 197         (error "TIOCPGRP ioctl failed: ~S"
 198                (sb-unix:get-unix-error-msg error)))
 199       result))
 200   (process-pid proc))
 201
 202 (defun process-kill (proc signal &optional (whom :pid))
 203   "Hand SIGNAL to PROC. If WHOM is :PID, use the kill Unix system call. If
 204    WHOM is :PROCESS-GROUP, use the killpg Unix system call. If WHOM is
 205    :PTY-PROCESS-GROUP deliver the signal to whichever process group is
 206    currently in the foreground."
 207   (let ((pid (ecase whom
 208                ((:pid :process-group)
 209                 (process-pid proc))
 210                (:pty-process-group
 211                 #-hpux
 212                 (find-current-foreground-process proc)))))
 213     (multiple-value-bind
 214           (okay errno)
 215         (case whom
 216           #+hpux
 217           (:pty-process-group
 218            (sb-unix:unix-ioctl (sb-sys:fd-stream-fd (process-pty proc))
 219                                sb-unix:TIOCSIGSEND
 220                                (sb-sys:int-sap
 221                                 (sb-unix:unix-signal-number signal))))
 222           ((:process-group #-hpux :pty-process-group)
 223            (sb-unix:unix-killpg pid signal))
 224           (t
 225            (sb-unix:unix-kill pid signal)))
 226       (cond ((not okay)
 227              (values nil errno))
 228             ((and (eql pid (process-pid proc))
 229                   (= (sb-unix:unix-signal-number signal)
 230                      (sb-unix:unix-signal-number :sigcont)))
 231              (setf (process-%status proc) :running)
 232              (setf (process-exit-code proc) nil)
 233              (when (process-status-hook proc)
 234                (funcall (process-status-hook proc) proc))
 235              t)
 236             (t
 237              t)))))
 238
 239 (defun process-alive-p (proc)
 240   "Return T if the process is still alive, NIL otherwise."
 241   (let ((status (process-status proc)))
 242     (if (or (eq status :running)
 243             (eq status :stopped))
 244         t
 245         nil)))
 246
 247 (defun process-close (proc)
 248   "Close all streams connected to PROC and stop maintaining the status slot."
 249   (macrolet ((frob (stream abort)
 250                `(when ,stream (close ,stream :abort ,abort))))
 251     (frob (process-pty    proc)   t) ; Don't FLUSH-OUTPUT to dead process, ..
 252     (frob (process-input  proc)   t) ; .. 'cause it will generate SIGPIPE.
 253     (frob (process-output proc) nil)
 254     (frob (process-error  proc) nil))
 255   (sb-sys:without-interrupts
 256    (setf *active-processes* (delete proc *active-processes*)))
 257   proc)
 258
 259 ;;; the handler for SIGCHLD signals that RUN-PROGRAM establishes
 260 (defun sigchld-handler (ignore1 ignore2 ignore3)
 261   (declare (ignore ignore1 ignore2 ignore3))
 262   (get-processes-status-changes))
 263
 264 (defun get-processes-status-changes ()
 265   (loop
 266       (multiple-value-bind (pid what code core)
 267           (wait3 t t)
 268         (unless pid
 269           (return))
 270         (let ((proc (find pid *active-processes* :key #'process-pid)))
 271           (when proc
 272             (setf (process-%status proc) what)
 273             (setf (process-exit-code proc) code)
 274             (setf (process-core-dumped proc) core)
 275             (when (process-status-hook proc)
 276               (funcall (process-status-hook proc) proc))
 277             (when (position what #(:exited :signaled))
 278               (sb-sys:without-interrupts
 279                (setf *active-processes*
 280                      (delete proc *active-processes*)))))))))
 281 \f
 282 ;;;; RUN-PROGRAM and close friends
 283
 284 ;;; list of file descriptors to close when RUN-PROGRAM exits due to an error
 285 (defvar *close-on-error* nil)
 286
 287 ;;; list of file descriptors to close when RUN-PROGRAM returns in the parent
 288 (defvar *close-in-parent* nil)
 289
 290 ;;; list of handlers installed by RUN-PROGRAM
 291 (defvar *handlers-installed* nil)
 292
 293 #+FreeBSD
 294 (def-alien-type nil
 295   (struct sgttyb
 296           (sg-ispeed sb-c-call:char)    ; input speed
 297           (sg-ospeed sb-c-call:char)    ; output speed
 298           (sg-erase sb-c-call:char)     ; erase character
 299           (sg-kill sb-c-call:char)      ; kill character
 300           (sg-flags sb-c-call:short)))  ; mode flags
 301 #+OpenBSD
 302 (def-alien-type nil
 303   (struct sgttyb
 304           (sg-four sb-c-call:int)
 305           (sg-chars (array sb-c-call:char 4))
 306           (sg-flags sb-c-call:int)))
 307
 308 ;;; Find an unused pty. Return three values: the file descriptor for
 309 ;;; the master side of the pty, the file descriptor for the slave side
 310 ;;; of the pty, and the name of the tty device for the slave side.
 311 (defun find-a-pty ()
 312   (dolist (char '(#\p #\q))
 313     (dotimes (digit 16)
 314       (let* ((master-name (format nil "/dev/pty~C~X" char digit))
 315              (master-fd (sb-unix:unix-open master-name
 316                                            sb-unix:o_rdwr
 317                                            #o666)))
 318         (when master-fd
 319           (let* ((slave-name (format nil "/dev/tty~C~X" char digit))
 320                  (slave-fd (sb-unix:unix-open slave-name
 321                                               sb-unix:o_rdwr
 322                                               #o666)))
 323             (when slave-fd
 324               ;; comment from classic CMU CL:
 325               ;;   Maybe put a vhangup here?
 326               ;;
 327               ;; FIXME: It seems as though this logic should be in
 328               ;; OPEN-PTY, not FIND-A-PTY (both from the comments
 329               ;; documenting DEFUN FIND-A-PTY, and from the
 330               ;; connotations of the function names).
 331               ;;
 332               ;; FIXME: It would be nice to have a note, and/or a pointer
 333               ;; to some reference material somewhere, explaining
 334               ;; why we need this on *BSD and not on Linux.
 335               #+bsd
 336               (sb-alien:with-alien ((stuff (sb-alien:struct sgttyb)))
 337                 (let ((sap (sb-alien:alien-sap stuff)))
 338                   (sb-unix:unix-ioctl slave-fd sb-unix:TIOCGETP sap)
 339                   (setf (sb-alien:slot stuff 'sg-flags)
 340                         ;; This is EVENP|ODDP, the same numeric code
 341                         ;; both on FreeBSD and on OpenBSD. -- WHN 20000929
 342                         #o300) ; EVENP|ODDP
 343                   (sb-unix:unix-ioctl slave-fd sb-unix:TIOCSETP sap)
 344                   (sb-unix:unix-ioctl master-fd sb-unix:TIOCGETP sap)
 345                   (setf (sb-alien:slot stuff 'sg-flags)
 346                         (logand (sb-alien:slot stuff 'sg-flags)
 347                                 ;; This is ~ECHO, the same numeric
 348                                 ;; code both on FreeBSD and on OpenBSD.
 349                                 ;; -- WHN 20000929
 350                                 (lognot 8))) ; ~ECHO
 351                   (sb-unix:unix-ioctl master-fd sb-unix:TIOCSETP sap)))
 352               (return-from find-a-pty
 353                 (values master-fd
 354                         slave-fd
 355                         slave-name)))
 356             (sb-unix:unix-close master-fd))))))
 357   (error "could not find a pty"))
 358
 359 (defun open-pty (pty cookie)
 360   (when pty
 361     (multiple-value-bind
 362           (master slave name)
 363         (find-a-pty)
 364       (push master *close-on-error*)
 365       (push slave *close-in-parent*)
 366       (when (streamp pty)
 367         (multiple-value-bind (new-fd errno) (sb-unix:unix-dup master)
 368           (unless new-fd
 369             (error "could not SB-UNIX:UNIX-DUP ~D: ~S"
 370                    master (sb-unix:get-unix-error-msg errno)))
 371           (push new-fd *close-on-error*)
 372           (copy-descriptor-to-stream new-fd pty cookie)))
 373       (values name
 374               (sb-sys:make-fd-stream master :input t :output t)))))
 375
 376 (defmacro round-bytes-to-words (n)
 377   `(logand (the fixnum (+ (the fixnum ,n) 3)) (lognot 3)))
 378
 379 (defun string-list-to-c-strvec (string-list)
 380   ;; Make a pass over STRING-LIST to calculate the amount of memory
 381   ;; needed to hold the strvec.
 382   (let ((string-bytes 0)
 383         ;; We need an extra for the null, and an extra 'cause exect
 384         ;; clobbers argv[-1].
 385         (vec-bytes (* #-alpha 4 #+alpha 8 (+ (length string-list) 2))))
 386     (declare (fixnum string-bytes vec-bytes))
 387     (dolist (s string-list)
 388       (enforce-type s simple-string)
 389       (incf string-bytes (round-bytes-to-words (1+ (length s)))))
 390     ;; Now allocate the memory and fill it in.
 391     (let* ((total-bytes (+ string-bytes vec-bytes))
 392            (vec-sap (sb-sys:allocate-system-memory total-bytes))
 393            (string-sap (sap+ vec-sap vec-bytes))
 394            (i #-alpha 4 #+alpha 8))
 395       (declare (type (and unsigned-byte fixnum) total-bytes i)
 396                (type sb-sys:system-area-pointer vec-sap string-sap))
 397       (dolist (s string-list)
 398         (declare (simple-string s))
 399         (let ((n (length s)))
 400           ;; Blast the string into place.
 401           (sb-kernel:copy-to-system-area (the simple-string s)
 402                                          (* sb-vm:vector-data-offset
 403                                             sb-vm:word-bits)
 404                                          string-sap 0
 405                                          (* (1+ n) sb-vm:byte-bits))
 406           ;; Blast the pointer to the string into place.
 407           (setf (sap-ref-sap vec-sap i) string-sap)
 408           (setf string-sap (sap+ string-sap (round-bytes-to-words (1+ n))))
 409           (incf i #-alpha 4 #+alpha 8)))
 410       ;; Blast in the last null pointer.
 411       (setf (sap-ref-sap vec-sap i) (int-sap 0))
 412       (values vec-sap (sap+ vec-sap #-alpha 4 #+alpha 8) total-bytes))))
 413
 414 (defmacro with-c-strvec ((var str-list) &body body)
 415   (let ((sap (gensym "SAP-"))
 416         (size (gensym "SIZE-")))
 417     `(multiple-value-bind
 418       (,sap ,var ,size)
 419       (string-list-to-c-strvec ,str-list)
 420       (unwind-protect
 421            (progn
 422              ,@body)
 423         (sb-sys:deallocate-system-memory ,sap ,size)))))
 424
 425 (sb-alien:def-alien-routine spawn sb-c-call:int
 426   (program sb-c-call:c-string)
 427   (argv (* sb-c-call:c-string))
 428   (envp (* sb-c-call:c-string))
 429   (pty-name sb-c-call:c-string)
 430   (stdin sb-c-call:int)
 431   (stdout sb-c-call:int)
 432   (stderr sb-c-call:int))
 433
 434 ;;; FIXME: There shouldn't be two semiredundant versions of the
 435 ;;; documentation. Since this is a public extension function, the
 436 ;;; documentation should be in the doc string. So all information from
 437 ;;; this comment should be merged into the doc string, and then this
 438 ;;; comment can go away.
 439 ;;;
 440 ;;; RUN-PROGRAM uses fork() and execve() to run a different program.
 441 ;;; Strange stuff happens to keep the Unix state of the world
 442 ;;; coherent.
 443 ;;;
 444 ;;; The child process needs to get its input from somewhere, and send
 445 ;;; its output (both standard and error) to somewhere. We have to do
 446 ;;; different things depending on where these somewheres really are.
 447 ;;;
 448 ;;; For input, there are five options:
 449 ;;;  -- T: Just leave fd 0 alone. Pretty simple.
 450 ;;;  -- "file": Read from the file. We need to open the file and
 451 ;;;     pull the descriptor out of the stream. The parent should close
 452 ;;;     this stream after the child is up and running to free any
 453 ;;;     storage used in the parent.
 454 ;;;  -- NIL: Same as "file", but use "/dev/null" as the file.
 455 ;;;  -- :STREAM: Use Unix pipe() to create two descriptors. Use
 456 ;;;     SB-SYS:MAKE-FD-STREAM to create the output stream on the
 457 ;;;     writeable descriptor, and pass the readable descriptor to
 458 ;;;     the child. The parent must close the readable descriptor for
 459 ;;;     EOF to be passed up correctly.
 460 ;;;  -- a stream: If it's a fd-stream, just pull the descriptor out
 461 ;;;     of it. Otherwise make a pipe as in :STREAM, and copy
 462 ;;;     everything across.
 463 ;;;
 464 ;;; For output, there are five options:
 465 ;;;  -- T: Leave descriptor 1 alone.
 466 ;;;  -- "file": dump output to the file.
 467 ;;;  -- NIL: dump output to /dev/null.
 468 ;;;  -- :STREAM: return a stream that can be read from.
 469 ;;;  -- a stream: if it's a fd-stream, use the descriptor in it.
 470 ;;;     Otherwise, copy stuff from output to stream.
 471 ;;;
 472 ;;; For error, there are all the same options as output plus:
 473 ;;;  -- :OUTPUT: redirect to the same place as output.
 474 ;;;
 475 ;;; RUN-PROGRAM returns a PROCESS structure for the process if
 476 ;;; the fork worked, and NIL if it did not.
 477 (defun run-program (program args
 478                     &key
 479                     (env nil env-p)
 480                     (environment (if env-p
 481                                      (unix-environment-sbcl-from-cmucl env)
 482                                      (posix-environ))
 483                                  environment-p)
 484                     (wait t)
 485                     pty
 486                     input
 487                     if-input-does-not-exist
 488                     output
 489                     (if-output-exists :error)
 490                     (error :output)
 491                     (if-error-exists :error)
 492                     status-hook)
 493   "RUN-PROGRAM creates a new Unix process running the Unix program found in
 494    the file specified by the PROGRAM argument.  ARGS are the standard
 495    arguments that can be passed to a Unix program. For no arguments, use NIL
 496    (which means that just the name of the program is passed as arg 0).
 497
 498    RUN-PROGRAM will either return NIL or a PROCESS structure.  See the CMU
 499    Common Lisp Users Manual for details about the PROCESS structure.
 500
 501    notes about Unix environments (as in the :ENVIRONMENT and :ENV args):
 502      1. The SBCL implementation of RUN-PROGRAM, like Perl and many other
 503         programs, but unlike the original CMU CL implementation, copies
 504         the Unix environment by default.
 505      2. Running Unix programs from a setuid process, or in any other
 506         situation where the Unix environment is under the control of someone
 507         else, is a mother lode of security problems. If you are contemplating
 508         doing this, read about it first. (The Perl community has a lot of good
 509         documentation about this and other security issues in script-like
 510         programs.)
 511
 512    The &KEY arguments have the following meanings:
 513      :ENVIRONMENT
 514         a list of SIMPLE-STRINGs describing the new Unix environment (as
 515         in \"man environ\"). The default is to copy the environment of
 516         the current process.
 517      :ENV
 518         an alternative lossy representation of the new Unix environment,
 519         for compatibility with CMU CL
 520      :WAIT
 521         If non-NIL (default), wait until the created process finishes.  If
 522         NIL, continue running Lisp until the program finishes.
 523      :PTY
 524         Either T, NIL, or a stream.  Unless NIL, the subprocess is established
 525         under a PTY.  If :pty is a stream, all output to this pty is sent to
 526         this stream, otherwise the PROCESS-PTY slot is filled in with a stream
 527         connected to pty that can read output and write input.
 528      :INPUT
 529         Either T, NIL, a pathname, a stream, or :STREAM.  If T, the standard
 530         input for the current process is inherited.  If NIL, /dev/null
 531         is used.  If a pathname, the file so specified is used.  If a stream,
 532         all the input is read from that stream and send to the subprocess.  If
 533         :STREAM, the PROCESS-INPUT slot is filled in with a stream that sends
 534         its output to the process. Defaults to NIL.
 535      :IF-INPUT-DOES-NOT-EXIST (when :INPUT is the name of a file)
 536         can be one of:
 537            :ERROR to generate an error
 538            :CREATE to create an empty file
 539            NIL (the default) to return NIL from RUN-PROGRAM
 540      :OUTPUT
 541         Either T, NIL, a pathname, a stream, or :STREAM.  If T, the standard
 542         output for the current process is inherited.  If NIL, /dev/null
 543         is used.  If a pathname, the file so specified is used.  If a stream,
 544         all the output from the process is written to this stream. If
 545         :STREAM, the PROCESS-OUTPUT slot is filled in with a stream that can
 546         be read to get the output. Defaults to NIL.
 547      :IF-OUTPUT-EXISTS (when :OUTPUT is the name of a file)
 548         can be one of:
 549            :ERROR (the default) to generate an error
 550            :SUPERSEDE to supersede the file with output from the program
 551            :APPEND to append output from the program to the file
 552            NIL to return NIL from RUN-PROGRAM, without doing anything
 553      :ERROR and :IF-ERROR-EXISTS
 554         Same as :OUTPUT and :IF-OUTPUT-EXISTS, except that :ERROR can also be
 555         specified as :OUTPUT in which case all error output is routed to the
 556         same place as normal output.
 557      :STATUS-HOOK
 558         This is a function the system calls whenever the status of the
 559         process changes.  The function takes the process as an argument."
 560
 561   (when (and env-p environment-p)
 562     (error "can't specify :ENV and :ENVIRONMENT simultaneously"))
 563   ;; Make sure that the interrupt handler is installed.
 564   (sb-sys:enable-interrupt :sigchld #'sigchld-handler)
 565   ;; Prepend the program to the argument list.
 566   (push (namestring program) args)
 567   (let (;; Clear various specials used by GET-DESCRIPTOR-FOR to
 568         ;; communicate cleanup info.
 569         *close-on-error*
 570         *close-in-parent*
 571         *handlers-installed*
 572         ;; Establish PROC at this level so that we can return it.
 573         proc
 574         ;; It's friendly to allow the caller to pass any string
 575         ;; designator, but internally we'd like SIMPLE-STRINGs.
 576         (simple-args (mapcar (lambda (x) (coerce x 'simple-string)) args)))
 577     (unwind-protect
 578          (let (;; FIXME: The old code here used to do
 579                ;;   (MERGE-PATHNAMES PROGRAM "path:"),
 580                ;; which is the right idea (searching through the Unix
 581                ;; PATH). Unfortunately, there is no logical pathname
 582                ;; "path:" defined in sbcl-0.6.10. It would probably be
 583                ;; reasonable to restore Unix PATH searching in SBCL, e.g.
 584                ;; with a function FIND-EXECUTABLE-FILE-IN-POSIX-PATH.
 585                ;; (I don't want to do it with search lists the way
 586                ;; that CMU CL did, because those are a non-ANSI
 587                ;; extension which I'd like to get rid of. -- WHN)
 588                (pfile (unix-namestring program t t))
 589                (cookie (list 0)))
 590            (unless pfile
 591              (error "no such program: ~S" program))
 592            (multiple-value-bind (stdin input-stream)
 593                (get-descriptor-for input cookie
 594                                    :direction :input
 595                                    :if-does-not-exist if-input-does-not-exist)
 596              (multiple-value-bind (stdout output-stream)
 597                  (get-descriptor-for output cookie
 598                                      :direction :output
 599                                      :if-exists if-output-exists)
 600                (multiple-value-bind (stderr error-stream)
 601                    (if (eq error :output)
 602                        (values stdout output-stream)
 603                        (get-descriptor-for error cookie
 604                                            :direction :output
 605                                            :if-exists if-error-exists))
 606                  (multiple-value-bind (pty-name pty-stream)
 607                      (open-pty pty cookie)
 608                    ;; Make sure we are not notified about the child
 609                    ;; death before we have installed the PROCESS
 610                    ;; structure in *ACTIVE-PROCESSES*.
 611                    (sb-sys:without-interrupts
 612                     (with-c-strvec (args-vec simple-args)
 613                       (with-c-strvec (environment-vec environment)
 614                         (let ((child-pid
 615                                (without-gcing
 616                                 (spawn pfile args-vec environment-vec pty-name
 617                                        stdin stdout stderr))))
 618                           (when (< child-pid 0)
 619                             (error "could not fork child process: ~S"
 620                                    (sb-unix:get-unix-error-msg)))
 621                           (setf proc (make-process :pid child-pid
 622                                                    :%status :running
 623                                                    :pty pty-stream
 624                                                    :input input-stream
 625                                                    :output output-stream
 626                                                    :error error-stream
 627                                                    :status-hook status-hook
 628                                                    :cookie cookie))
 629                           (push proc *active-processes*))))))))))
 630       (dolist (fd *close-in-parent*)
 631         (sb-unix:unix-close fd))
 632       (unless proc
 633         (dolist (fd *close-on-error*)
 634           (sb-unix:unix-close fd))
 635         (dolist (handler *handlers-installed*)
 636           (sb-sys:remove-fd-handler handler))))
 637     (when (and wait proc)
 638       (process-wait proc))
 639     proc))
 640
 641 ;;; Install a handler for any input that shows up on the file
 642 ;;; descriptor. The handler reads the data and writes it to the
 643 ;;; stream.
 644 (defun copy-descriptor-to-stream (descriptor stream cookie)
 645   (incf (car cookie))
 646   (let ((string (make-string 256))
 647         handler)
 648     (setf handler
 649           (sb-sys:add-fd-handler
 650            descriptor
 651            :input #'(lambda (fd)
 652                       (declare (ignore fd))
 653                       (loop
 654                           (unless handler
 655                             (return))
 656                           (multiple-value-bind
 657                                 (result readable/errno)
 658                               (sb-unix:unix-select (1+ descriptor)
 659                                                    (ash 1 descriptor)
 660                                                    0 0 0)
 661                             (cond ((null result)
 662                                    (error "could not select on sub-process: ~S"
 663                                           (sb-unix:get-unix-error-msg
 664                                            readable/errno)))
 665                                   ((zerop result)
 666                                    (return))))
 667                         (sb-alien:with-alien ((buf (sb-alien:array
 668                                                     sb-c-call:char
 669                                                     256)))
 670                           (multiple-value-bind
 671                                 (count errno)
 672                               (sb-unix:unix-read descriptor
 673                                                  (alien-sap buf)
 674                                                  256)
 675                             (cond ((or (and (null count)
 676                                             (eql errno sb-unix:eio))
 677                                        (eql count 0))
 678                                    (sb-sys:remove-fd-handler handler)
 679                                    (setf handler nil)
 680                                    (decf (car cookie))
 681                                    (sb-unix:unix-close descriptor)
 682                                    (return))
 683                                   ((null count)
 684                                    (sb-sys:remove-fd-handler handler)
 685                                    (setf handler nil)
 686                                    (decf (car cookie))
 687                                    (error "could not read input from sub-process: ~S"
 688                                           (sb-unix:get-unix-error-msg errno)))
 689                                   (t
 690                                    (sb-kernel:copy-from-system-area
 691                                     (alien-sap buf) 0
 692                                     string (* sb-vm:vector-data-offset
 693                                               sb-vm:word-bits)
 694                                     (* count sb-vm:byte-bits))
 695                                    (write-string string stream
 696                                                  :end count)))))))))))
 697
 698 ;;; Find a file descriptor to use for object given the direction.
 699 ;;; Returns the descriptor. If object is :STREAM, returns the created
 700 ;;; stream as the second value.
 701 (defun get-descriptor-for (object
 702                            cookie
 703                            &rest keys
 704                            &key direction
 705                            &allow-other-keys)
 706   (cond ((eq object t)
 707          ;; No new descriptor is needed.
 708          (values -1 nil))
 709         ((eq object nil)
 710          ;; Use /dev/null.
 711          (multiple-value-bind
 712                (fd errno)
 713              (sb-unix:unix-open "/dev/null"
 714                                 (case direction
 715                                   (:input sb-unix:o_rdonly)
 716                                   (:output sb-unix:o_wronly)
 717                                   (t sb-unix:o_rdwr))
 718                                 #o666)
 719            (unless fd
 720              (error "could not open \"/dev/null\": ~S"
 721                     (sb-unix:get-unix-error-msg errno)))
 722            (push fd *close-in-parent*)
 723            (values fd nil)))
 724         ((eq object :stream)
 725          (multiple-value-bind
 726                (read-fd write-fd)
 727              (sb-unix:unix-pipe)
 728            (unless read-fd
 729              (error "could not create pipe: ~S"
 730                     (sb-unix:get-unix-error-msg write-fd)))
 731            (case direction
 732              (:input
 733               (push read-fd *close-in-parent*)
 734               (push write-fd *close-on-error*)
 735               (let ((stream (sb-sys:make-fd-stream write-fd :output t)))
 736                 (values read-fd stream)))
 737              (:output
 738               (push read-fd *close-on-error*)
 739               (push write-fd *close-in-parent*)
 740               (let ((stream (sb-sys:make-fd-stream read-fd :input t)))
 741                 (values write-fd stream)))
 742              (t
 743               (sb-unix:unix-close read-fd)
 744               (sb-unix:unix-close write-fd)
 745               (error "Direction must be either :INPUT or :OUTPUT, not ~S."
 746                      direction)))))
 747         ((or (pathnamep object) (stringp object))
 748          (with-open-stream (file (apply #'open object keys))
 749            (multiple-value-bind
 750                  (fd errno)
 751                (sb-unix:unix-dup (sb-sys:fd-stream-fd file))
 752              (cond (fd
 753                     (push fd *close-in-parent*)
 754                     (values fd nil))
 755                    (t
 756                     (error "could not duplicate file descriptor: ~S"
 757                            (sb-unix:get-unix-error-msg errno)))))))
 758         ((sb-sys:fd-stream-p object)
 759          (values (sb-sys:fd-stream-fd object) nil))
 760         ((streamp object)
 761          (ecase direction
 762            (:input
 763             ;; FIXME: We could use a better way of setting up
 764             ;; temporary files, both here and in LOAD-FOREIGN.
 765             (dotimes (count
 766                        256
 767                       (error "could not open a temporary file in /tmp"))
 768               (let* ((name (format nil "/tmp/.run-program-~D" count))
 769                      (fd (sb-unix:unix-open name
 770                                             (logior sb-unix:o_rdwr
 771                                                     sb-unix:o_creat
 772                                                     sb-unix:o_excl)
 773                                             #o666)))
 774                 (sb-unix:unix-unlink name)
 775                 (when fd
 776                   (let ((newline (string #\Newline)))
 777                     (loop
 778                         (multiple-value-bind
 779                               (line no-cr)
 780                             (read-line object nil nil)
 781                           (unless line
 782                             (return))
 783                           (sb-unix:unix-write fd line 0 (length line))
 784                           (if no-cr
 785                               (return)
 786                               (sb-unix:unix-write fd newline 0 1)))))
 787                   (sb-unix:unix-lseek fd 0 sb-unix:l_set)
 788                   (push fd *close-in-parent*)
 789                   (return (values fd nil))))))
 790            (:output
 791             (multiple-value-bind (read-fd write-fd)
 792                 (sb-unix:unix-pipe)
 793               (unless read-fd
 794                 (error "could not create pipe: ~S"
 795                        (sb-unix:get-unix-error-msg write-fd)))
 796               (copy-descriptor-to-stream read-fd object cookie)
 797               (push read-fd *close-on-error*)
 798               (push write-fd *close-in-parent*)
 799               (values write-fd nil)))))
 800         (t
 801          (error "invalid option to RUN-PROGRAM: ~S" object))))