src/code/sxhash.lisp

   1 ;;;; that part of SXHASH logic which runs not only in the target Lisp but
   2 ;;;; in the cross-compilation host Lisp
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14
  15 (sb!xc:define-modify-macro mixf (y) mix)
  16
  17 ;;; SXHASH of FLOAT values is defined directly in terms of DEFTRANSFORM in
  18 ;;; order to avoid boxing.
  19 (deftransform sxhash ((x) (single-float))
  20   '(let* ((val (+ 0.0f0 x))
  21           (bits (logand (single-float-bits val) #.(1- (ash 1 32)))))
  22      (logxor 66194023
  23              (sxhash (the fixnum
  24                           (logand most-positive-fixnum
  25                                   (logxor bits
  26                                           (ash bits -7))))))))
  27 (deftransform sxhash ((x) (double-float))
  28   '(let* ((val (+ 0.0d0 x))
  29           (hi (logand (double-float-high-bits val) #.(1- (ash 1 32))))
  30           (lo (double-float-low-bits val))
  31           (hilo (logxor hi lo)))
  32      (logxor 475038542
  33              (sxhash (the fixnum
  34                           (logand most-positive-fixnum
  35                                   (logxor hilo
  36                                           (ash hilo -7))))))))
  37
  38 ;;; SXHASH of FIXNUM values is defined as a DEFTRANSFORM because it's so
  39 ;;; simple.
  40 (deftransform sxhash ((x) (fixnum))
  41   '(logand most-positive-fixnum
  42            (logxor (ash (logand x (ash most-positive-fixnum -4)) 4)
  43                    (logand (ash x -1) most-positive-fixnum) ; to get sign bit into hash
  44                    361475658)))
  45
  46 ;;; SXHASH of SIMPLE-BIT-VECTOR values is defined as a DEFTRANSFORM
  47 ;;; because it is endian-dependent.
  48 (deftransform sxhash ((x) (simple-bit-vector))
  49   `(let ((result 410823708))
  50     (declare (type fixnum result))
  51     (let ((length (length x)))
  52       (cond
  53         ((= length 0) (mix result (sxhash 0)))
  54         (t
  55          (mixf result (sxhash (length x)))
  56          (do* ((i sb!vm:vector-data-offset (+ i 1))
  57                ;; FIXME: should we respect DEPTHOID?  SXHASH on
  58                ;; strings doesn't seem to...
  59                (end-1 (+ sb!vm:vector-data-offset
  60                          (floor (1- length) sb!vm:n-word-bits))))
  61               ((= i end-1)
  62                (let ((num
  63                       (logand
  64                        (ash (1- (ash 1 (mod length sb!vm:n-word-bits)))
  65                             ,(ecase sb!c:*backend-byte-order*
  66                                (:little-endian 0)
  67                                (:big-endian
  68                                 '(- sb!vm:n-word-bits
  69                                     (mod length sb!vm:n-word-bits)))))
  70                        (%raw-bits x i))))
  71                  (mix result ,(ecase sb!c:*backend-byte-order*
  72                                 (:little-endian
  73                                  '(logand num most-positive-fixnum))
  74                                 (:big-endian
  75                                  '(ash num (- sb!vm:n-lowtag-bits)))))))
  76            (declare (type index i end-1))
  77            (let ((num (%raw-bits x i)))
  78              (mixf result ,(ecase sb!c:*backend-byte-order*
  79                              (:little-endian
  80                               '(logand num most-positive-fixnum))
  81                              ;; FIXME: I'm not certain that
  82                              ;; N-LOWTAG-BITS is the clearest way of
  83                              ;; expressing this: it's essentially the
  84                              ;; difference between `(UNSIGNED-BYTE
  85                              ;; ,SB!VM:N-WORD-BITS) and (AND FIXNUM
  86                              ;; UNSIGNED-BYTE).
  87                              (:big-endian
  88                               '(ash num (- sb!vm:n-lowtag-bits))))))))))))
  89
  90 ;;; Some other common SXHASH cases are defined as DEFTRANSFORMs in
  91 ;;; order to avoid having to do TYPECASE at runtime.
  92 ;;;
  93 ;;; We also take the opportunity to handle the cases of constant
  94 ;;; strings, and of symbols whose names are known at compile time;
  95 ;;; except that since SXHASH on the cross-compilation host is not in
  96 ;;; general compatible with SXHASH on the target SBCL, we can't so
  97 ;;; easily do this optimization in the cross-compiler, and SBCL itself
  98 ;;; doesn't seem to need this optimization, so we don't try.
  99 (deftransform sxhash ((x) (simple-string))
 100   (if #+sb-xc-host nil #-sb-xc-host (constant-lvar-p x)
 101       (sxhash (lvar-value x))
 102       '(%sxhash-simple-string x)))
 103 (deftransform sxhash ((x) (symbol))
 104   (if #+sb-xc-host nil #-sb-xc-host (constant-lvar-p x)
 105       (sxhash (lvar-value x))
 106       (if (csubtypep (lvar-type x) (specifier-type 'null))
 107           ;; FIXME: this isn't in fact as optimized as it could be;
 108           ;; this does a memory load, whereas (because we know the
 109           ;; layout of NIL) we could simply take the address of NIL
 110           ;; (or the contents of NULL-TN) and mask off the appropriate
 111           ;; bits, since SYMBOL-HASH of NIL is also NIL's CDR, which
 112           ;; is NIL.  -- CSR, 2004-07-14
 113           '(symbol-hash x)
 114           ;; Cache the value of the symbol's sxhash in the symbol-hash
 115           ;; slot.
 116           '(let ((result (symbol-hash x)))
 117             ;; 0 marks uninitialized slot. We can't use negative
 118             ;; values for the uninitialized slots since NIL might be
 119             ;; located so high in memory on some platforms that its
 120             ;; SYMBOL-HASH (which contains NIL itself) is a negative
 121             ;; fixnum.
 122             (if (= 0 result)
 123                 (let ((sxhash (%sxhash-simple-string (symbol-name x))))
 124                   ;; We could do a (logior sxhash #x10000000) to
 125                   ;; ensure that we never store a 0 in the
 126                   ;; slot. However, it's such an unlikely event
 127                   ;; (1/5e8?) that it makes more sense to optimize for
 128                   ;; the common case...
 129                   (%set-symbol-hash x sxhash)
 130                   sxhash)
 131                 result)))))