src/code/target-package.lisp

   1 ;;;; PACKAGEs and stuff like that
   2 ;;;;
   3 ;;;; Note: The code in this file signals many correctable errors. This
   4 ;;;; is not just an arbitrary aesthetic decision on the part of the
   5 ;;;; implementor -- many of these are specified by ANSI 11.1.1.2.5,
   6 ;;;; "Prevention of Name Conflicts in Packages":
   7 ;;;;   Within one package, any particular name can refer to at most one
   8 ;;;;   symbol. A name conflict is said to occur when there would be more
   9 ;;;;   than one candidate symbol. Any time a name conflict is about to
  10 ;;;;   occur, a correctable error is signaled.
  11 ;;;;
  12 ;;;; FIXME: The code contains a lot of type declarations. Are they
  13 ;;;; all really necessary?
  14
  15 ;;;; This software is part of the SBCL system. See the README file for
  16 ;;;; more information.
  17 ;;;;
  18 ;;;; This software is derived from the CMU CL system, which was
  19 ;;;; written at Carnegie Mellon University and released into the
  20 ;;;; public domain. The software is in the public domain and is
  21 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  22 ;;;; files for more information.
  23
  24 (in-package "SB!IMPL")
  25
  26 (!begin-collecting-cold-init-forms)
  27
  28 (!cold-init-forms
  29   (/show0 "entering !PACKAGE-COLD-INIT"))
  30 \f
  31 ;;;; PACKAGE-HASHTABLE stuff
  32
  33 (def!method print-object ((table package-hashtable) stream)
  34   (declare (type stream stream))
  35   (print-unreadable-object (table stream :type t)
  36     (format stream
  37             ":SIZE ~S :FREE ~S :DELETED ~S"
  38             (package-hashtable-size table)
  39             (package-hashtable-free table)
  40             (package-hashtable-deleted table))))
  41
  42 ;;; the maximum load factor we allow in a package hashtable
  43 (defconstant +package-rehash-threshold+ 0.75)
  44
  45 ;;; the load factor desired for a package hashtable when writing a
  46 ;;; core image
  47 (defconstant +package-hashtable-image-load-factor+ 0.5)
  48
  49 ;;; All destructive package modifications are serialized on this lock,
  50 ;;; plus iterations on *PACKAGE-NAMES*.
  51 (defvar *package-lock*)
  52
  53 (!cold-init-forms
  54  (setf *package-lock* (sb!thread::make-spinlock :name "Package Lock")))
  55
  56 (defmacro with-packages ((&key) &body forms)
  57   `(sb!thread::with-recursive-spinlock (*package-lock*)
  58      ,@forms))
  59
  60 ;;; Make a package hashtable having a prime number of entries at least
  61 ;;; as great as (/ SIZE +PACKAGE-REHASH-THRESHOLD+). If RES is supplied,
  62 ;;; then it is destructively modified to produce the result. This is
  63 ;;; useful when changing the size, since there are many pointers to
  64 ;;; the hashtable.
  65 ;;; Actually, the smallest table built here has three entries. This
  66 ;;; is necessary because the double hashing step size is calculated
  67 ;;; using a division by the table size minus two.
  68 (defun make-or-remake-package-hashtable (size
  69                                          &optional
  70                                          res)
  71   (flet ((actual-package-hashtable-size (size)
  72            (loop for n of-type fixnum
  73               from (logior (ceiling size +package-rehash-threshold+) 1)
  74               by 2
  75               when (positive-primep n) return n)))
  76     (let* ((n (actual-package-hashtable-size size))
  77            (size (truncate (* n +package-rehash-threshold+)))
  78            (table (make-array n))
  79            (hash (make-array n
  80                              :element-type '(unsigned-byte 8)
  81                              :initial-element 0)))
  82       (if res
  83           (setf (package-hashtable-table res) table
  84                 (package-hashtable-hash res) hash
  85                 (package-hashtable-size res) size
  86                 (package-hashtable-free res) size
  87                 (package-hashtable-deleted res) 0)
  88           (setf res (%make-package-hashtable table hash size)))
  89       res)))
  90
  91 ;;; Destructively resize TABLE to have room for at least SIZE entries
  92 ;;; and rehash its existing entries.
  93 (defun resize-package-hashtable (table size)
  94   (let* ((vec (package-hashtable-table table))
  95          (hash (package-hashtable-hash table))
  96          (len (length vec)))
  97     (make-or-remake-package-hashtable size table)
  98     (dotimes (i len)
  99       (when (> (aref hash i) 1)
 100         (add-symbol table (svref vec i))))))
 101 \f
 102 ;;;; package locking operations, built conditionally on :sb-package-locks
 103
 104 #!+sb-package-locks
 105 (progn
 106 (defun package-locked-p (package)
 107   #!+sb-doc
 108   "Returns T when PACKAGE is locked, NIL otherwise. Signals an error
 109 if PACKAGE doesn't designate a valid package."
 110   (package-lock (find-undeleted-package-or-lose package)))
 111
 112 (defun lock-package (package)
 113   #!+sb-doc
 114   "Locks PACKAGE and returns T. Has no effect if PACKAGE was already
 115 locked. Signals an error if PACKAGE is not a valid package designator"
 116   (setf (package-lock (find-undeleted-package-or-lose package)) t))
 117
 118 (defun unlock-package (package)
 119   #!+sb-doc
 120   "Unlocks PACKAGE and returns T. Has no effect if PACKAGE was already
 121 unlocked. Signals an error if PACKAGE is not a valid package designator."
 122   (setf (package-lock (find-undeleted-package-or-lose package)) nil)
 123   t)
 124
 125 (defun package-implemented-by-list (package)
 126   #!+sb-doc
 127   "Returns a list containing the implementation packages of
 128 PACKAGE. Signals an error if PACKAGE is not a valid package designator."
 129   (package-%implementation-packages (find-undeleted-package-or-lose package)))
 130
 131 (defun package-implements-list (package)
 132   #!+sb-doc
 133   "Returns the packages that PACKAGE is an implementation package
 134 of. Signals an error if PACKAGE is not a valid package designator."
 135   (let ((package (find-undeleted-package-or-lose package)))
 136     (loop for x in (list-all-packages)
 137           when (member package (package-%implementation-packages x))
 138           collect x)))
 139
 140 (defun add-implementation-package (packages-to-add
 141                                    &optional (package *package*))
 142   #!+sb-doc
 143   "Adds PACKAGES-TO-ADD as implementation packages of PACKAGE. Signals
 144 an error if PACKAGE or any of the PACKAGES-TO-ADD is not a valid
 145 package designator."
 146   (let ((package (find-undeleted-package-or-lose package))
 147         (packages-to-add (package-listify packages-to-add)))
 148     (setf (package-%implementation-packages package)
 149           (union (package-%implementation-packages package)
 150                  (mapcar #'find-undeleted-package-or-lose packages-to-add)))))
 151
 152 (defun remove-implementation-package (packages-to-remove
 153                                       &optional (package *package*))
 154   #!+sb-doc
 155   "Removes PACKAGES-TO-REMOVE from the implementation packages of
 156 PACKAGE. Signals an error if PACKAGE or any of the PACKAGES-TO-REMOVE
 157 is not a valid package designator."
 158   (let ((package (find-undeleted-package-or-lose package))
 159         (packages-to-remove (package-listify packages-to-remove)))
 160     (setf (package-%implementation-packages package)
 161           (nset-difference
 162            (package-%implementation-packages package)
 163            (mapcar #'find-undeleted-package-or-lose packages-to-remove)))))
 164
 165 (defmacro with-unlocked-packages ((&rest packages) &body forms)
 166   #!+sb-doc
 167   "Unlocks PACKAGES for the dynamic scope of the body. Signals an
 168 error if any of PACKAGES is not a valid package designator."
 169   (with-unique-names (unlocked-packages)
 170     `(let (,unlocked-packages)
 171       (unwind-protect
 172            (progn
 173              (dolist (p ',packages)
 174                (when (package-locked-p p)
 175                  (push p ,unlocked-packages)
 176                  (unlock-package p)))
 177              ,@forms)
 178         (dolist (p ,unlocked-packages)
 179           (when (find-package p)
 180             (lock-package p)))))))
 181
 182 (defun package-lock-violation (package &key (symbol nil symbol-p)
 183                                format-control format-arguments)
 184   (let* ((restart :continue)
 185          (cl-violation-p (eq package *cl-package*))
 186          (error-arguments
 187           (append (list (if symbol-p
 188                             'symbol-package-locked-error
 189                             'package-locked-error)
 190                         :package package
 191                         :format-control format-control
 192                         :format-arguments format-arguments)
 193                   (when symbol-p (list :symbol symbol))
 194                   (list :references
 195                         (append '((:sbcl :node "Package Locks"))
 196                                 (when cl-violation-p
 197                                   '((:ansi-cl :section (11 1 2 1 2)))))))))
 198     (restart-case
 199         (apply #'cerror "Ignore the package lock." error-arguments)
 200       (:ignore-all ()
 201         :report "Ignore all package locks in the context of this operation."
 202         (setf restart :ignore-all))
 203       (:unlock-package ()
 204         :report "Unlock the package."
 205         (setf restart :unlock-package)))
 206     (ecase restart
 207       (:continue
 208        (pushnew package *ignored-package-locks*))
 209       (:ignore-all
 210        (setf *ignored-package-locks* t))
 211       (:unlock-package
 212        (unlock-package package)))))
 213
 214 (defun package-lock-violation-p (package &optional (symbol nil symbolp))
 215   ;; KLUDGE: (package-lock package) needs to be before
 216   ;; comparison to *package*, since during cold init this gets
 217   ;; called before *package* is bound -- but no package should
 218   ;; be locked at that point.
 219   (and package
 220        (package-lock package)
 221        ;; In package or implementation package
 222        (not (or (eq package *package*)
 223                 (member *package* (package-%implementation-packages package))))
 224        ;; Runtime disabling
 225        (not (eq t *ignored-package-locks*))
 226        (or (eq :invalid *ignored-package-locks*)
 227            (not (member package *ignored-package-locks*)))
 228        ;; declarations for symbols
 229        (not (and symbolp (member symbol (disabled-package-locks))))))
 230
 231 (defun disabled-package-locks ()
 232   (if (boundp 'sb!c::*lexenv*)
 233       (sb!c::lexenv-disabled-package-locks sb!c::*lexenv*)
 234       sb!c::*disabled-package-locks*))
 235
 236 ) ; progn
 237
 238 ;;;; more package-locking these are NOPs unless :sb-package-locks is
 239 ;;;; in target features. Cross-compiler NOPs for these are in cross-misc.
 240
 241 ;;; The right way to establish a package lock context is
 242 ;;; WITH-SINGLE-PACKAGE-LOCKED-ERROR, defined in early-package.lisp
 243 ;;;
 244 ;;; Must be used inside the dynamic contour established by
 245 ;;; WITH-SINGLE-PACKAGE-LOCKED-ERROR
 246 (defun assert-package-unlocked (package &optional format-control
 247                                 &rest format-arguments)
 248   #!-sb-package-locks
 249   (declare (ignore format-control format-arguments))
 250   #!+sb-package-locks
 251   (when (package-lock-violation-p package)
 252     (package-lock-violation package
 253                             :format-control format-control
 254                             :format-arguments format-arguments))
 255   package)
 256
 257 ;;; Must be used inside the dynamic contour established by
 258 ;;; WITH-SINGLE-PACKAGE-LOCKED-ERROR.
 259 ;;;
 260 ;;; FIXME: Maybe we should establish such contours for he toplevel
 261 ;;; and others, so that %set-fdefinition and others could just use
 262 ;;; this.
 263 (defun assert-symbol-home-package-unlocked (name format)
 264   #!-sb-package-locks
 265   (declare (ignore format))
 266   #!+sb-package-locks
 267   (let* ((symbol (etypecase name
 268                    (symbol name)
 269                    (list (if (and (consp (cdr name))
 270                                   (eq 'setf (first name)))
 271                              (second name)
 272                              ;; Skip lists of length 1, single conses and
 273                              ;; (class-predicate foo), etc.
 274                              ;; FIXME: MOP and package-lock
 275                              ;; interaction needs to be thought about.
 276                              (return-from
 277                               assert-symbol-home-package-unlocked
 278                                name)))))
 279          (package (symbol-package symbol)))
 280     (when (package-lock-violation-p package symbol)
 281       (package-lock-violation package
 282                               :symbol symbol
 283                               :format-control format
 284                               :format-arguments (list name))))
 285   name)
 286
 287 \f
 288 ;;;; miscellaneous PACKAGE operations
 289
 290 (def!method print-object ((package package) stream)
 291   (let ((name (package-%name package)))
 292     (if name
 293         (print-unreadable-object (package stream :type t)
 294           (prin1 name stream))
 295         (print-unreadable-object (package stream :type t :identity t)
 296           (write-string "(deleted)" stream)))))
 297
 298 ;;; ANSI says (in the definition of DELETE-PACKAGE) that these, and
 299 ;;; most other operations, are unspecified for deleted packages. We
 300 ;;; just do the easy thing and signal errors in that case.
 301 (macrolet ((def (ext real)
 302              `(defun ,ext (x) (,real (find-undeleted-package-or-lose x)))))
 303   (def package-nicknames package-%nicknames)
 304   (def package-use-list package-%use-list)
 305   (def package-used-by-list package-%used-by-list)
 306   (def package-shadowing-symbols package-%shadowing-symbols))
 307
 308 (defun %package-hashtable-symbol-count (table)
 309   (let ((size (the fixnum
 310                 (- (package-hashtable-size table)
 311                    (package-hashtable-deleted table)))))
 312     (the fixnum
 313       (- size (package-hashtable-free table)))))
 314
 315 (defun package-internal-symbol-count (package)
 316   (%package-hashtable-symbol-count (package-internal-symbols package)))
 317
 318 (defun package-external-symbol-count (package)
 319   (%package-hashtable-symbol-count (package-external-symbols package)))
 320 \f
 321 (defvar *package* (error "*PACKAGE* should be initialized in cold load!")
 322   #!+sb-doc "the current package")
 323 ;;; FIXME: should be declared of type PACKAGE, with no NIL init form,
 324 ;;; after I get around to cleaning up DOCUMENTATION
 325
 326 ;;; a map from package names to packages
 327 (defvar *package-names*)
 328 (declaim (type hash-table *package-names*))
 329 (!cold-init-forms
 330   (setf *package-names* (make-hash-table :test 'equal)))
 331
 332 ;;; This magical variable is T during initialization so that
 333 ;;; USE-PACKAGE's of packages that don't yet exist quietly win. Such
 334 ;;; packages are thrown onto the list *DEFERRED-USE-PACKAGES* so that
 335 ;;; this can be fixed up later.
 336 ;;;
 337 ;;; FIXME: This could be cleaned up the same way I do it in my package
 338 ;;; hacking when setting up the cross-compiler. Then we wouldn't have
 339 ;;; this extraneous global variable and annoying runtime tests on
 340 ;;; package operations. (*DEFERRED-USE-PACKAGES* would also go away.)
 341 (defvar *in-package-init*)
 342
 343 ;;; pending USE-PACKAGE arguments saved up while *IN-PACKAGE-INIT* is true
 344 (defvar *!deferred-use-packages*)
 345 (!cold-init-forms
 346   (setf *!deferred-use-packages* nil))
 347
 348 (define-condition bootstrap-package-not-found (condition)
 349   ((name :initarg :name :reader bootstrap-package-name)))
 350 (defun debootstrap-package (&optional condition)
 351   (invoke-restart
 352    (find-restart-or-control-error 'debootstrap-package condition)))
 353
 354 (defun find-package (package-designator)
 355   (flet ((find-package-from-string (string)
 356            (declare (type string string))
 357            (let ((packageoid (gethash string *package-names*)))
 358              (when (and (null packageoid)
 359                         (not *in-package-init*) ; KLUDGE
 360                         (let ((mismatch (mismatch "SB!" string)))
 361                           (and mismatch (= mismatch 3))))
 362                (restart-case
 363                    (signal 'bootstrap-package-not-found :name string)
 364                  (debootstrap-package ()
 365                    (return-from find-package
 366                      (if (string= string "SB!XC")
 367                          (find-package "COMMON-LISP")
 368                          (find-package
 369                           (substitute #\- #\! string :count 1)))))))
 370              packageoid)))
 371     (typecase package-designator
 372       (package package-designator)
 373       (symbol (find-package-from-string (symbol-name package-designator)))
 374       (string (find-package-from-string package-designator))
 375       (character (find-package-from-string (string package-designator)))
 376       (t (error 'type-error
 377                 :datum package-designator
 378                 :expected-type '(or character package string symbol))))))
 379
 380 ;;; Return a list of packages given a package designator or list of
 381 ;;; package designators, or die trying.
 382 (defun package-listify (thing)
 383   (let ((res ()))
 384     (dolist (thing (if (listp thing) thing (list thing)) res)
 385       (push (find-undeleted-package-or-lose thing) res))))
 386
 387 ;;; Make a package name into a simple-string.
 388 (defun package-namify (n)
 389   (stringify-package-designator n))
 390
 391 ;;; ANSI specifies (in the definition of DELETE-PACKAGE) that PACKAGE-NAME
 392 ;;; returns NIL (not an error) for a deleted package, so this is a special
 393 ;;; case where we want to use bare %FIND-PACKAGE-OR-LOSE instead of
 394 ;;; FIND-UNDELETED-PACKAGE-OR-LOSE.
 395 (defun package-name (package-designator)
 396   (package-%name (%find-package-or-lose package-designator)))
 397 \f
 398 ;;;; operations on package hashtables
 399
 400 ;;; Compute a number from the sxhash of the pname and the length which
 401 ;;; must be between 2 and 255.
 402 (defmacro entry-hash (length sxhash)
 403   `(the fixnum
 404         (+ (the fixnum
 405                 (rem (the fixnum
 406                           (logxor ,length
 407                                   ,sxhash
 408                                   (the fixnum (ash ,sxhash -8))
 409                                   (the fixnum (ash ,sxhash -16))
 410                                   (the fixnum (ash ,sxhash -19))))
 411                      254))
 412            2)))
 413 ;;; FIXME: should be wrapped in EVAL-WHEN (COMPILE EXECUTE)
 414
 415 ;;; Add a symbol to a package hashtable. The symbol is assumed
 416 ;;; not to be present.
 417 (defun add-symbol (table symbol)
 418   (when (zerop (package-hashtable-free table))
 419     ;; The hashtable is full. Resize it to be able to hold twice the
 420     ;; amount of symbols than it currently contains. The actual new size
 421     ;; can be smaller than twice the current size if the table contained
 422     ;; deleted entries.
 423     (resize-package-hashtable table
 424                               (* (- (package-hashtable-size table)
 425                                     (package-hashtable-deleted table))
 426                                  2)))
 427   (let* ((vec (package-hashtable-table table))
 428          (hash (package-hashtable-hash table))
 429          (len (length vec))
 430          (sxhash (%sxhash-simple-string (symbol-name symbol)))
 431          (h2 (1+ (rem sxhash (- len 2)))))
 432     (declare (fixnum sxhash h2))
 433     (do ((i (rem sxhash len) (rem (+ i h2) len)))
 434         ((< (the fixnum (aref hash i)) 2)
 435          (if (zerop (the fixnum (aref hash i)))
 436              (decf (package-hashtable-free table))
 437              (decf (package-hashtable-deleted table)))
 438          (setf (svref vec i) symbol)
 439          (setf (aref hash i)
 440                (entry-hash (length (symbol-name symbol))
 441                            sxhash)))
 442       (declare (fixnum i)))))
 443
 444 ;;; Resize the package hashtables of all packages so that their load
 445 ;;; factor is +PACKAGE-HASHTABLE-IMAGE-LOAD-FACTOR+. Called from
 446 ;;; SAVE-LISP-AND-DIE to optimize space usage in the image.
 447 (defun tune-hashtable-sizes-of-all-packages ()
 448   (flet ((tune-table-size (table)
 449            (resize-package-hashtable
 450             table
 451             (round (* (/ +package-rehash-threshold+
 452                          +package-hashtable-image-load-factor+)
 453                       (- (package-hashtable-size table)
 454                          (package-hashtable-free table)
 455                          (package-hashtable-deleted table)))))))
 456     (dolist (package (list-all-packages))
 457       (tune-table-size (package-internal-symbols package))
 458       (tune-table-size (package-external-symbols package)))))
 459
 460 ;;; Find where the symbol named STRING is stored in TABLE. INDEX-VAR
 461 ;;; is bound to the index, or NIL if it is not present. SYMBOL-VAR
 462 ;;; is bound to the symbol. LENGTH and HASH are the length and sxhash
 463 ;;; of STRING. ENTRY-HASH is the entry-hash of the string and length.
 464 (defmacro with-symbol ((index-var symbol-var table string length sxhash
 465                                   entry-hash)
 466                        &body forms)
 467   (let ((vec (gensym)) (hash (gensym)) (len (gensym)) (h2 (gensym))
 468         (name (gensym)) (name-len (gensym)) (ehash (gensym)))
 469     `(let* ((,vec (package-hashtable-table ,table))
 470             (,hash (package-hashtable-hash ,table))
 471             (,len (length ,vec))
 472             (,h2 (1+ (the index (rem (the index ,sxhash)
 473                                       (the index (- ,len 2)))))))
 474        (declare (type index ,len ,h2))
 475        (prog ((,index-var (rem (the index ,sxhash) ,len))
 476               ,symbol-var ,ehash)
 477          (declare (type (or index null) ,index-var))
 478          LOOP
 479          (setq ,ehash (aref ,hash ,index-var))
 480          (cond ((eql ,ehash ,entry-hash)
 481                 (setq ,symbol-var (svref ,vec ,index-var))
 482                 (let* ((,name (symbol-name ,symbol-var))
 483                        (,name-len (length ,name)))
 484                   (declare (type index ,name-len))
 485                   (when (and (= ,name-len ,length)
 486                              (string= ,string ,name
 487                                       :end1 ,length
 488                                       :end2 ,name-len))
 489                     (go DOIT))))
 490                ((zerop ,ehash)
 491                 (setq ,index-var nil)
 492                 (go DOIT)))
 493          (setq ,index-var (+ ,index-var ,h2))
 494          (when (>= ,index-var ,len)
 495            (setq ,index-var (- ,index-var ,len)))
 496          (go LOOP)
 497          DOIT
 498          (return (progn ,@forms))))))
 499
 500 ;;; Delete the entry for STRING in TABLE. The entry must exist.
 501 (defun nuke-symbol (table string)
 502   (declare (simple-string string))
 503   (let* ((length (length string))
 504          (hash (%sxhash-simple-string string))
 505          (ehash (entry-hash length hash)))
 506     (declare (type index length hash))
 507     (with-symbol (index symbol table string length hash ehash)
 508       (setf (aref (package-hashtable-hash table) index) 1)
 509       (setf (aref (package-hashtable-table table) index) nil)
 510       (incf (package-hashtable-deleted table))))
 511   ;; If the table is less than one quarter full, halve its size and
 512   ;; rehash the entries.
 513   (let* ((size (package-hashtable-size table))
 514          (deleted (package-hashtable-deleted table))
 515          (used (- size
 516                   (package-hashtable-free table)
 517                   deleted)))
 518     (declare (type fixnum size deleted used))
 519     (when (< used (truncate size 4))
 520       (resize-package-hashtable table (* used 2)))))
 521 \f
 522 ;;; Enter any new NICKNAMES for PACKAGE into *PACKAGE-NAMES*.
 523 ;;; If there is a conflict then give the user a chance to do
 524 ;;; something about it.
 525 (defun enter-new-nicknames (package nicknames)
 526   (declare (type list nicknames))
 527   (dolist (n nicknames)
 528     (let* ((n (package-namify n))
 529            (found (gethash n *package-names*)))
 530       (cond ((not found)
 531              (setf (gethash n *package-names*) package)
 532              (push n (package-%nicknames package)))
 533             ((eq found package))
 534             ((string= (the string (package-%name found)) n)
 535              (cerror "Ignore this nickname."
 536                      'simple-package-error
 537                      :package package
 538                      :format-control "~S is a package name, so it cannot be a nickname for ~S."
 539                      :format-arguments (list n (package-%name package))))
 540             (t
 541              (cerror "Leave this nickname alone."
 542                      'simple-package-error
 543                      :package package
 544                      :format-control "~S is already a nickname for ~S."
 545                      :format-arguments (list n (package-%name found))))))))
 546
 547 (defun make-package (name &key
 548                           (use '#.*default-package-use-list*)
 549                           nicknames
 550                           (internal-symbols 10)
 551                           (external-symbols 10))
 552   #!+sb-doc
 553   #.(format nil
 554      "Make a new package having the specified NAME, NICKNAMES, and USE
 555 list. :INTERNAL-SYMBOLS and :EXTERNAL-SYMBOLS are estimates for the number of
 556 internal and external symbols which will ultimately be present in the package.
 557 The default value of USE is implementation-dependent, and in this
 558 implementation it is ~S." *default-package-use-list*)
 559   (with-packages ()
 560     ;; Check for package name conflicts in name and nicknames, then
 561     ;; make the package.
 562     (when (find-package name)
 563       ;; ANSI specifies that this error is correctable.
 564       (cerror "Leave existing package alone."
 565               "A package named ~S already exists" name))
 566     (let* ((name (package-namify name))
 567            (package (internal-make-package
 568                      :%name name
 569                      :internal-symbols (make-or-remake-package-hashtable
 570                                         internal-symbols)
 571                      :external-symbols (make-or-remake-package-hashtable
 572                                         external-symbols))))
 573
 574       ;; Do a USE-PACKAGE for each thing in the USE list so that checking for
 575       ;; conflicting exports among used packages is done.
 576       (if *in-package-init*
 577           (push (list use package) *!deferred-use-packages*)
 578           (use-package use package))
 579
 580       ;; FIXME: ENTER-NEW-NICKNAMES can fail (ERROR) if nicknames are illegal,
 581       ;; which would leave us with possibly-bad side effects from the earlier
 582       ;; USE-PACKAGE (e.g. this package on the used-by lists of other packages,
 583       ;; but not in *PACKAGE-NAMES*, and possibly import side effects too?).
 584       ;; Perhaps this can be solved by just moving ENTER-NEW-NICKNAMES before
 585       ;; USE-PACKAGE, but I need to check what kinds of errors can be caused by
 586       ;; USE-PACKAGE, too.
 587       (enter-new-nicknames package nicknames)
 588       (setf (gethash name *package-names*) package))))
 589
 590 ;;; Change the name if we can, blast any old nicknames and then
 591 ;;; add in any new ones.
 592 ;;;
 593 ;;; FIXME: ANSI claims that NAME is a package designator (not just a
 594 ;;; string designator -- weird). Thus, NAME could
 595 ;;; be a package instead of a string. Presumably then we should not change
 596 ;;; the package name if NAME is the same package that's referred to by PACKAGE.
 597 ;;; If it's a *different* package, we should probably signal an error.
 598 ;;; (perhaps (ERROR 'ANSI-WEIRDNESS ..):-)
 599 (defun rename-package (package name &optional (nicknames ()))
 600   #!+sb-doc
 601   "Changes the name and nicknames for a package."
 602   (with-packages ()
 603     (let* ((package (find-undeleted-package-or-lose package))
 604            (name (package-namify name))
 605            (found (find-package name))
 606            (nicks (mapcar #'string nicknames)))
 607       (unless (or (not found) (eq found package))
 608         (error 'simple-package-error
 609                :package name
 610                :format-control "A package named ~S already exists."
 611                :format-arguments (list name)))
 612       (with-single-package-locked-error ()
 613         (unless (and (string= name (package-name package))
 614                      (null (set-difference nicks (package-nicknames package)
 615                                            :test #'string=)))
 616           (assert-package-unlocked package "rename as ~A~@[ with nickname~P ~
 617                                            ~{~A~^, ~}~]"
 618                                    name (length nicks) nicks))
 619         ;; do the renaming
 620         (remhash (package-%name package) *package-names*)
 621         (dolist (n (package-%nicknames package))
 622           (remhash n *package-names*))
 623         (setf (package-%name package) name
 624               (gethash name *package-names*) package
 625               (package-%nicknames package) ())
 626         (enter-new-nicknames package nicknames))
 627       package)))
 628
 629 (defun delete-package (package-designator)
 630   #!+sb-doc
 631   "Delete the package designated by PACKAGE-DESIGNATOR from the package
 632   system data structures."
 633   (with-packages ()
 634     (let ((package (if (packagep package-designator)
 635                        package-designator
 636                        (find-package package-designator))))
 637       (cond ((not package)
 638              ;; This continuable error is required by ANSI.
 639              (cerror
 640               "Return ~S."
 641               (make-condition
 642                'simple-package-error
 643                :package package-designator
 644                :format-control "There is no package named ~S."
 645                :format-arguments (list package-designator))
 646               nil))
 647             ((not (package-name package)) ; already deleted
 648              nil)
 649             (t
 650              (with-single-package-locked-error
 651                  (:package package "deleting package ~A" package)
 652                (let ((use-list (package-used-by-list package)))
 653                  (when use-list
 654                    ;; This continuable error is specified by ANSI.
 655                    (cerror
 656                     "Remove dependency in other packages."
 657                     (make-condition
 658                      'simple-package-error
 659                      :package package
 660                      :format-control
 661                      "~@<Package ~S is used by package~P:~2I~_~S~@:>"
 662                      :format-arguments (list (package-name package)
 663                                              (length use-list)
 664                                              (mapcar #'package-name use-list))))
 665                    (dolist (p use-list)
 666                      (unuse-package package p))))
 667                (dolist (used (package-use-list package))
 668                  (unuse-package used package))
 669                (do-symbols (sym package)
 670                  (unintern sym package))
 671                (remhash (package-name package) *package-names*)
 672                (dolist (nick (package-nicknames package))
 673                  (remhash nick *package-names*))
 674                (setf (package-%name package) nil
 675                      ;; Setting PACKAGE-%NAME to NIL is required in order to
 676                      ;; make PACKAGE-NAME return NIL for a deleted package as
 677                      ;; ANSI requires. Setting the other slots to NIL
 678                      ;; and blowing away the PACKAGE-HASHTABLES is just done
 679                      ;; for tidiness and to help the GC.
 680                      (package-%nicknames package) nil
 681                      (package-%use-list package) nil
 682                      (package-tables package) nil
 683                      (package-%shadowing-symbols package) nil
 684                      (package-internal-symbols package)
 685                      (make-or-remake-package-hashtable 0)
 686                      (package-external-symbols package)
 687                      (make-or-remake-package-hashtable 0))
 688                t))))))
 689
 690 (defun list-all-packages ()
 691   #!+sb-doc
 692   "Return a list of all existing packages."
 693   (let ((res ()))
 694     (with-packages ()
 695       (maphash (lambda (k v)
 696                  (declare (ignore k))
 697                  (pushnew v res))
 698                *package-names*))
 699     res))
 700 \f
 701 (defun intern (name &optional (package (sane-package)))
 702   #!+sb-doc
 703   "Return a symbol in PACKAGE having the specified NAME, creating it
 704   if necessary."
 705   ;; We just simple-stringify the name and call INTERN*, where the real
 706   ;; logic is.
 707   (let ((name (if (simple-string-p name)
 708                   name
 709                   (coerce name 'simple-string)))
 710         (package (find-undeleted-package-or-lose package)))
 711     (declare (simple-string name))
 712       (intern* name
 713                (length name)
 714                package)))
 715
 716 (defun find-symbol (name &optional (package (sane-package)))
 717   #!+sb-doc
 718   "Return the symbol named STRING in PACKAGE. If such a symbol is found
 719   then the second value is :INTERNAL, :EXTERNAL or :INHERITED to indicate
 720   how the symbol is accessible. If no symbol is found then both values
 721   are NIL."
 722   ;; We just simple-stringify the name and call FIND-SYMBOL*, where the
 723   ;; real logic is.
 724   (let ((name (if (simple-string-p name) name (coerce name 'simple-string))))
 725     (declare (simple-string name))
 726     (find-symbol* name
 727                   (length name)
 728                   (find-undeleted-package-or-lose package))))
 729
 730 ;;; If the symbol named by the first LENGTH characters of NAME doesn't exist,
 731 ;;; then create it, special-casing the keyword package.
 732 (defun intern* (name length package)
 733   (declare (simple-string name))
 734   (multiple-value-bind (symbol where) (find-symbol* name length package)
 735     (cond (where
 736            (values symbol where))
 737           (t
 738            ;; Let's try again with a lock: the common case has the
 739            ;; symbol already interned, handled by the first leg of the
 740            ;; COND, but in case another thread is interning in
 741            ;; parallel we need to check after grabbing the lock.
 742            (with-packages ()
 743              (setf (values symbol where) (find-symbol* name length package))
 744              (if where
 745                  (values symbol where)
 746                  (let ((symbol-name (subseq name 0 length)))
 747                    (with-single-package-locked-error
 748                        (:package package "interning ~A" symbol-name)
 749                      (let ((symbol (make-symbol symbol-name)))
 750                        (%set-symbol-package symbol package)
 751                        (cond
 752                          ((eq package *keyword-package*)
 753                           (add-symbol (package-external-symbols package) symbol)
 754                           (%set-symbol-value symbol symbol))
 755                          (t
 756                           (add-symbol (package-internal-symbols package) symbol)))
 757                        (values symbol nil))))))))))
 758
 759 ;;; Check internal and external symbols, then scan down the list
 760 ;;; of hashtables for inherited symbols.
 761 (defun find-symbol* (string length package)
 762   (declare (simple-string string)
 763            (type index length))
 764   (let* ((hash (%sxhash-simple-substring string length))
 765          (ehash (entry-hash length hash)))
 766     (declare (type index hash ehash))
 767     (with-symbol (found symbol (package-internal-symbols package)
 768                         string length hash ehash)
 769       (when found
 770         (return-from find-symbol* (values symbol :internal))))
 771     (with-symbol (found symbol (package-external-symbols package)
 772                         string length hash ehash)
 773       (when found
 774         (return-from find-symbol* (values symbol :external))))
 775     (let ((head (package-tables package)))
 776       (do ((prev head table)
 777            (table (cdr head) (cdr table)))
 778           ((null table) (values nil nil))
 779         (with-symbol (found symbol (car table) string length hash ehash)
 780           (when found
 781             ;; At this point we used to move the table to the
 782             ;; beginning of the list, probably on the theory that we'd
 783             ;; soon be looking up further items there. Unfortunately
 784             ;; that was very much non-thread safe. Since the failure
 785             ;; mode was nasty (corruption of the package in a way
 786             ;; which would make symbol lookups loop infinitely) and it
 787             ;; would be triggered just by doing reads to a resource
 788             ;; that users can't do their own locking on, that code has
 789             ;; been removed. If we ever add locking to packages,
 790             ;; resurrecting that code might make sense, even though it
 791             ;; didn't seem to have much of an performance effect in
 792             ;; normal use.
 793             ;;
 794             ;; -- JES, 2006-09-13
 795             (return-from find-symbol* (values symbol :inherited))))))))
 796
 797 ;;; Similar to FIND-SYMBOL, but only looks for an external symbol.
 798 ;;; This is used for fast name-conflict checking in this file and symbol
 799 ;;; printing in the printer.
 800 (defun find-external-symbol (string package)
 801   (declare (simple-string string))
 802   (let* ((length (length string))
 803          (hash (%sxhash-simple-string string))
 804          (ehash (entry-hash length hash)))
 805     (declare (type index length hash))
 806     (with-symbol (found symbol (package-external-symbols package)
 807                         string length hash ehash)
 808       (values symbol found))))
 809 \f
 810 (defun print-symbol-with-prefix (stream symbol colon at)
 811   #!+sb-doc
 812   "For use with ~/: Write SYMBOL to STREAM as if it is not accessible from
 813   the current package."
 814   (declare (ignore colon at))
 815   ;; Only keywords should be accessible from the keyword package, and
 816   ;; keywords are always printed with colons, so this guarantees that the
 817   ;; symbol will not be printed without a prefix.
 818   (let ((*package* *keyword-package*))
 819     (write symbol :stream stream :escape t)))
 820
 821 (define-condition name-conflict (reference-condition package-error)
 822   ((function :initarg :function :reader name-conflict-function)
 823    (datum :initarg :datum :reader name-conflict-datum)
 824    (symbols :initarg :symbols :reader name-conflict-symbols))
 825   (:default-initargs :references (list '(:ansi-cl :section (11 1 1 2 5))))
 826   (:report
 827    (lambda (c s)
 828      (format s "~@<~S ~S causes name-conflicts in ~S between the ~
 829                 following symbols:~2I~@:_~
 830                 ~{~/sb-impl::print-symbol-with-prefix/~^, ~}~:@>"
 831              (name-conflict-function c)
 832              (name-conflict-datum c)
 833              (package-error-package c)
 834              (name-conflict-symbols c)))))
 835
 836 (defun name-conflict (package function datum &rest symbols)
 837   (restart-case
 838       (error 'name-conflict :package package :symbols symbols
 839              :function function :datum datum)
 840     (resolve-conflict (chosen-symbol)
 841       :report "Resolve conflict."
 842       :interactive
 843       (lambda ()
 844         (let* ((len (length symbols))
 845                (nlen (length (write-to-string len :base 10)))
 846                (*print-pretty* t))
 847           (format *query-io* "~&~@<Select a symbol to be made accessible in ~
 848                               package ~A:~2I~@:_~{~{~V,' D. ~
 849                               ~/sb-impl::print-symbol-with-prefix/~}~@:_~}~
 850                               ~@:>"
 851                 (package-name package)
 852                 (loop for s in symbols
 853                       for i upfrom 1
 854                       collect (list nlen i s)))
 855           (loop
 856            (format *query-io* "~&Enter an integer (between 1 and ~D): " len)
 857            (finish-output *query-io*)
 858            (let ((i (parse-integer (read-line *query-io*) :junk-allowed t)))
 859              (when (and i (<= 1 i len))
 860                (return (list (nth (1- i) symbols))))))))
 861       (multiple-value-bind (package-symbol status)
 862           (find-symbol (symbol-name chosen-symbol) package)
 863         (let* ((accessiblep status)     ; never NIL here
 864                (presentp (and accessiblep
 865                               (not (eq :inherited status)))))
 866           (ecase function
 867             ((unintern)
 868              (if presentp
 869                  (if (eq package-symbol chosen-symbol)
 870                      (shadow (list package-symbol) package)
 871                      (shadowing-import (list chosen-symbol) package))
 872                  (shadowing-import (list chosen-symbol) package)))
 873             ((use-package export)
 874              (if presentp
 875                  (if (eq package-symbol chosen-symbol)
 876                      (shadow (list package-symbol) package) ; CLHS 11.1.1.2.5
 877                      (if (eq (symbol-package package-symbol) package)
 878                          (unintern package-symbol package) ; CLHS 11.1.1.2.5
 879                          (shadowing-import (list chosen-symbol) package)))
 880                  (shadowing-import (list chosen-symbol) package)))
 881             ((import)
 882              (if presentp
 883                  (if (eq package-symbol chosen-symbol)
 884                      nil                ; re-importing the same symbol
 885                      (shadowing-import (list chosen-symbol) package))
 886                  (shadowing-import (list chosen-symbol) package)))))))))
 887
 888 ;;; If we are uninterning a shadowing symbol, then a name conflict can
 889 ;;; result, otherwise just nuke the symbol.
 890 (defun unintern (symbol &optional (package (sane-package)))
 891   #!+sb-doc
 892   "Makes SYMBOL no longer present in PACKAGE. If SYMBOL was present then T is
 893 returned, otherwise NIL. If PACKAGE is SYMBOL's home package, then it is made
 894 uninterned."
 895   (with-packages ()
 896     (let* ((package (find-undeleted-package-or-lose package))
 897            (name (symbol-name symbol))
 898            (shadowing-symbols (package-%shadowing-symbols package)))
 899       (declare (list shadowing-symbols))
 900
 901       (with-single-package-locked-error ()
 902         (when (find-symbol name package)
 903           (assert-package-unlocked package "uninterning ~A" name))
 904
 905         ;; If a name conflict is revealed, give us a chance to
 906         ;; shadowing-import one of the accessible symbols.
 907         (when (member symbol shadowing-symbols)
 908           (let ((cset ()))
 909             (dolist (p (package-%use-list package))
 910               (multiple-value-bind (s w) (find-external-symbol name p)
 911                 (when w (pushnew s cset))))
 912             (when (cdr cset)
 913               (apply #'name-conflict package 'unintern symbol cset)
 914               (return-from unintern t)))
 915           (setf (package-%shadowing-symbols package)
 916                 (remove symbol shadowing-symbols)))
 917
 918         (multiple-value-bind (s w) (find-symbol name package)
 919           (declare (ignore s))
 920           (cond ((or (eq w :internal) (eq w :external))
 921                  (nuke-symbol (if (eq w :internal)
 922                                   (package-internal-symbols package)
 923                                   (package-external-symbols package))
 924                               name)
 925                  (if (eq (symbol-package symbol) package)
 926                      (%set-symbol-package symbol nil))
 927                  t)
 928                 (t nil)))))))
 929 \f
 930 ;;; Take a symbol-or-list-of-symbols and return a list, checking types.
 931 (defun symbol-listify (thing)
 932   (cond ((listp thing)
 933          (dolist (s thing)
 934            (unless (symbolp s) (error "~S is not a symbol." s)))
 935          thing)
 936         ((symbolp thing) (list thing))
 937         (t
 938          (error "~S is neither a symbol nor a list of symbols." thing))))
 939
 940 (defun string-listify (thing)
 941   (mapcar #'string (if (listp thing)
 942                        thing
 943                        (list thing))))
 944
 945 ;;; This is like UNINTERN, except if SYMBOL is inherited, it chases
 946 ;;; down the package it is inherited from and uninterns it there. Used
 947 ;;; for name-conflict resolution. Shadowing symbols are not uninterned
 948 ;;; since they do not cause conflicts.
 949 (defun moby-unintern (symbol package)
 950   (unless (member symbol (package-%shadowing-symbols package))
 951     (or (unintern symbol package)
 952         (let ((name (symbol-name symbol)))
 953           (multiple-value-bind (s w) (find-symbol name package)
 954             (declare (ignore s))
 955             (when (eq w :inherited)
 956               (dolist (q (package-%use-list package))
 957                 (multiple-value-bind (u x) (find-external-symbol name q)
 958                   (declare (ignore u))
 959                   (when x
 960                     (unintern symbol q)
 961                     (return t))))))))))
 962 \f
 963 (defun export (symbols &optional (package (sane-package)))
 964   #!+sb-doc
 965   "Exports SYMBOLS from PACKAGE, checking that no name conflicts result."
 966   (with-packages ()
 967     (let ((package (find-undeleted-package-or-lose package))
 968           (syms ()))
 969       ;; Punt any symbols that are already external.
 970       (dolist (sym (symbol-listify symbols))
 971         (multiple-value-bind (s w)
 972             (find-external-symbol (symbol-name sym) package)
 973           (declare (ignore s))
 974           (unless (or w (member sym syms))
 975             (push sym syms))))
 976       (with-single-package-locked-error ()
 977         (when syms
 978           (assert-package-unlocked package "exporting symbol~P ~{~A~^, ~}"
 979                                    (length syms) syms))
 980         ;; Find symbols and packages with conflicts.
 981         (let ((used-by (package-%used-by-list package)))
 982           (dolist (sym syms)
 983             (let ((name (symbol-name sym)))
 984               (dolist (p used-by)
 985                 (multiple-value-bind (s w) (find-symbol name p)
 986                   (when (and w
 987                              (not (eq s sym))
 988                              (not (member s (package-%shadowing-symbols p))))
 989                     ;; Beware: the name conflict is in package P, not in
 990                     ;; PACKAGE.
 991                     (name-conflict p 'export sym sym s)))))))
 992         ;; Check that all symbols are accessible. If not, ask to import them.
 993         (let ((missing ())
 994               (imports ()))
 995           (dolist (sym syms)
 996             (multiple-value-bind (s w) (find-symbol (symbol-name sym) package)
 997               (cond ((not (and w (eq s sym)))
 998                      (push sym missing))
 999                     ((eq w :inherited)
1000                      (push sym imports)))))
1001           (when missing
1002             (cerror
1003              "~S these symbols into the ~A package."
1004              (make-condition
1005               'simple-package-error
1006               :package package
1007               :format-control
1008               "~@<These symbols are not accessible in the ~A package:~2I~_~S~@:>"
1009               :format-arguments (list (package-%name package) missing))
1010              'import (package-%name package))
1011             (import missing package))
1012           (import imports package))
1013
1014         ;; And now, three pages later, we export the suckers.
1015         (let ((internal (package-internal-symbols package))
1016               (external (package-external-symbols package)))
1017           (dolist (sym syms)
1018             (nuke-symbol internal (symbol-name sym))
1019             (add-symbol external sym))))
1020       t)))
1021 \f
1022 ;;; Check that all symbols are accessible, then move from external to internal.
1023 (defun unexport (symbols &optional (package (sane-package)))
1024   #!+sb-doc
1025   "Makes SYMBOLS no longer exported from PACKAGE."
1026   (with-packages ()
1027     (let ((package (find-undeleted-package-or-lose package))
1028           (syms ()))
1029       (dolist (sym (symbol-listify symbols))
1030         (multiple-value-bind (s w) (find-symbol (symbol-name sym) package)
1031           (cond ((or (not w) (not (eq s sym)))
1032                  (error 'simple-package-error
1033                         :package package
1034                         :format-control "~S is not accessible in the ~A package."
1035                         :format-arguments (list sym (package-%name package))))
1036                 ((eq w :external) (pushnew sym syms)))))
1037       (with-single-package-locked-error ()
1038         (when syms
1039           (assert-package-unlocked package "unexporting symbol~P ~{~A~^, ~}"
1040                                    (length syms) syms))
1041         (let ((internal (package-internal-symbols package))
1042               (external (package-external-symbols package)))
1043           (dolist (sym syms)
1044             (add-symbol internal sym)
1045             (nuke-symbol external (symbol-name sym)))))
1046       t)))
1047 \f
1048 ;;; Check for name conflict caused by the import and let the user
1049 ;;; shadowing-import if there is.
1050 (defun import (symbols &optional (package (sane-package)))
1051   #!+sb-doc
1052   "Make SYMBOLS accessible as internal symbols in PACKAGE. If a symbol is
1053 already accessible then it has no effect. If a name conflict would result from
1054 the importation, then a correctable error is signalled."
1055   (with-packages ()
1056     (let* ((package (find-undeleted-package-or-lose package))
1057            (symbols (symbol-listify symbols))
1058            (homeless (remove-if #'symbol-package symbols))
1059            (syms ()))
1060       (with-single-package-locked-error ()
1061         (dolist (sym symbols)
1062           (multiple-value-bind (s w) (find-symbol (symbol-name sym) package)
1063             (cond ((not w)
1064                    (let ((found (member sym syms :test #'string=)))
1065                      (if found
1066                          (when (not (eq (car found) sym))
1067                            (name-conflict package 'import sym sym (car found)))
1068                          (push sym syms))))
1069                   ((not (eq s sym))
1070                    (name-conflict package 'import sym sym s))
1071                   ((eq w :inherited) (push sym syms)))))
1072         (when (or homeless syms)
1073           (let ((union (delete-duplicates (append homeless syms))))
1074             (assert-package-unlocked package "importing symbol~P ~{~A~^, ~}"
1075                                      (length union) union)))
1076         ;; Add the new symbols to the internal hashtable.
1077         (let ((internal (package-internal-symbols package)))
1078           (dolist (sym syms)
1079             (add-symbol internal sym)))
1080         ;; If any of the symbols are uninterned, make them be owned by PACKAGE.
1081         (dolist (sym homeless)
1082           (%set-symbol-package sym package))
1083         t))))
1084 \f
1085 ;;; If a conflicting symbol is present, unintern it, otherwise just
1086 ;;; stick the symbol in.
1087 (defun shadowing-import (symbols &optional (package (sane-package)))
1088   #!+sb-doc
1089   "Import SYMBOLS into package, disregarding any name conflict. If
1090   a symbol of the same name is present, then it is uninterned."
1091   (with-packages ()
1092     (let* ((package (find-undeleted-package-or-lose package))
1093            (internal (package-internal-symbols package))
1094            (symbols (symbol-listify symbols))
1095            (lock-asserted-p nil))
1096       (with-single-package-locked-error ()
1097         (dolist (sym symbols)
1098           (multiple-value-bind (s w) (find-symbol (symbol-name sym) package)
1099             (unless (or lock-asserted-p
1100                         (and (eq s sym)
1101                              (member s (package-shadowing-symbols package))))
1102               (assert-package-unlocked package "shadowing-importing symbol~P ~
1103                                            ~{~A~^, ~}" (length symbols) symbols)
1104               (setf lock-asserted-p t))
1105             (unless (and w (not (eq w :inherited)) (eq s sym))
1106               (when (or (eq w :internal) (eq w :external))
1107                 ;; If it was shadowed, we don't want UNINTERN to flame out...
1108                 (setf (package-%shadowing-symbols package)
1109                       (remove s (the list (package-%shadowing-symbols package))))
1110                 (unintern s package))
1111               (add-symbol internal sym))
1112             (pushnew sym (package-%shadowing-symbols package)))))))
1113   t)
1114
1115 (defun shadow (symbols &optional (package (sane-package)))
1116   #!+sb-doc
1117   "Make an internal symbol in PACKAGE with the same name as each of the
1118 specified SYMBOLS. If a symbol with the given name is already present in
1119 PACKAGE, then the existing symbol is placed in the shadowing symbols list if
1120 it is not already present."
1121   (with-packages ()
1122     (let* ((package (find-undeleted-package-or-lose package))
1123            (internal (package-internal-symbols package))
1124            (symbols (string-listify symbols))
1125            (lock-asserted-p nil))
1126       (flet ((present-p (w)
1127                (and w (not (eq w :inherited)))))
1128         (with-single-package-locked-error ()
1129           (dolist (name symbols)
1130             (multiple-value-bind (s w) (find-symbol name package)
1131               (unless (or lock-asserted-p
1132                           (and (present-p w)
1133                                (member s (package-shadowing-symbols package))))
1134                 (assert-package-unlocked package "shadowing symbol~P ~{~A~^, ~}"
1135                                          (length symbols) symbols)
1136                 (setf lock-asserted-p t))
1137               (unless (present-p w)
1138                 (setq s (make-symbol name))
1139                 (%set-symbol-package s package)
1140                 (add-symbol internal s))
1141               (pushnew s (package-%shadowing-symbols package))))))))
1142   t)
1143 \f
1144 ;;; Do stuff to use a package, with all kinds of fun name-conflict checking.
1145 (defun use-package (packages-to-use &optional (package (sane-package)))
1146   #!+sb-doc
1147   "Add all the PACKAGES-TO-USE to the use list for PACKAGE so that the
1148 external symbols of the used packages are accessible as internal symbols in
1149 PACKAGE."
1150   (with-packages ()
1151     (let ((packages (package-listify packages-to-use))
1152           (package (find-undeleted-package-or-lose package)))
1153
1154       ;; Loop over each package, USE'ing one at a time...
1155       (with-single-package-locked-error ()
1156         (dolist (pkg packages)
1157           (unless (member pkg (package-%use-list package))
1158             (assert-package-unlocked package "using package~P ~{~A~^, ~}"
1159                                      (length packages) packages)
1160             (let ((shadowing-symbols (package-%shadowing-symbols package))
1161                   (use-list (package-%use-list package)))
1162
1163               ;; If the number of symbols already accessible is less
1164               ;; than the number to be inherited then it is faster to
1165               ;; run the test the other way. This is particularly
1166               ;; valuable in the case of a new package USEing
1167               ;; COMMON-LISP.
1168               (cond
1169                 ((< (+ (package-internal-symbol-count package)
1170                        (package-external-symbol-count package)
1171                        (let ((res 0))
1172                          (dolist (p use-list res)
1173                            (incf res (package-external-symbol-count p)))))
1174                     (package-external-symbol-count pkg))
1175                  (do-symbols (sym package)
1176                    (multiple-value-bind (s w)
1177                        (find-external-symbol (symbol-name sym) pkg)
1178                      (when (and w
1179                                 (not (eq s sym))
1180                                 (not (member sym shadowing-symbols)))
1181                        (name-conflict package 'use-package pkg sym s))))
1182                  (dolist (p use-list)
1183                    (do-external-symbols (sym p)
1184                      (multiple-value-bind (s w)
1185                          (find-external-symbol (symbol-name sym) pkg)
1186                        (when (and w
1187                                   (not (eq s sym))
1188                                   (not (member
1189                                         (find-symbol (symbol-name sym) package)
1190                                         shadowing-symbols)))
1191                          (name-conflict package 'use-package pkg sym s))))))
1192                 (t
1193                  (do-external-symbols (sym pkg)
1194                    (multiple-value-bind (s w)
1195                        (find-symbol (symbol-name sym) package)
1196                      (when (and w
1197                                 (not (eq s sym))
1198                                 (not (member s shadowing-symbols)))
1199                        (name-conflict package 'use-package pkg sym s)))))))
1200
1201             (push pkg (package-%use-list package))
1202             (push (package-external-symbols pkg) (cdr (package-tables package)))
1203             (push package (package-%used-by-list pkg)))))))
1204   t)
1205
1206 (defun unuse-package (packages-to-unuse &optional (package (sane-package)))
1207   #!+sb-doc
1208   "Remove PACKAGES-TO-UNUSE from the USE list for PACKAGE."
1209   (with-packages ()
1210     (let ((package (find-undeleted-package-or-lose package))
1211           (packages (package-listify packages-to-unuse)))
1212       (with-single-package-locked-error ()
1213         (dolist (p packages)
1214           (when (member p (package-use-list package))
1215             (assert-package-unlocked package "unusing package~P ~{~A~^, ~}"
1216                                      (length packages) packages))
1217           (setf (package-%use-list package)
1218                 (remove p (the list (package-%use-list package))))
1219           (setf (package-tables package)
1220                 (delete (package-external-symbols p)
1221                         (the list (package-tables package))))
1222           (setf (package-%used-by-list p)
1223                 (remove package (the list (package-%used-by-list p))))))
1224       t)))
1225
1226 (defun find-all-symbols (string-or-symbol)
1227   #!+sb-doc
1228   "Return a list of all symbols in the system having the specified name."
1229   (let ((string (string string-or-symbol))
1230         (res ()))
1231     (with-packages ()
1232       (maphash (lambda (k v)
1233                  (declare (ignore k))
1234                  (multiple-value-bind (s w) (find-symbol string v)
1235                    (when w (pushnew s res))))
1236                *package-names*))
1237     res))
1238 \f
1239 ;;;; APROPOS and APROPOS-LIST
1240
1241 (defun briefly-describe-symbol (symbol)
1242   (fresh-line)
1243   (prin1 symbol)
1244   (when (boundp symbol)
1245     (write-string " (bound)"))
1246   (when (fboundp symbol)
1247     (write-string " (fbound)")))
1248
1249 (defun apropos-list (string-designator
1250                      &optional
1251                      package-designator
1252                      external-only)
1253   #!+sb-doc
1254   "Like APROPOS, except that it returns a list of the symbols found instead
1255   of describing them."
1256   (if package-designator
1257       (let ((package (find-undeleted-package-or-lose package-designator))
1258             (string (stringify-string-designator string-designator))
1259             (result nil))
1260         (do-symbols (symbol package)
1261           (when (and (eq (symbol-package symbol) package)
1262                      (or (not external-only)
1263                          (eq (nth-value 1 (find-symbol (symbol-name symbol)
1264                                                        package))
1265                              :external))
1266                      (search string (symbol-name symbol) :test #'char-equal))
1267             (push symbol result)))
1268         (sort result #'string-lessp))
1269       (mapcan (lambda (package)
1270                 (apropos-list string-designator package external-only))
1271               (sort (list-all-packages) #'string-lessp :key #'package-name))))
1272
1273 (defun apropos (string-designator &optional package external-only)
1274   #!+sb-doc
1275   "Briefly describe all symbols which contain the specified STRING.
1276   If PACKAGE is supplied then only describe symbols present in
1277   that package. If EXTERNAL-ONLY then only describe
1278   external symbols in the specified package."
1279   ;; Implementing this in terms of APROPOS-LIST keeps things simple at the cost
1280   ;; of some unnecessary consing; and the unnecessary consing shouldn't be an
1281   ;; issue, since this function is is only useful interactively anyway, and
1282   ;; we can cons and GC a lot faster than the typical user can read..
1283   (dolist (symbol (apropos-list string-designator package external-only))
1284     (briefly-describe-symbol symbol))
1285   (values))
1286 \f
1287 ;;;; final initialization
1288
1289 ;;;; The cold loader (GENESIS) makes the data structure in
1290 ;;;; *!INITIAL-SYMBOLS*. We grovel over it, making the specified
1291 ;;;; packages and interning the symbols. For a description of the
1292 ;;;; format of *!INITIAL-SYMBOLS*, see the GENESIS source.
1293
1294 (defvar *!initial-symbols*)
1295
1296 (!cold-init-forms
1297
1298   (setq *in-package-init* t)
1299
1300   (/show0 "about to loop over *!INITIAL-SYMBOLS* to make packages")
1301   (dolist (spec *!initial-symbols*)
1302     (let* ((pkg (apply #'make-package (first spec)))
1303            (internal (package-internal-symbols pkg))
1304            (external (package-external-symbols pkg)))
1305       (/show0 "back from MAKE-PACKAGE, PACKAGE-NAME=..")
1306       (/primitive-print (package-name pkg))
1307
1308       ;; Put internal symbols in the internal hashtable and set package.
1309       (dolist (symbol (second spec))
1310         (add-symbol internal symbol)
1311         (%set-symbol-package symbol pkg))
1312
1313       ;; External symbols same, only go in external table.
1314       (dolist (symbol (third spec))
1315         (add-symbol external symbol)
1316         (%set-symbol-package symbol pkg))
1317
1318       ;; Don't set package for imported symbols.
1319       (dolist (symbol (fourth spec))
1320         (add-symbol internal symbol))
1321       (dolist (symbol (fifth spec))
1322         (add-symbol external symbol))
1323
1324       ;; Put shadowing symbols in the shadowing symbols list.
1325       (setf (package-%shadowing-symbols pkg) (sixth spec))
1326       ;; Set the package documentation
1327       (setf (package-doc-string pkg) (seventh spec))))
1328
1329   ;; FIXME: These assignments are also done at toplevel in
1330   ;; boot-extensions.lisp. They should probably only be done once.
1331   (/show0 "setting up *CL-PACKAGE* and *KEYWORD-PACKAGE*")
1332   (setq *cl-package* (find-package "COMMON-LISP"))
1333   (setq *keyword-package* (find-package "KEYWORD"))
1334
1335   (/show0 "about to MAKUNBOUND *!INITIAL-SYMBOLS*")
1336   (%makunbound '*!initial-symbols*)       ; (so that it gets GCed)
1337
1338   ;; Make some other packages that should be around in the cold load.
1339   ;; The COMMON-LISP-USER package is required by the ANSI standard,
1340   ;; but not completely specified by it, so in the cross-compilation
1341   ;; host Lisp it could contain various symbols, USE-PACKAGEs, or
1342   ;; nicknames that we don't want in our target SBCL. For that reason,
1343   ;; we handle it specially, not dumping the host Lisp version at
1344   ;; genesis time..
1345   (aver (not (find-package "COMMON-LISP-USER")))
1346   ;; ..but instead making our own from scratch here.
1347   (/show0 "about to MAKE-PACKAGE COMMON-LISP-USER")
1348   (make-package "COMMON-LISP-USER"
1349                 :nicknames '("CL-USER")
1350                 :use '("COMMON-LISP"
1351                        ;; ANSI encourages us to put extension packages
1352                        ;; in the USE list of COMMON-LISP-USER.
1353                        "SB!ALIEN" "SB!ALIEN" "SB!DEBUG"
1354                        "SB!EXT" "SB!GRAY" "SB!PROFILE"))
1355
1356   ;; Now do the *!DEFERRED-USE-PACKAGES*.
1357   (/show0 "about to do *!DEFERRED-USE-PACKAGES*")
1358   (dolist (args *!deferred-use-packages*)
1359     (apply #'use-package args))
1360
1361   ;; The Age Of Magic is over, we can behave ANSIly henceforth.
1362   (/show0 "about to SETQ *IN-PACKAGE-INIT*")
1363   (setq *in-package-init* nil)
1364
1365   ;; For the kernel core image wizards, set the package to *CL-PACKAGE*.
1366   ;;
1367   ;; FIXME: We should just set this to (FIND-PACKAGE
1368   ;; "COMMON-LISP-USER") once and for all here, instead of setting it
1369   ;; once here and resetting it later.
1370   (setq *package* *cl-package*))
1371 \f
1372 (!cold-init-forms
1373   (/show0 "done with !PACKAGE-COLD-INIT"))
1374
1375 (!defun-from-collected-cold-init-forms !package-cold-init)