src/code/target-package.lisp

   1 ;;;; PACKAGEs and stuff like that
   2 ;;;;
   3 ;;;; Note: The code in this file signals many correctable errors. This
   4 ;;;; is not just an arbitrary aesthetic decision on the part of the
   5 ;;;; implementor -- many of these are specified by ANSI 11.1.1.2.5,
   6 ;;;; "Prevention of Name Conflicts in Packages":
   7 ;;;;   Within one package, any particular name can refer to at most one
   8 ;;;;   symbol. A name conflict is said to occur when there would be more
   9 ;;;;   than one candidate symbol. Any time a name conflict is about to
  10 ;;;;   occur, a correctable error is signaled.
  11 ;;;;
  12 ;;;; FIXME: The code contains a lot of type declarations. Are they
  13 ;;;; all really necessary?
  14
  15 ;;;; This software is part of the SBCL system. See the README file for
  16 ;;;; more information.
  17 ;;;;
  18 ;;;; This software is derived from the CMU CL system, which was
  19 ;;;; written at Carnegie Mellon University and released into the
  20 ;;;; public domain. The software is in the public domain and is
  21 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  22 ;;;; files for more information.
  23
  24 (in-package "SB!IMPL")
  25
  26 (!begin-collecting-cold-init-forms)
  27
  28 (!cold-init-forms
  29   (/show0 "entering !PACKAGE-COLD-INIT"))
  30 \f
  31 ;;;; Thread safety
  32 ;;;;
  33 ;;;; ...this could still use work, but the basic idea is:
  34 ;;;;
  35 ;;;; *PACKAGE-GRAPH-LOCK* is held via WITH-PACKAGE-GRAPH while working on
  36 ;;;; package graph, including package -> package links, and interning and
  37 ;;;; uninterning symbols.
  38 ;;;;
  39 ;;;; Hash-table lock on *PACKAGE-NAMES* is held via WITH-PACKAGE-NAMES while
  40 ;;;; frobbing name -> package associations.
  41 ;;;;
  42 ;;;; There should be no deadlocks due to ordering issues between these two, as
  43 ;;;; the latter is only held over operations guaranteed to terminate in finite
  44 ;;;; time.
  45 ;;;;
  46 ;;;; Errors may be signalled while holding on to the *PACKAGE-GRAPH-LOCK*,
  47 ;;;; which can still lead to pretty damned inconvenient situations -- but
  48 ;;;; since FIND-PACKAGE, FIND-SYMBOL from other threads isn't blocked by this,
  49 ;;;; the situation isn't *quite* hopeless.
  50 ;;;;
  51 ;;;; A better long-term solution seems to be in splitting the granularity of
  52 ;;;; the *PACKAGE-GRAPH-LOCK* down: for interning a per-package lock should be
  53 ;;;; sufficient, though interaction between parallel intern and use-package
  54 ;;;; needs to be considered with some care.
  55
  56 (defvar *package-graph-lock*)
  57 (!cold-init-forms
  58  (setf *package-graph-lock* (sb!thread:make-mutex :name "Package Graph Lock")))
  59
  60 (defun call-with-package-graph (function)
  61   (declare (function function))
  62   ;; FIXME: Since name conflicts can be signalled while holding the
  63   ;; mutex, user code can be run leading to lock ordering problems.
  64   (sb!thread:with-recursive-lock (*package-graph-lock*)
  65     (funcall function)))
  66
  67 ;;; a map from package names to packages
  68 (defvar *package-names*)
  69 (declaim (type hash-table *package-names*))
  70 (!cold-init-forms
  71  (setf *package-names* (make-hash-table :test 'equal :synchronized t)))
  72
  73 (defmacro with-package-names ((names &key) &body body)
  74   `(let ((,names *package-names*))
  75      (with-locked-system-table (,names)
  76        ,@body)))
  77 \f
  78 ;;;; PACKAGE-HASHTABLE stuff
  79
  80 (def!method print-object ((table package-hashtable) stream)
  81   (declare (type stream stream))
  82   (print-unreadable-object (table stream :type t)
  83     (format stream
  84             ":SIZE ~S :FREE ~S :DELETED ~S"
  85             (package-hashtable-size table)
  86             (package-hashtable-free table)
  87             (package-hashtable-deleted table))))
  88
  89 ;;; the maximum load factor we allow in a package hashtable
  90 (defconstant +package-rehash-threshold+ 0.75)
  91
  92 ;;; the load factor desired for a package hashtable when writing a
  93 ;;; core image
  94 (defconstant +package-hashtable-image-load-factor+ 0.5)
  95
  96 ;;; Make a package hashtable having a prime number of entries at least
  97 ;;; as great as (/ SIZE +PACKAGE-REHASH-THRESHOLD+). If RES is supplied,
  98 ;;; then it is destructively modified to produce the result. This is
  99 ;;; useful when changing the size, since there are many pointers to
 100 ;;; the hashtable.
 101 ;;; Actually, the smallest table built here has three entries. This
 102 ;;; is necessary because the double hashing step size is calculated
 103 ;;; using a division by the table size minus two.
 104 (defun make-or-remake-package-hashtable (size
 105                                          &optional
 106                                          res)
 107   (flet ((actual-package-hashtable-size (size)
 108            (loop for n of-type fixnum
 109               from (logior (ceiling size +package-rehash-threshold+) 1)
 110               by 2
 111               when (positive-primep n) return n)))
 112     (let* ((n (actual-package-hashtable-size size))
 113            (size (truncate (* n +package-rehash-threshold+)))
 114            (table (make-array n))
 115            (hash (make-array n
 116                              :element-type '(unsigned-byte 8)
 117                              :initial-element 0)))
 118       (if res
 119           (setf (package-hashtable-table res) table
 120                 (package-hashtable-hash res) hash
 121                 (package-hashtable-size res) size
 122                 (package-hashtable-free res) size
 123                 (package-hashtable-deleted res) 0)
 124           (setf res (%make-package-hashtable table hash size)))
 125       res)))
 126
 127 ;;; Destructively resize TABLE to have room for at least SIZE entries
 128 ;;; and rehash its existing entries.
 129 (defun resize-package-hashtable (table size)
 130   (let* ((vec (package-hashtable-table table))
 131          (hash (package-hashtable-hash table))
 132          (len (length vec)))
 133     (make-or-remake-package-hashtable size table)
 134     (dotimes (i len)
 135       (when (> (aref hash i) 1)
 136         (add-symbol table (svref vec i))))))
 137 \f
 138 ;;;; package locking operations, built conditionally on :sb-package-locks
 139
 140 #!+sb-package-locks
 141 (progn
 142 (defun package-locked-p (package)
 143   #!+sb-doc
 144   "Returns T when PACKAGE is locked, NIL otherwise. Signals an error
 145 if PACKAGE doesn't designate a valid package."
 146   (package-lock (find-undeleted-package-or-lose package)))
 147
 148 (defun lock-package (package)
 149   #!+sb-doc
 150   "Locks PACKAGE and returns T. Has no effect if PACKAGE was already
 151 locked. Signals an error if PACKAGE is not a valid package designator"
 152   (setf (package-lock (find-undeleted-package-or-lose package)) t))
 153
 154 (defun unlock-package (package)
 155   #!+sb-doc
 156   "Unlocks PACKAGE and returns T. Has no effect if PACKAGE was already
 157 unlocked. Signals an error if PACKAGE is not a valid package designator."
 158   (setf (package-lock (find-undeleted-package-or-lose package)) nil)
 159   t)
 160
 161 (defun package-implemented-by-list (package)
 162   #!+sb-doc
 163   "Returns a list containing the implementation packages of
 164 PACKAGE. Signals an error if PACKAGE is not a valid package designator."
 165   (package-%implementation-packages (find-undeleted-package-or-lose package)))
 166
 167 (defun package-implements-list (package)
 168   #!+sb-doc
 169   "Returns the packages that PACKAGE is an implementation package
 170 of. Signals an error if PACKAGE is not a valid package designator."
 171   (let ((package (find-undeleted-package-or-lose package)))
 172     (loop for x in (list-all-packages)
 173           when (member package (package-%implementation-packages x))
 174           collect x)))
 175
 176 (defun add-implementation-package (packages-to-add
 177                                    &optional (package *package*))
 178   #!+sb-doc
 179   "Adds PACKAGES-TO-ADD as implementation packages of PACKAGE. Signals
 180 an error if PACKAGE or any of the PACKAGES-TO-ADD is not a valid
 181 package designator."
 182   (let ((package (find-undeleted-package-or-lose package))
 183         (packages-to-add (package-listify packages-to-add)))
 184     (setf (package-%implementation-packages package)
 185           (union (package-%implementation-packages package)
 186                  (mapcar #'find-undeleted-package-or-lose packages-to-add)))))
 187
 188 (defun remove-implementation-package (packages-to-remove
 189                                       &optional (package *package*))
 190   #!+sb-doc
 191   "Removes PACKAGES-TO-REMOVE from the implementation packages of
 192 PACKAGE. Signals an error if PACKAGE or any of the PACKAGES-TO-REMOVE
 193 is not a valid package designator."
 194   (let ((package (find-undeleted-package-or-lose package))
 195         (packages-to-remove (package-listify packages-to-remove)))
 196     (setf (package-%implementation-packages package)
 197           (nset-difference
 198            (package-%implementation-packages package)
 199            (mapcar #'find-undeleted-package-or-lose packages-to-remove)))))
 200
 201 (defmacro with-unlocked-packages ((&rest packages) &body forms)
 202   #!+sb-doc
 203   "Unlocks PACKAGES for the dynamic scope of the body. Signals an
 204 error if any of PACKAGES is not a valid package designator."
 205   (with-unique-names (unlocked-packages)
 206     `(let (,unlocked-packages)
 207       (unwind-protect
 208            (progn
 209              (dolist (p ',packages)
 210                (when (package-locked-p p)
 211                  (push p ,unlocked-packages)
 212                  (unlock-package p)))
 213              ,@forms)
 214         (dolist (p ,unlocked-packages)
 215           (when (find-package p)
 216             (lock-package p)))))))
 217
 218 (defun package-lock-violation (package &key (symbol nil symbol-p)
 219                                format-control format-arguments)
 220   (let* ((restart :continue)
 221          (cl-violation-p (eq package *cl-package*))
 222          (error-arguments
 223           (append (list (if symbol-p
 224                             'symbol-package-locked-error
 225                             'package-locked-error)
 226                         :package package
 227                         :format-control format-control
 228                         :format-arguments format-arguments)
 229                   (when symbol-p (list :symbol symbol))
 230                   (list :references
 231                         (append '((:sbcl :node "Package Locks"))
 232                                 (when cl-violation-p
 233                                   '((:ansi-cl :section (11 1 2 1 2)))))))))
 234     (restart-case
 235         (apply #'cerror "Ignore the package lock." error-arguments)
 236       (:ignore-all ()
 237         :report "Ignore all package locks in the context of this operation."
 238         (setf restart :ignore-all))
 239       (:unlock-package ()
 240         :report "Unlock the package."
 241         (setf restart :unlock-package)))
 242     (ecase restart
 243       (:continue
 244        (pushnew package *ignored-package-locks*))
 245       (:ignore-all
 246        (setf *ignored-package-locks* t))
 247       (:unlock-package
 248        (unlock-package package)))))
 249
 250 (defun package-lock-violation-p (package &optional (symbol nil symbolp))
 251   ;; KLUDGE: (package-lock package) needs to be before
 252   ;; comparison to *package*, since during cold init this gets
 253   ;; called before *package* is bound -- but no package should
 254   ;; be locked at that point.
 255   (and package
 256        (package-lock package)
 257        ;; In package or implementation package
 258        (not (or (eq package *package*)
 259                 (member *package* (package-%implementation-packages package))))
 260        ;; Runtime disabling
 261        (not (eq t *ignored-package-locks*))
 262        (or (eq :invalid *ignored-package-locks*)
 263            (not (member package *ignored-package-locks*)))
 264        ;; declarations for symbols
 265        (not (and symbolp (member symbol (disabled-package-locks))))))
 266
 267 (defun disabled-package-locks ()
 268   (if (boundp 'sb!c::*lexenv*)
 269       (sb!c::lexenv-disabled-package-locks sb!c::*lexenv*)
 270       sb!c::*disabled-package-locks*))
 271
 272 ) ; progn
 273
 274 ;;;; more package-locking these are NOPs unless :sb-package-locks is
 275 ;;;; in target features. Cross-compiler NOPs for these are in cross-misc.
 276
 277 ;;; The right way to establish a package lock context is
 278 ;;; WITH-SINGLE-PACKAGE-LOCKED-ERROR, defined in early-package.lisp
 279 ;;;
 280 ;;; Must be used inside the dynamic contour established by
 281 ;;; WITH-SINGLE-PACKAGE-LOCKED-ERROR
 282 (defun assert-package-unlocked (package &optional format-control
 283                                 &rest format-arguments)
 284   #!-sb-package-locks
 285   (declare (ignore format-control format-arguments))
 286   #!+sb-package-locks
 287   (when (package-lock-violation-p package)
 288     (package-lock-violation package
 289                             :format-control format-control
 290                             :format-arguments format-arguments))
 291   package)
 292
 293 ;;; Must be used inside the dynamic contour established by
 294 ;;; WITH-SINGLE-PACKAGE-LOCKED-ERROR.
 295 ;;;
 296 ;;; FIXME: Maybe we should establish such contours for he toplevel
 297 ;;; and others, so that %set-fdefinition and others could just use
 298 ;;; this.
 299 (defun assert-symbol-home-package-unlocked (name format)
 300   #!-sb-package-locks
 301   (declare (ignore format))
 302   #!+sb-package-locks
 303   (let* ((symbol (etypecase name
 304                    (symbol name)
 305                    (list (if (and (consp (cdr name))
 306                                   (eq 'setf (first name)))
 307                              (second name)
 308                              ;; Skip lists of length 1, single conses and
 309                              ;; (class-predicate foo), etc.
 310                              ;; FIXME: MOP and package-lock
 311                              ;; interaction needs to be thought about.
 312                              (return-from
 313                               assert-symbol-home-package-unlocked
 314                                name)))))
 315          (package (symbol-package symbol)))
 316     (when (package-lock-violation-p package symbol)
 317       (package-lock-violation package
 318                               :symbol symbol
 319                               :format-control format
 320                               :format-arguments (list name))))
 321   name)
 322
 323 \f
 324 ;;;; miscellaneous PACKAGE operations
 325
 326 (def!method print-object ((package package) stream)
 327   (let ((name (package-%name package)))
 328     (if name
 329         (print-unreadable-object (package stream :type t)
 330           (prin1 name stream))
 331         (print-unreadable-object (package stream :type t :identity t)
 332           (write-string "(deleted)" stream)))))
 333
 334 ;;; ANSI says (in the definition of DELETE-PACKAGE) that these, and
 335 ;;; most other operations, are unspecified for deleted packages. We
 336 ;;; just do the easy thing and signal errors in that case.
 337 (macrolet ((def (ext real)
 338              `(defun ,ext (package-designator)
 339                 (,real (find-undeleted-package-or-lose package-designator)))))
 340   (def package-nicknames package-%nicknames)
 341   (def package-use-list package-%use-list)
 342   (def package-used-by-list package-%used-by-list)
 343   (def package-shadowing-symbols package-%shadowing-symbols))
 344
 345 (defun %package-hashtable-symbol-count (table)
 346   (let ((size (the fixnum
 347                 (- (package-hashtable-size table)
 348                    (package-hashtable-deleted table)))))
 349     (the fixnum
 350       (- size (package-hashtable-free table)))))
 351
 352 (defun package-internal-symbol-count (package)
 353   (%package-hashtable-symbol-count (package-internal-symbols package)))
 354
 355 (defun package-external-symbol-count (package)
 356   (%package-hashtable-symbol-count (package-external-symbols package)))
 357 \f
 358 (defvar *package* (error "*PACKAGE* should be initialized in cold load!")
 359   #!+sb-doc "the current package")
 360 ;;; FIXME: should be declared of type PACKAGE, with no NIL init form,
 361 ;;; after I get around to cleaning up DOCUMENTATION
 362
 363 ;;; This magical variable is T during initialization so that
 364 ;;; USE-PACKAGE's of packages that don't yet exist quietly win. Such
 365 ;;; packages are thrown onto the list *DEFERRED-USE-PACKAGES* so that
 366 ;;; this can be fixed up later.
 367 ;;;
 368 ;;; FIXME: This could be cleaned up the same way I do it in my package
 369 ;;; hacking when setting up the cross-compiler. Then we wouldn't have
 370 ;;; this extraneous global variable and annoying runtime tests on
 371 ;;; package operations. (*DEFERRED-USE-PACKAGES* would also go away.)
 372 (defvar *in-package-init*)
 373
 374 ;;; pending USE-PACKAGE arguments saved up while *IN-PACKAGE-INIT* is true
 375 (defvar *!deferred-use-packages*)
 376 (!cold-init-forms
 377   (setf *!deferred-use-packages* nil))
 378
 379 (define-condition bootstrap-package-not-found (condition)
 380   ((name :initarg :name :reader bootstrap-package-name)))
 381 (defun debootstrap-package (&optional condition)
 382   (invoke-restart
 383    (find-restart-or-control-error 'debootstrap-package condition)))
 384
 385 (defun find-package (package-designator)
 386   (flet ((find-package-from-string (string)
 387            (declare (type string string))
 388            (let ((packageoid (gethash string *package-names*)))
 389              (when (and (null packageoid)
 390                         (not *in-package-init*) ; KLUDGE
 391                         (let ((mismatch (mismatch "SB!" string)))
 392                           (and mismatch (= mismatch 3))))
 393                (restart-case
 394                    (signal 'bootstrap-package-not-found :name string)
 395                  (debootstrap-package ()
 396                    (return-from find-package
 397                      (if (string= string "SB!XC")
 398                          (find-package "COMMON-LISP")
 399                          (find-package
 400                           (substitute #\- #\! string :count 1)))))))
 401              packageoid)))
 402     (typecase package-designator
 403       (package package-designator)
 404       (symbol (find-package-from-string (symbol-name package-designator)))
 405       (string (find-package-from-string package-designator))
 406       (character (find-package-from-string (string package-designator)))
 407       (t (error 'type-error
 408                 :datum package-designator
 409                 :expected-type '(or character package string symbol))))))
 410
 411 ;;; Return a list of packages given a package designator or list of
 412 ;;; package designators, or die trying.
 413 (defun package-listify (thing)
 414   (let ((res ()))
 415     (dolist (thing (if (listp thing) thing (list thing)) res)
 416       (push (find-undeleted-package-or-lose thing) res))))
 417
 418 ;;; Make a package name into a simple-string.
 419 (defun package-namify (n)
 420   (stringify-package-designator n))
 421
 422 ;;; ANSI specifies (in the definition of DELETE-PACKAGE) that PACKAGE-NAME
 423 ;;; returns NIL (not an error) for a deleted package, so this is a special
 424 ;;; case where we want to use bare %FIND-PACKAGE-OR-LOSE instead of
 425 ;;; FIND-UNDELETED-PACKAGE-OR-LOSE.
 426 (defun package-name (package-designator)
 427   (package-%name (%find-package-or-lose package-designator)))
 428 \f
 429 ;;;; operations on package hashtables
 430
 431 ;;; Compute a number from the sxhash of the pname and the length which
 432 ;;; must be between 2 and 255.
 433 (defmacro entry-hash (length sxhash)
 434   `(the fixnum
 435         (+ (the fixnum
 436                 (rem (the fixnum
 437                           (logxor ,length
 438                                   ,sxhash
 439                                   (the fixnum (ash ,sxhash -8))
 440                                   (the fixnum (ash ,sxhash -16))
 441                                   (the fixnum (ash ,sxhash -19))))
 442                      254))
 443            2)))
 444 ;;; FIXME: should be wrapped in EVAL-WHEN (COMPILE EXECUTE)
 445
 446 ;;; Add a symbol to a package hashtable. The symbol is assumed
 447 ;;; not to be present.
 448 (defun add-symbol (table symbol)
 449   (when (zerop (package-hashtable-free table))
 450     ;; The hashtable is full. Resize it to be able to hold twice the
 451     ;; amount of symbols than it currently contains. The actual new size
 452     ;; can be smaller than twice the current size if the table contained
 453     ;; deleted entries.
 454     (resize-package-hashtable table
 455                               (* (- (package-hashtable-size table)
 456                                     (package-hashtable-deleted table))
 457                                  2)))
 458   (let* ((vec (package-hashtable-table table))
 459          (hash (package-hashtable-hash table))
 460          (len (length vec))
 461          (sxhash (%sxhash-simple-string (symbol-name symbol)))
 462          (h2 (1+ (rem sxhash (- len 2)))))
 463     (declare (fixnum sxhash h2))
 464     (do ((i (rem sxhash len) (rem (+ i h2) len)))
 465         ((< (the fixnum (aref hash i)) 2)
 466          (if (zerop (the fixnum (aref hash i)))
 467              (decf (package-hashtable-free table))
 468              (decf (package-hashtable-deleted table)))
 469          (setf (svref vec i) symbol)
 470          (setf (aref hash i)
 471                (entry-hash (length (symbol-name symbol))
 472                            sxhash)))
 473       (declare (fixnum i)))))
 474
 475 ;;; Resize the package hashtables of all packages so that their load
 476 ;;; factor is +PACKAGE-HASHTABLE-IMAGE-LOAD-FACTOR+. Called from
 477 ;;; SAVE-LISP-AND-DIE to optimize space usage in the image.
 478 (defun tune-hashtable-sizes-of-all-packages ()
 479   (flet ((tune-table-size (table)
 480            (resize-package-hashtable
 481             table
 482             (round (* (/ +package-rehash-threshold+
 483                          +package-hashtable-image-load-factor+)
 484                       (- (package-hashtable-size table)
 485                          (package-hashtable-free table)
 486                          (package-hashtable-deleted table)))))))
 487     (dolist (package (list-all-packages))
 488       (tune-table-size (package-internal-symbols package))
 489       (tune-table-size (package-external-symbols package)))))
 490
 491 ;;; Find where the symbol named STRING is stored in TABLE. INDEX-VAR
 492 ;;; is bound to the index, or NIL if it is not present. SYMBOL-VAR
 493 ;;; is bound to the symbol. LENGTH and HASH are the length and sxhash
 494 ;;; of STRING. ENTRY-HASH is the entry-hash of the string and length.
 495 (defmacro with-symbol ((index-var symbol-var table string length sxhash
 496                                   entry-hash)
 497                        &body forms)
 498   (let ((vec (gensym)) (hash (gensym)) (len (gensym)) (h2 (gensym))
 499         (name (gensym)) (name-len (gensym)) (ehash (gensym)))
 500     `(let* ((,vec (package-hashtable-table ,table))
 501             (,hash (package-hashtable-hash ,table))
 502             (,len (length ,vec))
 503             (,h2 (1+ (the index (rem (the hash ,sxhash)
 504                                       (the index (- ,len 2)))))))
 505        (declare (type index ,len ,h2))
 506        (prog ((,index-var (rem (the hash ,sxhash) ,len))
 507               ,symbol-var ,ehash)
 508          (declare (type (or index null) ,index-var))
 509          LOOP
 510          (setq ,ehash (aref ,hash ,index-var))
 511          (cond ((eql ,ehash ,entry-hash)
 512                 (setq ,symbol-var (svref ,vec ,index-var))
 513                 (let* ((,name (symbol-name ,symbol-var))
 514                        (,name-len (length ,name)))
 515                   (declare (type index ,name-len))
 516                   (when (and (= ,name-len ,length)
 517                              (string= ,string ,name
 518                                       :end1 ,length
 519                                       :end2 ,name-len))
 520                     (go DOIT))))
 521                ((zerop ,ehash)
 522                 (setq ,index-var nil)
 523                 (go DOIT)))
 524          (setq ,index-var (+ ,index-var ,h2))
 525          (when (>= ,index-var ,len)
 526            (setq ,index-var (- ,index-var ,len)))
 527          (go LOOP)
 528          DOIT
 529          (return (progn ,@forms))))))
 530
 531 ;;; Delete the entry for STRING in TABLE. The entry must exist.
 532 (defun nuke-symbol (table string)
 533   (declare (simple-string string))
 534   (let* ((length (length string))
 535          (hash (%sxhash-simple-string string))
 536          (ehash (entry-hash length hash)))
 537     (declare (type index length)
 538              (type hash hash))
 539     (with-symbol (index symbol table string length hash ehash)
 540       (setf (aref (package-hashtable-hash table) index) 1)
 541       (setf (aref (package-hashtable-table table) index) nil)
 542       (incf (package-hashtable-deleted table))))
 543   ;; If the table is less than one quarter full, halve its size and
 544   ;; rehash the entries.
 545   (let* ((size (package-hashtable-size table))
 546          (deleted (package-hashtable-deleted table))
 547          (used (- size
 548                   (package-hashtable-free table)
 549                   deleted)))
 550     (declare (type fixnum size deleted used))
 551     (when (< used (truncate size 4))
 552       (resize-package-hashtable table (* used 2)))))
 553 \f
 554 ;;; Enter any new NICKNAMES for PACKAGE into *PACKAGE-NAMES*. If there is a
 555 ;;; conflict then give the user a chance to do something about it. Caller is
 556 ;;; responsible for having acquired the mutex via WITH-PACKAGES.
 557 (defun %enter-new-nicknames (package nicknames)
 558   (declare (type list nicknames))
 559   (dolist (n nicknames)
 560     (let* ((n (package-namify n))
 561            (found (with-package-names (names)
 562                     (or (gethash n names)
 563                         (progn
 564                           (setf (gethash n names) package)
 565                           (push n (package-%nicknames package))
 566                           package)))))
 567       (cond ((eq found package))
 568             ((string= (the string (package-%name found)) n)
 569              (cerror "Ignore this nickname."
 570                      'simple-package-error
 571                      :package package
 572                      :format-control "~S is a package name, so it cannot be a nickname for ~S."
 573                      :format-arguments (list n (package-%name package))))
 574             (t
 575              (cerror "Leave this nickname alone."
 576                      'simple-package-error
 577                      :package package
 578                      :format-control "~S is already a nickname for ~S."
 579                      :format-arguments (list n (package-%name found))))))))
 580
 581 (defun make-package (name &key
 582                           (use '#.*default-package-use-list*)
 583                           nicknames
 584                           (internal-symbols 10)
 585                           (external-symbols 10))
 586   #!+sb-doc
 587   #.(format nil
 588      "Make a new package having the specified NAME, NICKNAMES, and USE
 589 list. :INTERNAL-SYMBOLS and :EXTERNAL-SYMBOLS are estimates for the number of
 590 internal and external symbols which will ultimately be present in the package.
 591 The default value of USE is implementation-dependent, and in this
 592 implementation it is ~S." *default-package-use-list*)
 593   (prog (clobber)
 594    :restart
 595      (when (find-package name)
 596        ;; ANSI specifies that this error is correctable.
 597        (cerror "Clobber existing package."
 598                "A package named ~S already exists" name)
 599        (setf clobber t))
 600      (with-package-graph ()
 601        ;; Check for race, signal the error outside the lock.
 602        (when (and (not clobber) (find-package name))
 603          (go :restart))
 604        (let* ((name (package-namify name))
 605               (package (internal-make-package
 606                         :%name name
 607                         :internal-symbols (make-or-remake-package-hashtable
 608                                            internal-symbols)
 609                         :external-symbols (make-or-remake-package-hashtable
 610                                            external-symbols))))
 611
 612          ;; Do a USE-PACKAGE for each thing in the USE list so that checking for
 613          ;; conflicting exports among used packages is done.
 614          (if *in-package-init*
 615              (push (list use package) *!deferred-use-packages*)
 616              (use-package use package))
 617
 618          ;; FIXME: ENTER-NEW-NICKNAMES can fail (ERROR) if nicknames are illegal,
 619          ;; which would leave us with possibly-bad side effects from the earlier
 620          ;; USE-PACKAGE (e.g. this package on the used-by lists of other packages,
 621          ;; but not in *PACKAGE-NAMES*, and possibly import side effects too?).
 622          ;; Perhaps this can be solved by just moving ENTER-NEW-NICKNAMES before
 623          ;; USE-PACKAGE, but I need to check what kinds of errors can be caused by
 624          ;; USE-PACKAGE, too.
 625          (%enter-new-nicknames package nicknames)
 626          (return (setf (gethash name *package-names*) package))))
 627      (bug "never")))
 628
 629 ;;; Change the name if we can, blast any old nicknames and then
 630 ;;; add in any new ones.
 631 ;;;
 632 ;;; FIXME: ANSI claims that NAME is a package designator (not just a
 633 ;;; string designator -- weird). Thus, NAME could
 634 ;;; be a package instead of a string. Presumably then we should not change
 635 ;;; the package name if NAME is the same package that's referred to by PACKAGE.
 636 ;;; If it's a *different* package, we should probably signal an error.
 637 ;;; (perhaps (ERROR 'ANSI-WEIRDNESS ..):-)
 638 (defun rename-package (package-designator name &optional (nicknames ()))
 639   #!+sb-doc
 640   "Changes the name and nicknames for a package."
 641   (let ((package nil))
 642   (tagbody :restart
 643        (setq package (find-undeleted-package-or-lose package-designator))
 644        (let* ((name (package-namify name))
 645             (found (find-package name))
 646             (nicks (mapcar #'string nicknames)))
 647        (unless (or (not found) (eq found package))
 648          (error 'simple-package-error
 649                 :package name
 650                 :format-control "A package named ~S already exists."
 651                 :format-arguments (list name)))
 652        (with-single-package-locked-error ()
 653          (unless (and (string= name (package-name package))
 654                       (null (set-difference nicks (package-nicknames package)
 655                                             :test #'string=)))
 656            (assert-package-unlocked package "rename as ~A~@[ with nickname~P ~
 657                                            ~{~A~^, ~}~]"
 658                                     name (length nicks) nicks))
 659          (with-package-names (names)
 660            ;; Check for race conditions now that we have the lock.
 661            (unless (eq package (find-package package-designator))
 662              (go :restart))
 663            ;; Do the renaming.
 664            (remhash (package-%name package) names)
 665            (dolist (n (package-%nicknames package))
 666              (remhash n names))
 667            (setf (package-%name package) name
 668                  (gethash name names) package
 669                  (package-%nicknames package) ()))
 670            (%enter-new-nicknames package nicknames))))
 671     package))
 672
 673 (defun delete-package (package-designator)
 674   #!+sb-doc
 675   "Delete the package designated by PACKAGE-DESIGNATOR from the package
 676   system data structures."
 677   (tagbody :restart
 678      (let ((package (find-package package-designator)))
 679        (cond ((not package)
 680               ;; This continuable error is required by ANSI.
 681               (cerror
 682                "Return ~S."
 683                (make-condition
 684                 'simple-package-error
 685                 :package package-designator
 686                 :format-control "There is no package named ~S."
 687                 :format-arguments (list package-designator))
 688                (return-from delete-package nil)))
 689              ((not (package-name package)) ; already deleted
 690               (return-from delete-package nil))
 691              (t
 692               (with-single-package-locked-error
 693                   (:package package "deleting package ~A" package)
 694                 (let ((use-list (package-used-by-list package)))
 695                   (when use-list
 696                     ;; This continuable error is specified by ANSI.
 697                     (cerror
 698                      "Remove dependency in other packages."
 699                      (make-condition
 700                       'simple-package-error
 701                       :package package
 702                       :format-control
 703                       "~@<Package ~S is used by package~P:~2I~_~S~@:>"
 704                       :format-arguments (list (package-name package)
 705                                               (length use-list)
 706                                               (mapcar #'package-name use-list))))
 707                     (dolist (p use-list)
 708                       (unuse-package package p))))
 709                 (with-package-graph ()
 710                   ;; Check for races, restart if necessary.
 711                   (let ((package2 (find-package package-designator)))
 712                     (when (or (neq package package2) (package-used-by-list package2))
 713                       (go :restart)))
 714                   (dolist (used (package-use-list package))
 715                     (unuse-package used package))
 716                   (do-symbols (sym package)
 717                     (unintern sym package))
 718                   (with-package-names (names)
 719                     (remhash (package-name package) names)
 720                     (dolist (nick (package-nicknames package))
 721                       (remhash nick names))
 722                     (setf (package-%name package) nil
 723                           ;; Setting PACKAGE-%NAME to NIL is required in order to
 724                           ;; make PACKAGE-NAME return NIL for a deleted package as
 725                           ;; ANSI requires. Setting the other slots to NIL
 726                           ;; and blowing away the PACKAGE-HASHTABLES is just done
 727                           ;; for tidiness and to help the GC.
 728                           (package-%nicknames package) nil))
 729                   (setf (package-%use-list package) nil
 730                         (package-tables package) nil
 731                         (package-%shadowing-symbols package) nil
 732                         (package-internal-symbols package)
 733                         (make-or-remake-package-hashtable 0)
 734                         (package-external-symbols package)
 735                         (make-or-remake-package-hashtable 0)))
 736                 (return-from delete-package t)))))))
 737
 738 (defun list-all-packages ()
 739   #!+sb-doc
 740   "Return a list of all existing packages."
 741   (let ((res ()))
 742     (with-package-names (names)
 743       (maphash (lambda (k v)
 744                  (declare (ignore k))
 745                  (pushnew v res))
 746                names))
 747     res))
 748 \f
 749 (defun intern (name &optional (package (sane-package)))
 750   #!+sb-doc
 751   "Return a symbol in PACKAGE having the specified NAME, creating it
 752   if necessary."
 753   ;; We just simple-stringify the name and call INTERN*, where the real
 754   ;; logic is.
 755   (let ((name (if (simple-string-p name)
 756                   name
 757                   (coerce name 'simple-string)))
 758         (package (find-undeleted-package-or-lose package)))
 759     (declare (simple-string name))
 760       (intern* name
 761                (length name)
 762                package)))
 763
 764 (defun find-symbol (name &optional (package (sane-package)))
 765   #!+sb-doc
 766   "Return the symbol named STRING in PACKAGE. If such a symbol is found
 767   then the second value is :INTERNAL, :EXTERNAL or :INHERITED to indicate
 768   how the symbol is accessible. If no symbol is found then both values
 769   are NIL."
 770   ;; We just simple-stringify the name and call FIND-SYMBOL*, where the
 771   ;; real logic is.
 772   (let ((name (if (simple-string-p name) name (coerce name 'simple-string))))
 773     (declare (simple-string name))
 774     (find-symbol* name
 775                   (length name)
 776                   (find-undeleted-package-or-lose package))))
 777
 778 ;;; If the symbol named by the first LENGTH characters of NAME doesn't exist,
 779 ;;; then create it, special-casing the keyword package.
 780 (defun intern* (name length package &key no-copy)
 781   (declare (simple-string name))
 782   (multiple-value-bind (symbol where) (find-symbol* name length package)
 783     (cond (where
 784            (values symbol where))
 785           (t
 786            ;; Let's try again with a lock: the common case has the
 787            ;; symbol already interned, handled by the first leg of the
 788            ;; COND, but in case another thread is interning in
 789            ;; parallel we need to check after grabbing the lock.
 790            (with-package-graph ()
 791              (setf (values symbol where) (find-symbol* name length package))
 792              (if where
 793                  (values symbol where)
 794                  (let ((symbol-name (cond (no-copy
 795                                            (aver (= (length name) length))
 796                                            name)
 797                                           (t
 798                                            ;; This so that SUBSEQ is inlined,
 799                                            ;; because we need it fixed for cold init.
 800                                            (string-dispatch
 801                                                ((simple-array base-char (*))
 802                                                 (simple-array character (*)))
 803                                                name
 804                                              (declare (optimize speed))
 805                                              (subseq name 0 length))))))
 806                    (with-single-package-locked-error
 807                        (:package package "interning ~A" symbol-name)
 808                      (let ((symbol (make-symbol symbol-name)))
 809                        (%set-symbol-package symbol package)
 810                        (cond
 811                          ((eq package *keyword-package*)
 812                           (%set-symbol-value symbol symbol)
 813                           (add-symbol (package-external-symbols package) symbol))
 814                          (t
 815                           (add-symbol (package-internal-symbols package) symbol)))
 816                        (values symbol nil))))))))))
 817
 818 ;;; Check internal and external symbols, then scan down the list
 819 ;;; of hashtables for inherited symbols.
 820 (defun find-symbol* (string length package)
 821   (declare (simple-string string)
 822            (type index length))
 823   (let* ((hash (%sxhash-simple-substring string length))
 824          (ehash (entry-hash length hash)))
 825     (declare (type hash hash ehash))
 826     (with-symbol (found symbol (package-internal-symbols package)
 827                         string length hash ehash)
 828       (when found
 829         (return-from find-symbol* (values symbol :internal))))
 830     (with-symbol (found symbol (package-external-symbols package)
 831                         string length hash ehash)
 832       (when found
 833         (return-from find-symbol* (values symbol :external))))
 834     (let ((head (package-tables package)))
 835       (do ((prev head table)
 836            (table (cdr head) (cdr table)))
 837           ((null table) (values nil nil))
 838         (with-symbol (found symbol (car table) string length hash ehash)
 839           (when found
 840             ;; At this point we used to move the table to the
 841             ;; beginning of the list, probably on the theory that we'd
 842             ;; soon be looking up further items there. Unfortunately
 843             ;; that was very much non-thread safe. Since the failure
 844             ;; mode was nasty (corruption of the package in a way
 845             ;; which would make symbol lookups loop infinitely) and it
 846             ;; would be triggered just by doing reads to a resource
 847             ;; that users can't do their own locking on, that code has
 848             ;; been removed. If we ever add locking to packages,
 849             ;; resurrecting that code might make sense, even though it
 850             ;; didn't seem to have much of an performance effect in
 851             ;; normal use.
 852             ;;
 853             ;; -- JES, 2006-09-13
 854             (return-from find-symbol* (values symbol :inherited))))))))
 855
 856 ;;; Similar to FIND-SYMBOL, but only looks for an external symbol.
 857 ;;; This is used for fast name-conflict checking in this file and symbol
 858 ;;; printing in the printer.
 859 (defun find-external-symbol (string package)
 860   (declare (simple-string string))
 861   (let* ((length (length string))
 862          (hash (%sxhash-simple-string string))
 863          (ehash (entry-hash length hash)))
 864     (declare (type index length)
 865              (type hash hash))
 866     (with-symbol (found symbol (package-external-symbols package)
 867                         string length hash ehash)
 868       (values symbol found))))
 869 \f
 870 (defun print-symbol-with-prefix (stream symbol colon at)
 871   #!+sb-doc
 872   "For use with ~/: Write SYMBOL to STREAM as if it is not accessible from
 873   the current package."
 874   (declare (ignore colon at))
 875   ;; Only keywords should be accessible from the keyword package, and
 876   ;; keywords are always printed with colons, so this guarantees that the
 877   ;; symbol will not be printed without a prefix.
 878   (let ((*package* *keyword-package*))
 879     (write symbol :stream stream :escape t)))
 880
 881 (define-condition name-conflict (reference-condition package-error)
 882   ((function :initarg :function :reader name-conflict-function)
 883    (datum :initarg :datum :reader name-conflict-datum)
 884    (symbols :initarg :symbols :reader name-conflict-symbols))
 885   (:default-initargs :references (list '(:ansi-cl :section (11 1 1 2 5))))
 886   (:report
 887    (lambda (c s)
 888      (format s "~@<~S ~S causes name-conflicts in ~S between the ~
 889                 following symbols:~2I~@:_~
 890                 ~{~/sb-impl::print-symbol-with-prefix/~^, ~}~:@>"
 891              (name-conflict-function c)
 892              (name-conflict-datum c)
 893              (package-error-package c)
 894              (name-conflict-symbols c)))))
 895
 896 (defun name-conflict (package function datum &rest symbols)
 897   (flet ((importp (c)
 898            (declare (ignore c))
 899            (eq 'import function))
 900          (use-or-export-p (c)
 901            (declare (ignore c))
 902            (or (eq 'use-package function)
 903                (eq 'export function)))
 904          (old-symbol ()
 905            (car (remove datum symbols))))
 906     (let ((pname (package-name package)))
 907       (restart-case
 908           (error 'name-conflict :package package :symbols symbols
 909                                 :function function :datum datum)
 910         ;; USE-PACKAGE and EXPORT
 911         (keep-old ()
 912           :report (lambda (s)
 913                     (ecase function
 914                       (export
 915                        (format s "Keep ~S accessible in ~A (shadowing ~S)."
 916                                (old-symbol) pname datum))
 917                       (use-package
 918                        (format s "Keep symbols already accessible ~A (shadowing others)."
 919                                pname))))
 920           :test use-or-export-p
 921           (dolist (s (remove-duplicates symbols :test #'string=))
 922             (shadow (symbol-name s) package)))
 923         (take-new ()
 924           :report (lambda (s)
 925                     (ecase function
 926                       (export
 927                        (format s "Make ~S accessible in ~A (uninterning ~S)."
 928                                datum pname (old-symbol)))
 929                       (use-package
 930                        (format s "Make newly exposed symbols accessible in ~A, ~
 931                                   uninterning old ones."
 932                                pname))))
 933           :test use-or-export-p
 934           (dolist (s symbols)
 935             (when (eq s (find-symbol (symbol-name s) package))
 936               (unintern s package))))
 937         ;; IMPORT
 938         (shadowing-import-it ()
 939           :report (lambda (s)
 940                     (format s "Shadowing-import ~S, uninterning ~S."
 941                             datum (old-symbol)))
 942           :test importp
 943           (shadowing-import datum package))
 944         (dont-import-it ()
 945           :report (lambda (s)
 946                     (format s "Don't import ~S, keeping ~S."
 947                             datum
 948                             (car (remove datum symbols))))
 949           :test importp)
 950         ;; General case. This is exposed via SB-EXT.
 951         (resolve-conflict (chosen-symbol)
 952           :report "Resolve conflict."
 953           :interactive
 954           (lambda ()
 955             (let* ((len (length symbols))
 956                    (nlen (length (write-to-string len :base 10)))
 957                    (*print-pretty* t))
 958               (format *query-io* "~&~@<Select a symbol to be made accessible in ~
 959                               package ~A:~2I~@:_~{~{~V,' D. ~
 960                               ~/sb-impl::print-symbol-with-prefix/~}~@:_~}~
 961                               ~@:>"
 962                       (package-name package)
 963                       (loop for s in symbols
 964                             for i upfrom 1
 965                             collect (list nlen i s)))
 966               (loop
 967                 (format *query-io* "~&Enter an integer (between 1 and ~D): " len)
 968                 (finish-output *query-io*)
 969                 (let ((i (parse-integer (read-line *query-io*) :junk-allowed t)))
 970                   (when (and i (<= 1 i len))
 971                     (return (list (nth (1- i) symbols))))))))
 972           (multiple-value-bind (package-symbol status)
 973               (find-symbol (symbol-name chosen-symbol) package)
 974             (let* ((accessiblep status)     ; never NIL here
 975                    (presentp (and accessiblep
 976                                   (not (eq :inherited status)))))
 977               (ecase function
 978                 ((unintern)
 979                  (if presentp
 980                      (if (eq package-symbol chosen-symbol)
 981                          (shadow (list package-symbol) package)
 982                          (shadowing-import (list chosen-symbol) package))
 983                      (shadowing-import (list chosen-symbol) package)))
 984                 ((use-package export)
 985                  (if presentp
 986                      (if (eq package-symbol chosen-symbol)
 987                          (shadow (list package-symbol) package) ; CLHS 11.1.1.2.5
 988                          (if (eq (symbol-package package-symbol) package)
 989                              (unintern package-symbol package) ; CLHS 11.1.1.2.5
 990                              (shadowing-import (list chosen-symbol) package)))
 991                      (shadowing-import (list chosen-symbol) package)))
 992                 ((import)
 993                  (if presentp
 994                      (if (eq package-symbol chosen-symbol)
 995                          nil                ; re-importing the same symbol
 996                          (shadowing-import (list chosen-symbol) package))
 997                      (shadowing-import (list chosen-symbol) package)))))))))))
 998
 999 ;;; If we are uninterning a shadowing symbol, then a name conflict can
1000 ;;; result, otherwise just nuke the symbol.
1001 (defun unintern (symbol &optional (package (sane-package)))
1002   #!+sb-doc
1003   "Makes SYMBOL no longer present in PACKAGE. If SYMBOL was present then T is
1004 returned, otherwise NIL. If PACKAGE is SYMBOL's home package, then it is made
1005 uninterned."
1006   (with-package-graph ()
1007     (let* ((package (find-undeleted-package-or-lose package))
1008            (name (symbol-name symbol))
1009            (shadowing-symbols (package-%shadowing-symbols package)))
1010       (declare (list shadowing-symbols))
1011
1012       (with-single-package-locked-error ()
1013         (when (find-symbol name package)
1014           (assert-package-unlocked package "uninterning ~A" name))
1015
1016         ;; If a name conflict is revealed, give us a chance to
1017         ;; shadowing-import one of the accessible symbols.
1018         (when (member symbol shadowing-symbols)
1019           (let ((cset ()))
1020             (dolist (p (package-%use-list package))
1021               (multiple-value-bind (s w) (find-external-symbol name p)
1022                 (when w (pushnew s cset))))
1023             (when (cdr cset)
1024               (apply #'name-conflict package 'unintern symbol cset)
1025               (return-from unintern t)))
1026           (setf (package-%shadowing-symbols package)
1027                 (remove symbol shadowing-symbols)))
1028
1029         (multiple-value-bind (s w) (find-symbol name package)
1030           (cond ((not (eq symbol s)) nil)
1031                 ((or (eq w :internal) (eq w :external))
1032                  (nuke-symbol (if (eq w :internal)
1033                                   (package-internal-symbols package)
1034                                   (package-external-symbols package))
1035                               name)
1036                  (if (eq (symbol-package symbol) package)
1037                      (%set-symbol-package symbol nil))
1038                  t)
1039                 (t nil)))))))
1040 \f
1041 ;;; Take a symbol-or-list-of-symbols and return a list, checking types.
1042 (defun symbol-listify (thing)
1043   (cond ((listp thing)
1044          (dolist (s thing)
1045            (unless (symbolp s) (error "~S is not a symbol." s)))
1046          thing)
1047         ((symbolp thing) (list thing))
1048         (t
1049          (error "~S is neither a symbol nor a list of symbols." thing))))
1050
1051 (defun string-listify (thing)
1052   (mapcar #'string (if (listp thing)
1053                        thing
1054                        (list thing))))
1055
1056 ;;; This is like UNINTERN, except if SYMBOL is inherited, it chases
1057 ;;; down the package it is inherited from and uninterns it there. Used
1058 ;;; for name-conflict resolution. Shadowing symbols are not uninterned
1059 ;;; since they do not cause conflicts.
1060 (defun moby-unintern (symbol package)
1061   (unless (member symbol (package-%shadowing-symbols package))
1062     (or (unintern symbol package)
1063         (let ((name (symbol-name symbol)))
1064           (multiple-value-bind (s w) (find-symbol name package)
1065             (declare (ignore s))
1066             (when (eq w :inherited)
1067               (dolist (q (package-%use-list package))
1068                 (multiple-value-bind (u x) (find-external-symbol name q)
1069                   (declare (ignore u))
1070                   (when x
1071                     (unintern symbol q)
1072                     (return t))))))))))
1073 \f
1074 (defun export (symbols &optional (package (sane-package)))
1075   #!+sb-doc
1076   "Exports SYMBOLS from PACKAGE, checking that no name conflicts result."
1077   (with-package-graph ()
1078     (let ((package (find-undeleted-package-or-lose package))
1079           (symbols (symbol-listify symbols))
1080           (syms ()))
1081       ;; Punt any symbols that are already external.
1082       (dolist (sym symbols)
1083         (multiple-value-bind (s w)
1084             (find-external-symbol (symbol-name sym) package)
1085           (declare (ignore s))
1086           (unless (or w (member sym syms))
1087             (push sym syms))))
1088       (with-single-package-locked-error ()
1089         (when syms
1090           (assert-package-unlocked package "exporting symbol~P ~{~A~^, ~}"
1091                                    (length syms) syms))
1092         ;; Find symbols and packages with conflicts.
1093         (let ((used-by (package-%used-by-list package)))
1094           (dolist (sym syms)
1095             (let ((name (symbol-name sym)))
1096               (dolist (p used-by)
1097                 (multiple-value-bind (s w) (find-symbol name p)
1098                   (when (and w
1099                              (not (eq s sym))
1100                              (not (member s (package-%shadowing-symbols p))))
1101                     ;; Beware: the name conflict is in package P, not in
1102                     ;; PACKAGE.
1103                     (name-conflict p 'export sym sym s)))))))
1104         ;; Check that all symbols are accessible. If not, ask to import them.
1105         (let ((missing ())
1106               (imports ()))
1107           (dolist (sym syms)
1108             (multiple-value-bind (s w) (find-symbol (symbol-name sym) package)
1109               (cond ((not (and w (eq s sym)))
1110                      (push sym missing))
1111                     ((eq w :inherited)
1112                      (push sym imports)))))
1113           (when missing
1114             (cerror
1115              "~S these symbols into the ~A package."
1116              (make-condition
1117               'simple-package-error
1118               :package package
1119               :format-control
1120               "~@<These symbols are not accessible in the ~A package:~2I~_~S~@:>"
1121               :format-arguments (list (package-%name package) missing))
1122              'import (package-%name package))
1123             (import missing package))
1124           (import imports package))
1125
1126         ;; And now, three pages later, we export the suckers.
1127         (let ((internal (package-internal-symbols package))
1128               (external (package-external-symbols package)))
1129           (dolist (sym syms)
1130             (nuke-symbol internal (symbol-name sym))
1131             (add-symbol external sym))))
1132       t)))
1133 \f
1134 ;;; Check that all symbols are accessible, then move from external to internal.
1135 (defun unexport (symbols &optional (package (sane-package)))
1136   #!+sb-doc
1137   "Makes SYMBOLS no longer exported from PACKAGE."
1138   (with-package-graph ()
1139     (let ((package (find-undeleted-package-or-lose package))
1140           (symbols (symbol-listify symbols))
1141           (syms ()))
1142       (dolist (sym symbols)
1143         (multiple-value-bind (s w) (find-symbol (symbol-name sym) package)
1144           (cond ((or (not w) (not (eq s sym)))
1145                  (error 'simple-package-error
1146                         :package package
1147                         :format-control "~S is not accessible in the ~A package."
1148                         :format-arguments (list sym (package-%name package))))
1149                 ((eq w :external) (pushnew sym syms)))))
1150       (with-single-package-locked-error ()
1151         (when syms
1152           (assert-package-unlocked package "unexporting symbol~P ~{~A~^, ~}"
1153                                    (length syms) syms))
1154         (let ((internal (package-internal-symbols package))
1155               (external (package-external-symbols package)))
1156           (dolist (sym syms)
1157             (add-symbol internal sym)
1158             (nuke-symbol external (symbol-name sym)))))
1159       t)))
1160 \f
1161 ;;; Check for name conflict caused by the import and let the user
1162 ;;; shadowing-import if there is.
1163 (defun import (symbols &optional (package (sane-package)))
1164   #!+sb-doc
1165   "Make SYMBOLS accessible as internal symbols in PACKAGE. If a symbol is
1166 already accessible then it has no effect. If a name conflict would result from
1167 the importation, then a correctable error is signalled."
1168   (with-package-graph ()
1169     (let* ((package (find-undeleted-package-or-lose package))
1170            (symbols (symbol-listify symbols))
1171            (homeless (remove-if #'symbol-package symbols))
1172            (syms ()))
1173       (with-single-package-locked-error ()
1174         (dolist (sym symbols)
1175           (multiple-value-bind (s w) (find-symbol (symbol-name sym) package)
1176             (cond ((not w)
1177                    (let ((found (member sym syms :test #'string=)))
1178                      (if found
1179                          (when (not (eq (car found) sym))
1180                            (setf syms (remove (car found) syms))
1181                            (name-conflict package 'import sym sym (car found)))
1182                          (push sym syms))))
1183                   ((not (eq s sym))
1184                    (name-conflict package 'import sym sym s))
1185                   ((eq w :inherited) (push sym syms)))))
1186         (when (or homeless syms)
1187           (let ((union (delete-duplicates (append homeless syms))))
1188             (assert-package-unlocked package "importing symbol~P ~{~A~^, ~}"
1189                                      (length union) union)))
1190         ;; Add the new symbols to the internal hashtable.
1191         (let ((internal (package-internal-symbols package)))
1192           (dolist (sym syms)
1193             (add-symbol internal sym)))
1194         ;; If any of the symbols are uninterned, make them be owned by PACKAGE.
1195         (dolist (sym homeless)
1196           (%set-symbol-package sym package))
1197         t))))
1198 \f
1199 ;;; If a conflicting symbol is present, unintern it, otherwise just
1200 ;;; stick the symbol in.
1201 (defun shadowing-import (symbols &optional (package (sane-package)))
1202   #!+sb-doc
1203   "Import SYMBOLS into package, disregarding any name conflict. If
1204   a symbol of the same name is present, then it is uninterned."
1205   (with-package-graph ()
1206     (let* ((package (find-undeleted-package-or-lose package))
1207            (internal (package-internal-symbols package))
1208            (symbols (symbol-listify symbols))
1209            (lock-asserted-p nil))
1210       (with-single-package-locked-error ()
1211         (dolist (sym symbols)
1212           (multiple-value-bind (s w) (find-symbol (symbol-name sym) package)
1213             (unless (or lock-asserted-p
1214                         (and (eq s sym)
1215                              (member s (package-shadowing-symbols package))))
1216               (assert-package-unlocked package "shadowing-importing symbol~P ~
1217                                            ~{~A~^, ~}" (length symbols) symbols)
1218               (setf lock-asserted-p t))
1219             (unless (and w (not (eq w :inherited)) (eq s sym))
1220               (when (or (eq w :internal) (eq w :external))
1221                 ;; If it was shadowed, we don't want UNINTERN to flame out...
1222                 (setf (package-%shadowing-symbols package)
1223                       (remove s (the list (package-%shadowing-symbols package))))
1224                 (unintern s package))
1225               (add-symbol internal sym))
1226             (pushnew sym (package-%shadowing-symbols package)))))))
1227   t)
1228
1229 (defun shadow (symbols &optional (package (sane-package)))
1230   #!+sb-doc
1231   "Make an internal symbol in PACKAGE with the same name as each of the
1232 specified SYMBOLS. If a symbol with the given name is already present in
1233 PACKAGE, then the existing symbol is placed in the shadowing symbols list if
1234 it is not already present."
1235   (with-package-graph ()
1236     (let* ((package (find-undeleted-package-or-lose package))
1237            (internal (package-internal-symbols package))
1238            (symbols (string-listify symbols))
1239            (lock-asserted-p nil))
1240       (flet ((present-p (w)
1241                (and w (not (eq w :inherited)))))
1242         (with-single-package-locked-error ()
1243           (dolist (name symbols)
1244             (multiple-value-bind (s w) (find-symbol name package)
1245               (unless (or lock-asserted-p
1246                           (and (present-p w)
1247                                (member s (package-shadowing-symbols package))))
1248                 (assert-package-unlocked package "shadowing symbol~P ~{~A~^, ~}"
1249                                          (length symbols) symbols)
1250                 (setf lock-asserted-p t))
1251               (unless (present-p w)
1252                 (setq s (make-symbol name))
1253                 (%set-symbol-package s package)
1254                 (add-symbol internal s))
1255               (pushnew s (package-%shadowing-symbols package))))))))
1256   t)
1257 \f
1258 ;;; Do stuff to use a package, with all kinds of fun name-conflict checking.
1259 (defun use-package (packages-to-use &optional (package (sane-package)))
1260   #!+sb-doc
1261   "Add all the PACKAGES-TO-USE to the use list for PACKAGE so that the
1262 external symbols of the used packages are accessible as internal symbols in
1263 PACKAGE."
1264   (with-package-graph ()
1265     (let ((packages (package-listify packages-to-use))
1266           (package (find-undeleted-package-or-lose package)))
1267
1268       ;; Loop over each package, USE'ing one at a time...
1269       (with-single-package-locked-error ()
1270         (dolist (pkg packages)
1271           (unless (member pkg (package-%use-list package))
1272             (assert-package-unlocked package "using package~P ~{~A~^, ~}"
1273                                      (length packages) packages)
1274             (let ((shadowing-symbols (package-%shadowing-symbols package))
1275                   (use-list (package-%use-list package)))
1276
1277               ;; If the number of symbols already accessible is less
1278               ;; than the number to be inherited then it is faster to
1279               ;; run the test the other way. This is particularly
1280               ;; valuable in the case of a new package USEing
1281               ;; COMMON-LISP.
1282               (cond
1283                 ((< (+ (package-internal-symbol-count package)
1284                        (package-external-symbol-count package)
1285                        (let ((res 0))
1286                          (dolist (p use-list res)
1287                            (incf res (package-external-symbol-count p)))))
1288                     (package-external-symbol-count pkg))
1289                  (do-symbols (sym package)
1290                    (multiple-value-bind (s w)
1291                        (find-external-symbol (symbol-name sym) pkg)
1292                      (when (and w
1293                                 (not (eq s sym))
1294                                 (not (member sym shadowing-symbols)))
1295                        (name-conflict package 'use-package pkg sym s))))
1296                  (dolist (p use-list)
1297                    (do-external-symbols (sym p)
1298                      (multiple-value-bind (s w)
1299                          (find-external-symbol (symbol-name sym) pkg)
1300                        (when (and w
1301                                   (not (eq s sym))
1302                                   (not (member
1303                                         (find-symbol (symbol-name sym) package)
1304                                         shadowing-symbols)))
1305                          (name-conflict package 'use-package pkg sym s))))))
1306                 (t
1307                  (do-external-symbols (sym pkg)
1308                    (multiple-value-bind (s w)
1309                        (find-symbol (symbol-name sym) package)
1310                      (when (and w
1311                                 (not (eq s sym))
1312                                 (not (member s shadowing-symbols)))
1313                        (name-conflict package 'use-package pkg sym s)))))))
1314
1315             (push pkg (package-%use-list package))
1316             (push (package-external-symbols pkg) (cdr (package-tables package)))
1317             (push package (package-%used-by-list pkg)))))))
1318   t)
1319
1320 (defun unuse-package (packages-to-unuse &optional (package (sane-package)))
1321   #!+sb-doc
1322   "Remove PACKAGES-TO-UNUSE from the USE list for PACKAGE."
1323   (with-package-graph ()
1324     (let ((package (find-undeleted-package-or-lose package))
1325           (packages (package-listify packages-to-unuse)))
1326       (with-single-package-locked-error ()
1327         (dolist (p packages)
1328           (when (member p (package-use-list package))
1329             (assert-package-unlocked package "unusing package~P ~{~A~^, ~}"
1330                                      (length packages) packages))
1331           (setf (package-%use-list package)
1332                 (remove p (the list (package-%use-list package))))
1333           (setf (package-tables package)
1334                 (delete (package-external-symbols p)
1335                         (the list (package-tables package))))
1336           (setf (package-%used-by-list p)
1337                 (remove package (the list (package-%used-by-list p))))))
1338       t)))
1339
1340 (defun find-all-symbols (string-or-symbol)
1341   #!+sb-doc
1342   "Return a list of all symbols in the system having the specified name."
1343   (let ((string (string string-or-symbol))
1344         (res ()))
1345     (with-package-names (names)
1346       (maphash (lambda (k v)
1347                  (declare (ignore k))
1348                  (multiple-value-bind (s w) (find-symbol string v)
1349                    (when w (pushnew s res))))
1350                names))
1351     res))
1352 \f
1353 ;;;; APROPOS and APROPOS-LIST
1354
1355 (defun briefly-describe-symbol (symbol)
1356   (fresh-line)
1357   (prin1 symbol)
1358   (when (boundp symbol)
1359     (write-string " (bound)"))
1360   (when (fboundp symbol)
1361     (write-string " (fbound)")))
1362
1363 (defun apropos-list (string-designator
1364                      &optional
1365                      package-designator
1366                      external-only)
1367   #!+sb-doc
1368   "Like APROPOS, except that it returns a list of the symbols found instead
1369   of describing them."
1370   (if package-designator
1371       (let ((package (find-undeleted-package-or-lose package-designator))
1372             (string (stringify-string-designator string-designator))
1373             (result nil))
1374         (do-symbols (symbol package)
1375           (when (and (eq (symbol-package symbol) package)
1376                      (or (not external-only)
1377                          (eq (nth-value 1 (find-symbol (symbol-name symbol)
1378                                                        package))
1379                              :external))
1380                      (search string (symbol-name symbol) :test #'char-equal))
1381             (push symbol result)))
1382         (sort result #'string-lessp))
1383       (mapcan (lambda (package)
1384                 (apropos-list string-designator package external-only))
1385               (sort (list-all-packages) #'string-lessp :key #'package-name))))
1386
1387 (defun apropos (string-designator &optional package external-only)
1388   #!+sb-doc
1389   "Briefly describe all symbols which contain the specified STRING.
1390   If PACKAGE is supplied then only describe symbols present in
1391   that package. If EXTERNAL-ONLY then only describe
1392   external symbols in the specified package."
1393   ;; Implementing this in terms of APROPOS-LIST keeps things simple at the cost
1394   ;; of some unnecessary consing; and the unnecessary consing shouldn't be an
1395   ;; issue, since this function is is only useful interactively anyway, and
1396   ;; we can cons and GC a lot faster than the typical user can read..
1397   (dolist (symbol (apropos-list string-designator package external-only))
1398     (briefly-describe-symbol symbol))
1399   (values))
1400 \f
1401 ;;;; final initialization
1402
1403 ;;;; The cold loader (GENESIS) makes the data structure in
1404 ;;;; *!INITIAL-SYMBOLS*. We grovel over it, making the specified
1405 ;;;; packages and interning the symbols. For a description of the
1406 ;;;; format of *!INITIAL-SYMBOLS*, see the GENESIS source.
1407
1408 (defvar *!initial-symbols*)
1409
1410 (!cold-init-forms
1411
1412   (setq *in-package-init* t)
1413
1414   (/show0 "about to loop over *!INITIAL-SYMBOLS* to make packages")
1415   (dolist (spec *!initial-symbols*)
1416     (let* ((pkg (apply #'make-package (first spec)))
1417            (internal (package-internal-symbols pkg))
1418            (external (package-external-symbols pkg)))
1419       (/show0 "back from MAKE-PACKAGE, PACKAGE-NAME=..")
1420       (/primitive-print (package-name pkg))
1421
1422       ;; Put internal symbols in the internal hashtable and set package.
1423       (dolist (symbol (second spec))
1424         (add-symbol internal symbol)
1425         (%set-symbol-package symbol pkg))
1426
1427       ;; External symbols same, only go in external table.
1428       (dolist (symbol (third spec))
1429         (add-symbol external symbol)
1430         (%set-symbol-package symbol pkg))
1431
1432       ;; Don't set package for imported symbols.
1433       (dolist (symbol (fourth spec))
1434         (add-symbol internal symbol))
1435       (dolist (symbol (fifth spec))
1436         (add-symbol external symbol))
1437
1438       ;; Put shadowing symbols in the shadowing symbols list.
1439       (setf (package-%shadowing-symbols pkg) (sixth spec))
1440       ;; Set the package documentation
1441       (setf (package-doc-string pkg) (seventh spec))))
1442
1443   ;; FIXME: These assignments are also done at toplevel in
1444   ;; boot-extensions.lisp. They should probably only be done once.
1445   (/show0 "setting up *CL-PACKAGE* and *KEYWORD-PACKAGE*")
1446   (setq *cl-package* (find-package "COMMON-LISP"))
1447   (setq *keyword-package* (find-package "KEYWORD"))
1448
1449   (/show0 "about to MAKUNBOUND *!INITIAL-SYMBOLS*")
1450   (%makunbound '*!initial-symbols*)       ; (so that it gets GCed)
1451
1452   ;; Make some other packages that should be around in the cold load.
1453   ;; The COMMON-LISP-USER package is required by the ANSI standard,
1454   ;; but not completely specified by it, so in the cross-compilation
1455   ;; host Lisp it could contain various symbols, USE-PACKAGEs, or
1456   ;; nicknames that we don't want in our target SBCL. For that reason,
1457   ;; we handle it specially, not dumping the host Lisp version at
1458   ;; genesis time..
1459   (aver (not (find-package "COMMON-LISP-USER")))
1460   ;; ..but instead making our own from scratch here.
1461   (/show0 "about to MAKE-PACKAGE COMMON-LISP-USER")
1462   (make-package "COMMON-LISP-USER"
1463                 :nicknames '("CL-USER")
1464                 :use '("COMMON-LISP"
1465                        ;; ANSI encourages us to put extension packages
1466                        ;; in the USE list of COMMON-LISP-USER.
1467                        "SB!ALIEN" "SB!ALIEN" "SB!DEBUG"
1468                        "SB!EXT" "SB!GRAY" "SB!PROFILE"))
1469
1470   ;; Now do the *!DEFERRED-USE-PACKAGES*.
1471   (/show0 "about to do *!DEFERRED-USE-PACKAGES*")
1472   (dolist (args *!deferred-use-packages*)
1473     (apply #'use-package args))
1474
1475   ;; The Age Of Magic is over, we can behave ANSIly henceforth.
1476   (/show0 "about to SETQ *IN-PACKAGE-INIT*")
1477   (setq *in-package-init* nil)
1478
1479   ;; For the kernel core image wizards, set the package to *CL-PACKAGE*.
1480   ;;
1481   ;; FIXME: We should just set this to (FIND-PACKAGE
1482   ;; "COMMON-LISP-USER") once and for all here, instead of setting it
1483   ;; once here and resetting it later.
1484   (setq *package* *cl-package*))
1485 \f
1486 (!cold-init-forms
1487   (/show0 "done with !PACKAGE-COLD-INIT"))
1488
1489 (!defun-from-collected-cold-init-forms !package-cold-init)