src/code/target-defstruct.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3 ;;;;
   4 ;;;; This software is derived from the CMU CL system, which was
   5 ;;;; written at Carnegie Mellon University and released into the
   6 ;;;; public domain. The software is in the public domain and is
   7 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
   8 ;;;; files for more information.
   9
  10 (in-package "SB!KERNEL")
  11
  12 (/show0 "target-defstruct.lisp 12")
  13 \f
  14 ;;;; structure frobbing primitives
  15
  16 ;;; Allocate a new instance with LENGTH data slots.
  17 (defun %make-instance (length)
  18   (declare (type index length))
  19   (%make-instance length))
  20
  21 ;;; Given an instance, return its length.
  22 (defun %instance-length (instance)
  23   (declare (type instance instance))
  24   (%instance-length instance))
  25
  26 ;;; Return the value from the INDEXth slot of INSTANCE. This is SETFable.
  27 (defun %instance-ref (instance index)
  28   (%instance-ref instance index))
  29
  30 ;;; Set the INDEXth slot of INSTANCE to NEW-VALUE.
  31 (defun %instance-set (instance index new-value)
  32   (setf (%instance-ref instance index) new-value))
  33
  34 (defun %raw-ref-single (vec index)
  35   (declare (type index index))
  36   (%raw-ref-single vec index))
  37
  38 (defun %raw-ref-double (vec index)
  39   (declare (type index index))
  40   (%raw-ref-double vec index))
  41
  42 #!+long-float
  43 (defun %raw-ref-long (vec index)
  44   (declare (type index index))
  45   (%raw-ref-long vec index))
  46
  47 (defun %raw-set-single (vec index val)
  48   (declare (type index index))
  49   (%raw-set-single vec index val))
  50
  51 (defun %raw-set-double (vec index val)
  52   (declare (type index index))
  53   (%raw-set-double vec index val))
  54
  55 #!+long-float
  56 (defun %raw-set-long (vec index val)
  57   (declare (type index index))
  58   (%raw-set-long vec index val))
  59
  60 (defun %raw-ref-complex-single (vec index)
  61   (declare (type index index))
  62   (%raw-ref-complex-single vec index))
  63
  64 (defun %raw-ref-complex-double (vec index)
  65   (declare (type index index))
  66   (%raw-ref-complex-double vec index))
  67
  68 #!+long-float
  69 (defun %raw-ref-complex-long (vec index)
  70   (declare (type index index))
  71   (%raw-ref-complex-long vec index))
  72
  73 (defun %raw-set-complex-single (vec index val)
  74   (declare (type index index))
  75   (%raw-set-complex-single vec index val))
  76
  77 (defun %raw-set-complex-double (vec index val)
  78   (declare (type index index))
  79   (%raw-set-complex-double vec index val))
  80
  81 #!+long-float
  82 (defun %raw-set-complex-long (vec index val)
  83   (declare (type index index))
  84   (%raw-set-complex-long vec index val))
  85
  86 (defun %instance-layout (instance)
  87   (%instance-layout instance))
  88
  89 (defun %set-instance-layout (instance new-value)
  90   (%set-instance-layout instance new-value))
  91
  92 (defun %make-funcallable-instance (len layout)
  93    (%make-funcallable-instance len layout))
  94
  95 (defun funcallable-instance-p (x) (funcallable-instance-p x))
  96
  97 (defun %funcallable-instance-info (fin i)
  98   (%funcallable-instance-info fin i))
  99
 100 (defun %set-funcallable-instance-info (fin i new-value)
 101   (%set-funcallable-instance-info fin i new-value))
 102
 103 (defun funcallable-instance-fun (fin)
 104   (%funcallable-instance-lexenv fin))
 105
 106 ;;; The heart of the magic of funcallable instances ("FINs"). The
 107 ;;; function for a FIN must be a magical INSTANCE-LAMBDA form. When
 108 ;;; called (as with any other function), we grab the code pointer, and
 109 ;;; call it, leaving the original function object in LEXENV (in case
 110 ;;; it was a closure). If it is actually a FIN, then we need to do an
 111 ;;; extra indirection with funcallable-instance-lexenv to get at any
 112 ;;; closure environment. This extra indirection is set up when
 113 ;;; accessing the closure environment of an INSTANCE-LAMBDA. Note that
 114 ;;; the original FIN pointer is lost, so if the called function wants
 115 ;;; to get at the original object to do some slot accesses, it must
 116 ;;; close over the FIN object.
 117 ;;;
 118 ;;; If we set the FIN function to be a FIN, we directly copy across
 119 ;;; both the code pointer and the lexenv, since that code pointer (for
 120 ;;; an instance-lambda) is expecting that lexenv to be accessed. This
 121 ;;; effectively pre-flattens what would otherwise be a chain of
 122 ;;; indirections. (That used to happen when PCL dispatch functions
 123 ;;; were byte-compiled; now that the byte compiler is gone, I can't
 124 ;;; think of another example offhand. -- WHN 2001-10-06)
 125 ;;;
 126 ;;; The only loss is that if someone accesses the
 127 ;;; FUNCALLABLE-INSTANCE-FUN, then won't get a FIN back. This probably
 128 ;;; doesn't matter, since PCL only sets the FIN function.
 129 (defun (setf funcallable-instance-fun) (new-value fin)
 130   (setf (%funcallable-instance-fun fin)
 131         (%closure-fun new-value))
 132   (setf (%funcallable-instance-lexenv fin)
 133         (if (funcallable-instance-p new-value)
 134             (%funcallable-instance-lexenv new-value)
 135             new-value)))
 136 \f
 137 ;;;; target-only parts of the DEFSTRUCT top-level code
 138
 139 ;;; Catch attempts to mess up definitions of symbols in the CL package.
 140 (defun protect-cl (symbol)
 141   (/show0 "entering PROTECT-CL, SYMBOL=..")
 142   (/hexstr symbol)
 143   (when (and *cold-init-complete-p*
 144              (eq (symbol-package symbol) *cl-package*))
 145     (cerror "Go ahead and patch the system."
 146             "attempting to modify a symbol in the COMMON-LISP package: ~S"
 147             symbol))
 148   (/show0 "leaving PROTECT-CL")
 149   (values))
 150
 151 ;;; the part of %DEFSTRUCT which sets up out-of-line implementations
 152 ;;; of those structure functions which are sufficiently similar
 153 ;;; between structures that they can be closures
 154 ;;;
 155 ;;; (The "static" in the name is because it needs to be done not only
 156 ;;; in ordinary toplevel %DEFSTRUCT, but also in cold init as early as
 157 ;;; possible, to simulate static linking of structure functions as
 158 ;;; nearly as possible.)
 159 (defun %target-defstruct (dd layout)
 160   (declare (type defstruct-description dd))
 161   (declare (type layout layout))
 162
 163   (/show0 "entering %TARGET-DEFSTRUCT")
 164
 165   ;; (Constructors aren't set up here, because constructors are
 166   ;; varied enough (possibly parsing any specified argument list)
 167   ;; that we can't reasonably implement them as closures, and so
 168   ;; implement them with DEFUN instead.)
 169
 170   ;; Set FDEFINITIONs for slot accessors.
 171   (dolist (dsd (dd-slots dd))
 172     (/show0 "doing FDEFINITION for slot accessor")
 173     (let ((accessor-name (dsd-accessor-name dsd)))
 174       (/show0 "ACCESSOR-NAME=..")
 175       (/hexstr accessor-name)
 176       (protect-cl accessor-name)
 177       (/hexstr "getting READER-FUN and WRITER-FUN")
 178       (multiple-value-bind (reader-fun writer-fun) (slot-accessor-funs dd dsd)
 179         (declare (type function reader-fun writer-fun))
 180         (/show0 "got READER-FUN and WRITER-FUN=..")
 181         (/hexstr reader-fun)
 182         (setf (symbol-function accessor-name) reader-fun)
 183         (unless (dsd-read-only dsd)
 184           (/show0 "setting FDEFINITION for WRITER-FUN=..")
 185           (/hexstr writer-fun)
 186           (setf (fdefinition `(setf ,accessor-name)) writer-fun)))))
 187
 188   ;; Set FDEFINITION for copier.
 189   (when (dd-copier-name dd)
 190     (/show0 "doing FDEFINITION for copier")
 191     (protect-cl (dd-copier-name dd))
 192     ;; We can't use COPY-STRUCTURE for other kinds of objects, notably
 193     ;; funcallable structures, since it returns a STRUCTURE-OBJECT.
 194     ;; (And funcallable instances don't need copiers anyway.)
 195     (aver (eql (dd-type dd) 'structure))
 196     (setf (symbol-function (dd-copier-name dd))
 197           ;; FIXME: should use a closure which checks arg type before copying
 198           #'copy-structure))
 199
 200   ;; Set FDEFINITION for predicate.
 201   (when (dd-predicate-name dd)
 202     (/show0 "doing FDEFINITION for predicate")
 203     (protect-cl (dd-predicate-name dd))
 204     (setf (symbol-function (dd-predicate-name dd))
 205           (ecase (dd-type dd)
 206             ;; structures with LAYOUTs
 207             ((structure funcallable-structure)
 208              (/show0 "with-LAYOUT case")
 209              (lambda (object)
 210                (declare (optimize (speed 3) (safety 0)))
 211                (/noshow0 "in with-LAYOUT structure predicate closure, OBJECT,LAYOUT=..")
 212                (/nohexstr object)
 213                (/nohexstr layout)
 214                (typep-to-layout object layout)))
 215             ;; structures with no LAYOUT (i.e. :TYPE VECTOR or :TYPE LIST)
 216             ;;
 217             ;; FIXME: should handle the :NAMED T case in these cases
 218             (vector
 219              (/show0 ":TYPE VECTOR case")
 220              #'vectorp)
 221             (list
 222              (/show0 ":TYPE LIST case")
 223              #'listp))))
 224
 225   (/show0 "leaving %TARGET-DEFSTRUCT")
 226   (values))
 227
 228 \f
 229 ;;;; generating out-of-line slot accessor functions
 230
 231 ;;; FIXME: Ideally, the presence of the type checks in the functions
 232 ;;; here would be conditional on the optimization policy at the point
 233 ;;; of expansion of DEFSTRUCT. (For now we're just doing the simpler
 234 ;;; thing, putting in the type checks unconditionally.)
 235
 236 ;;; Return (VALUES SLOT-READER-FUN SLOT-WRITER-FUN).
 237 (defun slot-accessor-funs (dd dsd)
 238
 239   #+sb-xc (/show0 "entering SLOT-ACCESSOR-FUNS")
 240
 241   ;; various code generators
 242   ;;
 243   ;; Note: They're only minimally parameterized, and cavalierly grab
 244   ;; things like INSTANCE and DSD-INDEX from the namespace they're
 245   ;; expanded in.
 246   (macrolet (;; code shared between funcallable instance case and the
 247              ;; ordinary STRUCTURE-OBJECT case: Handle native
 248              ;; structures with LAYOUTs and (possibly) raw slots.
 249              (%native-slot-accessor-funs (dd-ref-fun-name)
 250                (let ((instance-type-check-form
 251                       '(%check-structure-type-from-layout instance layout)))
 252                  (/show "macroexpanding %NATIVE-SLOT-ACCESSOR-FUNS" dd-ref-fun-name instance-type-check-form)
 253                  `(let ((layout (dd-layout-or-lose dd))
 254                         (dsd-raw-type (dsd-raw-type dsd)))
 255                     #+sb-xc (/show0 "in %NATIVE-SLOT-ACCESSOR-FUNS macroexpanded code")
 256                     ;; Map over all the possible RAW-TYPEs, compiling
 257                     ;; a different closure-function for each one, so
 258                     ;; that once the COND over RAW-TYPEs happens (at
 259                     ;; the time closure is allocated) there are no
 260                     ;; more decisions to be made and things execute
 261                     ;; reasonably efficiently.
 262                     (cond
 263                      ;; nonraw slot case
 264                      ((eql dsd-raw-type t)
 265                       #+sb-xc (/show0 "in nonraw slot case")
 266                       (%slotplace-accessor-funs
 267                        (,dd-ref-fun-name instance dsd-index)
 268                        ,instance-type-check-form))
 269                      ;; raw slot cases
 270                      ,@(mapcar (lambda (rtd)
 271                                  (let ((raw-type (raw-slot-data-raw-type rtd))
 272                                        (accessor-name
 273                                         (raw-slot-data-accessor-name rtd))
 274                                        (n-words (raw-slot-data-n-words rtd)))
 275                                    `((equal dsd-raw-type ',raw-type)
 276                                      #+sb-xc (/show0 "in raw slot case")
 277                                      (let ((raw-index (dd-raw-index dd)))
 278                                        (multiple-value-bind (scaled-dsd-index
 279                                                              misalignment)
 280                                            (floor dsd-index ,n-words)
 281                                          (aver (zerop misalignment))
 282                                          (%slotplace-accessor-funs
 283                                           (,accessor-name (,dd-ref-fun-name
 284                                                            instance
 285                                                            raw-index)
 286                                                           scaled-dsd-index)
 287                                           ,instance-type-check-form))))))
 288                                *raw-slot-data-list*)
 289                      ;; oops
 290                      (t
 291                       (error "internal error: unexpected DSD-RAW-TYPE ~S"
 292                              dsd-raw-type))))))
 293              ;; code shared between DEFSTRUCT :TYPE LIST and
 294              ;; DEFSTRUCT :TYPE VECTOR cases: Handle the "typed
 295              ;; structure" case, with no LAYOUTs and no raw slots.
 296              (%colontyped-slot-accessor-funs () (error "stub"))
 297              ;; the common structure of the raw-slot and not-raw-slot
 298              ;; cases, defined in terms of the writable SLOTPLACE. All
 299              ;; possible flavors of slot access should be able to pass
 300              ;; through here.
 301              (%slotplace-accessor-funs (slotplace instance-type-check-form)
 302                (/show "macroexpanding %SLOTPLACE-ACCESSOR-FUNS" slotplace instance-type-check-form)
 303                `(values (lambda (instance)
 304                           (/noshow0 "in %SLOTPLACE-ACCESSOR-FUNS-defined reader")
 305                           ,instance-type-check-form
 306                           (/noshow0 "back from INSTANCE-TYPE-CHECK-FORM")
 307                           ,slotplace)
 308                         (let ((typecheckfun (typespec-typecheckfun dsd-type)))
 309                           (lambda (new-value instance)
 310                             (/noshow0 "in %SLOTPLACE-ACCESSOR-FUNS-defined writer")
 311                             ,instance-type-check-form
 312                             (/noshow0 "back from INSTANCE-TYPE-CHECK-FORM")
 313                             (funcall typecheckfun new-value)
 314                             (/noshow0 "back from TYPECHECKFUN")
 315                             (setf ,slotplace new-value))))))
 316
 317     (let ((dsd-index (dsd-index dsd))
 318           (dsd-type (dsd-type dsd)))
 319
 320       #+sb-xc (/show0 "got DSD-TYPE=..")
 321       #+sb-xc (/hexstr dsd-type)
 322       (ecase (dd-type dd)
 323
 324         ;; native structures
 325         (structure
 326          #+sb-xc (/show0 "case of DSD-TYPE = STRUCTURE")
 327          (%native-slot-accessor-funs %instance-ref))
 328
 329         ;; structures with the :TYPE option
 330
 331         ;; FIXME: Worry about these later..
 332         #|
 333         ;; In :TYPE LIST and :TYPE VECTOR structures, ANSI specifies the
 334         ;; layout completely, so that raw slots are impossible.
 335         (list
 336          (dd-type-slot-accessor-funs nth-but-with-sane-arg-order
 337                                  `(%check-structure-type-from-dd
 338                                  :maybe-raw-p nil))
 339         (vector
 340          (dd-type-slot-accessor-funs aref
 341                                  :maybe-raw-p nil)))
 342         |#
 343         ))))
 344 \f
 345 ;;; Copy any old kind of structure.
 346 (defun copy-structure (structure)
 347   #!+sb-doc
 348   "Return a copy of STRUCTURE with the same (EQL) slot values."
 349   (declare (type structure-object structure))
 350   (let* ((len (%instance-length structure))
 351          (res (%make-instance len))
 352          (layout (%instance-layout structure)))
 353
 354     (declare (type index len))
 355     (when (layout-invalid layout)
 356       (error "attempt to copy an obsolete structure:~%  ~S" structure))
 357
 358     ;; Copy ordinary slots.
 359     (dotimes (i len)
 360       (declare (type index i))
 361       (setf (%instance-ref res i)
 362             (%instance-ref structure i)))
 363
 364     ;; Copy raw slots.
 365     (let ((raw-index (dd-raw-index (layout-info layout))))
 366       (when raw-index
 367         (let* ((data (%instance-ref structure raw-index))
 368                (raw-len (length data))
 369                (new (make-array raw-len :element-type '(unsigned-byte 32))))
 370           (declare (type (simple-array (unsigned-byte 32) (*)) data))
 371           (setf (%instance-ref res raw-index) new)
 372           (dotimes (i raw-len)
 373             (setf (aref new i) (aref data i))))))
 374
 375     res))
 376 \f
 377 ;;; default PRINT-OBJECT and MAKE-LOAD-FORM methods
 378
 379 (defun %default-structure-pretty-print (structure stream)
 380   (let* ((layout (%instance-layout structure))
 381          (name (sb!xc:class-name (layout-class layout)))
 382          (dd (layout-info layout)))
 383     (pprint-logical-block (stream nil :prefix "#S(" :suffix ")")
 384       (prin1 name stream)
 385       (let ((remaining-slots (dd-slots dd)))
 386         (when remaining-slots
 387           (write-char #\space stream)
 388           ;; CMU CL had (PPRINT-INDENT :BLOCK 2 STREAM) here,
 389           ;; but I can't see why. -- WHN 20000205
 390           (pprint-newline :linear stream)
 391           (loop
 392            (pprint-pop)
 393            (let ((slot (pop remaining-slots)))
 394              (write-char #\: stream)
 395              (output-symbol-name (dsd-%name slot) stream)
 396              (write-char #\space stream)
 397              (pprint-newline :miser stream)
 398              (output-object (funcall (fdefinition (dsd-accessor-name slot))
 399                                      structure)
 400                             stream)
 401              (when (null remaining-slots)
 402                (return))
 403              (write-char #\space stream)
 404              (pprint-newline :linear stream))))))))
 405 (defun %default-structure-ugly-print (structure stream)
 406   (let* ((layout (%instance-layout structure))
 407          (name (sb!xc:class-name (layout-class layout)))
 408          (dd (layout-info layout)))
 409     (descend-into (stream)
 410       (write-string "#S(" stream)
 411       (prin1 name stream)
 412       (do ((index 0 (1+ index))
 413            (remaining-slots (dd-slots dd) (cdr remaining-slots)))
 414           ((or (null remaining-slots)
 415                (and (not *print-readably*)
 416                     *print-length*
 417                     (>= index *print-length*)))
 418            (if (null remaining-slots)
 419                (write-string ")" stream)
 420                (write-string " ...)" stream)))
 421         (declare (type index index))
 422         (write-char #\space stream)
 423         (write-char #\: stream)
 424         (let ((slot (first remaining-slots)))
 425           (output-symbol-name (dsd-%name slot) stream)
 426           (write-char #\space stream)
 427           (output-object
 428            (funcall (fdefinition (dsd-accessor-name slot))
 429                     structure)
 430            stream))))))
 431 (defun default-structure-print (structure stream depth)
 432   (declare (ignore depth))
 433   (cond ((funcallable-instance-p structure)
 434          (print-unreadable-object (structure stream :identity t :type t)))
 435         (*print-pretty*
 436          (%default-structure-pretty-print structure stream))
 437         (t
 438          (%default-structure-ugly-print structure-stream))))
 439 (def!method print-object ((x structure-object) stream)
 440   (default-structure-print x stream *current-level*))
 441
 442 (defun make-load-form-saving-slots (object &key slot-names environment)
 443   (declare (ignore object environment))
 444   (if slot-names
 445     (error "stub: MAKE-LOAD-FORM-SAVING-SLOTS :SLOT-NAMES not implemented") ; KLUDGE
 446     :just-dump-it-normally))
 447 \f
 448 ;;;; testing structure types
 449
 450 ;;; Return true if OBJ is an object of the structure type
 451 ;;; corresponding to LAYOUT. This is called by the accessor closures,
 452 ;;; which have a handle on the type's LAYOUT.
 453 ;;;
 454 ;;; FIXME: This is fairly big, so it should probably become
 455 ;;; MAYBE-INLINE instead of INLINE. Or else we could fix things up so
 456 ;;; that the things which call it are all closures, so that it's
 457 ;;; expanded only in a small number of places.
 458 #!-sb-fluid (declaim (inline typep-to-layout))
 459 (defun typep-to-layout (obj layout)
 460   (declare (type layout layout) (optimize (speed 3) (safety 0)))
 461   (/noshow0 "entering TYPEP-TO-LAYOUT, OBJ,LAYOUT=..")
 462   (/nohexstr obj)
 463   (/nohexstr layout)
 464   (when (layout-invalid layout)
 465     (error "An obsolete structure accessor function was called."))
 466   (/noshow0 "back from testing LAYOUT-INVALID LAYOUT")
 467   ;; FIXME: CMU CL used (%INSTANCEP OBJ) here. Check that
 468   ;; (TYPEP OBJ 'INSTANCE) is optimized to equally efficient code.
 469   (and (typep obj 'instance)
 470        (let ((obj-layout (%instance-layout obj)))
 471          (cond ((eq obj-layout layout)
 472                 ;; (In this case OBJ-LAYOUT can't be invalid, because
 473                 ;; we determined LAYOUT is valid in the test above.)
 474                 (/noshow0 "EQ case")
 475                 t)
 476                ((layout-invalid obj-layout)
 477                 (/noshow0 "LAYOUT-INVALID case")
 478                 (error 'layout-invalid
 479                        :expected-type (layout-class obj-layout)
 480                        :datum obj))
 481                (t
 482                 (let ((depthoid (layout-depthoid layout)))
 483                   (/noshow0 "DEPTHOID case, DEPTHOID,LAYOUT-INHERITS=..")
 484                   (/nohexstr depthoid)
 485                   (/nohexstr layout-inherits)
 486                   (and (> (layout-depthoid obj-layout) depthoid)
 487                        (eq (svref (layout-inherits obj-layout) depthoid)
 488                            layout))))))))
 489 \f
 490 ;;;; checking structure types
 491
 492 ;;; Check that X is an instance of the named structure type.
 493 (defmacro %check-structure-type-from-name (x name)
 494   `(%check-structure-type-from-layout ,x ,(compiler-layout-or-lose name)))
 495
 496 ;;; Check that X is a structure of the type described by DD.
 497 (defmacro %check-structure-type-from-dd (x dd)
 498   (declare (type defstruct-description dd))
 499   (let ((class-name (dd-name dd)))
 500     (ecase (dd-type dd)
 501       ((structure funcallable-instance)
 502        `(%check-structure-type-from-layout
 503          ,x
 504          ,(compiler-layout-or-lose class-name)))
 505       ((vector)
 506        (let ((xx (gensym "X")))
 507          `(let ((,xx ,x))
 508             (declare (type vector ,xx))
 509             ,@(when (dd-named dd)
 510                 `((unless (eql (aref ,xx 0) ',class-name)
 511                     (error
 512                      'simple-type-error
 513                      :datum (aref ,xx 0)
 514                      :expected-type `(member ,class-name)
 515                      :format-control
 516                      "~@<missing name in instance of ~
 517                       VECTOR-typed structure ~S: ~2I~_S~:>"
 518                      :format-arguments (list ',class-name ,xx)))))
 519             (values))))
 520       ((list)
 521        (let ((xx (gensym "X")))
 522          `(let ((,xx ,x))
 523             (declare (type list ,xx))
 524             ,@(when (dd-named dd)
 525                 `((unless (eql (first ,xx) ',class-name)
 526                     (error
 527                      'simple-type-error
 528                      :datum (aref ,xx 0)
 529                      :expected-type `(member ,class-name)
 530                      :format-control
 531                      "~@<missing name in instance of LIST-typed structure ~S: ~
 532                       ~2I~_S~:>"
 533                      :format-arguments (list ',class-name ,xx)))))
 534             (values)))))))
 535
 536 ;;; Check that X is an instance of the structure class with layout LAYOUT.
 537 (defun %check-structure-type-from-layout (x layout)
 538   (unless (typep-to-layout x layout)
 539     (error 'type-error
 540            :datum x
 541            :expected-type (class-name (layout-class layout))))
 542   (values))
 543 \f
 544 (/show0 "target-defstruct.lisp end of file")