src/code/target-defstruct.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3 ;;;;
   4 ;;;; This software is derived from the CMU CL system, which was
   5 ;;;; written at Carnegie Mellon University and released into the
   6 ;;;; public domain. The software is in the public domain and is
   7 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
   8 ;;;; files for more information.
   9
  10 (in-package "SB!KERNEL")
  11
  12 (/show0 "target-defstruct.lisp 12")
  13 \f
  14 ;;;; structure frobbing primitives
  15
  16 (defun %make-instance (length)
  17   #!+sb-doc
  18   "Allocate a new instance with LENGTH data slots."
  19   (declare (type index length))
  20   (%make-instance length))
  21
  22 (defun %instance-length (instance)
  23   #!+sb-doc
  24   "Given an instance, return its length."
  25   (declare (type instance instance))
  26   (%instance-length instance))
  27
  28 (defun %instance-ref (instance index)
  29   #!+sb-doc
  30   "Return the value from the INDEXth slot of INSTANCE. This is SETFable."
  31   (%instance-ref instance index))
  32
  33 (defun %instance-set (instance index new-value)
  34   #!+sb-doc
  35   "Set the INDEXth slot of INSTANCE to NEW-VALUE."
  36   (setf (%instance-ref instance index) new-value))
  37
  38 (defun %raw-ref-single (vec index)
  39   (declare (type index index))
  40   (%raw-ref-single vec index))
  41
  42 (defun %raw-ref-double (vec index)
  43   (declare (type index index))
  44   (%raw-ref-double vec index))
  45
  46 #!+long-float
  47 (defun %raw-ref-long (vec index)
  48   (declare (type index index))
  49   (%raw-ref-long vec index))
  50
  51 (defun %raw-set-single (vec index val)
  52   (declare (type index index))
  53   (%raw-set-single vec index val))
  54
  55 (defun %raw-set-double (vec index val)
  56   (declare (type index index))
  57   (%raw-set-double vec index val))
  58
  59 #!+long-float
  60 (defun %raw-set-long (vec index val)
  61   (declare (type index index))
  62   (%raw-set-long vec index val))
  63
  64 (defun %raw-ref-complex-single (vec index)
  65   (declare (type index index))
  66   (%raw-ref-complex-single vec index))
  67
  68 (defun %raw-ref-complex-double (vec index)
  69   (declare (type index index))
  70   (%raw-ref-complex-double vec index))
  71
  72 #!+long-float
  73 (defun %raw-ref-complex-long (vec index)
  74   (declare (type index index))
  75   (%raw-ref-complex-long vec index))
  76
  77 (defun %raw-set-complex-single (vec index val)
  78   (declare (type index index))
  79   (%raw-set-complex-single vec index val))
  80
  81 (defun %raw-set-complex-double (vec index val)
  82   (declare (type index index))
  83   (%raw-set-complex-double vec index val))
  84
  85 #!+long-float
  86 (defun %raw-set-complex-long (vec index val)
  87   (declare (type index index))
  88   (%raw-set-complex-long vec index val))
  89
  90 (defun %instance-layout (instance)
  91   (%instance-layout instance))
  92
  93 (defun %set-instance-layout (instance new-value)
  94   (%set-instance-layout instance new-value))
  95
  96 (defun %make-funcallable-instance (len layout)
  97    (%make-funcallable-instance len layout))
  98
  99 (defun funcallable-instance-p (x) (funcallable-instance-p x))
 100
 101 (defun %funcallable-instance-info (fin i)
 102   (%funcallable-instance-info fin i))
 103
 104 (defun %set-funcallable-instance-info (fin i new-value)
 105   (%set-funcallable-instance-info fin i new-value))
 106
 107 (defun funcallable-instance-function (fin)
 108   (%funcallable-instance-lexenv fin))
 109
 110 ;;; The heart of the magic of funcallable instances ("FINs"). The
 111 ;;; function for a FIN must be a magical INSTANCE-LAMBDA form. When
 112 ;;; called (as with any other function), we grab the code pointer, and
 113 ;;; call it, leaving the original function object in LEXENV (in case
 114 ;;; it was a closure). If it is actually a FIN, then we need to do an
 115 ;;; extra indirection with funcallable-instance-lexenv to get at any
 116 ;;; closure environment. This extra indirection is set up when
 117 ;;; accessing the closure environment of an INSTANCE-LAMBDA. Note that
 118 ;;; the original FIN pointer is lost, so if the called function wants
 119 ;;; to get at the original object to do some slot accesses, it must
 120 ;;; close over the FIN object.
 121 ;;;
 122 ;;; If we set the FIN function to be a FIN, we directly copy across
 123 ;;; both the code pointer and the lexenv, since that code pointer (for
 124 ;;; an instance-lambda) is expecting that lexenv to be accessed. This
 125 ;;; effectively pre-flattens what would otherwise be a chain of
 126 ;;; indirections. Lest this sound like an excessively obscure case,
 127 ;;; note that it happens when PCL dispatch functions are
 128 ;;; byte-compiled.
 129 ;;;
 130 ;;; The only loss is that if someone accesses the
 131 ;;; FUNCALLABLE-INSTANCE-FUNCTION, then won't get a FIN back. This
 132 ;;; probably doesn't matter, since PCL only sets the FIN function. And
 133 ;;; the only reason that interpreted functions are FINs instead of
 134 ;;; bare closures is for debuggability.
 135 (defun (setf funcallable-instance-function) (new-value fin)
 136   (setf (%funcallable-instance-function fin)
 137         (%closure-function new-value))
 138   (setf (%funcallable-instance-lexenv fin)
 139         (if (funcallable-instance-p new-value)
 140             (%funcallable-instance-lexenv new-value)
 141             new-value)))
 142 \f
 143 ;;; Copy any old kind of structure.
 144 (defun copy-structure (structure)
 145   #!+sb-doc
 146   "Return a copy of STRUCTURE with the same (EQL) slot values."
 147   (declare (type structure-object structure))
 148   (let* ((len (%instance-length structure))
 149          (res (%make-instance len))
 150          (layout (%instance-layout structure)))
 151
 152     (declare (type index len))
 153     (when (layout-invalid layout)
 154       (error "attempt to copy an obsolete structure:~%  ~S" structure))
 155
 156     ;; Copy ordinary slots.
 157     (dotimes (i len)
 158       (declare (type index i))
 159       (setf (%instance-ref res i)
 160             (%instance-ref structure i)))
 161
 162     ;; Copy raw slots.
 163     (let ((raw-index (dd-raw-index (layout-info layout))))
 164       (when raw-index
 165         (let* ((data (%instance-ref structure raw-index))
 166                (raw-len (length data))
 167                (new (make-array raw-len :element-type '(unsigned-byte 32))))
 168           (declare (type (simple-array (unsigned-byte 32) (*)) data))
 169           (setf (%instance-ref res raw-index) new)
 170           (dotimes (i raw-len)
 171             (setf (aref new i) (aref data i))))))
 172
 173     res))
 174 \f
 175 ;;; default PRINT and MAKE-LOAD-FORM methods
 176
 177 (defun default-structure-print (structure stream depth)
 178   (declare (ignore depth))
 179   (if (funcallable-instance-p structure)
 180       (print-unreadable-object (structure stream :identity t :type t))
 181       (let* ((type (%instance-layout structure))
 182              (name (sb!xc:class-name (layout-class type)))
 183              (dd (layout-info type)))
 184         (if *print-pretty*
 185             (pprint-logical-block (stream nil :prefix "#S(" :suffix ")")
 186               (prin1 name stream)
 187               (let ((slots (dd-slots dd)))
 188                 (when slots
 189                   (write-char #\space stream)
 190                   ;; CMU CL had (PPRINT-INDENT :BLOCK 2 STREAM) here,
 191                   ;; but I can't see why. -- WHN 20000205
 192                   (pprint-newline :linear stream)
 193                   (loop
 194                     (pprint-pop)
 195                     (let ((slot (pop slots)))
 196                       (write-char #\: stream)
 197                       (output-symbol-name (dsd-%name slot) stream)
 198                       (write-char #\space stream)
 199                       (pprint-newline :miser stream)
 200                       (output-object (funcall (fdefinition (dsd-accessor slot))
 201                                               structure)
 202                                      stream)
 203                       (when (null slots)
 204                         (return))
 205                       (write-char #\space stream)
 206                       (pprint-newline :linear stream))))))
 207             (descend-into (stream)
 208               (write-string "#S(" stream)
 209               (prin1 name stream)
 210               (do ((index 0 (1+ index))
 211                    (slots (dd-slots dd) (cdr slots)))
 212                   ((or (null slots)
 213                        (and (not *print-readably*)
 214                             *print-length*
 215                             (>= index *print-length*)))
 216                    (if (null slots)
 217                        (write-string ")" stream)
 218                        (write-string " ...)" stream)))
 219                 (declare (type index index))
 220                 (write-char #\space stream)
 221                 (write-char #\: stream)
 222                 (let ((slot (first slots)))
 223                   (output-symbol-name (dsd-%name slot) stream)
 224                   (write-char #\space stream)
 225                   (output-object (funcall (fdefinition (dsd-accessor slot))
 226                                           structure)
 227                                  stream))))))))
 228 (def!method print-object ((x structure-object) stream)
 229   (default-structure-print x stream *current-level*))
 230
 231 (defun make-load-form-saving-slots (object &key slot-names environment)
 232   (declare (ignore object environment))
 233   (if slot-names
 234     (error "stub: MAKE-LOAD-FORM-SAVING-SLOTS :SLOT-NAMES not implemented") ; KLUDGE
 235     :just-dump-it-normally))
 236 \f
 237 ;;; Return true if OBJ is an object of the structure type
 238 ;;; corresponding to LAYOUT. This is called by the accessor closures,
 239 ;;; which have a handle on the type's layout.
 240 ;;;
 241 ;;; FIXME: This is fairly big, so it should probably become
 242 ;;; MAYBE-INLINE instead of INLINE. Or else we could fix things up so
 243 ;;; that the things which call it are all closures, so that it's
 244 ;;; expanded only in a small number of places.
 245 #!-sb-fluid (declaim (inline typep-to-layout))
 246 (defun typep-to-layout (obj layout)
 247   (declare (type layout layout) (optimize (speed 3) (safety 0)))
 248   (when (layout-invalid layout)
 249     (error "An obsolete structure accessor function was called."))
 250   ;; FIXME: CMU CL used (%INSTANCEP OBJ) here. Check that
 251   ;; (TYPEP OBJ 'INSTANCE) is optimized to equally efficient code.
 252   (and (typep obj 'instance)
 253        (let ((obj-layout (%instance-layout obj)))
 254          (cond ((eq obj-layout layout)
 255                 t)
 256                ;; FIXME: Does the test for LAYOUT-INVALID really belong
 257                ;; after the test for EQ LAYOUT? Either explain why this
 258                ;; is, or change the order.
 259                ((layout-invalid obj-layout)
 260                 (error 'layout-invalid
 261                        :expected-type (layout-class obj-layout)
 262                        :datum obj))
 263                (t
 264                  (let ((depthoid (layout-depthoid layout)))
 265                    (and (> (layout-depthoid obj-layout) depthoid)
 266                         (eq (svref (layout-inherits obj-layout) depthoid)
 267                             layout))))))))
 268 \f
 269 ;;;; implementing structure slot accessors as closures
 270
 271 ;;; In the normal case of structures that have a real type (i.e. no
 272 ;;; :TYPE option was specified), we want to optimize things for space
 273 ;;; as well as speed, since there can be thousands of defined slot
 274 ;;; accessors.
 275 ;;;
 276 ;;; What we do is define the accessors and copier as closures over
 277 ;;; general-case code. Since the compiler will normally open-code
 278 ;;; accessors, the (minor) extra speed penalty for full calls is not a
 279 ;;; concern.
 280 ;;;
 281 ;;; KLUDGE: This is a minor headache at cold init time, since genesis
 282 ;;; doesn't know how to create the closures in the cold image, so the
 283 ;;; function definitions aren't done until the appropriate top level
 284 ;;; forms are executed, so any forward references to structure slots
 285 ;;; (which are compiled into full calls) fail. The headache can be
 286 ;;; treated by using SB!XC:DEFSTRUCT on the relevant structure at
 287 ;;; build-the-cross-compiler time, so that the compiler is born
 288 ;;; knowing how to inline accesses to the relevant structure, so no
 289 ;;; full calls are made. This can be achieved by calling
 290 ;;; SB!XC:DEFSTRUCT directly, or by using DEF!STRUCT, which (among
 291 ;;; other things) calls SB!XC:DEFSTRUCT for you.
 292
 293 ;;; Return closures to do slot access according to Layout and DSD. We check
 294 ;;; types, then do the access. This is only used for normal slots, not raw
 295 ;;; slots.
 296 (defun structure-slot-getter (layout dsd)
 297   (let ((class (layout-class layout)))
 298     (if (typep class 'basic-structure-class)
 299         #'(lambda (structure)
 300             (declare (optimize (speed 3) (safety 0)))
 301             (flet ((structure-test (structure)
 302                      (typep-to-layout structure layout)))
 303               (unless (structure-test structure)
 304                 (error 'simple-type-error
 305                        :datum structure
 306                        :expected-type (class-name (layout-class layout))
 307                        :format-control
 308                        "Structure for accessor ~S is not a ~S:~% ~S"
 309                        :format-arguments
 310                        (list (dsd-accessor dsd)
 311                              (sb!xc:class-name (layout-class layout))
 312                              structure))))
 313             (%instance-ref structure (dsd-index dsd)))
 314         #'(lambda (structure)
 315             (declare (optimize (speed 3) (safety 0)))
 316             (unless (%typep structure class)
 317               (error 'simple-type-error
 318                      :datum structure
 319                      :expected-type 'class
 320                      :format-control
 321                      "The structure for accessor ~S is not a ~S:~% ~S"
 322                      :format-arguments
 323                      (list (dsd-accessor dsd) class
 324                            structure)))
 325             (%instance-ref structure (dsd-index dsd))))))
 326 (defun structure-slot-setter (layout dsd)
 327   (let ((class (layout-class layout)))
 328     (if (typep class 'basic-structure-class)
 329         #'(lambda (new-value structure)
 330             (declare (optimize (speed 3) (safety 0)))
 331             (flet ((structure-test (structure)
 332                      (typep-to-layout structure layout))
 333                    (typep-test (new-value)
 334                      (%typep new-value (dsd-type dsd))))
 335               (unless (structure-test structure)
 336                 (error 'simple-type-error
 337                        :datum structure
 338                        :expected-type (class-name (layout-class layout))
 339                        :format-control
 340                        "The structure for setter ~S is not a ~S:~% ~S"
 341                        :format-arguments
 342                        (list `(setf ,(dsd-accessor dsd))
 343                              (sb!xc:class-name (layout-class layout))
 344                              structure)))
 345               (unless  (typep-test new-value)
 346                 (error 'simple-type-error
 347                        :datum new-value
 348                        :expected-type (class-name (layout-class layout))
 349                        :format-control
 350                        "The new value for setter ~S is not a ~S:~% ~S"
 351                        :format-arguments
 352                        (list `(setf ,(dsd-accessor dsd))
 353                               (dsd-type dsd)
 354                               new-value))))
 355             (setf (%instance-ref structure (dsd-index dsd)) new-value))
 356         #'(lambda (new-value structure)
 357             (declare (optimize (speed 3) (safety 0)))
 358             (flet ((structure-test (structure)
 359                      (sb!xc:typep structure class))
 360                    (typep-test (new-value)
 361                      (%typep new-value (dsd-type dsd))))
 362               (unless (structure-test structure)
 363                 (error 'simple-type-error
 364                        :datum structure
 365                        :expected-type (class-name (layout-class layout))
 366                        :format-control
 367                        "The structure for setter ~S is not a ~S:~% ~S"
 368                        :format-arguments
 369                        (list `(setf ,(dsd-accessor dsd))
 370                              (sb!xc:class-name class)
 371                              structure)))
 372               (unless  (typep-test new-value)
 373                 (error 'simple-type-error
 374                        :datum new-value
 375                        :expected-type (class-name (layout-class layout))
 376                        :format-control
 377                        "The new value for setter ~S is not a ~S:~% ~S"
 378                        :format-arguments
 379                        (list `(setf ,(dsd-accessor dsd))
 380                              (dsd-type dsd)
 381                              new-value))))
 382             (setf (%instance-ref structure (dsd-index dsd)) new-value)))))
 383
 384 (/show0 "target-defstruct.lisp end of file")