src/code/signal.lisp

   1 ;;;; handling UNIX signals
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!UNIX")
  13 \f
  14 ;;;; macros for dynamically enabling and disabling signal handling
  15
  16 ;;; Notes on how the without-interrupts/with-interrupts stuff works:
  17 ;;;
  18 ;;; Before invoking the supplied handler for any of the signals that
  19 ;;; can be blocked, the C interrupt support code checks to see whether
  20 ;;; *interrupts-enabled* has been bound to NIL. If so, it saves the
  21 ;;; signal number and the value of the signal mask (from the signal
  22 ;;; context), sets the signal mask to block all blockable signals,
  23 ;;; sets *interrupt-pending* and returns without handling the signal.
  24 ;;;
  25 ;;; When we drop out the without interrupts, we check to see whether
  26 ;;; *INTERRUPT-PENDING* has been set. If so, we call
  27 ;;; RECEIVE-PENDING-INTERRUPT, which generates a SIGTRAP. The C code
  28 ;;; invokes the handler for the saved signal instead of the SIGTRAP
  29 ;;; after replacing the signal mask in the signal context with the
  30 ;;; saved value. When that hander returns, the original signal mask is
  31 ;;; installed, allowing any other pending signals to be handled.
  32 ;;;
  33 ;;; This means that the cost of WITHOUT-INTERRUPTS is just a special
  34 ;;; binding in the case when no signals are delivered (the normal
  35 ;;; case). It's only when a signal is actually delivered that we use
  36 ;;; any system calls, and by then the cost of the extra system calls
  37 ;;; are lost in the noise when compared with the cost of delivering
  38 ;;; the signal in the first place.
  39 ;;;
  40 ;;; The conditional bindings done by this code here are worth the
  41 ;;; trouble as binding is more expensive then read & test -- so
  42 ;;;  (if *foo*
  43 ;;;      (foo)
  44 ;;;      (let ((*foo* t))
  45 ;;;        (foo)))
  46 ;;; is faster then
  47 ;;;  (let ((*foo* t))
  48 ;;;    (foo))
  49 ;;; provided that the first branch is true "often enough".
  50
  51 (defvar *interrupts-enabled* t)
  52 (defvar *interrupt-pending* nil)
  53 (defvar *allow-with-interrupts* t)
  54 ;;; This is to support signal handlers that want to return to the
  55 ;;; interrupted context without leaving anything extra on the stack. A
  56 ;;; simple
  57 ;;;
  58 ;;;  (without-interrupts
  59 ;;;   (unblock-deferrable-signals)
  60 ;;;   (allow-with-interrupts ...))
  61 ;;;
  62 ;;; would not cut it, as upon leaving WITHOUT-INTERRUPTS the pending
  63 ;;; handlers is run with stuff from the function in which this is
  64 ;;; still on the stack.
  65 (defvar *unblock-deferrables-on-enabling-interrupts-p* nil)
  66
  67 (sb!xc:defmacro without-interrupts (&body body)
  68   #!+sb-doc
  69   "Executes BODY with all deferrable interrupts disabled. Deferrable
  70 interrupts arriving during execution of the BODY take effect after BODY has
  71 been executed.
  72
  73 Deferrable interrupts include most blockable POSIX signals, and
  74 SB-THREAD:INTERRUPT-THREAD. Does not interfere with garbage collection, and
  75 unlike in many traditional Lisps using userspace threads, in SBCL
  76 WITHOUT-INTERRUPTS does not inhibit scheduling of other threads.
  77
  78 Binds ALLOW-WITH-INTERRUPTS and WITH-LOCAL-INTERRUPTS as a local macros.
  79
  80 ALLOW-WITH-INTERRUPTS allows the WITH-INTERRUPTS to take effect during the
  81 dynamic scope of its body, unless there is an outer WITHOUT-INTERRUPTS without
  82 a corresponding ALLOW-WITH-INTERRUPTS.
  83
  84 WITH-LOCAL-INTERRUPTS executes its body with interrupts enabled provided that
  85 for there is an ALLOW-WITH-INTERRUPTS for every WITHOUT-INTERRUPTS surrounding
  86 the current one. WITH-LOCAL-INTERRUPTS is equivalent to:
  87
  88   (allow-with-interrupts (with-interrupts ...))
  89
  90 Care must be taken not to let either ALLOW-WITH-INTERRUPTS or
  91 WITH-LOCAL-INTERRUPTS appear in a function that escapes from inside the
  92 WITHOUT-INTERRUPTS in:
  93
  94   (without-interrupts
  95     ;; The body of the lambda would be executed with WITH-INTERRUPTS allowed
  96     ;; regardless of the interrupt policy in effect when it is called.
  97     (lambda () (allow-with-interrupts ...)))
  98
  99   (without-interrupts
 100     ;; The body of the lambda would be executed with interrupts enabled
 101     ;; regardless of the interrupt policy in effect when it is called.
 102     (lambda () (with-local-interrupts ...)))
 103 "
 104   (with-unique-names (outer-allow-with-interrupts without-interrupts-body)
 105     `(dx-flet ((,without-interrupts-body ()
 106               (declare (disable-package-locks allow-with-interrupts
 107                                               with-local-interrupts))
 108               (macrolet
 109                   ((allow-with-interrupts
 110                      (&body allow-forms)
 111                      `(let ((*allow-with-interrupts*
 112                              ,',outer-allow-with-interrupts))
 113                         ,@allow-forms))
 114                    (with-local-interrupts
 115                      (&body with-forms)
 116                      `(let ((*allow-with-interrupts*
 117                              ,',outer-allow-with-interrupts)
 118                             (*interrupts-enabled*
 119                              ,',outer-allow-with-interrupts))
 120                         (when ,',outer-allow-with-interrupts
 121                           (when *unblock-deferrables-on-enabling-interrupts-p*
 122                             (setq *unblock-deferrables-on-enabling-interrupts-p*
 123                                   nil)
 124                             (sb!unix::unblock-deferrable-signals))
 125                           (when *interrupt-pending*
 126                             (receive-pending-interrupt)))
 127                         (locally ,@with-forms))))
 128                 (let ((*interrupts-enabled* nil)
 129                       (,outer-allow-with-interrupts *allow-with-interrupts*)
 130                       (*allow-with-interrupts* nil))
 131                   (declare (ignorable ,outer-allow-with-interrupts))
 132                   (declare (enable-package-locks allow-with-interrupts
 133                                                  with-local-interrupts))
 134                   ,@body))))
 135        (if *interrupts-enabled*
 136            (unwind-protect
 137                 (,without-interrupts-body)
 138              ;; If we were interrupted in the protected section,
 139              ;; then the interrupts are still blocked and it remains
 140              ;; so until the pending interrupt is handled.
 141              ;;
 142              ;; If we were not interrupted in the protected section,
 143              ;; but here, then even if the interrupt handler enters
 144              ;; another WITHOUT-INTERRUPTS, the pending interrupt will be
 145              ;; handled immediately upon exit from said
 146              ;; WITHOUT-INTERRUPTS, so it is as if nothing has happened.
 147              (when *interrupt-pending*
 148                (receive-pending-interrupt)))
 149            (,without-interrupts-body)))))
 150
 151 (sb!xc:defmacro with-interrupts (&body body)
 152   #!+sb-doc
 153   "Executes BODY with deferrable interrupts conditionally enabled. If there
 154 are pending interrupts they take effect prior to executing BODY.
 155
 156 As interrupts are normally allowed WITH-INTERRUPTS only makes sense if there
 157 is an outer WITHOUT-INTERRUPTS with a corresponding ALLOW-WITH-INTERRUPTS:
 158 interrupts are not enabled if any outer WITHOUT-INTERRUPTS is not accompanied
 159 by ALLOW-WITH-INTERRUPTS."
 160   (with-unique-names (allowp enablep)
 161     ;; We could manage without ENABLEP here, but that would require
 162     ;; taking extra care not to ever have *ALLOW-WITH-INTERRUPTS* NIL
 163     ;; and *INTERRUPTS-ENABLED* T -- instead of risking future breakage
 164     ;; we take the tiny hit here.
 165     `(let* ((,allowp *allow-with-interrupts*)
 166             (,enablep *interrupts-enabled*)
 167             (*interrupts-enabled* (or ,enablep ,allowp)))
 168        (when (and ,allowp (not ,enablep))
 169          (when *unblock-deferrables-on-enabling-interrupts-p*
 170            (setq *unblock-deferrables-on-enabling-interrupts-p* nil)
 171            (sb!unix::unblock-deferrable-signals))
 172          (when *interrupt-pending*
 173            (receive-pending-interrupt)))
 174        (locally ,@body))))
 175
 176 (defmacro allow-with-interrupts (&body body)
 177   (declare (ignore body))
 178   (error "~S is valid only inside ~S."
 179          'allow-with-interrupts 'without-interrupts))
 180
 181 (defmacro with-local-interrupts (&body body)
 182   (declare (ignore body))
 183   (error "~S is valid only inside ~S."
 184          'with-local-interrupts 'without-interrupts))
 185
 186 ;;; A low-level operation that assumes that *INTERRUPTS-ENABLED* is
 187 ;;; false, *ALLOW-WITH-INTERRUPTS* is true and deferrable signals are
 188 ;;; unblocked.
 189 (defun %check-interrupts ()
 190   ;; Here we check for pending interrupts first, because reading a
 191   ;; special is faster then binding it!
 192   (when *interrupt-pending*
 193     (let ((*interrupts-enabled* t))
 194       (receive-pending-interrupt))))