src/code/symbol.lisp

   1 ;;;; code to manipulate symbols (but not packages, which are handled
   2 ;;;; elsewhere)
   3 ;;;;
   4 ;;;; Many of these definitions are trivial interpreter entries to
   5 ;;;; functions open-coded by the compiler.
   6
   7 ;;;; This software is part of the SBCL system. See the README file for
   8 ;;;; more information.
   9 ;;;;
  10 ;;;; This software is derived from the CMU CL system, which was
  11 ;;;; written at Carnegie Mellon University and released into the
  12 ;;;; public domain. The software is in the public domain and is
  13 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  14 ;;;; files for more information.
  15
  16 (in-package "SB!IMPL")
  17
  18 (declaim (maybe-inline get %put getf remprop %putf get-properties keywordp))
  19
  20 (defun symbol-value (symbol)
  21   #!+sb-doc
  22   "Return SYMBOL's current bound value."
  23   (declare (optimize (safety 1)))
  24   (symbol-value symbol))
  25
  26 (defun boundp (symbol)
  27   #!+sb-doc
  28   "Return non-NIL if SYMBOL is bound to a value."
  29   (boundp symbol))
  30
  31 (defun set (symbol new-value)
  32   #!+sb-doc
  33   "Set SYMBOL's value cell to NEW-VALUE."
  34   (declare (type symbol symbol))
  35   (about-to-modify-symbol-value symbol)
  36   (%set-symbol-value symbol new-value))
  37
  38 (defun %set-symbol-value (symbol new-value)
  39   (%set-symbol-value symbol new-value))
  40
  41 (defun makunbound (symbol)
  42   #!+sb-doc
  43   "Make SYMBOL unbound, removing any value it may currently have."
  44   (set symbol
  45        (%primitive sb!c:make-other-immediate-type
  46                    0
  47                    sb!vm:unbound-marker-widetag))
  48   symbol)
  49
  50 ;;; Return the built-in hash value for SYMBOL.
  51 #!+(or x86 mips) ;; only backends for which a SYMBOL-HASH vop exists
  52 (defun symbol-hash (symbol)
  53   (symbol-hash symbol))
  54
  55 ;;; Compute the hash value for SYMBOL.
  56 #!-(or x86 mips)
  57 (defun symbol-hash (symbol)
  58   (%sxhash-simple-string (symbol-name symbol)))
  59
  60 (defun symbol-function (symbol)
  61   #!+sb-doc
  62   "Return SYMBOL's current function definition. Settable with SETF."
  63   (%coerce-name-to-fun symbol))
  64
  65 (defun (setf symbol-function) (new-value symbol)
  66   (declare (type symbol symbol) (type function new-value))
  67   (setf (%coerce-name-to-fun symbol) new-value))
  68
  69 (defun symbol-plist (symbol)
  70   #!+sb-doc
  71   "Return SYMBOL's property list."
  72   (symbol-plist symbol))
  73
  74 (defun %set-symbol-plist (symbol new-value)
  75   (setf (symbol-plist symbol) new-value))
  76
  77 (defun symbol-name (symbol)
  78   #!+sb-doc
  79   "Return SYMBOL's name as a string."
  80   (symbol-name symbol))
  81
  82 (defun symbol-package (symbol)
  83   #!+sb-doc
  84   "Return the package SYMBOL was interned in, or NIL if none."
  85   (symbol-package symbol))
  86
  87 (defun %set-symbol-package (symbol package)
  88   (declare (type symbol symbol))
  89   (%set-symbol-package symbol package))
  90
  91 (defun make-symbol (string)
  92   #!+sb-doc
  93   "Make and return a new symbol with the STRING as its print name."
  94   (make-symbol string))
  95
  96 (defun get (symbol indicator &optional (default nil))
  97   #!+sb-doc
  98   "Look on the property list of SYMBOL for the specified INDICATOR. If this
  99   is found, return the associated value, else return DEFAULT."
 100   (do ((pl (symbol-plist symbol) (cddr pl)))
 101       ((atom pl) default)
 102     (cond ((atom (cdr pl))
 103            (error "~S has an odd number of items in its property list."
 104                    symbol))
 105           ((eq (car pl) indicator)
 106            (return (cadr pl))))))
 107
 108 (defun %put (symbol indicator value)
 109   #!+sb-doc
 110   "The VALUE is added as a property of SYMBOL under the specified INDICATOR.
 111   Returns VALUE."
 112   (do ((pl (symbol-plist symbol) (cddr pl)))
 113       ((endp pl)
 114        (setf (symbol-plist symbol)
 115              (list* indicator value (symbol-plist symbol)))
 116        value)
 117     (cond ((endp (cdr pl))
 118            (error "~S has an odd number of items in its property list."
 119                   symbol))
 120           ((eq (car pl) indicator)
 121            (rplaca (cdr pl) value)
 122            (return value)))))
 123
 124 (defun remprop (symbol indicator)
 125   #!+sb-doc
 126   "Look on property list of SYMBOL for property with specified
 127   INDICATOR. If found, splice this indicator and its value out of
 128   the plist, and return the tail of the original list starting with
 129   INDICATOR. If not found, return () with no side effects.
 130
 131   NOTE: The ANSI specification requires REMPROP to return true (not false)
 132   or false (the symbol NIL). Portable code should not rely on any other value."
 133   (do ((pl (symbol-plist symbol) (cddr pl))
 134        (prev nil pl))
 135       ((atom pl) nil)
 136     (cond ((atom (cdr pl))
 137            (error "~S has an odd number of items in its property list."
 138                   symbol))
 139           ((eq (car pl) indicator)
 140            (cond (prev (rplacd (cdr prev) (cddr pl)))
 141                  (t
 142                   (setf (symbol-plist symbol) (cddr pl))))
 143            (return pl)))))
 144
 145 (defun getf (place indicator &optional (default ()))
 146   #!+sb-doc
 147   "Search the property list stored in Place for an indicator EQ to INDICATOR.
 148   If one is found, return the corresponding value, else return DEFAULT."
 149   (do ((plist place (cddr plist)))
 150       ((null plist) default)
 151     (cond ((atom (cdr plist))
 152            (error "~S is a malformed property list."
 153                   place))
 154           ((eq (car plist) indicator)
 155            (return (cadr plist))))))
 156
 157 (defun %putf (place property new-value)
 158   (declare (type list place))
 159   (do ((plist place (cddr plist)))
 160       ((endp plist) (list* property new-value place))
 161     (declare (type list plist))
 162     (when (eq (car plist) property)
 163       (setf (cadr plist) new-value)
 164       (return place))))
 165
 166 (defun get-properties (place indicator-list)
 167   #!+sb-doc
 168   "Like GETF, except that INDICATOR-LIST is a list of indicators which will
 169   be looked for in the property list stored in PLACE. Three values are
 170   returned, see manual for details."
 171   (do ((plist place (cddr plist)))
 172       ((null plist) (values nil nil nil))
 173     (cond ((atom (cdr plist))
 174            (error "~S is a malformed proprty list."
 175                   place))
 176           ((memq (car plist) indicator-list)
 177            (return (values (car plist) (cadr plist) plist))))))
 178
 179 (defun copy-symbol (symbol &optional (copy-props nil) &aux new-symbol)
 180   #!+sb-doc
 181   "Make and return a new uninterned symbol with the same print name
 182   as SYMBOL. If COPY-PROPS is false, the new symbol is neither bound
 183   nor fbound and has no properties, else it has a copy of SYMBOL's
 184   function, value and property list."
 185   (declare (type symbol symbol))
 186   (setq new-symbol (make-symbol (symbol-name symbol)))
 187   (when copy-props
 188     (%set-symbol-value new-symbol
 189                        (%primitive sb!c:fast-symbol-value symbol))
 190     (setf (symbol-plist new-symbol)
 191           (copy-list (symbol-plist symbol)))
 192     (when (fboundp symbol)
 193       (setf (symbol-function new-symbol) (symbol-function symbol))))
 194   new-symbol)
 195
 196 ;;; FIXME: This declaration should be redundant.
 197 (declaim (special *keyword-package*))
 198
 199 (defun keywordp (object)
 200   #!+sb-doc
 201   "Return true if Object is a symbol in the \"KEYWORD\" package."
 202   (and (symbolp object)
 203        (eq (symbol-package object) *keyword-package*)))
 204 \f
 205 ;;;; GENSYM and friends
 206
 207 (defvar *gensym-counter* 0
 208   #!+sb-doc
 209   "counter for generating unique GENSYM symbols")
 210 (declaim (type unsigned-byte *gensym-counter*))
 211
 212 (defun gensym (&optional (thing "G"))
 213   #!+sb-doc
 214   "Creates a new uninterned symbol whose name is a prefix string (defaults
 215    to \"G\"), followed by a decimal number. Thing, when supplied, will
 216    alter the prefix if it is a string, or be used for the decimal number
 217    if it is a number, of this symbol. The default value of the number is
 218    the current value of *gensym-counter* which is incremented each time
 219    it is used."
 220   (let ((old *gensym-counter*))
 221     (unless (numberp thing)
 222       (let ((new (etypecase old
 223                    (index (1+ old))
 224                    (unsigned-byte (1+ old)))))
 225         (declare (optimize (speed 3) (safety 0)(inhibit-warnings 3)))
 226         (setq *gensym-counter* new)))
 227     (multiple-value-bind (prefix int)
 228         (etypecase thing
 229           (simple-string (values thing old))
 230           (fixnum (values "G" thing))
 231           (string (values (coerce thing 'simple-string) old)))
 232       (declare (simple-string prefix))
 233       (make-symbol
 234        (concatenate 'simple-string prefix
 235                     (the simple-string
 236                          (quick-integer-to-string int)))))))
 237
 238 (defvar *gentemp-counter* 0)
 239 (declaim (type unsigned-byte *gentemp-counter*))
 240
 241 (defun gentemp (&optional (prefix "T") (package (sane-package)))
 242   #!+sb-doc
 243   "Creates a new symbol interned in package PACKAGE with the given PREFIX."
 244   (declare (type string prefix))
 245   (loop
 246     (let ((*print-base* 10)
 247           (*print-radix* nil)
 248           (*print-pretty* nil)
 249           (new-pname (format nil "~A~D" prefix (incf *gentemp-counter*))))
 250       (multiple-value-bind (symbol existsp) (find-symbol new-pname package)
 251         (declare (ignore symbol))
 252         (unless existsp (return (values (intern new-pname package))))))))