src/code/target-alieneval.lisp

   1 ;;;; This file contains parts of the ALIEN implementation that
   2 ;;;; are not part of the compiler.
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!ALIEN")
  14
  15 (/show0 "target-alieneval.lisp 15")
  16 \f
  17 ;;;; alien variables
  18
  19 ;;; Make a string out of the symbol, converting all uppercase letters to
  20 ;;; lower case and hyphens into underscores.
  21 (eval-when (:compile-toplevel :load-toplevel :execute)
  22   (defun guess-alien-name-from-lisp-name (lisp-name)
  23     (declare (type symbol lisp-name))
  24     (nsubstitute #\_ #\- (string-downcase (symbol-name lisp-name)))))
  25
  26 ;;; The opposite of GUESS-ALIEN-NAME-FROM-LISP-NAME. Make a symbol out
  27 ;;; of the string, converting all lowercase letters to uppercase and
  28 ;;; underscores into hyphens.
  29 (eval-when (:compile-toplevel :load-toplevel :execute)
  30   (defun guess-lisp-name-from-alien-name (alien-name)
  31     (declare (type simple-string alien-name))
  32     (intern (nsubstitute #\- #\_ (string-upcase alien-name)))))
  33
  34 ;;; Extract the Lisp and alien names from NAME. If only one is given,
  35 ;;; guess the other.
  36 (eval-when (:compile-toplevel :load-toplevel :execute)
  37   (defun pick-lisp-and-alien-names (name)
  38     (etypecase name
  39       (string
  40        (values (guess-lisp-name-from-alien-name name) name))
  41       (symbol
  42        (values name (guess-alien-name-from-lisp-name name)))
  43       (list
  44        (unless (proper-list-of-length-p name 2)
  45          (error "badly formed alien name"))
  46        (values (cadr name) (car name))))))
  47
  48 (defmacro define-alien-variable (name type &environment env)
  49   #!+sb-doc
  50   "Define NAME as an external alien variable of type TYPE. NAME should be
  51    a list of a string holding the alien name and a symbol to use as the Lisp
  52    name. If NAME is just a symbol or string, then the other name is guessed
  53    from the one supplied."
  54   (multiple-value-bind (lisp-name alien-name) (pick-lisp-and-alien-names name)
  55     (with-auxiliary-alien-types env
  56       (let ((alien-type (parse-alien-type type env)))
  57         `(eval-when (:compile-toplevel :load-toplevel :execute)
  58            ,@(when *new-auxiliary-types*
  59                `((%def-auxiliary-alien-types ',*new-auxiliary-types*)))
  60            (%define-alien-variable ',lisp-name
  61                                    ',alien-name
  62                                    ',alien-type))))))
  63
  64 (defmacro def-alien-variable (&rest rest)
  65   (deprecation-warning 'def-alien-variable 'define-alien-variable)
  66   `(define-alien-variable ,@rest))
  67
  68 ;;; Do the actual work of DEFINE-ALIEN-VARIABLE.
  69 (eval-when (:compile-toplevel :load-toplevel :execute)
  70   (defun %define-alien-variable (lisp-name alien-name type)
  71     (setf (info :variable :kind lisp-name) :alien)
  72     (setf (info :variable :where-from lisp-name) :defined)
  73     (clear-info :variable :constant-value lisp-name)
  74     (setf (info :variable :alien-info lisp-name)
  75           (make-heap-alien-info :type type
  76                                 :sap-form `(foreign-symbol-sap ',alien-name t)))))
  77
  78 (defmacro extern-alien (name type &environment env)
  79   #!+sb-doc
  80   "Access the alien variable named NAME, assuming it is of type TYPE. This
  81    is SETFable."
  82   (let* ((alien-name (etypecase name
  83                        (symbol (guess-alien-name-from-lisp-name name))
  84                        (string name)))
  85          (alien-type (parse-alien-type type env))
  86          (datap (not (alien-fun-type-p alien-type))))
  87     `(%heap-alien ',(make-heap-alien-info
  88                      :type alien-type
  89                      :sap-form `(foreign-symbol-sap ',alien-name ,datap)))))
  90
  91 (defmacro with-alien (bindings &body body &environment env)
  92   #!+sb-doc
  93   "Establish some local alien variables. Each BINDING is of the form:
  94      VAR TYPE [ ALLOCATION ] [ INITIAL-VALUE | EXTERNAL-NAME ]
  95    ALLOCATION should be one of:
  96      :LOCAL (the default)
  97        The alien is allocated on the stack, and has dynamic extent.
  98      :STATIC
  99        The alien is allocated on the heap, and has infinite extent. The alien
 100        is allocated at load time, so the same piece of memory is used each time
 101        this form executes.
 102      :EXTERN
 103        No alien is allocated, but VAR is established as a local name for
 104        the external alien given by EXTERNAL-NAME."
 105   (/show "entering WITH-ALIEN" bindings)
 106   (with-auxiliary-alien-types env
 107     (dolist (binding (reverse bindings))
 108       (/show binding)
 109       (destructuring-bind
 110           (symbol type &optional (opt1 nil opt1p) (opt2 nil opt2p))
 111           binding
 112         (/show symbol type opt1 opt2)
 113         (let* ((alien-type (parse-alien-type type env))
 114                (datap (not (alien-fun-type-p alien-type))))
 115           (/show alien-type)
 116           (multiple-value-bind (allocation initial-value)
 117               (if opt2p
 118                   (values opt1 opt2)
 119                   (case opt1
 120                     (:extern
 121                      (values opt1 (guess-alien-name-from-lisp-name symbol)))
 122                     (:static
 123                      (values opt1 nil))
 124                     (t
 125                      (values :local opt1))))
 126             (/show allocation initial-value)
 127             (setf body
 128                   (ecase allocation
 129                     #+nil
 130                     (:static
 131                      (let ((sap
 132                             (make-symbol (concatenate 'string "SAP-FOR-"
 133                                                       (symbol-name symbol)))))
 134                        `((let ((,sap (load-time-value (%make-alien ...))))
 135                            (declare (type system-area-pointer ,sap))
 136                            (symbol-macrolet
 137                             ((,symbol (sap-alien ,sap ,type)))
 138                             ,@(when initial-value
 139                                 `((setq ,symbol ,initial-value)))
 140                             ,@body)))))
 141                     (:extern
 142                      (/show0 ":EXTERN case")
 143                      (let ((info (make-heap-alien-info
 144                                   :type alien-type
 145                                   :sap-form `(foreign-symbol-sap ',initial-value
 146                                                                  ,datap))))
 147                        `((symbol-macrolet
 148                           ((,symbol (%heap-alien ',info)))
 149                           ,@body))))
 150                     (:local
 151                      (/show0 ":LOCAL case")
 152                      (let ((var (gensym))
 153                            (initval (if initial-value (gensym)))
 154                            (info (make-local-alien-info :type alien-type)))
 155                        (/show var initval info)
 156                        `((let ((,var (make-local-alien ',info))
 157                                ,@(when initial-value
 158                                    `((,initval ,initial-value))))
 159                            (note-local-alien-type ',info ,var)
 160                            (multiple-value-prog1
 161                                (symbol-macrolet
 162                                 ((,symbol (local-alien ',info ,var)))
 163                                 ,@(when initial-value
 164                                     `((setq ,symbol ,initval)))
 165                                 ,@body)
 166                                (dispose-local-alien ',info ,var))))))))))))
 167     (/show "revised" body)
 168     (verify-local-auxiliaries-okay)
 169     (/show0 "back from VERIFY-LOCAL-AUXILIARIES-OK, returning")
 170     `(symbol-macrolet ((&auxiliary-type-definitions&
 171                         ,(append *new-auxiliary-types*
 172                                  (auxiliary-type-definitions env))))
 173        ,@body)))
 174 \f
 175 ;;;; runtime C values that don't correspond directly to Lisp types
 176
 177 ;;; Note: The DEFSTRUCT for ALIEN-VALUE lives in a separate file
 178 ;;; 'cause it has to be real early in the cold-load order.
 179 #!-sb-fluid (declaim (freeze-type alien-value))
 180 (def!method print-object ((value alien-value) stream)
 181   (print-unreadable-object (value stream)
 182     (format stream
 183             "~S ~S #X~8,'0X ~S ~S"
 184             'alien-value
 185             :sap (sap-int (alien-value-sap value))
 186             :type (unparse-alien-type (alien-value-type value)))))
 187
 188 #!-sb-fluid (declaim (inline null-alien))
 189 (defun null-alien (x)
 190   #!+sb-doc
 191   "Return true if X (which must be an ALIEN pointer) is null, false otherwise."
 192   (zerop (sap-int (alien-sap x))))
 193
 194 (defmacro sap-alien (sap type &environment env)
 195   #!+sb-doc
 196   "Convert the system area pointer SAP to an ALIEN of the specified TYPE (not
 197    evaluated.) TYPE must be pointer-like."
 198   (let ((alien-type (parse-alien-type type env)))
 199     (if (eq (compute-alien-rep-type alien-type) 'system-area-pointer)
 200         `(%sap-alien ,sap ',alien-type)
 201         (error "cannot make an alien of type ~S out of a SAP" type))))
 202
 203 (defun %sap-alien (sap type)
 204   (declare (type system-area-pointer sap)
 205            (type alien-type type))
 206   (make-alien-value :sap sap :type type))
 207
 208 (defun alien-sap (alien)
 209   #!+sb-doc
 210   "Return a System-Area-Pointer pointing to Alien's data."
 211   (declare (type alien-value alien))
 212   (alien-value-sap alien))
 213 \f
 214 ;;;; allocation/deallocation of heap aliens
 215
 216 (defmacro make-alien (type &optional size &environment env)
 217   #!+sb-doc
 218   "Allocate an alien of type TYPE and return an alien pointer to it. If SIZE
 219 is supplied, how it is interpreted depends on TYPE. If TYPE is an array type,
 220 SIZE is used as the first dimension for the allocated array. If TYPE is not an
 221 array, then SIZE is the number of elements to allocate. The memory is
 222 allocated using ``malloc'', so it can be passed to foreign functions which use
 223 ``free''."
 224   (let ((alien-type (if (alien-type-p type)
 225                         type
 226                         (parse-alien-type type env))))
 227     (multiple-value-bind (size-expr element-type)
 228         (if (alien-array-type-p alien-type)
 229             (let ((dims (alien-array-type-dimensions alien-type)))
 230               (cond
 231                 (size
 232                  (unless dims
 233                    (error
 234                     "cannot override the size of zero-dimensional arrays"))
 235                  (when (constantp size)
 236                    (setf alien-type (copy-alien-array-type alien-type))
 237                    (setf (alien-array-type-dimensions alien-type)
 238                          (cons (constant-form-value size) (cdr dims)))))
 239                 (dims
 240                  (setf size (car dims)))
 241                 (t
 242                  (setf size 1)))
 243               (values `(* ,size ,@(cdr dims))
 244                       (alien-array-type-element-type alien-type)))
 245             (values (or size 1) alien-type))
 246       (let ((bits (alien-type-bits element-type))
 247             (alignment (alien-type-alignment element-type)))
 248         (unless bits
 249           (error "The size of ~S is unknown."
 250                  (unparse-alien-type element-type)))
 251         (unless alignment
 252           (error "The alignment of ~S is unknown."
 253                  (unparse-alien-type element-type)))
 254         ;; This is the one place where the %SAP-ALIEN note is quite
 255         ;; undesirable, in most uses of MAKE-ALIEN the %SAP-ALIEN
 256         ;; cannot be optimized away.
 257         `(locally (declare (muffle-conditions compiler-note))
 258            (%sap-alien (%make-alien (* ,(align-offset bits alignment)
 259                                        ,size-expr))
 260                        ',(make-alien-pointer-type :to alien-type)))))))
 261
 262 ;;; Allocate a block of memory at least BITS bits long and return a
 263 ;;; system area pointer to it.
 264 #!-sb-fluid (declaim (inline %make-alien))
 265 (defun %make-alien (bits)
 266   (declare (type index bits))
 267   (alien-funcall (extern-alien "malloc"
 268                                (function system-area-pointer unsigned))
 269                  (ash (the index (+ bits 7)) -3)))
 270
 271 #!-sb-fluid (declaim (inline free-alien))
 272 (defun free-alien (alien)
 273   #!+sb-doc
 274   "Dispose of the storage pointed to by ALIEN. ALIEN must have been allocated
 275    by MAKE-ALIEN or malloc(3)."
 276   (alien-funcall (extern-alien "free" (function (values) system-area-pointer))
 277                  (alien-sap alien))
 278   nil)
 279 \f
 280 ;;;; the SLOT operator
 281
 282 ;;; Find the field named SLOT, or die trying.
 283 (defun slot-or-lose (type slot)
 284   (declare (type alien-record-type type)
 285            (type symbol slot))
 286   (or (find slot (alien-record-type-fields type)
 287             :key #'alien-record-field-name)
 288       (error "There is no slot named ~S in ~S." slot type)))
 289
 290 ;;; Extract the value from the named slot from the record ALIEN. If
 291 ;;; ALIEN is actually a pointer, then DEREF it first.
 292 (defun slot (alien slot)
 293   #!+sb-doc
 294   "Extract SLOT from the Alien STRUCT or UNION ALIEN. May be set with SETF."
 295   (declare (type alien-value alien)
 296            (type symbol slot)
 297            (optimize (inhibit-warnings 3)))
 298   (let ((type (alien-value-type alien)))
 299     (etypecase type
 300       (alien-pointer-type
 301        (slot (deref alien) slot))
 302       (alien-record-type
 303        (let ((field (slot-or-lose type slot)))
 304          (extract-alien-value (alien-value-sap alien)
 305                               (alien-record-field-offset field)
 306                               (alien-record-field-type field)))))))
 307
 308 ;;; Deposit the value in the specified slot of the record ALIEN. If
 309 ;;; the ALIEN is really a pointer, DEREF it first. The compiler uses
 310 ;;; this when it can't figure out anything better.
 311 (defun %set-slot (alien slot value)
 312   (declare (type alien-value alien)
 313            (type symbol slot)
 314            (optimize (inhibit-warnings 3)))
 315   (let ((type (alien-value-type alien)))
 316     (etypecase type
 317       (alien-pointer-type
 318        (%set-slot (deref alien) slot value))
 319       (alien-record-type
 320        (let ((field (slot-or-lose type slot)))
 321          (deposit-alien-value (alien-value-sap alien)
 322                               (alien-record-field-offset field)
 323                               (alien-record-field-type field)
 324                               value))))))
 325
 326 ;;; Compute the address of the specified slot and return a pointer to it.
 327 (defun %slot-addr (alien slot)
 328   (declare (type alien-value alien)
 329            (type symbol slot)
 330            (optimize (inhibit-warnings 3)))
 331   (let ((type (alien-value-type alien)))
 332     (etypecase type
 333       (alien-pointer-type
 334        (%slot-addr (deref alien) slot))
 335       (alien-record-type
 336        (let* ((field (slot-or-lose type slot))
 337               (offset (alien-record-field-offset field))
 338               (field-type (alien-record-field-type field)))
 339          (%sap-alien (sap+ (alien-sap alien) (/ offset sb!vm:n-byte-bits))
 340                      (make-alien-pointer-type :to field-type)))))))
 341 \f
 342 ;;;; the DEREF operator
 343
 344 ;;; This function does most of the work of the different DEREF
 345 ;;; methods. It returns two values: the type and the offset (in bits)
 346 ;;; of the referred-to alien.
 347 (defun deref-guts (alien indices)
 348   (declare (type alien-value alien)
 349            (type list indices)
 350            (values alien-type integer))
 351   (let ((type (alien-value-type alien)))
 352     (etypecase type
 353       (alien-pointer-type
 354        (when (cdr indices)
 355          (error "too many indices when DEREF'ing ~S: ~W"
 356                 type
 357                 (length indices)))
 358        (let ((element-type (alien-pointer-type-to type)))
 359          (values element-type
 360                  (if indices
 361                      (* (align-offset (alien-type-bits element-type)
 362                                       (alien-type-alignment element-type))
 363                         (car indices))
 364                      0))))
 365       (alien-array-type
 366        (unless (= (length indices) (length (alien-array-type-dimensions type)))
 367          (error "incorrect number of indices when DEREF'ing ~S: ~W"
 368                 type (length indices)))
 369        (labels ((frob (dims indices offset)
 370                   (if (null dims)
 371                       offset
 372                       (frob (cdr dims) (cdr indices)
 373                         (+ (if (zerop offset)
 374                                0
 375                                (* offset (car dims)))
 376                            (car indices))))))
 377          (let ((element-type (alien-array-type-element-type type)))
 378            (values element-type
 379                    (* (align-offset (alien-type-bits element-type)
 380                                     (alien-type-alignment element-type))
 381                       (frob (alien-array-type-dimensions type)
 382                         indices 0)))))))))
 383
 384 ;;; Dereference the alien and return the results.
 385 (defun deref (alien &rest indices)
 386   #!+sb-doc
 387   "De-reference an Alien pointer or array. If an array, the indices are used
 388    as the indices of the array element to access. If a pointer, one index can
 389    optionally be specified, giving the equivalent of C pointer arithmetic."
 390   (declare (type alien-value alien)
 391            (type list indices)
 392            (optimize (inhibit-warnings 3)))
 393   (multiple-value-bind (target-type offset) (deref-guts alien indices)
 394     (extract-alien-value (alien-value-sap alien)
 395                          offset
 396                          target-type)))
 397
 398 (defun %set-deref (alien value &rest indices)
 399   (declare (type alien-value alien)
 400            (type list indices)
 401            (optimize (inhibit-warnings 3)))
 402   (multiple-value-bind (target-type offset) (deref-guts alien indices)
 403     (deposit-alien-value (alien-value-sap alien)
 404                          offset
 405                          target-type
 406                          value)))
 407
 408 (defun %deref-addr (alien &rest indices)
 409   (declare (type alien-value alien)
 410            (type list indices)
 411            (optimize (inhibit-warnings 3)))
 412   (multiple-value-bind (target-type offset) (deref-guts alien indices)
 413     (%sap-alien (sap+ (alien-value-sap alien) (/ offset sb!vm:n-byte-bits))
 414                 (make-alien-pointer-type :to target-type))))
 415 \f
 416 ;;;; accessing heap alien variables
 417
 418 (defun %heap-alien (info)
 419   (declare (type heap-alien-info info)
 420            (optimize (inhibit-warnings 3)))
 421   (extract-alien-value (eval (heap-alien-info-sap-form info))
 422                        0
 423                        (heap-alien-info-type info)))
 424
 425 (defun %set-heap-alien (info value)
 426   (declare (type heap-alien-info info)
 427            (optimize (inhibit-warnings 3)))
 428   (deposit-alien-value (eval (heap-alien-info-sap-form info))
 429                        0
 430                        (heap-alien-info-type info)
 431                        value))
 432
 433 (defun %heap-alien-addr (info)
 434   (declare (type heap-alien-info info)
 435            (optimize (inhibit-warnings 3)))
 436   (%sap-alien (eval (heap-alien-info-sap-form info))
 437               (make-alien-pointer-type :to (heap-alien-info-type info))))
 438 \f
 439 ;;;; accessing local aliens
 440
 441 (defun make-local-alien (info)
 442   (let* ((alien (eval `(make-alien ,(local-alien-info-type info))))
 443          (alien-sap (alien-sap alien)))
 444     (finalize
 445      alien
 446      (lambda ()
 447        (alien-funcall
 448         (extern-alien "free" (function (values) system-area-pointer))
 449         alien-sap)))
 450     alien))
 451
 452 (defun note-local-alien-type (info alien)
 453   (declare (ignore info alien))
 454   nil)
 455
 456 (defun local-alien (info alien)
 457   (declare (ignore info))
 458   (deref alien))
 459
 460 (defun %set-local-alien (info alien value)
 461   (declare (ignore info))
 462   (setf (deref alien) value))
 463
 464 (define-setf-expander local-alien (&whole whole info alien)
 465   (let ((value (gensym))
 466         (info-var (gensym))
 467         (alloc-tmp (gensym))
 468         (info (if (and (consp info)
 469                        (eq (car info) 'quote))
 470                   (second info)
 471                   (error "Something is wrong; local-alien-info not found: ~S"
 472                          whole))))
 473     (values nil
 474             nil
 475             (list value)
 476             `(if (%local-alien-forced-to-memory-p ',info)
 477                  (%set-local-alien ',info ,alien ,value)
 478                    (let* ((,info-var ',(local-alien-info-type info))
 479                           (,alloc-tmp (deport-alloc ,value ,info-var)))
 480                      (maybe-with-pinned-objects (,alloc-tmp) (,(local-alien-info-type info))
 481                        (setf ,alien (deport ,alloc-tmp ,info-var)))))
 482             whole)))
 483
 484 (defun %local-alien-forced-to-memory-p (info)
 485   (local-alien-info-force-to-memory-p info))
 486
 487 (defun %local-alien-addr (info alien)
 488   (declare (type local-alien-info info))
 489   (unless (local-alien-info-force-to-memory-p info)
 490     (error "~S isn't forced to memory. Something went wrong." alien))
 491   alien)
 492
 493 (defun dispose-local-alien (info alien)
 494   (declare (ignore info))
 495   (cancel-finalization alien)
 496   (free-alien alien))
 497 \f
 498 ;;;; the CAST macro
 499
 500 (defmacro cast (alien type &environment env)
 501   #!+sb-doc
 502   "Convert ALIEN to an Alien of the specified TYPE (not evaluated.)  Both types
 503    must be Alien array, pointer or function types."
 504   `(%cast ,alien ',(parse-alien-type type env)))
 505
 506 (defun %cast (alien target-type)
 507   (declare (type alien-value alien)
 508            (type alien-type target-type)
 509            (optimize (safety 2))
 510            (optimize (inhibit-warnings 3)))
 511   (if (or (alien-pointer-type-p target-type)
 512           (alien-array-type-p target-type)
 513           (alien-fun-type-p target-type))
 514       (let ((alien-type (alien-value-type alien)))
 515         (if (or (alien-pointer-type-p alien-type)
 516                 (alien-array-type-p alien-type)
 517                 (alien-fun-type-p alien-type))
 518             (naturalize (alien-value-sap alien) target-type)
 519             (error "~S cannot be casted." alien)))
 520       (error "cannot cast to alien type ~S" (unparse-alien-type target-type))))
 521 \f
 522 ;;;; the ALIEN-SIZE macro
 523
 524 (defmacro alien-size (type &optional (units :bits) &environment env)
 525   #!+sb-doc
 526   "Return the size of the alien type TYPE. UNITS specifies the units to
 527    use and can be either :BITS, :BYTES, or :WORDS."
 528   (let* ((alien-type (parse-alien-type type env))
 529          (bits (alien-type-bits alien-type)))
 530     (if bits
 531         (values (ceiling bits
 532                          (ecase units
 533                            (:bits 1)
 534                            (:bytes sb!vm:n-byte-bits)
 535                            (:words sb!vm:n-word-bits))))
 536         (error "unknown size for alien type ~S"
 537                (unparse-alien-type alien-type)))))
 538 \f
 539 ;;;; NATURALIZE, DEPORT, EXTRACT-ALIEN-VALUE, DEPOSIT-ALIEN-VALUE
 540
 541 (defun coerce-to-interpreted-function (lambda-form)
 542   (let (#!+sb-eval
 543         (*evaluator-mode* :interpret))
 544     (coerce lambda-form 'function)))
 545
 546 (defun naturalize (alien type)
 547   (declare (type alien-type type))
 548   (funcall (coerce-to-interpreted-function (compute-naturalize-lambda type))
 549            alien type))
 550
 551 (defun deport (value type)
 552   (declare (type alien-type type))
 553   (funcall (coerce-to-interpreted-function (compute-deport-lambda type))
 554            value type))
 555
 556 (defun deport-alloc (value type)
 557   (declare (type alien-type type))
 558   (funcall (coerce-to-interpreted-function (compute-deport-alloc-lambda type))
 559            value type))
 560
 561 (defun extract-alien-value (sap offset type)
 562   (declare (type system-area-pointer sap)
 563            (type unsigned-byte offset)
 564            (type alien-type type))
 565   (funcall (coerce-to-interpreted-function (compute-extract-lambda type))
 566            sap offset type))
 567
 568 (defun deposit-alien-value (sap offset type value)
 569   (declare (type system-area-pointer sap)
 570            (type unsigned-byte offset)
 571            (type alien-type type))
 572   (funcall (coerce-to-interpreted-function (compute-deposit-lambda type))
 573            sap offset type value))
 574 \f
 575 ;;;; ALIEN-FUNCALL, DEFINE-ALIEN-ROUTINE
 576
 577 (defun alien-funcall (alien &rest args)
 578   #!+sb-doc
 579   "Call the foreign function ALIEN with the specified arguments. ALIEN's
 580    type specifies the argument and result types."
 581   (declare (type alien-value alien))
 582   (let ((type (alien-value-type alien)))
 583     (typecase type
 584       (alien-pointer-type
 585        (apply #'alien-funcall (deref alien) args))
 586       (alien-fun-type
 587        (unless (= (length (alien-fun-type-arg-types type))
 588                   (length args))
 589          (error "wrong number of arguments for ~S~%expected ~W, got ~W"
 590                 type
 591                 (length (alien-fun-type-arg-types type))
 592                 (length args)))
 593        (let ((stub (alien-fun-type-stub type)))
 594          (unless stub
 595            (setf stub
 596                  (let ((fun (gensym))
 597                        (parms (make-gensym-list (length args))))
 598                    (compile nil
 599                             `(lambda (,fun ,@parms)
 600                                (declare (optimize (sb!c::insert-step-conditions 0)))
 601                                (declare (type (alien ,type) ,fun))
 602                                (alien-funcall ,fun ,@parms)))))
 603            (setf (alien-fun-type-stub type) stub))
 604          (apply stub alien args)))
 605       (t
 606        (error "~S is not an alien function." alien)))))
 607
 608 (defmacro define-alien-routine (name result-type
 609                                      &rest args
 610                                      &environment lexenv)
 611   #!+sb-doc
 612   "DEFINE-ALIEN-ROUTINE Name Result-Type {(Arg-Name Arg-Type [Style])}*
 613
 614   Define a foreign interface function for the routine with the specified NAME.
 615   Also automatically DECLAIM the FTYPE of the defined function.
 616
 617   NAME may be either a string, a symbol, or a list of the form (string symbol).
 618
 619   RETURN-TYPE is the alien type for the function return value. VOID may be
 620   used to specify a function with no result.
 621
 622   The remaining forms specify individual arguments that are passed to the
 623   routine. ARG-NAME is a symbol that names the argument, primarily for
 624   documentation. ARG-TYPE is the C type of the argument. STYLE specifies the
 625   way that the argument is passed.
 626
 627   :IN
 628         An :IN argument is simply passed by value. The value to be passed is
 629         obtained from argument(s) to the interface function. No values are
 630         returned for :In arguments. This is the default mode.
 631
 632   :OUT
 633         The specified argument type must be a pointer to a fixed sized object.
 634         A pointer to a preallocated object is passed to the routine, and the
 635         the object is accessed on return, with the value being returned from
 636         the interface function. :OUT and :IN-OUT cannot be used with pointers
 637         to arrays, records or functions.
 638
 639   :COPY
 640         This is similar to :IN, except that the argument values are stored
 641         on the stack, and a pointer to the object is passed instead of
 642         the value itself.
 643
 644   :IN-OUT
 645         This is a combination of :OUT and :COPY. A pointer to the argument is
 646         passed, with the object being initialized from the supplied argument
 647         and the return value being determined by accessing the object on
 648         return."
 649   (multiple-value-bind (lisp-name alien-name)
 650       (pick-lisp-and-alien-names name)
 651     (collect ((docs) (lisp-args) (lisp-arg-types)
 652               (lisp-result-types
 653                (cond ((eql result-type 'void)
 654                       ;; What values does a function return, if it
 655                       ;; returns no values? Exactly one - NIL. -- APD,
 656                       ;; 2003-03-02
 657                       (list 'null))
 658                      (t
 659                       ;; FIXME: Check for VALUES.
 660                       (list `(alien ,result-type)))))
 661               (arg-types) (alien-vars)
 662               (alien-args) (results))
 663       (dolist (arg args)
 664         (if (stringp arg)
 665             (docs arg)
 666             (destructuring-bind (name type &optional (style :in)) arg
 667               (unless (member style '(:in :copy :out :in-out))
 668                 (error "bogus argument style ~S in ~S" style arg))
 669               (when (and (member style '(:out :in-out))
 670                          (typep (parse-alien-type type lexenv)
 671                                 'alien-pointer-type))
 672                 (error "can't use :OUT or :IN-OUT on pointer-like type:~%  ~S"
 673                        type))
 674               (let (arg-type)
 675                 (cond ((eq style :in)
 676                        (setq arg-type type)
 677                        (alien-args name))
 678                       (t
 679                        (setq arg-type `(* ,type))
 680                        (if (eq style :out)
 681                            (alien-vars `(,name ,type))
 682                            (alien-vars `(,name ,type ,name)))
 683                        (alien-args `(addr ,name))))
 684                 (arg-types arg-type)
 685                 (unless (eq style :out)
 686                   (lisp-args name)
 687                   (lisp-arg-types t
 688                                   ;; FIXME: It should be something
 689                                   ;; like `(ALIEN ,ARG-TYPE), except
 690                                   ;; for we also accept SAPs where
 691                                   ;; pointers are required.
 692                                   )))
 693               (when (or (eq style :out) (eq style :in-out))
 694                 (results name)
 695                 (lisp-result-types `(alien ,type))))))
 696       `(progn
 697          ;; The theory behind this automatic DECLAIM is that (1) if
 698          ;; you're calling C, static typing is what you're doing
 699          ;; anyway, and (2) such a declamation can be (especially for
 700          ;; alien values) both messy to do by hand and very important
 701          ;; for performance of later code which uses the return value.
 702          (declaim (ftype (function ,(lisp-arg-types)
 703                                    (values ,@(lisp-result-types) &optional))
 704                          ,lisp-name))
 705          (defun ,lisp-name ,(lisp-args)
 706            ,@(docs)
 707            (with-alien
 708             ((,lisp-name (function ,result-type ,@(arg-types))
 709                          :extern ,alien-name)
 710              ,@(alien-vars))
 711              #-nil
 712              (values (alien-funcall ,lisp-name ,@(alien-args))
 713                      ,@(results))
 714              #+nil
 715              (if (alien-values-type-p result-type)
 716                  ;; FIXME: RESULT-TYPE is a type specifier, so it
 717                  ;; cannot be of type ALIEN-VALUES-TYPE. Also note,
 718                  ;; that if RESULT-TYPE is VOID, then this code
 719                  ;; disagrees with the computation of the return type
 720                  ;; and with all usages of this macro. -- APD,
 721                  ;; 2002-03-02
 722                  (let ((temps (make-gensym-list
 723                                (length
 724                                 (alien-values-type-values result-type)))))
 725                    `(multiple-value-bind ,temps
 726                         (alien-funcall ,lisp-name ,@(alien-args))
 727                       (values ,@temps ,@(results))))
 728                  (values (alien-funcall ,lisp-name ,@(alien-args))
 729                          ,@(results)))))))))
 730
 731 (defmacro def-alien-routine (&rest rest)
 732   (deprecation-warning 'def-alien-routine 'define-alien-routine)
 733   `(define-alien-routine ,@rest))
 734 \f
 735 (defun alien-typep (object type)
 736   #!+sb-doc
 737   "Return T iff OBJECT is an alien of type TYPE."
 738   (let ((lisp-rep-type (compute-lisp-rep-type type)))
 739     (if lisp-rep-type
 740         (typep object lisp-rep-type)
 741         (and (alien-value-p object)
 742              (alien-subtype-p (alien-value-type object) type)))))
 743
 744 ;;;; ALIEN CALLBACKS
 745 ;;;;
 746 ;;;; See "Foreign Linkage / Callbacks" in the SBCL Internals manual.
 747
 748 (defvar *alien-callback-info* nil
 749   "Maps SAPs to corresponding CALLBACK-INFO structures: contains all the
 750 information we need to manipulate callbacks after their creation. Used for
 751 changing the lisp-side function they point to, invalidation, etc.")
 752
 753 (defstruct callback-info
 754   specifier
 755   function ; NULL if invalid
 756   wrapper
 757   index)
 758
 759 (defun callback-info-key (info)
 760   (cons (callback-info-specifier info) (callback-info-function info)))
 761
 762 (defun alien-callback-info (alien)
 763   (cdr (assoc (alien-sap alien) *alien-callback-info* :test #'sap=)))
 764
 765 (defvar *alien-callbacks* (make-hash-table :test #'equal)
 766   "Cache of existing callback SAPs, indexed with (SPECIFER . FUNCTION). Used for
 767 memoization: we don't create new callbacks if one pointing to the correct
 768 function with the same specifier already exists.")
 769
 770 (defvar *alien-callback-wrappers* (make-hash-table :test #'equal)
 771   "Cache of existing lisp weappers, indexed with SPECIFER. Used for memoization:
 772 we don't create new wrappers if one for the same specifier already exists.")
 773
 774 (defvar *alien-callback-trampolines* (make-array 32 :fill-pointer 0 :adjustable t)
 775   "Lisp trampoline store: assembler wrappers contain indexes to this, and
 776 ENTER-ALIEN-CALLBACK pulls the corresponsing trampoline out and calls it.")
 777
 778 (defun %alien-callback-sap (specifier result-type argument-types function wrapper)
 779   (let ((key (cons specifier function)))
 780     (or (gethash key *alien-callbacks*)
 781         (setf (gethash key *alien-callbacks*)
 782               (let* ((index (fill-pointer *alien-callback-trampolines*))
 783                      ;; Aside from the INDEX this is known at
 784                      ;; compile-time, which could be utilized by
 785                      ;; having the two-stage assembler tramp &
 786                      ;; wrapper mentioned in [1] above: only the
 787                      ;; per-function tramp would need assembler at
 788                      ;; runtime. Possibly we could even pregenerate
 789                      ;; the code and just patch the index in later.
 790                      (assembler-wrapper (alien-callback-assembler-wrapper
 791                                          index result-type argument-types)))
 792                 (vector-push-extend
 793                  (alien-callback-lisp-trampoline wrapper function)
 794                  *alien-callback-trampolines*)
 795                 (let ((sap (vector-sap assembler-wrapper)))
 796                   (push (cons sap (make-callback-info :specifier specifier
 797                                                       :function function
 798                                                       :wrapper wrapper
 799                                                       :index index))
 800                         *alien-callback-info*)
 801                   sap))))))
 802
 803 (defun alien-callback-lisp-trampoline (wrapper function)
 804   (declare (function wrapper) (optimize speed))
 805   (lambda (args-pointer result-pointer)
 806     (funcall wrapper args-pointer result-pointer function)))
 807
 808 (defun alien-callback-lisp-wrapper-lambda (specifier result-type argument-types env)
 809   (let* ((arguments (make-gensym-list (length argument-types)))
 810          (argument-names arguments)
 811          (argument-specs (cddr specifier)))
 812     `(lambda (args-pointer result-pointer function)
 813        ;; FIXME: the saps are not gc safe
 814        (let ((args-sap (int-sap
 815                         (sb!kernel:get-lisp-obj-address args-pointer)))
 816              (res-sap (int-sap
 817                        (sb!kernel:get-lisp-obj-address result-pointer))))
 818          (declare (ignorable args-sap res-sap))
 819          (with-alien
 820              ,(loop
 821                  with offset = 0
 822                  for spec in argument-specs
 823                  collect `(,(pop argument-names) ,spec
 824                             :local ,(alien-callback-accessor-form
 825                                      spec 'args-sap offset))
 826                  do (incf offset (alien-callback-argument-bytes spec env)))
 827            ,(flet ((store (spec)
 828                           (if spec
 829                               `(setf (deref (sap-alien res-sap (* ,spec)))
 830                                      (funcall function ,@arguments))
 831                               `(funcall function ,@arguments))))
 832                   (cond ((alien-void-type-p result-type)
 833                          (store nil))
 834                         ((alien-integer-type-p result-type)
 835                          (if (alien-integer-type-signed result-type)
 836                              (store `(signed
 837                                       ,(alien-type-word-aligned-bits result-type)))
 838                              (store
 839                               `(unsigned
 840                                 ,(alien-type-word-aligned-bits result-type)))))
 841                         (t
 842                          (store (unparse-alien-type result-type)))))))
 843        (values))))
 844
 845 (defun invalid-alien-callback (&rest arguments)
 846   (declare (ignore arguments))
 847   (error "Invalid alien callback called."))
 848
 849
 850 (defun parse-callback-specification (result-type lambda-list)
 851   (values
 852    `(function ,result-type ,@(mapcar #'second lambda-list))
 853    (mapcar #'first lambda-list)))
 854
 855
 856 (defun parse-alien-ftype (specifier env)
 857   (destructuring-bind (function result-type &rest argument-types)
 858       specifier
 859     (aver (eq 'function function))
 860     (values (let ((*values-type-okay* t))
 861               (parse-alien-type result-type env))
 862             (mapcar (lambda (spec)
 863                       (parse-alien-type spec env))
 864                     argument-types))))
 865
 866 (defun alien-void-type-p (type)
 867   (and (alien-values-type-p type) (not (alien-values-type-values type))))
 868
 869 (defun alien-type-word-aligned-bits (type)
 870   (align-offset (alien-type-bits type) sb!vm:n-word-bits))
 871
 872 (defun alien-callback-argument-bytes (spec env)
 873   (let ((type (parse-alien-type spec env)))
 874     (if (or (alien-integer-type-p type)
 875             (alien-float-type-p type)
 876             (alien-pointer-type-p type)
 877             (alien-system-area-pointer-type-p type))
 878         (ceiling (alien-type-word-aligned-bits type) sb!vm:n-byte-bits)
 879         (error "Unsupported callback argument type: ~A" type))))
 880
 881 (defun enter-alien-callback (index return arguments)
 882   (funcall (aref *alien-callback-trampolines* index)
 883            return
 884            arguments))
 885
 886 ;;; To ensure that callback wrapper functions continue working even
 887 ;;; if #'ENTER-ALIEN-CALLBACK moves in memory, access to it is indirected
 888 ;;; through the *ENTER-ALIEN-CALLBACK* static symbol. -- JES, 2006-01-01
 889 (defvar *enter-alien-callback* #'enter-alien-callback)
 890
 891 ;;;; interface (not public, yet) for alien callbacks
 892
 893 (defmacro alien-callback (specifier function &environment env)
 894   "Returns an alien-value with of alien ftype SPECIFIER, that can be passed to
 895 an alien function as a pointer to the FUNCTION. If a callback for the given
 896 SPECIFIER and FUNCTION already exists, it is returned instead of consing a new
 897 one."
 898   ;; Pull out as much work as is convenient to macro-expansion time, specifically
 899   ;; everything that can be done given just the SPECIFIER and ENV.
 900   (multiple-value-bind (result-type argument-types) (parse-alien-ftype specifier env)
 901     `(%sap-alien
 902       (%alien-callback-sap ',specifier ',result-type ',argument-types
 903                            ,function
 904                            (or (gethash ',specifier *alien-callback-wrappers*)
 905                                (setf (gethash ',specifier *alien-callback-wrappers*)
 906                                      (compile nil
 907                                               ',(alien-callback-lisp-wrapper-lambda
 908                                                  specifier result-type argument-types env)))))
 909       ',(parse-alien-type specifier env))))
 910
 911 (defun alien-callback-p (alien)
 912   "Returns true if the alien is associated with a lisp-side callback,
 913 and a secondary return value of true if the callback is still valid."
 914   (let ((info (alien-callback-info alien)))
 915     (when info
 916       (values t (and (callback-info-function info) t)))))
 917
 918 (defun alien-callback-function (alien)
 919   "Returns the lisp function designator associated with the callback."
 920   (let ((info (alien-callback-info alien)))
 921     (when info
 922       (callback-info-function info))))
 923
 924 (defun (setf alien-callback-function) (function alien)
 925   "Changes the lisp function designated by the callback."
 926   (let ((info (alien-callback-info alien)))
 927     (unless info
 928       (error "Not an alien callback: ~S" alien))
 929     ;; sap cache
 930     (let ((key (callback-info-key info)))
 931       (remhash key *alien-callbacks*)
 932       (setf (gethash key *alien-callbacks*) (alien-sap alien)))
 933     ;; trampoline
 934     (setf (aref *alien-callback-trampolines* (callback-info-index info))
 935           (alien-callback-lisp-trampoline (callback-info-wrapper info) function))
 936     ;; metadata
 937     (setf (callback-info-function info) function)
 938     function))
 939
 940 (defun invalidate-alien-callback (alien)
 941   "Invalidates the callback designated by the alien, if any, allowing the
 942 associated lisp function to be GC'd, and causing further calls to the same
 943 callback signal an error."
 944   (let ((info (alien-callback-info alien)))
 945     (when (and info (callback-info-function info))
 946       ;; sap cache
 947       (remhash (callback-info-key info) *alien-callbacks*)
 948       ;; trampoline
 949       (setf (aref *alien-callback-trampolines* (callback-info-index info))
 950             #'invalid-alien-callback)
 951       ;; metadata
 952       (setf (callback-info-function info) nil)
 953       t)))
 954
 955 ;;; FIXME: This call assembles a new callback for every closure,
 956 ;;; which sucks hugely. ...not that I can think of an obvious
 957 ;;; solution. Possibly maybe we could write a generalized closure
 958 ;;; callback analogous to closure_tramp, and share the actual wrapper?
 959 ;;;
 960 ;;; For lambdas that result in simple-funs we get the callback from
 961 ;;; the cache on subsequent calls.
 962 (defmacro alien-lambda (result-type typed-lambda-list &body forms)
 963   (multiple-value-bind (specifier lambda-list)
 964       (parse-callback-specification result-type typed-lambda-list)
 965     `(alien-callback ,specifier (lambda ,lambda-list ,@forms))))
 966
 967 ;;; FIXME: Should subsequent (SETF FDEFINITION) affect the callback or not?
 968 ;;; What about subsequent DEFINE-ALIEN-CALLBACKs? My guess is that changing
 969 ;;; the FDEFINITION should invalidate the callback, and redefining the
 970 ;;; callback should change existing callbacks to point to the new defintion.
 971 (defmacro define-alien-callback (name result-type typed-lambda-list &body forms)
 972   "Defines #'NAME as a function with the given body and lambda-list, and NAME as
 973 the alien callback for that function with the given alien type."
 974   (declare (symbol name))
 975   (multiple-value-bind (specifier lambda-list)
 976       (parse-callback-specification result-type typed-lambda-list)
 977     `(progn
 978        (defun ,name ,lambda-list ,@forms)
 979        (defparameter ,name (alien-callback ,specifier #',name)))))