src/code/target-alieneval.lisp

   1 ;;;; This file contains parts of the ALIEN implementation that
   2 ;;;; are not part of the compiler.
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!ALIEN")
  14
  15 (/show0 "target-alieneval.lisp 15")
  16 \f
  17 ;;;; alien variables
  18
  19 ;;; Make a string out of the symbol, converting all uppercase letters to
  20 ;;; lower case and hyphens into underscores.
  21 (eval-when (:compile-toplevel :load-toplevel :execute)
  22   (defun guess-alien-name-from-lisp-name (lisp-name)
  23     (declare (type symbol lisp-name))
  24     (nsubstitute #\_ #\- (string-downcase (symbol-name lisp-name)))))
  25
  26 ;;; The opposite of GUESS-ALIEN-NAME-FROM-LISP-NAME. Make a symbol out
  27 ;;; of the string, converting all lowercase letters to uppercase and
  28 ;;; underscores into hyphens.
  29 (eval-when (:compile-toplevel :load-toplevel :execute)
  30   (defun guess-lisp-name-from-alien-name (alien-name)
  31     (declare (type simple-string alien-name))
  32     (intern (nsubstitute #\- #\_ (string-upcase alien-name)))))
  33
  34 ;;; Extract the Lisp and alien names from NAME. If only one is given,
  35 ;;; guess the other.
  36 (eval-when (:compile-toplevel :load-toplevel :execute)
  37   (defun pick-lisp-and-alien-names (name)
  38     (etypecase name
  39       (string
  40        (values (guess-lisp-name-from-alien-name name) name))
  41       (symbol
  42        (values name (guess-alien-name-from-lisp-name name)))
  43       (list
  44        (unless (proper-list-of-length-p name 2)
  45          (error "badly formed alien name"))
  46        (values (cadr name) (car name))))))
  47
  48 (defmacro define-alien-variable (name type &environment env)
  49   #!+sb-doc
  50   "Define NAME as an external alien variable of type TYPE. NAME should be
  51    a list of a string holding the alien name and a symbol to use as the Lisp
  52    name. If NAME is just a symbol or string, then the other name is guessed
  53    from the one supplied."
  54   (multiple-value-bind (lisp-name alien-name) (pick-lisp-and-alien-names name)
  55     (with-auxiliary-alien-types env
  56       (let ((alien-type (parse-alien-type type env)))
  57         `(eval-when (:compile-toplevel :load-toplevel :execute)
  58            ,@(when *new-auxiliary-types*
  59                `((%def-auxiliary-alien-types ',*new-auxiliary-types*)))
  60            (%define-alien-variable ',lisp-name
  61                                    ',alien-name
  62                                    ',alien-type))))))
  63
  64 (defmacro def-alien-variable (&rest rest)
  65   (deprecation-warning 'def-alien-variable 'define-alien-variable)
  66   `(define-alien-variable ,@rest))
  67
  68 ;;; Do the actual work of DEFINE-ALIEN-VARIABLE.
  69 (eval-when (:compile-toplevel :load-toplevel :execute)
  70   (defun %define-alien-variable (lisp-name alien-name type)
  71     (setf (info :variable :kind lisp-name) :alien)
  72     (setf (info :variable :where-from lisp-name) :defined)
  73     (clear-info :variable :constant-value lisp-name)
  74     (setf (info :variable :alien-info lisp-name)
  75           (make-heap-alien-info :type type
  76                                 :sap-form `(foreign-symbol-sap ',alien-name t)))))
  77
  78 (defmacro extern-alien (name type &environment env)
  79   #!+sb-doc
  80   "Access the alien variable named NAME, assuming it is of type TYPE. This
  81    is SETFable."
  82   (let* ((alien-name (etypecase name
  83                        (symbol (guess-alien-name-from-lisp-name name))
  84                        (string name)))
  85          (alien-type (parse-alien-type type env))
  86          (datap (not (alien-fun-type-p alien-type))))
  87     `(%heap-alien ',(make-heap-alien-info
  88                      :type alien-type
  89                      :sap-form `(foreign-symbol-sap ',alien-name ,datap)))))
  90
  91 (defmacro with-alien (bindings &body body &environment env)
  92   #!+sb-doc
  93   "Establish some local alien variables. Each BINDING is of the form:
  94      VAR TYPE [ ALLOCATION ] [ INITIAL-VALUE | EXTERNAL-NAME ]
  95    ALLOCATION should be one of:
  96      :LOCAL (the default)
  97        The alien is allocated on the stack, and has dynamic extent.
  98      :STATIC
  99        The alien is allocated on the heap, and has infinite extent. The alien
 100        is allocated at load time, so the same piece of memory is used each time
 101        this form executes.
 102      :EXTERN
 103        No alien is allocated, but VAR is established as a local name for
 104        the external alien given by EXTERNAL-NAME."
 105   (/show "entering WITH-ALIEN" bindings)
 106   (with-auxiliary-alien-types env
 107     (dolist (binding (reverse bindings))
 108       (/show binding)
 109       (destructuring-bind
 110           (symbol type &optional (opt1 nil opt1p) (opt2 nil opt2p))
 111           binding
 112         (/show symbol type opt1 opt2)
 113         (let* ((alien-type (parse-alien-type type env))
 114                (datap (not (alien-fun-type-p alien-type))))
 115           (/show alien-type)
 116           (multiple-value-bind (allocation initial-value)
 117               (if opt2p
 118                   (values opt1 opt2)
 119                   (case opt1
 120                     (:extern
 121                      (values opt1 (guess-alien-name-from-lisp-name symbol)))
 122                     (:static
 123                      (values opt1 nil))
 124                     (t
 125                      (values :local opt1))))
 126             (/show allocation initial-value)
 127             (setf body
 128                   (ecase allocation
 129                     #+nil
 130                     (:static
 131                      (let ((sap
 132                             (make-symbol (concatenate 'string "SAP-FOR-"
 133                                                       (symbol-name symbol)))))
 134                        `((let ((,sap (load-time-value (%make-alien ...))))
 135                            (declare (type system-area-pointer ,sap))
 136                            (symbol-macrolet
 137                             ((,symbol (sap-alien ,sap ,type)))
 138                             ,@(when initial-value
 139                                 `((setq ,symbol ,initial-value)))
 140                             ,@body)))))
 141                     (:extern
 142                      (/show0 ":EXTERN case")
 143                      (let ((info (make-heap-alien-info
 144                                   :type alien-type
 145                                   :sap-form `(foreign-symbol-sap ',initial-value
 146                                                                  ,datap))))
 147                        `((symbol-macrolet
 148                           ((,symbol (%heap-alien ',info)))
 149                           ,@body))))
 150                     (:local
 151                      (/show0 ":LOCAL case")
 152                      (let ((var (gensym))
 153                            (initval (if initial-value (gensym)))
 154                            (info (make-local-alien-info :type alien-type)))
 155                        (/show var initval info)
 156                        `((let ((,var (make-local-alien ',info))
 157                                ,@(when initial-value
 158                                    `((,initval ,initial-value))))
 159                            (note-local-alien-type ',info ,var)
 160                            (multiple-value-prog1
 161                                (symbol-macrolet
 162                                 ((,symbol (local-alien ',info ,var)))
 163                                 ,@(when initial-value
 164                                     `((setq ,symbol ,initval)))
 165                                 ,@body)
 166                                (dispose-local-alien ',info ,var))))))))))))
 167     (/show "revised" body)
 168     (verify-local-auxiliaries-okay)
 169     (/show0 "back from VERIFY-LOCAL-AUXILIARIES-OK, returning")
 170     `(symbol-macrolet ((&auxiliary-type-definitions&
 171                         ,(append *new-auxiliary-types*
 172                                  (auxiliary-type-definitions env))))
 173        ,@body)))
 174 \f
 175 ;;;; runtime C values that don't correspond directly to Lisp types
 176
 177 ;;; Note: The DEFSTRUCT for ALIEN-VALUE lives in a separate file
 178 ;;; 'cause it has to be real early in the cold-load order.
 179 #!-sb-fluid (declaim (freeze-type alien-value))
 180 (def!method print-object ((value alien-value) stream)
 181   (print-unreadable-object (value stream)
 182     (format stream
 183             "~S ~S #X~8,'0X ~S ~S"
 184             'alien-value
 185             :sap (sap-int (alien-value-sap value))
 186             :type (unparse-alien-type (alien-value-type value)))))
 187
 188 #!-sb-fluid (declaim (inline null-alien))
 189 (defun null-alien (x)
 190   #!+sb-doc
 191   "Return true if X (which must be an ALIEN pointer) is null, false otherwise."
 192   (zerop (sap-int (alien-sap x))))
 193
 194 (defmacro sap-alien (sap type &environment env)
 195   #!+sb-doc
 196   "Convert the system area pointer SAP to an ALIEN of the specified TYPE (not
 197    evaluated.) TYPE must be pointer-like."
 198   (let ((alien-type (parse-alien-type type env)))
 199     (if (eq (compute-alien-rep-type alien-type) 'system-area-pointer)
 200         `(%sap-alien ,sap ',alien-type)
 201         (error "cannot make an alien of type ~S out of a SAP" type))))
 202
 203 (defun %sap-alien (sap type)
 204   (declare (type system-area-pointer sap)
 205            (type alien-type type))
 206   (make-alien-value :sap sap :type type))
 207
 208 (defun alien-sap (alien)
 209   #!+sb-doc
 210   "Return a System-Area-Pointer pointing to Alien's data."
 211   (declare (type alien-value alien))
 212   (alien-value-sap alien))
 213 \f
 214 ;;;; allocation/deallocation of heap aliens
 215
 216 (defmacro make-alien (type &optional size &environment env)
 217   #!+sb-doc
 218   "Allocate an alien of type TYPE and return an alien pointer to it. If SIZE
 219 is supplied, how it is interpreted depends on TYPE. If TYPE is an array type,
 220 SIZE is used as the first dimension for the allocated array. If TYPE is not an
 221 array, then SIZE is the number of elements to allocate. The memory is
 222 allocated using ``malloc'', so it can be passed to foreign functions which use
 223 ``free''."
 224   (let ((alien-type (if (alien-type-p type)
 225                         type
 226                         (parse-alien-type type env))))
 227     (multiple-value-bind (size-expr element-type)
 228         (if (alien-array-type-p alien-type)
 229             (let ((dims (alien-array-type-dimensions alien-type)))
 230               (cond
 231                 (size
 232                  (unless dims
 233                    (error
 234                     "cannot override the size of zero-dimensional arrays"))
 235                  (when (constantp size)
 236                    (setf alien-type (copy-alien-array-type alien-type))
 237                    (setf (alien-array-type-dimensions alien-type)
 238                          (cons (constant-form-value size) (cdr dims)))))
 239                 (dims
 240                  (setf size (car dims)))
 241                 (t
 242                  (setf size 1)))
 243               (values `(* ,size ,@(cdr dims))
 244                       (alien-array-type-element-type alien-type)))
 245             (values (or size 1) alien-type))
 246       (let ((bits (alien-type-bits element-type))
 247             (alignment (alien-type-alignment element-type)))
 248         (unless bits
 249           (error "The size of ~S is unknown."
 250                  (unparse-alien-type element-type)))
 251         (unless alignment
 252           (error "The alignment of ~S is unknown."
 253                  (unparse-alien-type element-type)))
 254         ;; This is the one place where the %SAP-ALIEN note is quite
 255         ;; undesirable, in most uses of MAKE-ALIEN the %SAP-ALIEN
 256         ;; cannot be optimized away.
 257         `(locally (declare (muffle-conditions compiler-note))
 258            (%sap-alien (%make-alien (* ,(align-offset bits alignment)
 259                                        ,size-expr))
 260                        ',(make-alien-pointer-type :to alien-type)))))))
 261
 262 ;;; Allocate a block of memory at least BITS bits long and return a
 263 ;;; system area pointer to it.
 264 #!-sb-fluid (declaim (inline %make-alien))
 265 (defun %make-alien (bits)
 266   (declare (type index bits))
 267   (alien-funcall (extern-alien "malloc"
 268                                (function system-area-pointer unsigned))
 269                  (ash (the index (+ bits 7)) -3)))
 270
 271 #!-sb-fluid (declaim (inline free-alien))
 272 (defun free-alien (alien)
 273   #!+sb-doc
 274   "Dispose of the storage pointed to by ALIEN. ALIEN must have been allocated
 275    by MAKE-ALIEN or malloc(3)."
 276   (alien-funcall (extern-alien "free" (function (values) system-area-pointer))
 277                  (alien-sap alien))
 278   nil)
 279 \f
 280 ;;;; the SLOT operator
 281
 282 ;;; Find the field named SLOT, or die trying.
 283 (defun slot-or-lose (type slot)
 284   (declare (type alien-record-type type)
 285            (type symbol slot))
 286   (or (find slot (alien-record-type-fields type)
 287             :key #'alien-record-field-name)
 288       (error "There is no slot named ~S in ~S." slot type)))
 289
 290 ;;; Extract the value from the named slot from the record ALIEN. If
 291 ;;; ALIEN is actually a pointer, then DEREF it first.
 292 (defun slot (alien slot)
 293   #!+sb-doc
 294   "Extract SLOT from the Alien STRUCT or UNION ALIEN. May be set with SETF."
 295   (declare (type alien-value alien)
 296            (type symbol slot)
 297            (optimize (inhibit-warnings 3)))
 298   (let ((type (alien-value-type alien)))
 299     (etypecase type
 300       (alien-pointer-type
 301        (slot (deref alien) slot))
 302       (alien-record-type
 303        (let ((field (slot-or-lose type slot)))
 304          (extract-alien-value (alien-value-sap alien)
 305                               (alien-record-field-offset field)
 306                               (alien-record-field-type field)))))))
 307
 308 ;;; Deposit the value in the specified slot of the record ALIEN. If
 309 ;;; the ALIEN is really a pointer, DEREF it first. The compiler uses
 310 ;;; this when it can't figure out anything better.
 311 (defun %set-slot (alien slot value)
 312   (declare (type alien-value alien)
 313            (type symbol slot)
 314            (optimize (inhibit-warnings 3)))
 315   (let ((type (alien-value-type alien)))
 316     (etypecase type
 317       (alien-pointer-type
 318        (%set-slot (deref alien) slot value))
 319       (alien-record-type
 320        (let ((field (slot-or-lose type slot)))
 321          (deposit-alien-value (alien-value-sap alien)
 322                               (alien-record-field-offset field)
 323                               (alien-record-field-type field)
 324                               value))))))
 325
 326 ;;; Compute the address of the specified slot and return a pointer to it.
 327 (defun %slot-addr (alien slot)
 328   (declare (type alien-value alien)
 329            (type symbol slot)
 330            (optimize (inhibit-warnings 3)))
 331   (let ((type (alien-value-type alien)))
 332     (etypecase type
 333       (alien-pointer-type
 334        (%slot-addr (deref alien) slot))
 335       (alien-record-type
 336        (let* ((field (slot-or-lose type slot))
 337               (offset (alien-record-field-offset field))
 338               (field-type (alien-record-field-type field)))
 339          (%sap-alien (sap+ (alien-sap alien) (/ offset sb!vm:n-byte-bits))
 340                      (make-alien-pointer-type :to field-type)))))))
 341 \f
 342 ;;;; the DEREF operator
 343
 344 ;;; This function does most of the work of the different DEREF
 345 ;;; methods. It returns two values: the type and the offset (in bits)
 346 ;;; of the referred-to alien.
 347 (defun deref-guts (alien indices)
 348   (declare (type alien-value alien)
 349            (type list indices)
 350            (values alien-type integer))
 351   (let ((type (alien-value-type alien)))
 352     (etypecase type
 353       (alien-pointer-type
 354        (when (cdr indices)
 355          (error "too many indices when DEREF'ing ~S: ~W"
 356                 type
 357                 (length indices)))
 358        (let ((element-type (alien-pointer-type-to type)))
 359          (values element-type
 360                  (if indices
 361                      (* (align-offset (alien-type-bits element-type)
 362                                       (alien-type-alignment element-type))
 363                         (car indices))
 364                      0))))
 365       (alien-array-type
 366        (unless (= (length indices) (length (alien-array-type-dimensions type)))
 367          (error "incorrect number of indices when DEREF'ing ~S: ~W"
 368                 type (length indices)))
 369        (labels ((frob (dims indices offset)
 370                   (if (null dims)
 371                       offset
 372                       (frob (cdr dims) (cdr indices)
 373                         (+ (if (zerop offset)
 374                                0
 375                                (* offset (car dims)))
 376                            (car indices))))))
 377          (let ((element-type (alien-array-type-element-type type)))
 378            (values element-type
 379                    (* (align-offset (alien-type-bits element-type)
 380                                     (alien-type-alignment element-type))
 381                       (frob (alien-array-type-dimensions type)
 382                         indices 0)))))))))
 383
 384 ;;; Dereference the alien and return the results.
 385 (defun deref (alien &rest indices)
 386   #!+sb-doc
 387   "De-reference an Alien pointer or array. If an array, the indices are used
 388    as the indices of the array element to access. If a pointer, one index can
 389    optionally be specified, giving the equivalent of C pointer arithmetic."
 390   (declare (type alien-value alien)
 391            (type list indices)
 392            (optimize (inhibit-warnings 3)))
 393   (multiple-value-bind (target-type offset) (deref-guts alien indices)
 394     (extract-alien-value (alien-value-sap alien)
 395                          offset
 396                          target-type)))
 397
 398 (defun %set-deref (alien value &rest indices)
 399   (declare (type alien-value alien)
 400            (type list indices)
 401            (optimize (inhibit-warnings 3)))
 402   (multiple-value-bind (target-type offset) (deref-guts alien indices)
 403     (deposit-alien-value (alien-value-sap alien)
 404                          offset
 405                          target-type
 406                          value)))
 407
 408 (defun %deref-addr (alien &rest indices)
 409   (declare (type alien-value alien)
 410            (type list indices)
 411            (optimize (inhibit-warnings 3)))
 412   (multiple-value-bind (target-type offset) (deref-guts alien indices)
 413     (%sap-alien (sap+ (alien-value-sap alien) (/ offset sb!vm:n-byte-bits))
 414                 (make-alien-pointer-type :to target-type))))
 415 \f
 416 ;;;; accessing heap alien variables
 417
 418 (defun %heap-alien (info)
 419   (declare (type heap-alien-info info)
 420            (optimize (inhibit-warnings 3)))
 421   (extract-alien-value (eval (heap-alien-info-sap-form info))
 422                        0
 423                        (heap-alien-info-type info)))
 424
 425 (defun %set-heap-alien (info value)
 426   (declare (type heap-alien-info info)
 427            (optimize (inhibit-warnings 3)))
 428   (deposit-alien-value (eval (heap-alien-info-sap-form info))
 429                        0
 430                        (heap-alien-info-type info)
 431                        value))
 432
 433 (defun %heap-alien-addr (info)
 434   (declare (type heap-alien-info info)
 435            (optimize (inhibit-warnings 3)))
 436   (%sap-alien (eval (heap-alien-info-sap-form info))
 437               (make-alien-pointer-type :to (heap-alien-info-type info))))
 438 \f
 439 ;;;; accessing local aliens
 440
 441 (defun make-local-alien (info)
 442   (let* ((alien (eval `(make-alien ,(local-alien-info-type info))))
 443          (alien-sap (alien-sap alien)))
 444     (finalize
 445      alien
 446      (lambda ()
 447        (alien-funcall
 448         (extern-alien "free" (function (values) system-area-pointer))
 449         alien-sap)))
 450     alien))
 451
 452 (defun note-local-alien-type (info alien)
 453   (declare (ignore info alien))
 454   nil)
 455
 456 (defun local-alien (info alien)
 457   (declare (ignore info))
 458   (deref alien))
 459
 460 (defun %set-local-alien (info alien value)
 461   (declare (ignore info))
 462   (setf (deref alien) value))
 463
 464 (define-setf-expander local-alien (&whole whole info alien)
 465   (let ((value (gensym))
 466         (info (if (and (consp info)
 467                        (eq (car info) 'quote))
 468                   (second info)
 469                   (error "Something is wrong; local-alien-info not found: ~S"
 470                          whole))))
 471     (values nil
 472             nil
 473             (list value)
 474             `(if (%local-alien-forced-to-memory-p ',info)
 475                  (%set-local-alien ',info ,alien ,value)
 476                  (setf ,alien
 477                        (deport ,value ',(local-alien-info-type info))))
 478             whole)))
 479
 480 (defun %local-alien-forced-to-memory-p (info)
 481   (local-alien-info-force-to-memory-p info))
 482
 483 (defun %local-alien-addr (info alien)
 484   (declare (type local-alien-info info))
 485   (unless (local-alien-info-force-to-memory-p info)
 486     (error "~S isn't forced to memory. Something went wrong." alien))
 487   alien)
 488
 489 (defun dispose-local-alien (info alien)
 490   (declare (ignore info))
 491   (cancel-finalization alien)
 492   (free-alien alien))
 493 \f
 494 ;;;; the CAST macro
 495
 496 (defmacro cast (alien type &environment env)
 497   #!+sb-doc
 498   "Convert ALIEN to an Alien of the specified TYPE (not evaluated.)  Both types
 499    must be Alien array, pointer or function types."
 500   `(%cast ,alien ',(parse-alien-type type env)))
 501
 502 (defun %cast (alien target-type)
 503   (declare (type alien-value alien)
 504            (type alien-type target-type)
 505            (optimize (safety 2))
 506            (optimize (inhibit-warnings 3)))
 507   (if (or (alien-pointer-type-p target-type)
 508           (alien-array-type-p target-type)
 509           (alien-fun-type-p target-type))
 510       (let ((alien-type (alien-value-type alien)))
 511         (if (or (alien-pointer-type-p alien-type)
 512                 (alien-array-type-p alien-type)
 513                 (alien-fun-type-p alien-type))
 514             (naturalize (alien-value-sap alien) target-type)
 515             (error "~S cannot be casted." alien)))
 516       (error "cannot cast to alien type ~S" (unparse-alien-type target-type))))
 517 \f
 518 ;;;; the ALIEN-SIZE macro
 519
 520 (defmacro alien-size (type &optional (units :bits) &environment env)
 521   #!+sb-doc
 522   "Return the size of the alien type TYPE. UNITS specifies the units to
 523    use and can be either :BITS, :BYTES, or :WORDS."
 524   (let* ((alien-type (parse-alien-type type env))
 525          (bits (alien-type-bits alien-type)))
 526     (if bits
 527         (values (ceiling bits
 528                          (ecase units
 529                            (:bits 1)
 530                            (:bytes sb!vm:n-byte-bits)
 531                            (:words sb!vm:n-word-bits))))
 532         (error "unknown size for alien type ~S"
 533                (unparse-alien-type alien-type)))))
 534 \f
 535 ;;;; NATURALIZE, DEPORT, EXTRACT-ALIEN-VALUE, DEPOSIT-ALIEN-VALUE
 536
 537 (defun naturalize (alien type)
 538   (declare (type alien-type type))
 539   (funcall (coerce (compute-naturalize-lambda type) 'function)
 540            alien type))
 541
 542 (defun deport (value type)
 543   (declare (type alien-type type))
 544   (funcall (coerce (compute-deport-lambda type) 'function)
 545            value type))
 546
 547 (defun extract-alien-value (sap offset type)
 548   (declare (type system-area-pointer sap)
 549            (type unsigned-byte offset)
 550            (type alien-type type))
 551   (funcall (coerce (compute-extract-lambda type) 'function)
 552            sap offset type))
 553
 554 (defun deposit-alien-value (sap offset type value)
 555   (declare (type system-area-pointer sap)
 556            (type unsigned-byte offset)
 557            (type alien-type type))
 558   (funcall (coerce (compute-deposit-lambda type) 'function)
 559            sap offset type value))
 560 \f
 561 ;;;; ALIEN-FUNCALL, DEFINE-ALIEN-ROUTINE
 562
 563 (defun alien-funcall (alien &rest args)
 564   #!+sb-doc
 565   "Call the foreign function ALIEN with the specified arguments. ALIEN's
 566    type specifies the argument and result types."
 567   (declare (type alien-value alien))
 568   (let ((type (alien-value-type alien)))
 569     (typecase type
 570       (alien-pointer-type
 571        (apply #'alien-funcall (deref alien) args))
 572       (alien-fun-type
 573        (unless (= (length (alien-fun-type-arg-types type))
 574                   (length args))
 575          (error "wrong number of arguments for ~S~%expected ~W, got ~W"
 576                 type
 577                 (length (alien-fun-type-arg-types type))
 578                 (length args)))
 579        (let ((stub (alien-fun-type-stub type)))
 580          (unless stub
 581            (setf stub
 582                  (let ((fun (gensym))
 583                        (parms (make-gensym-list (length args))))
 584                    (compile nil
 585                             `(lambda (,fun ,@parms)
 586                                (declare (optimize (sb!c::insert-step-conditions 0)))
 587                                (declare (type (alien ,type) ,fun))
 588                                (alien-funcall ,fun ,@parms)))))
 589            (setf (alien-fun-type-stub type) stub))
 590          (apply stub alien args)))
 591       (t
 592        (error "~S is not an alien function." alien)))))
 593
 594 (defmacro define-alien-routine (name result-type
 595                                      &rest args
 596                                      &environment lexenv)
 597   #!+sb-doc
 598   "DEFINE-ALIEN-ROUTINE Name Result-Type {(Arg-Name Arg-Type [Style])}*
 599
 600   Define a foreign interface function for the routine with the specified NAME.
 601   Also automatically DECLAIM the FTYPE of the defined function.
 602
 603   NAME may be either a string, a symbol, or a list of the form (string symbol).
 604
 605   RETURN-TYPE is the alien type for the function return value. VOID may be
 606   used to specify a function with no result.
 607
 608   The remaining forms specify individual arguments that are passed to the
 609   routine. ARG-NAME is a symbol that names the argument, primarily for
 610   documentation. ARG-TYPE is the C type of the argument. STYLE specifies the
 611   way that the argument is passed.
 612
 613   :IN
 614         An :IN argument is simply passed by value. The value to be passed is
 615         obtained from argument(s) to the interface function. No values are
 616         returned for :In arguments. This is the default mode.
 617
 618   :OUT
 619         The specified argument type must be a pointer to a fixed sized object.
 620         A pointer to a preallocated object is passed to the routine, and the
 621         the object is accessed on return, with the value being returned from
 622         the interface function. :OUT and :IN-OUT cannot be used with pointers
 623         to arrays, records or functions.
 624
 625   :COPY
 626         This is similar to :IN, except that the argument values are stored
 627         on the stack, and a pointer to the object is passed instead of
 628         the value itself.
 629
 630   :IN-OUT
 631         This is a combination of :OUT and :COPY. A pointer to the argument is
 632         passed, with the object being initialized from the supplied argument
 633         and the return value being determined by accessing the object on
 634         return."
 635   (multiple-value-bind (lisp-name alien-name)
 636       (pick-lisp-and-alien-names name)
 637     (collect ((docs) (lisp-args) (lisp-arg-types)
 638               (lisp-result-types
 639                (cond ((eql result-type 'void)
 640                       ;; What values does a function return, if it
 641                       ;; returns no values? Exactly one - NIL. -- APD,
 642                       ;; 2003-03-02
 643                       (list 'null))
 644                      (t
 645                       ;; FIXME: Check for VALUES.
 646                       (list `(alien ,result-type)))))
 647               (arg-types) (alien-vars)
 648               (alien-args) (results))
 649       (dolist (arg args)
 650         (if (stringp arg)
 651             (docs arg)
 652             (destructuring-bind (name type &optional (style :in)) arg
 653               (unless (member style '(:in :copy :out :in-out))
 654                 (error "bogus argument style ~S in ~S" style arg))
 655               (when (and (member style '(:out :in-out))
 656                          (typep (parse-alien-type type lexenv)
 657                                 'alien-pointer-type))
 658                 (error "can't use :OUT or :IN-OUT on pointer-like type:~%  ~S"
 659                        type))
 660               (let (arg-type)
 661                 (cond ((eq style :in)
 662                        (setq arg-type type)
 663                        (alien-args name))
 664                       (t
 665                        (setq arg-type `(* ,type))
 666                        (if (eq style :out)
 667                            (alien-vars `(,name ,type))
 668                            (alien-vars `(,name ,type ,name)))
 669                        (alien-args `(addr ,name))))
 670                 (arg-types arg-type)
 671                 (unless (eq style :out)
 672                   (lisp-args name)
 673                   (lisp-arg-types t
 674                                   ;; FIXME: It should be something
 675                                   ;; like `(ALIEN ,ARG-TYPE), except
 676                                   ;; for we also accept SAPs where
 677                                   ;; pointers are required.
 678                                   )))
 679               (when (or (eq style :out) (eq style :in-out))
 680                 (results name)
 681                 (lisp-result-types `(alien ,type))))))
 682       `(progn
 683          ;; The theory behind this automatic DECLAIM is that (1) if
 684          ;; you're calling C, static typing is what you're doing
 685          ;; anyway, and (2) such a declamation can be (especially for
 686          ;; alien values) both messy to do by hand and very important
 687          ;; for performance of later code which uses the return value.
 688          (declaim (ftype (function ,(lisp-arg-types)
 689                                    (values ,@(lisp-result-types) &optional))
 690                          ,lisp-name))
 691          (defun ,lisp-name ,(lisp-args)
 692            ,@(docs)
 693            (with-alien
 694             ((,lisp-name (function ,result-type ,@(arg-types))
 695                          :extern ,alien-name)
 696              ,@(alien-vars))
 697              #-nil
 698              (values (alien-funcall ,lisp-name ,@(alien-args))
 699                      ,@(results))
 700              #+nil
 701              (if (alien-values-type-p result-type)
 702                  ;; FIXME: RESULT-TYPE is a type specifier, so it
 703                  ;; cannot be of type ALIEN-VALUES-TYPE. Also note,
 704                  ;; that if RESULT-TYPE is VOID, then this code
 705                  ;; disagrees with the computation of the return type
 706                  ;; and with all usages of this macro. -- APD,
 707                  ;; 2002-03-02
 708                  (let ((temps (make-gensym-list
 709                                (length
 710                                 (alien-values-type-values result-type)))))
 711                    `(multiple-value-bind ,temps
 712                         (alien-funcall ,lisp-name ,@(alien-args))
 713                       (values ,@temps ,@(results))))
 714                  (values (alien-funcall ,lisp-name ,@(alien-args))
 715                          ,@(results)))))))))
 716
 717 (defmacro def-alien-routine (&rest rest)
 718   (deprecation-warning 'def-alien-routine 'define-alien-routine)
 719   `(define-alien-routine ,@rest))
 720 \f
 721 (defun alien-typep (object type)
 722   #!+sb-doc
 723   "Return T iff OBJECT is an alien of type TYPE."
 724   (let ((lisp-rep-type (compute-lisp-rep-type type)))
 725     (if lisp-rep-type
 726         (typep object lisp-rep-type)
 727         (and (alien-value-p object)
 728              (alien-subtype-p (alien-value-type object) type)))))
 729
 730 ;;;; ALIEN CALLBACKS
 731 ;;;;
 732 ;;;; See "Foreign Linkage / Callbacks" in the SBCL Internals manual.
 733
 734 (defvar *alien-callback-info* nil
 735   "Maps SAPs to corresponding CALLBACK-INFO structures: contains all the
 736 information we need to manipulate callbacks after their creation. Used for
 737 changing the lisp-side function they point to, invalidation, etc.")
 738
 739 (defstruct callback-info
 740   specifier
 741   function ; NULL if invalid
 742   wrapper
 743   index)
 744
 745 (defun callback-info-key (info)
 746   (cons (callback-info-specifier info) (callback-info-function info)))
 747
 748 (defun alien-callback-info (alien)
 749   (cdr (assoc (alien-sap alien) *alien-callback-info* :test #'sap=)))
 750
 751 (defvar *alien-callbacks* (make-hash-table :test #'equal)
 752   "Cache of existing callback SAPs, indexed with (SPECIFER . FUNCTION). Used for
 753 memoization: we don't create new callbacks if one pointing to the correct
 754 function with the same specifier already exists.")
 755
 756 (defvar *alien-callback-wrappers* (make-hash-table :test #'equal)
 757   "Cache of existing lisp weappers, indexed with SPECIFER. Used for memoization:
 758 we don't create new wrappers if one for the same specifier already exists.")
 759
 760 (defvar *alien-callback-trampolines* (make-array 32 :fill-pointer 0 :adjustable t)
 761   "Lisp trampoline store: assembler wrappers contain indexes to this, and
 762 ENTER-ALIEN-CALLBACK pulls the corresponsing trampoline out and calls it.")
 763
 764 (defun %alien-callback-sap (specifier result-type argument-types function wrapper)
 765   (let ((key (cons specifier function)))
 766     (or (gethash key *alien-callbacks*)
 767         (setf (gethash key *alien-callbacks*)
 768               (let* ((index (fill-pointer *alien-callback-trampolines*))
 769                      ;; Aside from the INDEX this is known at
 770                      ;; compile-time, which could be utilized by
 771                      ;; having the two-stage assembler tramp &
 772                      ;; wrapper mentioned in [1] above: only the
 773                      ;; per-function tramp would need assembler at
 774                      ;; runtime. Possibly we could even pregenerate
 775                      ;; the code and just patch the index in later.
 776                      (assembler-wrapper (alien-callback-assembler-wrapper
 777                                          index result-type argument-types)))
 778                 (vector-push-extend
 779                  (alien-callback-lisp-trampoline wrapper function)
 780                  *alien-callback-trampolines*)
 781                 (let ((sap (vector-sap assembler-wrapper)))
 782                   (push (cons sap (make-callback-info :specifier specifier
 783                                                       :function function
 784                                                       :wrapper wrapper
 785                                                       :index index))
 786                         *alien-callback-info*)
 787                   sap))))))
 788
 789 (defun alien-callback-lisp-trampoline (wrapper function)
 790   (declare (function wrapper) (optimize speed))
 791   (lambda (args-pointer result-pointer)
 792     (funcall wrapper args-pointer result-pointer function)))
 793
 794 (defun alien-callback-lisp-wrapper-lambda (specifier result-type argument-types env)
 795   (let* ((arguments (make-gensym-list (length argument-types)))
 796          (argument-names arguments)
 797          (argument-specs (cddr specifier)))
 798     `(lambda (args-pointer result-pointer function)
 799        ;; FIXME: the saps are not gc safe
 800        (let ((args-sap (int-sap
 801                         (sb!kernel:get-lisp-obj-address args-pointer)))
 802              (res-sap (int-sap
 803                        (sb!kernel:get-lisp-obj-address result-pointer))))
 804          (declare (ignorable args-sap res-sap))
 805          (with-alien
 806              ,(loop
 807                  with offset = 0
 808                  for spec in argument-specs
 809                  collect `(,(pop argument-names) ,spec
 810                             :local ,(alien-callback-accessor-form
 811                                      spec 'args-sap offset))
 812                  do (incf offset (alien-callback-argument-bytes spec env)))
 813            ,(flet ((store (spec)
 814                           (if spec
 815                               `(setf (deref (sap-alien res-sap (* ,spec)))
 816                                      (funcall function ,@arguments))
 817                               `(funcall function ,@arguments))))
 818                   (cond ((alien-void-type-p result-type)
 819                          (store nil))
 820                         ((alien-integer-type-p result-type)
 821                          (if (alien-integer-type-signed result-type)
 822                              (store `(signed
 823                                       ,(alien-type-word-aligned-bits result-type)))
 824                              (store
 825                               `(unsigned
 826                                 ,(alien-type-word-aligned-bits result-type)))))
 827                         (t
 828                          (store (unparse-alien-type result-type)))))))
 829        (values))))
 830
 831 (defun invalid-alien-callback (&rest arguments)
 832   (declare (ignore arguments))
 833   (error "Invalid alien callback called."))
 834
 835
 836 (defun parse-callback-specification (result-type lambda-list)
 837   (values
 838    `(function ,result-type ,@(mapcar #'second lambda-list))
 839    (mapcar #'first lambda-list)))
 840
 841
 842 (defun parse-alien-ftype (specifier env)
 843   (destructuring-bind (function result-type &rest argument-types)
 844       specifier
 845     (aver (eq 'function function))
 846     (values (let ((*values-type-okay* t))
 847               (parse-alien-type result-type env))
 848             (mapcar (lambda (spec)
 849                       (parse-alien-type spec env))
 850                     argument-types))))
 851
 852 (defun alien-void-type-p (type)
 853   (and (alien-values-type-p type) (not (alien-values-type-values type))))
 854
 855 (defun alien-type-word-aligned-bits (type)
 856   (align-offset (alien-type-bits type) sb!vm:n-word-bits))
 857
 858 (defun alien-callback-argument-bytes (spec env)
 859   (let ((type (parse-alien-type spec env)))
 860     (if (or (alien-integer-type-p type)
 861             (alien-float-type-p type)
 862             (alien-pointer-type-p type)
 863             (alien-system-area-pointer-type-p type))
 864         (ceiling (alien-type-word-aligned-bits type) sb!vm:n-byte-bits)
 865         (error "Unsupported callback argument type: ~A" type))))
 866
 867 (defun enter-alien-callback (index return arguments)
 868   (funcall (aref *alien-callback-trampolines* index)
 869            return
 870            arguments))
 871
 872 ;;; To ensure that callback wrapper functions continue working even
 873 ;;; if #'ENTER-ALIEN-CALLBACK moves in memory, access to it is indirected
 874 ;;; through the *ENTER-ALIEN-CALLBACK* static symbol. -- JES, 2006-01-01
 875 (defvar *enter-alien-callback* #'enter-alien-callback)
 876
 877 ;;;; interface (not public, yet) for alien callbacks
 878
 879 (defmacro alien-callback (specifier function &environment env)
 880   "Returns an alien-value with of alien ftype SPECIFIER, that can be passed to
 881 an alien function as a pointer to the FUNCTION. If a callback for the given
 882 SPECIFIER and FUNCTION already exists, it is returned instead of consing a new
 883 one."
 884   ;; Pull out as much work as is convenient to macro-expansion time, specifically
 885   ;; everything that can be done given just the SPECIFIER and ENV.
 886   (multiple-value-bind (result-type argument-types) (parse-alien-ftype specifier env)
 887     `(%sap-alien
 888       (%alien-callback-sap ',specifier ',result-type ',argument-types
 889                            ,function
 890                            (or (gethash ',specifier *alien-callback-wrappers*)
 891                                (setf (gethash ',specifier *alien-callback-wrappers*)
 892                                      (compile nil
 893                                               ',(alien-callback-lisp-wrapper-lambda
 894                                                  specifier result-type argument-types env)))))
 895       ',(parse-alien-type specifier env))))
 896
 897 (defun alien-callback-p (alien)
 898   "Returns true if the alien is associated with a lisp-side callback,
 899 and a secondary return value of true if the callback is still valid."
 900   (let ((info (alien-callback-info alien)))
 901     (when info
 902       (values t (and (callback-info-function info) t)))))
 903
 904 (defun alien-callback-function (alien)
 905   "Returns the lisp function designator associated with the callback."
 906   (let ((info (alien-callback-info alien)))
 907     (when info
 908       (callback-info-function info))))
 909
 910 (defun (setf alien-callback-function) (function alien)
 911   "Changes the lisp function designated by the callback."
 912   (let ((info (alien-callback-info alien)))
 913     (unless info
 914       (error "Not an alien callback: ~S" alien))
 915     ;; sap cache
 916     (let ((key (callback-info-key info)))
 917       (remhash key *alien-callbacks*)
 918       (setf (gethash key *alien-callbacks*) (alien-sap alien)))
 919     ;; trampoline
 920     (setf (aref *alien-callback-trampolines* (callback-info-index info))
 921           (alien-callback-lisp-trampoline (callback-info-wrapper info) function))
 922     ;; metadata
 923     (setf (callback-info-function info) function)
 924     function))
 925
 926 (defun invalidate-alien-callback (alien)
 927   "Invalidates the callback designated by the alien, if any, allowing the
 928 associated lisp function to be GC'd, and causing further calls to the same
 929 callback signal an error."
 930   (let ((info (alien-callback-info alien)))
 931     (when (and info (callback-info-function info))
 932       ;; sap cache
 933       (remhash (callback-info-key info) *alien-callbacks*)
 934       ;; trampoline
 935       (setf (aref *alien-callback-trampolines* (callback-info-index info))
 936             #'invalid-alien-callback)
 937       ;; metadata
 938       (setf (callback-info-function info) nil)
 939       t)))
 940
 941 ;;; FIXME: This call assembles a new callback for every closure,
 942 ;;; which sucks hugely. ...not that I can think of an obvious
 943 ;;; solution. Possibly maybe we could write a generalized closure
 944 ;;; callback analogous to closure_tramp, and share the actual wrapper?
 945 ;;;
 946 ;;; For lambdas that result in simple-funs we get the callback from
 947 ;;; the cache on subsequent calls.
 948 (defmacro alien-lambda (result-type typed-lambda-list &body forms)
 949   (multiple-value-bind (specifier lambda-list)
 950       (parse-callback-specification result-type typed-lambda-list)
 951     `(alien-callback ,specifier (lambda ,lambda-list ,@forms))))
 952
 953 ;;; FIXME: Should subsequent (SETF FDEFINITION) affect the callback or not?
 954 ;;; What about subsequent DEFINE-ALIEN-CALLBACKs? My guess is that changing
 955 ;;; the FDEFINITION should invalidate the callback, and redefining the
 956 ;;; callback should change existing callbacks to point to the new defintion.
 957 (defmacro define-alien-callback (name result-type typed-lambda-list &body forms)
 958   "Defines #'NAME as a function with the given body and lambda-list, and NAME as
 959 the alien callback for that function with the given alien type."
 960   (declare (symbol name))
 961   (multiple-value-bind (specifier lambda-list)
 962       (parse-callback-specification result-type typed-lambda-list)
 963     `(progn
 964        (defun ,name ,lambda-list ,@forms)
 965        (defparameter ,name (alien-callback ,specifier #',name)))))