src/code/save.lisp

   1 ;;;; Dump the current Lisp image into a core file. Also contains
   2 ;;;; various high-level initialization stuff: loading init files and
   3 ;;;; parsing environment variables.
   4 ;;;;
   5 ;;;; (All the real work is done by C.)
   6
   7 ;;;; This software is part of the SBCL system. See the README file for
   8 ;;;; more information.
   9 ;;;;
  10 ;;;; This software is derived from the CMU CL system, which was
  11 ;;;; written at Carnegie Mellon University and released into the
  12 ;;;; public domain. The software is in the public domain and is
  13 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  14 ;;;; files for more information.
  15
  16 (in-package "SB!IMPL")
  17 \f
  18 ;;;; SAVE-LISP-AND-DIE itself
  19
  20 (define-alien-routine "save" (boolean)
  21   (file c-string)
  22   (initial-fun (unsigned #.sb!vm:n-word-bits))
  23   (prepend-runtime int)
  24   (save-runtime-options int))
  25
  26 #!+gencgc
  27 (define-alien-routine "gc_and_save" void
  28   (file c-string)
  29   (prepend-runtime int)
  30   (save-runtime-options int))
  31
  32 #!+gencgc
  33 (defvar sb!vm::*restart-lisp-function*)
  34
  35 (defun save-lisp-and-die (core-file-name &key
  36                                          (toplevel #'toplevel-init)
  37                                          (executable nil)
  38                                          (save-runtime-options nil)
  39                                          (purify t)
  40                                          (root-structures ())
  41                                          (environment-name "auxiliary"))
  42   #!+sb-doc
  43   "Save a \"core image\", i.e. enough information to restart a Lisp
  44 process later in the same state, in the file of the specified name.
  45 Only global state is preserved: the stack is unwound in the process.
  46
  47 The following &KEY arguments are defined:
  48
  49   :TOPLEVEL
  50      The function to run when the created core file is resumed. The
  51      default function handles command line toplevel option processing
  52      and runs the top level read-eval-print loop. This function returning
  53      is equivalent to (SB-EXT:QUIT :UNIX-STATUS 0) being called.
  54
  55   :EXECUTABLE
  56      If true, arrange to combine the SBCL runtime and the core image
  57      to create a standalone executable.  If false (the default), the
  58      core image will not be executable on its own. Executable images
  59      always behave as if they were passed the --noinform runtime option.
  60
  61   :SAVE-RUNTIME-OPTIONS
  62      If true, values of runtime options --dynamic-space-size and
  63      --control-stack-size that were used to start SBCL are stored in
  64      the standalone executable, and restored when the executable is
  65      run. This also inhibits normal runtime option processing, causing
  66      all command line arguments to be passed to the toplevel.
  67      Meaningless if :EXECUTABLE is NIL.
  68
  69   :PURIFY
  70      If true (the default on cheneygc), do a purifying GC which moves all
  71      dynamically allocated objects into static space. This takes
  72      somewhat longer than the normal GC which is otherwise done, but
  73      it's only done once, and subsequent GC's will be done less often
  74      and will take less time in the resulting core file. See the PURIFY
  75      function. This parameter has no effect on platforms using the
  76      generational garbage collector.
  77
  78   :ROOT-STRUCTURES
  79      This should be a list of the main entry points in any newly loaded
  80      systems. This need not be supplied, but locality and/or GC performance
  81      may be better if they are. Meaningless if :PURIFY is NIL. See the
  82      PURIFY function.
  83
  84   :ENVIRONMENT-NAME
  85      This is also passed to the PURIFY function when :PURIFY is T.
  86      (rarely used)
  87
  88 The save/load process changes the values of some global variables:
  89
  90   *STANDARD-OUTPUT*, *DEBUG-IO*, etc.
  91     Everything related to open streams is necessarily changed, since
  92     the OS won't let us preserve a stream across save and load.
  93
  94   *DEFAULT-PATHNAME-DEFAULTS*
  95     This is reinitialized to reflect the working directory where the
  96     saved core is loaded.
  97
  98 SAVE-LISP-AND-DIE interacts with SB-ALIEN:LOAD-SHARED-OBJECT: see its
  99 documentation for details.
 100
 101 On threaded platforms only a single thread may remain running after
 102 SB-EXT:*SAVE-HOOKS* have run. Applications using multiple threads can
 103 be SAVE-LISP-AND-DIE friendly by registering a save-hook that quits
 104 any additional threads, and an init-hook that restarts them.
 105
 106 This implementation is not as polished and painless as you might like:
 107   * It corrupts the current Lisp image enough that the current process
 108     needs to be killed afterwards. This can be worked around by forking
 109     another process that saves the core.
 110   * There is absolutely no binary compatibility of core images between
 111     different runtime support programs. Even runtimes built from the same
 112     sources at different times are treated as incompatible for this
 113     purpose.
 114 This isn't because we like it this way, but just because there don't
 115 seem to be good quick fixes for either limitation and no one has been
 116 sufficiently motivated to do lengthy fixes."
 117   #!+gencgc
 118   (declare (ignore purify root-structures environment-name))
 119   (tune-hashtable-sizes-of-all-packages)
 120   (deinit)
 121   ;; FIXME: Would it be possible to unmix the PURIFY logic from this
 122   ;; function, and just do a GC :FULL T here? (Then if the user wanted
 123   ;; a PURIFYed image, he'd just run PURIFY immediately before calling
 124   ;; SAVE-LISP-AND-DIE.)
 125   (labels ((restart-lisp ()
 126              (handling-end-of-the-world
 127                (reinit)
 128                #!+hpux (sb!sys:%primitive sb!vm::setup-return-from-lisp-stub)
 129                (funcall toplevel)))
 130            (foreign-bool (value)
 131              (if value 1 0))
 132            (save-core (gc)
 133              (let ((name (native-namestring
 134                           (physicalize-pathname core-file-name)
 135                           :as-file t)))
 136                (when gc
 137                  #!-gencgc (gc)
 138                  ;; Do a destructive non-conservative GC, and then save a core.
 139                  ;; A normal GC will leave huge amounts of storage unreclaimed
 140                  ;; (over 50% on x86). This needs to be done by a single function
 141                  ;; since the GC will invalidate the stack.
 142                  #!+gencgc (gc-and-save name
 143                                         (foreign-bool executable)
 144                                         (foreign-bool save-runtime-options)))
 145                (without-gcing
 146                  (save name
 147                        (get-lisp-obj-address #'restart-lisp)
 148                        (foreign-bool executable)
 149                        (foreign-bool save-runtime-options))))))
 150     ;; Save the restart function into a static symbol, to allow GC-AND-SAVE
 151     ;; access to it even after the GC has moved it.
 152     #!+gencgc
 153     (setf sb!vm::*restart-lisp-function* #'restart-lisp)
 154     (cond #!-gencgc
 155           (purify
 156            (purify :root-structures root-structures
 157                    :environment-name environment-name)
 158            (save-core nil))
 159           (t
 160            ;; Compact the environment even though we're skipping the
 161            ;; other purification stages.
 162            (sb!kernel::compact-environment-aux "Auxiliary" 200)
 163            (save-core t)))
 164     ;; Something went very wrong -- reinitialize to have a prayer
 165     ;; of being able to report the error.
 166     (reinit)
 167     (error "Could not save core.")))
 168
 169 (defun deinit ()
 170   (call-hooks "save" *save-hooks*)
 171   (when (rest (sb!thread:list-all-threads))
 172     (error "Cannot save core with multiple threads running."))
 173   (float-deinit)
 174   (profile-deinit)
 175   (debug-deinit)
 176   (foreign-deinit)
 177   (stream-deinit)
 178   (deinit-finalizers)
 179   (drop-all-hash-caches))