src/code/save.lisp

   1 ;;;; Dump the current Lisp image into a core file. Also contains
   2 ;;;; various high-level initialization stuff: loading init files and
   3 ;;;; parsing environment variables.
   4 ;;;;
   5 ;;;; (All the real work is done by C.)
   6
   7 ;;;; This software is part of the SBCL system. See the README file for
   8 ;;;; more information.
   9 ;;;;
  10 ;;;; This software is derived from the CMU CL system, which was
  11 ;;;; written at Carnegie Mellon University and released into the
  12 ;;;; public domain. The software is in the public domain and is
  13 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  14 ;;;; files for more information.
  15
  16 (in-package "SB!IMPL")
  17 \f
  18 ;;;; SAVE-LISP-AND-DIE itself
  19
  20 (define-alien-routine "save" (boolean)
  21   (file c-string)
  22   (initial-fun (unsigned #.sb!vm:n-word-bits)))
  23
  24 #!+gencgc
  25 (define-alien-routine "gc_and_save" void
  26   (file c-string))
  27
  28 #!+gencgc
  29 (defvar sb!vm::*restart-lisp-function*)
  30
  31 (defun save-lisp-and-die (core-file-name &key
  32                                          (toplevel #'toplevel-init)
  33                                          (purify t)
  34                                          (root-structures ())
  35                                          (environment-name "auxiliary"))
  36   #!+sb-doc
  37   "Save a \"core image\", i.e. enough information to restart a Lisp
  38 process later in the same state, in the file of the specified name.
  39 Only global state is preserved: the stack is unwound in the process.
  40
  41 The following &KEY arguments are defined:
  42
  43   :TOPLEVEL
  44      The function to run when the created core file is resumed. The
  45      default function handles command line toplevel option processing
  46      and runs the top level read-eval-print loop. This function should
  47      not return.
  48
  49   :PURIFY
  50      If true (the default), do a purifying GC which moves all
  51      dynamically allocated objects into static space. This takes
  52      somewhat longer than the normal GC which is otherwise done, but
  53      it's only done once, and subsequent GC's will be done less often
  54      and will take less time in the resulting core file. See the PURIFY
  55      function.
  56
  57   :ROOT-STRUCTURES
  58      This should be a list of the main entry points in any newly loaded
  59      systems. This need not be supplied, but locality and/or GC performance
  60      may be better if they are. Meaningless if :PURIFY is NIL. See the
  61      PURIFY function.
  62
  63   :ENVIRONMENT-NAME
  64      This is also passed to the PURIFY function when :PURIFY is T.
  65      (rarely used)
  66
  67 The save/load process changes the values of some global variables:
  68
  69   *STANDARD-OUTPUT*, *DEBUG-IO*, etc.
  70     Everything related to open streams is necessarily changed, since
  71     the OS won't let us preserve a stream across save and load.
  72
  73   *DEFAULT-PATHNAME-DEFAULTS*
  74     This is reinitialized to reflect the working directory where the
  75     saved core is loaded.
  76
  77 Foreign objects loaded with SB-ALIEN:LOAD-SHARED-OBJECT are
  78 automatically reloaded on startup, but references to foreign symbols
  79 do not survive intact on all platforms: in this case a WARNING is
  80 signalled when saving the core. If no warning is signalled, then the
  81 foreign symbol references will remain intact. Platforms where this is
  82 currently the case are x86/FreeBSD, x86/Linux, x86/NetBSD,
  83 sparc/Linux, sparc/SunOS, and ppc/Darwin.
  84
  85 This implementation is not as polished and painless as you might like:
  86   * It corrupts the current Lisp image enough that the current process
  87     needs to be killed afterwards. This can be worked around by forking
  88     another process that saves the core.
  89   * It will not work if multiple threads are in use.
  90   * There is absolutely no binary compatibility of core images between
  91     different runtime support programs. Even runtimes built from the same
  92     sources at different times are treated as incompatible for this
  93     purpose.
  94 This isn't because we like it this way, but just because there don't
  95 seem to be good quick fixes for either limitation and no one has been
  96 sufficiently motivated to do lengthy fixes."
  97   (deinit)
  98   ;; FIXME: Would it be possible to unmix the PURIFY logic from this
  99   ;; function, and just do a GC :FULL T here? (Then if the user wanted
 100   ;; a PURIFYed image, he'd just run PURIFY immediately before calling
 101   ;; SAVE-LISP-AND-DIE.)
 102   (labels ((restart-lisp ()
 103              (handling-end-of-the-world
 104                (reinit)
 105                (funcall toplevel)))
 106            (save-core (gc)
 107              (when gc
 108                #!-gencgc (gc)
 109                ;; Do a destructive non-conservative GC, and then save a core.
 110                ;; A normal GC will leave huge amounts of storage unreclaimed
 111                ;; (over 50% on x86). This needs to be done by a single function
 112                ;; since the GC will invalidate the stack.
 113                #!+gencgc (gc-and-save (unix-namestring core-file-name nil)))
 114              (without-gcing
 115               (save (unix-namestring core-file-name nil)
 116                     (get-lisp-obj-address #'restart-lisp)))))
 117     ;; Save the restart function into a static symbol, to allow GC-AND-SAVE
 118     ;; access to it even after the GC has moved it.
 119     (setf sb!vm::*restart-lisp-function* #'restart-lisp)
 120     (cond (purify
 121            (purify :root-structures root-structures
 122                    :environment-name environment-name)
 123            (save-core nil))
 124           (t
 125            (save-core t)))))
 126
 127 (defun deinit ()
 128   (dolist (hook *save-hooks*)
 129     (with-simple-restart (continue "Skip this save hook.")
 130       (funcall hook)))
 131   (when (fboundp 'cancel-finalization)
 132     (cancel-finalization sb!sys:*tty*))
 133   (profile-deinit)
 134   (debug-deinit)
 135   (foreign-deinit))