src/code/target-pathname.lisp

   1 ;;;; machine/filesystem-independent pathname functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 #!-sb-fluid (declaim (freeze-type logical-pathname logical-host))
  15 \f
  16 ;;;; UNIX-HOST stuff
  17
  18 (def!struct (unix-host
  19              (:make-load-form-fun make-unix-host-load-form)
  20              (:include host
  21                        (parse #'parse-unix-namestring)
  22                        (unparse #'unparse-unix-namestring)
  23                        (unparse-host #'unparse-unix-host)
  24                        (unparse-directory #'unparse-unix-directory)
  25                        (unparse-file #'unparse-unix-file)
  26                        (unparse-enough #'unparse-unix-enough)
  27                        (customary-case :lower))))
  28
  29 (defvar *unix-host* (make-unix-host))
  30
  31 (defun make-unix-host-load-form (host)
  32   (declare (ignore host))
  33   '*unix-host*)
  34
  35 ;;; Return a value suitable, e.g., for preinitializing
  36 ;;; *DEFAULT-PATHNAME-DEFAULTS* before *DEFAULT-PATHNAME-DEFAULTS* is
  37 ;;; initialized (at which time we can't safely call e.g. #'PATHNAME).
  38 (defun make-trivial-default-pathname ()
  39   (%make-pathname *unix-host* nil nil nil nil :newest))
  40 \f
  41 ;;; pathname methods
  42
  43 (def!method print-object ((pathname pathname) stream)
  44   (let ((namestring (handler-case (namestring pathname)
  45                       (error nil))))
  46     (if namestring
  47         (format stream "#P~S" namestring)
  48         (print-unreadable-object (pathname stream :type t)
  49           (format stream
  50                   "~@<(with no namestring) ~_:HOST ~S ~_:DEVICE ~S ~_:DIRECTORY ~S ~
  51                   ~_:NAME ~S ~_:TYPE ~S ~_:VERSION ~S~:>"
  52                   (%pathname-host pathname)
  53                   (%pathname-device pathname)
  54                   (%pathname-directory pathname)
  55                   (%pathname-name pathname)
  56                   (%pathname-type pathname)
  57                   (%pathname-version pathname))))))
  58
  59 (def!method make-load-form ((pathname pathname) &optional environment)
  60   (make-load-form-saving-slots pathname :environment environment))
  61
  62 ;;; The potential conflict with search lists requires isolating the
  63 ;;; printed representation to use the i/o macro #.(logical-pathname
  64 ;;; <path-designator>).
  65 ;;;
  66 ;;; FIXME: We don't use search lists any more, so that comment is
  67 ;;; stale, right?
  68 (def!method print-object ((pathname logical-pathname) stream)
  69   (let ((namestring (handler-case (namestring pathname)
  70                       (error nil))))
  71     (if namestring
  72         (format stream "#.(CL:LOGICAL-PATHNAME ~S)" namestring)
  73         (print-unreadable-object (pathname stream :type t)
  74           (format
  75            stream
  76            "~_:HOST ~S ~_:DIRECTORY ~S ~_:FILE ~S ~_:NAME ~S ~_:VERSION ~S"
  77            (%pathname-host pathname)
  78            (%pathname-directory pathname)
  79            (%pathname-name pathname)
  80            (%pathname-type pathname)
  81            (%pathname-version pathname))))))
  82 \f
  83 ;;; A pathname is logical if the host component is a logical host.
  84 ;;; This constructor is used to make an instance of the correct type
  85 ;;; from parsed arguments.
  86 (defun %make-maybe-logical-pathname (host device directory name type version)
  87   ;; We canonicalize logical pathname components to uppercase. ANSI
  88   ;; doesn't strictly require this, leaving it up to the implementor;
  89   ;; but the arguments given in the X3J13 cleanup issue
  90   ;; PATHNAME-LOGICAL:ADD seem compelling: we should canonicalize the
  91   ;; case, and uppercase is the ordinary way to do that.
  92   (flet ((upcase-maybe (x) (typecase x (string (logical-word-or-lose x)) (t x))))
  93     (if (typep host 'logical-host)
  94         (%make-logical-pathname host
  95                                 :unspecific
  96                                 (mapcar #'upcase-maybe directory)
  97                                 (upcase-maybe name)
  98                                 (upcase-maybe type)
  99                                 version)
 100         (%make-pathname host device directory name type version))))
 101
 102 ;;; Hash table searching maps a logical pathname's host to its
 103 ;;; physical pathname translation.
 104 (defvar *logical-hosts* (make-hash-table :test 'equal))
 105 \f
 106 ;;;; patterns
 107
 108 (def!method make-load-form ((pattern pattern) &optional environment)
 109   (make-load-form-saving-slots pattern :environment environment))
 110
 111 (def!method print-object ((pattern pattern) stream)
 112   (print-unreadable-object (pattern stream :type t)
 113     (if *print-pretty*
 114         (let ((*print-escape* t))
 115           (pprint-fill stream (pattern-pieces pattern) nil))
 116         (prin1 (pattern-pieces pattern) stream))))
 117
 118 (defun pattern= (pattern1 pattern2)
 119   (declare (type pattern pattern1 pattern2))
 120   (let ((pieces1 (pattern-pieces pattern1))
 121         (pieces2 (pattern-pieces pattern2)))
 122     (and (= (length pieces1) (length pieces2))
 123          (every (lambda (piece1 piece2)
 124                   (typecase piece1
 125                     (simple-string
 126                      (and (simple-string-p piece2)
 127                           (string= piece1 piece2)))
 128                     (cons
 129                      (and (consp piece2)
 130                           (eq (car piece1) (car piece2))
 131                           (string= (cdr piece1) (cdr piece2))))
 132                     (t
 133                      (eq piece1 piece2))))
 134                 pieces1
 135                 pieces2))))
 136
 137 ;;; If the string matches the pattern returns the multiple values T
 138 ;;; and a list of the matched strings.
 139 (defun pattern-matches (pattern string)
 140   (declare (type pattern pattern)
 141            (type simple-string string))
 142   (let ((len (length string)))
 143     (labels ((maybe-prepend (subs cur-sub chars)
 144                (if cur-sub
 145                    (let* ((len (length chars))
 146                           (new (make-string len))
 147                           (index len))
 148                      (dolist (char chars)
 149                        (setf (schar new (decf index)) char))
 150                      (cons new subs))
 151                    subs))
 152              (matches (pieces start subs cur-sub chars)
 153                (if (null pieces)
 154                    (if (= start len)
 155                        (values t (maybe-prepend subs cur-sub chars))
 156                        (values nil nil))
 157                    (let ((piece (car pieces)))
 158                      (etypecase piece
 159                        (simple-string
 160                         (let ((end (+ start (length piece))))
 161                           (and (<= end len)
 162                                (string= piece string
 163                                         :start2 start :end2 end)
 164                                (matches (cdr pieces) end
 165                                         (maybe-prepend subs cur-sub chars)
 166                                         nil nil))))
 167                        (list
 168                         (ecase (car piece)
 169                           (:character-set
 170                            (and (< start len)
 171                                 (let ((char (schar string start)))
 172                                   (if (find char (cdr piece) :test #'char=)
 173                                       (matches (cdr pieces) (1+ start) subs t
 174                                                (cons char chars))))))))
 175                        ((member :single-char-wild)
 176                         (and (< start len)
 177                              (matches (cdr pieces) (1+ start) subs t
 178                                       (cons (schar string start) chars))))
 179                        ((member :multi-char-wild)
 180                         (multiple-value-bind (won new-subs)
 181                             (matches (cdr pieces) start subs t chars)
 182                           (if won
 183                               (values t new-subs)
 184                               (and (< start len)
 185                                    (matches pieces (1+ start) subs t
 186                                             (cons (schar string start)
 187                                                   chars)))))))))))
 188       (multiple-value-bind (won subs)
 189           (matches (pattern-pieces pattern) 0 nil nil nil)
 190         (values won (reverse subs))))))
 191
 192 ;;; PATHNAME-MATCH-P for directory components
 193 (defun directory-components-match (thing wild)
 194   (or (eq thing wild)
 195       (eq wild :wild)
 196       ;; If THING has a null directory, assume that it matches
 197       ;; (:ABSOLUTE :WILD-INFERIORS) or (:RELATIVE :WILD-INFERIORS).
 198       (and (consp wild)
 199            (null thing)
 200            (member (first wild) '(:absolute :relative))
 201            (eq (second wild) :wild-inferiors))
 202       (and (consp wild)
 203            (let ((wild1 (first wild)))
 204              (if (eq wild1 :wild-inferiors)
 205                  (let ((wild-subdirs (rest wild)))
 206                    (or (null wild-subdirs)
 207                        (loop
 208                          (when (directory-components-match thing wild-subdirs)
 209                            (return t))
 210                          (pop thing)
 211                          (unless thing (return nil)))))
 212                  (and (consp thing)
 213                       (components-match (first thing) wild1)
 214                       (directory-components-match (rest thing)
 215                                                   (rest wild))))))))
 216
 217 ;;; Return true if pathname component THING is matched by WILD. (not
 218 ;;; commutative)
 219 (defun components-match (thing wild)
 220   (declare (type (or pattern symbol simple-string integer) thing wild))
 221   (or (eq thing wild)
 222       (eq wild :wild)
 223       (typecase thing
 224         (simple-base-string
 225          ;; String is matched by itself, a matching pattern or :WILD.
 226          (typecase wild
 227            (pattern
 228             (values (pattern-matches wild thing)))
 229            (simple-base-string
 230             (string= thing wild))))
 231         (pattern
 232          ;; A pattern is only matched by an identical pattern.
 233          (and (pattern-p wild) (pattern= thing wild)))
 234         (integer
 235          ;; An integer (version number) is matched by :WILD or the
 236          ;; same integer. This branch will actually always be NIL as
 237          ;; long as the version is a fixnum.
 238          (eql thing wild)))))
 239
 240 ;;; a predicate for comparing two pathname slot component sub-entries
 241 (defun compare-component (this that)
 242   (or (eql this that)
 243       (typecase this
 244         (simple-string
 245          (and (simple-string-p that)
 246               (string= this that)))
 247         (pattern
 248          (and (pattern-p that)
 249               (pattern= this that)))
 250         (cons
 251          (and (consp that)
 252               (compare-component (car this) (car that))
 253               (compare-component (cdr this) (cdr that)))))))
 254 \f
 255 ;;;; pathname functions
 256
 257 (defun pathname= (pathname1 pathname2)
 258   (declare (type pathname pathname1)
 259            (type pathname pathname2))
 260   (and (eq (%pathname-host pathname1)
 261            (%pathname-host pathname2))
 262        (compare-component (%pathname-device pathname1)
 263                           (%pathname-device pathname2))
 264        (compare-component (%pathname-directory pathname1)
 265                           (%pathname-directory pathname2))
 266        (compare-component (%pathname-name pathname1)
 267                           (%pathname-name pathname2))
 268        (compare-component (%pathname-type pathname1)
 269                           (%pathname-type pathname2))
 270        (compare-component (%pathname-version pathname1)
 271                           (%pathname-version pathname2))))
 272
 273 ;;; Convert PATHNAME-DESIGNATOR (a pathname, or string, or
 274 ;;; stream), into a pathname in pathname.
 275 ;;;
 276 ;;; FIXME: was rewritten, should be tested (or rewritten again, this
 277 ;;; time using ONCE-ONLY, *then* tested)
 278 ;;; FIXME: become SB!XC:DEFMACRO inside EVAL-WHEN (COMPILE EVAL)?
 279 (defmacro with-pathname ((pathname pathname-designator) &body body)
 280   (let ((pd0 (gensym)))
 281     `(let* ((,pd0 ,pathname-designator)
 282             (,pathname (etypecase ,pd0
 283                          (pathname ,pd0)
 284                          (string (parse-namestring ,pd0))
 285                          (file-stream (file-name ,pd0)))))
 286        ,@body)))
 287
 288 ;;; Convert the var, a host or string name for a host, into a
 289 ;;; LOGICAL-HOST structure or nil if not defined.
 290 ;;;
 291 ;;; pw notes 1/12/97 this potentially useful macro is not used anywhere
 292 ;;; and 'find-host' is not defined. 'find-logical-host' seems to be needed.
 293 #|
 294 (defmacro with-host ((var expr) &body body)
 295   `(let ((,var (let ((,var ,expr))
 296                  (typecase ,var
 297                    (logical-host ,var)
 298                    (string (find-logical-host ,var nil))
 299                    (t nil)))))
 300      ,@body))
 301 |#
 302
 303 (defun pathname (thing)
 304   #!+sb-doc
 305   "Convert thing (a pathname, string or stream) into a pathname."
 306   (declare (type pathname-designator thing))
 307   (with-pathname (pathname thing)
 308     pathname))
 309
 310 ;;; Change the case of thing if DIDDLE-P.
 311 (defun maybe-diddle-case (thing diddle-p)
 312   (if (and diddle-p (not (or (symbolp thing) (integerp thing))))
 313       (labels ((check-for (pred in)
 314                  (typecase in
 315                    (pattern
 316                     (dolist (piece (pattern-pieces in))
 317                       (when (typecase piece
 318                               (simple-string
 319                                (check-for pred piece))
 320                               (cons
 321                                (case (car piece)
 322                                  (:character-set
 323                                   (check-for pred (cdr piece))))))
 324                         (return t))))
 325                    (list
 326                     (dolist (x in)
 327                       (when (check-for pred x)
 328                         (return t))))
 329                    (simple-base-string
 330                     (dotimes (i (length in))
 331                       (when (funcall pred (schar in i))
 332                         (return t))))
 333                    (t nil)))
 334                (diddle-with (fun thing)
 335                  (typecase thing
 336                    (pattern
 337                     (make-pattern
 338                      (mapcar (lambda (piece)
 339                                (typecase piece
 340                                  (simple-base-string
 341                                   (funcall fun piece))
 342                                  (cons
 343                                   (case (car piece)
 344                                     (:character-set
 345                                      (cons :character-set
 346                                            (funcall fun (cdr piece))))
 347                                     (t
 348                                      piece)))
 349                                  (t
 350                                   piece)))
 351                              (pattern-pieces thing))))
 352                    (list
 353                     (mapcar fun thing))
 354                    (simple-base-string
 355                     (funcall fun thing))
 356                    (t
 357                     thing))))
 358         (let ((any-uppers (check-for #'upper-case-p thing))
 359               (any-lowers (check-for #'lower-case-p thing)))
 360           (cond ((and any-uppers any-lowers)
 361                  ;; mixed case, stays the same
 362                  thing)
 363                 (any-uppers
 364                  ;; all uppercase, becomes all lower case
 365                  (diddle-with (lambda (x) (if (stringp x)
 366                                               (string-downcase x)
 367                                               x)) thing))
 368                 (any-lowers
 369                  ;; all lowercase, becomes all upper case
 370                  (diddle-with (lambda (x) (if (stringp x)
 371                                               (string-upcase x)
 372                                               x)) thing))
 373                 (t
 374                  ;; no letters?  I guess just leave it.
 375                  thing))))
 376       thing))
 377
 378 (defun merge-directories (dir1 dir2 diddle-case)
 379   (if (or (eq (car dir1) :absolute)
 380           (null dir2))
 381       dir1
 382       (let ((results nil))
 383         (flet ((add (dir)
 384                  (if (and (eq dir :back)
 385                           results
 386                           (not (eq (car results) :back)))
 387                      (pop results)
 388                      (push dir results))))
 389           (dolist (dir (maybe-diddle-case dir2 diddle-case))
 390             (add dir))
 391           (dolist (dir (cdr dir1))
 392             (add dir)))
 393         (reverse results))))
 394
 395 (defun merge-pathnames (pathname
 396                         &optional
 397                         (defaults *default-pathname-defaults*)
 398                         (default-version :newest))
 399   #!+sb-doc
 400   "Construct a filled in pathname by completing the unspecified components
 401    from the defaults."
 402   (declare (type pathname-designator pathname)
 403            (type pathname-designator defaults)
 404            (values pathname))
 405   (with-pathname (defaults defaults)
 406     (let ((pathname (let ((*default-pathname-defaults* defaults))
 407                       (pathname pathname))))
 408       (let* ((default-host (%pathname-host defaults))
 409              (pathname-host (%pathname-host pathname))
 410              (diddle-case
 411               (and default-host pathname-host
 412                    (not (eq (host-customary-case default-host)
 413                             (host-customary-case pathname-host))))))
 414         (%make-maybe-logical-pathname
 415          (or pathname-host default-host)
 416          (or (%pathname-device pathname)
 417              (maybe-diddle-case (%pathname-device defaults)
 418                                 diddle-case))
 419          (merge-directories (%pathname-directory pathname)
 420                             (%pathname-directory defaults)
 421                             diddle-case)
 422          (or (%pathname-name pathname)
 423              (maybe-diddle-case (%pathname-name defaults)
 424                                 diddle-case))
 425          (or (%pathname-type pathname)
 426              (maybe-diddle-case (%pathname-type defaults)
 427                                 diddle-case))
 428          (or (%pathname-version pathname)
 429              default-version))))))
 430
 431 (defun import-directory (directory diddle-case)
 432   (etypecase directory
 433     (null nil)
 434     ((member :wild) '(:absolute :wild-inferiors))
 435     ((member :unspecific) '(:relative))
 436     (list
 437      (collect ((results))
 438        (results (pop directory))
 439        (dolist (piece directory)
 440          (cond ((member piece '(:wild :wild-inferiors :up :back))
 441                 (results piece))
 442                ((or (simple-string-p piece) (pattern-p piece))
 443                 (results (maybe-diddle-case piece diddle-case)))
 444                ((stringp piece)
 445                 (results (maybe-diddle-case (coerce piece 'simple-string)
 446                                             diddle-case)))
 447                (t
 448                 (error "~S is not allowed as a directory component." piece))))
 449        (results)))
 450     (simple-string
 451      `(:absolute
 452        ,(maybe-diddle-case directory diddle-case)))
 453     (string
 454      `(:absolute
 455        ,(maybe-diddle-case (coerce directory 'simple-string)
 456                            diddle-case)))))
 457
 458 (defun make-pathname (&key host
 459                            (device nil devp)
 460                            (directory nil dirp)
 461                            (name nil namep)
 462                            (type nil typep)
 463                            (version nil versionp)
 464                            defaults
 465                            (case :local))
 466   #!+sb-doc
 467   "Makes a new pathname from the component arguments. Note that host is
 468 a host-structure or string."
 469   (declare (type (or string host pathname-component-tokens) host)
 470            (type (or string pathname-component-tokens) device)
 471            (type (or list string pattern pathname-component-tokens) directory)
 472            (type (or string pattern pathname-component-tokens) name type)
 473            (type (or integer pathname-component-tokens (member :newest))
 474                  version)
 475            (type (or pathname-designator null) defaults)
 476            (type (member :common :local) case))
 477   (let* ((defaults (when defaults
 478                      (with-pathname (defaults defaults) defaults)))
 479          (default-host (if defaults
 480                            (%pathname-host defaults)
 481                            (pathname-host *default-pathname-defaults*)))
 482          ;; Raymond Toy writes: CLHS says make-pathname can take a
 483          ;; string (as a logical-host) for the host part. We map that
 484          ;; string into the corresponding logical host structure.
 485          ;;
 486          ;; Paul Werkowski writes:
 487          ;; HyperSpec says for the arg to MAKE-PATHNAME;
 488          ;; "host---a valid physical pathname host. ..."
 489          ;; where it probably means -- a valid pathname host.
 490          ;; "valid pathname host n. a valid physical pathname host or
 491          ;; a valid logical pathname host."
 492          ;; and defines
 493          ;; "valid physical pathname host n. any of a string,
 494          ;; a list of strings, or the symbol :unspecific,
 495          ;; that is recognized by the implementation as the name of a host."
 496          ;; "valid logical pathname host n. a string that has been defined
 497          ;; as the name of a logical host. ..."
 498          ;; HS is silent on what happens if the :HOST arg is NOT one of these.
 499          ;; It seems an error message is appropriate.
 500          (host (typecase host
 501                  (host host)            ; A valid host, use it.
 502                  ((string 0) *unix-host*) ; "" cannot be a logical host
 503                  (string (find-logical-host host t)) ; logical-host or lose.
 504                  (t default-host)))     ; unix-host
 505          (diddle-args (and (eq (host-customary-case host) :lower)
 506                            (eq case :common)))
 507          (diddle-defaults
 508           (not (eq (host-customary-case host)
 509                    (host-customary-case default-host))))
 510          (dev (if devp device (if defaults (%pathname-device defaults))))
 511          (dir (import-directory directory diddle-args))
 512          (ver (cond
 513                (versionp version)
 514                (defaults (%pathname-version defaults))
 515                (t nil))))
 516     (when (and defaults (not dirp))
 517       (setf dir
 518             (merge-directories dir
 519                                (%pathname-directory defaults)
 520                                diddle-defaults)))
 521
 522     (macrolet ((pick (var varp field)
 523                  `(cond ((or (simple-string-p ,var)
 524                              (pattern-p ,var))
 525                          (maybe-diddle-case ,var diddle-args))
 526                         ((stringp ,var)
 527                          (maybe-diddle-case (coerce ,var 'simple-string)
 528                                             diddle-args))
 529                         (,varp
 530                          (maybe-diddle-case ,var diddle-args))
 531                         (defaults
 532                          (maybe-diddle-case (,field defaults)
 533                                             diddle-defaults))
 534                         (t
 535                          nil))))
 536       (%make-maybe-logical-pathname host
 537                                     dev ; forced to :UNSPECIFIC when logical
 538                                     dir
 539                                     (pick name namep %pathname-name)
 540                                     (pick type typep %pathname-type)
 541                                     ver))))
 542
 543 (defun pathname-host (pathname &key (case :local))
 544   #!+sb-doc
 545   "Return PATHNAME's host."
 546   (declare (type pathname-designator pathname)
 547            (type (member :local :common) case)
 548            (values host)
 549            (ignore case))
 550   (with-pathname (pathname pathname)
 551     (%pathname-host pathname)))
 552
 553 (defun pathname-device (pathname &key (case :local))
 554   #!+sb-doc
 555   "Return PATHNAME's device."
 556   (declare (type pathname-designator pathname)
 557            (type (member :local :common) case))
 558   (with-pathname (pathname pathname)
 559     (maybe-diddle-case (%pathname-device pathname)
 560                        (and (eq case :common)
 561                             (eq (host-customary-case
 562                                  (%pathname-host pathname))
 563                                 :lower)))))
 564
 565 (defun pathname-directory (pathname &key (case :local))
 566   #!+sb-doc
 567   "Return PATHNAME's directory."
 568   (declare (type pathname-designator pathname)
 569            (type (member :local :common) case))
 570   (with-pathname (pathname pathname)
 571     (maybe-diddle-case (%pathname-directory pathname)
 572                        (and (eq case :common)
 573                             (eq (host-customary-case
 574                                  (%pathname-host pathname))
 575                                 :lower)))))
 576 (defun pathname-name (pathname &key (case :local))
 577   #!+sb-doc
 578   "Return PATHNAME's name."
 579   (declare (type pathname-designator pathname)
 580            (type (member :local :common) case))
 581   (with-pathname (pathname pathname)
 582     (maybe-diddle-case (%pathname-name pathname)
 583                        (and (eq case :common)
 584                             (eq (host-customary-case
 585                                  (%pathname-host pathname))
 586                                 :lower)))))
 587
 588 (defun pathname-type (pathname &key (case :local))
 589   #!+sb-doc
 590   "Return PATHNAME's type."
 591   (declare (type pathname-designator pathname)
 592            (type (member :local :common) case))
 593   (with-pathname (pathname pathname)
 594     (maybe-diddle-case (%pathname-type pathname)
 595                        (and (eq case :common)
 596                             (eq (host-customary-case
 597                                  (%pathname-host pathname))
 598                                 :lower)))))
 599
 600 (defun pathname-version (pathname)
 601   #!+sb-doc
 602   "Return PATHNAME's version."
 603   (declare (type pathname-designator pathname))
 604   (with-pathname (pathname pathname)
 605     (%pathname-version pathname)))
 606 \f
 607 ;;;; namestrings
 608
 609 ;;; Handle the case for PARSE-NAMESTRING parsing a potentially
 610 ;;; syntactically valid logical namestring with an explicit host.
 611 ;;;
 612 ;;; This then isn't fully general -- we are relying on the fact that
 613 ;;; we will only pass to parse-namestring namestring with an explicit
 614 ;;; logical host, so that we can pass the host return from
 615 ;;; parse-logical-namestring through to %PARSE-NAMESTRING as a truth
 616 ;;; value. Yeah, this is probably a KLUDGE - CSR, 2002-04-18
 617 (defun parseable-logical-namestring-p (namestr start end)
 618   (catch 'exit
 619     (handler-bind
 620         ((namestring-parse-error (lambda (c)
 621                                    (declare (ignore c))
 622                                    (throw 'exit nil))))
 623       (let ((colon (position #\: namestr :start start :end end)))
 624         (when colon
 625           (let ((potential-host
 626                  (logical-word-or-lose (subseq namestr start colon))))
 627             ;; depending on the outcome of CSR comp.lang.lisp post
 628             ;; "can PARSE-NAMESTRING create logical hosts", we may need
 629             ;; to do things with potential-host (create it
 630             ;; temporarily, parse the namestring and unintern the
 631             ;; logical host potential-host on failure.
 632             (declare (ignore potential-host))
 633             (let ((result
 634                    (handler-bind
 635                        ((simple-type-error (lambda (c)
 636                                              (declare (ignore c))
 637                                              (throw 'exit nil))))
 638                      (parse-logical-namestring namestr start end))))
 639               ;; if we got this far, we should have an explicit host
 640               ;; (first return value of parse-logical-namestring)
 641               (aver result)
 642               result)))))))
 643
 644 ;;; Handle the case where PARSE-NAMESTRING is actually parsing a
 645 ;;; namestring. We pick off the :JUNK-ALLOWED case then find a host to
 646 ;;; use for parsing, call the parser, then check whether the host matches.
 647 (defun %parse-namestring (namestr host defaults start end junk-allowed)
 648   (declare (type (or host null) host)
 649            (type string namestr)
 650            (type index start)
 651            (type (or index null) end))
 652   (if junk-allowed
 653       (handler-case
 654           (%parse-namestring namestr host defaults start end nil)
 655         (namestring-parse-error (condition)
 656           (values nil (namestring-parse-error-offset condition))))
 657       (let* ((end (or end (length namestr))))
 658         (multiple-value-bind (new-host device directory file type version)
 659             ;; Comments below are quotes from the HyperSpec
 660             ;; PARSE-NAMESTRING entry, reproduced here to demonstrate
 661             ;; that we actually have to do things this way rather than
 662             ;; some possibly more logical way. - CSR, 2002-04-18
 663             (cond
 664               ;; "If host is a logical host then thing is parsed as a
 665               ;; logical pathname namestring on the host."
 666               (host (funcall (host-parse host) namestr start end))
 667               ;; "If host is nil and thing is a syntactically valid
 668               ;; logical pathname namestring containing an explicit
 669               ;; host, then it is parsed as a logical pathname
 670               ;; namestring."
 671               ((parseable-logical-namestring-p namestr start end)
 672                (parse-logical-namestring namestr start end))
 673               ;; "If host is nil, default-pathname is a logical
 674               ;; pathname, and thing is a syntactically valid logical
 675               ;; pathname namestring without an explicit host, then it
 676               ;; is parsed as a logical pathname namestring on the
 677               ;; host that is the host component of default-pathname."
 678               ;;
 679               ;; "Otherwise, the parsing of thing is
 680               ;; implementation-defined."
 681               ;;
 682               ;; Both clauses are handled here, as the default
 683               ;; *DEFAULT-PATHNAME-DEFAULTS has a SB-IMPL::UNIX-HOST
 684               ;; for a host.
 685               ((pathname-host defaults)
 686                (funcall (host-parse (pathname-host defaults))
 687                         namestr
 688                         start
 689                         end))
 690               ;; I don't think we should ever get here, as the default
 691               ;; host will always have a non-null HOST, given that we
 692               ;; can't create a new pathname without going through
 693               ;; *DEFAULT-PATHNAME-DEFAULTS*, which has a non-null
 694               ;; host...
 695               (t (bug "Fallen through COND in %PARSE-NAMESTRING")))
 696           (when (and host new-host (not (eq new-host host)))
 697             (error 'simple-type-error
 698                    :datum new-host
 699                    ;; Note: ANSI requires that this be a TYPE-ERROR,
 700                    ;; but there seems to be no completely correct
 701                    ;; value to use for TYPE-ERROR-EXPECTED-TYPE.
 702                    ;; Instead, we return a sort of "type error allowed
 703                    ;; type", trying to say "it would be OK if you
 704                    ;; passed NIL as the host value" but not mentioning
 705                    ;; that a matching string would be OK too.
 706                    :expected-type 'null
 707                    :format-control
 708                    "The host in the namestring, ~S,~@
 709                     does not match the explicit HOST argument, ~S."
 710                    :format-arguments (list new-host host)))
 711           (let ((pn-host (or new-host host (pathname-host defaults))))
 712             (values (%make-maybe-logical-pathname
 713                      pn-host device directory file type version)
 714                     end))))))
 715
 716 ;;; If NAMESTR begins with a colon-terminated, defined, logical host,
 717 ;;; then return that host, otherwise return NIL.
 718 (defun extract-logical-host-prefix (namestr start end)
 719   (declare (type simple-base-string namestr)
 720            (type index start end)
 721            (values (or logical-host null)))
 722   (let ((colon-pos (position #\: namestr :start start :end end)))
 723     (if colon-pos
 724         (values (gethash (nstring-upcase (subseq namestr start colon-pos))
 725                          *logical-hosts*))
 726         nil)))
 727
 728 (defun parse-namestring (thing
 729                          &optional
 730                          host
 731                          (defaults *default-pathname-defaults*)
 732                          &key (start 0) end junk-allowed)
 733   (declare (type pathname-designator thing)
 734            (type (or list host string (member :unspecific)) host)
 735            (type pathname defaults)
 736            (type index start)
 737            (type (or index null) end)
 738            (type (or t null) junk-allowed)
 739            (values (or null pathname) (or null index)))
 740   ;; Generally, redundant specification of information in software,
 741   ;; whether in code or in comments, is bad. However, the ANSI spec
 742   ;; for this is messy enough that it's hard to hold in short-term
 743   ;; memory, so I've recorded these redundant notes on the
 744   ;; implications of the ANSI spec.
 745   ;;
 746   ;; According to the ANSI spec, HOST can be a valid pathname host, or
 747   ;; a logical host, or NIL.
 748   ;;
 749   ;; A valid pathname host can be a valid physical pathname host or a
 750   ;; valid logical pathname host.
 751   ;;
 752   ;; A valid physical pathname host is "any of a string, a list of
 753   ;; strings, or the symbol :UNSPECIFIC, that is recognized by the
 754   ;; implementation as the name of a host". In SBCL as of 0.6.9.8,
 755   ;; that means :UNSPECIFIC: though someday we might want to
 756   ;; generalize it to allow strings like "RTFM.MIT.EDU" or lists like
 757   ;; '("RTFM" "MIT" "EDU"), that's not supported now.
 758   ;;
 759   ;; A valid logical pathname host is a string which has been defined as
 760   ;; the name of a logical host, as with LOAD-LOGICAL-PATHNAME-TRANSLATIONS.
 761   ;;
 762   ;; A logical host is an object of implementation-dependent nature. In
 763   ;; SBCL, it's a member of the HOST class (a subclass of STRUCTURE-OBJECT).
 764   (let ((found-host (etypecase host
 765                       ((string 0)
 766                        ;; This is a special host. It's not valid as a
 767                        ;; logical host, so it is a sensible thing to
 768                        ;; designate the physical Unix host object. So
 769                        ;; we do that.
 770                        *unix-host*)
 771                       (string
 772                        ;; In general ANSI-compliant Common Lisps, a
 773                        ;; string might also be a physical pathname host,
 774                        ;; but ANSI leaves this up to the implementor,
 775                        ;; and in SBCL we don't do it, so it must be a
 776                        ;; logical host.
 777                        (find-logical-host host))
 778                       ((or null (member :unspecific))
 779                        ;; CLHS says that HOST=:UNSPECIFIC has
 780                        ;; implementation-defined behavior. We
 781                        ;; just turn it into NIL.
 782                        nil)
 783                       (list
 784                        ;; ANSI also allows LISTs to designate hosts,
 785                        ;; but leaves its interpretation
 786                        ;; implementation-defined. Our interpretation
 787                        ;; is that it's unsupported.:-|
 788                        (error "A LIST representing a pathname host is not ~
 789                               supported in this implementation:~%  ~S"
 790                               host))
 791                       (host
 792                        host))))
 793     (declare (type (or null host) found-host))
 794     (etypecase thing
 795       (simple-string
 796        (%parse-namestring thing found-host defaults start end junk-allowed))
 797       (string
 798        (%parse-namestring (coerce thing 'simple-string)
 799                           found-host defaults start end junk-allowed))
 800       (pathname
 801        (let ((defaulted-host (or found-host (%pathname-host defaults))))
 802          (declare (type host defaulted-host))
 803          (unless (eq defaulted-host (%pathname-host thing))
 804            (error "The HOST argument doesn't match the pathname host:~%  ~
 805                   ~S and ~S."
 806                   defaulted-host (%pathname-host thing))))
 807        (values thing start))
 808       (stream
 809        (let ((name (file-name thing)))
 810          (unless name
 811            (error "can't figure out the file associated with stream:~%  ~S"
 812                   thing))
 813          (values name nil))))))
 814
 815 (defun namestring (pathname)
 816   #!+sb-doc
 817   "Construct the full (name)string form of the pathname."
 818   (declare (type pathname-designator pathname)
 819            (values (or null simple-base-string)))
 820   (with-pathname (pathname pathname)
 821     (when pathname
 822       (let ((host (%pathname-host pathname)))
 823         (unless host
 824           (error "can't determine the namestring for pathnames with no ~
 825                   host:~%  ~S" pathname))
 826         (funcall (host-unparse host) pathname)))))
 827
 828 (defun host-namestring (pathname)
 829   #!+sb-doc
 830   "Return a string representation of the name of the host in the pathname."
 831   (declare (type pathname-designator pathname)
 832            (values (or null simple-base-string)))
 833   (with-pathname (pathname pathname)
 834     (let ((host (%pathname-host pathname)))
 835       (if host
 836           (funcall (host-unparse-host host) pathname)
 837           (error
 838            "can't determine the namestring for pathnames with no host:~%  ~S"
 839            pathname)))))
 840
 841 (defun directory-namestring (pathname)
 842   #!+sb-doc
 843   "Return a string representation of the directories used in the pathname."
 844   (declare (type pathname-designator pathname)
 845            (values (or null simple-base-string)))
 846   (with-pathname (pathname pathname)
 847     (let ((host (%pathname-host pathname)))
 848       (if host
 849           (funcall (host-unparse-directory host) pathname)
 850           (error
 851            "can't determine the namestring for pathnames with no host:~%  ~S"
 852            pathname)))))
 853
 854 (defun file-namestring (pathname)
 855   #!+sb-doc
 856   "Return a string representation of the name used in the pathname."
 857   (declare (type pathname-designator pathname)
 858            (values (or null simple-base-string)))
 859   (with-pathname (pathname pathname)
 860     (let ((host (%pathname-host pathname)))
 861       (if host
 862           (funcall (host-unparse-file host) pathname)
 863           (error
 864            "can't determine the namestring for pathnames with no host:~%  ~S"
 865            pathname)))))
 866
 867 (defun enough-namestring (pathname
 868                           &optional
 869                           (defaults *default-pathname-defaults*))
 870   #!+sb-doc
 871   "Return an abbreviated pathname sufficent to identify the pathname relative
 872    to the defaults."
 873   (declare (type pathname-designator pathname))
 874   (with-pathname (pathname pathname)
 875     (let ((host (%pathname-host pathname)))
 876       (if host
 877           (with-pathname (defaults defaults)
 878             (funcall (host-unparse-enough host) pathname defaults))
 879           (error
 880            "can't determine the namestring for pathnames with no host:~%  ~S"
 881            pathname)))))
 882 \f
 883 ;;;; wild pathnames
 884
 885 (defun wild-pathname-p (pathname &optional field-key)
 886   #!+sb-doc
 887   "Predicate for determining whether pathname contains any wildcards."
 888   (declare (type pathname-designator pathname)
 889            (type (member nil :host :device :directory :name :type :version)
 890                  field-key))
 891   (with-pathname (pathname pathname)
 892     (flet ((frob (x)
 893              (or (pattern-p x) (member x '(:wild :wild-inferiors)))))
 894       (ecase field-key
 895         ((nil)
 896          (or (wild-pathname-p pathname :host)
 897              (wild-pathname-p pathname :device)
 898              (wild-pathname-p pathname :directory)
 899              (wild-pathname-p pathname :name)
 900              (wild-pathname-p pathname :type)
 901              (wild-pathname-p pathname :version)))
 902         (:host (frob (%pathname-host pathname)))
 903         (:device (frob (%pathname-host pathname)))
 904         (:directory (some #'frob (%pathname-directory pathname)))
 905         (:name (frob (%pathname-name pathname)))
 906         (:type (frob (%pathname-type pathname)))
 907         (:version (frob (%pathname-version pathname)))))))
 908
 909 (defun pathname-match-p (in-pathname in-wildname)
 910   #!+sb-doc
 911   "Pathname matches the wildname template?"
 912   (declare (type pathname-designator in-pathname))
 913   (with-pathname (pathname in-pathname)
 914     (with-pathname (wildname in-wildname)
 915       (macrolet ((frob (field &optional (op 'components-match))
 916                    `(or (null (,field wildname))
 917                         (,op (,field pathname) (,field wildname)))))
 918         (and (or (null (%pathname-host wildname))
 919                  (eq (%pathname-host wildname) (%pathname-host pathname)))
 920              (frob %pathname-device)
 921              (frob %pathname-directory directory-components-match)
 922              (frob %pathname-name)
 923              (frob %pathname-type)
 924              (frob %pathname-version))))))
 925
 926 ;;; Place the substitutions into the pattern and return the string or pattern
 927 ;;; that results. If DIDDLE-CASE is true, we diddle the result case as well,
 928 ;;; in case we are translating between hosts with difference conventional case.
 929 ;;; The second value is the tail of subs with all of the values that we used up
 930 ;;; stripped off. Note that PATTERN-MATCHES matches all consecutive wildcards
 931 ;;; as a single string, so we ignore subsequent contiguous wildcards.
 932 (defun substitute-into (pattern subs diddle-case)
 933   (declare (type pattern pattern)
 934            (type list subs)
 935            (values (or simple-base-string pattern) list))
 936   (let ((in-wildcard nil)
 937         (pieces nil)
 938         (strings nil))
 939     (dolist (piece (pattern-pieces pattern))
 940       (cond ((simple-string-p piece)
 941              (push piece strings)
 942              (setf in-wildcard nil))
 943             (in-wildcard)
 944             (t
 945              (setf in-wildcard t)
 946              (unless subs
 947                (error "not enough wildcards in FROM pattern to match ~
 948                        TO pattern:~%  ~S"
 949                       pattern))
 950              (let ((sub (pop subs)))
 951                (typecase sub
 952                  (pattern
 953                   (when strings
 954                     (push (apply #'concatenate 'simple-string
 955                                  (nreverse strings))
 956                           pieces))
 957                   (dolist (piece (pattern-pieces sub))
 958                     (push piece pieces)))
 959                  (simple-string
 960                   (push sub strings))
 961                  (t
 962                   (error "can't substitute this into the middle of a word:~
 963                           ~%  ~S"
 964                          sub)))))))
 965
 966     (when strings
 967       (push (apply #'concatenate 'simple-string (nreverse strings))
 968             pieces))
 969     (values
 970      (maybe-diddle-case
 971       (if (and pieces (simple-string-p (car pieces)) (null (cdr pieces)))
 972           (car pieces)
 973           (make-pattern (nreverse pieces)))
 974       diddle-case)
 975      subs)))
 976
 977 ;;; Called when we can't see how source and from matched.
 978 (defun didnt-match-error (source from)
 979   (error "Pathname components from SOURCE and FROM args to TRANSLATE-PATHNAME~@
 980           did not match:~%  ~S ~S"
 981          source from))
 982
 983 ;;; Do TRANSLATE-COMPONENT for all components except host and directory.
 984 (defun translate-component (source from to diddle-case)
 985   (typecase to
 986     (pattern
 987      (typecase from
 988        (pattern
 989         (typecase source
 990           (pattern
 991            (if (pattern= from source)
 992                source
 993                (didnt-match-error source from)))
 994           (simple-string
 995            (multiple-value-bind (won subs) (pattern-matches from source)
 996              (if won
 997                  (values (substitute-into to subs diddle-case))
 998                  (didnt-match-error source from))))
 999           (t
1000            (maybe-diddle-case source diddle-case))))
1001        ((member :wild)
1002         (values (substitute-into to (list source) diddle-case)))
1003        (t
1004         (if (components-match source from)
1005             (maybe-diddle-case source diddle-case)
1006             (didnt-match-error source from)))))
1007     ((member nil :wild)
1008      (maybe-diddle-case source diddle-case))
1009     (t
1010      (if (components-match source from)
1011          to
1012          (didnt-match-error source from)))))
1013
1014 ;;; Return a list of all the things that we want to substitute into the TO
1015 ;;; pattern (the things matched by from on source.)  When From contains
1016 ;;; :WILD-INFERIORS, the result contains a sublist of the matched source
1017 ;;; subdirectories.
1018 (defun compute-directory-substitutions (orig-source orig-from)
1019   (let ((source orig-source)
1020         (from orig-from))
1021     (collect ((subs))
1022       (loop
1023         (unless source
1024           (unless (every (lambda (x) (eq x :wild-inferiors)) from)
1025             (didnt-match-error orig-source orig-from))
1026           (subs ())
1027           (return))
1028         (unless from (didnt-match-error orig-source orig-from))
1029         (let ((from-part (pop from))
1030               (source-part (pop source)))
1031           (typecase from-part
1032             (pattern
1033              (typecase source-part
1034                (pattern
1035                 (if (pattern= from-part source-part)
1036                     (subs source-part)
1037                     (didnt-match-error orig-source orig-from)))
1038                (simple-string
1039                 (multiple-value-bind (won new-subs)
1040                     (pattern-matches from-part source-part)
1041                   (if won
1042                       (dolist (sub new-subs)
1043                         (subs sub))
1044                       (didnt-match-error orig-source orig-from))))
1045                (t
1046                 (didnt-match-error orig-source orig-from))))
1047             ((member :wild)
1048              (subs source-part))
1049             ((member :wild-inferiors)
1050              (let ((remaining-source (cons source-part source)))
1051                (collect ((res))
1052                  (loop
1053                    (when (directory-components-match remaining-source from)
1054                      (return))
1055                    (unless remaining-source
1056                      (didnt-match-error orig-source orig-from))
1057                    (res (pop remaining-source)))
1058                  (subs (res))
1059                  (setq source remaining-source))))
1060             (simple-string
1061              (unless (and (simple-string-p source-part)
1062                           (string= from-part source-part))
1063                (didnt-match-error orig-source orig-from)))
1064             (t
1065              (didnt-match-error orig-source orig-from)))))
1066       (subs))))
1067
1068 ;;; This is called by TRANSLATE-PATHNAME on the directory components
1069 ;;; of its argument pathnames to produce the result directory
1070 ;;; component. If this leaves the directory NIL, we return the source
1071 ;;; directory. The :RELATIVE or :ABSOLUTE is taken from the source
1072 ;;; directory, except if TO is :ABSOLUTE, in which case the result
1073 ;;; will be :ABSOLUTE.
1074 (defun translate-directories (source from to diddle-case)
1075   (if (not (and source to from))
1076       (or (and to (null source) (remove :wild-inferiors to))
1077           (mapcar (lambda (x) (maybe-diddle-case x diddle-case)) source))
1078       (collect ((res))
1079                ;; If TO is :ABSOLUTE, the result should still be :ABSOLUTE.
1080                (res (if (eq (first to) :absolute)
1081                  :absolute
1082                  (first source)))
1083         (let ((subs-left (compute-directory-substitutions (rest source)
1084                                                           (rest from))))
1085           (dolist (to-part (rest to))
1086             (typecase to-part
1087               ((member :wild)
1088                (aver subs-left)
1089                (let ((match (pop subs-left)))
1090                  (when (listp match)
1091                    (error ":WILD-INFERIORS is not paired in from and to ~
1092                            patterns:~%  ~S ~S" from to))
1093                  (res (maybe-diddle-case match diddle-case))))
1094               ((member :wild-inferiors)
1095                (aver subs-left)
1096                (let ((match (pop subs-left)))
1097                  (unless (listp match)
1098                    (error ":WILD-INFERIORS not paired in from and to ~
1099                            patterns:~%  ~S ~S" from to))
1100                  (dolist (x match)
1101                    (res (maybe-diddle-case x diddle-case)))))
1102               (pattern
1103                (multiple-value-bind
1104                    (new new-subs-left)
1105                    (substitute-into to-part subs-left diddle-case)
1106                  (setf subs-left new-subs-left)
1107                  (res new)))
1108               (t (res to-part)))))
1109         (res))))
1110
1111 (defun translate-pathname (source from-wildname to-wildname &key)
1112   #!+sb-doc
1113   "Use the source pathname to translate the from-wildname's wild and
1114    unspecified elements into a completed to-pathname based on the to-wildname."
1115   (declare (type pathname-designator source from-wildname to-wildname))
1116   (with-pathname (source source)
1117     (with-pathname (from from-wildname)
1118       (with-pathname (to to-wildname)
1119           (let* ((source-host (%pathname-host source))
1120                  (to-host (%pathname-host to))
1121                  (diddle-case
1122                   (and source-host to-host
1123                        (not (eq (host-customary-case source-host)
1124                                 (host-customary-case to-host))))))
1125             (macrolet ((frob (field &optional (op 'translate-component))
1126                          `(let ((result (,op (,field source)
1127                                              (,field from)
1128                                              (,field to)
1129                                              diddle-case)))
1130                             (if (eq result :error)
1131                                 (error "~S doesn't match ~S." source from)
1132                                 result))))
1133               (%make-maybe-logical-pathname
1134                (or to-host source-host)
1135                (frob %pathname-device)
1136                (frob %pathname-directory translate-directories)
1137                (frob %pathname-name)
1138                (frob %pathname-type)
1139                (frob %pathname-version))))))))
1140 \f
1141 ;;;;  logical pathname support. ANSI 92-102 specification.
1142 ;;;;
1143 ;;;;  As logical-pathname translations are loaded they are
1144 ;;;;  canonicalized as patterns to enable rapid efficient translation
1145 ;;;;  into physical pathnames.
1146
1147 ;;;; utilities
1148
1149 ;;; Canonicalize a logical pathname word by uppercasing it checking that it
1150 ;;; contains only legal characters.
1151 (defun logical-word-or-lose (word)
1152   (declare (string word))
1153   (when (string= word "")
1154     (error 'namestring-parse-error
1155            :complaint "Attempted to treat invalid logical hostname ~
1156                        as a logical host:~%  ~S"
1157            :args (list word)
1158            :namestring word :offset 0))
1159   (let ((word (string-upcase word)))
1160     (dotimes (i (length word))
1161       (let ((ch (schar word i)))
1162         (unless (or (alpha-char-p ch) (digit-char-p ch) (char= ch #\-))
1163           (error 'namestring-parse-error
1164                  :complaint "logical namestring character which ~
1165                              is not alphanumeric or hyphen:~%  ~S"
1166                  :args (list ch)
1167                  :namestring word :offset i))))
1168     word))
1169
1170 ;;; Given a logical host or string, return a logical host. If ERROR-P
1171 ;;; is NIL, then return NIL when no such host exists.
1172 (defun find-logical-host (thing &optional (errorp t))
1173   (etypecase thing
1174     (string
1175      (let ((found (gethash (logical-word-or-lose thing)
1176                            *logical-hosts*)))
1177        (if (or found (not errorp))
1178            found
1179            ;; This is the error signalled from e.g.
1180            ;; LOGICAL-PATHNAME-TRANSLATIONS when host is not a defined
1181            ;; host, and ANSI specifies that that's a TYPE-ERROR.
1182            (error 'simple-type-error
1183                   :datum thing
1184                   ;; God only knows what ANSI expects us to use for
1185                   ;; the EXPECTED-TYPE here. Maybe this will be OK..
1186                   :expected-type
1187                   '(and string (satisfies logical-pathname-translations))
1188                   :format-control "logical host not yet defined: ~S"
1189                   :format-arguments (list thing)))))
1190     (logical-host thing)))
1191
1192 ;;; Given a logical host name or host, return a logical host, creating
1193 ;;; a new one if necessary.
1194 (defun intern-logical-host (thing)
1195   (declare (values logical-host))
1196   (or (find-logical-host thing nil)
1197       (let* ((name (logical-word-or-lose thing))
1198              (new (make-logical-host :name name)))
1199         (setf (gethash name *logical-hosts*) new)
1200         new)))
1201 \f
1202 ;;;; logical pathname parsing
1203
1204 ;;; Deal with multi-char wildcards in a logical pathname token.
1205 (defun maybe-make-logical-pattern (namestring chunks)
1206   (let ((chunk (caar chunks)))
1207     (collect ((pattern))
1208       (let ((last-pos 0)
1209             (len (length chunk)))
1210         (declare (fixnum last-pos))
1211         (loop
1212           (when (= last-pos len) (return))
1213           (let ((pos (or (position #\* chunk :start last-pos) len)))
1214             (if (= pos last-pos)
1215                 (when (pattern)
1216                   (error 'namestring-parse-error
1217                          :complaint "double asterisk inside of logical ~
1218                                      word: ~S"
1219                          :args (list chunk)
1220                          :namestring namestring
1221                          :offset (+ (cdar chunks) pos)))
1222                 (pattern (subseq chunk last-pos pos)))
1223             (if (= pos len)
1224                 (return)
1225                 (pattern :multi-char-wild))
1226             (setq last-pos (1+ pos)))))
1227         (aver (pattern))
1228         (if (cdr (pattern))
1229             (make-pattern (pattern))
1230             (let ((x (car (pattern))))
1231               (if (eq x :multi-char-wild)
1232                   :wild
1233                   x))))))
1234
1235 ;;; Return a list of conses where the CDR is the start position and
1236 ;;; the CAR is a string (token) or character (punctuation.)
1237 (defun logical-chunkify (namestr start end)
1238   (collect ((chunks))
1239     (do ((i start (1+ i))
1240          (prev 0))
1241         ((= i end)
1242          (when (> end prev)
1243             (chunks (cons (nstring-upcase (subseq namestr prev end)) prev))))
1244       (let ((ch (schar namestr i)))
1245         (unless (or (alpha-char-p ch) (digit-char-p ch)
1246                     (member ch '(#\- #\*)))
1247           (when (> i prev)
1248             (chunks (cons (nstring-upcase (subseq namestr prev i)) prev)))
1249           (setq prev (1+ i))
1250           (unless (member ch '(#\; #\: #\.))
1251             (error 'namestring-parse-error
1252                    :complaint "illegal character for logical pathname:~%  ~S"
1253                    :args (list ch)
1254                    :namestring namestr
1255                    :offset i))
1256           (chunks (cons ch i)))))
1257     (chunks)))
1258
1259 ;;; Break up a logical-namestring, always a string, into its
1260 ;;; constituent parts.
1261 (defun parse-logical-namestring (namestr start end)
1262   (declare (type simple-base-string namestr)
1263            (type index start end))
1264   (collect ((directory))
1265     (let ((host nil)
1266           (name nil)
1267           (type nil)
1268           (version nil))
1269       (labels ((expecting (what chunks)
1270                  (unless (and chunks (simple-string-p (caar chunks)))
1271                    (error 'namestring-parse-error
1272                           :complaint "expecting ~A, got ~:[nothing~;~S~]."
1273                           :args (list what (caar chunks) (caar chunks))
1274                           :namestring namestr
1275                           :offset (if chunks (cdar chunks) end)))
1276                  (caar chunks))
1277                (parse-host (chunks)
1278                  (case (caadr chunks)
1279                    (#\:
1280                     (setq host
1281                           (find-logical-host (expecting "a host name" chunks)))
1282                     (parse-relative (cddr chunks)))
1283                    (t
1284                     (parse-relative chunks))))
1285                (parse-relative (chunks)
1286                  (case (caar chunks)
1287                    (#\;
1288                     (directory :relative)
1289                     (parse-directory (cdr chunks)))
1290                    (t
1291                     (directory :absolute) ; Assumption! Maybe revoked later.
1292                     (parse-directory chunks))))
1293                (parse-directory (chunks)
1294                  (case (caadr chunks)
1295                    (#\;
1296                     (directory
1297                      (let ((res (expecting "a directory name" chunks)))
1298                        (cond ((string= res "..") :up)
1299                              ((string= res "**") :wild-inferiors)
1300                              (t
1301                               (maybe-make-logical-pattern namestr chunks)))))
1302                     (parse-directory (cddr chunks)))
1303                    (t
1304                     (parse-name chunks))))
1305                (parse-name (chunks)
1306                  (when chunks
1307                    (expecting "a file name" chunks)
1308                    (setq name (maybe-make-logical-pattern namestr chunks))
1309                    (expecting-dot (cdr chunks))))
1310                (expecting-dot (chunks)
1311                  (when chunks
1312                    (unless (eql (caar chunks) #\.)
1313                      (error 'namestring-parse-error
1314                             :complaint "expecting a dot, got ~S."
1315                             :args (list (caar chunks))
1316                             :namestring namestr
1317                             :offset (cdar chunks)))
1318                    (if type
1319                        (parse-version (cdr chunks))
1320                        (parse-type (cdr chunks)))))
1321                (parse-type (chunks)
1322                  (expecting "a file type" chunks)
1323                  (setq type (maybe-make-logical-pattern namestr chunks))
1324                  (expecting-dot (cdr chunks)))
1325                (parse-version (chunks)
1326                  (let ((str (expecting "a positive integer, * or NEWEST"
1327                                        chunks)))
1328                    (cond
1329                     ((string= str "*") (setq version :wild))
1330                     ((string= str "NEWEST") (setq version :newest))
1331                     (t
1332                      (multiple-value-bind (res pos)
1333                          (parse-integer str :junk-allowed t)
1334                        (unless (and res (plusp res))
1335                          (error 'namestring-parse-error
1336                                 :complaint "expected a positive integer, ~
1337                                             got ~S"
1338                                 :args (list str)
1339                                 :namestring namestr
1340                                 :offset (+ pos (cdar chunks))))
1341                        (setq version res)))))
1342                  (when (cdr chunks)
1343                    (error 'namestring-parse-error
1344                           :complaint "extra stuff after end of file name"
1345                           :namestring namestr
1346                           :offset (cdadr chunks)))))
1347         (parse-host (logical-chunkify namestr start end)))
1348       (values host :unspecific (directory) name type version))))
1349
1350 ;;; We can't initialize this yet because not all host methods are
1351 ;;; loaded yet.
1352 (defvar *logical-pathname-defaults*)
1353
1354 (defun logical-pathname (pathspec)
1355   #!+sb-doc
1356   "Converts the pathspec argument to a logical-pathname and returns it."
1357   (declare (type (or logical-pathname string stream) pathspec)
1358            (values logical-pathname))
1359   (if (typep pathspec 'logical-pathname)
1360       pathspec
1361       (let ((res (parse-namestring pathspec nil *logical-pathname-defaults*)))
1362         (when (eq (%pathname-host res)
1363                   (%pathname-host *logical-pathname-defaults*))
1364           (error "This logical namestring does not specify a host:~%  ~S"
1365                  pathspec))
1366         res)))
1367 \f
1368 ;;;; logical pathname unparsing
1369
1370 (defun unparse-logical-directory (pathname)
1371   (declare (type pathname pathname))
1372   (collect ((pieces))
1373     (let ((directory (%pathname-directory pathname)))
1374       (when directory
1375         (ecase (pop directory)
1376           (:absolute) ; nothing special
1377           (:relative (pieces ";")))
1378         (dolist (dir directory)
1379           (cond ((or (stringp dir) (pattern-p dir))
1380                  (pieces (unparse-logical-piece dir))
1381                  (pieces ";"))
1382                 ((eq dir :wild)
1383                  (pieces "*;"))
1384                 ((eq dir :wild-inferiors)
1385                  (pieces "**;"))
1386                 (t
1387                  (error "invalid directory component: ~S" dir))))))
1388     (apply #'concatenate 'simple-string (pieces))))
1389
1390 (defun unparse-logical-piece (thing)
1391   (etypecase thing
1392     (simple-string thing)
1393     (pattern
1394      (collect ((strings))
1395        (dolist (piece (pattern-pieces thing))
1396          (etypecase piece
1397            (simple-string (strings piece))
1398            (keyword
1399             (cond ((eq piece :wild-inferiors)
1400                    (strings "**"))
1401                   ((eq piece :multi-char-wild)
1402                    (strings "*"))
1403                   (t (error "invalid keyword: ~S" piece))))))
1404        (apply #'concatenate 'simple-string (strings))))))
1405
1406 ;;; Unparse a logical pathname string.
1407 (defun unparse-enough-namestring (pathname defaults)
1408   (let* ((path-directory (pathname-directory pathname))
1409          (def-directory (pathname-directory defaults))
1410          (enough-directory
1411            ;; Go down the directory lists to see what matches.  What's
1412            ;; left is what we want, more or less.
1413            (cond ((and (eq (first path-directory) (first def-directory))
1414                        (eq (first path-directory) :absolute))
1415                    ;; Both paths are :ABSOLUTE, so find where the
1416                    ;; common parts end and return what's left
1417                    (do* ((p (rest path-directory) (rest p))
1418                          (d (rest def-directory) (rest d)))
1419                         ((or (endp p) (endp d)
1420                              (not (equal (first p) (first d))))
1421                          `(:relative ,@p))))
1422                  (t
1423                    ;; At least one path is :RELATIVE, so just return the
1424                    ;; original path.  If the original path is :RELATIVE,
1425                    ;; then that's the right one.  If PATH-DIRECTORY is
1426                    ;; :ABSOLUTE, we want to return that except when
1427                    ;; DEF-DIRECTORY is :ABSOLUTE, as handled above. so return
1428                    ;; the original directory.
1429                    path-directory))))
1430     (make-pathname :host (pathname-host pathname)
1431                    :directory enough-directory
1432                    :name (pathname-name pathname)
1433                    :type (pathname-type pathname)
1434                    :version (pathname-version pathname))))
1435
1436 (defun unparse-logical-namestring (pathname)
1437   (declare (type logical-pathname pathname))
1438   (concatenate 'simple-string
1439                (logical-host-name (%pathname-host pathname)) ":"
1440                (unparse-logical-directory pathname)
1441                (unparse-unix-file pathname)))
1442 \f
1443 ;;;; logical pathname translations
1444
1445 ;;; Verify that the list of translations consists of lists and prepare
1446 ;;; canonical translations. (Parse pathnames and expand out wildcards
1447 ;;; into patterns.)
1448 (defun canonicalize-logical-pathname-translations (translation-list host)
1449   (declare (type list translation-list) (type host host)
1450            (values list))
1451   (mapcar (lambda (translation)
1452             (destructuring-bind (from to) translation
1453               (list (if (typep from 'logical-pathname)
1454                         from
1455                         (parse-namestring from host))
1456                     (pathname to))))
1457           translation-list))
1458
1459 (defun logical-pathname-translations (host)
1460   #!+sb-doc
1461   "Return the (logical) host object argument's list of translations."
1462   (declare (type (or string logical-host) host)
1463            (values list))
1464   (logical-host-translations (find-logical-host host)))
1465
1466 (defun (setf logical-pathname-translations) (translations host)
1467   #!+sb-doc
1468   "Set the translations list for the logical host argument."
1469   (declare (type (or string logical-host) host)
1470            (type list translations)
1471            (values list))
1472   (let ((host (intern-logical-host host)))
1473     (setf (logical-host-canon-transls host)
1474           (canonicalize-logical-pathname-translations translations host))
1475     (setf (logical-host-translations host) translations)))
1476
1477 (defun translate-logical-pathname (pathname &key)
1478   #!+sb-doc
1479   "Translate PATHNAME to a physical pathname, which is returned."
1480   (declare (type pathname-designator pathname)
1481            (values (or null pathname)))
1482   (typecase pathname
1483     (logical-pathname
1484      (dolist (x (logical-host-canon-transls (%pathname-host pathname))
1485                 (error 'simple-file-error
1486                        :pathname pathname
1487                        :format-control "no translation for ~S"
1488                        :format-arguments (list pathname)))
1489        (destructuring-bind (from to) x
1490          (when (pathname-match-p pathname from)
1491            (return (translate-logical-pathname
1492                     (translate-pathname pathname from to)))))))
1493     (pathname pathname)
1494     (t (translate-logical-pathname (pathname pathname)))))
1495
1496 (defvar *logical-pathname-defaults*
1497   (%make-logical-pathname (make-logical-host :name "BOGUS")
1498                           :unspecific
1499                           nil
1500                           nil
1501                           nil
1502                           nil))
1503
1504 (defun load-logical-pathname-translations (host)
1505   #!+sb-doc
1506   (declare (type string host)
1507            (values (member t nil)))
1508   (if (find-logical-host host nil)
1509       ;; This host is already defined, all is well and good.
1510       t
1511       ;; ANSI: "The specific nature of the search is
1512       ;; implementation-defined." SBCL: doesn't search at all
1513       (error "logical host ~S not found" host)))