src/code/symbol.lisp

   1 ;;;; code to manipulate symbols (but not packages, which are handled
   2 ;;;; elsewhere)
   3 ;;;;
   4 ;;;; Many of these definitions are trivial interpreter entries to
   5 ;;;; functions open-coded by the compiler.
   6
   7 ;;;; This software is part of the SBCL system. See the README file for
   8 ;;;; more information.
   9 ;;;;
  10 ;;;; This software is derived from the CMU CL system, which was
  11 ;;;; written at Carnegie Mellon University and released into the
  12 ;;;; public domain. The software is in the public domain and is
  13 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  14 ;;;; files for more information.
  15
  16 (in-package "SB!IMPL")
  17
  18 (declaim (maybe-inline get get2 get3 %put getf remprop %putf get-properties keywordp))
  19
  20 (defun symbol-value (symbol)
  21   #!+sb-doc
  22   "Return SYMBOL's current bound value."
  23   (declare (optimize (safety 1)))
  24   (symbol-value symbol))
  25
  26 (defun boundp (symbol)
  27   #!+sb-doc
  28   "Return non-NIL if SYMBOL is bound to a value."
  29   (boundp symbol))
  30
  31 (defun set (symbol new-value)
  32   #!+sb-doc
  33   "Set SYMBOL's value cell to NEW-VALUE."
  34   (declare (type symbol symbol))
  35   (about-to-modify-symbol-value symbol)
  36   (%set-symbol-value symbol new-value))
  37
  38 (defun %set-symbol-value (symbol new-value)
  39   (%set-symbol-value symbol new-value))
  40
  41 (defun makunbound (symbol)
  42   #!+sb-doc
  43   "Make SYMBOL unbound, removing any value it may currently have."
  44   (with-single-package-locked-error (:symbol symbol "unbinding the symbol ~A")
  45     (set symbol
  46          (%primitive sb!c:make-other-immediate-type
  47                      0
  48                      sb!vm:unbound-marker-widetag))
  49     symbol))
  50
  51 ;;; Return the built-in hash value for SYMBOL.
  52 (defun symbol-hash (symbol)
  53   (symbol-hash symbol))
  54
  55 (defun symbol-function (symbol)
  56   #!+sb-doc
  57   "Return SYMBOL's current function definition. Settable with SETF."
  58   (%coerce-name-to-fun symbol))
  59
  60 (defun (setf symbol-function) (new-value symbol)
  61   (declare (type symbol symbol) (type function new-value))
  62   (with-single-package-locked-error
  63       (:symbol symbol "setting the symbol-function of ~A")
  64     (setf (%coerce-name-to-fun symbol) new-value)))
  65
  66 (defun symbol-plist (symbol)
  67   #!+sb-doc
  68   "Return SYMBOL's property list."
  69   (symbol-plist symbol))
  70
  71 (defun %set-symbol-plist (symbol new-value)
  72   (setf (symbol-plist symbol) new-value))
  73
  74 (defun symbol-name (symbol)
  75   #!+sb-doc
  76   "Return SYMBOL's name as a string."
  77   (symbol-name symbol))
  78
  79 (defun symbol-package (symbol)
  80   #!+sb-doc
  81   "Return the package SYMBOL was interned in, or NIL if none."
  82   (symbol-package symbol))
  83
  84 (defun %set-symbol-package (symbol package)
  85   (declare (type symbol symbol))
  86   (%set-symbol-package symbol package))
  87
  88 (defun make-symbol (string)
  89   #!+sb-doc
  90   "Make and return a new symbol with the STRING as its print name."
  91   (make-symbol string))
  92
  93 (defun get (symbol indicator &optional (default nil))
  94   #!+sb-doc
  95   "Look on the property list of SYMBOL for the specified INDICATOR. If this
  96   is found, return the associated value, else return DEFAULT."
  97   (get3 symbol indicator default))
  98
  99 (defun get2 (symbol indicator)
 100   (get3 symbol indicator nil))
 101 #|
 102   (let (cdr-pl)
 103     (do ((pl (symbol-plist symbol) (cdr cdr-pl)))
 104         ((atom pl) nil)
 105       (setf cdr-pl (cdr pl))
 106       (cond ((atom cdr-pl)
 107              (error "~S has an odd number of items in its property list."
 108                     symbol))
 109             ((eq (car pl) indicator)
 110              (return (car cdr-pl)))))))
 111 |#
 112
 113 (defun get3 (symbol indicator default)
 114   (let (cdr-pl)
 115     (do ((pl (symbol-plist symbol) (cdr cdr-pl)))
 116         ((atom pl) default)
 117       (setq cdr-pl (cdr pl))
 118       (cond ((atom cdr-pl)
 119              (error "~S has an odd number of items in its property list."
 120                     symbol))
 121             ((eq (car pl) indicator)
 122              (return (car cdr-pl)))))))
 123
 124 (defun %put (symbol indicator value)
 125   #!+sb-doc
 126   "The VALUE is added as a property of SYMBOL under the specified INDICATOR.
 127   Returns VALUE."
 128   (do ((pl (symbol-plist symbol) (cddr pl)))
 129       ((endp pl)
 130        (setf (symbol-plist symbol)
 131              (list* indicator value (symbol-plist symbol)))
 132        value)
 133     (cond ((endp (cdr pl))
 134            (error "~S has an odd number of items in its property list."
 135                   symbol))
 136           ((eq (car pl) indicator)
 137            (rplaca (cdr pl) value)
 138            (return value)))))
 139
 140 (defun remprop (symbol indicator)
 141   #!+sb-doc
 142   "Look on property list of SYMBOL for property with specified
 143   INDICATOR. If found, splice this indicator and its value out of
 144   the plist, and return the tail of the original list starting with
 145   INDICATOR. If not found, return () with no side effects.
 146
 147   NOTE: The ANSI specification requires REMPROP to return true (not false)
 148   or false (the symbol NIL). Portable code should not rely on any other value."
 149   (do ((pl (symbol-plist symbol) (cddr pl))
 150        (prev nil pl))
 151       ((atom pl) nil)
 152     (cond ((atom (cdr pl))
 153            (error "~S has an odd number of items in its property list."
 154                   symbol))
 155           ((eq (car pl) indicator)
 156            (cond (prev (rplacd (cdr prev) (cddr pl)))
 157                  (t
 158                   (setf (symbol-plist symbol) (cddr pl))))
 159            (return pl)))))
 160
 161 (defun getf (place indicator &optional (default ()))
 162   #!+sb-doc
 163   "Search the property list stored in Place for an indicator EQ to INDICATOR.
 164   If one is found, return the corresponding value, else return DEFAULT."
 165   (do ((plist place (cddr plist)))
 166       ((null plist) default)
 167     (cond ((atom (cdr plist))
 168            (error 'simple-type-error
 169                   :format-control "malformed property list: ~S."
 170                   :format-arguments (list place)
 171                   :datum (cdr plist)
 172                   :expected-type 'cons))
 173           ((eq (car plist) indicator)
 174            (return (cadr plist))))))
 175
 176 (defun %putf (place property new-value)
 177   (declare (type list place))
 178   (do ((plist place (cddr plist)))
 179       ((endp plist) (list* property new-value place))
 180     (declare (type list plist))
 181     (when (eq (car plist) property)
 182       (setf (cadr plist) new-value)
 183       (return place))))
 184
 185 (defun get-properties (place indicator-list)
 186   #!+sb-doc
 187   "Like GETF, except that INDICATOR-LIST is a list of indicators which will
 188   be looked for in the property list stored in PLACE. Three values are
 189   returned, see manual for details."
 190   (do ((plist place (cddr plist)))
 191       ((null plist) (values nil nil nil))
 192     (cond ((atom (cdr plist))
 193            (error 'simple-type-error
 194                   :format-control "malformed property list: ~S."
 195                   :format-arguments (list place)
 196                   :datum (cdr plist)
 197                   :expected-type 'cons))
 198           ((memq (car plist) indicator-list)
 199            (return (values (car plist) (cadr plist) plist))))))
 200
 201 (defun copy-symbol (symbol &optional (copy-props nil) &aux new-symbol)
 202   #!+sb-doc
 203   "Make and return a new uninterned symbol with the same print name
 204   as SYMBOL. If COPY-PROPS is false, the new symbol is neither bound
 205   nor fbound and has no properties, else it has a copy of SYMBOL's
 206   function, value and property list."
 207   (declare (type symbol symbol))
 208   (setq new-symbol (make-symbol (symbol-name symbol)))
 209   (when copy-props
 210     (%set-symbol-value new-symbol
 211                        (%primitive sb!c:fast-symbol-value symbol))
 212     (setf (symbol-plist new-symbol)
 213           (copy-list (symbol-plist symbol)))
 214     (when (fboundp symbol)
 215       (setf (symbol-function new-symbol) (symbol-function symbol))))
 216   new-symbol)
 217
 218 ;;; FIXME: This declaration should be redundant.
 219 (declaim (special *keyword-package*))
 220
 221 (defun keywordp (object)
 222   #!+sb-doc
 223   "Return true if Object is a symbol in the \"KEYWORD\" package."
 224   (and (symbolp object)
 225        (eq (symbol-package object) *keyword-package*)))
 226 \f
 227 ;;;; GENSYM and friends
 228
 229 (defvar *gensym-counter* 0
 230   #!+sb-doc
 231   "counter for generating unique GENSYM symbols")
 232 (declaim (type unsigned-byte *gensym-counter*))
 233
 234 (defun gensym (&optional (thing "G"))
 235   #!+sb-doc
 236   "Creates a new uninterned symbol whose name is a prefix string (defaults
 237    to \"G\"), followed by a decimal number. Thing, when supplied, will
 238    alter the prefix if it is a string, or be used for the decimal number
 239    if it is a number, of this symbol. The default value of the number is
 240    the current value of *gensym-counter* which is incremented each time
 241    it is used."
 242   (let ((old *gensym-counter*))
 243     (unless (numberp thing)
 244       (let ((new (etypecase old
 245                    (index (1+ old))
 246                    (unsigned-byte (1+ old)))))
 247         (declare (optimize (speed 3) (safety 0)(inhibit-warnings 3)))
 248         (setq *gensym-counter* new)))
 249     (multiple-value-bind (prefix int)
 250         (etypecase thing
 251           (simple-string (values thing old))
 252           (fixnum (values "G" thing))
 253           (string (values (coerce thing 'simple-string) old)))
 254       (declare (simple-string prefix))
 255       (make-symbol
 256        (concatenate 'simple-string prefix
 257                     (the simple-string
 258                          (quick-integer-to-string int)))))))
 259
 260 (defvar *gentemp-counter* 0)
 261 (declaim (type unsigned-byte *gentemp-counter*))
 262
 263 (defun gentemp (&optional (prefix "T") (package (sane-package)))
 264   #!+sb-doc
 265   "Creates a new symbol interned in package PACKAGE with the given PREFIX."
 266   (declare (type string prefix))
 267   (loop
 268     (let ((*print-base* 10)
 269           (*print-radix* nil)
 270           (*print-pretty* nil)
 271           (new-pname (format nil "~A~D" prefix (incf *gentemp-counter*))))
 272       (multiple-value-bind (symbol existsp) (find-symbol new-pname package)
 273         (declare (ignore symbol))
 274         (unless existsp (return (values (intern new-pname package))))))))