src/code/stream.lisp

   1 ;;;; os-independent stream functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 ;;;; standard streams
  15
  16 ;;; The initialization of these streams is performed by
  17 ;;; STREAM-COLD-INIT-OR-RESET.
  18 (defvar *terminal-io* () #!+sb-doc "terminal I/O stream")
  19 (defvar *standard-input* () #!+sb-doc "default input stream")
  20 (defvar *standard-output* () #!+sb-doc "default output stream")
  21 (defvar *error-output* () #!+sb-doc "error output stream")
  22 (defvar *query-io* () #!+sb-doc "query I/O stream")
  23 (defvar *trace-output* () #!+sb-doc "trace output stream")
  24 (defvar *debug-io* () #!+sb-doc "interactive debugging stream")
  25
  26 (defun ill-in (stream &rest ignore)
  27   (declare (ignore ignore))
  28   (error 'simple-type-error
  29          :datum stream
  30          :expected-type '(satisfies input-stream-p)
  31          :format-control "~S is not a character input stream."
  32          :format-arguments (list stream)))
  33 (defun ill-out (stream &rest ignore)
  34   (declare (ignore ignore))
  35   (error 'simple-type-error
  36          :datum stream
  37          :expected-type '(satisfies output-stream-p)
  38          :format-control "~S is not a character output stream."
  39          :format-arguments (list stream)))
  40 (defun ill-bin (stream &rest ignore)
  41   (declare (ignore ignore))
  42   (error 'simple-type-error
  43          :datum stream
  44          :expected-type '(satisfies input-stream-p)
  45          :format-control "~S is not a binary input stream."
  46          :format-arguments (list stream)))
  47 (defun ill-bout (stream &rest ignore)
  48   (declare (ignore ignore))
  49   (error 'simple-type-error
  50          :datum stream
  51          :expected-type '(satisfies output-stream-p)
  52          :format-control "~S is not a binary output stream."
  53          :format-arguments (list stream)))
  54 (defun closed-flame (stream &rest ignore)
  55   (declare (ignore ignore))
  56   (error "~S is closed." stream))
  57 (defun no-op-placeholder (&rest ignore)
  58   (declare (ignore ignore)))
  59 \f
  60 ;;; stream manipulation functions
  61
  62 (declaim (inline ansi-stream-input-stream-p))
  63 (defun ansi-stream-input-stream-p (stream)
  64   (declare (type ansi-stream stream))
  65
  66   (when (synonym-stream-p stream)
  67     (setf stream
  68           (symbol-value (synonym-stream-symbol stream))))
  69
  70   (and (not (eq (ansi-stream-in stream) #'closed-flame))
  71        ;;; KLUDGE: It's probably not good to have EQ tests on function
  72        ;;; values like this. What if someone's redefined the function?
  73        ;;; Is there a better way? (Perhaps just VALID-FOR-INPUT and
  74        ;;; VALID-FOR-OUTPUT flags? -- WHN 19990902
  75        (or (not (eq (ansi-stream-in stream) #'ill-in))
  76            (not (eq (ansi-stream-bin stream) #'ill-bin)))))
  77
  78 (defun input-stream-p (stream)
  79   (declare (type stream stream))
  80   (and (ansi-stream-p stream)
  81        (ansi-stream-input-stream-p stream)))
  82
  83 (declaim (inline ansi-stream-output-stream-p))
  84 (defun ansi-stream-output-stream-p (stream)
  85   (declare (type ansi-stream stream))
  86
  87   (when (synonym-stream-p stream)
  88     (setf stream (symbol-value
  89                   (synonym-stream-symbol stream))))
  90
  91   (and (not (eq (ansi-stream-in stream) #'closed-flame))
  92        (or (not (eq (ansi-stream-out stream) #'ill-out))
  93            (not (eq (ansi-stream-bout stream) #'ill-bout)))))
  94
  95 (defun output-stream-p (stream)
  96   (declare (type stream stream))
  97
  98   (and (ansi-stream-p stream)
  99        (ansi-stream-output-stream-p stream)))
 100
 101 (declaim (inline ansi-stream-open-stream-p))
 102 (defun ansi-stream-open-stream-p (stream)
 103   (declare (type ansi-stream stream))
 104   ;; CLHS 22.1.4 lets us not worry about synonym streams here.
 105   (not (eq (ansi-stream-in stream) #'closed-flame)))
 106
 107 (defun open-stream-p (stream)
 108   (ansi-stream-open-stream-p stream))
 109
 110 (declaim (inline ansi-stream-element-type))
 111 (defun ansi-stream-element-type (stream)
 112   (declare (type ansi-stream stream))
 113   (funcall (ansi-stream-misc stream) stream :element-type))
 114
 115 (defun stream-element-type (stream)
 116   (ansi-stream-element-type stream))
 117
 118 (defun interactive-stream-p (stream)
 119   (declare (type stream stream))
 120   (funcall (ansi-stream-misc stream) stream :interactive-p))
 121
 122 (declaim (inline ansi-stream-close))
 123 (defun ansi-stream-close (stream abort)
 124   (declare (type ansi-stream stream))
 125   (when (open-stream-p stream)
 126     (funcall (ansi-stream-misc stream) stream :close abort))
 127   t)
 128
 129 (defun close (stream &key abort)
 130   (ansi-stream-close stream abort))
 131
 132 (defun set-closed-flame (stream)
 133   (setf (ansi-stream-in stream) #'closed-flame)
 134   (setf (ansi-stream-bin stream) #'closed-flame)
 135   (setf (ansi-stream-n-bin stream) #'closed-flame)
 136   (setf (ansi-stream-in stream) #'closed-flame)
 137   (setf (ansi-stream-out stream) #'closed-flame)
 138   (setf (ansi-stream-bout stream) #'closed-flame)
 139   (setf (ansi-stream-sout stream) #'closed-flame)
 140   (setf (ansi-stream-misc stream) #'closed-flame))
 141 \f
 142 ;;;; file position and file length
 143
 144 ;;; Call the MISC method with the :FILE-POSITION operation.
 145 (defun file-position (stream &optional position)
 146   (declare (type stream stream))
 147   (declare (type (or index (alien sb!unix:off-t) (member nil :start :end)) position))
 148   (cond
 149    (position
 150     (setf (ansi-stream-in-index stream) +ansi-stream-in-buffer-length+)
 151     (funcall (ansi-stream-misc stream) stream :file-position position))
 152    (t
 153     (let ((res (funcall (ansi-stream-misc stream) stream :file-position nil)))
 154       (when res
 155         (- res
 156            (- +ansi-stream-in-buffer-length+
 157               (ansi-stream-in-index stream))))))))
 158
 159 ;;; This is a literal translation of the ANSI glossary entry "stream
 160 ;;; associated with a file".
 161 ;;;
 162 ;;; KLUDGE: Note that since Unix famously thinks "everything is a
 163 ;;; file", and in particular stdin, stdout, and stderr are files, we
 164 ;;; end up with this test being satisfied for weird things like
 165 ;;; *STANDARD-OUTPUT* (to a tty). That seems unlikely to be what the
 166 ;;; ANSI spec really had in mind, especially since this is used as a
 167 ;;; qualification for operations like FILE-LENGTH (so that ANSI was
 168 ;;; probably thinking of something like what Unix calls block devices)
 169 ;;; but I can't see any better way to do it. -- WHN 2001-04-14
 170 (defun stream-associated-with-file-p (x)
 171   "Test for the ANSI concept \"stream associated with a file\"."
 172   (or (typep x 'file-stream)
 173       (and (synonym-stream-p x)
 174            (stream-associated-with-file-p (symbol-value
 175                                            (synonym-stream-symbol x))))))
 176
 177 (defun stream-must-be-associated-with-file (stream)
 178   (declare (type stream stream))
 179   (unless (stream-associated-with-file-p stream)
 180     (error 'simple-type-error
 181            ;; KLUDGE: The ANSI spec for FILE-LENGTH specifically says
 182            ;; this should be TYPE-ERROR. But what then can we use for
 183            ;; EXPECTED-TYPE? This SATISFIES type (with a nonstandard
 184            ;; private predicate function..) is ugly and confusing, but
 185            ;; I can't see any other way. -- WHN 2001-04-14
 186            :expected-type '(satisfies stream-associated-with-file-p)
 187            :format-control
 188            "~@<The stream ~2I~_~S ~I~_isn't associated with a file.~:>"
 189            :format-arguments (list stream))))
 190
 191 ;;; like FILE-POSITION, only using :FILE-LENGTH
 192 (defun file-length (stream)
 193   ;; FIXME: The following declaration uses yet undefined types, which
 194   ;; cause cross-compiler hangup.
 195   ;;
 196   ;; (declare (type (or file-stream synonym-stream) stream))
 197   (stream-must-be-associated-with-file stream)
 198   (funcall (ansi-stream-misc stream) stream :file-length))
 199 \f
 200 ;;;; input functions
 201
 202 (defun read-line (&optional (stream *standard-input*) (eof-error-p t) eof-value
 203                             recursive-p)
 204   (declare (ignore recursive-p))
 205   (let ((stream (in-synonym-of stream)))
 206     (if (ansi-stream-p stream)
 207         (prepare-for-fast-read-char stream
 208           (let ((res (make-string 80))
 209                 (len 80)
 210                 (index 0))
 211             (loop
 212              (let ((ch (fast-read-char nil nil)))
 213                (cond (ch
 214                       (when (char= ch #\newline)
 215                         (done-with-fast-read-char)
 216                         (return (values (shrink-vector res index) nil)))
 217                       (when (= index len)
 218                         (setq len (* len 2))
 219                         (let ((new (make-string len)))
 220                           (replace new res)
 221                           (setq res new)))
 222                       (setf (schar res index) ch)
 223                       (incf index))
 224                      ((zerop index)
 225                       (done-with-fast-read-char)
 226                       (return (values (eof-or-lose stream
 227                                                    eof-error-p
 228                                                    eof-value)
 229                                       t)))
 230                      ;; Since FAST-READ-CHAR already hit the eof char, we
 231                      ;; shouldn't do another READ-CHAR.
 232                      (t
 233                       (done-with-fast-read-char)
 234                       (return (values (shrink-vector res index) t))))))))
 235         ;; must be Gray streams FUNDAMENTAL-STREAM
 236         (multiple-value-bind (string eof) (stream-read-line stream)
 237           (if (and eof (zerop (length string)))
 238               (values (eof-or-lose stream eof-error-p eof-value) t)
 239               (values string eof))))))
 240
 241 ;;; We proclaim them INLINE here, then proclaim them MAYBE-INLINE at EOF,
 242 ;;; so, except in this file, they are not inline by default, but they can be.
 243 #!-sb-fluid (declaim (inline read-char unread-char read-byte listen))
 244
 245 (defun read-char (&optional (stream *standard-input*)
 246                             (eof-error-p t)
 247                             eof-value
 248                             recursive-p)
 249   (declare (ignore recursive-p))
 250   (let ((stream (in-synonym-of stream)))
 251     (if (ansi-stream-p stream)
 252         (prepare-for-fast-read-char stream
 253           (prog1
 254               (fast-read-char eof-error-p eof-value)
 255             (done-with-fast-read-char)))
 256         ;; must be Gray streams FUNDAMENTAL-STREAM
 257         (let ((char (stream-read-char stream)))
 258           (if (eq char :eof)
 259               (eof-or-lose stream eof-error-p eof-value)
 260               char)))))
 261
 262 (defun unread-char (character &optional (stream *standard-input*))
 263   (let ((stream (in-synonym-of stream)))
 264     (if (ansi-stream-p stream)
 265         (let ((index (1- (ansi-stream-in-index stream)))
 266               (buffer (ansi-stream-in-buffer stream)))
 267           (declare (fixnum index))
 268           (when (minusp index) (error "nothing to unread"))
 269           (cond (buffer
 270                  (setf (aref buffer index) (char-code character))
 271                  (setf (ansi-stream-in-index stream) index))
 272                 (t
 273                  (funcall (ansi-stream-misc stream) stream
 274                           :unread character))))
 275         ;; must be Gray streams FUNDAMENTAL-STREAM
 276         (stream-unread-char stream character)))
 277   nil)
 278
 279 (defun listen (&optional (stream *standard-input*))
 280   (let ((stream (in-synonym-of stream)))
 281     (if (ansi-stream-p stream)
 282         (or (/= (the fixnum (ansi-stream-in-index stream))
 283                 +ansi-stream-in-buffer-length+)
 284             ;; Test for T explicitly since misc methods return :EOF sometimes.
 285             (eq (funcall (ansi-stream-misc stream) stream :listen) t))
 286         ;; Fall through to Gray streams FUNDAMENTAL-STREAM case.
 287         (stream-listen stream))))
 288
 289 (defun read-char-no-hang (&optional (stream *standard-input*)
 290                                     (eof-error-p t)
 291                                     eof-value
 292                                     recursive-p)
 293   (declare (ignore recursive-p))
 294   (let ((stream (in-synonym-of stream)))
 295     (if (ansi-stream-p stream)
 296         (if (funcall (ansi-stream-misc stream) stream :listen)
 297             ;; On T or :EOF get READ-CHAR to do the work.
 298             (read-char stream eof-error-p eof-value)
 299             nil)
 300         ;; must be Gray streams FUNDAMENTAL-STREAM
 301         (let ((char (stream-read-char-no-hang stream)))
 302           (if (eq char :eof)
 303               (eof-or-lose stream eof-error-p eof-value)
 304               char)))))
 305
 306 (defun clear-input (&optional (stream *standard-input*))
 307   (let ((stream (in-synonym-of stream)))
 308     (cond ((ansi-stream-p stream)
 309            (setf (ansi-stream-in-index stream) +ansi-stream-in-buffer-length+)
 310            (funcall (ansi-stream-misc stream) stream :clear-input))
 311           (t
 312            (stream-clear-input stream))))
 313   nil)
 314 \f
 315 (declaim (maybe-inline read-byte))
 316 (defun read-byte (stream &optional (eof-error-p t) eof-value)
 317   (let ((stream (in-synonym-of stream)))
 318     (if (ansi-stream-p stream)
 319         (prepare-for-fast-read-byte stream
 320           (prog1
 321               (fast-read-byte eof-error-p eof-value t)
 322             (done-with-fast-read-byte)))
 323         ;; must be Gray streams FUNDAMENTAL-STREAM
 324         (let ((char (stream-read-byte stream)))
 325           (if (eq char :eof)
 326               (eof-or-lose stream eof-error-p eof-value)
 327               char)))))
 328
 329 ;;; Read NUMBYTES bytes into BUFFER beginning at START, and return the
 330 ;;; number of bytes read.
 331 ;;;
 332 ;;; Note: CMU CL's version of this had a special interpretation of
 333 ;;; EOF-ERROR-P which SBCL does not have. (In the EOF-ERROR-P=NIL
 334 ;;; case, CMU CL's version would return as soon as any data became
 335 ;;; available.) This could be useful behavior for things like pipes in
 336 ;;; some cases, but it wasn't being used in SBCL, so it was dropped.
 337 ;;; If we ever need it, it could be added later as a new variant N-BIN
 338 ;;; method (perhaps N-BIN-ASAP?) or something.
 339 (defun read-n-bytes (stream buffer start numbytes &optional (eof-error-p t))
 340   (declare (type ansi-stream stream)
 341            (type index numbytes start)
 342            (type (or (simple-array * (*)) system-area-pointer) buffer))
 343   (let* ((stream (in-synonym-of stream ansi-stream))
 344          (in-buffer (ansi-stream-in-buffer stream))
 345          (index (ansi-stream-in-index stream))
 346          (num-buffered (- +ansi-stream-in-buffer-length+ index)))
 347     (declare (fixnum index num-buffered))
 348     (cond
 349      ((not in-buffer)
 350       (funcall (ansi-stream-n-bin stream)
 351                stream
 352                buffer
 353                start
 354                numbytes
 355                eof-error-p))
 356      ((<= numbytes num-buffered)
 357       (%byte-blt in-buffer index
 358                  buffer start (+ start numbytes))
 359       (setf (ansi-stream-in-index stream) (+ index numbytes))
 360       numbytes)
 361      (t
 362       (let ((end (+ start num-buffered)))
 363         (%byte-blt in-buffer index buffer start end)
 364         (setf (ansi-stream-in-index stream) +ansi-stream-in-buffer-length+)
 365         (+ (funcall (ansi-stream-n-bin stream)
 366                     stream
 367                     buffer
 368                     end
 369                     (- numbytes num-buffered)
 370                     eof-error-p)
 371            num-buffered))))))
 372
 373 ;;; the amount of space we leave at the start of the in-buffer for
 374 ;;; unreading
 375 ;;;
 376 ;;; (It's 4 instead of 1 to allow word-aligned copies.)
 377 (defconstant +ansi-stream-in-buffer-extra+
 378   4) ; FIXME: should be symbolic constant
 379
 380 ;;; This function is called by the FAST-READ-CHAR expansion to refill
 381 ;;; the IN-BUFFER for text streams. There is definitely an IN-BUFFER,
 382 ;;; and hence must be an N-BIN method.
 383 (defun fast-read-char-refill (stream eof-error-p eof-value)
 384   (let* ((ibuf (ansi-stream-in-buffer stream))
 385          (count (funcall (ansi-stream-n-bin stream)
 386                          stream
 387                          ibuf
 388                          +ansi-stream-in-buffer-extra+
 389                          (- +ansi-stream-in-buffer-length+
 390                             +ansi-stream-in-buffer-extra+)
 391                          nil))
 392          (start (- +ansi-stream-in-buffer-length+ count)))
 393     (declare (type index start count))
 394     (cond ((zerop count)
 395            (setf (ansi-stream-in-index stream) +ansi-stream-in-buffer-length+)
 396            (funcall (ansi-stream-in stream) stream eof-error-p eof-value))
 397           (t
 398            (when (/= start +ansi-stream-in-buffer-extra+)
 399              (bit-bash-copy ibuf (+ (* +ansi-stream-in-buffer-extra+
 400                                        sb!vm:n-byte-bits)
 401                                     (* sb!vm:vector-data-offset
 402                                        sb!vm:n-word-bits))
 403                             ibuf (+ (the index (* start sb!vm:n-byte-bits))
 404                                     (* sb!vm:vector-data-offset
 405                                        sb!vm:n-word-bits))
 406                             (* count sb!vm:n-byte-bits)))
 407            (setf (ansi-stream-in-index stream) (1+ start))
 408            (code-char (aref ibuf start))))))
 409
 410 ;;; This is similar to FAST-READ-CHAR-REFILL, but we don't have to
 411 ;;; leave room for unreading.
 412 (defun fast-read-byte-refill (stream eof-error-p eof-value)
 413   (let* ((ibuf (ansi-stream-in-buffer stream))
 414          (count (funcall (ansi-stream-n-bin stream) stream
 415                          ibuf 0 +ansi-stream-in-buffer-length+
 416                          nil))
 417          (start (- +ansi-stream-in-buffer-length+ count)))
 418     (declare (type index start count))
 419     (cond ((zerop count)
 420            (setf (ansi-stream-in-index stream) +ansi-stream-in-buffer-length+)
 421            (funcall (ansi-stream-bin stream) stream eof-error-p eof-value))
 422           (t
 423            (unless (zerop start)
 424              (bit-bash-copy ibuf (* sb!vm:vector-data-offset sb!vm:n-word-bits)
 425                             ibuf (+ (the index (* start sb!vm:n-byte-bits))
 426                                     (* sb!vm:vector-data-offset
 427                                        sb!vm:n-word-bits))
 428                             (* count sb!vm:n-byte-bits)))
 429            (setf (ansi-stream-in-index stream) (1+ start))
 430            (aref ibuf start)))))
 431 \f
 432 ;;; output functions
 433
 434 (defun write-char (character &optional (stream *standard-output*))
 435   (with-out-stream stream (ansi-stream-out character)
 436                    (stream-write-char character))
 437   character)
 438
 439 (defun terpri (&optional (stream *standard-output*))
 440   (with-out-stream stream (ansi-stream-out #\newline) (stream-terpri))
 441   nil)
 442
 443 (defun fresh-line (&optional (stream *standard-output*))
 444   (let ((stream (out-synonym-of stream)))
 445     (if (ansi-stream-p stream)
 446         (when (/= (or (charpos stream) 1) 0)
 447           (funcall (ansi-stream-out stream) stream #\newline)
 448           t)
 449         ;; must be Gray streams FUNDAMENTAL-STREAM
 450         (stream-fresh-line stream))))
 451
 452 (defun write-string (string &optional (stream *standard-output*)
 453                             &key (start 0) end)
 454   (declare (type string string))
 455   ;; Note that even though you might expect, based on the behavior of
 456   ;; things like AREF, that the correct upper bound here is
 457   ;; (ARRAY-DIMENSION STRING 0), the ANSI glossary definitions for
 458   ;; "bounding index" and "length" indicate that in this case (i.e.
 459   ;; for the ANSI-specified functions WRITE-STRING [and WRITE-LINE]),
 460   ;; (LENGTH STRING) is the required upper bound. A foolish
 461   ;; consistency is the hobgoblin of lesser languages..
 462   (%write-string string stream start (%check-vector-sequence-bounds
 463                                       string start end))
 464   string)
 465
 466 (defun %write-string (string stream start end)
 467   (declare (type string string))
 468   (declare (type stream-designator stream))
 469   (declare (type index start end))
 470   (let ((stream (out-synonym-of stream)))
 471     (cond ((ansi-stream-p stream)
 472            (if (array-header-p string)
 473                (with-array-data ((data string) (offset-start start)
 474                                  (offset-end end))
 475                  (funcall (ansi-stream-sout stream)
 476                           stream data offset-start offset-end))
 477                (funcall (ansi-stream-sout stream) stream string start end))
 478            string)
 479           (t ; must be Gray streams FUNDAMENTAL-STREAM
 480            (stream-write-string stream string start end)))))
 481
 482 ;;; A wrapper function for all those (MACROLET OUT-FUN) definitions,
 483 ;;; which cannot deal with keyword arguments.
 484 (declaim (inline write-string-no-key))
 485 (defun write-string-no-key (string stream start end)
 486   (write-string string stream :start start :end end))
 487
 488 (defun write-line (string &optional (stream *standard-output*)
 489                           &key (start 0) end)
 490   (declare (type string string))
 491   ;; FIXME: Why is there this difference between the treatments of the
 492   ;; STREAM argument in WRITE-STRING and WRITE-LINE?
 493   (let ((defaulted-stream (out-synonym-of stream)))
 494     (%write-string string defaulted-stream start (%check-vector-sequence-bounds
 495                                                   string start end))
 496     (write-char #\newline defaulted-stream))
 497   string)
 498
 499 (defun charpos (&optional (stream *standard-output*))
 500   (with-out-stream stream (ansi-stream-misc :charpos) (stream-line-column)))
 501
 502 (defun line-length (&optional (stream *standard-output*))
 503   (with-out-stream stream (ansi-stream-misc :line-length)
 504                    (stream-line-length)))
 505
 506 (defun finish-output (&optional (stream *standard-output*))
 507   (with-out-stream stream (ansi-stream-misc :finish-output)
 508                    (stream-finish-output))
 509   nil)
 510
 511 (defun force-output (&optional (stream *standard-output*))
 512   (with-out-stream stream (ansi-stream-misc :force-output)
 513                    (stream-force-output))
 514   nil)
 515
 516 (defun clear-output (&optional (stream *standard-output*))
 517   (with-out-stream stream (ansi-stream-misc :clear-output)
 518                    (stream-force-output))
 519   nil)
 520
 521 (defun write-byte (integer stream)
 522   (with-out-stream stream (ansi-stream-bout integer)
 523                    (stream-write-byte integer))
 524   integer)
 525 \f
 526
 527 ;;; (These were inline throughout this file, but that's not appropriate
 528 ;;; globally.  And we must not inline them in the rest of this file if
 529 ;;; dispatch to gray or simple streams is to work, since both redefine
 530 ;;; these functions later.)
 531 (declaim (maybe-inline read-char unread-char read-byte listen))
 532
 533 ;;; This is called from ANSI-STREAM routines that encapsulate CLOS
 534 ;;; streams to handle the misc routines and dispatch to the
 535 ;;; appropriate SIMPLE- or FUNDAMENTAL-STREAM functions.
 536 (defun stream-misc-dispatch (stream operation &optional arg1 arg2)
 537   (declare (type stream stream) (ignore arg2))
 538   (ecase operation
 539     (:listen
 540      ;; Return T if input available, :EOF for end-of-file, otherwise NIL.
 541      (let ((char (read-char-no-hang stream nil :eof)))
 542        (when (characterp char)
 543          (unread-char char stream))
 544        char))
 545     (:unread
 546      (unread-char arg1 stream))
 547     (:close
 548      (close stream))
 549     (:clear-input
 550      (clear-input stream))
 551     (:force-output
 552      (force-output stream))
 553     (:finish-output
 554      (finish-output stream))
 555     (:element-type
 556      (stream-element-type stream))
 557     (:interactive-p
 558      (interactive-stream-p stream))
 559     (:line-length
 560      (line-length stream))
 561     (:charpos
 562      (charpos stream))
 563     (:file-length
 564      (file-length stream))
 565     (:file-position
 566      (file-position stream arg1))))
 567 \f
 568 ;;;; broadcast streams
 569
 570 (defstruct (broadcast-stream (:include ansi-stream
 571                                        (out #'broadcast-out)
 572                                        (bout #'broadcast-bout)
 573                                        (sout #'broadcast-sout)
 574                                        (misc #'broadcast-misc))
 575                              (:constructor %make-broadcast-stream
 576                                            (&rest streams))
 577                              (:copier nil))
 578   ;; a list of all the streams we broadcast to
 579   (streams () :type list :read-only t))
 580
 581 (defun make-broadcast-stream (&rest streams)
 582   (dolist (stream streams)
 583     (unless (output-stream-p stream)
 584       (error 'type-error
 585              :datum stream
 586              :expected-type '(satisfies output-stream-p))))
 587   (apply #'%make-broadcast-stream streams))
 588
 589 (macrolet ((out-fun (name fun &rest args)
 590              `(defun ,name (stream ,@args)
 591                 (dolist (stream (broadcast-stream-streams stream))
 592                   (,fun ,(car args) stream ,@(cdr args))))))
 593   (out-fun broadcast-out write-char char)
 594   (out-fun broadcast-bout write-byte byte)
 595   (out-fun broadcast-sout write-string-no-key string start end))
 596
 597 (defun broadcast-misc (stream operation &optional arg1 arg2)
 598   (let ((streams (broadcast-stream-streams stream)))
 599     (case operation
 600       ;; FIXME: This may not be the best place to note this, but I
 601       ;; think the :CHARPOS protocol needs revision.  Firstly, I think
 602       ;; this is the last place where a NULL return value was possible
 603       ;; (before adjusting it to be 0), so a bunch of conditionals IF
 604       ;; CHARPOS can be removed; secondly, it is my belief that
 605       ;; FD-STREAMS, when running FILE-POSITION, do not update the
 606       ;; CHARPOS, and consequently there will be much wrongness.
 607       ;;
 608       ;; FIXME: see also TWO-WAY-STREAM treatment of :CHARPOS -- why
 609       ;; is it testing the :charpos of an input stream?
 610       ;;
 611       ;; -- CSR, 2004-02-04
 612       (:charpos
 613        (dolist (stream streams 0)
 614          (let ((charpos (charpos stream)))
 615            (if charpos (return charpos)))))
 616       (:line-length
 617        (let ((min nil))
 618          (dolist (stream streams min)
 619            (let ((res (line-length stream)))
 620              (when res (setq min (if min (min res min) res)))))))
 621       (:element-type
 622        #+nil ; old, arguably more logical, version
 623        (let (res)
 624          (dolist (stream streams (if (> (length res) 1) `(and ,@res) t))
 625            (pushnew (stream-element-type stream) res :test #'equal)))
 626        ;; ANSI-specified version (under System Class BROADCAST-STREAM)
 627        (let ((res t))
 628          (do ((streams streams (cdr streams)))
 629              ((null streams) res)
 630            (when (null (cdr streams))
 631              (setq res (stream-element-type (car streams)))))))
 632       (:close
 633        (set-closed-flame stream))
 634       (t
 635        (let ((res nil))
 636          (dolist (stream streams res)
 637            (setq res
 638                  (if (ansi-stream-p stream)
 639                      (funcall (ansi-stream-misc stream) stream operation
 640                               arg1 arg2)
 641                      (stream-misc-dispatch stream operation arg1 arg2)))))))))
 642 \f
 643 ;;;; synonym streams
 644
 645 (defstruct (synonym-stream (:include ansi-stream
 646                                      (in #'synonym-in)
 647                                      (bin #'synonym-bin)
 648                                      (n-bin #'synonym-n-bin)
 649                                      (out #'synonym-out)
 650                                      (bout #'synonym-bout)
 651                                      (sout #'synonym-sout)
 652                                      (misc #'synonym-misc))
 653                            (:constructor make-synonym-stream (symbol))
 654                            (:copier nil))
 655   ;; This is the symbol, the value of which is the stream we are synonym to.
 656   (symbol nil :type symbol :read-only t))
 657 (def!method print-object ((x synonym-stream) stream)
 658   (print-unreadable-object (x stream :type t :identity t)
 659     (format stream ":SYMBOL ~S" (synonym-stream-symbol x))))
 660
 661 ;;; The output simple output methods just call the corresponding
 662 ;;; function on the synonymed stream.
 663 (macrolet ((out-fun (name fun &rest args)
 664              `(defun ,name (stream ,@args)
 665                 (declare (optimize (safety 1)))
 666                 (let ((syn (symbol-value (synonym-stream-symbol stream))))
 667                   (,fun ,(car args) syn ,@(cdr args))))))
 668   (out-fun synonym-out write-char ch)
 669   (out-fun synonym-bout write-byte n)
 670   (out-fun synonym-sout write-string-no-key string start end))
 671
 672 ;;; For the input methods, we just call the corresponding function on the
 673 ;;; synonymed stream. These functions deal with getting input out of
 674 ;;; the In-Buffer if there is any.
 675 (macrolet ((in-fun (name fun &rest args)
 676              `(defun ,name (stream ,@args)
 677                 (declare (optimize (safety 1)))
 678                 (,fun (symbol-value (synonym-stream-symbol stream))
 679                       ,@args))))
 680   (in-fun synonym-in read-char eof-error-p eof-value)
 681   (in-fun synonym-bin read-byte eof-error-p eof-value)
 682   (in-fun synonym-n-bin read-n-bytes buffer start numbytes eof-error-p))
 683
 684 (defun synonym-misc (stream operation &optional arg1 arg2)
 685   (declare (optimize (safety 1)))
 686   (let ((syn (symbol-value (synonym-stream-symbol stream))))
 687     (if (ansi-stream-p syn)
 688         ;; We have to special-case some operations which interact with
 689         ;; the in-buffer of the wrapped stream, since just calling
 690         ;; ANSI-STREAM-MISC on them
 691         (case operation
 692           (:listen (or (/= (the fixnum (ansi-stream-in-index syn))
 693                            +ansi-stream-in-buffer-length+)
 694                        (funcall (ansi-stream-misc syn) syn :listen)))
 695           (:clear-input (clear-input syn))
 696           (:unread (unread-char arg1 syn))
 697           (t
 698            (funcall (ansi-stream-misc syn) syn operation arg1 arg2)))
 699         (stream-misc-dispatch syn operation arg1 arg2))))
 700 \f
 701 ;;;; two-way streams
 702
 703 (defstruct (two-way-stream
 704             (:include ansi-stream
 705                       (in #'two-way-in)
 706                       (bin #'two-way-bin)
 707                       (n-bin #'two-way-n-bin)
 708                       (out #'two-way-out)
 709                       (bout #'two-way-bout)
 710                       (sout #'two-way-sout)
 711                       (misc #'two-way-misc))
 712             (:constructor %make-two-way-stream (input-stream output-stream))
 713             (:copier nil))
 714   (input-stream (missing-arg) :type stream :read-only t)
 715   (output-stream (missing-arg) :type stream :read-only t))
 716 (defprinter (two-way-stream) input-stream output-stream)
 717
 718 (defun make-two-way-stream (input-stream output-stream)
 719   #!+sb-doc
 720   "Return a bidirectional stream which gets its input from INPUT-STREAM and
 721    sends its output to OUTPUT-STREAM."
 722   ;; FIXME: This idiom of the-real-stream-of-a-possibly-synonym-stream
 723   ;; should be encapsulated in a function, and used here and most of
 724   ;; the other places that SYNONYM-STREAM-P appears.
 725   (unless (output-stream-p output-stream)
 726     (error 'type-error
 727            :datum output-stream
 728            :expected-type '(satisfies output-stream-p)))
 729   (unless (input-stream-p input-stream)
 730     (error 'type-error
 731            :datum input-stream
 732            :expected-type '(satisfies input-stream-p)))
 733   (funcall #'%make-two-way-stream input-stream output-stream))
 734
 735 (macrolet ((out-fun (name fun &rest args)
 736              `(defun ,name (stream ,@args)
 737                 (let ((syn (two-way-stream-output-stream stream)))
 738                   (,fun ,(car args) syn ,@(cdr args))))))
 739   (out-fun two-way-out write-char ch)
 740   (out-fun two-way-bout write-byte n)
 741   (out-fun two-way-sout write-string-no-key string start end))
 742
 743 (macrolet ((in-fun (name fun &rest args)
 744              `(defun ,name (stream ,@args)
 745                 (force-output (two-way-stream-output-stream stream))
 746                 (,fun (two-way-stream-input-stream stream) ,@args))))
 747   (in-fun two-way-in read-char eof-error-p eof-value)
 748   (in-fun two-way-bin read-byte eof-error-p eof-value)
 749   (in-fun two-way-n-bin read-n-bytes buffer start numbytes eof-error-p))
 750
 751 (defun two-way-misc (stream operation &optional arg1 arg2)
 752   (let* ((in (two-way-stream-input-stream stream))
 753          (out (two-way-stream-output-stream stream))
 754          (in-ansi-stream-p (ansi-stream-p in))
 755          (out-ansi-stream-p (ansi-stream-p out)))
 756     (case operation
 757       (:listen
 758        (if in-ansi-stream-p
 759            (or (/= (the fixnum (ansi-stream-in-index in))
 760                    +ansi-stream-in-buffer-length+)
 761                (funcall (ansi-stream-misc in) in :listen))
 762            (stream-listen in)))
 763       ((:finish-output :force-output :clear-output)
 764        (if out-ansi-stream-p
 765            (funcall (ansi-stream-misc out) out operation arg1 arg2)
 766            (stream-misc-dispatch out operation arg1 arg2)))
 767       (:clear-input (clear-input in))
 768       (:unread (unread-char arg1 in))
 769       (:element-type
 770        (let ((in-type (stream-element-type in))
 771              (out-type (stream-element-type out)))
 772          (if (equal in-type out-type)
 773              in-type `(and ,in-type ,out-type))))
 774       (:close
 775        (set-closed-flame stream))
 776       (t
 777        (or (if in-ansi-stream-p
 778                (funcall (ansi-stream-misc in) in operation arg1 arg2)
 779                (stream-misc-dispatch in operation arg1 arg2))
 780            (if out-ansi-stream-p
 781                (funcall (ansi-stream-misc out) out operation arg1 arg2)
 782                (stream-misc-dispatch out operation arg1 arg2)))))))
 783 \f
 784 ;;;; concatenated streams
 785
 786 (defstruct (concatenated-stream
 787             (:include ansi-stream
 788                       (in #'concatenated-in)
 789                       (bin #'concatenated-bin)
 790                       (n-bin #'concatenated-n-bin)
 791                       (misc #'concatenated-misc))
 792             (:constructor %make-concatenated-stream (&rest streams))
 793             (:copier nil))
 794   ;; The car of this is the substream we are reading from now.
 795   (streams nil :type list))
 796 (def!method print-object ((x concatenated-stream) stream)
 797   (print-unreadable-object (x stream :type t :identity t)
 798     (format stream
 799             ":STREAMS ~S"
 800             (concatenated-stream-streams x))))
 801
 802 (defun make-concatenated-stream (&rest streams)
 803   #!+sb-doc
 804   "Return a stream which takes its input from each of the streams in turn,
 805    going on to the next at EOF."
 806   (dolist (stream streams)
 807     (unless (input-stream-p stream)
 808       (error 'type-error
 809              :datum stream
 810              :expected-type '(satisfies input-stream-p))))
 811   (apply #'%make-concatenated-stream streams))
 812
 813 (macrolet ((in-fun (name fun)
 814              `(defun ,name (stream eof-error-p eof-value)
 815                 (do ((streams (concatenated-stream-streams stream)
 816                               (cdr streams)))
 817                     ((null streams)
 818                      (eof-or-lose stream eof-error-p eof-value))
 819                   (let* ((stream (car streams))
 820                          (result (,fun stream nil nil)))
 821                     (when result (return result)))
 822                   (pop (concatenated-stream-streams stream))))))
 823   (in-fun concatenated-in read-char)
 824   (in-fun concatenated-bin read-byte))
 825
 826 (defun concatenated-n-bin (stream buffer start numbytes eof-errorp)
 827   (do ((streams (concatenated-stream-streams stream) (cdr streams))
 828        (current-start start)
 829        (remaining-bytes numbytes))
 830       ((null streams)
 831        (if eof-errorp
 832            (error 'end-of-file :stream stream)
 833            (- numbytes remaining-bytes)))
 834     (let* ((stream (car streams))
 835            (bytes-read (read-n-bytes stream buffer current-start
 836                                      remaining-bytes nil)))
 837       (incf current-start bytes-read)
 838       (decf remaining-bytes bytes-read)
 839       (when (zerop remaining-bytes) (return numbytes)))
 840     (setf (concatenated-stream-streams stream) (cdr streams))))
 841
 842 (defun concatenated-misc (stream operation &optional arg1 arg2)
 843   (let* ((left (concatenated-stream-streams stream))
 844          (current (car left)))
 845     (case operation
 846       (:listen
 847        (unless left
 848          (return-from concatenated-misc :eof))
 849        (loop
 850         (let ((stuff (if (ansi-stream-p current)
 851                          (funcall (ansi-stream-misc current) current
 852                                   :listen)
 853                          (stream-misc-dispatch current :listen))))
 854           (cond ((eq stuff :eof)
 855                  ;; Advance STREAMS, and try again.
 856                  (pop (concatenated-stream-streams stream))
 857                  (setf current
 858                        (car (concatenated-stream-streams stream)))
 859                  (unless current
 860                    ;; No further streams. EOF.
 861                    (return :eof)))
 862                 (stuff
 863                  ;; Stuff's available.
 864                  (return t))
 865                 (t
 866                  ;; Nothing is available yet.
 867                  (return nil))))))
 868       (:clear-input (when left (clear-input current)))
 869       (:unread (when left (unread-char arg1 current)))
 870       (:close
 871        (set-closed-flame stream))
 872       (t
 873        (when left
 874          (if (ansi-stream-p current)
 875              (funcall (ansi-stream-misc current) current operation arg1 arg2)
 876              (stream-misc-dispatch current operation arg1 arg2)))))))
 877 \f
 878 ;;;; echo streams
 879
 880 (defstruct (echo-stream
 881             (:include two-way-stream
 882                       (in #'echo-in)
 883                       (bin #'echo-bin)
 884                       (misc #'echo-misc)
 885                       (n-bin #'echo-n-bin))
 886             (:constructor %make-echo-stream (input-stream output-stream))
 887             (:copier nil))
 888   unread-stuff)
 889 (def!method print-object ((x echo-stream) stream)
 890   (print-unreadable-object (x stream :type t :identity t)
 891     (format stream
 892             ":INPUT-STREAM ~S :OUTPUT-STREAM ~S"
 893             (two-way-stream-input-stream x)
 894             (two-way-stream-output-stream x))))
 895
 896 (defun make-echo-stream (input-stream output-stream)
 897   #!+sb-doc
 898   "Return a bidirectional stream which gets its input from INPUT-STREAM and
 899    sends its output to OUTPUT-STREAM. In addition, all input is echoed to
 900    the output stream."
 901   (unless (output-stream-p output-stream)
 902     (error 'type-error
 903            :datum output-stream
 904            :expected-type '(satisfies output-stream-p)))
 905   (unless (input-stream-p input-stream)
 906     (error 'type-error
 907            :datum input-stream
 908            :expected-type '(satisfies input-stream-p)))
 909   (funcall #'%make-echo-stream input-stream output-stream))
 910
 911 (macrolet ((in-fun (name in-fun out-fun &rest args)
 912              `(defun ,name (stream ,@args)
 913                 (or (pop (echo-stream-unread-stuff stream))
 914                     (let* ((in (echo-stream-input-stream stream))
 915                            (out (echo-stream-output-stream stream))
 916                            (result (if eof-error-p
 917                                        (,in-fun in ,@args)
 918                                        (,in-fun in nil in))))
 919                       (cond
 920                         ((eql result in) eof-value)
 921                         (t (,out-fun result out) result)))))))
 922   (in-fun echo-in read-char write-char eof-error-p eof-value)
 923   (in-fun echo-bin read-byte write-byte eof-error-p eof-value))
 924
 925 (defun echo-n-bin (stream buffer start numbytes eof-error-p)
 926   (let ((new-start start)
 927         (read 0))
 928     (loop
 929      (let ((thing (pop (echo-stream-unread-stuff stream))))
 930        (cond
 931          (thing
 932           (setf (aref buffer new-start) thing)
 933           (incf new-start)
 934           (incf read)
 935           (when (= read numbytes)
 936             (return-from echo-n-bin numbytes)))
 937          (t (return nil)))))
 938     (let ((bytes-read (read-n-bytes (echo-stream-input-stream stream) buffer
 939                                     new-start (- numbytes read) nil)))
 940       (cond
 941         ((not eof-error-p)
 942          (write-sequence buffer (echo-stream-output-stream stream)
 943                          :start new-start :end (+ new-start bytes-read))
 944          (+ bytes-read read))
 945         ((> numbytes (+ read bytes-read))
 946          (write-sequence buffer (echo-stream-output-stream stream)
 947                          :start new-start :end (+ new-start bytes-read))
 948          (error 'end-of-file :stream stream))
 949         (t
 950          (write-sequence buffer (echo-stream-output-stream stream)
 951                          :start new-start :end (+ new-start bytes-read))
 952          (aver (= numbytes (+ new-start bytes-read)))
 953          numbytes)))))
 954 \f
 955 ;;;; base STRING-STREAM stuff
 956
 957 (defstruct (string-stream
 958              (:include ansi-stream)
 959              (:constructor nil)
 960              (:copier nil))
 961   ;; FIXME: This type declaration is true, and will probably continue
 962   ;; to be true.  However, note well the comments in DEFTRANSFORM
 963   ;; REPLACE, implying that performance of REPLACE is somewhat
 964   ;; critical to performance of string streams.  If (VECTOR CHARACTER)
 965   ;; ever becomes different from (VECTOR BASE-CHAR), the transform
 966   ;; probably needs to be extended.
 967   (string (missing-arg) :type (vector character)))
 968 \f
 969 ;;;; STRING-INPUT-STREAM stuff
 970
 971 (defstruct (string-input-stream
 972              (:include string-stream
 973                        (in #'string-inch)
 974                        (bin #'ill-bin)
 975                        (n-bin #'string-stream-read-n-bytes)
 976                        (misc #'string-in-misc)
 977                        (string (missing-arg) :type simple-string))
 978              (:constructor internal-make-string-input-stream
 979                            (string current end))
 980              (:copier nil))
 981   (current (missing-arg) :type index)
 982   (end (missing-arg) :type index))
 983
 984 (defun string-inch (stream eof-error-p eof-value)
 985   (declare (type string-input-stream stream))
 986   (let ((string (string-input-stream-string stream))
 987         (index (string-input-stream-current stream)))
 988     (cond ((>= index (the index (string-input-stream-end stream)))
 989            (eof-or-lose stream eof-error-p eof-value))
 990           (t
 991            (setf (string-input-stream-current stream) (1+ index))
 992            (char string index)))))
 993
 994 (defun string-binch (stream eof-error-p eof-value)
 995   (declare (type string-input-stream stream))
 996   (let ((string (string-input-stream-string stream))
 997         (index (string-input-stream-current stream)))
 998     (cond ((>= index (the index (string-input-stream-end stream)))
 999            (eof-or-lose stream eof-error-p eof-value))
1000           (t
1001            (setf (string-input-stream-current stream) (1+ index))
1002            (char-code (char string index))))))
1003
1004 (defun string-stream-read-n-bytes (stream buffer start requested eof-error-p)
1005   (declare (type string-input-stream stream)
1006            (type index start requested))
1007   (let* ((string (string-input-stream-string stream))
1008          (index (string-input-stream-current stream))
1009          (available (- (string-input-stream-end stream) index))
1010          (copy (min available requested)))
1011     (declare (type simple-string string))
1012     (when (plusp copy)
1013       (setf (string-input-stream-current stream)
1014             (truly-the index (+ index copy)))
1015       (sb!sys:without-gcing
1016        (system-area-copy (vector-sap string)
1017                          (* index sb!vm:n-byte-bits)
1018                          (if (typep buffer 'system-area-pointer)
1019                              buffer
1020                              (vector-sap buffer))
1021                          (* start sb!vm:n-byte-bits)
1022                          (* copy sb!vm:n-byte-bits))))
1023     (if (and (> requested copy) eof-error-p)
1024         (error 'end-of-file :stream stream)
1025         copy)))
1026
1027 (defun string-in-misc (stream operation &optional arg1 arg2)
1028   (declare (type string-input-stream stream)
1029            (ignore arg2))
1030   (case operation
1031     (:file-position
1032      (if arg1
1033          (setf (string-input-stream-current stream)
1034                (case arg1
1035                  (:start 0)
1036                  (:end (string-input-stream-end stream))
1037                  ;; We allow moving position beyond EOF. Errors happen
1038                  ;; on read, not move -- or the user may extend the
1039                  ;; input string.
1040                  (t arg1)))
1041          (string-input-stream-current stream)))
1042     ;; According to ANSI: "Should signal an error of type type-error
1043     ;; if stream is not a stream associated with a file."
1044     ;; This is checked by FILE-LENGTH, so no need to do it here either.
1045     ;; (:file-length (length (string-input-stream-string stream)))
1046     (:unread (decf (string-input-stream-current stream)))
1047     (:close (set-closed-flame stream))
1048     (:listen (or (/= (the index (string-input-stream-current stream))
1049                      (the index (string-input-stream-end stream)))
1050                  :eof))
1051     (:element-type (array-element-type (string-input-stream-string stream)))))
1052
1053 (defun make-string-input-stream (string &optional (start 0) end)
1054   #!+sb-doc
1055   "Return an input stream which will supply the characters of STRING between
1056   START and END in order."
1057   (declare (type string string)
1058            (type index start)
1059            (type (or index null) end))
1060   (let* ((string (coerce string '(simple-array character (*))))
1061          (end (%check-vector-sequence-bounds string start end)))
1062     (with-array-data ((string string) (start start) (end end))
1063       (internal-make-string-input-stream
1064        string ;; now simple
1065        start
1066        end))))
1067 \f
1068 ;;;; STRING-OUTPUT-STREAM stuff
1069
1070 (defstruct (string-output-stream
1071             (:include string-stream
1072                       (out #'string-ouch)
1073                       (sout #'string-sout)
1074                       (misc #'string-out-misc)
1075                       ;; The string we throw stuff in.
1076                       (string (missing-arg)
1077                               :type (simple-array character (*))))
1078             (:constructor make-string-output-stream
1079                           (&key (element-type 'character)
1080                            &aux (string (make-string 40))))
1081             (:copier nil))
1082   ;; Index of the next location to use.
1083   (index 0 :type fixnum)
1084   ;; Index cache for string-output-stream-last-index
1085   (index-cache 0 :type fixnum)
1086   ;; Requested element type
1087   (element-type 'character))
1088
1089 #!+sb-doc
1090 (setf (fdocumentation 'make-string-output-stream 'function)
1091   "Return an output stream which will accumulate all output given it for
1092    the benefit of the function GET-OUTPUT-STREAM-STRING.")
1093
1094 (defun string-output-stream-last-index (stream)
1095   (max (string-output-stream-index stream)
1096        (string-output-stream-index-cache stream)))
1097
1098 (defun string-ouch (stream character)
1099   (let ((current (string-output-stream-index stream))
1100         (workspace (string-output-stream-string stream)))
1101     (declare (type (simple-array character (*)) workspace)
1102              (type fixnum current))
1103     (if (= current (the fixnum (length workspace)))
1104         (let ((new-workspace (make-string (* current 2))))
1105           (replace new-workspace workspace)
1106           (setf (aref new-workspace current) character
1107                 (string-output-stream-string stream) new-workspace))
1108         (setf (aref workspace current) character))
1109     (setf (string-output-stream-index stream) (1+ current))))
1110
1111 (defun string-sout (stream string start end)
1112   (declare (type simple-string string)
1113            (type fixnum start end))
1114   (let* ((string (if (typep string '(simple-array character (*)))
1115                      string
1116                      (coerce string '(simple-array character (*)))))
1117          (current (string-output-stream-index stream))
1118          (length (- end start))
1119          (dst-end (+ length current))
1120          (workspace (string-output-stream-string stream)))
1121     (declare (type (simple-array character (*)) workspace string)
1122              (type fixnum current length dst-end))
1123     (if (> dst-end (the fixnum (length workspace)))
1124         (let ((new-workspace (make-string (+ (* current 2) length))))
1125           (replace new-workspace workspace :end2 current)
1126           (replace new-workspace string
1127                    :start1 current :end1 dst-end
1128                    :start2 start :end2 end)
1129           (setf (string-output-stream-string stream) new-workspace))
1130         (replace workspace string
1131                  :start1 current :end1 dst-end
1132                  :start2 start :end2 end))
1133     (setf (string-output-stream-index stream) dst-end)))
1134
1135 (defun string-out-misc (stream operation &optional arg1 arg2)
1136   (declare (ignore arg2))
1137   (case operation
1138     (:file-position
1139      (if arg1
1140          (let ((end (string-output-stream-last-index stream)))
1141            (setf (string-output-stream-index-cache stream) end
1142                  (string-output-stream-index stream)
1143                  (case arg1
1144                    (:start 0)
1145                    (:end end)
1146                    (t
1147                     ;; We allow moving beyond the end of stream,
1148                     ;; implicitly extending the output stream.
1149                     (let ((buffer (string-output-stream-string stream)))
1150                       (when (> arg1 (length buffer))
1151                         (setf (string-output-stream-string stream)
1152                               (make-string
1153                                arg1 :element-type (array-element-type buffer))
1154                               (subseq (string-output-stream-string stream)
1155                                       0 end)
1156                               (subseq buffer 0 end))))
1157                       arg1))))
1158          (string-output-stream-index stream)))
1159     (:close (set-closed-flame stream))
1160     (:charpos
1161      (do ((index (1- (the fixnum (string-output-stream-index stream)))
1162                  (1- index))
1163           (count 0 (1+ count))
1164           (string (string-output-stream-string stream)))
1165          ((< index 0) count)
1166        (declare (type (simple-array character (*)) string)
1167                 (type fixnum index count))
1168        (if (char= (schar string index) #\newline)
1169            (return count))))
1170     (:element-type (array-element-type (string-output-stream-string stream)))))
1171
1172 ;;; Return a string of all the characters sent to a stream made by
1173 ;;; MAKE-STRING-OUTPUT-STREAM since the last call to this function.
1174 (defun get-output-stream-string (stream)
1175   (declare (type string-output-stream stream))
1176   (let* ((length (string-output-stream-last-index stream))
1177          (element-type (string-output-stream-element-type stream))
1178          (result
1179           (case element-type
1180             ;; Overwhelmingly common case; can be inlined.
1181             ((character) (make-string length))
1182             (t (make-string length :element-type element-type)))))
1183     ;; For the benefit of the REPLACE transform, let's do this, so
1184     ;; that the common case isn't ludicrously expensive.
1185     (etypecase result
1186       ((simple-array character (*))
1187        (replace result (string-output-stream-string stream)))
1188       ((simple-array nil (*))
1189        (replace result (string-output-stream-string stream))))
1190     (setf (string-output-stream-index stream) 0
1191           (string-output-stream-index-cache stream) 0)
1192     result))
1193
1194 ;;; Dump the characters buffer up in IN-STREAM to OUT-STREAM as
1195 ;;; GET-OUTPUT-STREAM-STRING would return them.
1196 (defun dump-output-stream-string (in-stream out-stream)
1197   (%write-string (string-output-stream-string in-stream)
1198                  out-stream
1199                  0
1200                  (string-output-stream-last-index in-stream))
1201   (setf (string-output-stream-index in-stream) 0
1202         (string-output-stream-index-cache in-stream) 0))
1203 \f
1204 ;;;; fill-pointer streams
1205
1206 ;;; Fill pointer STRING-OUTPUT-STREAMs are not explicitly mentioned in
1207 ;;; the CLM, but they are required for the implementation of
1208 ;;; WITH-OUTPUT-TO-STRING.
1209
1210 (deftype string-with-fill-pointer ()
1211   '(and (vector character)
1212         (satisfies array-has-fill-pointer-p)))
1213
1214 (defstruct (fill-pointer-output-stream
1215             (:include string-stream
1216                       (out #'fill-pointer-ouch)
1217                       (sout #'fill-pointer-sout)
1218                       (misc #'fill-pointer-misc)
1219                       ;; a string with a fill pointer where we stuff
1220                       ;; the stuff we write
1221                       (string (missing-arg)
1222                               :type string-with-fill-pointer
1223                               :read-only t))
1224             (:constructor make-fill-pointer-output-stream (string))
1225             (:copier nil)))
1226
1227 (defun fill-pointer-ouch (stream character)
1228   (let* ((buffer (fill-pointer-output-stream-string stream))
1229          (current (fill-pointer buffer))
1230          (current+1 (1+ current)))
1231     (declare (fixnum current))
1232     (with-array-data ((workspace buffer) (start) (end))
1233       (declare (type (simple-array character (*)) workspace))
1234       (let ((offset-current (+ start current)))
1235         (declare (fixnum offset-current))
1236         (if (= offset-current end)
1237             (let* ((new-length (1+ (* current 2)))
1238                    (new-workspace (make-string new-length)))
1239               (declare (simple-string new-workspace))
1240               (%byte-blt workspace start
1241                          new-workspace 0 current)
1242               (setf workspace new-workspace
1243                     offset-current current)
1244               (set-array-header buffer workspace new-length
1245                                 current+1 0 new-length nil))
1246             (setf (fill-pointer buffer) current+1))
1247         (setf (schar workspace offset-current) character)))
1248     current+1))
1249
1250 (defun fill-pointer-sout (stream string start end)
1251   (declare (simple-string string) (fixnum start end))
1252   (let* ((string (if (typep string '(simple-array character (*)))
1253                      string
1254                      (coerce string '(simple-array character (*)))))
1255          (buffer (fill-pointer-output-stream-string stream))
1256          (current (fill-pointer buffer))
1257          (string-len (- end start))
1258          (dst-end (+ string-len current)))
1259     (declare (fixnum current dst-end string-len))
1260     (with-array-data ((workspace buffer) (dst-start) (dst-length))
1261       (declare (type (simple-array character (*)) workspace))
1262       (let ((offset-dst-end (+ dst-start dst-end))
1263             (offset-current (+ dst-start current)))
1264         (declare (fixnum offset-dst-end offset-current))
1265         (if (> offset-dst-end dst-length)
1266             (let* ((new-length (+ (the fixnum (* current 2)) string-len))
1267                    (new-workspace (make-string new-length)))
1268               (declare (type (simple-array character (*)) new-workspace))
1269               (%byte-blt workspace dst-start
1270                          new-workspace 0 current)
1271               (setf workspace new-workspace)
1272               (setf offset-current current)
1273               (setf offset-dst-end dst-end)
1274               (set-array-header buffer
1275                                 workspace
1276                                 new-length
1277                                 dst-end
1278                                 0
1279                                 new-length
1280                                 nil))
1281             (setf (fill-pointer buffer) dst-end))
1282         (%byte-blt string start
1283                    workspace offset-current offset-dst-end)))
1284     dst-end))
1285
1286 (defun fill-pointer-misc (stream operation &optional arg1 arg2)
1287   (declare (ignore arg2))
1288   (case operation
1289     (:file-position
1290      (let ((buffer (fill-pointer-output-stream-string stream)))
1291        (if arg1
1292            (setf (fill-pointer buffer)
1293                  (case arg1
1294                    (:start 0)
1295                    ;; Fill-pointer is always at fill-pointer we will
1296                    ;; make :END move to the end of the actual string.
1297                    (:end (array-total-size buffer))
1298                    ;; We allow moving beyond the end of string if the
1299                    ;; string is adjustable.
1300                    (t (when (>= arg1 (array-total-size buffer))
1301                         (if (adjustable-array-p buffer)
1302                             (adjust-array buffer arg1)
1303                             (error "Cannot move FILE-POSITION beyond the end ~
1304                                     of WITH-OUTPUT-TO-STRING stream ~
1305                                     constructed with non-adjustable string.")))
1306                       arg1)))
1307            (fill-pointer buffer))))
1308     (:charpos
1309      (let* ((buffer (fill-pointer-output-stream-string stream))
1310             (current (fill-pointer buffer)))
1311        (with-array-data ((string buffer) (start) (end current))
1312          (declare (simple-string string) (ignore start))
1313          (let ((found (position #\newline string :test #'char=
1314                                 :end end :from-end t)))
1315            (if found
1316                (- end (the fixnum found))
1317                current)))))
1318      (:element-type (array-element-type
1319                      (fill-pointer-output-stream-string stream)))))
1320 \f
1321 ;;;; indenting streams
1322
1323 (defstruct (indenting-stream (:include ansi-stream
1324                                        (out #'indenting-out)
1325                                        (sout #'indenting-sout)
1326                                        (misc #'indenting-misc))
1327                              (:constructor make-indenting-stream (stream))
1328                              (:copier nil))
1329   ;; the stream we're based on
1330   stream
1331   ;; how much we indent on each line
1332   (indentation 0))
1333
1334 #!+sb-doc
1335 (setf (fdocumentation 'make-indenting-stream 'function)
1336  "Return an output stream which indents its output by some amount.")
1337
1338 ;;; INDENTING-INDENT writes the correct number of spaces needed to indent
1339 ;;; output on the given STREAM based on the specified SUB-STREAM.
1340 (defmacro indenting-indent (stream sub-stream)
1341   ;; KLUDGE: bare magic number 60
1342   `(do ((i 0 (+ i 60))
1343         (indentation (indenting-stream-indentation ,stream)))
1344        ((>= i indentation))
1345      (%write-string
1346       "                                                     "
1347       ,sub-stream
1348       0
1349       (min 60 (- indentation i)))))
1350
1351 ;;; INDENTING-OUT writes a character to an indenting stream.
1352 (defun indenting-out (stream char)
1353   (let ((sub-stream (indenting-stream-stream stream)))
1354     (write-char char sub-stream)
1355     (if (char= char #\newline)
1356         (indenting-indent stream sub-stream))))
1357
1358 ;;; INDENTING-SOUT writes a string to an indenting stream.
1359 (defun indenting-sout (stream string start end)
1360   (declare (simple-string string) (fixnum start end))
1361   (do ((i start)
1362        (sub-stream (indenting-stream-stream stream)))
1363       ((= i end))
1364     (let ((newline (position #\newline string :start i :end end)))
1365       (cond (newline
1366              (%write-string string sub-stream i (1+ newline))
1367              (indenting-indent stream sub-stream)
1368              (setq i (+ newline 1)))
1369             (t
1370              (%write-string string sub-stream i end)
1371              (setq i end))))))
1372
1373 ;;; INDENTING-MISC just treats just the :LINE-LENGTH message
1374 ;;; differently. INDENTING-CHARPOS says the charpos is the charpos of
1375 ;;; the base stream minus the stream's indentation.
1376 (defun indenting-misc (stream operation &optional arg1 arg2)
1377   (let ((sub-stream (indenting-stream-stream stream)))
1378     (if (ansi-stream-p sub-stream)
1379         (let ((method (ansi-stream-misc sub-stream)))
1380           (case operation
1381             (:line-length
1382              (let ((line-length (funcall method sub-stream operation)))
1383                (if line-length
1384                    (- line-length (indenting-stream-indentation stream)))))
1385             (:charpos
1386              (let ((charpos (funcall method sub-stream operation)))
1387                (if charpos
1388                    (- charpos (indenting-stream-indentation stream)))))
1389             (t
1390              (funcall method sub-stream operation arg1 arg2))))
1391         ;; must be Gray streams FUNDAMENTAL-STREAM
1392         (case operation
1393           (:line-length
1394            (let ((line-length (stream-line-length sub-stream)))
1395              (if line-length
1396                  (- line-length (indenting-stream-indentation stream)))))
1397           (:charpos
1398            (let ((charpos (stream-line-column sub-stream)))
1399              (if charpos
1400                  (- charpos (indenting-stream-indentation stream)))))
1401           (t
1402            (stream-misc-dispatch sub-stream operation arg1 arg2))))))
1403
1404 (declaim (maybe-inline read-char unread-char read-byte listen))
1405 \f
1406 ;;;; case frobbing streams, used by FORMAT ~(...~)
1407
1408 (defstruct (case-frob-stream
1409             (:include ansi-stream
1410                       (misc #'case-frob-misc))
1411             (:constructor %make-case-frob-stream (target out sout))
1412             (:copier nil))
1413   (target (missing-arg) :type stream))
1414
1415 (defun make-case-frob-stream (target kind)
1416   #!+sb-doc
1417   "Return a stream that sends all output to the stream TARGET, but modifies
1418    the case of letters, depending on KIND, which should be one of:
1419      :upcase - convert to upper case.
1420      :downcase - convert to lower case.
1421      :capitalize - convert the first letter of words to upper case and the
1422         rest of the word to lower case.
1423      :capitalize-first - convert the first letter of the first word to upper
1424         case and everything else to lower case."
1425   (declare (type stream target)
1426            (type (member :upcase :downcase :capitalize :capitalize-first)
1427                  kind)
1428            (values stream))
1429   (if (case-frob-stream-p target)
1430       ;; If we are going to be writing to a stream that already does
1431       ;; case frobbing, why bother frobbing the case just so it can
1432       ;; frob it again?
1433       target
1434       (multiple-value-bind (out sout)
1435           (ecase kind
1436             (:upcase
1437              (values #'case-frob-upcase-out
1438                      #'case-frob-upcase-sout))
1439             (:downcase
1440              (values #'case-frob-downcase-out
1441                      #'case-frob-downcase-sout))
1442             (:capitalize
1443              (values #'case-frob-capitalize-out
1444                      #'case-frob-capitalize-sout))
1445             (:capitalize-first
1446              (values #'case-frob-capitalize-first-out
1447                      #'case-frob-capitalize-first-sout)))
1448         (%make-case-frob-stream target out sout))))
1449
1450 (defun case-frob-misc (stream op &optional arg1 arg2)
1451   (declare (type case-frob-stream stream))
1452   (case op
1453     (:close
1454      (set-closed-flame stream))
1455     (t
1456      (let ((target (case-frob-stream-target stream)))
1457        (if (ansi-stream-p target)
1458            (funcall (ansi-stream-misc target) target op arg1 arg2)
1459            (stream-misc-dispatch target op arg1 arg2))))))
1460
1461 (defun case-frob-upcase-out (stream char)
1462   (declare (type case-frob-stream stream)
1463            (type base-char char))
1464   (let ((target (case-frob-stream-target stream))
1465         (char (char-upcase char)))
1466     (if (ansi-stream-p target)
1467         (funcall (ansi-stream-out target) target char)
1468         (stream-write-char target char))))
1469
1470 (defun case-frob-upcase-sout (stream str start end)
1471   (declare (type case-frob-stream stream)
1472            (type simple-base-string str)
1473            (type index start)
1474            (type (or index null) end))
1475   (let* ((target (case-frob-stream-target stream))
1476          (len (length str))
1477          (end (or end len))
1478          (string (if (and (zerop start) (= len end))
1479                      (string-upcase str)
1480                      (nstring-upcase (subseq str start end))))
1481          (string-len (- end start)))
1482     (if (ansi-stream-p target)
1483         (funcall (ansi-stream-sout target) target string 0 string-len)
1484         (stream-write-string target string 0 string-len))))
1485
1486 (defun case-frob-downcase-out (stream char)
1487   (declare (type case-frob-stream stream)
1488            (type base-char char))
1489   (let ((target (case-frob-stream-target stream))
1490         (char (char-downcase char)))
1491     (if (ansi-stream-p target)
1492         (funcall (ansi-stream-out target) target char)
1493         (stream-write-char target char))))
1494
1495 (defun case-frob-downcase-sout (stream str start end)
1496   (declare (type case-frob-stream stream)
1497            (type simple-base-string str)
1498            (type index start)
1499            (type (or index null) end))
1500   (let* ((target (case-frob-stream-target stream))
1501          (len (length str))
1502          (end (or end len))
1503          (string (if (and (zerop start) (= len end))
1504                      (string-downcase str)
1505                      (nstring-downcase (subseq str start end))))
1506          (string-len (- end start)))
1507     (if (ansi-stream-p target)
1508         (funcall (ansi-stream-sout target) target string 0 string-len)
1509         (stream-write-string target string 0 string-len))))
1510
1511 (defun case-frob-capitalize-out (stream char)
1512   (declare (type case-frob-stream stream)
1513            (type base-char char))
1514   (let ((target (case-frob-stream-target stream)))
1515     (cond ((alphanumericp char)
1516            (let ((char (char-upcase char)))
1517              (if (ansi-stream-p target)
1518                  (funcall (ansi-stream-out target) target char)
1519                  (stream-write-char target char)))
1520            (setf (case-frob-stream-out stream) #'case-frob-capitalize-aux-out)
1521            (setf (case-frob-stream-sout stream)
1522                  #'case-frob-capitalize-aux-sout))
1523           (t
1524            (if (ansi-stream-p target)
1525                (funcall (ansi-stream-out target) target char)
1526                (stream-write-char target char))))))
1527
1528 (defun case-frob-capitalize-sout (stream str start end)
1529   (declare (type case-frob-stream stream)
1530            (type simple-base-string str)
1531            (type index start)
1532            (type (or index null) end))
1533   (let* ((target (case-frob-stream-target stream))
1534          (str (subseq str start end))
1535          (len (length str))
1536          (inside-word nil))
1537     (dotimes (i len)
1538       (let ((char (schar str i)))
1539         (cond ((not (alphanumericp char))
1540                (setf inside-word nil))
1541               (inside-word
1542                (setf (schar str i) (char-downcase char)))
1543               (t
1544                (setf inside-word t)
1545                (setf (schar str i) (char-upcase char))))))
1546     (when inside-word
1547       (setf (case-frob-stream-out stream)
1548             #'case-frob-capitalize-aux-out)
1549       (setf (case-frob-stream-sout stream)
1550             #'case-frob-capitalize-aux-sout))
1551     (if (ansi-stream-p target)
1552         (funcall (ansi-stream-sout target) target str 0 len)
1553         (stream-write-string target str 0 len))))
1554
1555 (defun case-frob-capitalize-aux-out (stream char)
1556   (declare (type case-frob-stream stream)
1557            (type base-char char))
1558   (let ((target (case-frob-stream-target stream)))
1559     (cond ((alphanumericp char)
1560            (let ((char (char-downcase char)))
1561              (if (ansi-stream-p target)
1562                  (funcall (ansi-stream-out target) target char)
1563                  (stream-write-char target char))))
1564           (t
1565            (if (ansi-stream-p target)
1566                (funcall (ansi-stream-out target) target char)
1567                (stream-write-char target char))
1568            (setf (case-frob-stream-out stream)
1569                  #'case-frob-capitalize-out)
1570            (setf (case-frob-stream-sout stream)
1571                  #'case-frob-capitalize-sout)))))
1572
1573 (defun case-frob-capitalize-aux-sout (stream str start end)
1574   (declare (type case-frob-stream stream)
1575            (type simple-base-string str)
1576            (type index start)
1577            (type (or index null) end))
1578   (let* ((target (case-frob-stream-target stream))
1579          (str (subseq str start end))
1580          (len (length str))
1581          (inside-word t))
1582     (dotimes (i len)
1583       (let ((char (schar str i)))
1584         (cond ((not (alphanumericp char))
1585                (setf inside-word nil))
1586               (inside-word
1587                (setf (schar str i) (char-downcase char)))
1588               (t
1589                (setf inside-word t)
1590                (setf (schar str i) (char-upcase char))))))
1591     (unless inside-word
1592       (setf (case-frob-stream-out stream)
1593             #'case-frob-capitalize-out)
1594       (setf (case-frob-stream-sout stream)
1595             #'case-frob-capitalize-sout))
1596     (if (ansi-stream-p target)
1597         (funcall (ansi-stream-sout target) target str 0 len)
1598         (stream-write-string target str 0 len))))
1599
1600 (defun case-frob-capitalize-first-out (stream char)
1601   (declare (type case-frob-stream stream)
1602            (type base-char char))
1603   (let ((target (case-frob-stream-target stream)))
1604     (cond ((alphanumericp char)
1605            (let ((char (char-upcase char)))
1606              (if (ansi-stream-p target)
1607                  (funcall (ansi-stream-out target) target char)
1608                  (stream-write-char target char)))
1609            (setf (case-frob-stream-out stream)
1610                  #'case-frob-downcase-out)
1611            (setf (case-frob-stream-sout stream)
1612                  #'case-frob-downcase-sout))
1613           (t
1614            (if (ansi-stream-p target)
1615                (funcall (ansi-stream-out target) target char)
1616                (stream-write-char target char))))))
1617
1618 (defun case-frob-capitalize-first-sout (stream str start end)
1619   (declare (type case-frob-stream stream)
1620            (type simple-base-string str)
1621            (type index start)
1622            (type (or index null) end))
1623   (let* ((target (case-frob-stream-target stream))
1624          (str (subseq str start end))
1625          (len (length str)))
1626     (dotimes (i len)
1627       (let ((char (schar str i)))
1628         (when (alphanumericp char)
1629           (setf (schar str i) (char-upcase char))
1630           (do ((i (1+ i) (1+ i)))
1631               ((= i len))
1632             (setf (schar str i) (char-downcase (schar str i))))
1633           (setf (case-frob-stream-out stream)
1634                 #'case-frob-downcase-out)
1635           (setf (case-frob-stream-sout stream)
1636                 #'case-frob-downcase-sout)
1637           (return))))
1638     (if (ansi-stream-p target)
1639         (funcall (ansi-stream-sout target) target str 0 len)
1640         (stream-write-string target str 0 len))))
1641 \f
1642 ;;;; READ-SEQUENCE
1643
1644 (defun read-sequence (seq stream &key (start 0) end)
1645   #!+sb-doc
1646   "Destructively modify SEQ by reading elements from STREAM.
1647   That part of SEQ bounded by START and END is destructively modified by
1648   copying successive elements into it from STREAM. If the end of file
1649   for STREAM is reached before copying all elements of the subsequence,
1650   then the extra elements near the end of sequence are not updated, and
1651   the index of the next element is returned."
1652   (declare (type sequence seq)
1653            (type stream stream)
1654            (type index start)
1655            (type sequence-end end)
1656            (values index))
1657   (if (ansi-stream-p stream)
1658       (ansi-stream-read-sequence seq stream start end)
1659       ;; must be Gray streams FUNDAMENTAL-STREAM
1660       (stream-read-sequence stream seq start end)))
1661
1662 (defun ansi-stream-read-sequence (seq stream start %end)
1663   (declare (type sequence seq)
1664            (type ansi-stream stream)
1665            (type index start)
1666            (type sequence-end %end)
1667            (values index))
1668   (let ((end (or %end (length seq))))
1669     (declare (type index end))
1670     (etypecase seq
1671       (list
1672        (let ((read-function
1673               (if (subtypep (stream-element-type stream) 'character)
1674                   #'read-char
1675                   #'read-byte)))
1676          (do ((rem (nthcdr start seq) (rest rem))
1677               (i start (1+ i)))
1678              ((or (endp rem) (>= i end)) i)
1679            (declare (type list rem)
1680                     (type index i))
1681            (let ((el (funcall read-function stream nil :eof)))
1682              (when (eq el :eof)
1683                (return i))
1684              (setf (first rem) el)))))
1685       (vector
1686        (with-array-data ((data seq) (offset-start start) (offset-end end))
1687          (typecase data
1688            ((or (simple-array (unsigned-byte 8) (*))
1689                 (simple-array (signed-byte 8) (*))
1690                 simple-string)
1691             (let* ((numbytes (- end start))
1692                    (bytes-read (read-n-bytes stream data offset-start
1693                                              numbytes nil)))
1694               (if (< bytes-read numbytes)
1695                   (+ start bytes-read)
1696                   end)))
1697            (t
1698             (let ((read-function
1699                    (if (subtypep (stream-element-type stream) 'character)
1700                        #'read-char
1701                        #'read-byte)))
1702               (do ((i offset-start (1+ i)))
1703                   ((>= i offset-end) end)
1704                 (declare (type index i))
1705                 (let ((el (funcall read-function stream nil :eof)))
1706                   (when (eq el :eof)
1707                     (return (+ start (- i offset-start))))
1708                   (setf (aref data i) el)))))))))))
1709 \f
1710 ;;;; WRITE-SEQUENCE
1711
1712 (defun write-sequence (seq stream &key (start 0) (end nil))
1713   #!+sb-doc
1714   "Write the elements of SEQ bounded by START and END to STREAM."
1715   (declare (type sequence seq)
1716            (type stream stream)
1717            (type index start)
1718            (type sequence-end end)
1719            (values sequence))
1720   (if (ansi-stream-p stream)
1721       (ansi-stream-write-sequence seq stream start end)
1722       ;; must be Gray-streams FUNDAMENTAL-STREAM
1723       (stream-write-sequence stream seq start end)))
1724
1725 (defun ansi-stream-write-sequence (seq stream start %end)
1726   (declare (type sequence seq)
1727            (type ansi-stream stream)
1728            (type index start)
1729            (type sequence-end %end)
1730            (values sequence))
1731   (let ((end (or %end (length seq))))
1732     (declare (type index end))
1733     (etypecase seq
1734       (list
1735        (let ((write-function
1736               (if (subtypep (stream-element-type stream) 'character)
1737                   #'write-char
1738                   #'write-byte)))
1739          (do ((rem (nthcdr start seq) (rest rem))
1740               (i start (1+ i)))
1741              ((or (endp rem) (>= i end)) seq)
1742            (declare (type list rem)
1743                     (type index i))
1744            (funcall write-function (first rem) stream))))
1745       (string
1746        (%write-string seq stream start end))
1747       (vector
1748        (let ((write-function
1749               (if (subtypep (stream-element-type stream) 'character)
1750                   #'write-char
1751                   #'write-byte)))
1752          (do ((i start (1+ i)))
1753              ((>= i end) seq)
1754            (declare (type index i))
1755            (funcall write-function (aref seq i) stream)))))))
1756 \f
1757 ;;;; etc.