src/code/serve-event.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3 ;;;;
   4 ;;;; This software is derived from the CMU CL system, which was
   5 ;;;; written at Carnegie Mellon University and released into the
   6 ;;;; public domain. The software is in the public domain and is
   7 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
   8 ;;;; files for more information.
   9
  10 (in-package "SB!IMPL")
  11
  12 ;;;; file descriptor I/O noise
  13
  14 (defstruct (handler
  15             (:constructor make-handler (direction descriptor function))
  16             (:copier nil))
  17   ;; Reading or writing...
  18   (direction nil :type (member :input :output))
  19   ;; File descriptor this handler is tied to.
  20   (descriptor 0 :type (mod #.sb!unix:fd-setsize))
  21   ;; T iff this handler is running.
  22   ;;
  23   ;; FIXME: unused. At some point this used to be set to T
  24   ;; around the call to the handler-function, but that was commented
  25   ;; out with the verbose explantion "Doesn't work -- ACK".
  26   active
  27   ;; Function to call.
  28   (function nil :type function)
  29   ;; T if this descriptor is bogus.
  30   bogus)
  31
  32 (def!method print-object ((handler handler) stream)
  33   (print-unreadable-object (handler stream :type t)
  34     (format stream
  35             "~A on ~:[~;BOGUS ~]descriptor ~W: ~S"
  36             (handler-direction handler)
  37             (handler-bogus handler)
  38             (handler-descriptor handler)
  39             (handler-function handler))))
  40
  41 (defvar *descriptor-handlers* nil
  42   #!+sb-doc
  43   "List of all the currently active handlers for file descriptors")
  44
  45 (sb!xc:defmacro with-descriptor-handlers (&body forms)
  46   ;; FD-STREAM functionality can add and remove descriptors on it's
  47   ;; own, so getting an interrupt while modifying this and the
  48   ;; starting to recursively modify it could lose...
  49   `(without-interrupts ,@forms))
  50
  51 (defun list-all-descriptor-handlers ()
  52   (with-descriptor-handlers
  53     (copy-list *descriptor-handlers*)))
  54
  55 (defun select-descriptor-handlers (function)
  56   (declare (function function))
  57   (with-descriptor-handlers
  58     (remove-if-not function *descriptor-handlers*)))
  59
  60 (defun map-descriptor-handlers (function)
  61   (declare (function function))
  62   (with-descriptor-handlers
  63     (dolist (handler *descriptor-handlers*)
  64       (funcall function handler))))
  65
  66 ;;; Add a new handler to *descriptor-handlers*.
  67 (defun add-fd-handler (fd direction function)
  68   #!+sb-doc
  69   "Arange to call FUNCTION whenever FD is usable. DIRECTION should be
  70   either :INPUT or :OUTPUT. The value returned should be passed to
  71   SYSTEM:REMOVE-FD-HANDLER when it is no longer needed."
  72   (unless (member direction '(:input :output))
  73     ;; FIXME: should be TYPE-ERROR?
  74     (error "Invalid direction ~S, must be either :INPUT or :OUTPUT" direction))
  75   (unless (<= 0 fd (1- sb!unix:fd-setsize))
  76     (error "Cannot add an FD handler for ~D: not under FD_SETSIZE limit." fd))
  77   (let ((handler (make-handler direction fd function)))
  78     (with-descriptor-handlers
  79       (push handler *descriptor-handlers*))
  80     handler))
  81
  82 ;;; Remove an old handler from *descriptor-handlers*.
  83 (defun remove-fd-handler (handler)
  84   #!+sb-doc
  85   "Removes HANDLER from the list of active handlers."
  86   (with-descriptor-handlers
  87     (setf *descriptor-handlers*
  88           (delete handler *descriptor-handlers*))))
  89
  90 ;;; Search *descriptor-handlers* for any reference to fd, and nuke 'em.
  91 (defun invalidate-descriptor (fd)
  92   #!+sb-doc
  93   "Remove any handers refering to fd. This should only be used when attempting
  94   to recover from a detected inconsistancy."
  95   (with-descriptor-handlers
  96     (setf *descriptor-handlers*
  97           (delete fd *descriptor-handlers*
  98                   :key #'handler-descriptor))))
  99
 100 ;;; Add the handler to *descriptor-handlers* for the duration of BODY.
 101 (defmacro with-fd-handler ((fd direction function) &rest body)
 102   #!+sb-doc
 103   "Establish a handler with SYSTEM:ADD-FD-HANDLER for the duration of BODY.
 104    DIRECTION should be either :INPUT or :OUTPUT, FD is the file descriptor to
 105    use, and FUNCTION is the function to call whenever FD is usable."
 106   (let ((handler (gensym)))
 107     `(let (,handler)
 108        (unwind-protect
 109            (progn
 110              (setf ,handler (add-fd-handler ,fd ,direction ,function))
 111              ,@body)
 112          (when ,handler
 113            (remove-fd-handler ,handler))))))
 114
 115 ;;; First, get a list and mark bad file descriptors. Then signal an error
 116 ;;; offering a few restarts.
 117 (defun handler-descriptors-error ()
 118   (let ((bogus-handlers nil))
 119     (dolist (handler (list-all-descriptor-handlers))
 120       (unless (or (handler-bogus handler)
 121                   (sb!unix:unix-fstat (handler-descriptor handler)))
 122         (setf (handler-bogus handler) t)
 123         (push handler bogus-handlers)))
 124     (when bogus-handlers
 125       (restart-case (error "~S ~[have~;has a~:;have~] bad file descriptor~:P."
 126                            bogus-handlers (length bogus-handlers))
 127         (remove-them ()
 128           :report "Remove bogus handlers."
 129           (with-descriptor-handlers
 130             (setf *descriptor-handlers*
 131                   (delete-if #'handler-bogus *descriptor-handlers*))))
 132         (retry-them ()
 133           :report "Retry bogus handlers."
 134           (dolist (handler bogus-handlers)
 135             (setf (handler-bogus handler) nil)))
 136         (continue ()
 137           :report "Go on, leaving handlers marked as bogus."))))
 138   nil)
 139
 140 \f
 141 ;;;; SERVE-ALL-EVENTS, SERVE-EVENT, and friends
 142
 143 ;;; When a *periodic-polling-function* is defined the server will not
 144 ;;; block for more than the maximum event timeout and will call the
 145 ;;; polling function if it does time out.
 146 (declaim (type (or null symbol function) *periodic-polling-function*))
 147 (defvar *periodic-polling-function* nil
 148   "Either NIL, or a designator for a function callable without any
 149 arguments. Called when the system has been waiting for input for
 150 longer then *PERIODIC-POLLING-PERIOD* seconds. Shared between all
 151 threads, unless locally bound. EXPERIMENTAL.")
 152 (declaim (real *periodic-polling-period*))
 153 (defvar *periodic-polling-period* 0
 154   "A real number designating the number of seconds to wait for input
 155 at maximum, before calling the *PERIODIC-POLLING-FUNCTION* \(if any.)
 156 Shared between all threads, unless locally bound. EXPERIMENTAL.")
 157
 158 ;;; Wait until FD is usable for DIRECTION. The timeout given to serve-event is
 159 ;;; recalculated each time through the loop so that WAIT-UNTIL-FD-USABLE will
 160 ;;; timeout at the correct time irrespective of how many events are handled in
 161 ;;; the meantime.
 162 (defun wait-until-fd-usable (fd direction &optional timeout (serve-events t))
 163   #!+sb-doc
 164   "Wait until FD is usable for DIRECTION. DIRECTION should be either :INPUT or
 165 :OUTPUT. TIMEOUT, if supplied, is the number of seconds to wait before giving
 166 up. Returns true once the FD is usable, NIL return indicates timeout.
 167
 168 If SERVE-EVENTS is true (the default), events on other FDs are served while
 169 waiting."
 170   (tagbody
 171    :restart
 172      (multiple-value-bind (to-sec to-usec stop-sec stop-usec signalp)
 173          (decode-timeout timeout)
 174        (declare (type (or integer null) to-sec to-usec))
 175        (flet ((maybe-update-timeout ()
 176                 ;; If we return early, recompute the timeouts, possibly
 177                 ;; signaling the deadline or returning with NIL to caller.
 178                 (setf (values to-sec to-usec)
 179                       (relative-decoded-times stop-sec stop-usec))
 180                 (when (and (zerop to-sec) (not (plusp to-usec)))
 181                   (cond (signalp
 182                          (signal-deadline)
 183                          (go :restart))
 184                         (t
 185                          (return-from wait-until-fd-usable nil))))))
 186          (if (and serve-events
 187                   ;; No timeout or non-zero timeout
 188                   (or (not to-sec)
 189                       (not (= 0 to-sec to-usec)))
 190                   ;; Something to do while we wait
 191                   (or *descriptor-handlers* *periodic-polling-function*))
 192              ;; Loop around SUB-SERVE-EVENT till done.
 193              (dx-let ((usable (list nil)))
 194                (dx-flet ((usable! (fd)
 195                                   (declare (ignore fd))
 196                                   (setf (car usable) t)))
 197                  (with-fd-handler (fd direction #'usable!)
 198                    (loop
 199                      (sub-serve-event to-sec to-usec signalp)
 200                      (when (car usable)
 201                        (return-from wait-until-fd-usable t))
 202                      (when to-sec
 203                        (maybe-update-timeout))))))
 204              ;; If we don't have to serve events, just poll on the single FD instead.
 205              (loop for to-msec = (if (and to-sec to-usec)
 206                                      (+ (* 1000 to-sec) (truncate to-usec 1000))
 207                                      -1)
 208                    when (or #!+win32 (eq direction :output)
 209                             (sb!unix:unix-simple-poll fd direction to-msec))
 210                    do (return-from wait-until-fd-usable t)
 211                    else
 212                    do (when to-sec (maybe-update-timeout))))))))
 213 \f
 214 ;;; Wait for up to timeout seconds for an event to happen. Make sure all
 215 ;;; pending events are processed before returning.
 216 (defun serve-all-events (&optional timeout)
 217   #!+sb-doc
 218   "SERVE-ALL-EVENTS calls SERVE-EVENT with the specified timeout. If
 219 SERVE-EVENT does something (returns T) it loops over SERVE-EVENT with a
 220 timeout of 0 until there are no more events to serve. SERVE-ALL-EVENTS returns
 221 T if SERVE-EVENT did something and NIL if not."
 222   (do ((res nil)
 223        (sval (serve-event timeout) (serve-event 0)))
 224       ((null sval) res)
 225     (setq res t)))
 226
 227 ;;; Serve a single set of events.
 228 (defun serve-event (&optional timeout)
 229   #!+sb-doc
 230   "Receive pending events on all FD-STREAMS and dispatch to the appropriate
 231 handler functions. If timeout is specified, server will wait the specified
 232 time (in seconds) and then return, otherwise it will wait until something
 233 happens. Server returns T if something happened and NIL otherwise. Timeout
 234 0 means polling without waiting."
 235   (multiple-value-bind (to-sec to-usec stop-sec stop-usec signalp)
 236       (decode-timeout timeout)
 237     (declare (ignore stop-sec stop-usec))
 238     (sub-serve-event to-sec to-usec signalp)))
 239
 240 ;;; Takes timeout broken into seconds and microseconds, NIL timeout means
 241 ;;; to wait as long as needed.
 242 (defun sub-serve-event (to-sec to-usec deadlinep)
 243   (or
 244    (if *periodic-polling-function*
 245        (multiple-value-bind (p-sec p-usec)
 246            (decode-internal-time
 247             (seconds-to-internal-time *periodic-polling-period*))
 248          (if to-sec
 249              (loop repeat (/ (+ to-sec (/ to-usec 1e6))
 250                              *periodic-polling-period*)
 251                    thereis (sub-sub-serve-event p-sec p-usec)
 252                    do (funcall *periodic-polling-function*))
 253              (loop thereis (sub-sub-serve-event p-sec p-usec)
 254                    do (funcall *periodic-polling-function*))))
 255        (sub-sub-serve-event to-sec to-usec))
 256    (when deadlinep
 257      (signal-deadline))))
 258
 259 ;;; Handles the work of the above, except for periodic polling. Returns
 260 ;;; true if something of interest happened.
 261 (defun sub-sub-serve-event (to-sec to-usec)
 262   (sb!alien:with-alien ((read-fds (sb!alien:struct sb!unix:fd-set))
 263                         (write-fds (sb!alien:struct sb!unix:fd-set)))
 264     (sb!unix:fd-zero read-fds)
 265     (sb!unix:fd-zero write-fds)
 266     (let ((count 0))
 267       (declare (type index count))
 268
 269       ;; Initialize the fd-sets for UNIX-SELECT and return the active
 270       ;; descriptor count.
 271       (map-descriptor-handlers
 272        (lambda (handler)
 273          ;; FIXME: If HANDLER-ACTIVE ever is reinstanted, it needs
 274          ;; to be checked here in addition to HANDLER-BOGUS
 275          (unless (handler-bogus handler)
 276            (let ((fd (handler-descriptor handler)))
 277              (ecase (handler-direction handler)
 278                (:input (sb!unix:fd-set fd read-fds))
 279                (:output (sb!unix:fd-set fd write-fds)))
 280              (when (> fd count)
 281                (setf count fd))))))
 282       (incf count)
 283
 284       ;; Next, wait for something to happen.
 285       (multiple-value-bind (value err)
 286           (sb!unix:unix-fast-select count
 287                                     (sb!alien:addr read-fds)
 288                                     (sb!alien:addr write-fds)
 289                                     nil to-sec to-usec)
 290         #!+win32
 291         (declare (ignore err))
 292         ;; Now see what it was (if anything)
 293         (cond ((not value)
 294                ;; Interrupted or one of the file descriptors is bad.
 295                ;; FIXME: Check for other errnos. Why do we return true
 296                ;; when interrupted?
 297                #!-win32
 298                (case err
 299                  (#.sb!unix:ebadf
 300                   (handler-descriptors-error))
 301                  ((#.sb!unix:eintr #.sb!unix:eagain)
 302                   t)
 303                  (otherwise
 304                   (with-simple-restart (continue "Ignore failure and continue.")
 305                     (simple-perror "Unix system call select() failed"
 306                                    :errno err))))
 307                #!+win32
 308                (handler-descriptors-error))
 309               ((plusp value)
 310                ;; Got something. Call file descriptor handlers
 311                ;; according to the readable and writable masks
 312                ;; returned by select.
 313                (dolist (handler
 314                         (select-descriptor-handlers
 315                          (lambda (handler)
 316                            (let ((fd (handler-descriptor handler)))
 317                              (ecase (handler-direction handler)
 318                                (:input (sb!unix:fd-isset fd read-fds))
 319                                (:output (sb!unix:fd-isset fd write-fds)))))))
 320                  (with-simple-restart (remove-fd-handler "Remove ~S" handler)
 321                    (funcall (handler-function handler)
 322                             (handler-descriptor handler))
 323                    (go :next))
 324                  (remove-fd-handler handler)
 325                  :next)
 326                t))))))
 327