src/code/target-pathname.lisp

   1 ;;;; machine/filesystem-independent pathname functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 #!-sb-fluid (declaim (freeze-type logical-pathname logical-host))
  15 \f
  16 ;;;; UNIX-HOST stuff
  17
  18 (def!struct (unix-host
  19              (:make-load-form-fun make-unix-host-load-form)
  20              (:include host
  21                        (parse #'parse-unix-namestring)
  22                        (unparse #'unparse-unix-namestring)
  23                        (unparse-host #'unparse-unix-host)
  24                        (unparse-directory #'unparse-unix-directory)
  25                        (unparse-file #'unparse-unix-file)
  26                        (unparse-enough #'unparse-unix-enough)
  27                        (customary-case :lower))))
  28
  29 (defvar *unix-host* (make-unix-host))
  30
  31 (defun make-unix-host-load-form (host)
  32   (declare (ignore host))
  33   '*unix-host*)
  34
  35 ;;; Return a value suitable, e.g., for preinitializing
  36 ;;; *DEFAULT-PATHNAME-DEFAULTS* before *DEFAULT-PATHNAME-DEFAULTS* is
  37 ;;; initialized (at which time we can't safely call e.g. #'PATHNAME).
  38 (defun make-trivial-default-pathname ()
  39   (%make-pathname *unix-host* nil nil nil nil :newest))
  40 \f
  41 ;;; pathname methods
  42
  43 (def!method print-object ((pathname pathname) stream)
  44   (let ((namestring (handler-case (namestring pathname)
  45                       (error nil))))
  46     (if namestring
  47         (format stream "#P~S" namestring)
  48         (print-unreadable-object (pathname stream :type t)
  49           (format stream
  50                   "~@<(with no namestring) ~_:HOST ~S ~_:DEVICE ~S ~_:DIRECTORY ~S ~
  51                   ~_:NAME ~S ~_:TYPE ~S ~_:VERSION ~S~:>"
  52                   (%pathname-host pathname)
  53                   (%pathname-device pathname)
  54                   (%pathname-directory pathname)
  55                   (%pathname-name pathname)
  56                   (%pathname-type pathname)
  57                   (%pathname-version pathname))))))
  58
  59 (def!method make-load-form ((pathname pathname) &optional environment)
  60   (make-load-form-saving-slots pathname :environment environment))
  61
  62 ;;; The potential conflict with search lists requires isolating the
  63 ;;; printed representation to use the i/o macro #.(logical-pathname
  64 ;;; <path-designator>).
  65 ;;;
  66 ;;; FIXME: We don't use search lists any more, so that comment is
  67 ;;; stale, right?
  68 (def!method print-object ((pathname logical-pathname) stream)
  69   (let ((namestring (handler-case (namestring pathname)
  70                       (error nil))))
  71     (if namestring
  72         (format stream "#.(CL:LOGICAL-PATHNAME ~S)" namestring)
  73         (print-unreadable-object (pathname stream :type t)
  74           (format
  75            stream
  76            "~_:HOST ~S ~_:DIRECTORY ~S ~_:FILE ~S ~_:NAME ~S ~_:VERSION ~S"
  77            (%pathname-host pathname)
  78            (%pathname-directory pathname)
  79            (%pathname-name pathname)
  80            (%pathname-type pathname)
  81            (%pathname-version pathname))))))
  82 \f
  83 ;;; A pathname is logical if the host component is a logical host.
  84 ;;; This constructor is used to make an instance of the correct type
  85 ;;; from parsed arguments.
  86 (defun %make-maybe-logical-pathname (host device directory name type version)
  87   ;; We canonicalize logical pathname components to uppercase. ANSI
  88   ;; doesn't strictly require this, leaving it up to the implementor;
  89   ;; but the arguments given in the X3J13 cleanup issue
  90   ;; PATHNAME-LOGICAL:ADD seem compelling: we should canonicalize the
  91   ;; case, and uppercase is the ordinary way to do that.
  92   (flet ((upcase-maybe (x) (typecase x (string (logical-word-or-lose x)) (t x))))
  93     (if (typep host 'logical-host)
  94         (%make-logical-pathname host
  95                                 :unspecific
  96                                 (mapcar #'upcase-maybe directory)
  97                                 (upcase-maybe name)
  98                                 (upcase-maybe type)
  99                                 version)
 100         (%make-pathname host device directory name type version))))
 101
 102 ;;; Hash table searching maps a logical pathname's host to its
 103 ;;; physical pathname translation.
 104 (defvar *logical-hosts* (make-hash-table :test 'equal))
 105 \f
 106 ;;;; patterns
 107
 108 (def!method make-load-form ((pattern pattern) &optional environment)
 109   (make-load-form-saving-slots pattern :environment environment))
 110
 111 (def!method print-object ((pattern pattern) stream)
 112   (print-unreadable-object (pattern stream :type t)
 113     (if *print-pretty*
 114         (let ((*print-escape* t))
 115           (pprint-fill stream (pattern-pieces pattern) nil))
 116         (prin1 (pattern-pieces pattern) stream))))
 117
 118 (defun pattern= (pattern1 pattern2)
 119   (declare (type pattern pattern1 pattern2))
 120   (let ((pieces1 (pattern-pieces pattern1))
 121         (pieces2 (pattern-pieces pattern2)))
 122     (and (= (length pieces1) (length pieces2))
 123          (every (lambda (piece1 piece2)
 124                   (typecase piece1
 125                     (simple-string
 126                      (and (simple-string-p piece2)
 127                           (string= piece1 piece2)))
 128                     (cons
 129                      (and (consp piece2)
 130                           (eq (car piece1) (car piece2))
 131                           (string= (cdr piece1) (cdr piece2))))
 132                     (t
 133                      (eq piece1 piece2))))
 134                 pieces1
 135                 pieces2))))
 136
 137 ;;; If the string matches the pattern returns the multiple values T
 138 ;;; and a list of the matched strings.
 139 (defun pattern-matches (pattern string)
 140   (declare (type pattern pattern)
 141            (type simple-string string))
 142   (let ((len (length string)))
 143     (labels ((maybe-prepend (subs cur-sub chars)
 144                (if cur-sub
 145                    (let* ((len (length chars))
 146                           (new (make-string len))
 147                           (index len))
 148                      (dolist (char chars)
 149                        (setf (schar new (decf index)) char))
 150                      (cons new subs))
 151                    subs))
 152              (matches (pieces start subs cur-sub chars)
 153                (if (null pieces)
 154                    (if (= start len)
 155                        (values t (maybe-prepend subs cur-sub chars))
 156                        (values nil nil))
 157                    (let ((piece (car pieces)))
 158                      (etypecase piece
 159                        (simple-string
 160                         (let ((end (+ start (length piece))))
 161                           (and (<= end len)
 162                                (string= piece string
 163                                         :start2 start :end2 end)
 164                                (matches (cdr pieces) end
 165                                         (maybe-prepend subs cur-sub chars)
 166                                         nil nil))))
 167                        (list
 168                         (ecase (car piece)
 169                           (:character-set
 170                            (and (< start len)
 171                                 (let ((char (schar string start)))
 172                                   (if (find char (cdr piece) :test #'char=)
 173                                       (matches (cdr pieces) (1+ start) subs t
 174                                                (cons char chars))))))))
 175                        ((member :single-char-wild)
 176                         (and (< start len)
 177                              (matches (cdr pieces) (1+ start) subs t
 178                                       (cons (schar string start) chars))))
 179                        ((member :multi-char-wild)
 180                         (multiple-value-bind (won new-subs)
 181                             (matches (cdr pieces) start subs t chars)
 182                           (if won
 183                               (values t new-subs)
 184                               (and (< start len)
 185                                    (matches pieces (1+ start) subs t
 186                                             (cons (schar string start)
 187                                                   chars)))))))))))
 188       (multiple-value-bind (won subs)
 189           (matches (pattern-pieces pattern) 0 nil nil nil)
 190         (values won (reverse subs))))))
 191
 192 ;;; PATHNAME-MATCH-P for directory components
 193 (defun directory-components-match (thing wild)
 194   (or (eq thing wild)
 195       (eq wild :wild)
 196       ;; If THING has a null directory, assume that it matches
 197       ;; (:ABSOLUTE :WILD-INFERIORS) or (:RELATIVE :WILD-INFERIORS).
 198       (and (consp wild)
 199            (null thing)
 200            (member (first wild) '(:absolute :relative))
 201            (eq (second wild) :wild-inferiors))
 202       (and (consp wild)
 203            (let ((wild1 (first wild)))
 204              (if (eq wild1 :wild-inferiors)
 205                  (let ((wild-subdirs (rest wild)))
 206                    (or (null wild-subdirs)
 207                        (loop
 208                          (when (directory-components-match thing wild-subdirs)
 209                            (return t))
 210                          (pop thing)
 211                          (unless thing (return nil)))))
 212                  (and (consp thing)
 213                       (components-match (first thing) wild1)
 214                       (directory-components-match (rest thing)
 215                                                   (rest wild))))))))
 216
 217 ;;; Return true if pathname component THING is matched by WILD. (not
 218 ;;; commutative)
 219 (defun components-match (thing wild)
 220   (declare (type (or pattern symbol simple-string integer) thing wild))
 221   (or (eq thing wild)
 222       (eq wild :wild)
 223       (typecase thing
 224         (simple-base-string
 225          ;; String is matched by itself, a matching pattern or :WILD.
 226          (typecase wild
 227            (pattern
 228             (values (pattern-matches wild thing)))
 229            (simple-base-string
 230             (string= thing wild))))
 231         (pattern
 232          ;; A pattern is only matched by an identical pattern.
 233          (and (pattern-p wild) (pattern= thing wild)))
 234         (integer
 235          ;; An integer (version number) is matched by :WILD or the
 236          ;; same integer. This branch will actually always be NIL as
 237          ;; long as the version is a fixnum.
 238          (eql thing wild)))))
 239
 240 ;;; a predicate for comparing two pathname slot component sub-entries
 241 (defun compare-component (this that)
 242   (or (eql this that)
 243       (typecase this
 244         (simple-string
 245          (and (simple-string-p that)
 246               (string= this that)))
 247         (pattern
 248          (and (pattern-p that)
 249               (pattern= this that)))
 250         (cons
 251          (and (consp that)
 252               (compare-component (car this) (car that))
 253               (compare-component (cdr this) (cdr that)))))))
 254 \f
 255 ;;;; pathname functions
 256
 257 (defun pathname= (pathname1 pathname2)
 258   (declare (type pathname pathname1)
 259            (type pathname pathname2))
 260   (and (eq (%pathname-host pathname1)
 261            (%pathname-host pathname2))
 262        (compare-component (%pathname-device pathname1)
 263                           (%pathname-device pathname2))
 264        (compare-component (%pathname-directory pathname1)
 265                           (%pathname-directory pathname2))
 266        (compare-component (%pathname-name pathname1)
 267                           (%pathname-name pathname2))
 268        (compare-component (%pathname-type pathname1)
 269                           (%pathname-type pathname2))
 270        (compare-component (%pathname-version pathname1)
 271                           (%pathname-version pathname2))))
 272
 273 ;;; Convert PATHNAME-DESIGNATOR (a pathname, or string, or
 274 ;;; stream), into a pathname in pathname.
 275 ;;;
 276 ;;; FIXME: was rewritten, should be tested (or rewritten again, this
 277 ;;; time using ONCE-ONLY, *then* tested)
 278 ;;; FIXME: become SB!XC:DEFMACRO inside EVAL-WHEN (COMPILE EVAL)?
 279 (defmacro with-pathname ((pathname pathname-designator) &body body)
 280   (let ((pd0 (gensym)))
 281     `(let* ((,pd0 ,pathname-designator)
 282             (,pathname (etypecase ,pd0
 283                          (pathname ,pd0)
 284                          (string (parse-namestring ,pd0))
 285                          (file-stream (file-name ,pd0)))))
 286        ,@body)))
 287
 288 ;;; Convert the var, a host or string name for a host, into a
 289 ;;; LOGICAL-HOST structure or nil if not defined.
 290 ;;;
 291 ;;; pw notes 1/12/97 this potentially useful macro is not used anywhere
 292 ;;; and 'find-host' is not defined. 'find-logical-host' seems to be needed.
 293 #|
 294 (defmacro with-host ((var expr) &body body)
 295   `(let ((,var (let ((,var ,expr))
 296                  (typecase ,var
 297                    (logical-host ,var)
 298                    (string (find-logical-host ,var nil))
 299                    (t nil)))))
 300      ,@body))
 301 |#
 302
 303 (defun pathname (thing)
 304   #!+sb-doc
 305   "Convert thing (a pathname, string or stream) into a pathname."
 306   (declare (type pathname-designator thing))
 307   (with-pathname (pathname thing)
 308     pathname))
 309
 310 ;;; Change the case of thing if DIDDLE-P.
 311 (defun maybe-diddle-case (thing diddle-p)
 312   (if (and diddle-p (not (or (symbolp thing) (integerp thing))))
 313       (labels ((check-for (pred in)
 314                  (typecase in
 315                    (pattern
 316                     (dolist (piece (pattern-pieces in))
 317                       (when (typecase piece
 318                               (simple-string
 319                                (check-for pred piece))
 320                               (cons
 321                                (case (car piece)
 322                                  (:character-set
 323                                   (check-for pred (cdr piece))))))
 324                         (return t))))
 325                    (list
 326                     (dolist (x in)
 327                       (when (check-for pred x)
 328                         (return t))))
 329                    (simple-base-string
 330                     (dotimes (i (length in))
 331                       (when (funcall pred (schar in i))
 332                         (return t))))
 333                    (t nil)))
 334                (diddle-with (fun thing)
 335                  (typecase thing
 336                    (pattern
 337                     (make-pattern
 338                      (mapcar (lambda (piece)
 339                                (typecase piece
 340                                  (simple-base-string
 341                                   (funcall fun piece))
 342                                  (cons
 343                                   (case (car piece)
 344                                     (:character-set
 345                                      (cons :character-set
 346                                            (funcall fun (cdr piece))))
 347                                     (t
 348                                      piece)))
 349                                  (t
 350                                   piece)))
 351                              (pattern-pieces thing))))
 352                    (list
 353                     (mapcar fun thing))
 354                    (simple-base-string
 355                     (funcall fun thing))
 356                    (t
 357                     thing))))
 358         (let ((any-uppers (check-for #'upper-case-p thing))
 359               (any-lowers (check-for #'lower-case-p thing)))
 360           (cond ((and any-uppers any-lowers)
 361                  ;; mixed case, stays the same
 362                  thing)
 363                 (any-uppers
 364                  ;; all uppercase, becomes all lower case
 365                  (diddle-with (lambda (x) (if (stringp x)
 366                                               (string-downcase x)
 367                                               x)) thing))
 368                 (any-lowers
 369                  ;; all lowercase, becomes all upper case
 370                  (diddle-with (lambda (x) (if (stringp x)
 371                                               (string-upcase x)
 372                                               x)) thing))
 373                 (t
 374                  ;; no letters?  I guess just leave it.
 375                  thing))))
 376       thing))
 377
 378 (defun merge-directories (dir1 dir2 diddle-case)
 379   (if (or (eq (car dir1) :absolute)
 380           (null dir2))
 381       dir1
 382       (let ((results nil))
 383         (flet ((add (dir)
 384                  (if (and (eq dir :back)
 385                           results
 386                           (not (eq (car results) :back)))
 387                      (pop results)
 388                      (push dir results))))
 389           (dolist (dir (maybe-diddle-case dir2 diddle-case))
 390             (add dir))
 391           (dolist (dir (cdr dir1))
 392             (add dir)))
 393         (reverse results))))
 394
 395 (defun merge-pathnames (pathname
 396                         &optional
 397                         (defaults *default-pathname-defaults*)
 398                         (default-version :newest))
 399   #!+sb-doc
 400   "Construct a filled in pathname by completing the unspecified components
 401    from the defaults."
 402   (declare (type pathname-designator pathname)
 403            (type pathname-designator defaults)
 404            (values pathname))
 405   (with-pathname (defaults defaults)
 406     (let ((pathname (let ((*default-pathname-defaults* defaults))
 407                       (pathname pathname))))
 408       (let* ((default-host (%pathname-host defaults))
 409              (pathname-host (%pathname-host pathname))
 410              (diddle-case
 411               (and default-host pathname-host
 412                    (not (eq (host-customary-case default-host)
 413                             (host-customary-case pathname-host))))))
 414         (%make-maybe-logical-pathname
 415          (or pathname-host default-host)
 416          (or (%pathname-device pathname)
 417              (maybe-diddle-case (%pathname-device defaults)
 418                                 diddle-case))
 419          (merge-directories (%pathname-directory pathname)
 420                             (%pathname-directory defaults)
 421                             diddle-case)
 422          (or (%pathname-name pathname)
 423              (maybe-diddle-case (%pathname-name defaults)
 424                                 diddle-case))
 425          (or (%pathname-type pathname)
 426              (maybe-diddle-case (%pathname-type defaults)
 427                                 diddle-case))
 428          (or (%pathname-version pathname)
 429              default-version))))))
 430
 431 (defun import-directory (directory diddle-case)
 432   (etypecase directory
 433     (null nil)
 434     ((member :wild) '(:absolute :wild-inferiors))
 435     ((member :unspecific) '(:relative))
 436     (list
 437      (collect ((results))
 438        (results (pop directory))
 439        (dolist (piece directory)
 440          (cond ((member piece '(:wild :wild-inferiors :up :back))
 441                 (results piece))
 442                ((or (simple-string-p piece) (pattern-p piece))
 443                 (results (maybe-diddle-case piece diddle-case)))
 444                ((stringp piece)
 445                 (results (maybe-diddle-case (coerce piece 'simple-string)
 446                                             diddle-case)))
 447                (t
 448                 (error "~S is not allowed as a directory component." piece))))
 449        (results)))
 450     (simple-string
 451      `(:absolute
 452        ,(maybe-diddle-case directory diddle-case)))
 453     (string
 454      `(:absolute
 455        ,(maybe-diddle-case (coerce directory 'simple-string)
 456                            diddle-case)))))
 457
 458 (defun make-pathname (&key host
 459                            (device nil devp)
 460                            (directory nil dirp)
 461                            (name nil namep)
 462                            (type nil typep)
 463                            (version nil versionp)
 464                            defaults
 465                            (case :local))
 466   #!+sb-doc
 467   "Makes a new pathname from the component arguments. Note that host is
 468 a host-structure or string."
 469   (declare (type (or string host pathname-component-tokens) host)
 470            (type (or string pathname-component-tokens) device)
 471            (type (or list string pattern pathname-component-tokens) directory)
 472            (type (or string pattern pathname-component-tokens) name type)
 473            (type (or integer pathname-component-tokens (member :newest))
 474                  version)
 475            (type (or pathname-designator null) defaults)
 476            (type (member :common :local) case))
 477   (let* ((defaults (when defaults
 478                      (with-pathname (defaults defaults) defaults)))
 479          (default-host (if defaults
 480                            (%pathname-host defaults)
 481                            (pathname-host *default-pathname-defaults*)))
 482          ;; Raymond Toy writes: CLHS says make-pathname can take a
 483          ;; string (as a logical-host) for the host part. We map that
 484          ;; string into the corresponding logical host structure.
 485          ;;
 486          ;; Paul Werkowski writes:
 487          ;; HyperSpec says for the arg to MAKE-PATHNAME;
 488          ;; "host---a valid physical pathname host. ..."
 489          ;; where it probably means -- a valid pathname host.
 490          ;; "valid pathname host n. a valid physical pathname host or
 491          ;; a valid logical pathname host."
 492          ;; and defines
 493          ;; "valid physical pathname host n. any of a string,
 494          ;; a list of strings, or the symbol :unspecific,
 495          ;; that is recognized by the implementation as the name of a host."
 496          ;; "valid logical pathname host n. a string that has been defined
 497          ;; as the name of a logical host. ..."
 498          ;; HS is silent on what happens if the :HOST arg is NOT one of these.
 499          ;; It seems an error message is appropriate.
 500          (host (typecase host
 501                  (host host)            ; A valid host, use it.
 502                  ((string 0) *unix-host*) ; "" cannot be a logical host
 503                  (string (find-logical-host host t)) ; logical-host or lose.
 504                  (t default-host)))     ; unix-host
 505          (diddle-args (and (eq (host-customary-case host) :lower)
 506                            (eq case :common)))
 507          (diddle-defaults
 508           (not (eq (host-customary-case host)
 509                    (host-customary-case default-host))))
 510          (dev (if devp device (if defaults (%pathname-device defaults))))
 511          (dir (import-directory directory diddle-args))
 512          (ver (cond
 513                (versionp version)
 514                (defaults (%pathname-version defaults))
 515                (t nil))))
 516     (when (and defaults (not dirp))
 517       (setf dir
 518             (merge-directories dir
 519                                (%pathname-directory defaults)
 520                                diddle-defaults)))
 521
 522     (macrolet ((pick (var varp field)
 523                  `(cond ((or (simple-string-p ,var)
 524                              (pattern-p ,var))
 525                          (maybe-diddle-case ,var diddle-args))
 526                         ((stringp ,var)
 527                          (maybe-diddle-case (coerce ,var 'simple-string)
 528                                             diddle-args))
 529                         (,varp
 530                          (maybe-diddle-case ,var diddle-args))
 531                         (defaults
 532                          (maybe-diddle-case (,field defaults)
 533                                             diddle-defaults))
 534                         (t
 535                          nil))))
 536       (%make-maybe-logical-pathname host
 537                                     dev ; forced to :UNSPECIFIC when logical
 538                                     dir
 539                                     (pick name namep %pathname-name)
 540                                     (pick type typep %pathname-type)
 541                                     ver))))
 542
 543 (defun pathname-host (pathname &key (case :local))
 544   #!+sb-doc
 545   "Return PATHNAME's host."
 546   (declare (type pathname-designator pathname)
 547            (type (member :local :common) case)
 548            (values host)
 549            (ignore case))
 550   (with-pathname (pathname pathname)
 551     (%pathname-host pathname)))
 552
 553 (defun pathname-device (pathname &key (case :local))
 554   #!+sb-doc
 555   "Return PATHNAME's device."
 556   (declare (type pathname-designator pathname)
 557            (type (member :local :common) case))
 558   (with-pathname (pathname pathname)
 559     (maybe-diddle-case (%pathname-device pathname)
 560                        (and (eq case :common)
 561                             (eq (host-customary-case
 562                                  (%pathname-host pathname))
 563                                 :lower)))))
 564
 565 (defun pathname-directory (pathname &key (case :local))
 566   #!+sb-doc
 567   "Return PATHNAME's directory."
 568   (declare (type pathname-designator pathname)
 569            (type (member :local :common) case))
 570   (with-pathname (pathname pathname)
 571     (maybe-diddle-case (%pathname-directory pathname)
 572                        (and (eq case :common)
 573                             (eq (host-customary-case
 574                                  (%pathname-host pathname))
 575                                 :lower)))))
 576 (defun pathname-name (pathname &key (case :local))
 577   #!+sb-doc
 578   "Return PATHNAME's name."
 579   (declare (type pathname-designator pathname)
 580            (type (member :local :common) case))
 581   (with-pathname (pathname pathname)
 582     (maybe-diddle-case (%pathname-name pathname)
 583                        (and (eq case :common)
 584                             (eq (host-customary-case
 585                                  (%pathname-host pathname))
 586                                 :lower)))))
 587
 588 (defun pathname-type (pathname &key (case :local))
 589   #!+sb-doc
 590   "Return PATHNAME's type."
 591   (declare (type pathname-designator pathname)
 592            (type (member :local :common) case))
 593   (with-pathname (pathname pathname)
 594     (maybe-diddle-case (%pathname-type pathname)
 595                        (and (eq case :common)
 596                             (eq (host-customary-case
 597                                  (%pathname-host pathname))
 598                                 :lower)))))
 599
 600 (defun pathname-version (pathname)
 601   #!+sb-doc
 602   "Return PATHNAME's version."
 603   (declare (type pathname-designator pathname))
 604   (with-pathname (pathname pathname)
 605     (%pathname-version pathname)))
 606 \f
 607 ;;;; namestrings
 608
 609 ;;; Handle the case for PARSE-NAMESTRING parsing a potentially
 610 ;;; syntactically valid logical namestring with an explicit host.
 611 ;;;
 612 ;;; This then isn't fully general -- we are relying on the fact that
 613 ;;; we will only pass to parse-namestring namestring with an explicit
 614 ;;; logical host, so that we can pass the host return from
 615 ;;; parse-logical-namestring through to %PARSE-NAMESTRING as a truth
 616 ;;; value. Yeah, this is probably a KLUDGE - CSR, 2002-04-18
 617 (defun parseable-logical-namestring-p (namestr start end)
 618   (catch 'exit
 619     (handler-bind
 620         ((namestring-parse-error (lambda (c)
 621                                    (declare (ignore c))
 622                                    (throw 'exit nil))))
 623       (let ((colon (position #\: namestr :start start :end end)))
 624         (when colon
 625           (let ((potential-host
 626                  (logical-word-or-lose (subseq namestr start colon))))
 627             ;; depending on the outcome of CSR comp.lang.lisp post
 628             ;; "can PARSE-NAMESTRING create logical hosts", we may need
 629             ;; to do things with potential-host (create it
 630             ;; temporarily, parse the namestring and unintern the
 631             ;; logical host potential-host on failure.
 632             (declare (ignore potential-host))
 633             (let ((result
 634                    (handler-bind
 635                        ((simple-type-error (lambda (c)
 636                                              (declare (ignore c))
 637                                              (throw 'exit nil))))
 638                      (parse-logical-namestring namestr start end))))
 639               ;; if we got this far, we should have an explicit host
 640               ;; (first return value of parse-logical-namestring)
 641               (aver result)
 642               result)))))))
 643
 644 ;;; Handle the case where PARSE-NAMESTRING is actually parsing a
 645 ;;; namestring. We pick off the :JUNK-ALLOWED case then find a host to
 646 ;;; use for parsing, call the parser, then check whether the host matches.
 647 (defun %parse-namestring (namestr host defaults start end junk-allowed)
 648   (declare (type (or host null) host)
 649            (type string namestr)
 650            (type index start)
 651            (type (or index null) end))
 652   (cond
 653     (junk-allowed
 654      (handler-case
 655          (%parse-namestring namestr host defaults start end nil)
 656        (namestring-parse-error (condition)
 657          (values nil (namestring-parse-error-offset condition)))))
 658     (t
 659      (let* ((end (%check-vector-sequence-bounds namestr start end)))
 660        (multiple-value-bind (new-host device directory file type version)
 661            ;; Comments below are quotes from the HyperSpec
 662            ;; PARSE-NAMESTRING entry, reproduced here to demonstrate
 663            ;; that we actually have to do things this way rather than
 664            ;; some possibly more logical way. - CSR, 2002-04-18
 665            (cond
 666              ;; "If host is a logical host then thing is parsed as a
 667              ;; logical pathname namestring on the host."
 668              (host (funcall (host-parse host) namestr start end))
 669              ;; "If host is nil and thing is a syntactically valid
 670              ;; logical pathname namestring containing an explicit
 671              ;; host, then it is parsed as a logical pathname
 672              ;; namestring."
 673              ((parseable-logical-namestring-p namestr start end)
 674               (parse-logical-namestring namestr start end))
 675              ;; "If host is nil, default-pathname is a logical
 676              ;; pathname, and thing is a syntactically valid logical
 677              ;; pathname namestring without an explicit host, then it
 678              ;; is parsed as a logical pathname namestring on the
 679              ;; host that is the host component of default-pathname."
 680              ;;
 681              ;; "Otherwise, the parsing of thing is
 682              ;; implementation-defined."
 683              ;;
 684              ;; Both clauses are handled here, as the default
 685              ;; *DEFAULT-PATHNAME-DEFAULTS has a SB-IMPL::UNIX-HOST
 686              ;; for a host.
 687              ((pathname-host defaults)
 688               (funcall (host-parse (pathname-host defaults))
 689                        namestr
 690                        start
 691                        end))
 692              ;; I don't think we should ever get here, as the default
 693              ;; host will always have a non-null HOST, given that we
 694              ;; can't create a new pathname without going through
 695              ;; *DEFAULT-PATHNAME-DEFAULTS*, which has a non-null
 696              ;; host...
 697              (t (bug "Fallen through COND in %PARSE-NAMESTRING")))
 698          (when (and host new-host (not (eq new-host host)))
 699            (error 'simple-type-error
 700                   :datum new-host
 701                   ;; Note: ANSI requires that this be a TYPE-ERROR,
 702                   ;; but there seems to be no completely correct
 703                   ;; value to use for TYPE-ERROR-EXPECTED-TYPE.
 704                   ;; Instead, we return a sort of "type error allowed
 705                   ;; type", trying to say "it would be OK if you
 706                   ;; passed NIL as the host value" but not mentioning
 707                   ;; that a matching string would be OK too.
 708                   :expected-type 'null
 709                   :format-control
 710                   "The host in the namestring, ~S,~@
 711                     does not match the explicit HOST argument, ~S."
 712                   :format-arguments (list new-host host)))
 713          (let ((pn-host (or new-host host (pathname-host defaults))))
 714            (values (%make-maybe-logical-pathname
 715                     pn-host device directory file type version)
 716                    end)))))))
 717
 718 ;;; If NAMESTR begins with a colon-terminated, defined, logical host,
 719 ;;; then return that host, otherwise return NIL.
 720 (defun extract-logical-host-prefix (namestr start end)
 721   (declare (type simple-base-string namestr)
 722            (type index start end)
 723            (values (or logical-host null)))
 724   (let ((colon-pos (position #\: namestr :start start :end end)))
 725     (if colon-pos
 726         (values (gethash (nstring-upcase (subseq namestr start colon-pos))
 727                          *logical-hosts*))
 728         nil)))
 729
 730 (defun parse-namestring (thing
 731                          &optional
 732                          host
 733                          (defaults *default-pathname-defaults*)
 734                          &key (start 0) end junk-allowed)
 735   (declare (type pathname-designator thing)
 736            (type (or list host string (member :unspecific)) host)
 737            (type pathname defaults)
 738            (type index start)
 739            (type (or index null) end)
 740            (type (or t null) junk-allowed)
 741            (values (or null pathname) (or null index)))
 742   ;; Generally, redundant specification of information in software,
 743   ;; whether in code or in comments, is bad. However, the ANSI spec
 744   ;; for this is messy enough that it's hard to hold in short-term
 745   ;; memory, so I've recorded these redundant notes on the
 746   ;; implications of the ANSI spec.
 747   ;;
 748   ;; According to the ANSI spec, HOST can be a valid pathname host, or
 749   ;; a logical host, or NIL.
 750   ;;
 751   ;; A valid pathname host can be a valid physical pathname host or a
 752   ;; valid logical pathname host.
 753   ;;
 754   ;; A valid physical pathname host is "any of a string, a list of
 755   ;; strings, or the symbol :UNSPECIFIC, that is recognized by the
 756   ;; implementation as the name of a host". In SBCL as of 0.6.9.8,
 757   ;; that means :UNSPECIFIC: though someday we might want to
 758   ;; generalize it to allow strings like "RTFM.MIT.EDU" or lists like
 759   ;; '("RTFM" "MIT" "EDU"), that's not supported now.
 760   ;;
 761   ;; A valid logical pathname host is a string which has been defined as
 762   ;; the name of a logical host, as with LOAD-LOGICAL-PATHNAME-TRANSLATIONS.
 763   ;;
 764   ;; A logical host is an object of implementation-dependent nature. In
 765   ;; SBCL, it's a member of the HOST class (a subclass of STRUCTURE-OBJECT).
 766   (let ((found-host (etypecase host
 767                       ((string 0)
 768                        ;; This is a special host. It's not valid as a
 769                        ;; logical host, so it is a sensible thing to
 770                        ;; designate the physical Unix host object. So
 771                        ;; we do that.
 772                        *unix-host*)
 773                       (string
 774                        ;; In general ANSI-compliant Common Lisps, a
 775                        ;; string might also be a physical pathname host,
 776                        ;; but ANSI leaves this up to the implementor,
 777                        ;; and in SBCL we don't do it, so it must be a
 778                        ;; logical host.
 779                        (find-logical-host host))
 780                       ((or null (member :unspecific))
 781                        ;; CLHS says that HOST=:UNSPECIFIC has
 782                        ;; implementation-defined behavior. We
 783                        ;; just turn it into NIL.
 784                        nil)
 785                       (list
 786                        ;; ANSI also allows LISTs to designate hosts,
 787                        ;; but leaves its interpretation
 788                        ;; implementation-defined. Our interpretation
 789                        ;; is that it's unsupported.:-|
 790                        (error "A LIST representing a pathname host is not ~
 791                               supported in this implementation:~%  ~S"
 792                               host))
 793                       (host
 794                        host))))
 795     (declare (type (or null host) found-host))
 796     (etypecase thing
 797       (simple-string
 798        (%parse-namestring thing found-host defaults start end junk-allowed))
 799       (string
 800        (%parse-namestring (coerce thing 'simple-string)
 801                           found-host defaults start end junk-allowed))
 802       (pathname
 803        (let ((defaulted-host (or found-host (%pathname-host defaults))))
 804          (declare (type host defaulted-host))
 805          (unless (eq defaulted-host (%pathname-host thing))
 806            (error "The HOST argument doesn't match the pathname host:~%  ~
 807                   ~S and ~S."
 808                   defaulted-host (%pathname-host thing))))
 809        (values thing start))
 810       (stream
 811        (let ((name (file-name thing)))
 812          (unless name
 813            (error "can't figure out the file associated with stream:~%  ~S"
 814                   thing))
 815          (values name nil))))))
 816
 817 (defun namestring (pathname)
 818   #!+sb-doc
 819   "Construct the full (name)string form of the pathname."
 820   (declare (type pathname-designator pathname))
 821   (with-pathname (pathname pathname)
 822     (when pathname
 823       (let ((host (%pathname-host pathname)))
 824         (unless host
 825           (error "can't determine the namestring for pathnames with no ~
 826                   host:~%  ~S" pathname))
 827         (funcall (host-unparse host) pathname)))))
 828
 829 (defun host-namestring (pathname)
 830   #!+sb-doc
 831   "Return a string representation of the name of the host in the pathname."
 832   (declare (type pathname-designator pathname))
 833   (with-pathname (pathname pathname)
 834     (let ((host (%pathname-host pathname)))
 835       (if host
 836           (funcall (host-unparse-host host) pathname)
 837           (error
 838            "can't determine the namestring for pathnames with no host:~%  ~S"
 839            pathname)))))
 840
 841 (defun directory-namestring (pathname)
 842   #!+sb-doc
 843   "Return a string representation of the directories used in the pathname."
 844   (declare (type pathname-designator pathname))
 845   (with-pathname (pathname pathname)
 846     (let ((host (%pathname-host pathname)))
 847       (if host
 848           (funcall (host-unparse-directory host) pathname)
 849           (error
 850            "can't determine the namestring for pathnames with no host:~%  ~S"
 851            pathname)))))
 852
 853 (defun file-namestring (pathname)
 854   #!+sb-doc
 855   "Return a string representation of the name used in the pathname."
 856   (declare (type pathname-designator pathname))
 857   (with-pathname (pathname pathname)
 858     (let ((host (%pathname-host pathname)))
 859       (if host
 860           (funcall (host-unparse-file host) pathname)
 861           (error
 862            "can't determine the namestring for pathnames with no host:~%  ~S"
 863            pathname)))))
 864
 865 (defun enough-namestring (pathname
 866                           &optional
 867                           (defaults *default-pathname-defaults*))
 868   #!+sb-doc
 869   "Return an abbreviated pathname sufficent to identify the pathname relative
 870    to the defaults."
 871   (declare (type pathname-designator pathname))
 872   (with-pathname (pathname pathname)
 873     (let ((host (%pathname-host pathname)))
 874       (if host
 875           (with-pathname (defaults defaults)
 876             (funcall (host-unparse-enough host) pathname defaults))
 877           (error
 878            "can't determine the namestring for pathnames with no host:~%  ~S"
 879            pathname)))))
 880 \f
 881 ;;;; wild pathnames
 882
 883 (defun wild-pathname-p (pathname &optional field-key)
 884   #!+sb-doc
 885   "Predicate for determining whether pathname contains any wildcards."
 886   (declare (type pathname-designator pathname)
 887            (type (member nil :host :device :directory :name :type :version)
 888                  field-key))
 889   (with-pathname (pathname pathname)
 890     (flet ((frob (x)
 891              (or (pattern-p x) (member x '(:wild :wild-inferiors)))))
 892       (ecase field-key
 893         ((nil)
 894          (or (wild-pathname-p pathname :host)
 895              (wild-pathname-p pathname :device)
 896              (wild-pathname-p pathname :directory)
 897              (wild-pathname-p pathname :name)
 898              (wild-pathname-p pathname :type)
 899              (wild-pathname-p pathname :version)))
 900         (:host (frob (%pathname-host pathname)))
 901         (:device (frob (%pathname-host pathname)))
 902         (:directory (some #'frob (%pathname-directory pathname)))
 903         (:name (frob (%pathname-name pathname)))
 904         (:type (frob (%pathname-type pathname)))
 905         (:version (frob (%pathname-version pathname)))))))
 906
 907 (defun pathname-match-p (in-pathname in-wildname)
 908   #!+sb-doc
 909   "Pathname matches the wildname template?"
 910   (declare (type pathname-designator in-pathname))
 911   (with-pathname (pathname in-pathname)
 912     (with-pathname (wildname in-wildname)
 913       (macrolet ((frob (field &optional (op 'components-match))
 914                    `(or (null (,field wildname))
 915                         (,op (,field pathname) (,field wildname)))))
 916         (and (or (null (%pathname-host wildname))
 917                  (eq (%pathname-host wildname) (%pathname-host pathname)))
 918              (frob %pathname-device)
 919              (frob %pathname-directory directory-components-match)
 920              (frob %pathname-name)
 921              (frob %pathname-type)
 922              (frob %pathname-version))))))
 923
 924 ;;; Place the substitutions into the pattern and return the string or pattern
 925 ;;; that results. If DIDDLE-CASE is true, we diddle the result case as well,
 926 ;;; in case we are translating between hosts with difference conventional case.
 927 ;;; The second value is the tail of subs with all of the values that we used up
 928 ;;; stripped off. Note that PATTERN-MATCHES matches all consecutive wildcards
 929 ;;; as a single string, so we ignore subsequent contiguous wildcards.
 930 (defun substitute-into (pattern subs diddle-case)
 931   (declare (type pattern pattern)
 932            (type list subs)
 933            (values (or simple-base-string pattern) list))
 934   (let ((in-wildcard nil)
 935         (pieces nil)
 936         (strings nil))
 937     (dolist (piece (pattern-pieces pattern))
 938       (cond ((simple-string-p piece)
 939              (push piece strings)
 940              (setf in-wildcard nil))
 941             (in-wildcard)
 942             (t
 943              (setf in-wildcard t)
 944              (unless subs
 945                (error "not enough wildcards in FROM pattern to match ~
 946                        TO pattern:~%  ~S"
 947                       pattern))
 948              (let ((sub (pop subs)))
 949                (typecase sub
 950                  (pattern
 951                   (when strings
 952                     (push (apply #'concatenate 'simple-string
 953                                  (nreverse strings))
 954                           pieces))
 955                   (dolist (piece (pattern-pieces sub))
 956                     (push piece pieces)))
 957                  (simple-string
 958                   (push sub strings))
 959                  (t
 960                   (error "can't substitute this into the middle of a word:~
 961                           ~%  ~S"
 962                          sub)))))))
 963
 964     (when strings
 965       (push (apply #'concatenate 'simple-string (nreverse strings))
 966             pieces))
 967     (values
 968      (maybe-diddle-case
 969       (if (and pieces (simple-string-p (car pieces)) (null (cdr pieces)))
 970           (car pieces)
 971           (make-pattern (nreverse pieces)))
 972       diddle-case)
 973      subs)))
 974
 975 ;;; Called when we can't see how source and from matched.
 976 (defun didnt-match-error (source from)
 977   (error "Pathname components from SOURCE and FROM args to TRANSLATE-PATHNAME~@
 978           did not match:~%  ~S ~S"
 979          source from))
 980
 981 ;;; Do TRANSLATE-COMPONENT for all components except host and directory.
 982 (defun translate-component (source from to diddle-case)
 983   (typecase to
 984     (pattern
 985      (typecase from
 986        (pattern
 987         (typecase source
 988           (pattern
 989            (if (pattern= from source)
 990                source
 991                (didnt-match-error source from)))
 992           (simple-string
 993            (multiple-value-bind (won subs) (pattern-matches from source)
 994              (if won
 995                  (values (substitute-into to subs diddle-case))
 996                  (didnt-match-error source from))))
 997           (t
 998            (maybe-diddle-case source diddle-case))))
 999        ((member :wild)
1000         (values (substitute-into to (list source) diddle-case)))
1001        (t
1002         (if (components-match source from)
1003             (maybe-diddle-case source diddle-case)
1004             (didnt-match-error source from)))))
1005     ((member nil :wild)
1006      (maybe-diddle-case source diddle-case))
1007     (t
1008      (if (components-match source from)
1009          to
1010          (didnt-match-error source from)))))
1011
1012 ;;; Return a list of all the things that we want to substitute into the TO
1013 ;;; pattern (the things matched by from on source.)  When From contains
1014 ;;; :WILD-INFERIORS, the result contains a sublist of the matched source
1015 ;;; subdirectories.
1016 (defun compute-directory-substitutions (orig-source orig-from)
1017   (let ((source orig-source)
1018         (from orig-from))
1019     (collect ((subs))
1020       (loop
1021         (unless source
1022           (unless (every (lambda (x) (eq x :wild-inferiors)) from)
1023             (didnt-match-error orig-source orig-from))
1024           (subs ())
1025           (return))
1026         (unless from (didnt-match-error orig-source orig-from))
1027         (let ((from-part (pop from))
1028               (source-part (pop source)))
1029           (typecase from-part
1030             (pattern
1031              (typecase source-part
1032                (pattern
1033                 (if (pattern= from-part source-part)
1034                     (subs source-part)
1035                     (didnt-match-error orig-source orig-from)))
1036                (simple-string
1037                 (multiple-value-bind (won new-subs)
1038                     (pattern-matches from-part source-part)
1039                   (if won
1040                       (dolist (sub new-subs)
1041                         (subs sub))
1042                       (didnt-match-error orig-source orig-from))))
1043                (t
1044                 (didnt-match-error orig-source orig-from))))
1045             ((member :wild)
1046              (subs source-part))
1047             ((member :wild-inferiors)
1048              (let ((remaining-source (cons source-part source)))
1049                (collect ((res))
1050                  (loop
1051                    (when (directory-components-match remaining-source from)
1052                      (return))
1053                    (unless remaining-source
1054                      (didnt-match-error orig-source orig-from))
1055                    (res (pop remaining-source)))
1056                  (subs (res))
1057                  (setq source remaining-source))))
1058             (simple-string
1059              (unless (and (simple-string-p source-part)
1060                           (string= from-part source-part))
1061                (didnt-match-error orig-source orig-from)))
1062             (t
1063              (didnt-match-error orig-source orig-from)))))
1064       (subs))))
1065
1066 ;;; This is called by TRANSLATE-PATHNAME on the directory components
1067 ;;; of its argument pathnames to produce the result directory
1068 ;;; component. If this leaves the directory NIL, we return the source
1069 ;;; directory. The :RELATIVE or :ABSOLUTE is taken from the source
1070 ;;; directory, except if TO is :ABSOLUTE, in which case the result
1071 ;;; will be :ABSOLUTE.
1072 (defun translate-directories (source from to diddle-case)
1073   (if (not (and source to from))
1074       (or (and to (null source) (remove :wild-inferiors to))
1075           (mapcar (lambda (x) (maybe-diddle-case x diddle-case)) source))
1076       (collect ((res))
1077                ;; If TO is :ABSOLUTE, the result should still be :ABSOLUTE.
1078                (res (if (eq (first to) :absolute)
1079                  :absolute
1080                  (first source)))
1081         (let ((subs-left (compute-directory-substitutions (rest source)
1082                                                           (rest from))))
1083           (dolist (to-part (rest to))
1084             (typecase to-part
1085               ((member :wild)
1086                (aver subs-left)
1087                (let ((match (pop subs-left)))
1088                  (when (listp match)
1089                    (error ":WILD-INFERIORS is not paired in from and to ~
1090                            patterns:~%  ~S ~S" from to))
1091                  (res (maybe-diddle-case match diddle-case))))
1092               ((member :wild-inferiors)
1093                (aver subs-left)
1094                (let ((match (pop subs-left)))
1095                  (unless (listp match)
1096                    (error ":WILD-INFERIORS not paired in from and to ~
1097                            patterns:~%  ~S ~S" from to))
1098                  (dolist (x match)
1099                    (res (maybe-diddle-case x diddle-case)))))
1100               (pattern
1101                (multiple-value-bind
1102                    (new new-subs-left)
1103                    (substitute-into to-part subs-left diddle-case)
1104                  (setf subs-left new-subs-left)
1105                  (res new)))
1106               (t (res to-part)))))
1107         (res))))
1108
1109 (defun translate-pathname (source from-wildname to-wildname &key)
1110   #!+sb-doc
1111   "Use the source pathname to translate the from-wildname's wild and
1112    unspecified elements into a completed to-pathname based on the to-wildname."
1113   (declare (type pathname-designator source from-wildname to-wildname))
1114   (with-pathname (source source)
1115     (with-pathname (from from-wildname)
1116       (with-pathname (to to-wildname)
1117           (let* ((source-host (%pathname-host source))
1118                  (to-host (%pathname-host to))
1119                  (diddle-case
1120                   (and source-host to-host
1121                        (not (eq (host-customary-case source-host)
1122                                 (host-customary-case to-host))))))
1123             (macrolet ((frob (field &optional (op 'translate-component))
1124                          `(let ((result (,op (,field source)
1125                                              (,field from)
1126                                              (,field to)
1127                                              diddle-case)))
1128                             (if (eq result :error)
1129                                 (error "~S doesn't match ~S." source from)
1130                                 result))))
1131               (%make-maybe-logical-pathname
1132                (or to-host source-host)
1133                (frob %pathname-device)
1134                (frob %pathname-directory translate-directories)
1135                (frob %pathname-name)
1136                (frob %pathname-type)
1137                (frob %pathname-version))))))))
1138 \f
1139 ;;;;  logical pathname support. ANSI 92-102 specification.
1140 ;;;;
1141 ;;;;  As logical-pathname translations are loaded they are
1142 ;;;;  canonicalized as patterns to enable rapid efficient translation
1143 ;;;;  into physical pathnames.
1144
1145 ;;;; utilities
1146
1147 ;;; Canonicalize a logical pathname word by uppercasing it checking that it
1148 ;;; contains only legal characters.
1149 (defun logical-word-or-lose (word)
1150   (declare (string word))
1151   (when (string= word "")
1152     (error 'namestring-parse-error
1153            :complaint "Attempted to treat invalid logical hostname ~
1154                        as a logical host:~%  ~S"
1155            :args (list word)
1156            :namestring word :offset 0))
1157   (let ((word (string-upcase word)))
1158     (dotimes (i (length word))
1159       (let ((ch (schar word i)))
1160         (unless (or (alpha-char-p ch) (digit-char-p ch) (char= ch #\-))
1161           (error 'namestring-parse-error
1162                  :complaint "logical namestring character which ~
1163                              is not alphanumeric or hyphen:~%  ~S"
1164                  :args (list ch)
1165                  :namestring word :offset i))))
1166     word))
1167
1168 ;;; Given a logical host or string, return a logical host. If ERROR-P
1169 ;;; is NIL, then return NIL when no such host exists.
1170 (defun find-logical-host (thing &optional (errorp t))
1171   (etypecase thing
1172     (string
1173      (let ((found (gethash (logical-word-or-lose thing)
1174                            *logical-hosts*)))
1175        (if (or found (not errorp))
1176            found
1177            ;; This is the error signalled from e.g.
1178            ;; LOGICAL-PATHNAME-TRANSLATIONS when host is not a defined
1179            ;; host, and ANSI specifies that that's a TYPE-ERROR.
1180            (error 'simple-type-error
1181                   :datum thing
1182                   ;; God only knows what ANSI expects us to use for
1183                   ;; the EXPECTED-TYPE here. Maybe this will be OK..
1184                   :expected-type
1185                   '(and string (satisfies logical-pathname-translations))
1186                   :format-control "logical host not yet defined: ~S"
1187                   :format-arguments (list thing)))))
1188     (logical-host thing)))
1189
1190 ;;; Given a logical host name or host, return a logical host, creating
1191 ;;; a new one if necessary.
1192 (defun intern-logical-host (thing)
1193   (declare (values logical-host))
1194   (or (find-logical-host thing nil)
1195       (let* ((name (logical-word-or-lose thing))
1196              (new (make-logical-host :name name)))
1197         (setf (gethash name *logical-hosts*) new)
1198         new)))
1199 \f
1200 ;;;; logical pathname parsing
1201
1202 ;;; Deal with multi-char wildcards in a logical pathname token.
1203 (defun maybe-make-logical-pattern (namestring chunks)
1204   (let ((chunk (caar chunks)))
1205     (collect ((pattern))
1206       (let ((last-pos 0)
1207             (len (length chunk)))
1208         (declare (fixnum last-pos))
1209         (loop
1210           (when (= last-pos len) (return))
1211           (let ((pos (or (position #\* chunk :start last-pos) len)))
1212             (if (= pos last-pos)
1213                 (when (pattern)
1214                   (error 'namestring-parse-error
1215                          :complaint "double asterisk inside of logical ~
1216                                      word: ~S"
1217                          :args (list chunk)
1218                          :namestring namestring
1219                          :offset (+ (cdar chunks) pos)))
1220                 (pattern (subseq chunk last-pos pos)))
1221             (if (= pos len)
1222                 (return)
1223                 (pattern :multi-char-wild))
1224             (setq last-pos (1+ pos)))))
1225         (aver (pattern))
1226         (if (cdr (pattern))
1227             (make-pattern (pattern))
1228             (let ((x (car (pattern))))
1229               (if (eq x :multi-char-wild)
1230                   :wild
1231                   x))))))
1232
1233 ;;; Return a list of conses where the CDR is the start position and
1234 ;;; the CAR is a string (token) or character (punctuation.)
1235 (defun logical-chunkify (namestr start end)
1236   (collect ((chunks))
1237     (do ((i start (1+ i))
1238          (prev 0))
1239         ((= i end)
1240          (when (> end prev)
1241             (chunks (cons (nstring-upcase (subseq namestr prev end)) prev))))
1242       (let ((ch (schar namestr i)))
1243         (unless (or (alpha-char-p ch) (digit-char-p ch)
1244                     (member ch '(#\- #\*)))
1245           (when (> i prev)
1246             (chunks (cons (nstring-upcase (subseq namestr prev i)) prev)))
1247           (setq prev (1+ i))
1248           (unless (member ch '(#\; #\: #\.))
1249             (error 'namestring-parse-error
1250                    :complaint "illegal character for logical pathname:~%  ~S"
1251                    :args (list ch)
1252                    :namestring namestr
1253                    :offset i))
1254           (chunks (cons ch i)))))
1255     (chunks)))
1256
1257 ;;; Break up a logical-namestring, always a string, into its
1258 ;;; constituent parts.
1259 (defun parse-logical-namestring (namestr start end)
1260   (declare (type simple-base-string namestr)
1261            (type index start end))
1262   (collect ((directory))
1263     (let ((host nil)
1264           (name nil)
1265           (type nil)
1266           (version nil))
1267       (labels ((expecting (what chunks)
1268                  (unless (and chunks (simple-string-p (caar chunks)))
1269                    (error 'namestring-parse-error
1270                           :complaint "expecting ~A, got ~:[nothing~;~S~]."
1271                           :args (list what (caar chunks) (caar chunks))
1272                           :namestring namestr
1273                           :offset (if chunks (cdar chunks) end)))
1274                  (caar chunks))
1275                (parse-host (chunks)
1276                  (case (caadr chunks)
1277                    (#\:
1278                     (setq host
1279                           (find-logical-host (expecting "a host name" chunks)))
1280                     (parse-relative (cddr chunks)))
1281                    (t
1282                     (parse-relative chunks))))
1283                (parse-relative (chunks)
1284                  (case (caar chunks)
1285                    (#\;
1286                     (directory :relative)
1287                     (parse-directory (cdr chunks)))
1288                    (t
1289                     (directory :absolute) ; Assumption! Maybe revoked later.
1290                     (parse-directory chunks))))
1291                (parse-directory (chunks)
1292                  (case (caadr chunks)
1293                    (#\;
1294                     (directory
1295                      (let ((res (expecting "a directory name" chunks)))
1296                        (cond ((string= res "..") :up)
1297                              ((string= res "**") :wild-inferiors)
1298                              (t
1299                               (maybe-make-logical-pattern namestr chunks)))))
1300                     (parse-directory (cddr chunks)))
1301                    (t
1302                     (parse-name chunks))))
1303                (parse-name (chunks)
1304                  (when chunks
1305                    (expecting "a file name" chunks)
1306                    (setq name (maybe-make-logical-pattern namestr chunks))
1307                    (expecting-dot (cdr chunks))))
1308                (expecting-dot (chunks)
1309                  (when chunks
1310                    (unless (eql (caar chunks) #\.)
1311                      (error 'namestring-parse-error
1312                             :complaint "expecting a dot, got ~S."
1313                             :args (list (caar chunks))
1314                             :namestring namestr
1315                             :offset (cdar chunks)))
1316                    (if type
1317                        (parse-version (cdr chunks))
1318                        (parse-type (cdr chunks)))))
1319                (parse-type (chunks)
1320                  (expecting "a file type" chunks)
1321                  (setq type (maybe-make-logical-pattern namestr chunks))
1322                  (expecting-dot (cdr chunks)))
1323                (parse-version (chunks)
1324                  (let ((str (expecting "a positive integer, * or NEWEST"
1325                                        chunks)))
1326                    (cond
1327                     ((string= str "*") (setq version :wild))
1328                     ((string= str "NEWEST") (setq version :newest))
1329                     (t
1330                      (multiple-value-bind (res pos)
1331                          (parse-integer str :junk-allowed t)
1332                        (unless (and res (plusp res))
1333                          (error 'namestring-parse-error
1334                                 :complaint "expected a positive integer, ~
1335                                             got ~S"
1336                                 :args (list str)
1337                                 :namestring namestr
1338                                 :offset (+ pos (cdar chunks))))
1339                        (setq version res)))))
1340                  (when (cdr chunks)
1341                    (error 'namestring-parse-error
1342                           :complaint "extra stuff after end of file name"
1343                           :namestring namestr
1344                           :offset (cdadr chunks)))))
1345         (parse-host (logical-chunkify namestr start end)))
1346       (values host :unspecific (directory) name type version))))
1347
1348 ;;; We can't initialize this yet because not all host methods are
1349 ;;; loaded yet.
1350 (defvar *logical-pathname-defaults*)
1351
1352 (defun logical-pathname (pathspec)
1353   #!+sb-doc
1354   "Converts the pathspec argument to a logical-pathname and returns it."
1355   (declare (type (or logical-pathname string stream) pathspec)
1356            (values logical-pathname))
1357   (if (typep pathspec 'logical-pathname)
1358       pathspec
1359       (let ((res (parse-namestring pathspec nil *logical-pathname-defaults*)))
1360         (when (eq (%pathname-host res)
1361                   (%pathname-host *logical-pathname-defaults*))
1362           (error "This logical namestring does not specify a host:~%  ~S"
1363                  pathspec))
1364         res)))
1365 \f
1366 ;;;; logical pathname unparsing
1367
1368 (defun unparse-logical-directory (pathname)
1369   (declare (type pathname pathname))
1370   (collect ((pieces))
1371     (let ((directory (%pathname-directory pathname)))
1372       (when directory
1373         (ecase (pop directory)
1374           (:absolute) ; nothing special
1375           (:relative (pieces ";")))
1376         (dolist (dir directory)
1377           (cond ((or (stringp dir) (pattern-p dir))
1378                  (pieces (unparse-logical-piece dir))
1379                  (pieces ";"))
1380                 ((eq dir :wild)
1381                  (pieces "*;"))
1382                 ((eq dir :wild-inferiors)
1383                  (pieces "**;"))
1384                 (t
1385                  (error "invalid directory component: ~S" dir))))))
1386     (apply #'concatenate 'simple-string (pieces))))
1387
1388 (defun unparse-logical-piece (thing)
1389   (etypecase thing
1390     (simple-string thing)
1391     (pattern
1392      (collect ((strings))
1393        (dolist (piece (pattern-pieces thing))
1394          (etypecase piece
1395            (simple-string (strings piece))
1396            (keyword
1397             (cond ((eq piece :wild-inferiors)
1398                    (strings "**"))
1399                   ((eq piece :multi-char-wild)
1400                    (strings "*"))
1401                   (t (error "invalid keyword: ~S" piece))))))
1402        (apply #'concatenate 'simple-string (strings))))))
1403
1404 ;;; Unparse a logical pathname string.
1405 (defun unparse-enough-namestring (pathname defaults)
1406   (let* ((path-directory (pathname-directory pathname))
1407          (def-directory (pathname-directory defaults))
1408          (enough-directory
1409            ;; Go down the directory lists to see what matches.  What's
1410            ;; left is what we want, more or less.
1411            (cond ((and (eq (first path-directory) (first def-directory))
1412                        (eq (first path-directory) :absolute))
1413                    ;; Both paths are :ABSOLUTE, so find where the
1414                    ;; common parts end and return what's left
1415                    (do* ((p (rest path-directory) (rest p))
1416                          (d (rest def-directory) (rest d)))
1417                         ((or (endp p) (endp d)
1418                              (not (equal (first p) (first d))))
1419                          `(:relative ,@p))))
1420                  (t
1421                    ;; At least one path is :RELATIVE, so just return the
1422                    ;; original path.  If the original path is :RELATIVE,
1423                    ;; then that's the right one.  If PATH-DIRECTORY is
1424                    ;; :ABSOLUTE, we want to return that except when
1425                    ;; DEF-DIRECTORY is :ABSOLUTE, as handled above. so return
1426                    ;; the original directory.
1427                    path-directory))))
1428     (unparse-logical-namestring
1429      (make-pathname :host (pathname-host pathname)
1430                     :directory enough-directory
1431                     :name (pathname-name pathname)
1432                     :type (pathname-type pathname)
1433                     :version (pathname-version pathname)))))
1434
1435 (defun unparse-logical-namestring (pathname)
1436   (declare (type logical-pathname pathname))
1437   (concatenate 'simple-string
1438                (logical-host-name (%pathname-host pathname)) ":"
1439                (unparse-logical-directory pathname)
1440                (unparse-unix-file pathname)))
1441 \f
1442 ;;;; logical pathname translations
1443
1444 ;;; Verify that the list of translations consists of lists and prepare
1445 ;;; canonical translations. (Parse pathnames and expand out wildcards
1446 ;;; into patterns.)
1447 (defun canonicalize-logical-pathname-translations (translation-list host)
1448   (declare (type list translation-list) (type host host)
1449            (values list))
1450   (mapcar (lambda (translation)
1451             (destructuring-bind (from to) translation
1452               (list (if (typep from 'logical-pathname)
1453                         from
1454                         (parse-namestring from host))
1455                     (pathname to))))
1456           translation-list))
1457
1458 (defun logical-pathname-translations (host)
1459   #!+sb-doc
1460   "Return the (logical) host object argument's list of translations."
1461   (declare (type (or string logical-host) host)
1462            (values list))
1463   (logical-host-translations (find-logical-host host)))
1464
1465 (defun (setf logical-pathname-translations) (translations host)
1466   #!+sb-doc
1467   "Set the translations list for the logical host argument."
1468   (declare (type (or string logical-host) host)
1469            (type list translations)
1470            (values list))
1471   (let ((host (intern-logical-host host)))
1472     (setf (logical-host-canon-transls host)
1473           (canonicalize-logical-pathname-translations translations host))
1474     (setf (logical-host-translations host) translations)))
1475
1476 (defun translate-logical-pathname (pathname &key)
1477   #!+sb-doc
1478   "Translate PATHNAME to a physical pathname, which is returned."
1479   (declare (type pathname-designator pathname)
1480            (values (or null pathname)))
1481   (typecase pathname
1482     (logical-pathname
1483      (dolist (x (logical-host-canon-transls (%pathname-host pathname))
1484                 (error 'simple-file-error
1485                        :pathname pathname
1486                        :format-control "no translation for ~S"
1487                        :format-arguments (list pathname)))
1488        (destructuring-bind (from to) x
1489          (when (pathname-match-p pathname from)
1490            (return (translate-logical-pathname
1491                     (translate-pathname pathname from to)))))))
1492     (pathname pathname)
1493     (t (translate-logical-pathname (pathname pathname)))))
1494
1495 (defvar *logical-pathname-defaults*
1496   (%make-logical-pathname (make-logical-host :name "BOGUS")
1497                           :unspecific
1498                           nil
1499                           nil
1500                           nil
1501                           nil))
1502
1503 (defun load-logical-pathname-translations (host)
1504   #!+sb-doc
1505   (declare (type string host)
1506            (values (member t nil)))
1507   (if (find-logical-host host nil)
1508       ;; This host is already defined, all is well and good.
1509       t
1510       ;; ANSI: "The specific nature of the search is
1511       ;; implementation-defined." SBCL: doesn't search at all
1512       (error "logical host ~S not found" host)))