src/code/target-misc.lisp

   1 ;;;; Environment query functions, DOCUMENTATION and DRIBBLE.
   2 ;;;;
   3 ;;;; FIXME: If there are exactly three things in here, it could be
   4 ;;;; exactly three files named e.g. equery.lisp, doc.lisp, and dribble.lisp.
   5
   6 ;;;; This software is part of the SBCL system. See the README file for
   7 ;;;; more information.
   8 ;;;;
   9 ;;;; This software is derived from the CMU CL system, which was
  10 ;;;; written at Carnegie Mellon University and released into the
  11 ;;;; public domain. The software is in the public domain and is
  12 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  13 ;;;; files for more information.
  14
  15 (in-package "SB!IMPL")
  16
  17 ;;; cobbled from stuff in describe.lisp.
  18 (defun function-doc (x)
  19   (let ((name
  20          (case (get-type x)
  21            (#.sb!vm:closure-header-type
  22             (%function-name (%closure-function x)))
  23            ((#.sb!vm:function-header-type #.sb!vm:closure-function-header-type)
  24             (%function-name x))
  25            (#.sb!vm:funcallable-instance-header-type
  26             (typecase x
  27               (byte-function
  28                (sb!c::byte-function-name x))
  29               (byte-closure
  30                (sb!c::byte-function-name (byte-closure-function x)))
  31               (t ;; funcallable-instance
  32                (%function-name
  33                 (funcallable-instance-function x))))))))
  34     (when (and name (typep name '(or symbol cons)))
  35       (values (info :function :documentation name)))))
  36
  37 (defvar *features* '#.sb-cold:*shebang-features*
  38   #!+sb-doc
  39   "a list of symbols that describe features provided by the
  40    implementation")
  41 \f
  42 ;;; various environment inquiries
  43
  44 (defun machine-instance ()
  45   #!+sb-doc
  46   "Return a string giving the name of the local machine."
  47   (sb!unix:unix-gethostname))
  48
  49 ;;; FIXME: Don't forget to set these in a sample site-init file.
  50 ;;; FIXME: Perhaps the functions could be SETFable instead of having the
  51 ;;; interface be through special variables? As far as I can tell
  52 ;;; from ANSI 11.1.2.1.1 "Constraints on the COMMON-LISP Package
  53 ;;; for Conforming Implementations" it is kosher to add a SETF function for
  54 ;;; a symbol in COMMON-LISP..
  55 (defvar *short-site-name* nil
  56   #!+sb-doc
  57   "The value of SHORT-SITE-NAME.")
  58 (defvar *long-site-name* nil
  59   #!+sb-doc "the value of LONG-SITE-NAME")
  60 (defun short-site-name ()
  61   #!+sb-doc
  62   "Returns a string with the abbreviated site name, or NIL if not known."
  63   *short-site-name*)
  64 (defun long-site-name ()
  65   #!+sb-doc
  66   "Returns a string with the long form of the site name, or NIL if not known."
  67   *long-site-name*)
  68 \f
  69 ;;;; dribble stuff
  70
  71 ;;; Each time we start dribbling to a new stream, we put it in
  72 ;;; *DRIBBLE-STREAM*, and push a list of *DRIBBLE-STREAM*, *STANDARD-INPUT*,
  73 ;;; *STANDARD-OUTPUT* and *ERROR-OUTPUT* in *PREVIOUS-DRIBBLE-STREAMS*.
  74 ;;; *STANDARD-OUTPUT* and *ERROR-OUTPUT* is changed to a broadcast stream that
  75 ;;; broadcasts to *DRIBBLE-STREAM* and to the old values of the variables.
  76 ;;; *STANDARD-INPUT* is changed to an echo stream that echos input from the old
  77 ;;; value of standard input to *DRIBBLE-STREAM*.
  78 ;;;
  79 ;;; When dribble is called with no arguments, *DRIBBLE-STREAM* is closed,
  80 ;;; and the values of *DRIBBLE-STREAM*, *STANDARD-INPUT*, and
  81 ;;; *STANDARD-OUTPUT* are popped from *PREVIOUS-DRIBBLE-STREAMS*.
  82
  83 (defvar *previous-dribble-streams* nil)
  84 (defvar *dribble-stream* nil)
  85
  86 (defun dribble (&optional pathname &key (if-exists :append))
  87   #!+sb-doc
  88   "With a file name as an argument, dribble opens the file and sends a
  89   record of further I/O to that file. Without an argument, it closes
  90   the dribble file, and quits logging."
  91   (cond (pathname
  92          (let* ((new-dribble-stream
  93                  (open pathname
  94                        :direction :output
  95                        :if-exists if-exists
  96                        :if-does-not-exist :create))
  97                 (new-standard-output
  98                  (make-broadcast-stream *standard-output* new-dribble-stream))
  99                 (new-error-output
 100                  (make-broadcast-stream *error-output* new-dribble-stream))
 101                 (new-standard-input
 102                  (make-echo-stream *standard-input* new-dribble-stream)))
 103            (push (list *dribble-stream* *standard-input* *standard-output*
 104                        *error-output*)
 105                  *previous-dribble-streams*)
 106            (setf *dribble-stream* new-dribble-stream)
 107            (setf *standard-input* new-standard-input)
 108            (setf *standard-output* new-standard-output)
 109            (setf *error-output* new-error-output)))
 110         ((null *dribble-stream*)
 111          (error "not currently dribbling"))
 112         (t
 113          (let ((old-streams (pop *previous-dribble-streams*)))
 114            (close *dribble-stream*)
 115            (setf *dribble-stream* (first old-streams))
 116            (setf *standard-input* (second old-streams))
 117            (setf *standard-output* (third old-streams))
 118            (setf *error-output* (fourth old-streams)))))
 119   (values))
 120
 121 (defun %byte-blt (src src-start dst dst-start dst-end)
 122   (%byte-blt src src-start dst dst-start dst-end))