src/code/target-eval.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3 ;;;;
   4 ;;;; This software is derived from the CMU CL system, which was
   5 ;;;; written at Carnegie Mellon University and released into the
   6 ;;;; public domain. The software is in the public domain and is
   7 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
   8 ;;;; files for more information.
   9
  10 (in-package "SB!EVAL")
  11
  12 ;;; This is defined here so that the printer etc. can call
  13 ;;; INTERPRETED-FUNCTION-P before the full interpreter is loaded.
  14
  15 ;;; an interpreted function
  16 (defstruct (interpreted-function
  17             (:alternate-metaclass sb!kernel:funcallable-instance
  18                                   sb!kernel:funcallable-structure-class
  19                                   sb!kernel:make-funcallable-structure-class)
  20             (:type sb!kernel:funcallable-structure)
  21             (:constructor %make-interpreted-function)
  22             (:copier nil)
  23             ;; FIXME: Binding PRINT-OBJECT isn't going to help unless
  24             ;; we fix the print-a-funcallable-instance code so that
  25             ;; it calls PRINT-OBJECT in this case.
  26             (:print-object
  27              (lambda (x stream)
  28                (print-unreadable-object (x stream :identity t)
  29                  (interpreted-function-%name x)))))
  30   ;; The name of this interpreted function, or NIL if none specified.
  31   (%name nil)
  32   ;; This function's debug arglist.
  33   (arglist nil)
  34   ;; A lambda that can be converted to get the definition.
  35   (lambda nil)
  36   ;; If this function has been converted, then this is the XEP. If this is
  37   ;; false, then the function is not in the cache (or is in the process of
  38   ;; being removed.)
  39   (definition nil :type (or sb!c::clambda null))
  40   ;; The number of consecutive GCs that this function has been unused.
  41   ;; This is used to control cache replacement.
  42   (gcs 0 :type sb!c::index)
  43   ;; True if Lambda has been converted at least once, and thus warnings should
  44   ;; be suppressed on additional conversions.
  45   (converted-once nil)
  46   ;; For a closure, the closure date vector.
  47   (closure nil :type (or null simple-vector)))
  48 \f
  49 (in-package "SB!IMPL")
  50
  51 ;;;; One of the steps in building a nice debuggable macro is changing
  52 ;;;; its MACRO-FUNCTION to print as e.g.
  53 ;;;;   #<Interpreted Function "DEFMACRO BAR" {9166351}>
  54 ;;;; instead of some weird internal representation showing the
  55 ;;;; environment argument and stuff. This function is called in order
  56 ;;;; to try to make that happen.
  57 ;;;;
  58 ;;;; When we're running in the target SBCL, we own the
  59 ;;;; INTERPRETED-FUNCTION definition, and we can do this; that's what
  60 ;;;; the definition below does. When we're a Python cross-compiler
  61 ;;;; running in some arbitrary ANSI Common Lisp, we can't do this (and
  62 ;;;; we don't care that much about making nice debuggable macros
  63 ;;;; anyway). In that environment, a stub no-op version of this
  64 ;;;; function is used.
  65 (defun try-to-rename-interpreted-function-as-macro (f name lambda-list)
  66   (aver (sb!eval:interpreted-function-p f))
  67   (setf (sb!eval:interpreted-function-name f)
  68         (format nil "DEFMACRO ~S" name)
  69         (sb!eval:interpreted-function-arglist f)
  70         lambda-list)
  71   (values))
  72 \f
  73 ;;;; EVAL and friends
  74
  75 ;;; This needs to be initialized in the cold load, since the top-level
  76 ;;; catcher will always restore the initial value.
  77 (defvar *eval-stack-top* 0)
  78
  79 ;;; Pick off a few easy cases, and call INTERNAL-EVAL for the rest. If
  80 ;;; *ALREADY-EVALED-THIS* is true, then we bind it to NIL before doing
  81 ;;; a call so that the effect is confined to the lexical scope of the
  82 ;;; EVAL-WHEN.
  83 (defun eval (original-exp)
  84   #!+sb-doc
  85   "Evaluates its single argument in a null lexical environment, returns the
  86   result or results."
  87   (declare (optimize (safety 1)))
  88   (let ((exp (macroexpand original-exp)))
  89     (typecase exp
  90       (symbol
  91        (ecase (info :variable :kind exp)
  92          (:constant
  93           (values (info :variable :constant-value exp)))
  94          ((:special :global)
  95           (symbol-value exp))
  96          (:alien
  97           (sb!eval:internal-eval original-exp))))
  98       (list
  99        (let ((name (first exp))
 100              (args (1- (length exp))))
 101          (case name
 102            (function
 103             (unless (= args 1)
 104               (error "wrong number of args to FUNCTION:~% ~S" exp))
 105             (let ((name (second exp)))
 106               (if (or (atom name)
 107                       (and (consp name)
 108                            (eq (car name) 'setf)))
 109                   (fdefinition name)
 110                   (sb!eval:make-interpreted-function name))))
 111            (quote
 112             (unless (= args 1)
 113               (error "wrong number of args to QUOTE:~% ~S" exp))
 114             (second exp))
 115            (setq
 116             (unless (evenp args)
 117               (error "odd number of args to SETQ:~% ~S" exp))
 118             (unless (zerop args)
 119               (do ((name (cdr exp) (cddr name)))
 120                   ((null name)
 121                    (do ((args (cdr exp) (cddr args)))
 122                        ((null (cddr args))
 123                         ;; We duplicate the call to SET so that the
 124                         ;; correct value gets returned.
 125                         (set (first args) (eval (second args))))
 126                      (set (first args) (eval (second args)))))
 127                 (let ((symbol (first name)))
 128                   (case (info :variable :kind symbol)
 129                     ;; FIXME: I took out the *TOP-LEVEL-AUTO-DECLARE*
 130                     ;; test here, and removed the *TOP-LEVEL-AUTO-DECLARE*
 131                     ;; variable; the code should now act as though that
 132                     ;; variable is NIL. This should be tested..
 133                     (:special)
 134                     (t (return (sb!eval:internal-eval original-exp))))))))
 135            ((progn)
 136             (when (> args 0)
 137               (dolist (x (butlast (rest exp)) (eval (car (last exp))))
 138                 (eval x))))
 139            ((eval-when)
 140             (if (and (> args 0)
 141                      (or (member 'eval (second exp))
 142                          (member :execute (second exp))))
 143                 (when (> args 1)
 144                   (dolist (x (butlast (cddr exp)) (eval (car (last exp))))
 145                     (eval x)))
 146                 (sb!eval:internal-eval original-exp)))
 147            (t
 148             (if (and (symbolp name)
 149                      (eq (info :function :kind name) :function))
 150                 (collect ((args))
 151                   (dolist (arg (rest exp))
 152                     (args (eval arg)))
 153                   (if sb!eval::*already-evaled-this*
 154                       (let ((sb!eval::*already-evaled-this* nil))
 155                         (apply (symbol-function name) (args)))
 156                       (apply (symbol-function name) (args))))
 157                 (sb!eval:internal-eval original-exp))))))
 158       (t
 159        exp))))
 160
 161 ;;; Given a function, return three values:
 162 ;;; 1] A lambda expression that could be used to define the function,
 163 ;;;    or NIL if the definition isn't available.
 164 ;;; 2] NIL if the function was definitely defined in a null lexical
 165 ;;;    environment, and T otherwise.
 166 ;;; 3] Some object that \"names\" the function. Although this is
 167 ;;;    allowed to be any object, CMU CL always returns a valid
 168 ;;;    function name or a string.
 169 ;;;
 170 ;;; If interpreted, use the interpreter interface. Otherwise, see
 171 ;;; whether it was compiled with COMPILE. If that fails, check for an
 172 ;;; inline expansion.
 173 (defun function-lambda-expression (fun)
 174   (declare (type function fun))
 175   (if (sb!eval:interpreted-function-p fun)
 176       (sb!eval:interpreted-function-lambda-expression fun)
 177       (let* ((fun (%function-self fun))
 178              (name (%function-name fun))
 179              (code (sb!di::function-code-header fun))
 180              (info (sb!kernel:%code-debug-info code)))
 181         (if info
 182             (let ((source (first (sb!c::compiled-debug-info-source info))))
 183               (cond ((and (eq (sb!c::debug-source-from source) :lisp)
 184                           (eq (sb!c::debug-source-info source) fun))
 185                      (values (second (svref (sb!c::debug-source-name source) 0))
 186                              nil name))
 187                     ((stringp name)
 188                      (values nil t name))
 189                     (t
 190                      (let ((exp (info :function :inline-expansion name)))
 191                        (if exp
 192                            (values exp nil name)
 193                            (values nil t name))))))
 194             (values nil t name)))))
 195
 196 ;;; Like FIND-IF, only we do it on a compiled closure's environment.
 197 (defun find-if-in-closure (test fun)
 198   (dotimes (index (1- (get-closure-length fun)))
 199     (let ((elt (%closure-index-ref fun index)))
 200       (when (funcall test elt)
 201         (return elt)))))
 202 \f
 203 ;;; function invocation
 204
 205 (defun apply (function arg &rest args)
 206   #!+sb-doc
 207   "Applies FUNCTION to a list of arguments produced by evaluating ARGS in
 208   the manner of LIST*. That is, a list is made of the values of all but the
 209   last argument, appended to the value of the last argument, which must be a
 210   list."
 211   (cond ((atom args)
 212          (apply function arg))
 213         ((atom (cdr args))
 214          (apply function (cons arg (car args))))
 215         (t (do* ((a1 args a2)
 216                  (a2 (cdr args) (cdr a2)))
 217                 ((atom (cdr a2))
 218                  (rplacd a1 (car a2))
 219                  (apply function (cons arg args)))))))
 220
 221 (defun funcall (function &rest arguments)
 222   #!+sb-doc
 223   "Calls Function with the given Arguments."
 224   (apply function arguments))
 225 \f
 226 ;;; multiple-value forms
 227
 228 (defun values (&rest values)
 229   #!+sb-doc
 230   "Returns all arguments, in order, as values."
 231   (values-list values))
 232
 233 (defun values-list (list)
 234   #!+sb-doc
 235   "Returns all of the elements of LIST, in order, as values."
 236   (values-list list))