src/code/stream.lisp

   1 ;;;; os-independent stream functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 ;;;; standard streams
  15
  16 ;;; The initialization of these streams is performed by
  17 ;;; STREAM-COLD-INIT-OR-RESET.
  18 (defvar *terminal-io* () #!+sb-doc "terminal I/O stream")
  19 (defvar *standard-input* () #!+sb-doc "default input stream")
  20 (defvar *standard-output* () #!+sb-doc "default output stream")
  21 (defvar *error-output* () #!+sb-doc "error output stream")
  22 (defvar *query-io* () #!+sb-doc "query I/O stream")
  23 (defvar *trace-output* () #!+sb-doc "trace output stream")
  24 (defvar *debug-io* () #!+sb-doc "interactive debugging stream")
  25
  26 (defun ill-in (stream &rest ignore)
  27   (declare (ignore ignore))
  28   (error 'simple-type-error
  29          :datum stream
  30          :expected-type '(satisfies input-stream-p)
  31          :format-control "~S is not a character input stream."
  32          :format-arguments (list stream)))
  33 (defun ill-out (stream &rest ignore)
  34   (declare (ignore ignore))
  35   (error 'simple-type-error
  36          :datum stream
  37          :expected-type '(satisfies output-stream-p)
  38          :format-control "~S is not a character output stream."
  39          :format-arguments (list stream)))
  40 (defun ill-bin (stream &rest ignore)
  41   (declare (ignore ignore))
  42   (error 'simple-type-error
  43          :datum stream
  44          :expected-type '(satisfies input-stream-p)
  45          :format-control "~S is not a binary input stream."
  46          :format-arguments (list stream)))
  47 (defun ill-bout (stream &rest ignore)
  48   (declare (ignore ignore))
  49   (error 'simple-type-error
  50          :datum stream
  51          :expected-type '(satisfies output-stream-p)
  52          :format-control "~S is not a binary output stream."
  53          :format-arguments (list stream)))
  54 (defun closed-flame (stream &rest ignore)
  55   (declare (ignore ignore))
  56   (error "~S is closed." stream))
  57 (defun no-op-placeholder (&rest ignore)
  58   (declare (ignore ignore)))
  59 \f
  60 ;;; stream manipulation functions
  61
  62 (declaim (inline ansi-stream-input-stream-p))
  63 (defun ansi-stream-input-stream-p (stream)
  64   (declare (type ansi-stream stream))
  65
  66   (when (synonym-stream-p stream)
  67     (setf stream
  68           (symbol-value (synonym-stream-symbol stream))))
  69
  70   (and (not (eq (ansi-stream-in stream) #'closed-flame))
  71        ;;; KLUDGE: It's probably not good to have EQ tests on function
  72        ;;; values like this. What if someone's redefined the function?
  73        ;;; Is there a better way? (Perhaps just VALID-FOR-INPUT and
  74        ;;; VALID-FOR-OUTPUT flags? -- WHN 19990902
  75        (or (not (eq (ansi-stream-in stream) #'ill-in))
  76            (not (eq (ansi-stream-bin stream) #'ill-bin)))))
  77
  78 (defun input-stream-p (stream)
  79   (declare (type stream stream))
  80   (and (ansi-stream-p stream)
  81        (ansi-stream-input-stream-p stream)))
  82
  83 (declaim (inline ansi-stream-output-stream-p))
  84 (defun ansi-stream-output-stream-p (stream)
  85   (declare (type ansi-stream stream))
  86
  87   (when (synonym-stream-p stream)
  88     (setf stream (symbol-value
  89                   (synonym-stream-symbol stream))))
  90
  91   (and (not (eq (ansi-stream-in stream) #'closed-flame))
  92        (or (not (eq (ansi-stream-out stream) #'ill-out))
  93            (not (eq (ansi-stream-bout stream) #'ill-bout)))))
  94
  95 (defun output-stream-p (stream)
  96   (declare (type stream stream))
  97
  98   (and (ansi-stream-p stream)
  99        (ansi-stream-output-stream-p stream)))
 100
 101 (declaim (inline ansi-stream-open-stream-p))
 102 (defun ansi-stream-open-stream-p (stream)
 103   (declare (type ansi-stream stream))
 104   ;; CLHS 22.1.4 lets us not worry about synonym streams here.
 105   (not (eq (ansi-stream-in stream) #'closed-flame)))
 106
 107 (defun open-stream-p (stream)
 108   (ansi-stream-open-stream-p stream))
 109
 110 (declaim (inline ansi-stream-element-type))
 111 (defun ansi-stream-element-type (stream)
 112   (declare (type ansi-stream stream))
 113   (funcall (ansi-stream-misc stream) stream :element-type))
 114
 115 (defun stream-element-type (stream)
 116   (ansi-stream-element-type stream))
 117
 118 (defun interactive-stream-p (stream)
 119   (declare (type stream stream))
 120   (funcall (ansi-stream-misc stream) stream :interactive-p))
 121
 122 (declaim (inline ansi-stream-close))
 123 (defun ansi-stream-close (stream abort)
 124   (declare (type ansi-stream stream))
 125   (when (open-stream-p stream)
 126     (funcall (ansi-stream-misc stream) stream :close abort))
 127   t)
 128
 129 (defun close (stream &key abort)
 130   (ansi-stream-close stream abort))
 131
 132 (defun set-closed-flame (stream)
 133   (setf (ansi-stream-in stream) #'closed-flame)
 134   (setf (ansi-stream-bin stream) #'closed-flame)
 135   (setf (ansi-stream-n-bin stream) #'closed-flame)
 136   (setf (ansi-stream-in stream) #'closed-flame)
 137   (setf (ansi-stream-out stream) #'closed-flame)
 138   (setf (ansi-stream-bout stream) #'closed-flame)
 139   (setf (ansi-stream-sout stream) #'closed-flame)
 140   (setf (ansi-stream-misc stream) #'closed-flame))
 141 \f
 142 ;;;; file position and file length
 143
 144 ;;; Call the MISC method with the :FILE-POSITION operation.
 145 (defun file-position (stream &optional position)
 146   (declare (type stream stream))
 147   (declare (type (or index (alien sb!unix:off-t) (member nil :start :end)) position))
 148   (cond
 149    (position
 150     (setf (ansi-stream-in-index stream) +ansi-stream-in-buffer-length+)
 151     (funcall (ansi-stream-misc stream) stream :file-position position))
 152    (t
 153     (let ((res (funcall (ansi-stream-misc stream) stream :file-position nil)))
 154       (when res
 155         (- res
 156            (- +ansi-stream-in-buffer-length+
 157               (ansi-stream-in-index stream))))))))
 158
 159 ;;; This is a literal translation of the ANSI glossary entry "stream
 160 ;;; associated with a file".
 161 ;;;
 162 ;;; KLUDGE: Note that since Unix famously thinks "everything is a
 163 ;;; file", and in particular stdin, stdout, and stderr are files, we
 164 ;;; end up with this test being satisfied for weird things like
 165 ;;; *STANDARD-OUTPUT* (to a tty). That seems unlikely to be what the
 166 ;;; ANSI spec really had in mind, especially since this is used as a
 167 ;;; qualification for operations like FILE-LENGTH (so that ANSI was
 168 ;;; probably thinking of something like what Unix calls block devices)
 169 ;;; but I can't see any better way to do it. -- WHN 2001-04-14
 170 (defun stream-associated-with-file-p (x)
 171   "Test for the ANSI concept \"stream associated with a file\"."
 172   (or (typep x 'file-stream)
 173       (and (synonym-stream-p x)
 174            (stream-associated-with-file-p (symbol-value
 175                                            (synonym-stream-symbol x))))))
 176
 177 (defun stream-must-be-associated-with-file (stream)
 178   (declare (type stream stream))
 179   (unless (stream-associated-with-file-p stream)
 180     (error 'simple-type-error
 181            ;; KLUDGE: The ANSI spec for FILE-LENGTH specifically says
 182            ;; this should be TYPE-ERROR. But what then can we use for
 183            ;; EXPECTED-TYPE? This SATISFIES type (with a nonstandard
 184            ;; private predicate function..) is ugly and confusing, but
 185            ;; I can't see any other way. -- WHN 2001-04-14
 186            :expected-type '(satisfies stream-associated-with-file-p)
 187            :format-control
 188            "~@<The stream ~2I~_~S ~I~_isn't associated with a file.~:>"
 189            :format-arguments (list stream))))
 190
 191 ;;; like FILE-POSITION, only using :FILE-LENGTH
 192 (defun file-length (stream)
 193   ;; FIXME: The following declaration uses yet undefined types, which
 194   ;; cause cross-compiler hangup.
 195   ;;
 196   ;; (declare (type (or file-stream synonym-stream) stream))
 197   (stream-must-be-associated-with-file stream)
 198   (funcall (ansi-stream-misc stream) stream :file-length))
 199 \f
 200 ;;;; input functions
 201
 202 (defun read-line (&optional (stream *standard-input*) (eof-error-p t) eof-value
 203                             recursive-p)
 204   (declare (ignore recursive-p))
 205   (let ((stream (in-synonym-of stream)))
 206     (if (ansi-stream-p stream)
 207         (prepare-for-fast-read-char stream
 208           (let ((res (make-string 80))
 209                 (len 80)
 210                 (index 0))
 211             (loop
 212              (let ((ch (fast-read-char nil nil)))
 213                (cond (ch
 214                       (when (char= ch #\newline)
 215                         (done-with-fast-read-char)
 216                         (return (values (shrink-vector res index) nil)))
 217                       (when (= index len)
 218                         (setq len (* len 2))
 219                         (let ((new (make-string len)))
 220                           (replace new res)
 221                           (setq res new)))
 222                       (setf (schar res index) ch)
 223                       (incf index))
 224                      ((zerop index)
 225                       (done-with-fast-read-char)
 226                       (return (values (eof-or-lose stream
 227                                                    eof-error-p
 228                                                    eof-value)
 229                                       t)))
 230                      ;; Since FAST-READ-CHAR already hit the eof char, we
 231                      ;; shouldn't do another READ-CHAR.
 232                      (t
 233                       (done-with-fast-read-char)
 234                       (return (values (shrink-vector res index) t))))))))
 235         ;; must be Gray streams FUNDAMENTAL-STREAM
 236         (multiple-value-bind (string eof) (stream-read-line stream)
 237           (if (and eof (zerop (length string)))
 238               (values (eof-or-lose stream eof-error-p eof-value) t)
 239               (values string eof))))))
 240
 241 ;;; We proclaim them INLINE here, then proclaim them MAYBE-INLINE at EOF,
 242 ;;; so, except in this file, they are not inline by default, but they can be.
 243 #!-sb-fluid (declaim (inline read-char unread-char read-byte listen))
 244
 245 (defun read-char (&optional (stream *standard-input*)
 246                             (eof-error-p t)
 247                             eof-value
 248                             recursive-p)
 249   (declare (ignore recursive-p))
 250   (let ((stream (in-synonym-of stream)))
 251     (if (ansi-stream-p stream)
 252         (prepare-for-fast-read-char stream
 253           (prog1
 254               (fast-read-char eof-error-p eof-value)
 255             (done-with-fast-read-char)))
 256         ;; must be Gray streams FUNDAMENTAL-STREAM
 257         (let ((char (stream-read-char stream)))
 258           (if (eq char :eof)
 259               (eof-or-lose stream eof-error-p eof-value)
 260               char)))))
 261
 262 (defun unread-char (character &optional (stream *standard-input*))
 263   (let ((stream (in-synonym-of stream)))
 264     (if (ansi-stream-p stream)
 265         (let ((index (1- (ansi-stream-in-index stream)))
 266               (buffer (ansi-stream-in-buffer stream)))
 267           (declare (fixnum index))
 268           (when (minusp index) (error "nothing to unread"))
 269           (cond (buffer
 270                  (setf (aref buffer index) (char-code character))
 271                  (setf (ansi-stream-in-index stream) index))
 272                 (t
 273                  (funcall (ansi-stream-misc stream) stream
 274                           :unread character))))
 275         ;; must be Gray streams FUNDAMENTAL-STREAM
 276         (stream-unread-char stream character)))
 277   nil)
 278
 279 (defun listen (&optional (stream *standard-input*))
 280   (let ((stream (in-synonym-of stream)))
 281     (if (ansi-stream-p stream)
 282         (or (/= (the fixnum (ansi-stream-in-index stream))
 283                 +ansi-stream-in-buffer-length+)
 284             ;; Test for T explicitly since misc methods return :EOF sometimes.
 285             (eq (funcall (ansi-stream-misc stream) stream :listen) t))
 286         ;; Fall through to Gray streams FUNDAMENTAL-STREAM case.
 287         (stream-listen stream))))
 288
 289 (defun read-char-no-hang (&optional (stream *standard-input*)
 290                                     (eof-error-p t)
 291                                     eof-value
 292                                     recursive-p)
 293   (declare (ignore recursive-p))
 294   (let ((stream (in-synonym-of stream)))
 295     (if (ansi-stream-p stream)
 296         (if (funcall (ansi-stream-misc stream) stream :listen)
 297             ;; On T or :EOF get READ-CHAR to do the work.
 298             (read-char stream eof-error-p eof-value)
 299             nil)
 300         ;; must be Gray streams FUNDAMENTAL-STREAM
 301         (let ((char (stream-read-char-no-hang stream)))
 302           (if (eq char :eof)
 303               (eof-or-lose stream eof-error-p eof-value)
 304               char)))))
 305
 306 (defun clear-input (&optional (stream *standard-input*))
 307   (let ((stream (in-synonym-of stream)))
 308     (cond ((ansi-stream-p stream)
 309            (setf (ansi-stream-in-index stream) +ansi-stream-in-buffer-length+)
 310            (funcall (ansi-stream-misc stream) stream :clear-input))
 311           (t
 312            (stream-clear-input stream))))
 313   nil)
 314 \f
 315 (declaim (maybe-inline read-byte))
 316 (defun read-byte (stream &optional (eof-error-p t) eof-value)
 317   (let ((stream (in-synonym-of stream)))
 318     (if (ansi-stream-p stream)
 319         (prepare-for-fast-read-byte stream
 320           (prog1
 321               (fast-read-byte eof-error-p eof-value t)
 322             (done-with-fast-read-byte)))
 323         ;; must be Gray streams FUNDAMENTAL-STREAM
 324         (let ((char (stream-read-byte stream)))
 325           (if (eq char :eof)
 326               (eof-or-lose stream eof-error-p eof-value)
 327               char)))))
 328
 329 ;;; Read NUMBYTES bytes into BUFFER beginning at START, and return the
 330 ;;; number of bytes read.
 331 ;;;
 332 ;;; Note: CMU CL's version of this had a special interpretation of
 333 ;;; EOF-ERROR-P which SBCL does not have. (In the EOF-ERROR-P=NIL
 334 ;;; case, CMU CL's version would return as soon as any data became
 335 ;;; available.) This could be useful behavior for things like pipes in
 336 ;;; some cases, but it wasn't being used in SBCL, so it was dropped.
 337 ;;; If we ever need it, it could be added later as a new variant N-BIN
 338 ;;; method (perhaps N-BIN-ASAP?) or something.
 339 (defun read-n-bytes (stream buffer start numbytes &optional (eof-error-p t))
 340   (declare (type ansi-stream stream)
 341            (type index numbytes start)
 342            (type (or (simple-array * (*)) system-area-pointer) buffer))
 343   (let* ((stream (in-synonym-of stream ansi-stream))
 344          (in-buffer (ansi-stream-in-buffer stream))
 345          (index (ansi-stream-in-index stream))
 346          (num-buffered (- +ansi-stream-in-buffer-length+ index)))
 347     (declare (fixnum index num-buffered))
 348     (cond
 349      ((not in-buffer)
 350       (funcall (ansi-stream-n-bin stream)
 351                stream
 352                buffer
 353                start
 354                numbytes
 355                eof-error-p))
 356      ((<= numbytes num-buffered)
 357       (%byte-blt in-buffer index
 358                  buffer start (+ start numbytes))
 359       (setf (ansi-stream-in-index stream) (+ index numbytes))
 360       numbytes)
 361      (t
 362       (let ((end (+ start num-buffered)))
 363         (%byte-blt in-buffer index buffer start end)
 364         (setf (ansi-stream-in-index stream) +ansi-stream-in-buffer-length+)
 365         (+ (funcall (ansi-stream-n-bin stream)
 366                     stream
 367                     buffer
 368                     end
 369                     (- numbytes num-buffered)
 370                     eof-error-p)
 371            num-buffered))))))
 372
 373 ;;; the amount of space we leave at the start of the in-buffer for
 374 ;;; unreading
 375 ;;;
 376 ;;; (It's 4 instead of 1 to allow word-aligned copies.)
 377 (defconstant +ansi-stream-in-buffer-extra+
 378   4) ; FIXME: should be symbolic constant
 379
 380 ;;; This function is called by the FAST-READ-CHAR expansion to refill
 381 ;;; the IN-BUFFER for text streams. There is definitely an IN-BUFFER,
 382 ;;; and hence must be an N-BIN method.
 383 (defun fast-read-char-refill (stream eof-error-p eof-value)
 384   (let* ((ibuf (ansi-stream-in-buffer stream))
 385          (count (funcall (ansi-stream-n-bin stream)
 386                          stream
 387                          ibuf
 388                          +ansi-stream-in-buffer-extra+
 389                          (- +ansi-stream-in-buffer-length+
 390                             +ansi-stream-in-buffer-extra+)
 391                          nil))
 392          (start (- +ansi-stream-in-buffer-length+ count)))
 393     (declare (type index start count))
 394     (cond ((zerop count)
 395            (setf (ansi-stream-in-index stream) +ansi-stream-in-buffer-length+)
 396            (funcall (ansi-stream-in stream) stream eof-error-p eof-value))
 397           (t
 398            (when (/= start +ansi-stream-in-buffer-extra+)
 399              (bit-bash-copy ibuf (+ (* +ansi-stream-in-buffer-extra+
 400                                        sb!vm:n-byte-bits)
 401                                     (* sb!vm:vector-data-offset
 402                                        sb!vm:n-word-bits))
 403                             ibuf (+ (the index (* start sb!vm:n-byte-bits))
 404                                     (* sb!vm:vector-data-offset
 405                                        sb!vm:n-word-bits))
 406                             (* count sb!vm:n-byte-bits)))
 407            (setf (ansi-stream-in-index stream) (1+ start))
 408            (code-char (aref ibuf start))))))
 409
 410 ;;; This is similar to FAST-READ-CHAR-REFILL, but we don't have to
 411 ;;; leave room for unreading.
 412 (defun fast-read-byte-refill (stream eof-error-p eof-value)
 413   (let* ((ibuf (ansi-stream-in-buffer stream))
 414          (count (funcall (ansi-stream-n-bin stream) stream
 415                          ibuf 0 +ansi-stream-in-buffer-length+
 416                          nil))
 417          (start (- +ansi-stream-in-buffer-length+ count)))
 418     (declare (type index start count))
 419     (cond ((zerop count)
 420            (setf (ansi-stream-in-index stream) +ansi-stream-in-buffer-length+)
 421            (funcall (ansi-stream-bin stream) stream eof-error-p eof-value))
 422           (t
 423            (unless (zerop start)
 424              (bit-bash-copy ibuf (* sb!vm:vector-data-offset sb!vm:n-word-bits)
 425                             ibuf (+ (the index (* start sb!vm:n-byte-bits))
 426                                     (* sb!vm:vector-data-offset
 427                                        sb!vm:n-word-bits))
 428                             (* count sb!vm:n-byte-bits)))
 429            (setf (ansi-stream-in-index stream) (1+ start))
 430            (aref ibuf start)))))
 431 \f
 432 ;;; output functions
 433
 434 (defun write-char (character &optional (stream *standard-output*))
 435   (with-out-stream stream (ansi-stream-out character)
 436                    (stream-write-char character))
 437   character)
 438
 439 (defun terpri (&optional (stream *standard-output*))
 440   (with-out-stream stream (ansi-stream-out #\newline) (stream-terpri))
 441   nil)
 442
 443 (defun fresh-line (&optional (stream *standard-output*))
 444   (let ((stream (out-synonym-of stream)))
 445     (if (ansi-stream-p stream)
 446         (when (/= (or (charpos stream) 1) 0)
 447           (funcall (ansi-stream-out stream) stream #\newline)
 448           t)
 449         ;; must be Gray streams FUNDAMENTAL-STREAM
 450         (stream-fresh-line stream))))
 451
 452 (defun write-string (string &optional (stream *standard-output*)
 453                             &key (start 0) end)
 454   (declare (type string string))
 455   ;; Note that even though you might expect, based on the behavior of
 456   ;; things like AREF, that the correct upper bound here is
 457   ;; (ARRAY-DIMENSION STRING 0), the ANSI glossary definitions for
 458   ;; "bounding index" and "length" indicate that in this case (i.e.
 459   ;; for the ANSI-specified functions WRITE-STRING [and WRITE-LINE]),
 460   ;; (LENGTH STRING) is the required upper bound. A foolish
 461   ;; consistency is the hobgoblin of lesser languages..
 462   (%write-string string stream start (%check-vector-sequence-bounds
 463                                       string start end))
 464   string)
 465
 466 (defun %write-string (string stream start end)
 467   (declare (type string string))
 468   (declare (type stream-designator stream))
 469   (declare (type index start end))
 470   (let ((stream (out-synonym-of stream)))
 471     (cond ((ansi-stream-p stream)
 472            (if (array-header-p string)
 473                (with-array-data ((data string) (offset-start start)
 474                                  (offset-end end))
 475                  (funcall (ansi-stream-sout stream)
 476                           stream data offset-start offset-end))
 477                (funcall (ansi-stream-sout stream) stream string start end))
 478            string)
 479           (t ; must be Gray streams FUNDAMENTAL-STREAM
 480            (stream-write-string stream string start end)))))
 481
 482 ;;; A wrapper function for all those (MACROLET OUT-FUN) definitions,
 483 ;;; which cannot deal with keyword arguments.
 484 (declaim (inline write-string-no-key))
 485 (defun write-string-no-key (string stream start end)
 486   (write-string string stream :start start :end end))
 487
 488 (defun write-line (string &optional (stream *standard-output*)
 489                           &key (start 0) end)
 490   (declare (type string string))
 491   ;; FIXME: Why is there this difference between the treatments of the
 492   ;; STREAM argument in WRITE-STRING and WRITE-LINE?
 493   (let ((defaulted-stream (out-synonym-of stream)))
 494     (%write-string string defaulted-stream start (%check-vector-sequence-bounds
 495                                                   string start end))
 496     (write-char #\newline defaulted-stream))
 497   string)
 498
 499 (defun charpos (&optional (stream *standard-output*))
 500   (with-out-stream stream (ansi-stream-misc :charpos) (stream-line-column)))
 501
 502 (defun line-length (&optional (stream *standard-output*))
 503   (with-out-stream stream (ansi-stream-misc :line-length)
 504                    (stream-line-length)))
 505
 506 (defun finish-output (&optional (stream *standard-output*))
 507   (with-out-stream stream (ansi-stream-misc :finish-output)
 508                    (stream-finish-output))
 509   nil)
 510
 511 (defun force-output (&optional (stream *standard-output*))
 512   (with-out-stream stream (ansi-stream-misc :force-output)
 513                    (stream-force-output))
 514   nil)
 515
 516 (defun clear-output (&optional (stream *standard-output*))
 517   (with-out-stream stream (ansi-stream-misc :clear-output)
 518                    (stream-force-output))
 519   nil)
 520
 521 (defun write-byte (integer stream)
 522   (with-out-stream stream (ansi-stream-bout integer)
 523                    (stream-write-byte integer))
 524   integer)
 525 \f
 526
 527 ;;; (These were inline throughout this file, but that's not appropriate
 528 ;;; globally.  And we must not inline them in the rest of this file if
 529 ;;; dispatch to gray or simple streams is to work, since both redefine
 530 ;;; these functions later.)
 531 (declaim (maybe-inline read-char unread-char read-byte listen))
 532
 533 ;;; This is called from ANSI-STREAM routines that encapsulate CLOS
 534 ;;; streams to handle the misc routines and dispatch to the
 535 ;;; appropriate SIMPLE- or FUNDAMENTAL-STREAM functions.
 536 (defun stream-misc-dispatch (stream operation &optional arg1 arg2)
 537   (declare (type stream stream) (ignore arg2))
 538   (ecase operation
 539     (:listen
 540      ;; Return T if input available, :EOF for end-of-file, otherwise NIL.
 541      (let ((char (read-char-no-hang stream nil :eof)))
 542        (when (characterp char)
 543          (unread-char char stream))
 544        char))
 545     (:unread
 546      (unread-char arg1 stream))
 547     (:close
 548      (close stream))
 549     (:clear-input
 550      (clear-input stream))
 551     (:force-output
 552      (force-output stream))
 553     (:finish-output
 554      (finish-output stream))
 555     (:element-type
 556      (stream-element-type stream))
 557     (:interactive-p
 558      (interactive-stream-p stream))
 559     (:line-length
 560      (line-length stream))
 561     (:charpos
 562      (charpos stream))
 563     (:file-length
 564      (file-length stream))
 565     (:file-position
 566      (file-position stream arg1))))
 567 \f
 568 ;;;; broadcast streams
 569
 570 (defstruct (broadcast-stream (:include ansi-stream
 571                                        (out #'broadcast-out)
 572                                        (bout #'broadcast-bout)
 573                                        (sout #'broadcast-sout)
 574                                        (misc #'broadcast-misc))
 575                              (:constructor %make-broadcast-stream
 576                                            (&rest streams))
 577                              (:copier nil))
 578   ;; a list of all the streams we broadcast to
 579   (streams () :type list :read-only t))
 580
 581 (defun make-broadcast-stream (&rest streams)
 582   (dolist (stream streams)
 583     (unless (output-stream-p stream)
 584       (error 'type-error
 585              :datum stream
 586              :expected-type '(satisfies output-stream-p))))
 587   (apply #'%make-broadcast-stream streams))
 588
 589 (macrolet ((out-fun (name fun &rest args)
 590              `(defun ,name (stream ,@args)
 591                 (dolist (stream (broadcast-stream-streams stream))
 592                   (,fun ,(car args) stream ,@(cdr args))))))
 593   (out-fun broadcast-out write-char char)
 594   (out-fun broadcast-bout write-byte byte)
 595   (out-fun broadcast-sout write-string-no-key string start end))
 596
 597 (defun broadcast-misc (stream operation &optional arg1 arg2)
 598   (let ((streams (broadcast-stream-streams stream)))
 599     (case operation
 600       ;; FIXME: This may not be the best place to note this, but I
 601       ;; think the :CHARPOS protocol needs revision.  Firstly, I think
 602       ;; this is the last place where a NULL return value was possible
 603       ;; (before adjusting it to be 0), so a bunch of conditionals IF
 604       ;; CHARPOS can be removed; secondly, it is my belief that
 605       ;; FD-STREAMS, when running FILE-POSITION, do not update the
 606       ;; CHARPOS, and consequently there will be much wrongness.
 607       ;;
 608       ;; FIXME: see also TWO-WAY-STREAM treatment of :CHARPOS -- why
 609       ;; is it testing the :charpos of an input stream?
 610       ;;
 611       ;; -- CSR, 2004-02-04
 612       (:charpos
 613        (dolist (stream streams 0)
 614          (let ((charpos (charpos stream)))
 615            (if charpos (return charpos)))))
 616       (:line-length
 617        (let ((min nil))
 618          (dolist (stream streams min)
 619            (let ((res (line-length stream)))
 620              (when res (setq min (if min (min res min) res)))))))
 621       (:element-type
 622        #+nil ; old, arguably more logical, version
 623        (let (res)
 624          (dolist (stream streams (if (> (length res) 1) `(and ,@res) t))
 625            (pushnew (stream-element-type stream) res :test #'equal)))
 626        ;; ANSI-specified version (under System Class BROADCAST-STREAM)
 627        (let ((res t))
 628          (do ((streams streams (cdr streams)))
 629              ((null streams) res)
 630            (when (null (cdr streams))
 631              (setq res (stream-element-type (car streams)))))))
 632       (:close
 633        (set-closed-flame stream))
 634       (t
 635        (let ((res nil))
 636          (dolist (stream streams res)
 637            (setq res
 638                  (if (ansi-stream-p stream)
 639                      (funcall (ansi-stream-misc stream) stream operation
 640                               arg1 arg2)
 641                      (stream-misc-dispatch stream operation arg1 arg2)))))))))
 642 \f
 643 ;;;; synonym streams
 644
 645 (defstruct (synonym-stream (:include ansi-stream
 646                                      (in #'synonym-in)
 647                                      (bin #'synonym-bin)
 648                                      (n-bin #'synonym-n-bin)
 649                                      (out #'synonym-out)
 650                                      (bout #'synonym-bout)
 651                                      (sout #'synonym-sout)
 652                                      (misc #'synonym-misc))
 653                            (:constructor make-synonym-stream (symbol))
 654                            (:copier nil))
 655   ;; This is the symbol, the value of which is the stream we are synonym to.
 656   (symbol nil :type symbol :read-only t))
 657 (def!method print-object ((x synonym-stream) stream)
 658   (print-unreadable-object (x stream :type t :identity t)
 659     (format stream ":SYMBOL ~S" (synonym-stream-symbol x))))
 660
 661 ;;; The output simple output methods just call the corresponding
 662 ;;; function on the synonymed stream.
 663 (macrolet ((out-fun (name fun &rest args)
 664              `(defun ,name (stream ,@args)
 665                 (declare (optimize (safety 1)))
 666                 (let ((syn (symbol-value (synonym-stream-symbol stream))))
 667                   (,fun ,(car args) syn ,@(cdr args))))))
 668   (out-fun synonym-out write-char ch)
 669   (out-fun synonym-bout write-byte n)
 670   (out-fun synonym-sout write-string-no-key string start end))
 671
 672 ;;; For the input methods, we just call the corresponding function on the
 673 ;;; synonymed stream. These functions deal with getting input out of
 674 ;;; the In-Buffer if there is any.
 675 (macrolet ((in-fun (name fun &rest args)
 676              `(defun ,name (stream ,@args)
 677                 (declare (optimize (safety 1)))
 678                 (,fun (symbol-value (synonym-stream-symbol stream))
 679                       ,@args))))
 680   (in-fun synonym-in read-char eof-error-p eof-value)
 681   (in-fun synonym-bin read-byte eof-error-p eof-value)
 682   (in-fun synonym-n-bin read-n-bytes buffer start numbytes eof-error-p))
 683
 684 (defun synonym-misc (stream operation &optional arg1 arg2)
 685   (declare (optimize (safety 1)))
 686   (let ((syn (symbol-value (synonym-stream-symbol stream))))
 687     (if (ansi-stream-p syn)
 688         ;; We have to special-case some operations which interact with
 689         ;; the in-buffer of the wrapped stream, since just calling
 690         ;; ANSI-STREAM-MISC on them
 691         (case operation
 692           (:listen (or (/= (the fixnum (ansi-stream-in-index syn))
 693                            +ansi-stream-in-buffer-length+)
 694                        (funcall (ansi-stream-misc syn) syn :listen)))
 695           (:clear-input (clear-input syn))
 696           (:unread (unread-char arg1 syn))
 697           (t
 698            (funcall (ansi-stream-misc syn) syn operation arg1 arg2)))
 699         (stream-misc-dispatch syn operation arg1 arg2))))
 700 \f
 701 ;;;; two-way streams
 702
 703 (defstruct (two-way-stream
 704             (:include ansi-stream
 705                       (in #'two-way-in)
 706                       (bin #'two-way-bin)
 707                       (n-bin #'two-way-n-bin)
 708                       (out #'two-way-out)
 709                       (bout #'two-way-bout)
 710                       (sout #'two-way-sout)
 711                       (misc #'two-way-misc))
 712             (:constructor %make-two-way-stream (input-stream output-stream))
 713             (:copier nil))
 714   (input-stream (missing-arg) :type stream :read-only t)
 715   (output-stream (missing-arg) :type stream :read-only t))
 716 (defprinter (two-way-stream) input-stream output-stream)
 717
 718 (defun make-two-way-stream (input-stream output-stream)
 719   #!+sb-doc
 720   "Return a bidirectional stream which gets its input from INPUT-STREAM and
 721    sends its output to OUTPUT-STREAM."
 722   ;; FIXME: This idiom of the-real-stream-of-a-possibly-synonym-stream
 723   ;; should be encapsulated in a function, and used here and most of
 724   ;; the other places that SYNONYM-STREAM-P appears.
 725   (unless (output-stream-p output-stream)
 726     (error 'type-error
 727            :datum output-stream
 728            :expected-type '(satisfies output-stream-p)))
 729   (unless (input-stream-p input-stream)
 730     (error 'type-error
 731            :datum input-stream
 732            :expected-type '(satisfies input-stream-p)))
 733   (funcall #'%make-two-way-stream input-stream output-stream))
 734
 735 (macrolet ((out-fun (name fun &rest args)
 736              `(defun ,name (stream ,@args)
 737                 (let ((syn (two-way-stream-output-stream stream)))
 738                   (,fun ,(car args) syn ,@(cdr args))))))
 739   (out-fun two-way-out write-char ch)
 740   (out-fun two-way-bout write-byte n)
 741   (out-fun two-way-sout write-string-no-key string start end))
 742
 743 (macrolet ((in-fun (name fun &rest args)
 744              `(defun ,name (stream ,@args)
 745                 (force-output (two-way-stream-output-stream stream))
 746                 (,fun (two-way-stream-input-stream stream) ,@args))))
 747   (in-fun two-way-in read-char eof-error-p eof-value)
 748   (in-fun two-way-bin read-byte eof-error-p eof-value)
 749   (in-fun two-way-n-bin read-n-bytes buffer start numbytes eof-error-p))
 750
 751 (defun two-way-misc (stream operation &optional arg1 arg2)
 752   (let* ((in (two-way-stream-input-stream stream))
 753          (out (two-way-stream-output-stream stream))
 754          (in-ansi-stream-p (ansi-stream-p in))
 755          (out-ansi-stream-p (ansi-stream-p out)))
 756     (case operation
 757       (:listen
 758        (if in-ansi-stream-p
 759            (or (/= (the fixnum (ansi-stream-in-index in))
 760                    +ansi-stream-in-buffer-length+)
 761                (funcall (ansi-stream-misc in) in :listen))
 762            (stream-listen in)))
 763       ((:finish-output :force-output :clear-output)
 764        (if out-ansi-stream-p
 765            (funcall (ansi-stream-misc out) out operation arg1 arg2)
 766            (stream-misc-dispatch out operation arg1 arg2)))
 767       (:clear-input (clear-input in))
 768       (:unread (unread-char arg1 in))
 769       (:element-type
 770        (let ((in-type (stream-element-type in))
 771              (out-type (stream-element-type out)))
 772          (if (equal in-type out-type)
 773              in-type `(and ,in-type ,out-type))))
 774       (:close
 775        (set-closed-flame stream))
 776       (t
 777        (or (if in-ansi-stream-p
 778                (funcall (ansi-stream-misc in) in operation arg1 arg2)
 779                (stream-misc-dispatch in operation arg1 arg2))
 780            (if out-ansi-stream-p
 781                (funcall (ansi-stream-misc out) out operation arg1 arg2)
 782                (stream-misc-dispatch out operation arg1 arg2)))))))
 783 \f
 784 ;;;; concatenated streams
 785
 786 (defstruct (concatenated-stream
 787             (:include ansi-stream
 788                       (in #'concatenated-in)
 789                       (bin #'concatenated-bin)
 790                       (n-bin #'concatenated-n-bin)
 791                       (misc #'concatenated-misc))
 792             (:constructor %make-concatenated-stream
 793                           (&rest streams &aux (current streams)))
 794             (:copier nil))
 795   ;; The car of this is the substream we are reading from now.
 796   current
 797   ;; This is a list of all the substreams there ever were. We need to
 798   ;; remember them so that we can close them.
 799   ;;
 800   ;; FIXME: ANSI says this is supposed to be the list of streams that
 801   ;; we still have to read from. So either this needs to become a
 802   ;; private member %STREAM (with CONCATENATED-STREAM-STREAMS a wrapper
 803   ;; around it which discards closed files from the head of the list)
 804   ;; or we need to update it as we run out of files.
 805   (streams nil :type list :read-only t))
 806 (def!method print-object ((x concatenated-stream) stream)
 807   (print-unreadable-object (x stream :type t :identity t)
 808     (format stream
 809             ":STREAMS ~S"
 810             (concatenated-stream-streams x))))
 811
 812 (defun make-concatenated-stream (&rest streams)
 813   #!+sb-doc
 814   "Return a stream which takes its input from each of the streams in turn,
 815    going on to the next at EOF."
 816   (dolist (stream streams)
 817     (unless (input-stream-p stream)
 818       (error 'type-error
 819              :datum stream
 820              :expected-type '(satisfies input-stream-p))))
 821   (apply #'%make-concatenated-stream streams))
 822
 823 (macrolet ((in-fun (name fun)
 824              `(defun ,name (stream eof-error-p eof-value)
 825                 (do ((current (concatenated-stream-current stream)
 826                               (cdr current)))
 827                     ((null current)
 828                      (eof-or-lose stream eof-error-p eof-value))
 829                   (let* ((stream (car current))
 830                          (result (,fun stream nil nil)))
 831                     (when result (return result)))
 832                   (pop (concatenated-stream-current stream))))))
 833   (in-fun concatenated-in read-char)
 834   (in-fun concatenated-bin read-byte))
 835
 836 (defun concatenated-n-bin (stream buffer start numbytes eof-errorp)
 837   (do ((current (concatenated-stream-current stream) (cdr current))
 838        (current-start start)
 839        (remaining-bytes numbytes))
 840       ((null current)
 841        (if eof-errorp
 842            (error 'end-of-file :stream stream)
 843            (- numbytes remaining-bytes)))
 844     (let* ((stream (car current))
 845            (bytes-read (read-n-bytes stream buffer current-start
 846                                      remaining-bytes nil)))
 847       (incf current-start bytes-read)
 848       (decf remaining-bytes bytes-read)
 849       (when (zerop remaining-bytes) (return numbytes)))
 850     (setf (concatenated-stream-current stream) (cdr current))))
 851
 852 (defun concatenated-misc (stream operation &optional arg1 arg2)
 853   (let ((left (concatenated-stream-current stream)))
 854     (when left
 855       (let* ((current (car left)))
 856         (case operation
 857           (:listen
 858            (loop
 859              (let ((stuff (if (ansi-stream-p current)
 860                               (funcall (ansi-stream-misc current) current
 861                                        :listen)
 862                               (stream-misc-dispatch current :listen))))
 863                (cond ((eq stuff :eof)
 864                       ;; Advance CURRENT, and try again.
 865                       (pop (concatenated-stream-current stream))
 866                       (setf current
 867                             (car (concatenated-stream-current stream)))
 868                       (unless current
 869                         ;; No further streams. EOF.
 870                         (return :eof)))
 871                      (stuff
 872                       ;; Stuff's available.
 873                       (return t))
 874                      (t
 875                       ;; Nothing is available yet.
 876                       (return nil))))))
 877           (:clear-input (clear-input current))
 878           (:unread (unread-char arg1 current))
 879           (:close
 880            (set-closed-flame stream))
 881           (t
 882            (if (ansi-stream-p current)
 883                (funcall (ansi-stream-misc current) current operation arg1 arg2)
 884                (stream-misc-dispatch current operation arg1 arg2))))))))
 885 \f
 886 ;;;; echo streams
 887
 888 (defstruct (echo-stream
 889             (:include two-way-stream
 890                       (in #'echo-in)
 891                       (bin #'echo-bin)
 892                       (misc #'echo-misc)
 893                       (n-bin #'ill-bin))
 894             (:constructor %make-echo-stream (input-stream output-stream))
 895             (:copier nil))
 896   unread-stuff)
 897 (def!method print-object ((x echo-stream) stream)
 898   (print-unreadable-object (x stream :type t :identity t)
 899     (format stream
 900             ":INPUT-STREAM ~S :OUTPUT-STREAM ~S"
 901             (two-way-stream-input-stream x)
 902             (two-way-stream-output-stream x))))
 903
 904 (defun make-echo-stream (input-stream output-stream)
 905   #!+sb-doc
 906   "Return a bidirectional stream which gets its input from INPUT-STREAM and
 907    sends its output to OUTPUT-STREAM. In addition, all input is echoed to
 908    the output stream."
 909   (unless (output-stream-p output-stream)
 910     (error 'type-error
 911            :datum output-stream
 912            :expected-type '(satisfies output-stream-p)))
 913   (unless (input-stream-p input-stream)
 914     (error 'type-error
 915            :datum input-stream
 916            :expected-type '(satisfies input-stream-p)))
 917   (funcall #'%make-echo-stream input-stream output-stream))
 918
 919 (macrolet ((in-fun (name in-fun out-fun &rest args)
 920              `(defun ,name (stream ,@args)
 921                 (or (pop (echo-stream-unread-stuff stream))
 922                     (let* ((in (echo-stream-input-stream stream))
 923                            (out (echo-stream-output-stream stream))
 924                            (result (,in-fun in ,@args)))
 925                       (,out-fun result out)
 926                       result)))))
 927   (in-fun echo-in read-char write-char eof-error-p eof-value)
 928   (in-fun echo-bin read-byte write-byte eof-error-p eof-value))
 929 \f
 930 ;;;; base STRING-STREAM stuff
 931
 932 (defstruct (string-stream
 933              (:include ansi-stream)
 934              (:constructor nil)
 935              (:copier nil))
 936   ;; FIXME: This type declaration is true, and will probably continue
 937   ;; to be true.  However, note well the comments in DEFTRANSFORM
 938   ;; REPLACE, implying that performance of REPLACE is somewhat
 939   ;; critical to performance of string streams.  If (VECTOR CHARACTER)
 940   ;; ever becomes different from (VECTOR BASE-CHAR), the transform
 941   ;; probably needs to be extended.
 942   (string (missing-arg) :type (vector character)))
 943 \f
 944 ;;;; STRING-INPUT-STREAM stuff
 945
 946 (defstruct (string-input-stream
 947              (:include string-stream
 948                        (in #'string-inch)
 949                        (bin #'ill-bin)
 950                        (n-bin #'string-stream-read-n-bytes)
 951                        (misc #'string-in-misc)
 952                        (string (missing-arg) :type simple-string))
 953              (:constructor internal-make-string-input-stream
 954                            (string current end))
 955              (:copier nil))
 956   (current (missing-arg) :type index)
 957   (end (missing-arg) :type index))
 958
 959 (defun string-inch (stream eof-error-p eof-value)
 960   (declare (type string-input-stream stream))
 961   (let ((string (string-input-stream-string stream))
 962         (index (string-input-stream-current stream)))
 963     (cond ((>= index (the index (string-input-stream-end stream)))
 964            (eof-or-lose stream eof-error-p eof-value))
 965           (t
 966            (setf (string-input-stream-current stream) (1+ index))
 967            (char string index)))))
 968
 969 (defun string-binch (stream eof-error-p eof-value)
 970   (declare (type string-input-stream stream))
 971   (let ((string (string-input-stream-string stream))
 972         (index (string-input-stream-current stream)))
 973     (cond ((>= index (the index (string-input-stream-end stream)))
 974            (eof-or-lose stream eof-error-p eof-value))
 975           (t
 976            (setf (string-input-stream-current stream) (1+ index))
 977            (char-code (char string index))))))
 978
 979 (defun string-stream-read-n-bytes (stream buffer start requested eof-error-p)
 980   (declare (type string-input-stream stream)
 981            (type index start requested))
 982   (let* ((string (string-input-stream-string stream))
 983          (index (string-input-stream-current stream))
 984          (available (- (string-input-stream-end stream) index))
 985          (copy (min available requested)))
 986     (declare (type simple-string string))
 987     (when (plusp copy)
 988       (setf (string-input-stream-current stream)
 989             (truly-the index (+ index copy)))
 990       (sb!sys:without-gcing
 991        (system-area-copy (vector-sap string)
 992                          (* index sb!vm:n-byte-bits)
 993                          (if (typep buffer 'system-area-pointer)
 994                              buffer
 995                              (vector-sap buffer))
 996                          (* start sb!vm:n-byte-bits)
 997                          (* copy sb!vm:n-byte-bits))))
 998     (if (and (> requested copy) eof-error-p)
 999         (error 'end-of-file :stream stream)
1000         copy)))
1001
1002 (defun string-in-misc (stream operation &optional arg1 arg2)
1003   (declare (type string-input-stream stream)
1004            (ignore arg2))
1005   (case operation
1006     (:file-position
1007      (if arg1
1008          (setf (string-input-stream-current stream)
1009                (case arg1
1010                  (:start 0)
1011                  (:end (string-input-stream-end stream))
1012                  ;; We allow moving position beyond EOF. Errors happen
1013                  ;; on read, not move -- or the user may extend the
1014                  ;; input string.
1015                  (t arg1)))
1016          (string-input-stream-current stream)))
1017     ;; According to ANSI: "Should signal an error of type type-error
1018     ;; if stream is not a stream associated with a file."
1019     ;; This is checked by FILE-LENGTH, so no need to do it here either.
1020     ;; (:file-length (length (string-input-stream-string stream)))
1021     (:unread (decf (string-input-stream-current stream)))
1022     (:listen (or (/= (the index (string-input-stream-current stream))
1023                      (the index (string-input-stream-end stream)))
1024                  :eof))
1025     (:element-type (array-element-type (string-input-stream-string stream)))))
1026
1027 (defun make-string-input-stream (string &optional (start 0) end)
1028   #!+sb-doc
1029   "Return an input stream which will supply the characters of STRING between
1030   START and END in order."
1031   (declare (type string string)
1032            (type index start)
1033            (type (or index null) end))
1034   (let* ((string (coerce string '(simple-array character (*))))
1035          (end (%check-vector-sequence-bounds string start end)))
1036     (with-array-data ((string string) (start start) (end end))
1037       (internal-make-string-input-stream
1038        string ;; now simple
1039        start
1040        end))))
1041 \f
1042 ;;;; STRING-OUTPUT-STREAM stuff
1043
1044 (defstruct (string-output-stream
1045             (:include string-stream
1046                       (out #'string-ouch)
1047                       (sout #'string-sout)
1048                       (misc #'string-out-misc)
1049                       ;; The string we throw stuff in.
1050                       (string (missing-arg)
1051                               :type (simple-array character (*))))
1052             (:constructor make-string-output-stream
1053                           (&key (element-type 'character)
1054                            &aux (string (make-string 40))))
1055             (:copier nil))
1056   ;; Index of the next location to use.
1057   (index 0 :type fixnum)
1058   ;; Index cache for string-output-stream-last-index
1059   (index-cache 0 :type fixnum)
1060   ;; Requested element type
1061   (element-type 'character))
1062
1063 #!+sb-doc
1064 (setf (fdocumentation 'make-string-output-stream 'function)
1065   "Return an output stream which will accumulate all output given it for
1066    the benefit of the function GET-OUTPUT-STREAM-STRING.")
1067
1068 (defun string-output-stream-last-index (stream)
1069   (max (string-output-stream-index stream)
1070        (string-output-stream-index-cache stream)))
1071
1072 (defun string-ouch (stream character)
1073   (let ((current (string-output-stream-index stream))
1074         (workspace (string-output-stream-string stream)))
1075     (declare (type (simple-array character (*)) workspace)
1076              (type fixnum current))
1077     (if (= current (the fixnum (length workspace)))
1078         (let ((new-workspace (make-string (* current 2))))
1079           (replace new-workspace workspace)
1080           (setf (aref new-workspace current) character
1081                 (string-output-stream-string stream) new-workspace))
1082         (setf (aref workspace current) character))
1083     (setf (string-output-stream-index stream) (1+ current))))
1084
1085 (defun string-sout (stream string start end)
1086   (declare (type simple-string string)
1087            (type fixnum start end))
1088   (let* ((string (if (typep string '(simple-array character (*)))
1089                      string
1090                      (coerce string '(simple-array character (*)))))
1091          (current (string-output-stream-index stream))
1092          (length (- end start))
1093          (dst-end (+ length current))
1094          (workspace (string-output-stream-string stream)))
1095     (declare (type (simple-array character (*)) workspace string)
1096              (type fixnum current length dst-end))
1097     (if (> dst-end (the fixnum (length workspace)))
1098         (let ((new-workspace (make-string (+ (* current 2) length))))
1099           (replace new-workspace workspace :end2 current)
1100           (replace new-workspace string
1101                    :start1 current :end1 dst-end
1102                    :start2 start :end2 end)
1103           (setf (string-output-stream-string stream) new-workspace))
1104         (replace workspace string
1105                  :start1 current :end1 dst-end
1106                  :start2 start :end2 end))
1107     (setf (string-output-stream-index stream) dst-end)))
1108
1109 (defun string-out-misc (stream operation &optional arg1 arg2)
1110   (declare (ignore arg2))
1111   (case operation
1112     (:file-position
1113      (if arg1
1114          (let ((end (string-output-stream-last-index stream)))
1115            (setf (string-output-stream-index-cache stream) end
1116                  (string-output-stream-index stream)
1117                  (case arg1
1118                    (:start 0)
1119                    (:end end)
1120                    (t
1121                     ;; We allow moving beyond the end of stream,
1122                     ;; implicitly extending the output stream.
1123                     (let ((buffer (string-output-stream-string stream)))
1124                       (when (> arg1 (length buffer))
1125                         (setf (string-output-stream-string stream)
1126                               (make-string
1127                                arg1 :element-type (array-element-type buffer))
1128                               (subseq (string-output-stream-string stream)
1129                                       0 end)
1130                               (subseq buffer 0 end))))
1131                       arg1))))
1132          (string-output-stream-index stream)))
1133     (:charpos
1134      (do ((index (1- (the fixnum (string-output-stream-index stream)))
1135                  (1- index))
1136           (count 0 (1+ count))
1137           (string (string-output-stream-string stream)))
1138          ((< index 0) count)
1139        (declare (type (simple-array character (*)) string)
1140                 (type fixnum index count))
1141        (if (char= (schar string index) #\newline)
1142            (return count))))
1143     (:element-type (array-element-type (string-output-stream-string stream)))))
1144
1145 ;;; Return a string of all the characters sent to a stream made by
1146 ;;; MAKE-STRING-OUTPUT-STREAM since the last call to this function.
1147 (defun get-output-stream-string (stream)
1148   (declare (type string-output-stream stream))
1149   (let* ((length (string-output-stream-last-index stream))
1150          (element-type (string-output-stream-element-type stream))
1151          (result
1152           (case element-type
1153             ;; Overwhelmingly common case; can be inlined.
1154             ((character) (make-string length))
1155             (t (make-string length :element-type element-type)))))
1156     ;; For the benefit of the REPLACE transform, let's do this, so
1157     ;; that the common case isn't ludicrously expensive.
1158     (etypecase result
1159       ((simple-array character (*))
1160        (replace result (string-output-stream-string stream)))
1161       ((simple-array nil (*))
1162        (replace result (string-output-stream-string stream))))
1163     (setf (string-output-stream-index stream) 0
1164           (string-output-stream-index-cache stream) 0)
1165     result))
1166
1167 ;;; Dump the characters buffer up in IN-STREAM to OUT-STREAM as
1168 ;;; GET-OUTPUT-STREAM-STRING would return them.
1169 (defun dump-output-stream-string (in-stream out-stream)
1170   (%write-string (string-output-stream-string in-stream)
1171                  out-stream
1172                  0
1173                  (string-output-stream-last-index in-stream))
1174   (setf (string-output-stream-index in-stream) 0
1175         (string-output-stream-index-cache in-stream) 0))
1176 \f
1177 ;;;; fill-pointer streams
1178
1179 ;;; Fill pointer STRING-OUTPUT-STREAMs are not explicitly mentioned in
1180 ;;; the CLM, but they are required for the implementation of
1181 ;;; WITH-OUTPUT-TO-STRING.
1182
1183 (deftype string-with-fill-pointer ()
1184   '(and (vector character)
1185         (satisfies array-has-fill-pointer-p)))
1186
1187 (defstruct (fill-pointer-output-stream
1188             (:include string-stream
1189                       (out #'fill-pointer-ouch)
1190                       (sout #'fill-pointer-sout)
1191                       (misc #'fill-pointer-misc)
1192                       ;; a string with a fill pointer where we stuff
1193                       ;; the stuff we write
1194                       (string (missing-arg)
1195                               :type string-with-fill-pointer
1196                               :read-only t))
1197             (:constructor make-fill-pointer-output-stream (string))
1198             (:copier nil)))
1199
1200 (defun fill-pointer-ouch (stream character)
1201   (let* ((buffer (fill-pointer-output-stream-string stream))
1202          (current (fill-pointer buffer))
1203          (current+1 (1+ current)))
1204     (declare (fixnum current))
1205     (with-array-data ((workspace buffer) (start) (end))
1206       (declare (type (simple-array character (*)) workspace))
1207       (let ((offset-current (+ start current)))
1208         (declare (fixnum offset-current))
1209         (if (= offset-current end)
1210             (let* ((new-length (1+ (* current 2)))
1211                    (new-workspace (make-string new-length)))
1212               (declare (simple-string new-workspace))
1213               (%byte-blt workspace start
1214                          new-workspace 0 current)
1215               (setf workspace new-workspace
1216                     offset-current current)
1217               (set-array-header buffer workspace new-length
1218                                 current+1 0 new-length nil))
1219             (setf (fill-pointer buffer) current+1))
1220         (setf (schar workspace offset-current) character)))
1221     current+1))
1222
1223 (defun fill-pointer-sout (stream string start end)
1224   (declare (simple-string string) (fixnum start end))
1225   (let* ((string (if (typep string '(simple-array character (*)))
1226                      string
1227                      (coerce string '(simple-array character (*)))))
1228          (buffer (fill-pointer-output-stream-string stream))
1229          (current (fill-pointer buffer))
1230          (string-len (- end start))
1231          (dst-end (+ string-len current)))
1232     (declare (fixnum current dst-end string-len))
1233     (with-array-data ((workspace buffer) (dst-start) (dst-length))
1234       (declare (type (simple-array character (*)) workspace))
1235       (let ((offset-dst-end (+ dst-start dst-end))
1236             (offset-current (+ dst-start current)))
1237         (declare (fixnum offset-dst-end offset-current))
1238         (if (> offset-dst-end dst-length)
1239             (let* ((new-length (+ (the fixnum (* current 2)) string-len))
1240                    (new-workspace (make-string new-length)))
1241               (declare (type (simple-array character (*)) new-workspace))
1242               (%byte-blt workspace dst-start
1243                          new-workspace 0 current)
1244               (setf workspace new-workspace)
1245               (setf offset-current current)
1246               (setf offset-dst-end dst-end)
1247               (set-array-header buffer
1248                                 workspace
1249                                 new-length
1250                                 dst-end
1251                                 0
1252                                 new-length
1253                                 nil))
1254             (setf (fill-pointer buffer) dst-end))
1255         (%byte-blt string start
1256                    workspace offset-current offset-dst-end)))
1257     dst-end))
1258
1259 (defun fill-pointer-misc (stream operation &optional arg1 arg2)
1260   (declare (ignore arg1 arg2))
1261   (case operation
1262     (:file-position
1263      (let ((buffer (fill-pointer-output-stream-string stream)))
1264        (if arg1
1265            (setf (fill-pointer buffer)
1266                  (case arg1
1267                    (:start 0)
1268                    ;; Fill-pointer is always at fill-pointer we will
1269                    ;; make :END move to the end of the actual string.
1270                    (:end (array-total-size buffer))
1271                    ;; We allow moving beyond the end of string if the
1272                    ;; string is adjustable.
1273                    (t (when (>= arg1 (array-total-size buffer))
1274                         (if (adjustable-array-p buffer)
1275                             (adjust-array buffer arg1)
1276                             (error "Cannot move FILE-POSITION beyond the end ~
1277                                     of WITH-OUTPUT-TO-STRING stream ~
1278                                     constructed with non-adjustable string.")))
1279                       arg1)))
1280            (fill-pointer buffer))))
1281     (:charpos
1282      (let* ((buffer (fill-pointer-output-stream-string stream))
1283             (current (fill-pointer buffer)))
1284        (with-array-data ((string buffer) (start) (end current))
1285          (declare (simple-string string) (ignore start))
1286          (let ((found (position #\newline string :test #'char=
1287                                 :end end :from-end t)))
1288            (if found
1289                (- end (the fixnum found))
1290                current)))))
1291      (:element-type (array-element-type
1292                      (fill-pointer-output-stream-string stream)))))
1293 \f
1294 ;;;; indenting streams
1295
1296 (defstruct (indenting-stream (:include ansi-stream
1297                                        (out #'indenting-out)
1298                                        (sout #'indenting-sout)
1299                                        (misc #'indenting-misc))
1300                              (:constructor make-indenting-stream (stream))
1301                              (:copier nil))
1302   ;; the stream we're based on
1303   stream
1304   ;; how much we indent on each line
1305   (indentation 0))
1306
1307 #!+sb-doc
1308 (setf (fdocumentation 'make-indenting-stream 'function)
1309  "Return an output stream which indents its output by some amount.")
1310
1311 ;;; INDENTING-INDENT writes the correct number of spaces needed to indent
1312 ;;; output on the given STREAM based on the specified SUB-STREAM.
1313 (defmacro indenting-indent (stream sub-stream)
1314   ;; KLUDGE: bare magic number 60
1315   `(do ((i 0 (+ i 60))
1316         (indentation (indenting-stream-indentation ,stream)))
1317        ((>= i indentation))
1318      (%write-string
1319       "                                                     "
1320       ,sub-stream
1321       0
1322       (min 60 (- indentation i)))))
1323
1324 ;;; INDENTING-OUT writes a character to an indenting stream.
1325 (defun indenting-out (stream char)
1326   (let ((sub-stream (indenting-stream-stream stream)))
1327     (write-char char sub-stream)
1328     (if (char= char #\newline)
1329         (indenting-indent stream sub-stream))))
1330
1331 ;;; INDENTING-SOUT writes a string to an indenting stream.
1332 (defun indenting-sout (stream string start end)
1333   (declare (simple-string string) (fixnum start end))
1334   (do ((i start)
1335        (sub-stream (indenting-stream-stream stream)))
1336       ((= i end))
1337     (let ((newline (position #\newline string :start i :end end)))
1338       (cond (newline
1339              (%write-string string sub-stream i (1+ newline))
1340              (indenting-indent stream sub-stream)
1341              (setq i (+ newline 1)))
1342             (t
1343              (%write-string string sub-stream i end)
1344              (setq i end))))))
1345
1346 ;;; INDENTING-MISC just treats just the :LINE-LENGTH message
1347 ;;; differently. INDENTING-CHARPOS says the charpos is the charpos of
1348 ;;; the base stream minus the stream's indentation.
1349 (defun indenting-misc (stream operation &optional arg1 arg2)
1350   (let ((sub-stream (indenting-stream-stream stream)))
1351     (if (ansi-stream-p sub-stream)
1352         (let ((method (ansi-stream-misc sub-stream)))
1353           (case operation
1354             (:line-length
1355              (let ((line-length (funcall method sub-stream operation)))
1356                (if line-length
1357                    (- line-length (indenting-stream-indentation stream)))))
1358             (:charpos
1359              (let ((charpos (funcall method sub-stream operation)))
1360                (if charpos
1361                    (- charpos (indenting-stream-indentation stream)))))
1362             (t
1363              (funcall method sub-stream operation arg1 arg2))))
1364         ;; must be Gray streams FUNDAMENTAL-STREAM
1365         (case operation
1366           (:line-length
1367            (let ((line-length (stream-line-length sub-stream)))
1368              (if line-length
1369                  (- line-length (indenting-stream-indentation stream)))))
1370           (:charpos
1371            (let ((charpos (stream-line-column sub-stream)))
1372              (if charpos
1373                  (- charpos (indenting-stream-indentation stream)))))
1374           (t
1375            (stream-misc-dispatch sub-stream operation arg1 arg2))))))
1376
1377 (declaim (maybe-inline read-char unread-char read-byte listen))
1378 \f
1379 ;;;; case frobbing streams, used by FORMAT ~(...~)
1380
1381 (defstruct (case-frob-stream
1382             (:include ansi-stream
1383                       (misc #'case-frob-misc))
1384             (:constructor %make-case-frob-stream (target out sout))
1385             (:copier nil))
1386   (target (missing-arg) :type stream))
1387
1388 (defun make-case-frob-stream (target kind)
1389   #!+sb-doc
1390   "Return a stream that sends all output to the stream TARGET, but modifies
1391    the case of letters, depending on KIND, which should be one of:
1392      :upcase - convert to upper case.
1393      :downcase - convert to lower case.
1394      :capitalize - convert the first letter of words to upper case and the
1395         rest of the word to lower case.
1396      :capitalize-first - convert the first letter of the first word to upper
1397         case and everything else to lower case."
1398   (declare (type stream target)
1399            (type (member :upcase :downcase :capitalize :capitalize-first)
1400                  kind)
1401            (values stream))
1402   (if (case-frob-stream-p target)
1403       ;; If we are going to be writing to a stream that already does
1404       ;; case frobbing, why bother frobbing the case just so it can
1405       ;; frob it again?
1406       target
1407       (multiple-value-bind (out sout)
1408           (ecase kind
1409             (:upcase
1410              (values #'case-frob-upcase-out
1411                      #'case-frob-upcase-sout))
1412             (:downcase
1413              (values #'case-frob-downcase-out
1414                      #'case-frob-downcase-sout))
1415             (:capitalize
1416              (values #'case-frob-capitalize-out
1417                      #'case-frob-capitalize-sout))
1418             (:capitalize-first
1419              (values #'case-frob-capitalize-first-out
1420                      #'case-frob-capitalize-first-sout)))
1421         (%make-case-frob-stream target out sout))))
1422
1423 (defun case-frob-misc (stream op &optional arg1 arg2)
1424   (declare (type case-frob-stream stream))
1425   (case op
1426     (:close
1427      (set-closed-flame stream))
1428     (t
1429      (let ((target (case-frob-stream-target stream)))
1430        (if (ansi-stream-p target)
1431            (funcall (ansi-stream-misc target) target op arg1 arg2)
1432            (stream-misc-dispatch target op arg1 arg2))))))
1433
1434 (defun case-frob-upcase-out (stream char)
1435   (declare (type case-frob-stream stream)
1436            (type base-char char))
1437   (let ((target (case-frob-stream-target stream))
1438         (char (char-upcase char)))
1439     (if (ansi-stream-p target)
1440         (funcall (ansi-stream-out target) target char)
1441         (stream-write-char target char))))
1442
1443 (defun case-frob-upcase-sout (stream str start end)
1444   (declare (type case-frob-stream stream)
1445            (type simple-base-string str)
1446            (type index start)
1447            (type (or index null) end))
1448   (let* ((target (case-frob-stream-target stream))
1449          (len (length str))
1450          (end (or end len))
1451          (string (if (and (zerop start) (= len end))
1452                      (string-upcase str)
1453                      (nstring-upcase (subseq str start end))))
1454          (string-len (- end start)))
1455     (if (ansi-stream-p target)
1456         (funcall (ansi-stream-sout target) target string 0 string-len)
1457         (stream-write-string target string 0 string-len))))
1458
1459 (defun case-frob-downcase-out (stream char)
1460   (declare (type case-frob-stream stream)
1461            (type base-char char))
1462   (let ((target (case-frob-stream-target stream))
1463         (char (char-downcase char)))
1464     (if (ansi-stream-p target)
1465         (funcall (ansi-stream-out target) target char)
1466         (stream-write-char target char))))
1467
1468 (defun case-frob-downcase-sout (stream str start end)
1469   (declare (type case-frob-stream stream)
1470            (type simple-base-string str)
1471            (type index start)
1472            (type (or index null) end))
1473   (let* ((target (case-frob-stream-target stream))
1474          (len (length str))
1475          (end (or end len))
1476          (string (if (and (zerop start) (= len end))
1477                      (string-downcase str)
1478                      (nstring-downcase (subseq str start end))))
1479          (string-len (- end start)))
1480     (if (ansi-stream-p target)
1481         (funcall (ansi-stream-sout target) target string 0 string-len)
1482         (stream-write-string target string 0 string-len))))
1483
1484 (defun case-frob-capitalize-out (stream char)
1485   (declare (type case-frob-stream stream)
1486            (type base-char char))
1487   (let ((target (case-frob-stream-target stream)))
1488     (cond ((alphanumericp char)
1489            (let ((char (char-upcase char)))
1490              (if (ansi-stream-p target)
1491                  (funcall (ansi-stream-out target) target char)
1492                  (stream-write-char target char)))
1493            (setf (case-frob-stream-out stream) #'case-frob-capitalize-aux-out)
1494            (setf (case-frob-stream-sout stream)
1495                  #'case-frob-capitalize-aux-sout))
1496           (t
1497            (if (ansi-stream-p target)
1498                (funcall (ansi-stream-out target) target char)
1499                (stream-write-char target char))))))
1500
1501 (defun case-frob-capitalize-sout (stream str start end)
1502   (declare (type case-frob-stream stream)
1503            (type simple-base-string str)
1504            (type index start)
1505            (type (or index null) end))
1506   (let* ((target (case-frob-stream-target stream))
1507          (str (subseq str start end))
1508          (len (length str))
1509          (inside-word nil))
1510     (dotimes (i len)
1511       (let ((char (schar str i)))
1512         (cond ((not (alphanumericp char))
1513                (setf inside-word nil))
1514               (inside-word
1515                (setf (schar str i) (char-downcase char)))
1516               (t
1517                (setf inside-word t)
1518                (setf (schar str i) (char-upcase char))))))
1519     (when inside-word
1520       (setf (case-frob-stream-out stream)
1521             #'case-frob-capitalize-aux-out)
1522       (setf (case-frob-stream-sout stream)
1523             #'case-frob-capitalize-aux-sout))
1524     (if (ansi-stream-p target)
1525         (funcall (ansi-stream-sout target) target str 0 len)
1526         (stream-write-string target str 0 len))))
1527
1528 (defun case-frob-capitalize-aux-out (stream char)
1529   (declare (type case-frob-stream stream)
1530            (type base-char char))
1531   (let ((target (case-frob-stream-target stream)))
1532     (cond ((alphanumericp char)
1533            (let ((char (char-downcase char)))
1534              (if (ansi-stream-p target)
1535                  (funcall (ansi-stream-out target) target char)
1536                  (stream-write-char target char))))
1537           (t
1538            (if (ansi-stream-p target)
1539                (funcall (ansi-stream-out target) target char)
1540                (stream-write-char target char))
1541            (setf (case-frob-stream-out stream)
1542                  #'case-frob-capitalize-out)
1543            (setf (case-frob-stream-sout stream)
1544                  #'case-frob-capitalize-sout)))))
1545
1546 (defun case-frob-capitalize-aux-sout (stream str start end)
1547   (declare (type case-frob-stream stream)
1548            (type simple-base-string str)
1549            (type index start)
1550            (type (or index null) end))
1551   (let* ((target (case-frob-stream-target stream))
1552          (str (subseq str start end))
1553          (len (length str))
1554          (inside-word t))
1555     (dotimes (i len)
1556       (let ((char (schar str i)))
1557         (cond ((not (alphanumericp char))
1558                (setf inside-word nil))
1559               (inside-word
1560                (setf (schar str i) (char-downcase char)))
1561               (t
1562                (setf inside-word t)
1563                (setf (schar str i) (char-upcase char))))))
1564     (unless inside-word
1565       (setf (case-frob-stream-out stream)
1566             #'case-frob-capitalize-out)
1567       (setf (case-frob-stream-sout stream)
1568             #'case-frob-capitalize-sout))
1569     (if (ansi-stream-p target)
1570         (funcall (ansi-stream-sout target) target str 0 len)
1571         (stream-write-string target str 0 len))))
1572
1573 (defun case-frob-capitalize-first-out (stream char)
1574   (declare (type case-frob-stream stream)
1575            (type base-char char))
1576   (let ((target (case-frob-stream-target stream)))
1577     (cond ((alphanumericp char)
1578            (let ((char (char-upcase char)))
1579              (if (ansi-stream-p target)
1580                  (funcall (ansi-stream-out target) target char)
1581                  (stream-write-char target char)))
1582            (setf (case-frob-stream-out stream)
1583                  #'case-frob-downcase-out)
1584            (setf (case-frob-stream-sout stream)
1585                  #'case-frob-downcase-sout))
1586           (t
1587            (if (ansi-stream-p target)
1588                (funcall (ansi-stream-out target) target char)
1589                (stream-write-char target char))))))
1590
1591 (defun case-frob-capitalize-first-sout (stream str start end)
1592   (declare (type case-frob-stream stream)
1593            (type simple-base-string str)
1594            (type index start)
1595            (type (or index null) end))
1596   (let* ((target (case-frob-stream-target stream))
1597          (str (subseq str start end))
1598          (len (length str)))
1599     (dotimes (i len)
1600       (let ((char (schar str i)))
1601         (when (alphanumericp char)
1602           (setf (schar str i) (char-upcase char))
1603           (do ((i (1+ i) (1+ i)))
1604               ((= i len))
1605             (setf (schar str i) (char-downcase (schar str i))))
1606           (setf (case-frob-stream-out stream)
1607                 #'case-frob-downcase-out)
1608           (setf (case-frob-stream-sout stream)
1609                 #'case-frob-downcase-sout)
1610           (return))))
1611     (if (ansi-stream-p target)
1612         (funcall (ansi-stream-sout target) target str 0 len)
1613         (stream-write-string target str 0 len))))
1614 \f
1615 ;;;; READ-SEQUENCE
1616
1617 (defun read-sequence (seq stream &key (start 0) end)
1618   #!+sb-doc
1619   "Destructively modify SEQ by reading elements from STREAM.
1620   That part of SEQ bounded by START and END is destructively modified by
1621   copying successive elements into it from STREAM. If the end of file
1622   for STREAM is reached before copying all elements of the subsequence,
1623   then the extra elements near the end of sequence are not updated, and
1624   the index of the next element is returned."
1625   (declare (type sequence seq)
1626            (type stream stream)
1627            (type index start)
1628            (type sequence-end end)
1629            (values index))
1630   (if (ansi-stream-p stream)
1631       (ansi-stream-read-sequence seq stream start end)
1632       ;; must be Gray streams FUNDAMENTAL-STREAM
1633       (stream-read-sequence stream seq start end)))
1634
1635 (defun ansi-stream-read-sequence (seq stream start %end)
1636   (declare (type sequence seq)
1637            (type ansi-stream stream)
1638            (type index start)
1639            (type sequence-end %end)
1640            (values index))
1641   (let ((end (or %end (length seq))))
1642     (declare (type index end))
1643     (etypecase seq
1644       (list
1645        (let ((read-function
1646               (if (subtypep (stream-element-type stream) 'character)
1647                   #'read-char
1648                   #'read-byte)))
1649          (do ((rem (nthcdr start seq) (rest rem))
1650               (i start (1+ i)))
1651              ((or (endp rem) (>= i end)) i)
1652            (declare (type list rem)
1653                     (type index i))
1654            (let ((el (funcall read-function stream nil :eof)))
1655              (when (eq el :eof)
1656                (return i))
1657              (setf (first rem) el)))))
1658       (vector
1659        (with-array-data ((data seq) (offset-start start) (offset-end end))
1660          (typecase data
1661            ((or (simple-array (unsigned-byte 8) (*))
1662                 (simple-array (signed-byte 8) (*))
1663                 simple-string)
1664             (let* ((numbytes (- end start))
1665                    (bytes-read (sb!sys:read-n-bytes stream
1666                                                     data
1667                                                     offset-start
1668                                                     numbytes
1669                                                     nil)))
1670               (if (< bytes-read numbytes)
1671                   (+ start bytes-read)
1672                   end)))
1673            (t
1674             (let ((read-function
1675                    (if (subtypep (stream-element-type stream) 'character)
1676                        #'read-char
1677                        #'read-byte)))
1678               (do ((i offset-start (1+ i)))
1679                   ((>= i offset-end) end)
1680                 (declare (type index i))
1681                 (let ((el (funcall read-function stream nil :eof)))
1682                   (when (eq el :eof)
1683                     (return (+ start (- i offset-start))))
1684                   (setf (aref data i) el)))))))))))
1685 \f
1686 ;;;; WRITE-SEQUENCE
1687
1688 (defun write-sequence (seq stream &key (start 0) (end nil))
1689   #!+sb-doc
1690   "Write the elements of SEQ bounded by START and END to STREAM."
1691   (declare (type sequence seq)
1692            (type stream stream)
1693            (type index start)
1694            (type sequence-end end)
1695            (values sequence))
1696   (if (ansi-stream-p stream)
1697       (ansi-stream-write-sequence seq stream start end)
1698       ;; must be Gray-streams FUNDAMENTAL-STREAM
1699       (stream-write-sequence stream seq start end)))
1700
1701 (defun ansi-stream-write-sequence (seq stream start %end)
1702   (declare (type sequence seq)
1703            (type ansi-stream stream)
1704            (type index start)
1705            (type sequence-end %end)
1706            (values sequence))
1707   (let ((end (or %end (length seq))))
1708     (declare (type index end))
1709     (etypecase seq
1710       (list
1711        (let ((write-function
1712               (if (subtypep (stream-element-type stream) 'character)
1713                   #'write-char
1714                   #'write-byte)))
1715          (do ((rem (nthcdr start seq) (rest rem))
1716               (i start (1+ i)))
1717              ((or (endp rem) (>= i end)) seq)
1718            (declare (type list rem)
1719                     (type index i))
1720            (funcall write-function (first rem) stream))))
1721       (string
1722        (%write-string seq stream start end))
1723       (vector
1724        (let ((write-function
1725               (if (subtypep (stream-element-type stream) 'character)
1726                   #'write-char
1727                   #'write-byte)))
1728          (do ((i start (1+ i)))
1729              ((>= i end) seq)
1730            (declare (type index i))
1731            (funcall write-function (aref seq i) stream)))))))
1732 \f
1733 ;;;; etc.