src/code/target-pathname.lisp

   1 ;;;; machine/filesystem-independent pathname functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 #!-sb-fluid (declaim (freeze-type logical-pathname logical-host))
  15 \f
  16 ;;;; UNIX-HOST stuff
  17
  18 (def!struct (unix-host
  19              (:make-load-form-fun make-unix-host-load-form)
  20              (:include host
  21                        (parse #'parse-unix-namestring)
  22                        (unparse #'unparse-unix-namestring)
  23                        (unparse-host #'unparse-unix-host)
  24                        (unparse-directory #'unparse-unix-directory)
  25                        (unparse-file #'unparse-unix-file)
  26                        (unparse-enough #'unparse-unix-enough)
  27                        (customary-case :lower))))
  28
  29 (defvar *unix-host* (make-unix-host))
  30
  31 (defun make-unix-host-load-form (host)
  32   (declare (ignore host))
  33   '*unix-host*)
  34
  35 ;;; Return a value suitable, e.g., for preinitializing
  36 ;;; *DEFAULT-PATHNAME-DEFAULTS* before *DEFAULT-PATHNAME-DEFAULTS* is
  37 ;;; initialized (at which time we can't safely call e.g. #'PATHNAME).
  38 (defun make-trivial-default-pathname ()
  39   (%make-pathname *unix-host* nil nil nil nil :newest))
  40 \f
  41 ;;; pathname methods
  42
  43 (def!method print-object ((pathname pathname) stream)
  44   (let ((namestring (handler-case (namestring pathname)
  45                       (error nil))))
  46     (if namestring
  47         (format stream "#P~S" namestring)
  48         (print-unreadable-object (pathname stream :type t)
  49           (format stream
  50                   "~@<(with no namestring) ~_:HOST ~S ~_:DEVICE ~S ~_:DIRECTORY ~S ~
  51                   ~_:NAME ~S ~_:TYPE ~S ~_:VERSION ~S~:>"
  52                   (%pathname-host pathname)
  53                   (%pathname-device pathname)
  54                   (%pathname-directory pathname)
  55                   (%pathname-name pathname)
  56                   (%pathname-type pathname)
  57                   (%pathname-version pathname))))))
  58
  59 (def!method make-load-form ((pathname pathname) &optional environment)
  60   (make-load-form-saving-slots pathname :environment environment))
  61
  62 ;;; The potential conflict with search lists requires isolating the
  63 ;;; printed representation to use the i/o macro #.(logical-pathname
  64 ;;; <path-designator>).
  65 ;;;
  66 ;;; FIXME: We don't use search lists any more, so that comment is
  67 ;;; stale, right?
  68 (def!method print-object ((pathname logical-pathname) stream)
  69   (let ((namestring (handler-case (namestring pathname)
  70                       (error nil))))
  71     (if namestring
  72         (format stream "#.(CL:LOGICAL-PATHNAME ~S)" namestring)
  73         (print-unreadable-object (pathname stream :type t)
  74           (format
  75            stream
  76            "~_:HOST ~S ~_:DIRECTORY ~S ~_:FILE ~S ~_:NAME ~S ~_:VERSION ~S"
  77            (%pathname-host pathname)
  78            (%pathname-directory pathname)
  79            (%pathname-name pathname)
  80            (%pathname-type pathname)
  81            (%pathname-version pathname))))))
  82 \f
  83 ;;; A pathname is logical if the host component is a logical host.
  84 ;;; This constructor is used to make an instance of the correct type
  85 ;;; from parsed arguments.
  86 (defun %make-maybe-logical-pathname (host device directory name type version)
  87   ;; We canonicalize logical pathname components to uppercase. ANSI
  88   ;; doesn't strictly require this, leaving it up to the implementor;
  89   ;; but the arguments given in the X3J13 cleanup issue
  90   ;; PATHNAME-LOGICAL:ADD seem compelling: we should canonicalize the
  91   ;; case, and uppercase is the ordinary way to do that.
  92   (flet ((upcase-maybe (x) (typecase x (string (logical-word-or-lose x)) (t x))))
  93     (if (typep host 'logical-host)
  94         (%make-logical-pathname host
  95                                 :unspecific
  96                                 (mapcar #'upcase-maybe directory)
  97                                 (upcase-maybe name)
  98                                 (upcase-maybe type)
  99                                 version)
 100         (%make-pathname host device directory name type version))))
 101
 102 ;;; Hash table searching maps a logical pathname's host to its
 103 ;;; physical pathname translation.
 104 (defvar *logical-hosts* (make-hash-table :test 'equal))
 105 \f
 106 ;;;; patterns
 107
 108 (def!method make-load-form ((pattern pattern) &optional environment)
 109   (make-load-form-saving-slots pattern :environment environment))
 110
 111 (def!method print-object ((pattern pattern) stream)
 112   (print-unreadable-object (pattern stream :type t)
 113     (if *print-pretty*
 114         (let ((*print-escape* t))
 115           (pprint-fill stream (pattern-pieces pattern) nil))
 116         (prin1 (pattern-pieces pattern) stream))))
 117
 118 (defun pattern= (pattern1 pattern2)
 119   (declare (type pattern pattern1 pattern2))
 120   (let ((pieces1 (pattern-pieces pattern1))
 121         (pieces2 (pattern-pieces pattern2)))
 122     (and (= (length pieces1) (length pieces2))
 123          (every (lambda (piece1 piece2)
 124                   (typecase piece1
 125                     (simple-string
 126                      (and (simple-string-p piece2)
 127                           (string= piece1 piece2)))
 128                     (cons
 129                      (and (consp piece2)
 130                           (eq (car piece1) (car piece2))
 131                           (string= (cdr piece1) (cdr piece2))))
 132                     (t
 133                      (eq piece1 piece2))))
 134                 pieces1
 135                 pieces2))))
 136
 137 ;;; If the string matches the pattern returns the multiple values T
 138 ;;; and a list of the matched strings.
 139 (defun pattern-matches (pattern string)
 140   (declare (type pattern pattern)
 141            (type simple-string string))
 142   (let ((len (length string)))
 143     (labels ((maybe-prepend (subs cur-sub chars)
 144                (if cur-sub
 145                    (let* ((len (length chars))
 146                           (new (make-string len))
 147                           (index len))
 148                      (dolist (char chars)
 149                        (setf (schar new (decf index)) char))
 150                      (cons new subs))
 151                    subs))
 152              (matches (pieces start subs cur-sub chars)
 153                (if (null pieces)
 154                    (if (= start len)
 155                        (values t (maybe-prepend subs cur-sub chars))
 156                        (values nil nil))
 157                    (let ((piece (car pieces)))
 158                      (etypecase piece
 159                        (simple-string
 160                         (let ((end (+ start (length piece))))
 161                           (and (<= end len)
 162                                (string= piece string
 163                                         :start2 start :end2 end)
 164                                (matches (cdr pieces) end
 165                                         (maybe-prepend subs cur-sub chars)
 166                                         nil nil))))
 167                        (list
 168                         (ecase (car piece)
 169                           (:character-set
 170                            (and (< start len)
 171                                 (let ((char (schar string start)))
 172                                   (if (find char (cdr piece) :test #'char=)
 173                                       (matches (cdr pieces) (1+ start) subs t
 174                                                (cons char chars))))))))
 175                        ((member :single-char-wild)
 176                         (and (< start len)
 177                              (matches (cdr pieces) (1+ start) subs t
 178                                       (cons (schar string start) chars))))
 179                        ((member :multi-char-wild)
 180                         (multiple-value-bind (won new-subs)
 181                             (matches (cdr pieces) start subs t chars)
 182                           (if won
 183                               (values t new-subs)
 184                               (and (< start len)
 185                                    (matches pieces (1+ start) subs t
 186                                             (cons (schar string start)
 187                                                   chars)))))))))))
 188       (multiple-value-bind (won subs)
 189           (matches (pattern-pieces pattern) 0 nil nil nil)
 190         (values won (reverse subs))))))
 191
 192 ;;; PATHNAME-MATCH-P for directory components
 193 (defun directory-components-match (thing wild)
 194   (or (eq thing wild)
 195       (eq wild :wild)
 196       ;; If THING has a null directory, assume that it matches
 197       ;; (:ABSOLUTE :WILD-INFERIORS) or (:RELATIVE :WILD-INFERIORS).
 198       (and (consp wild)
 199            (null thing)
 200            (member (first wild) '(:absolute :relative))
 201            (eq (second wild) :wild-inferiors))
 202       (and (consp wild)
 203            (let ((wild1 (first wild)))
 204              (if (eq wild1 :wild-inferiors)
 205                  (let ((wild-subdirs (rest wild)))
 206                    (or (null wild-subdirs)
 207                        (loop
 208                          (when (directory-components-match thing wild-subdirs)
 209                            (return t))
 210                          (pop thing)
 211                          (unless thing (return nil)))))
 212                  (and (consp thing)
 213                       (components-match (first thing) wild1)
 214                       (directory-components-match (rest thing)
 215                                                   (rest wild))))))))
 216
 217 ;;; Return true if pathname component THING is matched by WILD. (not
 218 ;;; commutative)
 219 (defun components-match (thing wild)
 220   (declare (type (or pattern symbol simple-string integer) thing wild))
 221   (or (eq thing wild)
 222       (eq wild :wild)
 223       (typecase thing
 224         (simple-base-string
 225          ;; String is matched by itself, a matching pattern or :WILD.
 226          (typecase wild
 227            (pattern
 228             (values (pattern-matches wild thing)))
 229            (simple-base-string
 230             (string= thing wild))))
 231         (pattern
 232          ;; A pattern is only matched by an identical pattern.
 233          (and (pattern-p wild) (pattern= thing wild)))
 234         (integer
 235          ;; An integer (version number) is matched by :WILD or the
 236          ;; same integer. This branch will actually always be NIL as
 237          ;; long as the version is a fixnum.
 238          (eql thing wild)))))
 239
 240 ;;; a predicate for comparing two pathname slot component sub-entries
 241 (defun compare-component (this that)
 242   (or (eql this that)
 243       (typecase this
 244         (simple-string
 245          (and (simple-string-p that)
 246               (string= this that)))
 247         (pattern
 248          (and (pattern-p that)
 249               (pattern= this that)))
 250         (cons
 251          (and (consp that)
 252               (compare-component (car this) (car that))
 253               (compare-component (cdr this) (cdr that)))))))
 254 \f
 255 ;;;; pathname functions
 256
 257 (defun pathname= (pathname1 pathname2)
 258   (declare (type pathname pathname1)
 259            (type pathname pathname2))
 260   (and (eq (%pathname-host pathname1)
 261            (%pathname-host pathname2))
 262        (compare-component (%pathname-device pathname1)
 263                           (%pathname-device pathname2))
 264        (compare-component (%pathname-directory pathname1)
 265                           (%pathname-directory pathname2))
 266        (compare-component (%pathname-name pathname1)
 267                           (%pathname-name pathname2))
 268        (compare-component (%pathname-type pathname1)
 269                           (%pathname-type pathname2))
 270        (compare-component (%pathname-version pathname1)
 271                           (%pathname-version pathname2))))
 272
 273 ;;; Convert PATHNAME-DESIGNATOR (a pathname, or string, or
 274 ;;; stream), into a pathname in pathname.
 275 ;;;
 276 ;;; FIXME: was rewritten, should be tested (or rewritten again, this
 277 ;;; time using ONCE-ONLY, *then* tested)
 278 ;;; FIXME: become SB!XC:DEFMACRO inside EVAL-WHEN (COMPILE EVAL)?
 279 (defmacro with-pathname ((pathname pathname-designator) &body body)
 280   (let ((pd0 (gensym)))
 281     `(let* ((,pd0 ,pathname-designator)
 282             (,pathname (etypecase ,pd0
 283                          (pathname ,pd0)
 284                          (string (parse-namestring ,pd0))
 285                          (file-stream (file-name ,pd0)))))
 286        ,@body)))
 287
 288 ;;; Convert the var, a host or string name for a host, into a
 289 ;;; LOGICAL-HOST structure or nil if not defined.
 290 ;;;
 291 ;;; pw notes 1/12/97 this potentially useful macro is not used anywhere
 292 ;;; and 'find-host' is not defined. 'find-logical-host' seems to be needed.
 293 #|
 294 (defmacro with-host ((var expr) &body body)
 295   `(let ((,var (let ((,var ,expr))
 296                  (typecase ,var
 297                    (logical-host ,var)
 298                    (string (find-logical-host ,var nil))
 299                    (t nil)))))
 300      ,@body))
 301 |#
 302
 303 (defun pathname (thing)
 304   #!+sb-doc
 305   "Convert thing (a pathname, string or stream) into a pathname."
 306   (declare (type pathname-designator thing))
 307   (with-pathname (pathname thing)
 308     pathname))
 309
 310 ;;; Change the case of thing if DIDDLE-P.
 311 (defun maybe-diddle-case (thing diddle-p)
 312   (if (and diddle-p (not (or (symbolp thing) (integerp thing))))
 313       (labels ((check-for (pred in)
 314                  (typecase in
 315                    (pattern
 316                     (dolist (piece (pattern-pieces in))
 317                       (when (typecase piece
 318                               (simple-string
 319                                (check-for pred piece))
 320                               (cons
 321                                (case (car piece)
 322                                  (:character-set
 323                                   (check-for pred (cdr piece))))))
 324                         (return t))))
 325                    (list
 326                     (dolist (x in)
 327                       (when (check-for pred x)
 328                         (return t))))
 329                    (simple-base-string
 330                     (dotimes (i (length in))
 331                       (when (funcall pred (schar in i))
 332                         (return t))))
 333                    (t nil)))
 334                (diddle-with (fun thing)
 335                  (typecase thing
 336                    (pattern
 337                     (make-pattern
 338                      (mapcar (lambda (piece)
 339                                (typecase piece
 340                                  (simple-base-string
 341                                   (funcall fun piece))
 342                                  (cons
 343                                   (case (car piece)
 344                                     (:character-set
 345                                      (cons :character-set
 346                                            (funcall fun (cdr piece))))
 347                                     (t
 348                                      piece)))
 349                                  (t
 350                                   piece)))
 351                              (pattern-pieces thing))))
 352                    (list
 353                     (mapcar fun thing))
 354                    (simple-base-string
 355                     (funcall fun thing))
 356                    (t
 357                     thing))))
 358         (let ((any-uppers (check-for #'upper-case-p thing))
 359               (any-lowers (check-for #'lower-case-p thing)))
 360           (cond ((and any-uppers any-lowers)
 361                  ;; mixed case, stays the same
 362                  thing)
 363                 (any-uppers
 364                  ;; all uppercase, becomes all lower case
 365                  (diddle-with (lambda (x) (if (stringp x)
 366                                               (string-downcase x)
 367                                               x)) thing))
 368                 (any-lowers
 369                  ;; all lowercase, becomes all upper case
 370                  (diddle-with (lambda (x) (if (stringp x)
 371                                               (string-upcase x)
 372                                               x)) thing))
 373                 (t
 374                  ;; no letters?  I guess just leave it.
 375                  thing))))
 376       thing))
 377
 378 (defun merge-directories (dir1 dir2 diddle-case)
 379   (if (or (eq (car dir1) :absolute)
 380           (null dir2))
 381       dir1
 382       (let ((results nil))
 383         (flet ((add (dir)
 384                  (if (and (eq dir :back)
 385                           results
 386                           (not (eq (car results) :back)))
 387                      (pop results)
 388                      (push dir results))))
 389           (dolist (dir (maybe-diddle-case dir2 diddle-case))
 390             (add dir))
 391           (dolist (dir (cdr dir1))
 392             (add dir)))
 393         (reverse results))))
 394
 395 (defun merge-pathnames (pathname
 396                         &optional
 397                         (defaults *default-pathname-defaults*)
 398                         (default-version :newest))
 399   #!+sb-doc
 400   "Construct a filled in pathname by completing the unspecified components
 401    from the defaults."
 402   (declare (type pathname-designator pathname)
 403            (type pathname-designator defaults)
 404            (values pathname))
 405   (with-pathname (defaults defaults)
 406     (let ((pathname (let ((*default-pathname-defaults* defaults))
 407                       (pathname pathname))))
 408       (let* ((default-host (%pathname-host defaults))
 409              (pathname-host (%pathname-host pathname))
 410              (diddle-case
 411               (and default-host pathname-host
 412                    (not (eq (host-customary-case default-host)
 413                             (host-customary-case pathname-host))))))
 414         (%make-maybe-logical-pathname
 415          (or pathname-host default-host)
 416          (or (%pathname-device pathname)
 417              (maybe-diddle-case (%pathname-device defaults)
 418                                 diddle-case))
 419          (merge-directories (%pathname-directory pathname)
 420                             (%pathname-directory defaults)
 421                             diddle-case)
 422          (or (%pathname-name pathname)
 423              (maybe-diddle-case (%pathname-name defaults)
 424                                 diddle-case))
 425          (or (%pathname-type pathname)
 426              (maybe-diddle-case (%pathname-type defaults)
 427                                 diddle-case))
 428          (or (%pathname-version pathname)
 429              default-version))))))
 430
 431 (defun import-directory (directory diddle-case)
 432   (etypecase directory
 433     (null nil)
 434     ((member :wild) '(:absolute :wild-inferiors))
 435     ((member :unspecific) '(:relative))
 436     (list
 437      (collect ((results))
 438        (results (pop directory))
 439        (dolist (piece directory)
 440          (cond ((member piece '(:wild :wild-inferiors :up :back))
 441                 (results piece))
 442                ((or (simple-string-p piece) (pattern-p piece))
 443                 (results (maybe-diddle-case piece diddle-case)))
 444                ((stringp piece)
 445                 (results (maybe-diddle-case (coerce piece 'simple-string)
 446                                             diddle-case)))
 447                (t
 448                 (error "~S is not allowed as a directory component." piece))))
 449        (results)))
 450     (simple-string
 451      `(:absolute
 452        ,(maybe-diddle-case directory diddle-case)))
 453     (string
 454      `(:absolute
 455        ,(maybe-diddle-case (coerce directory 'simple-string)
 456                            diddle-case)))))
 457
 458 (defun make-pathname (&key host
 459                            (device nil devp)
 460                            (directory nil dirp)
 461                            (name nil namep)
 462                            (type nil typep)
 463                            (version nil versionp)
 464                            defaults
 465                            (case :local))
 466   #!+sb-doc
 467   "Makes a new pathname from the component arguments. Note that host is
 468 a host-structure or string."
 469   (declare (type (or string host pathname-component-tokens) host)
 470            (type (or string pathname-component-tokens) device)
 471            (type (or list string pattern pathname-component-tokens) directory)
 472            (type (or string pattern pathname-component-tokens) name type)
 473            (type (or integer pathname-component-tokens (member :newest))
 474                  version)
 475            (type (or pathname-designator null) defaults)
 476            (type (member :common :local) case))
 477   (let* ((defaults (when defaults
 478                      (with-pathname (defaults defaults) defaults)))
 479          (default-host (if defaults
 480                            (%pathname-host defaults)
 481                            (pathname-host *default-pathname-defaults*)))
 482          ;; Raymond Toy writes: CLHS says make-pathname can take a
 483          ;; string (as a logical-host) for the host part. We map that
 484          ;; string into the corresponding logical host structure.
 485          ;;
 486          ;; Paul Werkowski writes:
 487          ;; HyperSpec says for the arg to MAKE-PATHNAME;
 488          ;; "host---a valid physical pathname host. ..."
 489          ;; where it probably means -- a valid pathname host.
 490          ;; "valid pathname host n. a valid physical pathname host or
 491          ;; a valid logical pathname host."
 492          ;; and defines
 493          ;; "valid physical pathname host n. any of a string,
 494          ;; a list of strings, or the symbol :unspecific,
 495          ;; that is recognized by the implementation as the name of a host."
 496          ;; "valid logical pathname host n. a string that has been defined
 497          ;; as the name of a logical host. ..."
 498          ;; HS is silent on what happens if the :HOST arg is NOT one of these.
 499          ;; It seems an error message is appropriate.
 500          (host (typecase host
 501                  (host host)            ; A valid host, use it.
 502                  ((string 0) *unix-host*) ; "" cannot be a logical host
 503                  (string (find-logical-host host t)) ; logical-host or lose.
 504                  (t default-host)))     ; unix-host
 505          (diddle-args (and (eq (host-customary-case host) :lower)
 506                            (eq case :common)))
 507          (diddle-defaults
 508           (not (eq (host-customary-case host)
 509                    (host-customary-case default-host))))
 510          (dev (if devp device (if defaults (%pathname-device defaults))))
 511          (dir (import-directory directory diddle-args))
 512          (ver (cond
 513                (versionp version)
 514                (defaults (%pathname-version defaults))
 515                (t nil))))
 516     (when (and defaults (not dirp))
 517       (setf dir
 518             (merge-directories dir
 519                                (%pathname-directory defaults)
 520                                diddle-defaults)))
 521
 522     (macrolet ((pick (var varp field)
 523                  `(cond ((or (simple-string-p ,var)
 524                              (pattern-p ,var))
 525                          (maybe-diddle-case ,var diddle-args))
 526                         ((stringp ,var)
 527                          (maybe-diddle-case (coerce ,var 'simple-string)
 528                                             diddle-args))
 529                         (,varp
 530                          (maybe-diddle-case ,var diddle-args))
 531                         (defaults
 532                          (maybe-diddle-case (,field defaults)
 533                                             diddle-defaults))
 534                         (t
 535                          nil))))
 536       (%make-maybe-logical-pathname host
 537                                     dev ; forced to :UNSPECIFIC when logical
 538                                     dir
 539                                     (pick name namep %pathname-name)
 540                                     (pick type typep %pathname-type)
 541                                     ver))))
 542
 543 (defun pathname-host (pathname &key (case :local))
 544   #!+sb-doc
 545   "Return PATHNAME's host."
 546   (declare (type pathname-designator pathname)
 547            (type (member :local :common) case)
 548            (values host)
 549            (ignore case))
 550   (with-pathname (pathname pathname)
 551     (%pathname-host pathname)))
 552
 553 (defun pathname-device (pathname &key (case :local))
 554   #!+sb-doc
 555   "Return PATHNAME's device."
 556   (declare (type pathname-designator pathname)
 557            (type (member :local :common) case))
 558   (with-pathname (pathname pathname)
 559     (maybe-diddle-case (%pathname-device pathname)
 560                        (and (eq case :common)
 561                             (eq (host-customary-case
 562                                  (%pathname-host pathname))
 563                                 :lower)))))
 564
 565 (defun pathname-directory (pathname &key (case :local))
 566   #!+sb-doc
 567   "Return PATHNAME's directory."
 568   (declare (type pathname-designator pathname)
 569            (type (member :local :common) case))
 570   (with-pathname (pathname pathname)
 571     (maybe-diddle-case (%pathname-directory pathname)
 572                        (and (eq case :common)
 573                             (eq (host-customary-case
 574                                  (%pathname-host pathname))
 575                                 :lower)))))
 576 (defun pathname-name (pathname &key (case :local))
 577   #!+sb-doc
 578   "Return PATHNAME's name."
 579   (declare (type pathname-designator pathname)
 580            (type (member :local :common) case))
 581   (with-pathname (pathname pathname)
 582     (maybe-diddle-case (%pathname-name pathname)
 583                        (and (eq case :common)
 584                             (eq (host-customary-case
 585                                  (%pathname-host pathname))
 586                                 :lower)))))
 587
 588 (defun pathname-type (pathname &key (case :local))
 589   #!+sb-doc
 590   "Return PATHNAME's type."
 591   (declare (type pathname-designator pathname)
 592            (type (member :local :common) case))
 593   (with-pathname (pathname pathname)
 594     (maybe-diddle-case (%pathname-type pathname)
 595                        (and (eq case :common)
 596                             (eq (host-customary-case
 597                                  (%pathname-host pathname))
 598                                 :lower)))))
 599
 600 (defun pathname-version (pathname)
 601   #!+sb-doc
 602   "Return PATHNAME's version."
 603   (declare (type pathname-designator pathname))
 604   (with-pathname (pathname pathname)
 605     (%pathname-version pathname)))
 606 \f
 607 ;;;; namestrings
 608
 609 ;;; Handle the case for PARSE-NAMESTRING parsing a potentially
 610 ;;; syntactically valid logical namestring with an explicit host.
 611 ;;;
 612 ;;; This then isn't fully general -- we are relying on the fact that
 613 ;;; we will only pass to parse-namestring namestring with an explicit
 614 ;;; logical host, so that we can pass the host return from
 615 ;;; parse-logical-namestring through to %PARSE-NAMESTRING as a truth
 616 ;;; value. Yeah, this is probably a KLUDGE - CSR, 2002-04-18
 617 (defun parseable-logical-namestring-p (namestr start end)
 618   (catch 'exit
 619     (handler-bind
 620         ((namestring-parse-error (lambda (c)
 621                                    (declare (ignore c))
 622                                    (throw 'exit nil))))
 623       (let ((colon (position #\: namestr :start start :end end)))
 624         (when colon
 625           (let ((potential-host
 626                  (logical-word-or-lose (subseq namestr start colon))))
 627             ;; depending on the outcome of CSR comp.lang.lisp post
 628             ;; "can PARSE-NAMESTRING create logical hosts", we may need
 629             ;; to do things with potential-host (create it
 630             ;; temporarily, parse the namestring and unintern the
 631             ;; logical host potential-host on failure.
 632             (declare (ignore potential-host))
 633             (let ((result
 634                    (handler-bind
 635                        ((simple-type-error (lambda (c)
 636                                              (declare (ignore c))
 637                                              (throw 'exit nil))))
 638                      (parse-logical-namestring namestr start end))))
 639               ;; if we got this far, we should have an explicit host
 640               ;; (first return value of parse-logical-namestring)
 641               (aver result)
 642               result)))))))
 643
 644 ;;; Handle the case where PARSE-NAMESTRING is actually parsing a
 645 ;;; namestring. We pick off the :JUNK-ALLOWED case then find a host to
 646 ;;; use for parsing, call the parser, then check whether the host matches.
 647 (defun %parse-namestring (namestr host defaults start end junk-allowed)
 648   (declare (type (or host null) host)
 649            (type string namestr)
 650            (type index start)
 651            (type (or index null) end))
 652   (cond
 653     (junk-allowed
 654      (handler-case
 655          (%parse-namestring namestr host defaults start end nil)
 656        (namestring-parse-error (condition)
 657          (values nil (namestring-parse-error-offset condition)))))
 658     (t
 659      (let* ((end (%check-vector-sequence-bounds namestr start end)))
 660        (multiple-value-bind (new-host device directory file type version)
 661            ;; Comments below are quotes from the HyperSpec
 662            ;; PARSE-NAMESTRING entry, reproduced here to demonstrate
 663            ;; that we actually have to do things this way rather than
 664            ;; some possibly more logical way. - CSR, 2002-04-18
 665            (cond
 666              ;; "If host is a logical host then thing is parsed as a
 667              ;; logical pathname namestring on the host."
 668              (host (funcall (host-parse host) namestr start end))
 669              ;; "If host is nil and thing is a syntactically valid
 670              ;; logical pathname namestring containing an explicit
 671              ;; host, then it is parsed as a logical pathname
 672              ;; namestring."
 673              ((parseable-logical-namestring-p namestr start end)
 674               (parse-logical-namestring namestr start end))
 675              ;; "If host is nil, default-pathname is a logical
 676              ;; pathname, and thing is a syntactically valid logical
 677              ;; pathname namestring without an explicit host, then it
 678              ;; is parsed as a logical pathname namestring on the
 679              ;; host that is the host component of default-pathname."
 680              ;;
 681              ;; "Otherwise, the parsing of thing is
 682              ;; implementation-defined."
 683              ;;
 684              ;; Both clauses are handled here, as the default
 685              ;; *DEFAULT-PATHNAME-DEFAULTS has a SB-IMPL::UNIX-HOST
 686              ;; for a host.
 687              ((pathname-host defaults)
 688               (funcall (host-parse (pathname-host defaults))
 689                        namestr
 690                        start
 691                        end))
 692              ;; I don't think we should ever get here, as the default
 693              ;; host will always have a non-null HOST, given that we
 694              ;; can't create a new pathname without going through
 695              ;; *DEFAULT-PATHNAME-DEFAULTS*, which has a non-null
 696              ;; host...
 697              (t (bug "Fallen through COND in %PARSE-NAMESTRING")))
 698          (when (and host new-host (not (eq new-host host)))
 699            (error 'simple-type-error
 700                   :datum new-host
 701                   ;; Note: ANSI requires that this be a TYPE-ERROR,
 702                   ;; but there seems to be no completely correct
 703                   ;; value to use for TYPE-ERROR-EXPECTED-TYPE.
 704                   ;; Instead, we return a sort of "type error allowed
 705                   ;; type", trying to say "it would be OK if you
 706                   ;; passed NIL as the host value" but not mentioning
 707                   ;; that a matching string would be OK too.
 708                   :expected-type 'null
 709                   :format-control
 710                   "The host in the namestring, ~S,~@
 711                     does not match the explicit HOST argument, ~S."
 712                   :format-arguments (list new-host host)))
 713          (let ((pn-host (or new-host host (pathname-host defaults))))
 714            (values (%make-maybe-logical-pathname
 715                     pn-host device directory file type version)
 716                    end)))))))
 717
 718 ;;; If NAMESTR begins with a colon-terminated, defined, logical host,
 719 ;;; then return that host, otherwise return NIL.
 720 (defun extract-logical-host-prefix (namestr start end)
 721   (declare (type simple-base-string namestr)
 722            (type index start end)
 723            (values (or logical-host null)))
 724   (let ((colon-pos (position #\: namestr :start start :end end)))
 725     (if colon-pos
 726         (values (gethash (nstring-upcase (subseq namestr start colon-pos))
 727                          *logical-hosts*))
 728         nil)))
 729
 730 (defun parse-namestring (thing
 731                          &optional
 732                          host
 733                          (defaults *default-pathname-defaults*)
 734                          &key (start 0) end junk-allowed)
 735   (declare (type pathname-designator thing)
 736            (type (or list host string (member :unspecific)) host)
 737            (type pathname defaults)
 738            (type index start)
 739            (type (or index null) end)
 740            (type (or t null) junk-allowed)
 741            (values (or null pathname) (or null index)))
 742   ;; Generally, redundant specification of information in software,
 743   ;; whether in code or in comments, is bad. However, the ANSI spec
 744   ;; for this is messy enough that it's hard to hold in short-term
 745   ;; memory, so I've recorded these redundant notes on the
 746   ;; implications of the ANSI spec.
 747   ;;
 748   ;; According to the ANSI spec, HOST can be a valid pathname host, or
 749   ;; a logical host, or NIL.
 750   ;;
 751   ;; A valid pathname host can be a valid physical pathname host or a
 752   ;; valid logical pathname host.
 753   ;;
 754   ;; A valid physical pathname host is "any of a string, a list of
 755   ;; strings, or the symbol :UNSPECIFIC, that is recognized by the
 756   ;; implementation as the name of a host". In SBCL as of 0.6.9.8,
 757   ;; that means :UNSPECIFIC: though someday we might want to
 758   ;; generalize it to allow strings like "RTFM.MIT.EDU" or lists like
 759   ;; '("RTFM" "MIT" "EDU"), that's not supported now.
 760   ;;
 761   ;; A valid logical pathname host is a string which has been defined as
 762   ;; the name of a logical host, as with LOAD-LOGICAL-PATHNAME-TRANSLATIONS.
 763   ;;
 764   ;; A logical host is an object of implementation-dependent nature. In
 765   ;; SBCL, it's a member of the HOST class (a subclass of STRUCTURE-OBJECT).
 766   (let ((found-host (etypecase host
 767                       ((string 0)
 768                        ;; This is a special host. It's not valid as a
 769                        ;; logical host, so it is a sensible thing to
 770                        ;; designate the physical Unix host object. So
 771                        ;; we do that.
 772                        *unix-host*)
 773                       (string
 774                        ;; In general ANSI-compliant Common Lisps, a
 775                        ;; string might also be a physical pathname host,
 776                        ;; but ANSI leaves this up to the implementor,
 777                        ;; and in SBCL we don't do it, so it must be a
 778                        ;; logical host.
 779                        (find-logical-host host))
 780                       ((or null (member :unspecific))
 781                        ;; CLHS says that HOST=:UNSPECIFIC has
 782                        ;; implementation-defined behavior. We
 783                        ;; just turn it into NIL.
 784                        nil)
 785                       (list
 786                        ;; ANSI also allows LISTs to designate hosts,
 787                        ;; but leaves its interpretation
 788                        ;; implementation-defined. Our interpretation
 789                        ;; is that it's unsupported.:-|
 790                        (error "A LIST representing a pathname host is not ~
 791                               supported in this implementation:~%  ~S"
 792                               host))
 793                       (host
 794                        host))))
 795     (declare (type (or null host) found-host))
 796     (etypecase thing
 797       (simple-string
 798        (%parse-namestring thing found-host defaults start end junk-allowed))
 799       (string
 800        (%parse-namestring (coerce thing 'simple-string)
 801                           found-host defaults start end junk-allowed))
 802       (pathname
 803        (let ((defaulted-host (or found-host (%pathname-host defaults))))
 804          (declare (type host defaulted-host))
 805          (unless (eq defaulted-host (%pathname-host thing))
 806            (error "The HOST argument doesn't match the pathname host:~%  ~
 807                   ~S and ~S."
 808                   defaulted-host (%pathname-host thing))))
 809        (values thing start))
 810       (stream
 811        (let ((name (file-name thing)))
 812          (unless name
 813            (error "can't figure out the file associated with stream:~%  ~S"
 814                   thing))
 815          (values name nil))))))
 816
 817 (defun namestring (pathname)
 818   #!+sb-doc
 819   "Construct the full (name)string form of the pathname."
 820   (declare (type pathname-designator pathname)
 821            (values (or null simple-base-string)))
 822   (with-pathname (pathname pathname)
 823     (when pathname
 824       (let ((host (%pathname-host pathname)))
 825         (unless host
 826           (error "can't determine the namestring for pathnames with no ~
 827                   host:~%  ~S" pathname))
 828         (funcall (host-unparse host) pathname)))))
 829
 830 (defun host-namestring (pathname)
 831   #!+sb-doc
 832   "Return a string representation of the name of the host in the pathname."
 833   (declare (type pathname-designator pathname)
 834            (values (or null simple-base-string)))
 835   (with-pathname (pathname pathname)
 836     (let ((host (%pathname-host pathname)))
 837       (if host
 838           (funcall (host-unparse-host host) pathname)
 839           (error
 840            "can't determine the namestring for pathnames with no host:~%  ~S"
 841            pathname)))))
 842
 843 (defun directory-namestring (pathname)
 844   #!+sb-doc
 845   "Return a string representation of the directories used in the pathname."
 846   (declare (type pathname-designator pathname)
 847            (values (or null simple-base-string)))
 848   (with-pathname (pathname pathname)
 849     (let ((host (%pathname-host pathname)))
 850       (if host
 851           (funcall (host-unparse-directory host) pathname)
 852           (error
 853            "can't determine the namestring for pathnames with no host:~%  ~S"
 854            pathname)))))
 855
 856 (defun file-namestring (pathname)
 857   #!+sb-doc
 858   "Return a string representation of the name used in the pathname."
 859   (declare (type pathname-designator pathname)
 860            (values (or null simple-base-string)))
 861   (with-pathname (pathname pathname)
 862     (let ((host (%pathname-host pathname)))
 863       (if host
 864           (funcall (host-unparse-file host) pathname)
 865           (error
 866            "can't determine the namestring for pathnames with no host:~%  ~S"
 867            pathname)))))
 868
 869 (defun enough-namestring (pathname
 870                           &optional
 871                           (defaults *default-pathname-defaults*))
 872   #!+sb-doc
 873   "Return an abbreviated pathname sufficent to identify the pathname relative
 874    to the defaults."
 875   (declare (type pathname-designator pathname))
 876   (with-pathname (pathname pathname)
 877     (let ((host (%pathname-host pathname)))
 878       (if host
 879           (with-pathname (defaults defaults)
 880             (funcall (host-unparse-enough host) pathname defaults))
 881           (error
 882            "can't determine the namestring for pathnames with no host:~%  ~S"
 883            pathname)))))
 884 \f
 885 ;;;; wild pathnames
 886
 887 (defun wild-pathname-p (pathname &optional field-key)
 888   #!+sb-doc
 889   "Predicate for determining whether pathname contains any wildcards."
 890   (declare (type pathname-designator pathname)
 891            (type (member nil :host :device :directory :name :type :version)
 892                  field-key))
 893   (with-pathname (pathname pathname)
 894     (flet ((frob (x)
 895              (or (pattern-p x) (member x '(:wild :wild-inferiors)))))
 896       (ecase field-key
 897         ((nil)
 898          (or (wild-pathname-p pathname :host)
 899              (wild-pathname-p pathname :device)
 900              (wild-pathname-p pathname :directory)
 901              (wild-pathname-p pathname :name)
 902              (wild-pathname-p pathname :type)
 903              (wild-pathname-p pathname :version)))
 904         (:host (frob (%pathname-host pathname)))
 905         (:device (frob (%pathname-host pathname)))
 906         (:directory (some #'frob (%pathname-directory pathname)))
 907         (:name (frob (%pathname-name pathname)))
 908         (:type (frob (%pathname-type pathname)))
 909         (:version (frob (%pathname-version pathname)))))))
 910
 911 (defun pathname-match-p (in-pathname in-wildname)
 912   #!+sb-doc
 913   "Pathname matches the wildname template?"
 914   (declare (type pathname-designator in-pathname))
 915   (with-pathname (pathname in-pathname)
 916     (with-pathname (wildname in-wildname)
 917       (macrolet ((frob (field &optional (op 'components-match))
 918                    `(or (null (,field wildname))
 919                         (,op (,field pathname) (,field wildname)))))
 920         (and (or (null (%pathname-host wildname))
 921                  (eq (%pathname-host wildname) (%pathname-host pathname)))
 922              (frob %pathname-device)
 923              (frob %pathname-directory directory-components-match)
 924              (frob %pathname-name)
 925              (frob %pathname-type)
 926              (frob %pathname-version))))))
 927
 928 ;;; Place the substitutions into the pattern and return the string or pattern
 929 ;;; that results. If DIDDLE-CASE is true, we diddle the result case as well,
 930 ;;; in case we are translating between hosts with difference conventional case.
 931 ;;; The second value is the tail of subs with all of the values that we used up
 932 ;;; stripped off. Note that PATTERN-MATCHES matches all consecutive wildcards
 933 ;;; as a single string, so we ignore subsequent contiguous wildcards.
 934 (defun substitute-into (pattern subs diddle-case)
 935   (declare (type pattern pattern)
 936            (type list subs)
 937            (values (or simple-base-string pattern) list))
 938   (let ((in-wildcard nil)
 939         (pieces nil)
 940         (strings nil))
 941     (dolist (piece (pattern-pieces pattern))
 942       (cond ((simple-string-p piece)
 943              (push piece strings)
 944              (setf in-wildcard nil))
 945             (in-wildcard)
 946             (t
 947              (setf in-wildcard t)
 948              (unless subs
 949                (error "not enough wildcards in FROM pattern to match ~
 950                        TO pattern:~%  ~S"
 951                       pattern))
 952              (let ((sub (pop subs)))
 953                (typecase sub
 954                  (pattern
 955                   (when strings
 956                     (push (apply #'concatenate 'simple-string
 957                                  (nreverse strings))
 958                           pieces))
 959                   (dolist (piece (pattern-pieces sub))
 960                     (push piece pieces)))
 961                  (simple-string
 962                   (push sub strings))
 963                  (t
 964                   (error "can't substitute this into the middle of a word:~
 965                           ~%  ~S"
 966                          sub)))))))
 967
 968     (when strings
 969       (push (apply #'concatenate 'simple-string (nreverse strings))
 970             pieces))
 971     (values
 972      (maybe-diddle-case
 973       (if (and pieces (simple-string-p (car pieces)) (null (cdr pieces)))
 974           (car pieces)
 975           (make-pattern (nreverse pieces)))
 976       diddle-case)
 977      subs)))
 978
 979 ;;; Called when we can't see how source and from matched.
 980 (defun didnt-match-error (source from)
 981   (error "Pathname components from SOURCE and FROM args to TRANSLATE-PATHNAME~@
 982           did not match:~%  ~S ~S"
 983          source from))
 984
 985 ;;; Do TRANSLATE-COMPONENT for all components except host and directory.
 986 (defun translate-component (source from to diddle-case)
 987   (typecase to
 988     (pattern
 989      (typecase from
 990        (pattern
 991         (typecase source
 992           (pattern
 993            (if (pattern= from source)
 994                source
 995                (didnt-match-error source from)))
 996           (simple-string
 997            (multiple-value-bind (won subs) (pattern-matches from source)
 998              (if won
 999                  (values (substitute-into to subs diddle-case))
1000                  (didnt-match-error source from))))
1001           (t
1002            (maybe-diddle-case source diddle-case))))
1003        ((member :wild)
1004         (values (substitute-into to (list source) diddle-case)))
1005        (t
1006         (if (components-match source from)
1007             (maybe-diddle-case source diddle-case)
1008             (didnt-match-error source from)))))
1009     ((member nil :wild)
1010      (maybe-diddle-case source diddle-case))
1011     (t
1012      (if (components-match source from)
1013          to
1014          (didnt-match-error source from)))))
1015
1016 ;;; Return a list of all the things that we want to substitute into the TO
1017 ;;; pattern (the things matched by from on source.)  When From contains
1018 ;;; :WILD-INFERIORS, the result contains a sublist of the matched source
1019 ;;; subdirectories.
1020 (defun compute-directory-substitutions (orig-source orig-from)
1021   (let ((source orig-source)
1022         (from orig-from))
1023     (collect ((subs))
1024       (loop
1025         (unless source
1026           (unless (every (lambda (x) (eq x :wild-inferiors)) from)
1027             (didnt-match-error orig-source orig-from))
1028           (subs ())
1029           (return))
1030         (unless from (didnt-match-error orig-source orig-from))
1031         (let ((from-part (pop from))
1032               (source-part (pop source)))
1033           (typecase from-part
1034             (pattern
1035              (typecase source-part
1036                (pattern
1037                 (if (pattern= from-part source-part)
1038                     (subs source-part)
1039                     (didnt-match-error orig-source orig-from)))
1040                (simple-string
1041                 (multiple-value-bind (won new-subs)
1042                     (pattern-matches from-part source-part)
1043                   (if won
1044                       (dolist (sub new-subs)
1045                         (subs sub))
1046                       (didnt-match-error orig-source orig-from))))
1047                (t
1048                 (didnt-match-error orig-source orig-from))))
1049             ((member :wild)
1050              (subs source-part))
1051             ((member :wild-inferiors)
1052              (let ((remaining-source (cons source-part source)))
1053                (collect ((res))
1054                  (loop
1055                    (when (directory-components-match remaining-source from)
1056                      (return))
1057                    (unless remaining-source
1058                      (didnt-match-error orig-source orig-from))
1059                    (res (pop remaining-source)))
1060                  (subs (res))
1061                  (setq source remaining-source))))
1062             (simple-string
1063              (unless (and (simple-string-p source-part)
1064                           (string= from-part source-part))
1065                (didnt-match-error orig-source orig-from)))
1066             (t
1067              (didnt-match-error orig-source orig-from)))))
1068       (subs))))
1069
1070 ;;; This is called by TRANSLATE-PATHNAME on the directory components
1071 ;;; of its argument pathnames to produce the result directory
1072 ;;; component. If this leaves the directory NIL, we return the source
1073 ;;; directory. The :RELATIVE or :ABSOLUTE is taken from the source
1074 ;;; directory, except if TO is :ABSOLUTE, in which case the result
1075 ;;; will be :ABSOLUTE.
1076 (defun translate-directories (source from to diddle-case)
1077   (if (not (and source to from))
1078       (or (and to (null source) (remove :wild-inferiors to))
1079           (mapcar (lambda (x) (maybe-diddle-case x diddle-case)) source))
1080       (collect ((res))
1081                ;; If TO is :ABSOLUTE, the result should still be :ABSOLUTE.
1082                (res (if (eq (first to) :absolute)
1083                  :absolute
1084                  (first source)))
1085         (let ((subs-left (compute-directory-substitutions (rest source)
1086                                                           (rest from))))
1087           (dolist (to-part (rest to))
1088             (typecase to-part
1089               ((member :wild)
1090                (aver subs-left)
1091                (let ((match (pop subs-left)))
1092                  (when (listp match)
1093                    (error ":WILD-INFERIORS is not paired in from and to ~
1094                            patterns:~%  ~S ~S" from to))
1095                  (res (maybe-diddle-case match diddle-case))))
1096               ((member :wild-inferiors)
1097                (aver subs-left)
1098                (let ((match (pop subs-left)))
1099                  (unless (listp match)
1100                    (error ":WILD-INFERIORS not paired in from and to ~
1101                            patterns:~%  ~S ~S" from to))
1102                  (dolist (x match)
1103                    (res (maybe-diddle-case x diddle-case)))))
1104               (pattern
1105                (multiple-value-bind
1106                    (new new-subs-left)
1107                    (substitute-into to-part subs-left diddle-case)
1108                  (setf subs-left new-subs-left)
1109                  (res new)))
1110               (t (res to-part)))))
1111         (res))))
1112
1113 (defun translate-pathname (source from-wildname to-wildname &key)
1114   #!+sb-doc
1115   "Use the source pathname to translate the from-wildname's wild and
1116    unspecified elements into a completed to-pathname based on the to-wildname."
1117   (declare (type pathname-designator source from-wildname to-wildname))
1118   (with-pathname (source source)
1119     (with-pathname (from from-wildname)
1120       (with-pathname (to to-wildname)
1121           (let* ((source-host (%pathname-host source))
1122                  (to-host (%pathname-host to))
1123                  (diddle-case
1124                   (and source-host to-host
1125                        (not (eq (host-customary-case source-host)
1126                                 (host-customary-case to-host))))))
1127             (macrolet ((frob (field &optional (op 'translate-component))
1128                          `(let ((result (,op (,field source)
1129                                              (,field from)
1130                                              (,field to)
1131                                              diddle-case)))
1132                             (if (eq result :error)
1133                                 (error "~S doesn't match ~S." source from)
1134                                 result))))
1135               (%make-maybe-logical-pathname
1136                (or to-host source-host)
1137                (frob %pathname-device)
1138                (frob %pathname-directory translate-directories)
1139                (frob %pathname-name)
1140                (frob %pathname-type)
1141                (frob %pathname-version))))))))
1142 \f
1143 ;;;;  logical pathname support. ANSI 92-102 specification.
1144 ;;;;
1145 ;;;;  As logical-pathname translations are loaded they are
1146 ;;;;  canonicalized as patterns to enable rapid efficient translation
1147 ;;;;  into physical pathnames.
1148
1149 ;;;; utilities
1150
1151 ;;; Canonicalize a logical pathname word by uppercasing it checking that it
1152 ;;; contains only legal characters.
1153 (defun logical-word-or-lose (word)
1154   (declare (string word))
1155   (when (string= word "")
1156     (error 'namestring-parse-error
1157            :complaint "Attempted to treat invalid logical hostname ~
1158                        as a logical host:~%  ~S"
1159            :args (list word)
1160            :namestring word :offset 0))
1161   (let ((word (string-upcase word)))
1162     (dotimes (i (length word))
1163       (let ((ch (schar word i)))
1164         (unless (or (alpha-char-p ch) (digit-char-p ch) (char= ch #\-))
1165           (error 'namestring-parse-error
1166                  :complaint "logical namestring character which ~
1167                              is not alphanumeric or hyphen:~%  ~S"
1168                  :args (list ch)
1169                  :namestring word :offset i))))
1170     word))
1171
1172 ;;; Given a logical host or string, return a logical host. If ERROR-P
1173 ;;; is NIL, then return NIL when no such host exists.
1174 (defun find-logical-host (thing &optional (errorp t))
1175   (etypecase thing
1176     (string
1177      (let ((found (gethash (logical-word-or-lose thing)
1178                            *logical-hosts*)))
1179        (if (or found (not errorp))
1180            found
1181            ;; This is the error signalled from e.g.
1182            ;; LOGICAL-PATHNAME-TRANSLATIONS when host is not a defined
1183            ;; host, and ANSI specifies that that's a TYPE-ERROR.
1184            (error 'simple-type-error
1185                   :datum thing
1186                   ;; God only knows what ANSI expects us to use for
1187                   ;; the EXPECTED-TYPE here. Maybe this will be OK..
1188                   :expected-type
1189                   '(and string (satisfies logical-pathname-translations))
1190                   :format-control "logical host not yet defined: ~S"
1191                   :format-arguments (list thing)))))
1192     (logical-host thing)))
1193
1194 ;;; Given a logical host name or host, return a logical host, creating
1195 ;;; a new one if necessary.
1196 (defun intern-logical-host (thing)
1197   (declare (values logical-host))
1198   (or (find-logical-host thing nil)
1199       (let* ((name (logical-word-or-lose thing))
1200              (new (make-logical-host :name name)))
1201         (setf (gethash name *logical-hosts*) new)
1202         new)))
1203 \f
1204 ;;;; logical pathname parsing
1205
1206 ;;; Deal with multi-char wildcards in a logical pathname token.
1207 (defun maybe-make-logical-pattern (namestring chunks)
1208   (let ((chunk (caar chunks)))
1209     (collect ((pattern))
1210       (let ((last-pos 0)
1211             (len (length chunk)))
1212         (declare (fixnum last-pos))
1213         (loop
1214           (when (= last-pos len) (return))
1215           (let ((pos (or (position #\* chunk :start last-pos) len)))
1216             (if (= pos last-pos)
1217                 (when (pattern)
1218                   (error 'namestring-parse-error
1219                          :complaint "double asterisk inside of logical ~
1220                                      word: ~S"
1221                          :args (list chunk)
1222                          :namestring namestring
1223                          :offset (+ (cdar chunks) pos)))
1224                 (pattern (subseq chunk last-pos pos)))
1225             (if (= pos len)
1226                 (return)
1227                 (pattern :multi-char-wild))
1228             (setq last-pos (1+ pos)))))
1229         (aver (pattern))
1230         (if (cdr (pattern))
1231             (make-pattern (pattern))
1232             (let ((x (car (pattern))))
1233               (if (eq x :multi-char-wild)
1234                   :wild
1235                   x))))))
1236
1237 ;;; Return a list of conses where the CDR is the start position and
1238 ;;; the CAR is a string (token) or character (punctuation.)
1239 (defun logical-chunkify (namestr start end)
1240   (collect ((chunks))
1241     (do ((i start (1+ i))
1242          (prev 0))
1243         ((= i end)
1244          (when (> end prev)
1245             (chunks (cons (nstring-upcase (subseq namestr prev end)) prev))))
1246       (let ((ch (schar namestr i)))
1247         (unless (or (alpha-char-p ch) (digit-char-p ch)
1248                     (member ch '(#\- #\*)))
1249           (when (> i prev)
1250             (chunks (cons (nstring-upcase (subseq namestr prev i)) prev)))
1251           (setq prev (1+ i))
1252           (unless (member ch '(#\; #\: #\.))
1253             (error 'namestring-parse-error
1254                    :complaint "illegal character for logical pathname:~%  ~S"
1255                    :args (list ch)
1256                    :namestring namestr
1257                    :offset i))
1258           (chunks (cons ch i)))))
1259     (chunks)))
1260
1261 ;;; Break up a logical-namestring, always a string, into its
1262 ;;; constituent parts.
1263 (defun parse-logical-namestring (namestr start end)
1264   (declare (type simple-base-string namestr)
1265            (type index start end))
1266   (collect ((directory))
1267     (let ((host nil)
1268           (name nil)
1269           (type nil)
1270           (version nil))
1271       (labels ((expecting (what chunks)
1272                  (unless (and chunks (simple-string-p (caar chunks)))
1273                    (error 'namestring-parse-error
1274                           :complaint "expecting ~A, got ~:[nothing~;~S~]."
1275                           :args (list what (caar chunks) (caar chunks))
1276                           :namestring namestr
1277                           :offset (if chunks (cdar chunks) end)))
1278                  (caar chunks))
1279                (parse-host (chunks)
1280                  (case (caadr chunks)
1281                    (#\:
1282                     (setq host
1283                           (find-logical-host (expecting "a host name" chunks)))
1284                     (parse-relative (cddr chunks)))
1285                    (t
1286                     (parse-relative chunks))))
1287                (parse-relative (chunks)
1288                  (case (caar chunks)
1289                    (#\;
1290                     (directory :relative)
1291                     (parse-directory (cdr chunks)))
1292                    (t
1293                     (directory :absolute) ; Assumption! Maybe revoked later.
1294                     (parse-directory chunks))))
1295                (parse-directory (chunks)
1296                  (case (caadr chunks)
1297                    (#\;
1298                     (directory
1299                      (let ((res (expecting "a directory name" chunks)))
1300                        (cond ((string= res "..") :up)
1301                              ((string= res "**") :wild-inferiors)
1302                              (t
1303                               (maybe-make-logical-pattern namestr chunks)))))
1304                     (parse-directory (cddr chunks)))
1305                    (t
1306                     (parse-name chunks))))
1307                (parse-name (chunks)
1308                  (when chunks
1309                    (expecting "a file name" chunks)
1310                    (setq name (maybe-make-logical-pattern namestr chunks))
1311                    (expecting-dot (cdr chunks))))
1312                (expecting-dot (chunks)
1313                  (when chunks
1314                    (unless (eql (caar chunks) #\.)
1315                      (error 'namestring-parse-error
1316                             :complaint "expecting a dot, got ~S."
1317                             :args (list (caar chunks))
1318                             :namestring namestr
1319                             :offset (cdar chunks)))
1320                    (if type
1321                        (parse-version (cdr chunks))
1322                        (parse-type (cdr chunks)))))
1323                (parse-type (chunks)
1324                  (expecting "a file type" chunks)
1325                  (setq type (maybe-make-logical-pattern namestr chunks))
1326                  (expecting-dot (cdr chunks)))
1327                (parse-version (chunks)
1328                  (let ((str (expecting "a positive integer, * or NEWEST"
1329                                        chunks)))
1330                    (cond
1331                     ((string= str "*") (setq version :wild))
1332                     ((string= str "NEWEST") (setq version :newest))
1333                     (t
1334                      (multiple-value-bind (res pos)
1335                          (parse-integer str :junk-allowed t)
1336                        (unless (and res (plusp res))
1337                          (error 'namestring-parse-error
1338                                 :complaint "expected a positive integer, ~
1339                                             got ~S"
1340                                 :args (list str)
1341                                 :namestring namestr
1342                                 :offset (+ pos (cdar chunks))))
1343                        (setq version res)))))
1344                  (when (cdr chunks)
1345                    (error 'namestring-parse-error
1346                           :complaint "extra stuff after end of file name"
1347                           :namestring namestr
1348                           :offset (cdadr chunks)))))
1349         (parse-host (logical-chunkify namestr start end)))
1350       (values host :unspecific (directory) name type version))))
1351
1352 ;;; We can't initialize this yet because not all host methods are
1353 ;;; loaded yet.
1354 (defvar *logical-pathname-defaults*)
1355
1356 (defun logical-pathname (pathspec)
1357   #!+sb-doc
1358   "Converts the pathspec argument to a logical-pathname and returns it."
1359   (declare (type (or logical-pathname string stream) pathspec)
1360            (values logical-pathname))
1361   (if (typep pathspec 'logical-pathname)
1362       pathspec
1363       (let ((res (parse-namestring pathspec nil *logical-pathname-defaults*)))
1364         (when (eq (%pathname-host res)
1365                   (%pathname-host *logical-pathname-defaults*))
1366           (error "This logical namestring does not specify a host:~%  ~S"
1367                  pathspec))
1368         res)))
1369 \f
1370 ;;;; logical pathname unparsing
1371
1372 (defun unparse-logical-directory (pathname)
1373   (declare (type pathname pathname))
1374   (collect ((pieces))
1375     (let ((directory (%pathname-directory pathname)))
1376       (when directory
1377         (ecase (pop directory)
1378           (:absolute) ; nothing special
1379           (:relative (pieces ";")))
1380         (dolist (dir directory)
1381           (cond ((or (stringp dir) (pattern-p dir))
1382                  (pieces (unparse-logical-piece dir))
1383                  (pieces ";"))
1384                 ((eq dir :wild)
1385                  (pieces "*;"))
1386                 ((eq dir :wild-inferiors)
1387                  (pieces "**;"))
1388                 (t
1389                  (error "invalid directory component: ~S" dir))))))
1390     (apply #'concatenate 'simple-string (pieces))))
1391
1392 (defun unparse-logical-piece (thing)
1393   (etypecase thing
1394     (simple-string thing)
1395     (pattern
1396      (collect ((strings))
1397        (dolist (piece (pattern-pieces thing))
1398          (etypecase piece
1399            (simple-string (strings piece))
1400            (keyword
1401             (cond ((eq piece :wild-inferiors)
1402                    (strings "**"))
1403                   ((eq piece :multi-char-wild)
1404                    (strings "*"))
1405                   (t (error "invalid keyword: ~S" piece))))))
1406        (apply #'concatenate 'simple-string (strings))))))
1407
1408 ;;; Unparse a logical pathname string.
1409 (defun unparse-enough-namestring (pathname defaults)
1410   (let* ((path-directory (pathname-directory pathname))
1411          (def-directory (pathname-directory defaults))
1412          (enough-directory
1413            ;; Go down the directory lists to see what matches.  What's
1414            ;; left is what we want, more or less.
1415            (cond ((and (eq (first path-directory) (first def-directory))
1416                        (eq (first path-directory) :absolute))
1417                    ;; Both paths are :ABSOLUTE, so find where the
1418                    ;; common parts end and return what's left
1419                    (do* ((p (rest path-directory) (rest p))
1420                          (d (rest def-directory) (rest d)))
1421                         ((or (endp p) (endp d)
1422                              (not (equal (first p) (first d))))
1423                          `(:relative ,@p))))
1424                  (t
1425                    ;; At least one path is :RELATIVE, so just return the
1426                    ;; original path.  If the original path is :RELATIVE,
1427                    ;; then that's the right one.  If PATH-DIRECTORY is
1428                    ;; :ABSOLUTE, we want to return that except when
1429                    ;; DEF-DIRECTORY is :ABSOLUTE, as handled above. so return
1430                    ;; the original directory.
1431                    path-directory))))
1432     (make-pathname :host (pathname-host pathname)
1433                    :directory enough-directory
1434                    :name (pathname-name pathname)
1435                    :type (pathname-type pathname)
1436                    :version (pathname-version pathname))))
1437
1438 (defun unparse-logical-namestring (pathname)
1439   (declare (type logical-pathname pathname))
1440   (concatenate 'simple-string
1441                (logical-host-name (%pathname-host pathname)) ":"
1442                (unparse-logical-directory pathname)
1443                (unparse-unix-file pathname)))
1444 \f
1445 ;;;; logical pathname translations
1446
1447 ;;; Verify that the list of translations consists of lists and prepare
1448 ;;; canonical translations. (Parse pathnames and expand out wildcards
1449 ;;; into patterns.)
1450 (defun canonicalize-logical-pathname-translations (translation-list host)
1451   (declare (type list translation-list) (type host host)
1452            (values list))
1453   (mapcar (lambda (translation)
1454             (destructuring-bind (from to) translation
1455               (list (if (typep from 'logical-pathname)
1456                         from
1457                         (parse-namestring from host))
1458                     (pathname to))))
1459           translation-list))
1460
1461 (defun logical-pathname-translations (host)
1462   #!+sb-doc
1463   "Return the (logical) host object argument's list of translations."
1464   (declare (type (or string logical-host) host)
1465            (values list))
1466   (logical-host-translations (find-logical-host host)))
1467
1468 (defun (setf logical-pathname-translations) (translations host)
1469   #!+sb-doc
1470   "Set the translations list for the logical host argument."
1471   (declare (type (or string logical-host) host)
1472            (type list translations)
1473            (values list))
1474   (let ((host (intern-logical-host host)))
1475     (setf (logical-host-canon-transls host)
1476           (canonicalize-logical-pathname-translations translations host))
1477     (setf (logical-host-translations host) translations)))
1478
1479 (defun translate-logical-pathname (pathname &key)
1480   #!+sb-doc
1481   "Translate PATHNAME to a physical pathname, which is returned."
1482   (declare (type pathname-designator pathname)
1483            (values (or null pathname)))
1484   (typecase pathname
1485     (logical-pathname
1486      (dolist (x (logical-host-canon-transls (%pathname-host pathname))
1487                 (error 'simple-file-error
1488                        :pathname pathname
1489                        :format-control "no translation for ~S"
1490                        :format-arguments (list pathname)))
1491        (destructuring-bind (from to) x
1492          (when (pathname-match-p pathname from)
1493            (return (translate-logical-pathname
1494                     (translate-pathname pathname from to)))))))
1495     (pathname pathname)
1496     (t (translate-logical-pathname (pathname pathname)))))
1497
1498 (defvar *logical-pathname-defaults*
1499   (%make-logical-pathname (make-logical-host :name "BOGUS")
1500                           :unspecific
1501                           nil
1502                           nil
1503                           nil
1504                           nil))
1505
1506 (defun load-logical-pathname-translations (host)
1507   #!+sb-doc
1508   (declare (type string host)
1509            (values (member t nil)))
1510   (if (find-logical-host host nil)
1511       ;; This host is already defined, all is well and good.
1512       t
1513       ;; ANSI: "The specific nature of the search is
1514       ;; implementation-defined." SBCL: doesn't search at all
1515       (error "logical host ~S not found" host)))