src/code/save.lisp

   1 ;;;; Dump the current Lisp image into a core file. Also contains
   2 ;;;; various high-level initialization stuff: loading init files and
   3 ;;;; parsing environment variables.
   4 ;;;;
   5 ;;;; (All the real work is done by C.)
   6
   7 ;;;; This software is part of the SBCL system. See the README file for
   8 ;;;; more information.
   9 ;;;;
  10 ;;;; This software is derived from the CMU CL system, which was
  11 ;;;; written at Carnegie Mellon University and released into the
  12 ;;;; public domain. The software is in the public domain and is
  13 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  14 ;;;; files for more information.
  15
  16 (in-package "SB!IMPL")
  17 \f
  18 ;;;; SAVE-LISP-AND-DIE itself
  19
  20 (define-alien-routine "save" (boolean)
  21   (file c-string)
  22   (initial-fun (unsigned #.sb!vm:n-word-bits)))
  23
  24 ;;; FIXME: When this is run without the PURIFY option,
  25 ;;; it seems to save memory all the way up to the high-water mark,
  26 ;;; not just what's currently used; and then after loading the
  27 ;;; image to make a running Lisp, the memory never gets reclaimed.
  28 ;;; (But with the PURIFY option it seems to work OK.)
  29 (defun save-lisp-and-die (core-file-name &key
  30                                          (toplevel #'toplevel-init)
  31                                          (purify t)
  32                                          (root-structures ())
  33                                          (environment-name "auxiliary"))
  34   #!+sb-doc
  35   "Save a \"core image\", i.e. enough information to restart a Lisp
  36 process later in the same state, in the file of the specified name.
  37
  38 This implementation is not as polished and painless as you might
  39 like:
  40   * It corrupts the current Lisp image enough that the current process
  41     needs to be killed afterwards. This can be worked around by forking
  42     another process that saves the core.
  43   * It will not work if multiple threads are in use.
  44   * There is absolutely no binary compatibility of core images between
  45     different runtime support programs. Even runtimes built from the same
  46     sources at different times are treated as incompatible for this
  47     purpose.
  48 This isn't because we like it this way, but just because there don't
  49 seem to be good quick fixes for either limitation and no one has been
  50 sufficiently motivated to do lengthy fixes.
  51
  52 The following &KEY arguments are defined:
  53   :TOPLEVEL
  54      The function to run when the created core file is resumed. The
  55      default function handles command line toplevel option processing
  56      and runs the top level read-eval-print loop. This function should
  57      not return.
  58   :PURIFY
  59      If true (the default), do a purifying GC which moves all
  60      dynamically allocated objects into static space. This takes
  61      somewhat longer than the normal GC which is otherwise done, but
  62      it's only done once, and subsequent GC's will be done less often
  63      and will take less time in the resulting core file. See the PURIFY
  64      function.
  65   :ROOT-STRUCTURES
  66      This should be a list of the main entry points in any newly loaded
  67      systems. This need not be supplied, but locality and/or GC performance
  68      may be better if they are. Meaningless if :PURIFY is NIL. See the
  69      PURIFY function.
  70   :ENVIRONMENT-NAME
  71      This is also passed to the PURIFY function when :PURIFY is T.
  72      (rarely used)
  73
  74 The save/load process changes the values of some global variables:
  75   *STANDARD-OUTPUT*, *DEBUG-IO*, etc.
  76     Everything related to open streams is necessarily changed, since
  77     the OS won't let us preserve a stream across save and load.
  78   *DEFAULT-PATHNAME-DEFAULTS*
  79     This is reinitialized to reflect the working directory where the
  80     saved core is loaded."
  81   (deinit)
  82   ;; FIXME: Would it be possible to unmix the PURIFY logic from this
  83   ;; function, and just do a GC :FULL T here? (Then if the user wanted
  84   ;; a PURIFYed image, he'd just run PURIFY immediately before calling
  85   ;; SAVE-LISP-AND-DIE.)
  86   (if purify
  87       (purify :root-structures root-structures
  88               :environment-name environment-name)
  89       #-gencgc (gc) #+gencgc (gc :full t))
  90   (flet ((restart-lisp ()
  91            (handling-end-of-the-world
  92             (reinit)
  93             (funcall toplevel))))
  94     ;; FIXME: Perhaps WITHOUT-GCING should be wrapped around the
  95     ;; LET as well, to avoid the off chance of an interrupt triggering
  96     ;; GC and making our saved RESTART-LISP address invalid?
  97     (without-gcing
  98      (save (unix-namestring core-file-name nil)
  99            (get-lisp-obj-address #'restart-lisp)))))
 100
 101 (defun deinit ()
 102   (mapc #'funcall *save-hooks*)
 103   (when (fboundp 'cancel-finalization)
 104     (cancel-finalization sb!sys:*tty*))
 105   (profile-deinit)
 106   (debug-deinit)
 107   (foreign-deinit))