src/code/save.lisp

   1 ;;;; Dump the current Lisp image into a core file. Also contains
   2 ;;;; various high-level initialization stuff: loading init files and
   3 ;;;; parsing environment variables.
   4 ;;;;
   5 ;;;; (All the real work is done by C.)
   6
   7 ;;;; This software is part of the SBCL system. See the README file for
   8 ;;;; more information.
   9 ;;;;
  10 ;;;; This software is derived from the CMU CL system, which was
  11 ;;;; written at Carnegie Mellon University and released into the
  12 ;;;; public domain. The software is in the public domain and is
  13 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  14 ;;;; files for more information.
  15
  16 (in-package "SB!IMPL")
  17 \f
  18 ;;;; SAVE-LISP-AND-DIE itself
  19
  20 (sb!alien:define-alien-routine "save" (sb!alien:boolean)
  21   (file sb!alien:c-string)
  22   (initial-fun (sb!alien:unsigned #.sb!vm:n-word-bits)))
  23
  24 ;;; FIXME: When this is run without the PURIFY option,
  25 ;;; it seems to save memory all the way up to the high-water mark,
  26 ;;; not just what's currently used; and then after loading the
  27 ;;; image to make a running Lisp, the memory never gets reclaimed.
  28 ;;; (But with the PURIFY option it seems to work OK.)
  29 (defun save-lisp-and-die (core-file-name &key
  30                                          (toplevel #'toplevel-init)
  31                                          (purify t)
  32                                          (root-structures ())
  33                                          (environment-name "auxiliary"))
  34   #!+sb-doc
  35   "Save a \"core image\", i.e. enough information to restart a Lisp
  36   process later in the same state, in the file of the specified name.
  37
  38   This implementation is not as polished and painless as you might like:
  39     * It corrupts the current Lisp image enough that the current process
  40       needs to be killed afterwards.
  41     * It will not work if multiple threads are in use.
  42     * There is absolutely no binary compatibility of core images between
  43       different runtime support programs. Even runtimes built from the same
  44       sources at different times are treated as incompatible for this purpose.
  45   This isn't because we like it this way, but just because there don't
  46   seem to be good quick fixes for either limitation and no one has been
  47   sufficiently motivated to do lengthy fixes.
  48
  49   The following &KEY arguments are defined:
  50     :TOPLEVEL
  51        The function to run when the created core file is resumed.
  52        The default function handles command line toplevel option
  53        processing and runs the top level read-eval-print loop. This
  54        function should not return.
  55     :PURIFY
  56        If true (the default), do a purifying GC which moves all dynamically
  57        allocated objects into static space so that they stay pure. This takes
  58        somewhat longer than the normal GC which is otherwise done, but it's
  59        only done once, and subsequent GC's will be done less often and will
  60        take less time in the resulting core file. See the PURIFY function.
  61     :ROOT-STRUCTURES
  62        This should be a list of the main entry points in any newly loaded
  63        systems. This need not be supplied, but locality and/or GC performance
  64        may be better if they are. Meaningless if :PURIFY is NIL. See the
  65        PURIFY function.
  66     :ENVIRONMENT-NAME
  67        This is also passed to the PURIFY function when :PURIFY is T.
  68        (rarely used)
  69
  70   The save/load process changes the values of some global variables:
  71     *STANDARD-OUTPUT*, *DEBUG-IO*, etc.
  72       Everything related to open streams is necessarily changed, since
  73       the OS won't let us preserve a stream across save and load.
  74     *DEFAULT-PATHNAME-DEFAULTS*
  75       This is reinitialized to reflect the working directory where the
  76       saved core is loaded."
  77
  78   (when (fboundp 'cancel-finalization)
  79     (cancel-finalization sb!sys:*tty*))
  80   ;; FIXME: Would it be possible to unmix the PURIFY logic from this
  81   ;; function, and just do a GC :FULL T here? (Then if the user wanted
  82   ;; a PURIFYed image, he'd just run PURIFY immediately before calling
  83   ;; SAVE-LISP-AND-DIE.)
  84   (if purify
  85       (purify :root-structures root-structures
  86               :environment-name environment-name)
  87       #!-gencgc (gc) #!+gencgc (gc :full t))
  88   ;; FIXME: Wouldn't it be more correct to go through this list backwards
  89   ;; instead of forwards?
  90   (dolist (f *before-save-initializations*)
  91     (funcall f))
  92   (flet ((restart-lisp ()
  93            (handling-end-of-the-world
  94              (reinit)
  95              (dolist (f *after-save-initializations*)
  96                (funcall f))
  97              (funcall toplevel))))
  98     ;; FIXME: Perhaps WITHOUT-GCING should be wrapped around the
  99     ;; LET as well, to avoid the off chance of an interrupt triggering
 100     ;; GC and making our saved RESTART-LISP address invalid?
 101     (without-gcing
 102       (save (unix-namestring core-file-name nil)
 103             (get-lisp-obj-address #'restart-lisp)))))