src/code/target-c-call.lisp

   1 ;;;; FIXME: This file and host-c-call.lisp are separate from the
   2 ;;;; rest of the alien source code for historical reasons: CMU CL
   3 ;;;; made a distinction between the stuff in the C-CALL package and
   4 ;;;; stuff in the ALIEN package. There's no obvious boundary
   5 ;;;; there, though, and SBCL doesn't try to make this distinction,
   6 ;;;; so it might make sense to just merge these files in with the
   7 ;;;; rest of the SB-ALIEN code.
   8
   9 ;;;; This software is part of the SBCL system. See the README file for
  10 ;;;; more information.
  11 ;;;;
  12 ;;;; This software is derived from the CMU CL system, which was
  13 ;;;; written at Carnegie Mellon University and released into the
  14 ;;;; public domain. The software is in the public domain and is
  15 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  16 ;;;; files for more information.
  17
  18 (in-package "SB!ALIEN")
  19 \f
  20 ;;;; extra types
  21
  22 (define-alien-type char (integer 8))
  23 (define-alien-type short (integer 16))
  24 (define-alien-type int (integer 32))
  25 #!-(and win32 x86-64)
  26 (define-alien-type long (integer #.sb!vm::n-machine-word-bits))
  27 #!+(and win32 x86-64)
  28 (define-alien-type long (integer 32))
  29
  30 (define-alien-type long-long (integer 64))
  31
  32 (define-alien-type unsigned-char (unsigned 8))
  33 (define-alien-type unsigned-short (unsigned 16))
  34 (define-alien-type unsigned-int (unsigned 32))
  35 #!-(and win32 x86-64)
  36 (define-alien-type unsigned-long (unsigned #.sb!vm::n-machine-word-bits))
  37 #!+(and win32 x86-64)
  38 (define-alien-type unsigned-long (unsigned 32))
  39 (define-alien-type unsigned-long-long (unsigned 64))
  40
  41 (define-alien-type float single-float)
  42 (define-alien-type double double-float)
  43
  44 (define-alien-type utf8-string (c-string :external-format :utf8))
  45
  46 (define-alien-type-translator void ()
  47   (parse-alien-type '(values) (sb!kernel:make-null-lexenv)))
  48 \f
  49
  50 (defun default-c-string-external-format ()
  51   #!+sb-xc
  52   :latin-1
  53   #!-sb-xc
  54   (or *default-c-string-external-format*
  55       (setf *default-c-string-external-format*
  56             (sb!impl::default-external-format))))
  57
  58 ;;; FIXME: %NATURALIZE-C-STRING (and the UTF8 siblings below) would
  59 ;;; appear to be vulnerable to the lisp string moving from underneath
  60 ;;; them if the world undergoes a GC, possibly triggered by another
  61 ;;; thread.  Ugh.
  62 ;;;
  63 ;;; Actually the above shouldn't happen; x86 and x86-64 use GENCGC,
  64 ;;; so the string can't move by virtue of pointers to it from
  65 ;;; outside the heap. Other platforms will access the lisp string
  66 ;;; through the GC-safe interior pointer. -- JES, 2006-01-13
  67 (defun %naturalize-c-string (sap)
  68   (declare (type system-area-pointer sap))
  69   (locally
  70       (declare (optimize (speed 3) (safety 0)))
  71     (let ((length (loop for offset of-type fixnum upfrom 0
  72                         until (zerop (sap-ref-8 sap offset))
  73                         finally (return offset))))
  74       (let ((result (make-string length :element-type 'base-char)))
  75         (sb!kernel:copy-ub8-from-system-area sap 0 result 0 length)
  76         result))))
  77
  78 (defun string-to-c-string (string external-format)
  79   (declare (type simple-string string))
  80   (locally
  81       (declare (optimize (speed 3) (safety 0)))
  82     (let ((external-format (sb!impl::get-external-format-or-lose external-format)))
  83       (funcall (sb!impl::ef-write-c-string-fun external-format) string))))
  84
  85 (defun c-string-to-string (sap external-format element-type)
  86   (declare (type system-area-pointer sap))
  87   (locally
  88       (declare (optimize (speed 3) (safety 0)))
  89     (let ((external-format (sb!impl::get-external-format-or-lose external-format)))
  90       (funcall (sb!impl::ef-read-c-string-fun external-format) sap element-type))))