src/code/target-package.lisp

   1 ;;;; PACKAGEs and stuff like that
   2 ;;;;
   3 ;;;; Note: The code in this file signals many correctable errors. This
   4 ;;;; is not just an arbitrary aesthetic decision on the part of the
   5 ;;;; implementor -- many of these are specified by ANSI 11.1.1.2.5,
   6 ;;;; "Prevention of Name Conflicts in Packages":
   7 ;;;;   Within one package, any particular name can refer to at most one
   8 ;;;;   symbol. A name conflict is said to occur when there would be more
   9 ;;;;   than one candidate symbol. Any time a name conflict is about to
  10 ;;;;   occur, a correctable error is signaled.
  11 ;;;;
  12 ;;;; FIXME: The code contains a lot of type declarations. Are they
  13 ;;;; all really necessary?
  14
  15 ;;;; This software is part of the SBCL system. See the README file for
  16 ;;;; more information.
  17 ;;;;
  18 ;;;; This software is derived from the CMU CL system, which was
  19 ;;;; written at Carnegie Mellon University and released into the
  20 ;;;; public domain. The software is in the public domain and is
  21 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  22 ;;;; files for more information.
  23
  24 (in-package "SB!IMPL")
  25
  26 (!begin-collecting-cold-init-forms)
  27
  28 (!cold-init-forms
  29   (/show0 "entering !PACKAGE-COLD-INIT"))
  30 \f
  31 ;;;; Thread safety
  32 ;;;;
  33 ;;;; ...this could still use work, but the basic idea is:
  34 ;;;;
  35 ;;;; *PACKAGE-GRAPH-LOCK* is held via WITH-PACKAGE-GRAPH while working on
  36 ;;;; package graph, including package -> package links, and interning and
  37 ;;;; uninterning symbols.
  38 ;;;;
  39 ;;;; Hash-table lock on *PACKAGE-NAMES* is held via WITH-PACKAGE-NAMES while
  40 ;;;; frobbing name -> package associations.
  41 ;;;;
  42 ;;;; There should be no deadlocks due to ordering issues between these two, as
  43 ;;;; the latter is only held over operations guaranteed to terminate in finite
  44 ;;;; time.
  45 ;;;;
  46 ;;;; Errors may be signalled while holding on to the *PACKAGE-GRAPH-LOCK*,
  47 ;;;; which can still lead to pretty damned inconvenient situations -- but
  48 ;;;; since FIND-PACKAGE, FIND-SYMBOL from other threads isn't blocked by this,
  49 ;;;; the situation isn't *quite* hopeless.
  50 ;;;;
  51 ;;;; A better long-term solution seems to be in splitting the granularity of
  52 ;;;; the *PACKAGE-GRAPH-LOCK* down: for interning a per-package lock should be
  53 ;;;; sufficient, though interaction between parallel intern and use-package
  54 ;;;; needs to be considered with some care.
  55
  56 (defvar *package-graph-lock*)
  57 (!cold-init-forms
  58  (setf *package-graph-lock* (sb!thread:make-mutex :name "Package Graph Lock")))
  59
  60 (defun call-with-package-graph (function)
  61   (declare (function function))
  62   ;; FIXME: Since name conflicts can be signalled while holding the
  63   ;; mutex, user code can be run leading to lock ordering problems.
  64   (sb!thread:with-recursive-lock (*package-graph-lock*)
  65     (funcall function)))
  66
  67 ;;; a map from package names to packages
  68 (defvar *package-names*)
  69 (declaim (type hash-table *package-names*))
  70 (!cold-init-forms
  71  (setf *package-names* (make-hash-table :test 'equal :synchronized t)))
  72
  73 (defmacro with-package-names ((names &key) &body body)
  74   `(let ((,names *package-names*))
  75      (with-locked-system-table (,names)
  76        ,@body)))
  77 \f
  78 ;;;; PACKAGE-HASHTABLE stuff
  79
  80 (def!method print-object ((table package-hashtable) stream)
  81   (declare (type stream stream))
  82   (print-unreadable-object (table stream :type t)
  83     (format stream
  84             ":SIZE ~S :FREE ~S :DELETED ~S"
  85             (package-hashtable-size table)
  86             (package-hashtable-free table)
  87             (package-hashtable-deleted table))))
  88
  89 ;;; the maximum load factor we allow in a package hashtable
  90 (defconstant +package-rehash-threshold+ 0.75)
  91
  92 ;;; the load factor desired for a package hashtable when writing a
  93 ;;; core image
  94 (defconstant +package-hashtable-image-load-factor+ 0.5)
  95
  96 ;;; Make a package hashtable having a prime number of entries at least
  97 ;;; as great as (/ SIZE +PACKAGE-REHASH-THRESHOLD+). If RES is supplied,
  98 ;;; then it is destructively modified to produce the result. This is
  99 ;;; useful when changing the size, since there are many pointers to
 100 ;;; the hashtable.
 101 ;;; Actually, the smallest table built here has three entries. This
 102 ;;; is necessary because the double hashing step size is calculated
 103 ;;; using a division by the table size minus two.
 104 (defun make-or-remake-package-hashtable (size
 105                                          &optional
 106                                          res)
 107   (flet ((actual-package-hashtable-size (size)
 108            (loop for n of-type fixnum
 109               from (logior (ceiling size +package-rehash-threshold+) 1)
 110               by 2
 111               when (positive-primep n) return n)))
 112     (let* ((n (actual-package-hashtable-size size))
 113            (size (truncate (* n +package-rehash-threshold+)))
 114            (table (make-array n))
 115            (hash (make-array n
 116                              :element-type '(unsigned-byte 8)
 117                              :initial-element 0)))
 118       (if res
 119           (setf (package-hashtable-table res) table
 120                 (package-hashtable-hash res) hash
 121                 (package-hashtable-size res) size
 122                 (package-hashtable-free res) size
 123                 (package-hashtable-deleted res) 0)
 124           (setf res (%make-package-hashtable table hash size)))
 125       res)))
 126
 127 ;;; Destructively resize TABLE to have room for at least SIZE entries
 128 ;;; and rehash its existing entries.
 129 (defun resize-package-hashtable (table size)
 130   (let* ((vec (package-hashtable-table table))
 131          (hash (package-hashtable-hash table))
 132          (len (length vec)))
 133     (make-or-remake-package-hashtable size table)
 134     (dotimes (i len)
 135       (when (> (aref hash i) 1)
 136         (add-symbol table (svref vec i))))))
 137 \f
 138 ;;;; package locking operations, built conditionally on :sb-package-locks
 139
 140 #!+sb-package-locks
 141 (progn
 142 (defun package-locked-p (package)
 143   #!+sb-doc
 144   "Returns T when PACKAGE is locked, NIL otherwise. Signals an error
 145 if PACKAGE doesn't designate a valid package."
 146   (package-lock (find-undeleted-package-or-lose package)))
 147
 148 (defun lock-package (package)
 149   #!+sb-doc
 150   "Locks PACKAGE and returns T. Has no effect if PACKAGE was already
 151 locked. Signals an error if PACKAGE is not a valid package designator"
 152   (setf (package-lock (find-undeleted-package-or-lose package)) t))
 153
 154 (defun unlock-package (package)
 155   #!+sb-doc
 156   "Unlocks PACKAGE and returns T. Has no effect if PACKAGE was already
 157 unlocked. Signals an error if PACKAGE is not a valid package designator."
 158   (setf (package-lock (find-undeleted-package-or-lose package)) nil)
 159   t)
 160
 161 (defun package-implemented-by-list (package)
 162   #!+sb-doc
 163   "Returns a list containing the implementation packages of
 164 PACKAGE. Signals an error if PACKAGE is not a valid package designator."
 165   (package-%implementation-packages (find-undeleted-package-or-lose package)))
 166
 167 (defun package-implements-list (package)
 168   #!+sb-doc
 169   "Returns the packages that PACKAGE is an implementation package
 170 of. Signals an error if PACKAGE is not a valid package designator."
 171   (let ((package (find-undeleted-package-or-lose package)))
 172     (loop for x in (list-all-packages)
 173           when (member package (package-%implementation-packages x))
 174           collect x)))
 175
 176 (defun add-implementation-package (packages-to-add
 177                                    &optional (package *package*))
 178   #!+sb-doc
 179   "Adds PACKAGES-TO-ADD as implementation packages of PACKAGE. Signals
 180 an error if PACKAGE or any of the PACKAGES-TO-ADD is not a valid
 181 package designator."
 182   (let ((package (find-undeleted-package-or-lose package))
 183         (packages-to-add (package-listify packages-to-add)))
 184     (setf (package-%implementation-packages package)
 185           (union (package-%implementation-packages package)
 186                  (mapcar #'find-undeleted-package-or-lose packages-to-add)))))
 187
 188 (defun remove-implementation-package (packages-to-remove
 189                                       &optional (package *package*))
 190   #!+sb-doc
 191   "Removes PACKAGES-TO-REMOVE from the implementation packages of
 192 PACKAGE. Signals an error if PACKAGE or any of the PACKAGES-TO-REMOVE
 193 is not a valid package designator."
 194   (let ((package (find-undeleted-package-or-lose package))
 195         (packages-to-remove (package-listify packages-to-remove)))
 196     (setf (package-%implementation-packages package)
 197           (nset-difference
 198            (package-%implementation-packages package)
 199            (mapcar #'find-undeleted-package-or-lose packages-to-remove)))))
 200
 201 (defmacro with-unlocked-packages ((&rest packages) &body forms)
 202   #!+sb-doc
 203   "Unlocks PACKAGES for the dynamic scope of the body. Signals an
 204 error if any of PACKAGES is not a valid package designator."
 205   (with-unique-names (unlocked-packages)
 206     `(let (,unlocked-packages)
 207       (unwind-protect
 208            (progn
 209              (dolist (p ',packages)
 210                (when (package-locked-p p)
 211                  (push p ,unlocked-packages)
 212                  (unlock-package p)))
 213              ,@forms)
 214         (dolist (p ,unlocked-packages)
 215           (when (find-package p)
 216             (lock-package p)))))))
 217
 218 (defun package-lock-violation (package &key (symbol nil symbol-p)
 219                                format-control format-arguments)
 220   (let* ((restart :continue)
 221          (cl-violation-p (eq package *cl-package*))
 222          (error-arguments
 223           (append (list (if symbol-p
 224                             'symbol-package-locked-error
 225                             'package-locked-error)
 226                         :package package
 227                         :format-control format-control
 228                         :format-arguments format-arguments)
 229                   (when symbol-p (list :symbol symbol))
 230                   (list :references
 231                         (append '((:sbcl :node "Package Locks"))
 232                                 (when cl-violation-p
 233                                   '((:ansi-cl :section (11 1 2 1 2)))))))))
 234     (restart-case
 235         (apply #'cerror "Ignore the package lock." error-arguments)
 236       (:ignore-all ()
 237         :report "Ignore all package locks in the context of this operation."
 238         (setf restart :ignore-all))
 239       (:unlock-package ()
 240         :report "Unlock the package."
 241         (setf restart :unlock-package)))
 242     (ecase restart
 243       (:continue
 244        (pushnew package *ignored-package-locks*))
 245       (:ignore-all
 246        (setf *ignored-package-locks* t))
 247       (:unlock-package
 248        (unlock-package package)))))
 249
 250 (defun package-lock-violation-p (package &optional (symbol nil symbolp))
 251   ;; KLUDGE: (package-lock package) needs to be before
 252   ;; comparison to *package*, since during cold init this gets
 253   ;; called before *package* is bound -- but no package should
 254   ;; be locked at that point.
 255   (and package
 256        (package-lock package)
 257        ;; In package or implementation package
 258        (not (or (eq package *package*)
 259                 (member *package* (package-%implementation-packages package))))
 260        ;; Runtime disabling
 261        (not (eq t *ignored-package-locks*))
 262        (or (eq :invalid *ignored-package-locks*)
 263            (not (member package *ignored-package-locks*)))
 264        ;; declarations for symbols
 265        (not (and symbolp (member symbol (disabled-package-locks))))))
 266
 267 (defun disabled-package-locks ()
 268   (if (boundp 'sb!c::*lexenv*)
 269       (sb!c::lexenv-disabled-package-locks sb!c::*lexenv*)
 270       sb!c::*disabled-package-locks*))
 271
 272 ) ; progn
 273
 274 ;;;; more package-locking these are NOPs unless :sb-package-locks is
 275 ;;;; in target features. Cross-compiler NOPs for these are in cross-misc.
 276
 277 ;;; The right way to establish a package lock context is
 278 ;;; WITH-SINGLE-PACKAGE-LOCKED-ERROR, defined in early-package.lisp
 279 ;;;
 280 ;;; Must be used inside the dynamic contour established by
 281 ;;; WITH-SINGLE-PACKAGE-LOCKED-ERROR
 282 (defun assert-package-unlocked (package &optional format-control
 283                                 &rest format-arguments)
 284   #!-sb-package-locks
 285   (declare (ignore format-control format-arguments))
 286   #!+sb-package-locks
 287   (when (package-lock-violation-p package)
 288     (package-lock-violation package
 289                             :format-control format-control
 290                             :format-arguments format-arguments))
 291   package)
 292
 293 ;;; Must be used inside the dynamic contour established by
 294 ;;; WITH-SINGLE-PACKAGE-LOCKED-ERROR.
 295 ;;;
 296 ;;; FIXME: Maybe we should establish such contours for he toplevel
 297 ;;; and others, so that %set-fdefinition and others could just use
 298 ;;; this.
 299 (defun assert-symbol-home-package-unlocked (name format)
 300   #!-sb-package-locks
 301   (declare (ignore format))
 302   #!+sb-package-locks
 303   (let* ((symbol (etypecase name
 304                    (symbol name)
 305                    (list (if (and (consp (cdr name))
 306                                   (eq 'setf (first name)))
 307                              (second name)
 308                              ;; Skip lists of length 1, single conses and
 309                              ;; (class-predicate foo), etc.
 310                              ;; FIXME: MOP and package-lock
 311                              ;; interaction needs to be thought about.
 312                              (return-from
 313                               assert-symbol-home-package-unlocked
 314                                name)))))
 315          (package (symbol-package symbol)))
 316     (when (package-lock-violation-p package symbol)
 317       (package-lock-violation package
 318                               :symbol symbol
 319                               :format-control format
 320                               :format-arguments (list name))))
 321   name)
 322
 323 \f
 324 ;;;; miscellaneous PACKAGE operations
 325
 326 (def!method print-object ((package package) stream)
 327   (let ((name (package-%name package)))
 328     (if name
 329         (print-unreadable-object (package stream :type t)
 330           (prin1 name stream))
 331         (print-unreadable-object (package stream :type t :identity t)
 332           (write-string "(deleted)" stream)))))
 333
 334 ;;; ANSI says (in the definition of DELETE-PACKAGE) that these, and
 335 ;;; most other operations, are unspecified for deleted packages. We
 336 ;;; just do the easy thing and signal errors in that case.
 337 (macrolet ((def (ext real)
 338              `(defun ,ext (x) (,real (find-undeleted-package-or-lose x)))))
 339   (def package-nicknames package-%nicknames)
 340   (def package-use-list package-%use-list)
 341   (def package-used-by-list package-%used-by-list)
 342   (def package-shadowing-symbols package-%shadowing-symbols))
 343
 344 (defun %package-hashtable-symbol-count (table)
 345   (let ((size (the fixnum
 346                 (- (package-hashtable-size table)
 347                    (package-hashtable-deleted table)))))
 348     (the fixnum
 349       (- size (package-hashtable-free table)))))
 350
 351 (defun package-internal-symbol-count (package)
 352   (%package-hashtable-symbol-count (package-internal-symbols package)))
 353
 354 (defun package-external-symbol-count (package)
 355   (%package-hashtable-symbol-count (package-external-symbols package)))
 356 \f
 357 (defvar *package* (error "*PACKAGE* should be initialized in cold load!")
 358   #!+sb-doc "the current package")
 359 ;;; FIXME: should be declared of type PACKAGE, with no NIL init form,
 360 ;;; after I get around to cleaning up DOCUMENTATION
 361
 362 ;;; This magical variable is T during initialization so that
 363 ;;; USE-PACKAGE's of packages that don't yet exist quietly win. Such
 364 ;;; packages are thrown onto the list *DEFERRED-USE-PACKAGES* so that
 365 ;;; this can be fixed up later.
 366 ;;;
 367 ;;; FIXME: This could be cleaned up the same way I do it in my package
 368 ;;; hacking when setting up the cross-compiler. Then we wouldn't have
 369 ;;; this extraneous global variable and annoying runtime tests on
 370 ;;; package operations. (*DEFERRED-USE-PACKAGES* would also go away.)
 371 (defvar *in-package-init*)
 372
 373 ;;; pending USE-PACKAGE arguments saved up while *IN-PACKAGE-INIT* is true
 374 (defvar *!deferred-use-packages*)
 375 (!cold-init-forms
 376   (setf *!deferred-use-packages* nil))
 377
 378 (define-condition bootstrap-package-not-found (condition)
 379   ((name :initarg :name :reader bootstrap-package-name)))
 380 (defun debootstrap-package (&optional condition)
 381   (invoke-restart
 382    (find-restart-or-control-error 'debootstrap-package condition)))
 383
 384 (defun find-package (package-designator)
 385   (flet ((find-package-from-string (string)
 386            (declare (type string string))
 387            (let ((packageoid (gethash string *package-names*)))
 388              (when (and (null packageoid)
 389                         (not *in-package-init*) ; KLUDGE
 390                         (let ((mismatch (mismatch "SB!" string)))
 391                           (and mismatch (= mismatch 3))))
 392                (restart-case
 393                    (signal 'bootstrap-package-not-found :name string)
 394                  (debootstrap-package ()
 395                    (return-from find-package
 396                      (if (string= string "SB!XC")
 397                          (find-package "COMMON-LISP")
 398                          (find-package
 399                           (substitute #\- #\! string :count 1)))))))
 400              packageoid)))
 401     (typecase package-designator
 402       (package package-designator)
 403       (symbol (find-package-from-string (symbol-name package-designator)))
 404       (string (find-package-from-string package-designator))
 405       (character (find-package-from-string (string package-designator)))
 406       (t (error 'type-error
 407                 :datum package-designator
 408                 :expected-type '(or character package string symbol))))))
 409
 410 ;;; Return a list of packages given a package designator or list of
 411 ;;; package designators, or die trying.
 412 (defun package-listify (thing)
 413   (let ((res ()))
 414     (dolist (thing (if (listp thing) thing (list thing)) res)
 415       (push (find-undeleted-package-or-lose thing) res))))
 416
 417 ;;; Make a package name into a simple-string.
 418 (defun package-namify (n)
 419   (stringify-package-designator n))
 420
 421 ;;; ANSI specifies (in the definition of DELETE-PACKAGE) that PACKAGE-NAME
 422 ;;; returns NIL (not an error) for a deleted package, so this is a special
 423 ;;; case where we want to use bare %FIND-PACKAGE-OR-LOSE instead of
 424 ;;; FIND-UNDELETED-PACKAGE-OR-LOSE.
 425 (defun package-name (package-designator)
 426   (package-%name (%find-package-or-lose package-designator)))
 427 \f
 428 ;;;; operations on package hashtables
 429
 430 ;;; Compute a number from the sxhash of the pname and the length which
 431 ;;; must be between 2 and 255.
 432 (defmacro entry-hash (length sxhash)
 433   `(the fixnum
 434         (+ (the fixnum
 435                 (rem (the fixnum
 436                           (logxor ,length
 437                                   ,sxhash
 438                                   (the fixnum (ash ,sxhash -8))
 439                                   (the fixnum (ash ,sxhash -16))
 440                                   (the fixnum (ash ,sxhash -19))))
 441                      254))
 442            2)))
 443 ;;; FIXME: should be wrapped in EVAL-WHEN (COMPILE EXECUTE)
 444
 445 ;;; Add a symbol to a package hashtable. The symbol is assumed
 446 ;;; not to be present.
 447 (defun add-symbol (table symbol)
 448   (when (zerop (package-hashtable-free table))
 449     ;; The hashtable is full. Resize it to be able to hold twice the
 450     ;; amount of symbols than it currently contains. The actual new size
 451     ;; can be smaller than twice the current size if the table contained
 452     ;; deleted entries.
 453     (resize-package-hashtable table
 454                               (* (- (package-hashtable-size table)
 455                                     (package-hashtable-deleted table))
 456                                  2)))
 457   (let* ((vec (package-hashtable-table table))
 458          (hash (package-hashtable-hash table))
 459          (len (length vec))
 460          (sxhash (%sxhash-simple-string (symbol-name symbol)))
 461          (h2 (1+ (rem sxhash (- len 2)))))
 462     (declare (fixnum sxhash h2))
 463     (do ((i (rem sxhash len) (rem (+ i h2) len)))
 464         ((< (the fixnum (aref hash i)) 2)
 465          (if (zerop (the fixnum (aref hash i)))
 466              (decf (package-hashtable-free table))
 467              (decf (package-hashtable-deleted table)))
 468          (setf (svref vec i) symbol)
 469          (setf (aref hash i)
 470                (entry-hash (length (symbol-name symbol))
 471                            sxhash)))
 472       (declare (fixnum i)))))
 473
 474 ;;; Resize the package hashtables of all packages so that their load
 475 ;;; factor is +PACKAGE-HASHTABLE-IMAGE-LOAD-FACTOR+. Called from
 476 ;;; SAVE-LISP-AND-DIE to optimize space usage in the image.
 477 (defun tune-hashtable-sizes-of-all-packages ()
 478   (flet ((tune-table-size (table)
 479            (resize-package-hashtable
 480             table
 481             (round (* (/ +package-rehash-threshold+
 482                          +package-hashtable-image-load-factor+)
 483                       (- (package-hashtable-size table)
 484                          (package-hashtable-free table)
 485                          (package-hashtable-deleted table)))))))
 486     (dolist (package (list-all-packages))
 487       (tune-table-size (package-internal-symbols package))
 488       (tune-table-size (package-external-symbols package)))))
 489
 490 ;;; Find where the symbol named STRING is stored in TABLE. INDEX-VAR
 491 ;;; is bound to the index, or NIL if it is not present. SYMBOL-VAR
 492 ;;; is bound to the symbol. LENGTH and HASH are the length and sxhash
 493 ;;; of STRING. ENTRY-HASH is the entry-hash of the string and length.
 494 (defmacro with-symbol ((index-var symbol-var table string length sxhash
 495                                   entry-hash)
 496                        &body forms)
 497   (let ((vec (gensym)) (hash (gensym)) (len (gensym)) (h2 (gensym))
 498         (name (gensym)) (name-len (gensym)) (ehash (gensym)))
 499     `(let* ((,vec (package-hashtable-table ,table))
 500             (,hash (package-hashtable-hash ,table))
 501             (,len (length ,vec))
 502             (,h2 (1+ (the index (rem (the hash ,sxhash)
 503                                       (the index (- ,len 2)))))))
 504        (declare (type index ,len ,h2))
 505        (prog ((,index-var (rem (the hash ,sxhash) ,len))
 506               ,symbol-var ,ehash)
 507          (declare (type (or index null) ,index-var))
 508          LOOP
 509          (setq ,ehash (aref ,hash ,index-var))
 510          (cond ((eql ,ehash ,entry-hash)
 511                 (setq ,symbol-var (svref ,vec ,index-var))
 512                 (let* ((,name (symbol-name ,symbol-var))
 513                        (,name-len (length ,name)))
 514                   (declare (type index ,name-len))
 515                   (when (and (= ,name-len ,length)
 516                              (string= ,string ,name
 517                                       :end1 ,length
 518                                       :end2 ,name-len))
 519                     (go DOIT))))
 520                ((zerop ,ehash)
 521                 (setq ,index-var nil)
 522                 (go DOIT)))
 523          (setq ,index-var (+ ,index-var ,h2))
 524          (when (>= ,index-var ,len)
 525            (setq ,index-var (- ,index-var ,len)))
 526          (go LOOP)
 527          DOIT
 528          (return (progn ,@forms))))))
 529
 530 ;;; Delete the entry for STRING in TABLE. The entry must exist.
 531 (defun nuke-symbol (table string)
 532   (declare (simple-string string))
 533   (let* ((length (length string))
 534          (hash (%sxhash-simple-string string))
 535          (ehash (entry-hash length hash)))
 536     (declare (type index length)
 537              (type hash hash))
 538     (with-symbol (index symbol table string length hash ehash)
 539       (setf (aref (package-hashtable-hash table) index) 1)
 540       (setf (aref (package-hashtable-table table) index) nil)
 541       (incf (package-hashtable-deleted table))))
 542   ;; If the table is less than one quarter full, halve its size and
 543   ;; rehash the entries.
 544   (let* ((size (package-hashtable-size table))
 545          (deleted (package-hashtable-deleted table))
 546          (used (- size
 547                   (package-hashtable-free table)
 548                   deleted)))
 549     (declare (type fixnum size deleted used))
 550     (when (< used (truncate size 4))
 551       (resize-package-hashtable table (* used 2)))))
 552 \f
 553 ;;; Enter any new NICKNAMES for PACKAGE into *PACKAGE-NAMES*. If there is a
 554 ;;; conflict then give the user a chance to do something about it. Caller is
 555 ;;; responsible for having acquired the mutex via WITH-PACKAGES.
 556 (defun %enter-new-nicknames (package nicknames)
 557   (declare (type list nicknames))
 558   (dolist (n nicknames)
 559     (let* ((n (package-namify n))
 560            (found (with-package-names (names)
 561                     (or (gethash n names)
 562                         (progn
 563                           (setf (gethash n names) package)
 564                           (push n (package-%nicknames package))
 565                           package)))))
 566       (cond ((eq found package))
 567             ((string= (the string (package-%name found)) n)
 568              (cerror "Ignore this nickname."
 569                      'simple-package-error
 570                      :package package
 571                      :format-control "~S is a package name, so it cannot be a nickname for ~S."
 572                      :format-arguments (list n (package-%name package))))
 573             (t
 574              (cerror "Leave this nickname alone."
 575                      'simple-package-error
 576                      :package package
 577                      :format-control "~S is already a nickname for ~S."
 578                      :format-arguments (list n (package-%name found))))))))
 579
 580 (defun make-package (name &key
 581                           (use '#.*default-package-use-list*)
 582                           nicknames
 583                           (internal-symbols 10)
 584                           (external-symbols 10))
 585   #!+sb-doc
 586   #.(format nil
 587      "Make a new package having the specified NAME, NICKNAMES, and USE
 588 list. :INTERNAL-SYMBOLS and :EXTERNAL-SYMBOLS are estimates for the number of
 589 internal and external symbols which will ultimately be present in the package.
 590 The default value of USE is implementation-dependent, and in this
 591 implementation it is ~S." *default-package-use-list*)
 592   (prog (clobber)
 593    :restart
 594      (when (find-package name)
 595        ;; ANSI specifies that this error is correctable.
 596        (cerror "Clobber existing package."
 597                "A package named ~S already exists" name)
 598        (setf clobber t))
 599      (with-package-graph ()
 600        ;; Check for race, signal the error outside the lock.
 601        (when (and (not clobber) (find-package name))
 602          (go :restart))
 603        (let* ((name (package-namify name))
 604               (package (internal-make-package
 605                         :%name name
 606                         :internal-symbols (make-or-remake-package-hashtable
 607                                            internal-symbols)
 608                         :external-symbols (make-or-remake-package-hashtable
 609                                            external-symbols))))
 610
 611          ;; Do a USE-PACKAGE for each thing in the USE list so that checking for
 612          ;; conflicting exports among used packages is done.
 613          (if *in-package-init*
 614              (push (list use package) *!deferred-use-packages*)
 615              (use-package use package))
 616
 617          ;; FIXME: ENTER-NEW-NICKNAMES can fail (ERROR) if nicknames are illegal,
 618          ;; which would leave us with possibly-bad side effects from the earlier
 619          ;; USE-PACKAGE (e.g. this package on the used-by lists of other packages,
 620          ;; but not in *PACKAGE-NAMES*, and possibly import side effects too?).
 621          ;; Perhaps this can be solved by just moving ENTER-NEW-NICKNAMES before
 622          ;; USE-PACKAGE, but I need to check what kinds of errors can be caused by
 623          ;; USE-PACKAGE, too.
 624          (%enter-new-nicknames package nicknames)
 625          (return (setf (gethash name *package-names*) package))))
 626      (bug "never")))
 627
 628 ;;; Change the name if we can, blast any old nicknames and then
 629 ;;; add in any new ones.
 630 ;;;
 631 ;;; FIXME: ANSI claims that NAME is a package designator (not just a
 632 ;;; string designator -- weird). Thus, NAME could
 633 ;;; be a package instead of a string. Presumably then we should not change
 634 ;;; the package name if NAME is the same package that's referred to by PACKAGE.
 635 ;;; If it's a *different* package, we should probably signal an error.
 636 ;;; (perhaps (ERROR 'ANSI-WEIRDNESS ..):-)
 637 (defun rename-package (package-designator name &optional (nicknames ()))
 638   #!+sb-doc
 639   "Changes the name and nicknames for a package."
 640   (let ((package nil))
 641   (tagbody :restart
 642        (setq package (find-undeleted-package-or-lose package-designator))
 643        (let* ((name (package-namify name))
 644             (found (find-package name))
 645             (nicks (mapcar #'string nicknames)))
 646        (unless (or (not found) (eq found package))
 647          (error 'simple-package-error
 648                 :package name
 649                 :format-control "A package named ~S already exists."
 650                 :format-arguments (list name)))
 651        (with-single-package-locked-error ()
 652          (unless (and (string= name (package-name package))
 653                       (null (set-difference nicks (package-nicknames package)
 654                                             :test #'string=)))
 655            (assert-package-unlocked package "rename as ~A~@[ with nickname~P ~
 656                                            ~{~A~^, ~}~]"
 657                                     name (length nicks) nicks))
 658          (with-package-names (names)
 659            ;; Check for race conditions now that we have the lock.
 660            (unless (eq package (find-package package-designator))
 661              (go :restart))
 662            ;; Do the renaming.
 663            (remhash (package-%name package) names)
 664            (dolist (n (package-%nicknames package))
 665              (remhash n names))
 666            (setf (package-%name package) name
 667                  (gethash name names) package
 668                  (package-%nicknames package) ()))
 669            (%enter-new-nicknames package nicknames))))
 670     package))
 671
 672 (defun delete-package (package-designator)
 673   #!+sb-doc
 674   "Delete the package designated by PACKAGE-DESIGNATOR from the package
 675   system data structures."
 676   (tagbody :restart
 677      (let ((package (find-package package-designator)))
 678        (cond ((not package)
 679               ;; This continuable error is required by ANSI.
 680               (cerror
 681                "Return ~S."
 682                (make-condition
 683                 'simple-package-error
 684                 :package package-designator
 685                 :format-control "There is no package named ~S."
 686                 :format-arguments (list package-designator))
 687                (return-from delete-package nil)))
 688              ((not (package-name package)) ; already deleted
 689               (return-from delete-package nil))
 690              (t
 691               (with-single-package-locked-error
 692                   (:package package "deleting package ~A" package)
 693                 (let ((use-list (package-used-by-list package)))
 694                   (when use-list
 695                     ;; This continuable error is specified by ANSI.
 696                     (cerror
 697                      "Remove dependency in other packages."
 698                      (make-condition
 699                       'simple-package-error
 700                       :package package
 701                       :format-control
 702                       "~@<Package ~S is used by package~P:~2I~_~S~@:>"
 703                       :format-arguments (list (package-name package)
 704                                               (length use-list)
 705                                               (mapcar #'package-name use-list))))
 706                     (dolist (p use-list)
 707                       (unuse-package package p))))
 708                 (with-package-graph ()
 709                   ;; Check for races, restart if necessary.
 710                   (let ((package2 (find-package package-designator)))
 711                     (when (or (neq package package2) (package-used-by-list package2))
 712                       (go :restart)))
 713                   (dolist (used (package-use-list package))
 714                     (unuse-package used package))
 715                   (do-symbols (sym package)
 716                     (unintern sym package))
 717                   (with-package-names (names)
 718                     (remhash (package-name package) names)
 719                     (dolist (nick (package-nicknames package))
 720                       (remhash nick names))
 721                     (setf (package-%name package) nil
 722                           ;; Setting PACKAGE-%NAME to NIL is required in order to
 723                           ;; make PACKAGE-NAME return NIL for a deleted package as
 724                           ;; ANSI requires. Setting the other slots to NIL
 725                           ;; and blowing away the PACKAGE-HASHTABLES is just done
 726                           ;; for tidiness and to help the GC.
 727                           (package-%nicknames package) nil))
 728                   (setf (package-%use-list package) nil
 729                         (package-tables package) nil
 730                         (package-%shadowing-symbols package) nil
 731                         (package-internal-symbols package)
 732                         (make-or-remake-package-hashtable 0)
 733                         (package-external-symbols package)
 734                         (make-or-remake-package-hashtable 0)))
 735                 (return-from delete-package t)))))))
 736
 737 (defun list-all-packages ()
 738   #!+sb-doc
 739   "Return a list of all existing packages."
 740   (let ((res ()))
 741     (with-package-names (names)
 742       (maphash (lambda (k v)
 743                  (declare (ignore k))
 744                  (pushnew v res))
 745                names))
 746     res))
 747 \f
 748 (defun intern (name &optional (package (sane-package)))
 749   #!+sb-doc
 750   "Return a symbol in PACKAGE having the specified NAME, creating it
 751   if necessary."
 752   ;; We just simple-stringify the name and call INTERN*, where the real
 753   ;; logic is.
 754   (let ((name (if (simple-string-p name)
 755                   name
 756                   (coerce name 'simple-string)))
 757         (package (find-undeleted-package-or-lose package)))
 758     (declare (simple-string name))
 759       (intern* name
 760                (length name)
 761                package)))
 762
 763 (defun find-symbol (name &optional (package (sane-package)))
 764   #!+sb-doc
 765   "Return the symbol named STRING in PACKAGE. If such a symbol is found
 766   then the second value is :INTERNAL, :EXTERNAL or :INHERITED to indicate
 767   how the symbol is accessible. If no symbol is found then both values
 768   are NIL."
 769   ;; We just simple-stringify the name and call FIND-SYMBOL*, where the
 770   ;; real logic is.
 771   (let ((name (if (simple-string-p name) name (coerce name 'simple-string))))
 772     (declare (simple-string name))
 773     (find-symbol* name
 774                   (length name)
 775                   (find-undeleted-package-or-lose package))))
 776
 777 ;;; If the symbol named by the first LENGTH characters of NAME doesn't exist,
 778 ;;; then create it, special-casing the keyword package.
 779 (defun intern* (name length package &key no-copy)
 780   (declare (simple-string name))
 781   (multiple-value-bind (symbol where) (find-symbol* name length package)
 782     (cond (where
 783            (values symbol where))
 784           (t
 785            ;; Let's try again with a lock: the common case has the
 786            ;; symbol already interned, handled by the first leg of the
 787            ;; COND, but in case another thread is interning in
 788            ;; parallel we need to check after grabbing the lock.
 789            (with-package-graph ()
 790              (setf (values symbol where) (find-symbol* name length package))
 791              (if where
 792                  (values symbol where)
 793                  (let ((symbol-name (cond (no-copy
 794                                            (aver (= (length name) length))
 795                                            name)
 796                                           (t
 797                                            (subseq name 0 length)))))
 798                    (with-single-package-locked-error
 799                        (:package package "interning ~A" symbol-name)
 800                      (let ((symbol (make-symbol symbol-name)))
 801                        (%set-symbol-package symbol package)
 802                        (cond
 803                          ((eq package *keyword-package*)
 804                           (%set-symbol-value symbol symbol)
 805                           (add-symbol (package-external-symbols package) symbol))
 806                          (t
 807                           (add-symbol (package-internal-symbols package) symbol)))
 808                        (values symbol nil))))))))))
 809
 810 ;;; Check internal and external symbols, then scan down the list
 811 ;;; of hashtables for inherited symbols.
 812 (defun find-symbol* (string length package)
 813   (declare (simple-string string)
 814            (type index length))
 815   (let* ((hash (%sxhash-simple-substring string length))
 816          (ehash (entry-hash length hash)))
 817     (declare (type hash hash ehash))
 818     (with-symbol (found symbol (package-internal-symbols package)
 819                         string length hash ehash)
 820       (when found
 821         (return-from find-symbol* (values symbol :internal))))
 822     (with-symbol (found symbol (package-external-symbols package)
 823                         string length hash ehash)
 824       (when found
 825         (return-from find-symbol* (values symbol :external))))
 826     (let ((head (package-tables package)))
 827       (do ((prev head table)
 828            (table (cdr head) (cdr table)))
 829           ((null table) (values nil nil))
 830         (with-symbol (found symbol (car table) string length hash ehash)
 831           (when found
 832             ;; At this point we used to move the table to the
 833             ;; beginning of the list, probably on the theory that we'd
 834             ;; soon be looking up further items there. Unfortunately
 835             ;; that was very much non-thread safe. Since the failure
 836             ;; mode was nasty (corruption of the package in a way
 837             ;; which would make symbol lookups loop infinitely) and it
 838             ;; would be triggered just by doing reads to a resource
 839             ;; that users can't do their own locking on, that code has
 840             ;; been removed. If we ever add locking to packages,
 841             ;; resurrecting that code might make sense, even though it
 842             ;; didn't seem to have much of an performance effect in
 843             ;; normal use.
 844             ;;
 845             ;; -- JES, 2006-09-13
 846             (return-from find-symbol* (values symbol :inherited))))))))
 847
 848 ;;; Similar to FIND-SYMBOL, but only looks for an external symbol.
 849 ;;; This is used for fast name-conflict checking in this file and symbol
 850 ;;; printing in the printer.
 851 (defun find-external-symbol (string package)
 852   (declare (simple-string string))
 853   (let* ((length (length string))
 854          (hash (%sxhash-simple-string string))
 855          (ehash (entry-hash length hash)))
 856     (declare (type index length)
 857              (type hash hash))
 858     (with-symbol (found symbol (package-external-symbols package)
 859                         string length hash ehash)
 860       (values symbol found))))
 861 \f
 862 (defun print-symbol-with-prefix (stream symbol colon at)
 863   #!+sb-doc
 864   "For use with ~/: Write SYMBOL to STREAM as if it is not accessible from
 865   the current package."
 866   (declare (ignore colon at))
 867   ;; Only keywords should be accessible from the keyword package, and
 868   ;; keywords are always printed with colons, so this guarantees that the
 869   ;; symbol will not be printed without a prefix.
 870   (let ((*package* *keyword-package*))
 871     (write symbol :stream stream :escape t)))
 872
 873 (define-condition name-conflict (reference-condition package-error)
 874   ((function :initarg :function :reader name-conflict-function)
 875    (datum :initarg :datum :reader name-conflict-datum)
 876    (symbols :initarg :symbols :reader name-conflict-symbols))
 877   (:default-initargs :references (list '(:ansi-cl :section (11 1 1 2 5))))
 878   (:report
 879    (lambda (c s)
 880      (format s "~@<~S ~S causes name-conflicts in ~S between the ~
 881                 following symbols:~2I~@:_~
 882                 ~{~/sb-impl::print-symbol-with-prefix/~^, ~}~:@>"
 883              (name-conflict-function c)
 884              (name-conflict-datum c)
 885              (package-error-package c)
 886              (name-conflict-symbols c)))))
 887
 888 (defun name-conflict (package function datum &rest symbols)
 889   (restart-case
 890       (error 'name-conflict :package package :symbols symbols
 891              :function function :datum datum)
 892     (resolve-conflict (chosen-symbol)
 893       :report "Resolve conflict."
 894       :interactive
 895       (lambda ()
 896         (let* ((len (length symbols))
 897                (nlen (length (write-to-string len :base 10)))
 898                (*print-pretty* t))
 899           (format *query-io* "~&~@<Select a symbol to be made accessible in ~
 900                               package ~A:~2I~@:_~{~{~V,' D. ~
 901                               ~/sb-impl::print-symbol-with-prefix/~}~@:_~}~
 902                               ~@:>"
 903                 (package-name package)
 904                 (loop for s in symbols
 905                       for i upfrom 1
 906                       collect (list nlen i s)))
 907           (loop
 908            (format *query-io* "~&Enter an integer (between 1 and ~D): " len)
 909            (finish-output *query-io*)
 910            (let ((i (parse-integer (read-line *query-io*) :junk-allowed t)))
 911              (when (and i (<= 1 i len))
 912                (return (list (nth (1- i) symbols))))))))
 913       (multiple-value-bind (package-symbol status)
 914           (find-symbol (symbol-name chosen-symbol) package)
 915         (let* ((accessiblep status)     ; never NIL here
 916                (presentp (and accessiblep
 917                               (not (eq :inherited status)))))
 918           (ecase function
 919             ((unintern)
 920              (if presentp
 921                  (if (eq package-symbol chosen-symbol)
 922                      (shadow (list package-symbol) package)
 923                      (shadowing-import (list chosen-symbol) package))
 924                  (shadowing-import (list chosen-symbol) package)))
 925             ((use-package export)
 926              (if presentp
 927                  (if (eq package-symbol chosen-symbol)
 928                      (shadow (list package-symbol) package) ; CLHS 11.1.1.2.5
 929                      (if (eq (symbol-package package-symbol) package)
 930                          (unintern package-symbol package) ; CLHS 11.1.1.2.5
 931                          (shadowing-import (list chosen-symbol) package)))
 932                  (shadowing-import (list chosen-symbol) package)))
 933             ((import)
 934              (if presentp
 935                  (if (eq package-symbol chosen-symbol)
 936                      nil                ; re-importing the same symbol
 937                      (shadowing-import (list chosen-symbol) package))
 938                  (shadowing-import (list chosen-symbol) package)))))))))
 939
 940 ;;; If we are uninterning a shadowing symbol, then a name conflict can
 941 ;;; result, otherwise just nuke the symbol.
 942 (defun unintern (symbol &optional (package (sane-package)))
 943   #!+sb-doc
 944   "Makes SYMBOL no longer present in PACKAGE. If SYMBOL was present then T is
 945 returned, otherwise NIL. If PACKAGE is SYMBOL's home package, then it is made
 946 uninterned."
 947   (with-package-graph ()
 948     (let* ((package (find-undeleted-package-or-lose package))
 949            (name (symbol-name symbol))
 950            (shadowing-symbols (package-%shadowing-symbols package)))
 951       (declare (list shadowing-symbols))
 952
 953       (with-single-package-locked-error ()
 954         (when (find-symbol name package)
 955           (assert-package-unlocked package "uninterning ~A" name))
 956
 957         ;; If a name conflict is revealed, give us a chance to
 958         ;; shadowing-import one of the accessible symbols.
 959         (when (member symbol shadowing-symbols)
 960           (let ((cset ()))
 961             (dolist (p (package-%use-list package))
 962               (multiple-value-bind (s w) (find-external-symbol name p)
 963                 (when w (pushnew s cset))))
 964             (when (cdr cset)
 965               (apply #'name-conflict package 'unintern symbol cset)
 966               (return-from unintern t)))
 967           (setf (package-%shadowing-symbols package)
 968                 (remove symbol shadowing-symbols)))
 969
 970         (multiple-value-bind (s w) (find-symbol name package)
 971           (cond ((not (eq symbol s)) nil)
 972                 ((or (eq w :internal) (eq w :external))
 973                  (nuke-symbol (if (eq w :internal)
 974                                   (package-internal-symbols package)
 975                                   (package-external-symbols package))
 976                               name)
 977                  (if (eq (symbol-package symbol) package)
 978                      (%set-symbol-package symbol nil))
 979                  t)
 980                 (t nil)))))))
 981 \f
 982 ;;; Take a symbol-or-list-of-symbols and return a list, checking types.
 983 (defun symbol-listify (thing)
 984   (cond ((listp thing)
 985          (dolist (s thing)
 986            (unless (symbolp s) (error "~S is not a symbol." s)))
 987          thing)
 988         ((symbolp thing) (list thing))
 989         (t
 990          (error "~S is neither a symbol nor a list of symbols." thing))))
 991
 992 (defun string-listify (thing)
 993   (mapcar #'string (if (listp thing)
 994                        thing
 995                        (list thing))))
 996
 997 ;;; This is like UNINTERN, except if SYMBOL is inherited, it chases
 998 ;;; down the package it is inherited from and uninterns it there. Used
 999 ;;; for name-conflict resolution. Shadowing symbols are not uninterned
1000 ;;; since they do not cause conflicts.
1001 (defun moby-unintern (symbol package)
1002   (unless (member symbol (package-%shadowing-symbols package))
1003     (or (unintern symbol package)
1004         (let ((name (symbol-name symbol)))
1005           (multiple-value-bind (s w) (find-symbol name package)
1006             (declare (ignore s))
1007             (when (eq w :inherited)
1008               (dolist (q (package-%use-list package))
1009                 (multiple-value-bind (u x) (find-external-symbol name q)
1010                   (declare (ignore u))
1011                   (when x
1012                     (unintern symbol q)
1013                     (return t))))))))))
1014 \f
1015 (defun export (symbols &optional (package (sane-package)))
1016   #!+sb-doc
1017   "Exports SYMBOLS from PACKAGE, checking that no name conflicts result."
1018   (with-package-graph ()
1019     (let ((package (find-undeleted-package-or-lose package))
1020           (symbols (symbol-listify symbols))
1021           (syms ()))
1022       ;; Punt any symbols that are already external.
1023       (dolist (sym symbols)
1024         (multiple-value-bind (s w)
1025             (find-external-symbol (symbol-name sym) package)
1026           (declare (ignore s))
1027           (unless (or w (member sym syms))
1028             (push sym syms))))
1029       (with-single-package-locked-error ()
1030         (when syms
1031           (assert-package-unlocked package "exporting symbol~P ~{~A~^, ~}"
1032                                    (length syms) syms))
1033         ;; Find symbols and packages with conflicts.
1034         (let ((used-by (package-%used-by-list package)))
1035           (dolist (sym syms)
1036             (let ((name (symbol-name sym)))
1037               (dolist (p used-by)
1038                 (multiple-value-bind (s w) (find-symbol name p)
1039                   (when (and w
1040                              (not (eq s sym))
1041                              (not (member s (package-%shadowing-symbols p))))
1042                     ;; Beware: the name conflict is in package P, not in
1043                     ;; PACKAGE.
1044                     (name-conflict p 'export sym sym s)))))))
1045         ;; Check that all symbols are accessible. If not, ask to import them.
1046         (let ((missing ())
1047               (imports ()))
1048           (dolist (sym syms)
1049             (multiple-value-bind (s w) (find-symbol (symbol-name sym) package)
1050               (cond ((not (and w (eq s sym)))
1051                      (push sym missing))
1052                     ((eq w :inherited)
1053                      (push sym imports)))))
1054           (when missing
1055             (cerror
1056              "~S these symbols into the ~A package."
1057              (make-condition
1058               'simple-package-error
1059               :package package
1060               :format-control
1061               "~@<These symbols are not accessible in the ~A package:~2I~_~S~@:>"
1062               :format-arguments (list (package-%name package) missing))
1063              'import (package-%name package))
1064             (import missing package))
1065           (import imports package))
1066
1067         ;; And now, three pages later, we export the suckers.
1068         (let ((internal (package-internal-symbols package))
1069               (external (package-external-symbols package)))
1070           (dolist (sym syms)
1071             (nuke-symbol internal (symbol-name sym))
1072             (add-symbol external sym))))
1073       t)))
1074 \f
1075 ;;; Check that all symbols are accessible, then move from external to internal.
1076 (defun unexport (symbols &optional (package (sane-package)))
1077   #!+sb-doc
1078   "Makes SYMBOLS no longer exported from PACKAGE."
1079   (with-package-graph ()
1080     (let ((package (find-undeleted-package-or-lose package))
1081           (symbols (symbol-listify symbols))
1082           (syms ()))
1083       (dolist (sym symbols)
1084         (multiple-value-bind (s w) (find-symbol (symbol-name sym) package)
1085           (cond ((or (not w) (not (eq s sym)))
1086                  (error 'simple-package-error
1087                         :package package
1088                         :format-control "~S is not accessible in the ~A package."
1089                         :format-arguments (list sym (package-%name package))))
1090                 ((eq w :external) (pushnew sym syms)))))
1091       (with-single-package-locked-error ()
1092         (when syms
1093           (assert-package-unlocked package "unexporting symbol~P ~{~A~^, ~}"
1094                                    (length syms) syms))
1095         (let ((internal (package-internal-symbols package))
1096               (external (package-external-symbols package)))
1097           (dolist (sym syms)
1098             (add-symbol internal sym)
1099             (nuke-symbol external (symbol-name sym)))))
1100       t)))
1101 \f
1102 ;;; Check for name conflict caused by the import and let the user
1103 ;;; shadowing-import if there is.
1104 (defun import (symbols &optional (package (sane-package)))
1105   #!+sb-doc
1106   "Make SYMBOLS accessible as internal symbols in PACKAGE. If a symbol is
1107 already accessible then it has no effect. If a name conflict would result from
1108 the importation, then a correctable error is signalled."
1109   (with-package-graph ()
1110     (let* ((package (find-undeleted-package-or-lose package))
1111            (symbols (symbol-listify symbols))
1112            (homeless (remove-if #'symbol-package symbols))
1113            (syms ()))
1114       (with-single-package-locked-error ()
1115         (dolist (sym symbols)
1116           (multiple-value-bind (s w) (find-symbol (symbol-name sym) package)
1117             (cond ((not w)
1118                    (let ((found (member sym syms :test #'string=)))
1119                      (if found
1120                          (when (not (eq (car found) sym))
1121                            (setf syms (remove (car found) syms))
1122                            (name-conflict package 'import sym sym (car found)))
1123                          (push sym syms))))
1124                   ((not (eq s sym))
1125                    (name-conflict package 'import sym sym s))
1126                   ((eq w :inherited) (push sym syms)))))
1127         (when (or homeless syms)
1128           (let ((union (delete-duplicates (append homeless syms))))
1129             (assert-package-unlocked package "importing symbol~P ~{~A~^, ~}"
1130                                      (length union) union)))
1131         ;; Add the new symbols to the internal hashtable.
1132         (let ((internal (package-internal-symbols package)))
1133           (dolist (sym syms)
1134             (add-symbol internal sym)))
1135         ;; If any of the symbols are uninterned, make them be owned by PACKAGE.
1136         (dolist (sym homeless)
1137           (%set-symbol-package sym package))
1138         t))))
1139 \f
1140 ;;; If a conflicting symbol is present, unintern it, otherwise just
1141 ;;; stick the symbol in.
1142 (defun shadowing-import (symbols &optional (package (sane-package)))
1143   #!+sb-doc
1144   "Import SYMBOLS into package, disregarding any name conflict. If
1145   a symbol of the same name is present, then it is uninterned."
1146   (with-package-graph ()
1147     (let* ((package (find-undeleted-package-or-lose package))
1148            (internal (package-internal-symbols package))
1149            (symbols (symbol-listify symbols))
1150            (lock-asserted-p nil))
1151       (with-single-package-locked-error ()
1152         (dolist (sym symbols)
1153           (multiple-value-bind (s w) (find-symbol (symbol-name sym) package)
1154             (unless (or lock-asserted-p
1155                         (and (eq s sym)
1156                              (member s (package-shadowing-symbols package))))
1157               (assert-package-unlocked package "shadowing-importing symbol~P ~
1158                                            ~{~A~^, ~}" (length symbols) symbols)
1159               (setf lock-asserted-p t))
1160             (unless (and w (not (eq w :inherited)) (eq s sym))
1161               (when (or (eq w :internal) (eq w :external))
1162                 ;; If it was shadowed, we don't want UNINTERN to flame out...
1163                 (setf (package-%shadowing-symbols package)
1164                       (remove s (the list (package-%shadowing-symbols package))))
1165                 (unintern s package))
1166               (add-symbol internal sym))
1167             (pushnew sym (package-%shadowing-symbols package)))))))
1168   t)
1169
1170 (defun shadow (symbols &optional (package (sane-package)))
1171   #!+sb-doc
1172   "Make an internal symbol in PACKAGE with the same name as each of the
1173 specified SYMBOLS. If a symbol with the given name is already present in
1174 PACKAGE, then the existing symbol is placed in the shadowing symbols list if
1175 it is not already present."
1176   (with-package-graph ()
1177     (let* ((package (find-undeleted-package-or-lose package))
1178            (internal (package-internal-symbols package))
1179            (symbols (string-listify symbols))
1180            (lock-asserted-p nil))
1181       (flet ((present-p (w)
1182                (and w (not (eq w :inherited)))))
1183         (with-single-package-locked-error ()
1184           (dolist (name symbols)
1185             (multiple-value-bind (s w) (find-symbol name package)
1186               (unless (or lock-asserted-p
1187                           (and (present-p w)
1188                                (member s (package-shadowing-symbols package))))
1189                 (assert-package-unlocked package "shadowing symbol~P ~{~A~^, ~}"
1190                                          (length symbols) symbols)
1191                 (setf lock-asserted-p t))
1192               (unless (present-p w)
1193                 (setq s (make-symbol name))
1194                 (%set-symbol-package s package)
1195                 (add-symbol internal s))
1196               (pushnew s (package-%shadowing-symbols package))))))))
1197   t)
1198 \f
1199 ;;; Do stuff to use a package, with all kinds of fun name-conflict checking.
1200 (defun use-package (packages-to-use &optional (package (sane-package)))
1201   #!+sb-doc
1202   "Add all the PACKAGES-TO-USE to the use list for PACKAGE so that the
1203 external symbols of the used packages are accessible as internal symbols in
1204 PACKAGE."
1205   (with-package-graph ()
1206     (let ((packages (package-listify packages-to-use))
1207           (package (find-undeleted-package-or-lose package)))
1208
1209       ;; Loop over each package, USE'ing one at a time...
1210       (with-single-package-locked-error ()
1211         (dolist (pkg packages)
1212           (unless (member pkg (package-%use-list package))
1213             (assert-package-unlocked package "using package~P ~{~A~^, ~}"
1214                                      (length packages) packages)
1215             (let ((shadowing-symbols (package-%shadowing-symbols package))
1216                   (use-list (package-%use-list package)))
1217
1218               ;; If the number of symbols already accessible is less
1219               ;; than the number to be inherited then it is faster to
1220               ;; run the test the other way. This is particularly
1221               ;; valuable in the case of a new package USEing
1222               ;; COMMON-LISP.
1223               (cond
1224                 ((< (+ (package-internal-symbol-count package)
1225                        (package-external-symbol-count package)
1226                        (let ((res 0))
1227                          (dolist (p use-list res)
1228                            (incf res (package-external-symbol-count p)))))
1229                     (package-external-symbol-count pkg))
1230                  (do-symbols (sym package)
1231                    (multiple-value-bind (s w)
1232                        (find-external-symbol (symbol-name sym) pkg)
1233                      (when (and w
1234                                 (not (eq s sym))
1235                                 (not (member sym shadowing-symbols)))
1236                        (name-conflict package 'use-package pkg sym s))))
1237                  (dolist (p use-list)
1238                    (do-external-symbols (sym p)
1239                      (multiple-value-bind (s w)
1240                          (find-external-symbol (symbol-name sym) pkg)
1241                        (when (and w
1242                                   (not (eq s sym))
1243                                   (not (member
1244                                         (find-symbol (symbol-name sym) package)
1245                                         shadowing-symbols)))
1246                          (name-conflict package 'use-package pkg sym s))))))
1247                 (t
1248                  (do-external-symbols (sym pkg)
1249                    (multiple-value-bind (s w)
1250                        (find-symbol (symbol-name sym) package)
1251                      (when (and w
1252                                 (not (eq s sym))
1253                                 (not (member s shadowing-symbols)))
1254                        (name-conflict package 'use-package pkg sym s)))))))
1255
1256             (push pkg (package-%use-list package))
1257             (push (package-external-symbols pkg) (cdr (package-tables package)))
1258             (push package (package-%used-by-list pkg)))))))
1259   t)
1260
1261 (defun unuse-package (packages-to-unuse &optional (package (sane-package)))
1262   #!+sb-doc
1263   "Remove PACKAGES-TO-UNUSE from the USE list for PACKAGE."
1264   (with-package-graph ()
1265     (let ((package (find-undeleted-package-or-lose package))
1266           (packages (package-listify packages-to-unuse)))
1267       (with-single-package-locked-error ()
1268         (dolist (p packages)
1269           (when (member p (package-use-list package))
1270             (assert-package-unlocked package "unusing package~P ~{~A~^, ~}"
1271                                      (length packages) packages))
1272           (setf (package-%use-list package)
1273                 (remove p (the list (package-%use-list package))))
1274           (setf (package-tables package)
1275                 (delete (package-external-symbols p)
1276                         (the list (package-tables package))))
1277           (setf (package-%used-by-list p)
1278                 (remove package (the list (package-%used-by-list p))))))
1279       t)))
1280
1281 (defun find-all-symbols (string-or-symbol)
1282   #!+sb-doc
1283   "Return a list of all symbols in the system having the specified name."
1284   (let ((string (string string-or-symbol))
1285         (res ()))
1286     (with-package-names (names)
1287       (maphash (lambda (k v)
1288                  (declare (ignore k))
1289                  (multiple-value-bind (s w) (find-symbol string v)
1290                    (when w (pushnew s res))))
1291                names))
1292     res))
1293 \f
1294 ;;;; APROPOS and APROPOS-LIST
1295
1296 (defun briefly-describe-symbol (symbol)
1297   (fresh-line)
1298   (prin1 symbol)
1299   (when (boundp symbol)
1300     (write-string " (bound)"))
1301   (when (fboundp symbol)
1302     (write-string " (fbound)")))
1303
1304 (defun apropos-list (string-designator
1305                      &optional
1306                      package-designator
1307                      external-only)
1308   #!+sb-doc
1309   "Like APROPOS, except that it returns a list of the symbols found instead
1310   of describing them."
1311   (if package-designator
1312       (let ((package (find-undeleted-package-or-lose package-designator))
1313             (string (stringify-string-designator string-designator))
1314             (result nil))
1315         (do-symbols (symbol package)
1316           (when (and (eq (symbol-package symbol) package)
1317                      (or (not external-only)
1318                          (eq (nth-value 1 (find-symbol (symbol-name symbol)
1319                                                        package))
1320                              :external))
1321                      (search string (symbol-name symbol) :test #'char-equal))
1322             (push symbol result)))
1323         (sort result #'string-lessp))
1324       (mapcan (lambda (package)
1325                 (apropos-list string-designator package external-only))
1326               (sort (list-all-packages) #'string-lessp :key #'package-name))))
1327
1328 (defun apropos (string-designator &optional package external-only)
1329   #!+sb-doc
1330   "Briefly describe all symbols which contain the specified STRING.
1331   If PACKAGE is supplied then only describe symbols present in
1332   that package. If EXTERNAL-ONLY then only describe
1333   external symbols in the specified package."
1334   ;; Implementing this in terms of APROPOS-LIST keeps things simple at the cost
1335   ;; of some unnecessary consing; and the unnecessary consing shouldn't be an
1336   ;; issue, since this function is is only useful interactively anyway, and
1337   ;; we can cons and GC a lot faster than the typical user can read..
1338   (dolist (symbol (apropos-list string-designator package external-only))
1339     (briefly-describe-symbol symbol))
1340   (values))
1341 \f
1342 ;;;; final initialization
1343
1344 ;;;; The cold loader (GENESIS) makes the data structure in
1345 ;;;; *!INITIAL-SYMBOLS*. We grovel over it, making the specified
1346 ;;;; packages and interning the symbols. For a description of the
1347 ;;;; format of *!INITIAL-SYMBOLS*, see the GENESIS source.
1348
1349 (defvar *!initial-symbols*)
1350
1351 (!cold-init-forms
1352
1353   (setq *in-package-init* t)
1354
1355   (/show0 "about to loop over *!INITIAL-SYMBOLS* to make packages")
1356   (dolist (spec *!initial-symbols*)
1357     (let* ((pkg (apply #'make-package (first spec)))
1358            (internal (package-internal-symbols pkg))
1359            (external (package-external-symbols pkg)))
1360       (/show0 "back from MAKE-PACKAGE, PACKAGE-NAME=..")
1361       (/primitive-print (package-name pkg))
1362
1363       ;; Put internal symbols in the internal hashtable and set package.
1364       (dolist (symbol (second spec))
1365         (add-symbol internal symbol)
1366         (%set-symbol-package symbol pkg))
1367
1368       ;; External symbols same, only go in external table.
1369       (dolist (symbol (third spec))
1370         (add-symbol external symbol)
1371         (%set-symbol-package symbol pkg))
1372
1373       ;; Don't set package for imported symbols.
1374       (dolist (symbol (fourth spec))
1375         (add-symbol internal symbol))
1376       (dolist (symbol (fifth spec))
1377         (add-symbol external symbol))
1378
1379       ;; Put shadowing symbols in the shadowing symbols list.
1380       (setf (package-%shadowing-symbols pkg) (sixth spec))
1381       ;; Set the package documentation
1382       (setf (package-doc-string pkg) (seventh spec))))
1383
1384   ;; FIXME: These assignments are also done at toplevel in
1385   ;; boot-extensions.lisp. They should probably only be done once.
1386   (/show0 "setting up *CL-PACKAGE* and *KEYWORD-PACKAGE*")
1387   (setq *cl-package* (find-package "COMMON-LISP"))
1388   (setq *keyword-package* (find-package "KEYWORD"))
1389
1390   (/show0 "about to MAKUNBOUND *!INITIAL-SYMBOLS*")
1391   (%makunbound '*!initial-symbols*)       ; (so that it gets GCed)
1392
1393   ;; Make some other packages that should be around in the cold load.
1394   ;; The COMMON-LISP-USER package is required by the ANSI standard,
1395   ;; but not completely specified by it, so in the cross-compilation
1396   ;; host Lisp it could contain various symbols, USE-PACKAGEs, or
1397   ;; nicknames that we don't want in our target SBCL. For that reason,
1398   ;; we handle it specially, not dumping the host Lisp version at
1399   ;; genesis time..
1400   (aver (not (find-package "COMMON-LISP-USER")))
1401   ;; ..but instead making our own from scratch here.
1402   (/show0 "about to MAKE-PACKAGE COMMON-LISP-USER")
1403   (make-package "COMMON-LISP-USER"
1404                 :nicknames '("CL-USER")
1405                 :use '("COMMON-LISP"
1406                        ;; ANSI encourages us to put extension packages
1407                        ;; in the USE list of COMMON-LISP-USER.
1408                        "SB!ALIEN" "SB!ALIEN" "SB!DEBUG"
1409                        "SB!EXT" "SB!GRAY" "SB!PROFILE"))
1410
1411   ;; Now do the *!DEFERRED-USE-PACKAGES*.
1412   (/show0 "about to do *!DEFERRED-USE-PACKAGES*")
1413   (dolist (args *!deferred-use-packages*)
1414     (apply #'use-package args))
1415
1416   ;; The Age Of Magic is over, we can behave ANSIly henceforth.
1417   (/show0 "about to SETQ *IN-PACKAGE-INIT*")
1418   (setq *in-package-init* nil)
1419
1420   ;; For the kernel core image wizards, set the package to *CL-PACKAGE*.
1421   ;;
1422   ;; FIXME: We should just set this to (FIND-PACKAGE
1423   ;; "COMMON-LISP-USER") once and for all here, instead of setting it
1424   ;; once here and resetting it later.
1425   (setq *package* *cl-package*))
1426 \f
1427 (!cold-init-forms
1428   (/show0 "done with !PACKAGE-COLD-INIT"))
1429
1430 (!defun-from-collected-cold-init-forms !package-cold-init)