src/code/stream.lisp

   1 ;;;; os-independent stream functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 ;;;; standard streams
  15
  16 ;;; The initialization of these streams is performed by
  17 ;;; STREAM-COLD-INIT-OR-RESET.
  18 (defvar *terminal-io* () #!+sb-doc "terminal I/O stream")
  19 (defvar *standard-input* () #!+sb-doc "default input stream")
  20 (defvar *standard-output* () #!+sb-doc "default output stream")
  21 (defvar *error-output* () #!+sb-doc "error output stream")
  22 (defvar *query-io* () #!+sb-doc "query I/O stream")
  23 (defvar *trace-output* () #!+sb-doc "trace output stream")
  24 (defvar *debug-io* () #!+sb-doc "interactive debugging stream")
  25
  26 (defun ill-in (stream &rest ignore)
  27   (declare (ignore ignore))
  28   (error 'simple-type-error
  29          :datum stream
  30          :expected-type '(satisfies input-stream-p)
  31          :format-control "~S is not a character input stream."
  32          :format-arguments (list stream)))
  33 (defun ill-out (stream &rest ignore)
  34   (declare (ignore ignore))
  35   (error 'simple-type-error
  36          :datum stream
  37          :expected-type '(satisfies output-stream-p)
  38          :format-control "~S is not a character output stream."
  39          :format-arguments (list stream)))
  40 (defun ill-bin (stream &rest ignore)
  41   (declare (ignore ignore))
  42   (error 'simple-type-error
  43          :datum stream
  44          :expected-type '(satisfies input-stream-p)
  45          :format-control "~S is not a binary input stream."
  46          :format-arguments (list stream)))
  47 (defun ill-bout (stream &rest ignore)
  48   (declare (ignore ignore))
  49   (error 'simple-type-error
  50          :datum stream
  51          :expected-type '(satisfies output-stream-p)
  52          :format-control "~S is not a binary output stream."
  53          :format-arguments (list stream)))
  54 (defun closed-flame (stream &rest ignore)
  55   (declare (ignore ignore))
  56   (error "~S is closed." stream))
  57 (defun no-op-placeholder (&rest ignore)
  58   (declare (ignore ignore)))
  59 \f
  60 ;;; stream manipulation functions
  61
  62 (declaim (inline ansi-stream-input-stream-p))
  63 (defun ansi-stream-input-stream-p (stream)
  64   (declare (type ansi-stream stream))
  65
  66   (when (synonym-stream-p stream)
  67     (setf stream
  68           (symbol-value (synonym-stream-symbol stream))))
  69
  70   (and (not (eq (ansi-stream-in stream) #'closed-flame))
  71        ;;; KLUDGE: It's probably not good to have EQ tests on function
  72        ;;; values like this. What if someone's redefined the function?
  73        ;;; Is there a better way? (Perhaps just VALID-FOR-INPUT and
  74        ;;; VALID-FOR-OUTPUT flags? -- WHN 19990902
  75        (or (not (eq (ansi-stream-in stream) #'ill-in))
  76            (not (eq (ansi-stream-bin stream) #'ill-bin)))))
  77
  78 (defun input-stream-p (stream)
  79   (declare (type stream stream))
  80   (and (ansi-stream-p stream)
  81        (ansi-stream-input-stream-p stream)))
  82
  83 (declaim (inline ansi-stream-output-stream-p))
  84 (defun ansi-stream-output-stream-p (stream)
  85   (declare (type ansi-stream stream))
  86
  87   (when (synonym-stream-p stream)
  88     (setf stream (symbol-value
  89                   (synonym-stream-symbol stream))))
  90
  91   (and (not (eq (ansi-stream-in stream) #'closed-flame))
  92        (or (not (eq (ansi-stream-out stream) #'ill-out))
  93            (not (eq (ansi-stream-bout stream) #'ill-bout)))))
  94
  95 (defun output-stream-p (stream)
  96   (declare (type stream stream))
  97
  98   (and (ansi-stream-p stream)
  99        (ansi-stream-output-stream-p stream)))
 100
 101 (declaim (inline ansi-stream-open-stream-p))
 102 (defun ansi-stream-open-stream-p (stream)
 103   (declare (type ansi-stream stream))
 104   ;; CLHS 22.1.4 lets us not worry about synonym streams here.
 105   (not (eq (ansi-stream-in stream) #'closed-flame)))
 106
 107 (defun open-stream-p (stream)
 108   (ansi-stream-open-stream-p stream))
 109
 110 (declaim (inline ansi-stream-element-type))
 111 (defun ansi-stream-element-type (stream)
 112   (declare (type ansi-stream stream))
 113   (funcall (ansi-stream-misc stream) stream :element-type))
 114
 115 (defun stream-element-type (stream)
 116   (ansi-stream-element-type stream))
 117
 118 (defun interactive-stream-p (stream)
 119   (declare (type stream stream))
 120   (funcall (ansi-stream-misc stream) stream :interactive-p))
 121
 122 (declaim (inline ansi-stream-close))
 123 (defun ansi-stream-close (stream abort)
 124   (declare (type ansi-stream stream))
 125   (when (open-stream-p stream)
 126     (funcall (ansi-stream-misc stream) stream :close abort))
 127   t)
 128
 129 (defun close (stream &key abort)
 130   (ansi-stream-close stream abort))
 131
 132 (defun set-closed-flame (stream)
 133   (setf (ansi-stream-in stream) #'closed-flame)
 134   (setf (ansi-stream-bin stream) #'closed-flame)
 135   (setf (ansi-stream-n-bin stream) #'closed-flame)
 136   (setf (ansi-stream-in stream) #'closed-flame)
 137   (setf (ansi-stream-out stream) #'closed-flame)
 138   (setf (ansi-stream-bout stream) #'closed-flame)
 139   (setf (ansi-stream-sout stream) #'closed-flame)
 140   (setf (ansi-stream-misc stream) #'closed-flame))
 141 \f
 142 ;;;; file position and file length
 143
 144 ;;; Call the MISC method with the :FILE-POSITION operation.
 145 (defun file-position (stream &optional position)
 146   (declare (type stream stream))
 147   (declare (type (or index (alien sb!unix:off-t) (member nil :start :end)) position))
 148   (cond
 149    (position
 150     (setf (ansi-stream-in-index stream) +ansi-stream-in-buffer-length+)
 151     (funcall (ansi-stream-misc stream) stream :file-position position))
 152    (t
 153     (let ((res (funcall (ansi-stream-misc stream) stream :file-position nil)))
 154       (when res
 155         (- res
 156            (- +ansi-stream-in-buffer-length+
 157               (ansi-stream-in-index stream))))))))
 158
 159 ;;; This is a literal translation of the ANSI glossary entry "stream
 160 ;;; associated with a file".
 161 ;;;
 162 ;;; KLUDGE: Note that since Unix famously thinks "everything is a
 163 ;;; file", and in particular stdin, stdout, and stderr are files, we
 164 ;;; end up with this test being satisfied for weird things like
 165 ;;; *STANDARD-OUTPUT* (to a tty). That seems unlikely to be what the
 166 ;;; ANSI spec really had in mind, especially since this is used as a
 167 ;;; qualification for operations like FILE-LENGTH (so that ANSI was
 168 ;;; probably thinking of something like what Unix calls block devices)
 169 ;;; but I can't see any better way to do it. -- WHN 2001-04-14
 170 (defun stream-associated-with-file-p (x)
 171   "Test for the ANSI concept \"stream associated with a file\"."
 172   (or (typep x 'file-stream)
 173       (and (synonym-stream-p x)
 174            (stream-associated-with-file-p (symbol-value
 175                                            (synonym-stream-symbol x))))))
 176
 177 (defun stream-must-be-associated-with-file (stream)
 178   (declare (type stream stream))
 179   (unless (stream-associated-with-file-p stream)
 180     (error 'simple-type-error
 181            ;; KLUDGE: The ANSI spec for FILE-LENGTH specifically says
 182            ;; this should be TYPE-ERROR. But what then can we use for
 183            ;; EXPECTED-TYPE? This SATISFIES type (with a nonstandard
 184            ;; private predicate function..) is ugly and confusing, but
 185            ;; I can't see any other way. -- WHN 2001-04-14
 186            :expected-type '(satisfies stream-associated-with-file-p)
 187            :format-control
 188            "~@<The stream ~2I~_~S ~I~_isn't associated with a file.~:>"
 189            :format-arguments (list stream))))
 190
 191 ;;; like FILE-POSITION, only using :FILE-LENGTH
 192 (defun file-length (stream)
 193   ;; FIXME: The following declaration uses yet undefined types, which
 194   ;; cause cross-compiler hangup.
 195   ;;
 196   ;; (declare (type (or file-stream synonym-stream) stream))
 197   (stream-must-be-associated-with-file stream)
 198   (funcall (ansi-stream-misc stream) stream :file-length))
 199 \f
 200 ;;;; input functions
 201
 202 (defun read-line (&optional (stream *standard-input*) (eof-error-p t) eof-value
 203                             recursive-p)
 204   (declare (ignore recursive-p))
 205   (let ((stream (in-synonym-of stream)))
 206     (if (ansi-stream-p stream)
 207         (prepare-for-fast-read-char stream
 208           (let ((res (make-string 80))
 209                 (len 80)
 210                 (index 0))
 211             (loop
 212              (let ((ch (fast-read-char nil nil)))
 213                (cond (ch
 214                       (when (char= ch #\newline)
 215                         (done-with-fast-read-char)
 216                         (return (values (shrink-vector res index) nil)))
 217                       (when (= index len)
 218                         (setq len (* len 2))
 219                         (let ((new (make-string len)))
 220                           (replace new res)
 221                           (setq res new)))
 222                       (setf (schar res index) ch)
 223                       (incf index))
 224                      ((zerop index)
 225                       (done-with-fast-read-char)
 226                       (return (values (eof-or-lose stream
 227                                                    eof-error-p
 228                                                    eof-value)
 229                                       t)))
 230                      ;; Since FAST-READ-CHAR already hit the eof char, we
 231                      ;; shouldn't do another READ-CHAR.
 232                      (t
 233                       (done-with-fast-read-char)
 234                       (return (values (shrink-vector res index) t))))))))
 235         ;; must be Gray streams FUNDAMENTAL-STREAM
 236         (multiple-value-bind (string eof) (stream-read-line stream)
 237           (if (and eof (zerop (length string)))
 238               (values (eof-or-lose stream eof-error-p eof-value) t)
 239               (values string eof))))))
 240
 241 ;;; We proclaim them INLINE here, then proclaim them MAYBE-INLINE at EOF,
 242 ;;; so, except in this file, they are not inline by default, but they can be.
 243 #!-sb-fluid (declaim (inline read-char unread-char read-byte listen))
 244
 245 (defun read-char (&optional (stream *standard-input*)
 246                             (eof-error-p t)
 247                             eof-value
 248                             recursive-p)
 249   (declare (ignore recursive-p))
 250   (let ((stream (in-synonym-of stream)))
 251     (if (ansi-stream-p stream)
 252         (prepare-for-fast-read-char stream
 253           (prog1
 254               (fast-read-char eof-error-p eof-value)
 255             (done-with-fast-read-char)))
 256         ;; must be Gray streams FUNDAMENTAL-STREAM
 257         (let ((char (stream-read-char stream)))
 258           (if (eq char :eof)
 259               (eof-or-lose stream eof-error-p eof-value)
 260               char)))))
 261
 262 (defun unread-char (character &optional (stream *standard-input*))
 263   (let ((stream (in-synonym-of stream)))
 264     (if (ansi-stream-p stream)
 265         (let ((index (1- (ansi-stream-in-index stream)))
 266               (buffer (ansi-stream-in-buffer stream)))
 267           (declare (fixnum index))
 268           (when (minusp index) (error "nothing to unread"))
 269           (cond (buffer
 270                  (setf (aref buffer index) (char-code character))
 271                  (setf (ansi-stream-in-index stream) index))
 272                 (t
 273                  (funcall (ansi-stream-misc stream) stream
 274                           :unread character))))
 275         ;; must be Gray streams FUNDAMENTAL-STREAM
 276         (stream-unread-char stream character)))
 277   nil)
 278
 279 (defun listen (&optional (stream *standard-input*))
 280   (let ((stream (in-synonym-of stream)))
 281     (if (ansi-stream-p stream)
 282         (or (/= (the fixnum (ansi-stream-in-index stream))
 283                 +ansi-stream-in-buffer-length+)
 284             ;; Test for T explicitly since misc methods return :EOF sometimes.
 285             (eq (funcall (ansi-stream-misc stream) stream :listen) t))
 286         ;; Fall through to Gray streams FUNDAMENTAL-STREAM case.
 287         (stream-listen stream))))
 288
 289 (defun read-char-no-hang (&optional (stream *standard-input*)
 290                                     (eof-error-p t)
 291                                     eof-value
 292                                     recursive-p)
 293   (declare (ignore recursive-p))
 294   (let ((stream (in-synonym-of stream)))
 295     (if (ansi-stream-p stream)
 296         (if (funcall (ansi-stream-misc stream) stream :listen)
 297             ;; On T or :EOF get READ-CHAR to do the work.
 298             (read-char stream eof-error-p eof-value)
 299             nil)
 300         ;; must be Gray streams FUNDAMENTAL-STREAM
 301         (let ((char (stream-read-char-no-hang stream)))
 302           (if (eq char :eof)
 303               (eof-or-lose stream eof-error-p eof-value)
 304               char)))))
 305
 306 (defun clear-input (&optional (stream *standard-input*))
 307   (let ((stream (in-synonym-of stream)))
 308     (cond ((ansi-stream-p stream)
 309            (setf (ansi-stream-in-index stream) +ansi-stream-in-buffer-length+)
 310            (funcall (ansi-stream-misc stream) stream :clear-input))
 311           (t
 312            (stream-clear-input stream))))
 313   nil)
 314 \f
 315 (declaim (maybe-inline read-byte))
 316 (defun read-byte (stream &optional (eof-error-p t) eof-value)
 317   (let ((stream (in-synonym-of stream)))
 318     (if (ansi-stream-p stream)
 319         (prepare-for-fast-read-byte stream
 320           (prog1
 321               (fast-read-byte eof-error-p eof-value t)
 322             (done-with-fast-read-byte)))
 323         ;; must be Gray streams FUNDAMENTAL-STREAM
 324         (let ((char (stream-read-byte stream)))
 325           (if (eq char :eof)
 326               (eof-or-lose stream eof-error-p eof-value)
 327               char)))))
 328
 329 ;;; Read NUMBYTES bytes into BUFFER beginning at START, and return the
 330 ;;; number of bytes read.
 331 ;;;
 332 ;;; Note: CMU CL's version of this had a special interpretation of
 333 ;;; EOF-ERROR-P which SBCL does not have. (In the EOF-ERROR-P=NIL
 334 ;;; case, CMU CL's version would return as soon as any data became
 335 ;;; available.) This could be useful behavior for things like pipes in
 336 ;;; some cases, but it wasn't being used in SBCL, so it was dropped.
 337 ;;; If we ever need it, it could be added later as a new variant N-BIN
 338 ;;; method (perhaps N-BIN-ASAP?) or something.
 339 (defun read-n-bytes (stream buffer start numbytes &optional (eof-error-p t))
 340   (declare (type ansi-stream stream)
 341            (type index numbytes start)
 342            (type (or (simple-array * (*)) system-area-pointer) buffer))
 343   (let* ((stream (in-synonym-of stream ansi-stream))
 344          (in-buffer (ansi-stream-in-buffer stream))
 345          (index (ansi-stream-in-index stream))
 346          (num-buffered (- +ansi-stream-in-buffer-length+ index)))
 347     (declare (fixnum index num-buffered))
 348     (cond
 349      ((not in-buffer)
 350       (funcall (ansi-stream-n-bin stream)
 351                stream
 352                buffer
 353                start
 354                numbytes
 355                eof-error-p))
 356      ((<= numbytes num-buffered)
 357       (%byte-blt in-buffer index
 358                  buffer start (+ start numbytes))
 359       (setf (ansi-stream-in-index stream) (+ index numbytes))
 360       numbytes)
 361      (t
 362       (let ((end (+ start num-buffered)))
 363         (%byte-blt in-buffer index buffer start end)
 364         (setf (ansi-stream-in-index stream) +ansi-stream-in-buffer-length+)
 365         (+ (funcall (ansi-stream-n-bin stream)
 366                     stream
 367                     buffer
 368                     end
 369                     (- numbytes num-buffered)
 370                     eof-error-p)
 371            num-buffered))))))
 372
 373 ;;; the amount of space we leave at the start of the in-buffer for
 374 ;;; unreading
 375 ;;;
 376 ;;; (It's 4 instead of 1 to allow word-aligned copies.)
 377 (defconstant +ansi-stream-in-buffer-extra+
 378   4) ; FIXME: should be symbolic constant
 379
 380 ;;; This function is called by the FAST-READ-CHAR expansion to refill
 381 ;;; the IN-BUFFER for text streams. There is definitely an IN-BUFFER,
 382 ;;; and hence must be an N-BIN method.
 383 (defun fast-read-char-refill (stream eof-error-p eof-value)
 384   (let* ((ibuf (ansi-stream-in-buffer stream))
 385          (count (funcall (ansi-stream-n-bin stream)
 386                          stream
 387                          ibuf
 388                          +ansi-stream-in-buffer-extra+
 389                          (- +ansi-stream-in-buffer-length+
 390                             +ansi-stream-in-buffer-extra+)
 391                          nil))
 392          (start (- +ansi-stream-in-buffer-length+ count)))
 393     (declare (type index start count))
 394     (cond ((zerop count)
 395            (setf (ansi-stream-in-index stream) +ansi-stream-in-buffer-length+)
 396            (funcall (ansi-stream-in stream) stream eof-error-p eof-value))
 397           (t
 398            (when (/= start +ansi-stream-in-buffer-extra+)
 399              (bit-bash-copy ibuf (+ (* +ansi-stream-in-buffer-extra+
 400                                        sb!vm:n-byte-bits)
 401                                     (* sb!vm:vector-data-offset
 402                                        sb!vm:n-word-bits))
 403                             ibuf (+ (the index (* start sb!vm:n-byte-bits))
 404                                     (* sb!vm:vector-data-offset
 405                                        sb!vm:n-word-bits))
 406                             (* count sb!vm:n-byte-bits)))
 407            (setf (ansi-stream-in-index stream) (1+ start))
 408            (code-char (aref ibuf start))))))
 409
 410 ;;; This is similar to FAST-READ-CHAR-REFILL, but we don't have to
 411 ;;; leave room for unreading.
 412 (defun fast-read-byte-refill (stream eof-error-p eof-value)
 413   (let* ((ibuf (ansi-stream-in-buffer stream))
 414          (count (funcall (ansi-stream-n-bin stream) stream
 415                          ibuf 0 +ansi-stream-in-buffer-length+
 416                          nil))
 417          (start (- +ansi-stream-in-buffer-length+ count)))
 418     (declare (type index start count))
 419     (cond ((zerop count)
 420            (setf (ansi-stream-in-index stream) +ansi-stream-in-buffer-length+)
 421            (funcall (ansi-stream-bin stream) stream eof-error-p eof-value))
 422           (t
 423            (unless (zerop start)
 424              (bit-bash-copy ibuf (* sb!vm:vector-data-offset sb!vm:n-word-bits)
 425                             ibuf (+ (the index (* start sb!vm:n-byte-bits))
 426                                     (* sb!vm:vector-data-offset
 427                                        sb!vm:n-word-bits))
 428                             (* count sb!vm:n-byte-bits)))
 429            (setf (ansi-stream-in-index stream) (1+ start))
 430            (aref ibuf start)))))
 431 \f
 432 ;;; output functions
 433
 434 (defun write-char (character &optional (stream *standard-output*))
 435   (with-out-stream stream (ansi-stream-out character)
 436                    (stream-write-char character))
 437   character)
 438
 439 (defun terpri (&optional (stream *standard-output*))
 440   (with-out-stream stream (ansi-stream-out #\newline) (stream-terpri))
 441   nil)
 442
 443 (defun fresh-line (&optional (stream *standard-output*))
 444   (let ((stream (out-synonym-of stream)))
 445     (if (ansi-stream-p stream)
 446         (when (/= (or (charpos stream) 1) 0)
 447           (funcall (ansi-stream-out stream) stream #\newline)
 448           t)
 449         ;; must be Gray streams FUNDAMENTAL-STREAM
 450         (stream-fresh-line stream))))
 451
 452 (defun write-string (string &optional (stream *standard-output*)
 453                             &key (start 0) end)
 454   (declare (type string string))
 455   ;; Note that even though you might expect, based on the behavior of
 456   ;; things like AREF, that the correct upper bound here is
 457   ;; (ARRAY-DIMENSION STRING 0), the ANSI glossary definitions for
 458   ;; "bounding index" and "length" indicate that in this case (i.e.
 459   ;; for the ANSI-specified functions WRITE-STRING [and WRITE-LINE]),
 460   ;; (LENGTH STRING) is the required upper bound. A foolish
 461   ;; consistency is the hobgoblin of lesser languages..
 462   (%write-string string stream start (%check-vector-sequence-bounds
 463                                       string start end))
 464   string)
 465
 466 (defun %write-string (string stream start end)
 467   (declare (type string string))
 468   (declare (type stream-designator stream))
 469   (declare (type index start end))
 470   (let ((stream (out-synonym-of stream)))
 471     (cond ((ansi-stream-p stream)
 472            (if (array-header-p string)
 473                (with-array-data ((data string) (offset-start start)
 474                                  (offset-end end))
 475                  (funcall (ansi-stream-sout stream)
 476                           stream data offset-start offset-end))
 477                (funcall (ansi-stream-sout stream) stream string start end))
 478            string)
 479           (t ; must be Gray streams FUNDAMENTAL-STREAM
 480            (stream-write-string stream string start end)))))
 481
 482 ;;; A wrapper function for all those (MACROLET OUT-FUN) definitions,
 483 ;;; which cannot deal with keyword arguments.
 484 (declaim (inline write-string-no-key))
 485 (defun write-string-no-key (string stream start end)
 486   (write-string string stream :start start :end end))
 487
 488 (defun write-line (string &optional (stream *standard-output*)
 489                           &key (start 0) end)
 490   (declare (type string string))
 491   ;; FIXME: Why is there this difference between the treatments of the
 492   ;; STREAM argument in WRITE-STRING and WRITE-LINE?
 493   (let ((defaulted-stream (out-synonym-of stream)))
 494     (%write-string string defaulted-stream start (%check-vector-sequence-bounds
 495                                                   string start end))
 496     (write-char #\newline defaulted-stream))
 497   string)
 498
 499 (defun charpos (&optional (stream *standard-output*))
 500   (with-out-stream stream (ansi-stream-misc :charpos) (stream-line-column)))
 501
 502 (defun line-length (&optional (stream *standard-output*))
 503   (with-out-stream stream (ansi-stream-misc :line-length)
 504                    (stream-line-length)))
 505
 506 (defun finish-output (&optional (stream *standard-output*))
 507   (with-out-stream stream (ansi-stream-misc :finish-output)
 508                    (stream-finish-output))
 509   nil)
 510
 511 (defun force-output (&optional (stream *standard-output*))
 512   (with-out-stream stream (ansi-stream-misc :force-output)
 513                    (stream-force-output))
 514   nil)
 515
 516 (defun clear-output (&optional (stream *standard-output*))
 517   (with-out-stream stream (ansi-stream-misc :clear-output)
 518                    (stream-force-output))
 519   nil)
 520
 521 (defun write-byte (integer stream)
 522   (with-out-stream stream (ansi-stream-bout integer)
 523                    (stream-write-byte integer))
 524   integer)
 525 \f
 526
 527 ;;; (These were inline throughout this file, but that's not appropriate
 528 ;;; globally.  And we must not inline them in the rest of this file if
 529 ;;; dispatch to gray or simple streams is to work, since both redefine
 530 ;;; these functions later.)
 531 (declaim (maybe-inline read-char unread-char read-byte listen))
 532
 533 ;;; This is called from ANSI-STREAM routines that encapsulate CLOS
 534 ;;; streams to handle the misc routines and dispatch to the
 535 ;;; appropriate SIMPLE- or FUNDAMENTAL-STREAM functions.
 536 (defun stream-misc-dispatch (stream operation &optional arg1 arg2)
 537   (declare (type stream stream) (ignore arg2))
 538   (ecase operation
 539     (:listen
 540      ;; Return T if input available, :EOF for end-of-file, otherwise NIL.
 541      (let ((char (read-char-no-hang stream nil :eof)))
 542        (when (characterp char)
 543          (unread-char char stream))
 544        char))
 545     (:unread
 546      (unread-char arg1 stream))
 547     (:close
 548      (close stream))
 549     (:clear-input
 550      (clear-input stream))
 551     (:force-output
 552      (force-output stream))
 553     (:finish-output
 554      (finish-output stream))
 555     (:element-type
 556      (stream-element-type stream))
 557     (:interactive-p
 558      (interactive-stream-p stream))
 559     (:line-length
 560      (line-length stream))
 561     (:charpos
 562      (charpos stream))
 563     (:file-length
 564      (file-length stream))
 565     (:file-position
 566      (file-position stream arg1))))
 567 \f
 568 ;;;; broadcast streams
 569
 570 (defstruct (broadcast-stream (:include ansi-stream
 571                                        (out #'broadcast-out)
 572                                        (bout #'broadcast-bout)
 573                                        (sout #'broadcast-sout)
 574                                        (misc #'broadcast-misc))
 575                              (:constructor %make-broadcast-stream
 576                                            (&rest streams))
 577                              (:copier nil))
 578   ;; a list of all the streams we broadcast to
 579   (streams () :type list :read-only t))
 580
 581 (defun make-broadcast-stream (&rest streams)
 582   (dolist (stream streams)
 583     (unless (output-stream-p stream)
 584       (error 'type-error
 585              :datum stream
 586              :expected-type '(satisfies output-stream-p))))
 587   (apply #'%make-broadcast-stream streams))
 588
 589 (macrolet ((out-fun (name fun &rest args)
 590              `(defun ,name (stream ,@args)
 591                 (dolist (stream (broadcast-stream-streams stream))
 592                   (,fun ,(car args) stream ,@(cdr args))))))
 593   (out-fun broadcast-out write-char char)
 594   (out-fun broadcast-bout write-byte byte)
 595   (out-fun broadcast-sout write-string-no-key string start end))
 596
 597 (defun broadcast-misc (stream operation &optional arg1 arg2)
 598   (let ((streams (broadcast-stream-streams stream)))
 599     (case operation
 600       ;; FIXME: This may not be the best place to note this, but I
 601       ;; think the :CHARPOS protocol needs revision.  Firstly, I think
 602       ;; this is the last place where a NULL return value was possible
 603       ;; (before adjusting it to be 0), so a bunch of conditionals IF
 604       ;; CHARPOS can be removed; secondly, it is my belief that
 605       ;; FD-STREAMS, when running FILE-POSITION, do not update the
 606       ;; CHARPOS, and consequently there will be much wrongness.
 607       ;;
 608       ;; FIXME: see also TWO-WAY-STREAM treatment of :CHARPOS -- why
 609       ;; is it testing the :charpos of an input stream?
 610       ;;
 611       ;; -- CSR, 2004-02-04
 612       (:charpos
 613        (dolist (stream streams 0)
 614          (let ((charpos (charpos stream)))
 615            (if charpos (return charpos)))))
 616       (:line-length
 617        (let ((min nil))
 618          (dolist (stream streams min)
 619            (let ((res (line-length stream)))
 620              (when res (setq min (if min (min res min) res)))))))
 621       (:element-type
 622        #+nil ; old, arguably more logical, version
 623        (let (res)
 624          (dolist (stream streams (if (> (length res) 1) `(and ,@res) t))
 625            (pushnew (stream-element-type stream) res :test #'equal)))
 626        ;; ANSI-specified version (under System Class BROADCAST-STREAM)
 627        (let ((res t))
 628          (do ((streams streams (cdr streams)))
 629              ((null streams) res)
 630            (when (null (cdr streams))
 631              (setq res (stream-element-type (car streams)))))))
 632       (:close
 633        (set-closed-flame stream))
 634       (t
 635        (let ((res nil))
 636          (dolist (stream streams res)
 637            (setq res
 638                  (if (ansi-stream-p stream)
 639                      (funcall (ansi-stream-misc stream) stream operation
 640                               arg1 arg2)
 641                      (stream-misc-dispatch stream operation arg1 arg2)))))))))
 642 \f
 643 ;;;; synonym streams
 644
 645 (defstruct (synonym-stream (:include ansi-stream
 646                                      (in #'synonym-in)
 647                                      (bin #'synonym-bin)
 648                                      (n-bin #'synonym-n-bin)
 649                                      (out #'synonym-out)
 650                                      (bout #'synonym-bout)
 651                                      (sout #'synonym-sout)
 652                                      (misc #'synonym-misc))
 653                            (:constructor make-synonym-stream (symbol))
 654                            (:copier nil))
 655   ;; This is the symbol, the value of which is the stream we are synonym to.
 656   (symbol nil :type symbol :read-only t))
 657 (def!method print-object ((x synonym-stream) stream)
 658   (print-unreadable-object (x stream :type t :identity t)
 659     (format stream ":SYMBOL ~S" (synonym-stream-symbol x))))
 660
 661 ;;; The output simple output methods just call the corresponding
 662 ;;; function on the synonymed stream.
 663 (macrolet ((out-fun (name fun &rest args)
 664              `(defun ,name (stream ,@args)
 665                 (declare (optimize (safety 1)))
 666                 (let ((syn (symbol-value (synonym-stream-symbol stream))))
 667                   (,fun ,(car args) syn ,@(cdr args))))))
 668   (out-fun synonym-out write-char ch)
 669   (out-fun synonym-bout write-byte n)
 670   (out-fun synonym-sout write-string-no-key string start end))
 671
 672 ;;; For the input methods, we just call the corresponding function on the
 673 ;;; synonymed stream. These functions deal with getting input out of
 674 ;;; the In-Buffer if there is any.
 675 (macrolet ((in-fun (name fun &rest args)
 676              `(defun ,name (stream ,@args)
 677                 (declare (optimize (safety 1)))
 678                 (,fun (symbol-value (synonym-stream-symbol stream))
 679                       ,@args))))
 680   (in-fun synonym-in read-char eof-error-p eof-value)
 681   (in-fun synonym-bin read-byte eof-error-p eof-value)
 682   (in-fun synonym-n-bin read-n-bytes buffer start numbytes eof-error-p))
 683
 684 (defun synonym-misc (stream operation &optional arg1 arg2)
 685   (declare (optimize (safety 1)))
 686   (let ((syn (symbol-value (synonym-stream-symbol stream))))
 687     (if (ansi-stream-p syn)
 688         ;; We have to special-case some operations which interact with
 689         ;; the in-buffer of the wrapped stream, since just calling
 690         ;; ANSI-STREAM-MISC on them
 691         (case operation
 692           (:listen (or (/= (the fixnum (ansi-stream-in-index syn))
 693                            +ansi-stream-in-buffer-length+)
 694                        (funcall (ansi-stream-misc syn) syn :listen)))
 695           (:clear-input (clear-input syn))
 696           (:unread (unread-char arg1 syn))
 697           (t
 698            (funcall (ansi-stream-misc syn) syn operation arg1 arg2)))
 699         (stream-misc-dispatch syn operation arg1 arg2))))
 700 \f
 701 ;;;; two-way streams
 702
 703 (defstruct (two-way-stream
 704             (:include ansi-stream
 705                       (in #'two-way-in)
 706                       (bin #'two-way-bin)
 707                       (n-bin #'two-way-n-bin)
 708                       (out #'two-way-out)
 709                       (bout #'two-way-bout)
 710                       (sout #'two-way-sout)
 711                       (misc #'two-way-misc))
 712             (:constructor %make-two-way-stream (input-stream output-stream))
 713             (:copier nil))
 714   (input-stream (missing-arg) :type stream :read-only t)
 715   (output-stream (missing-arg) :type stream :read-only t))
 716 (defprinter (two-way-stream) input-stream output-stream)
 717
 718 (defun make-two-way-stream (input-stream output-stream)
 719   #!+sb-doc
 720   "Return a bidirectional stream which gets its input from INPUT-STREAM and
 721    sends its output to OUTPUT-STREAM."
 722   ;; FIXME: This idiom of the-real-stream-of-a-possibly-synonym-stream
 723   ;; should be encapsulated in a function, and used here and most of
 724   ;; the other places that SYNONYM-STREAM-P appears.
 725   (unless (output-stream-p output-stream)
 726     (error 'type-error
 727            :datum output-stream
 728            :expected-type '(satisfies output-stream-p)))
 729   (unless (input-stream-p input-stream)
 730     (error 'type-error
 731            :datum input-stream
 732            :expected-type '(satisfies input-stream-p)))
 733   (funcall #'%make-two-way-stream input-stream output-stream))
 734
 735 (macrolet ((out-fun (name fun &rest args)
 736              `(defun ,name (stream ,@args)
 737                 (let ((syn (two-way-stream-output-stream stream)))
 738                   (,fun ,(car args) syn ,@(cdr args))))))
 739   (out-fun two-way-out write-char ch)
 740   (out-fun two-way-bout write-byte n)
 741   (out-fun two-way-sout write-string-no-key string start end))
 742
 743 (macrolet ((in-fun (name fun &rest args)
 744              `(defun ,name (stream ,@args)
 745                 (force-output (two-way-stream-output-stream stream))
 746                 (,fun (two-way-stream-input-stream stream) ,@args))))
 747   (in-fun two-way-in read-char eof-error-p eof-value)
 748   (in-fun two-way-bin read-byte eof-error-p eof-value)
 749   (in-fun two-way-n-bin read-n-bytes buffer start numbytes eof-error-p))
 750
 751 (defun two-way-misc (stream operation &optional arg1 arg2)
 752   (let* ((in (two-way-stream-input-stream stream))
 753          (out (two-way-stream-output-stream stream))
 754          (in-ansi-stream-p (ansi-stream-p in))
 755          (out-ansi-stream-p (ansi-stream-p out)))
 756     (case operation
 757       (:listen
 758        (if in-ansi-stream-p
 759            (or (/= (the fixnum (ansi-stream-in-index in))
 760                    +ansi-stream-in-buffer-length+)
 761                (funcall (ansi-stream-misc in) in :listen))
 762            (stream-listen in)))
 763       ((:finish-output :force-output :clear-output)
 764        (if out-ansi-stream-p
 765            (funcall (ansi-stream-misc out) out operation arg1 arg2)
 766            (stream-misc-dispatch out operation arg1 arg2)))
 767       (:clear-input (clear-input in))
 768       (:unread (unread-char arg1 in))
 769       (:element-type
 770        (let ((in-type (stream-element-type in))
 771              (out-type (stream-element-type out)))
 772          (if (equal in-type out-type)
 773              in-type `(and ,in-type ,out-type))))
 774       (:close
 775        (set-closed-flame stream))
 776       (t
 777        (or (if in-ansi-stream-p
 778                (funcall (ansi-stream-misc in) in operation arg1 arg2)
 779                (stream-misc-dispatch in operation arg1 arg2))
 780            (if out-ansi-stream-p
 781                (funcall (ansi-stream-misc out) out operation arg1 arg2)
 782                (stream-misc-dispatch out operation arg1 arg2)))))))
 783 \f
 784 ;;;; concatenated streams
 785
 786 (defstruct (concatenated-stream
 787             (:include ansi-stream
 788                       (in #'concatenated-in)
 789                       (bin #'concatenated-bin)
 790                       (n-bin #'concatenated-n-bin)
 791                       (misc #'concatenated-misc))
 792             (:constructor %make-concatenated-stream (&rest streams))
 793             (:copier nil))
 794   ;; The car of this is the substream we are reading from now.
 795   (streams nil :type list))
 796 (def!method print-object ((x concatenated-stream) stream)
 797   (print-unreadable-object (x stream :type t :identity t)
 798     (format stream
 799             ":STREAMS ~S"
 800             (concatenated-stream-streams x))))
 801
 802 (defun make-concatenated-stream (&rest streams)
 803   #!+sb-doc
 804   "Return a stream which takes its input from each of the streams in turn,
 805    going on to the next at EOF."
 806   (dolist (stream streams)
 807     (unless (input-stream-p stream)
 808       (error 'type-error
 809              :datum stream
 810              :expected-type '(satisfies input-stream-p))))
 811   (apply #'%make-concatenated-stream streams))
 812
 813 (macrolet ((in-fun (name fun)
 814              `(defun ,name (stream eof-error-p eof-value)
 815                 (do ((streams (concatenated-stream-streams stream)
 816                               (cdr streams)))
 817                     ((null streams)
 818                      (eof-or-lose stream eof-error-p eof-value))
 819                   (let* ((stream (car streams))
 820                          (result (,fun stream nil nil)))
 821                     (when result (return result)))
 822                   (pop (concatenated-stream-streams stream))))))
 823   (in-fun concatenated-in read-char)
 824   (in-fun concatenated-bin read-byte))
 825
 826 (defun concatenated-n-bin (stream buffer start numbytes eof-errorp)
 827   (do ((streams (concatenated-stream-streams stream) (cdr streams))
 828        (current-start start)
 829        (remaining-bytes numbytes))
 830       ((null streams)
 831        (if eof-errorp
 832            (error 'end-of-file :stream stream)
 833            (- numbytes remaining-bytes)))
 834     (let* ((stream (car streams))
 835            (bytes-read (read-n-bytes stream buffer current-start
 836                                      remaining-bytes nil)))
 837       (incf current-start bytes-read)
 838       (decf remaining-bytes bytes-read)
 839       (when (zerop remaining-bytes) (return numbytes)))
 840     (setf (concatenated-stream-streams stream) (cdr streams))))
 841
 842 (defun concatenated-misc (stream operation &optional arg1 arg2)
 843   (let* ((left (concatenated-stream-streams stream))
 844          (current (car left)))
 845     (case operation
 846       (:listen
 847        (unless left
 848          (return-from concatenated-misc :eof))
 849        (loop
 850         (let ((stuff (if (ansi-stream-p current)
 851                          (funcall (ansi-stream-misc current) current
 852                                   :listen)
 853                          (stream-misc-dispatch current :listen))))
 854           (cond ((eq stuff :eof)
 855                  ;; Advance STREAMS, and try again.
 856                  (pop (concatenated-stream-streams stream))
 857                  (setf current
 858                        (car (concatenated-stream-streams stream)))
 859                  (unless current
 860                    ;; No further streams. EOF.
 861                    (return :eof)))
 862                 (stuff
 863                  ;; Stuff's available.
 864                  (return t))
 865                 (t
 866                  ;; Nothing is available yet.
 867                  (return nil))))))
 868       (:clear-input (when left (clear-input current)))
 869       (:unread (when left (unread-char arg1 current)))
 870       (:close
 871        (set-closed-flame stream))
 872       (t
 873        (when left
 874          (if (ansi-stream-p current)
 875              (funcall (ansi-stream-misc current) current operation arg1 arg2)
 876              (stream-misc-dispatch current operation arg1 arg2)))))))
 877 \f
 878 ;;;; echo streams
 879
 880 (defstruct (echo-stream
 881             (:include two-way-stream
 882                       (in #'echo-in)
 883                       (bin #'echo-bin)
 884                       (misc #'echo-misc)
 885                       (n-bin #'ill-bin))
 886             (:constructor %make-echo-stream (input-stream output-stream))
 887             (:copier nil))
 888   unread-stuff)
 889 (def!method print-object ((x echo-stream) stream)
 890   (print-unreadable-object (x stream :type t :identity t)
 891     (format stream
 892             ":INPUT-STREAM ~S :OUTPUT-STREAM ~S"
 893             (two-way-stream-input-stream x)
 894             (two-way-stream-output-stream x))))
 895
 896 (defun make-echo-stream (input-stream output-stream)
 897   #!+sb-doc
 898   "Return a bidirectional stream which gets its input from INPUT-STREAM and
 899    sends its output to OUTPUT-STREAM. In addition, all input is echoed to
 900    the output stream."
 901   (unless (output-stream-p output-stream)
 902     (error 'type-error
 903            :datum output-stream
 904            :expected-type '(satisfies output-stream-p)))
 905   (unless (input-stream-p input-stream)
 906     (error 'type-error
 907            :datum input-stream
 908            :expected-type '(satisfies input-stream-p)))
 909   (funcall #'%make-echo-stream input-stream output-stream))
 910
 911 (macrolet ((in-fun (name in-fun out-fun &rest args)
 912              `(defun ,name (stream ,@args)
 913                 (or (pop (echo-stream-unread-stuff stream))
 914                     (let* ((in (echo-stream-input-stream stream))
 915                            (out (echo-stream-output-stream stream))
 916                            (result (if eof-error-p
 917                                        (,in-fun in ,@args)
 918                                        (,in-fun in nil in))))
 919                       (cond
 920                         ((eql result in) eof-value)
 921                         (t (,out-fun result out) result)))))))
 922   (in-fun echo-in read-char write-char eof-error-p eof-value)
 923   (in-fun echo-bin read-byte write-byte eof-error-p eof-value))
 924 \f
 925 ;;;; base STRING-STREAM stuff
 926
 927 (defstruct (string-stream
 928              (:include ansi-stream)
 929              (:constructor nil)
 930              (:copier nil))
 931   ;; FIXME: This type declaration is true, and will probably continue
 932   ;; to be true.  However, note well the comments in DEFTRANSFORM
 933   ;; REPLACE, implying that performance of REPLACE is somewhat
 934   ;; critical to performance of string streams.  If (VECTOR CHARACTER)
 935   ;; ever becomes different from (VECTOR BASE-CHAR), the transform
 936   ;; probably needs to be extended.
 937   (string (missing-arg) :type (vector character)))
 938 \f
 939 ;;;; STRING-INPUT-STREAM stuff
 940
 941 (defstruct (string-input-stream
 942              (:include string-stream
 943                        (in #'string-inch)
 944                        (bin #'ill-bin)
 945                        (n-bin #'string-stream-read-n-bytes)
 946                        (misc #'string-in-misc)
 947                        (string (missing-arg) :type simple-string))
 948              (:constructor internal-make-string-input-stream
 949                            (string current end))
 950              (:copier nil))
 951   (current (missing-arg) :type index)
 952   (end (missing-arg) :type index))
 953
 954 (defun string-inch (stream eof-error-p eof-value)
 955   (declare (type string-input-stream stream))
 956   (let ((string (string-input-stream-string stream))
 957         (index (string-input-stream-current stream)))
 958     (cond ((>= index (the index (string-input-stream-end stream)))
 959            (eof-or-lose stream eof-error-p eof-value))
 960           (t
 961            (setf (string-input-stream-current stream) (1+ index))
 962            (char string index)))))
 963
 964 (defun string-binch (stream eof-error-p eof-value)
 965   (declare (type string-input-stream stream))
 966   (let ((string (string-input-stream-string stream))
 967         (index (string-input-stream-current stream)))
 968     (cond ((>= index (the index (string-input-stream-end stream)))
 969            (eof-or-lose stream eof-error-p eof-value))
 970           (t
 971            (setf (string-input-stream-current stream) (1+ index))
 972            (char-code (char string index))))))
 973
 974 (defun string-stream-read-n-bytes (stream buffer start requested eof-error-p)
 975   (declare (type string-input-stream stream)
 976            (type index start requested))
 977   (let* ((string (string-input-stream-string stream))
 978          (index (string-input-stream-current stream))
 979          (available (- (string-input-stream-end stream) index))
 980          (copy (min available requested)))
 981     (declare (type simple-string string))
 982     (when (plusp copy)
 983       (setf (string-input-stream-current stream)
 984             (truly-the index (+ index copy)))
 985       (sb!sys:without-gcing
 986        (system-area-copy (vector-sap string)
 987                          (* index sb!vm:n-byte-bits)
 988                          (if (typep buffer 'system-area-pointer)
 989                              buffer
 990                              (vector-sap buffer))
 991                          (* start sb!vm:n-byte-bits)
 992                          (* copy sb!vm:n-byte-bits))))
 993     (if (and (> requested copy) eof-error-p)
 994         (error 'end-of-file :stream stream)
 995         copy)))
 996
 997 (defun string-in-misc (stream operation &optional arg1 arg2)
 998   (declare (type string-input-stream stream)
 999            (ignore arg2))
1000   (case operation
1001     (:file-position
1002      (if arg1
1003          (setf (string-input-stream-current stream)
1004                (case arg1
1005                  (:start 0)
1006                  (:end (string-input-stream-end stream))
1007                  ;; We allow moving position beyond EOF. Errors happen
1008                  ;; on read, not move -- or the user may extend the
1009                  ;; input string.
1010                  (t arg1)))
1011          (string-input-stream-current stream)))
1012     ;; According to ANSI: "Should signal an error of type type-error
1013     ;; if stream is not a stream associated with a file."
1014     ;; This is checked by FILE-LENGTH, so no need to do it here either.
1015     ;; (:file-length (length (string-input-stream-string stream)))
1016     (:unread (decf (string-input-stream-current stream)))
1017     (:close (set-closed-flame stream))
1018     (:listen (or (/= (the index (string-input-stream-current stream))
1019                      (the index (string-input-stream-end stream)))
1020                  :eof))
1021     (:element-type (array-element-type (string-input-stream-string stream)))))
1022
1023 (defun make-string-input-stream (string &optional (start 0) end)
1024   #!+sb-doc
1025   "Return an input stream which will supply the characters of STRING between
1026   START and END in order."
1027   (declare (type string string)
1028            (type index start)
1029            (type (or index null) end))
1030   (let* ((string (coerce string '(simple-array character (*))))
1031          (end (%check-vector-sequence-bounds string start end)))
1032     (with-array-data ((string string) (start start) (end end))
1033       (internal-make-string-input-stream
1034        string ;; now simple
1035        start
1036        end))))
1037 \f
1038 ;;;; STRING-OUTPUT-STREAM stuff
1039
1040 (defstruct (string-output-stream
1041             (:include string-stream
1042                       (out #'string-ouch)
1043                       (sout #'string-sout)
1044                       (misc #'string-out-misc)
1045                       ;; The string we throw stuff in.
1046                       (string (missing-arg)
1047                               :type (simple-array character (*))))
1048             (:constructor make-string-output-stream
1049                           (&key (element-type 'character)
1050                            &aux (string (make-string 40))))
1051             (:copier nil))
1052   ;; Index of the next location to use.
1053   (index 0 :type fixnum)
1054   ;; Index cache for string-output-stream-last-index
1055   (index-cache 0 :type fixnum)
1056   ;; Requested element type
1057   (element-type 'character))
1058
1059 #!+sb-doc
1060 (setf (fdocumentation 'make-string-output-stream 'function)
1061   "Return an output stream which will accumulate all output given it for
1062    the benefit of the function GET-OUTPUT-STREAM-STRING.")
1063
1064 (defun string-output-stream-last-index (stream)
1065   (max (string-output-stream-index stream)
1066        (string-output-stream-index-cache stream)))
1067
1068 (defun string-ouch (stream character)
1069   (let ((current (string-output-stream-index stream))
1070         (workspace (string-output-stream-string stream)))
1071     (declare (type (simple-array character (*)) workspace)
1072              (type fixnum current))
1073     (if (= current (the fixnum (length workspace)))
1074         (let ((new-workspace (make-string (* current 2))))
1075           (replace new-workspace workspace)
1076           (setf (aref new-workspace current) character
1077                 (string-output-stream-string stream) new-workspace))
1078         (setf (aref workspace current) character))
1079     (setf (string-output-stream-index stream) (1+ current))))
1080
1081 (defun string-sout (stream string start end)
1082   (declare (type simple-string string)
1083            (type fixnum start end))
1084   (let* ((string (if (typep string '(simple-array character (*)))
1085                      string
1086                      (coerce string '(simple-array character (*)))))
1087          (current (string-output-stream-index stream))
1088          (length (- end start))
1089          (dst-end (+ length current))
1090          (workspace (string-output-stream-string stream)))
1091     (declare (type (simple-array character (*)) workspace string)
1092              (type fixnum current length dst-end))
1093     (if (> dst-end (the fixnum (length workspace)))
1094         (let ((new-workspace (make-string (+ (* current 2) length))))
1095           (replace new-workspace workspace :end2 current)
1096           (replace new-workspace string
1097                    :start1 current :end1 dst-end
1098                    :start2 start :end2 end)
1099           (setf (string-output-stream-string stream) new-workspace))
1100         (replace workspace string
1101                  :start1 current :end1 dst-end
1102                  :start2 start :end2 end))
1103     (setf (string-output-stream-index stream) dst-end)))
1104
1105 (defun string-out-misc (stream operation &optional arg1 arg2)
1106   (declare (ignore arg2))
1107   (case operation
1108     (:file-position
1109      (if arg1
1110          (let ((end (string-output-stream-last-index stream)))
1111            (setf (string-output-stream-index-cache stream) end
1112                  (string-output-stream-index stream)
1113                  (case arg1
1114                    (:start 0)
1115                    (:end end)
1116                    (t
1117                     ;; We allow moving beyond the end of stream,
1118                     ;; implicitly extending the output stream.
1119                     (let ((buffer (string-output-stream-string stream)))
1120                       (when (> arg1 (length buffer))
1121                         (setf (string-output-stream-string stream)
1122                               (make-string
1123                                arg1 :element-type (array-element-type buffer))
1124                               (subseq (string-output-stream-string stream)
1125                                       0 end)
1126                               (subseq buffer 0 end))))
1127                       arg1))))
1128          (string-output-stream-index stream)))
1129     (:close (set-closed-flame stream))
1130     (:charpos
1131      (do ((index (1- (the fixnum (string-output-stream-index stream)))
1132                  (1- index))
1133           (count 0 (1+ count))
1134           (string (string-output-stream-string stream)))
1135          ((< index 0) count)
1136        (declare (type (simple-array character (*)) string)
1137                 (type fixnum index count))
1138        (if (char= (schar string index) #\newline)
1139            (return count))))
1140     (:element-type (array-element-type (string-output-stream-string stream)))))
1141
1142 ;;; Return a string of all the characters sent to a stream made by
1143 ;;; MAKE-STRING-OUTPUT-STREAM since the last call to this function.
1144 (defun get-output-stream-string (stream)
1145   (declare (type string-output-stream stream))
1146   (let* ((length (string-output-stream-last-index stream))
1147          (element-type (string-output-stream-element-type stream))
1148          (result
1149           (case element-type
1150             ;; Overwhelmingly common case; can be inlined.
1151             ((character) (make-string length))
1152             (t (make-string length :element-type element-type)))))
1153     ;; For the benefit of the REPLACE transform, let's do this, so
1154     ;; that the common case isn't ludicrously expensive.
1155     (etypecase result
1156       ((simple-array character (*))
1157        (replace result (string-output-stream-string stream)))
1158       ((simple-array nil (*))
1159        (replace result (string-output-stream-string stream))))
1160     (setf (string-output-stream-index stream) 0
1161           (string-output-stream-index-cache stream) 0)
1162     result))
1163
1164 ;;; Dump the characters buffer up in IN-STREAM to OUT-STREAM as
1165 ;;; GET-OUTPUT-STREAM-STRING would return them.
1166 (defun dump-output-stream-string (in-stream out-stream)
1167   (%write-string (string-output-stream-string in-stream)
1168                  out-stream
1169                  0
1170                  (string-output-stream-last-index in-stream))
1171   (setf (string-output-stream-index in-stream) 0
1172         (string-output-stream-index-cache in-stream) 0))
1173 \f
1174 ;;;; fill-pointer streams
1175
1176 ;;; Fill pointer STRING-OUTPUT-STREAMs are not explicitly mentioned in
1177 ;;; the CLM, but they are required for the implementation of
1178 ;;; WITH-OUTPUT-TO-STRING.
1179
1180 (deftype string-with-fill-pointer ()
1181   '(and (vector character)
1182         (satisfies array-has-fill-pointer-p)))
1183
1184 (defstruct (fill-pointer-output-stream
1185             (:include string-stream
1186                       (out #'fill-pointer-ouch)
1187                       (sout #'fill-pointer-sout)
1188                       (misc #'fill-pointer-misc)
1189                       ;; a string with a fill pointer where we stuff
1190                       ;; the stuff we write
1191                       (string (missing-arg)
1192                               :type string-with-fill-pointer
1193                               :read-only t))
1194             (:constructor make-fill-pointer-output-stream (string))
1195             (:copier nil)))
1196
1197 (defun fill-pointer-ouch (stream character)
1198   (let* ((buffer (fill-pointer-output-stream-string stream))
1199          (current (fill-pointer buffer))
1200          (current+1 (1+ current)))
1201     (declare (fixnum current))
1202     (with-array-data ((workspace buffer) (start) (end))
1203       (declare (type (simple-array character (*)) workspace))
1204       (let ((offset-current (+ start current)))
1205         (declare (fixnum offset-current))
1206         (if (= offset-current end)
1207             (let* ((new-length (1+ (* current 2)))
1208                    (new-workspace (make-string new-length)))
1209               (declare (simple-string new-workspace))
1210               (%byte-blt workspace start
1211                          new-workspace 0 current)
1212               (setf workspace new-workspace
1213                     offset-current current)
1214               (set-array-header buffer workspace new-length
1215                                 current+1 0 new-length nil))
1216             (setf (fill-pointer buffer) current+1))
1217         (setf (schar workspace offset-current) character)))
1218     current+1))
1219
1220 (defun fill-pointer-sout (stream string start end)
1221   (declare (simple-string string) (fixnum start end))
1222   (let* ((string (if (typep string '(simple-array character (*)))
1223                      string
1224                      (coerce string '(simple-array character (*)))))
1225          (buffer (fill-pointer-output-stream-string stream))
1226          (current (fill-pointer buffer))
1227          (string-len (- end start))
1228          (dst-end (+ string-len current)))
1229     (declare (fixnum current dst-end string-len))
1230     (with-array-data ((workspace buffer) (dst-start) (dst-length))
1231       (declare (type (simple-array character (*)) workspace))
1232       (let ((offset-dst-end (+ dst-start dst-end))
1233             (offset-current (+ dst-start current)))
1234         (declare (fixnum offset-dst-end offset-current))
1235         (if (> offset-dst-end dst-length)
1236             (let* ((new-length (+ (the fixnum (* current 2)) string-len))
1237                    (new-workspace (make-string new-length)))
1238               (declare (type (simple-array character (*)) new-workspace))
1239               (%byte-blt workspace dst-start
1240                          new-workspace 0 current)
1241               (setf workspace new-workspace)
1242               (setf offset-current current)
1243               (setf offset-dst-end dst-end)
1244               (set-array-header buffer
1245                                 workspace
1246                                 new-length
1247                                 dst-end
1248                                 0
1249                                 new-length
1250                                 nil))
1251             (setf (fill-pointer buffer) dst-end))
1252         (%byte-blt string start
1253                    workspace offset-current offset-dst-end)))
1254     dst-end))
1255
1256 (defun fill-pointer-misc (stream operation &optional arg1 arg2)
1257   (declare (ignore arg2))
1258   (case operation
1259     (:file-position
1260      (let ((buffer (fill-pointer-output-stream-string stream)))
1261        (if arg1
1262            (setf (fill-pointer buffer)
1263                  (case arg1
1264                    (:start 0)
1265                    ;; Fill-pointer is always at fill-pointer we will
1266                    ;; make :END move to the end of the actual string.
1267                    (:end (array-total-size buffer))
1268                    ;; We allow moving beyond the end of string if the
1269                    ;; string is adjustable.
1270                    (t (when (>= arg1 (array-total-size buffer))
1271                         (if (adjustable-array-p buffer)
1272                             (adjust-array buffer arg1)
1273                             (error "Cannot move FILE-POSITION beyond the end ~
1274                                     of WITH-OUTPUT-TO-STRING stream ~
1275                                     constructed with non-adjustable string.")))
1276                       arg1)))
1277            (fill-pointer buffer))))
1278     (:charpos
1279      (let* ((buffer (fill-pointer-output-stream-string stream))
1280             (current (fill-pointer buffer)))
1281        (with-array-data ((string buffer) (start) (end current))
1282          (declare (simple-string string) (ignore start))
1283          (let ((found (position #\newline string :test #'char=
1284                                 :end end :from-end t)))
1285            (if found
1286                (- end (the fixnum found))
1287                current)))))
1288      (:element-type (array-element-type
1289                      (fill-pointer-output-stream-string stream)))))
1290 \f
1291 ;;;; indenting streams
1292
1293 (defstruct (indenting-stream (:include ansi-stream
1294                                        (out #'indenting-out)
1295                                        (sout #'indenting-sout)
1296                                        (misc #'indenting-misc))
1297                              (:constructor make-indenting-stream (stream))
1298                              (:copier nil))
1299   ;; the stream we're based on
1300   stream
1301   ;; how much we indent on each line
1302   (indentation 0))
1303
1304 #!+sb-doc
1305 (setf (fdocumentation 'make-indenting-stream 'function)
1306  "Return an output stream which indents its output by some amount.")
1307
1308 ;;; INDENTING-INDENT writes the correct number of spaces needed to indent
1309 ;;; output on the given STREAM based on the specified SUB-STREAM.
1310 (defmacro indenting-indent (stream sub-stream)
1311   ;; KLUDGE: bare magic number 60
1312   `(do ((i 0 (+ i 60))
1313         (indentation (indenting-stream-indentation ,stream)))
1314        ((>= i indentation))
1315      (%write-string
1316       "                                                     "
1317       ,sub-stream
1318       0
1319       (min 60 (- indentation i)))))
1320
1321 ;;; INDENTING-OUT writes a character to an indenting stream.
1322 (defun indenting-out (stream char)
1323   (let ((sub-stream (indenting-stream-stream stream)))
1324     (write-char char sub-stream)
1325     (if (char= char #\newline)
1326         (indenting-indent stream sub-stream))))
1327
1328 ;;; INDENTING-SOUT writes a string to an indenting stream.
1329 (defun indenting-sout (stream string start end)
1330   (declare (simple-string string) (fixnum start end))
1331   (do ((i start)
1332        (sub-stream (indenting-stream-stream stream)))
1333       ((= i end))
1334     (let ((newline (position #\newline string :start i :end end)))
1335       (cond (newline
1336              (%write-string string sub-stream i (1+ newline))
1337              (indenting-indent stream sub-stream)
1338              (setq i (+ newline 1)))
1339             (t
1340              (%write-string string sub-stream i end)
1341              (setq i end))))))
1342
1343 ;;; INDENTING-MISC just treats just the :LINE-LENGTH message
1344 ;;; differently. INDENTING-CHARPOS says the charpos is the charpos of
1345 ;;; the base stream minus the stream's indentation.
1346 (defun indenting-misc (stream operation &optional arg1 arg2)
1347   (let ((sub-stream (indenting-stream-stream stream)))
1348     (if (ansi-stream-p sub-stream)
1349         (let ((method (ansi-stream-misc sub-stream)))
1350           (case operation
1351             (:line-length
1352              (let ((line-length (funcall method sub-stream operation)))
1353                (if line-length
1354                    (- line-length (indenting-stream-indentation stream)))))
1355             (:charpos
1356              (let ((charpos (funcall method sub-stream operation)))
1357                (if charpos
1358                    (- charpos (indenting-stream-indentation stream)))))
1359             (t
1360              (funcall method sub-stream operation arg1 arg2))))
1361         ;; must be Gray streams FUNDAMENTAL-STREAM
1362         (case operation
1363           (:line-length
1364            (let ((line-length (stream-line-length sub-stream)))
1365              (if line-length
1366                  (- line-length (indenting-stream-indentation stream)))))
1367           (:charpos
1368            (let ((charpos (stream-line-column sub-stream)))
1369              (if charpos
1370                  (- charpos (indenting-stream-indentation stream)))))
1371           (t
1372            (stream-misc-dispatch sub-stream operation arg1 arg2))))))
1373
1374 (declaim (maybe-inline read-char unread-char read-byte listen))
1375 \f
1376 ;;;; case frobbing streams, used by FORMAT ~(...~)
1377
1378 (defstruct (case-frob-stream
1379             (:include ansi-stream
1380                       (misc #'case-frob-misc))
1381             (:constructor %make-case-frob-stream (target out sout))
1382             (:copier nil))
1383   (target (missing-arg) :type stream))
1384
1385 (defun make-case-frob-stream (target kind)
1386   #!+sb-doc
1387   "Return a stream that sends all output to the stream TARGET, but modifies
1388    the case of letters, depending on KIND, which should be one of:
1389      :upcase - convert to upper case.
1390      :downcase - convert to lower case.
1391      :capitalize - convert the first letter of words to upper case and the
1392         rest of the word to lower case.
1393      :capitalize-first - convert the first letter of the first word to upper
1394         case and everything else to lower case."
1395   (declare (type stream target)
1396            (type (member :upcase :downcase :capitalize :capitalize-first)
1397                  kind)
1398            (values stream))
1399   (if (case-frob-stream-p target)
1400       ;; If we are going to be writing to a stream that already does
1401       ;; case frobbing, why bother frobbing the case just so it can
1402       ;; frob it again?
1403       target
1404       (multiple-value-bind (out sout)
1405           (ecase kind
1406             (:upcase
1407              (values #'case-frob-upcase-out
1408                      #'case-frob-upcase-sout))
1409             (:downcase
1410              (values #'case-frob-downcase-out
1411                      #'case-frob-downcase-sout))
1412             (:capitalize
1413              (values #'case-frob-capitalize-out
1414                      #'case-frob-capitalize-sout))
1415             (:capitalize-first
1416              (values #'case-frob-capitalize-first-out
1417                      #'case-frob-capitalize-first-sout)))
1418         (%make-case-frob-stream target out sout))))
1419
1420 (defun case-frob-misc (stream op &optional arg1 arg2)
1421   (declare (type case-frob-stream stream))
1422   (case op
1423     (:close
1424      (set-closed-flame stream))
1425     (t
1426      (let ((target (case-frob-stream-target stream)))
1427        (if (ansi-stream-p target)
1428            (funcall (ansi-stream-misc target) target op arg1 arg2)
1429            (stream-misc-dispatch target op arg1 arg2))))))
1430
1431 (defun case-frob-upcase-out (stream char)
1432   (declare (type case-frob-stream stream)
1433            (type base-char char))
1434   (let ((target (case-frob-stream-target stream))
1435         (char (char-upcase char)))
1436     (if (ansi-stream-p target)
1437         (funcall (ansi-stream-out target) target char)
1438         (stream-write-char target char))))
1439
1440 (defun case-frob-upcase-sout (stream str start end)
1441   (declare (type case-frob-stream stream)
1442            (type simple-base-string str)
1443            (type index start)
1444            (type (or index null) end))
1445   (let* ((target (case-frob-stream-target stream))
1446          (len (length str))
1447          (end (or end len))
1448          (string (if (and (zerop start) (= len end))
1449                      (string-upcase str)
1450                      (nstring-upcase (subseq str start end))))
1451          (string-len (- end start)))
1452     (if (ansi-stream-p target)
1453         (funcall (ansi-stream-sout target) target string 0 string-len)
1454         (stream-write-string target string 0 string-len))))
1455
1456 (defun case-frob-downcase-out (stream char)
1457   (declare (type case-frob-stream stream)
1458            (type base-char char))
1459   (let ((target (case-frob-stream-target stream))
1460         (char (char-downcase char)))
1461     (if (ansi-stream-p target)
1462         (funcall (ansi-stream-out target) target char)
1463         (stream-write-char target char))))
1464
1465 (defun case-frob-downcase-sout (stream str start end)
1466   (declare (type case-frob-stream stream)
1467            (type simple-base-string str)
1468            (type index start)
1469            (type (or index null) end))
1470   (let* ((target (case-frob-stream-target stream))
1471          (len (length str))
1472          (end (or end len))
1473          (string (if (and (zerop start) (= len end))
1474                      (string-downcase str)
1475                      (nstring-downcase (subseq str start end))))
1476          (string-len (- end start)))
1477     (if (ansi-stream-p target)
1478         (funcall (ansi-stream-sout target) target string 0 string-len)
1479         (stream-write-string target string 0 string-len))))
1480
1481 (defun case-frob-capitalize-out (stream char)
1482   (declare (type case-frob-stream stream)
1483            (type base-char char))
1484   (let ((target (case-frob-stream-target stream)))
1485     (cond ((alphanumericp char)
1486            (let ((char (char-upcase char)))
1487              (if (ansi-stream-p target)
1488                  (funcall (ansi-stream-out target) target char)
1489                  (stream-write-char target char)))
1490            (setf (case-frob-stream-out stream) #'case-frob-capitalize-aux-out)
1491            (setf (case-frob-stream-sout stream)
1492                  #'case-frob-capitalize-aux-sout))
1493           (t
1494            (if (ansi-stream-p target)
1495                (funcall (ansi-stream-out target) target char)
1496                (stream-write-char target char))))))
1497
1498 (defun case-frob-capitalize-sout (stream str start end)
1499   (declare (type case-frob-stream stream)
1500            (type simple-base-string str)
1501            (type index start)
1502            (type (or index null) end))
1503   (let* ((target (case-frob-stream-target stream))
1504          (str (subseq str start end))
1505          (len (length str))
1506          (inside-word nil))
1507     (dotimes (i len)
1508       (let ((char (schar str i)))
1509         (cond ((not (alphanumericp char))
1510                (setf inside-word nil))
1511               (inside-word
1512                (setf (schar str i) (char-downcase char)))
1513               (t
1514                (setf inside-word t)
1515                (setf (schar str i) (char-upcase char))))))
1516     (when inside-word
1517       (setf (case-frob-stream-out stream)
1518             #'case-frob-capitalize-aux-out)
1519       (setf (case-frob-stream-sout stream)
1520             #'case-frob-capitalize-aux-sout))
1521     (if (ansi-stream-p target)
1522         (funcall (ansi-stream-sout target) target str 0 len)
1523         (stream-write-string target str 0 len))))
1524
1525 (defun case-frob-capitalize-aux-out (stream char)
1526   (declare (type case-frob-stream stream)
1527            (type base-char char))
1528   (let ((target (case-frob-stream-target stream)))
1529     (cond ((alphanumericp char)
1530            (let ((char (char-downcase char)))
1531              (if (ansi-stream-p target)
1532                  (funcall (ansi-stream-out target) target char)
1533                  (stream-write-char target char))))
1534           (t
1535            (if (ansi-stream-p target)
1536                (funcall (ansi-stream-out target) target char)
1537                (stream-write-char target char))
1538            (setf (case-frob-stream-out stream)
1539                  #'case-frob-capitalize-out)
1540            (setf (case-frob-stream-sout stream)
1541                  #'case-frob-capitalize-sout)))))
1542
1543 (defun case-frob-capitalize-aux-sout (stream str start end)
1544   (declare (type case-frob-stream stream)
1545            (type simple-base-string str)
1546            (type index start)
1547            (type (or index null) end))
1548   (let* ((target (case-frob-stream-target stream))
1549          (str (subseq str start end))
1550          (len (length str))
1551          (inside-word t))
1552     (dotimes (i len)
1553       (let ((char (schar str i)))
1554         (cond ((not (alphanumericp char))
1555                (setf inside-word nil))
1556               (inside-word
1557                (setf (schar str i) (char-downcase char)))
1558               (t
1559                (setf inside-word t)
1560                (setf (schar str i) (char-upcase char))))))
1561     (unless inside-word
1562       (setf (case-frob-stream-out stream)
1563             #'case-frob-capitalize-out)
1564       (setf (case-frob-stream-sout stream)
1565             #'case-frob-capitalize-sout))
1566     (if (ansi-stream-p target)
1567         (funcall (ansi-stream-sout target) target str 0 len)
1568         (stream-write-string target str 0 len))))
1569
1570 (defun case-frob-capitalize-first-out (stream char)
1571   (declare (type case-frob-stream stream)
1572            (type base-char char))
1573   (let ((target (case-frob-stream-target stream)))
1574     (cond ((alphanumericp char)
1575            (let ((char (char-upcase char)))
1576              (if (ansi-stream-p target)
1577                  (funcall (ansi-stream-out target) target char)
1578                  (stream-write-char target char)))
1579            (setf (case-frob-stream-out stream)
1580                  #'case-frob-downcase-out)
1581            (setf (case-frob-stream-sout stream)
1582                  #'case-frob-downcase-sout))
1583           (t
1584            (if (ansi-stream-p target)
1585                (funcall (ansi-stream-out target) target char)
1586                (stream-write-char target char))))))
1587
1588 (defun case-frob-capitalize-first-sout (stream str start end)
1589   (declare (type case-frob-stream stream)
1590            (type simple-base-string str)
1591            (type index start)
1592            (type (or index null) end))
1593   (let* ((target (case-frob-stream-target stream))
1594          (str (subseq str start end))
1595          (len (length str)))
1596     (dotimes (i len)
1597       (let ((char (schar str i)))
1598         (when (alphanumericp char)
1599           (setf (schar str i) (char-upcase char))
1600           (do ((i (1+ i) (1+ i)))
1601               ((= i len))
1602             (setf (schar str i) (char-downcase (schar str i))))
1603           (setf (case-frob-stream-out stream)
1604                 #'case-frob-downcase-out)
1605           (setf (case-frob-stream-sout stream)
1606                 #'case-frob-downcase-sout)
1607           (return))))
1608     (if (ansi-stream-p target)
1609         (funcall (ansi-stream-sout target) target str 0 len)
1610         (stream-write-string target str 0 len))))
1611 \f
1612 ;;;; READ-SEQUENCE
1613
1614 (defun read-sequence (seq stream &key (start 0) end)
1615   #!+sb-doc
1616   "Destructively modify SEQ by reading elements from STREAM.
1617   That part of SEQ bounded by START and END is destructively modified by
1618   copying successive elements into it from STREAM. If the end of file
1619   for STREAM is reached before copying all elements of the subsequence,
1620   then the extra elements near the end of sequence are not updated, and
1621   the index of the next element is returned."
1622   (declare (type sequence seq)
1623            (type stream stream)
1624            (type index start)
1625            (type sequence-end end)
1626            (values index))
1627   (if (ansi-stream-p stream)
1628       (ansi-stream-read-sequence seq stream start end)
1629       ;; must be Gray streams FUNDAMENTAL-STREAM
1630       (stream-read-sequence stream seq start end)))
1631
1632 (defun ansi-stream-read-sequence (seq stream start %end)
1633   (declare (type sequence seq)
1634            (type ansi-stream stream)
1635            (type index start)
1636            (type sequence-end %end)
1637            (values index))
1638   (let ((end (or %end (length seq))))
1639     (declare (type index end))
1640     (etypecase seq
1641       (list
1642        (let ((read-function
1643               (if (subtypep (stream-element-type stream) 'character)
1644                   #'read-char
1645                   #'read-byte)))
1646          (do ((rem (nthcdr start seq) (rest rem))
1647               (i start (1+ i)))
1648              ((or (endp rem) (>= i end)) i)
1649            (declare (type list rem)
1650                     (type index i))
1651            (let ((el (funcall read-function stream nil :eof)))
1652              (when (eq el :eof)
1653                (return i))
1654              (setf (first rem) el)))))
1655       (vector
1656        (with-array-data ((data seq) (offset-start start) (offset-end end))
1657          (typecase data
1658            ((or (simple-array (unsigned-byte 8) (*))
1659                 (simple-array (signed-byte 8) (*))
1660                 simple-string)
1661             (let* ((numbytes (- end start))
1662                    (bytes-read (sb!sys:read-n-bytes stream
1663                                                     data
1664                                                     offset-start
1665                                                     numbytes
1666                                                     nil)))
1667               (if (< bytes-read numbytes)
1668                   (+ start bytes-read)
1669                   end)))
1670            (t
1671             (let ((read-function
1672                    (if (subtypep (stream-element-type stream) 'character)
1673                        #'read-char
1674                        #'read-byte)))
1675               (do ((i offset-start (1+ i)))
1676                   ((>= i offset-end) end)
1677                 (declare (type index i))
1678                 (let ((el (funcall read-function stream nil :eof)))
1679                   (when (eq el :eof)
1680                     (return (+ start (- i offset-start))))
1681                   (setf (aref data i) el)))))))))))
1682 \f
1683 ;;;; WRITE-SEQUENCE
1684
1685 (defun write-sequence (seq stream &key (start 0) (end nil))
1686   #!+sb-doc
1687   "Write the elements of SEQ bounded by START and END to STREAM."
1688   (declare (type sequence seq)
1689            (type stream stream)
1690            (type index start)
1691            (type sequence-end end)
1692            (values sequence))
1693   (if (ansi-stream-p stream)
1694       (ansi-stream-write-sequence seq stream start end)
1695       ;; must be Gray-streams FUNDAMENTAL-STREAM
1696       (stream-write-sequence stream seq start end)))
1697
1698 (defun ansi-stream-write-sequence (seq stream start %end)
1699   (declare (type sequence seq)
1700            (type ansi-stream stream)
1701            (type index start)
1702            (type sequence-end %end)
1703            (values sequence))
1704   (let ((end (or %end (length seq))))
1705     (declare (type index end))
1706     (etypecase seq
1707       (list
1708        (let ((write-function
1709               (if (subtypep (stream-element-type stream) 'character)
1710                   #'write-char
1711                   #'write-byte)))
1712          (do ((rem (nthcdr start seq) (rest rem))
1713               (i start (1+ i)))
1714              ((or (endp rem) (>= i end)) seq)
1715            (declare (type list rem)
1716                     (type index i))
1717            (funcall write-function (first rem) stream))))
1718       (string
1719        (%write-string seq stream start end))
1720       (vector
1721        (let ((write-function
1722               (if (subtypep (stream-element-type stream) 'character)
1723                   #'write-char
1724                   #'write-byte)))
1725          (do ((i start (1+ i)))
1726              ((>= i end) seq)
1727            (declare (type index i))
1728            (funcall write-function (aref seq i) stream)))))))
1729 \f
1730 ;;;; etc.