src/code/target-pathname.lisp

   1 ;;;; machine/filesystem-independent pathname functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 #!-sb-fluid (declaim (freeze-type logical-pathname logical-host))
  15 \f
  16 ;;;; UNIX-HOST stuff
  17
  18 (def!struct (unix-host
  19              (:make-load-form-fun make-unix-host-load-form)
  20              (:include host
  21                        (parse #'parse-unix-namestring)
  22                        (unparse #'unparse-unix-namestring)
  23                        (unparse-host #'unparse-unix-host)
  24                        (unparse-directory #'unparse-unix-directory)
  25                        (unparse-file #'unparse-unix-file)
  26                        (unparse-enough #'unparse-unix-enough)
  27                        (customary-case :lower))))
  28
  29 (defvar *unix-host* (make-unix-host))
  30
  31 (defun make-unix-host-load-form (host)
  32   (declare (ignore host))
  33   '*unix-host*)
  34
  35 ;;; Return a value suitable, e.g., for preinitializing
  36 ;;; *DEFAULT-PATHNAME-DEFAULTS* before *DEFAULT-PATHNAME-DEFAULTS* is
  37 ;;; initialized (at which time we can't safely call e.g. #'PATHNAME).
  38 (defun make-trivial-default-pathname ()
  39   (%make-pathname *unix-host* nil nil nil nil :newest))
  40 \f
  41 ;;; pathname methods
  42
  43 (def!method print-object ((pathname pathname) stream)
  44   (let ((namestring (handler-case (namestring pathname)
  45                       (error nil))))
  46     (if namestring
  47         (format stream "#P~S" namestring)
  48         (print-unreadable-object (pathname stream :type t)
  49           (format stream
  50                   "~@<(with no namestring) ~_:HOST ~S ~_:DEVICE ~S ~_:DIRECTORY ~S ~
  51                   ~_:NAME ~S ~_:TYPE ~S ~_:VERSION ~S~:>"
  52                   (%pathname-host pathname)
  53                   (%pathname-device pathname)
  54                   (%pathname-directory pathname)
  55                   (%pathname-name pathname)
  56                   (%pathname-type pathname)
  57                   (%pathname-version pathname))))))
  58
  59 (def!method make-load-form ((pathname pathname) &optional environment)
  60   (make-load-form-saving-slots pathname :environment environment))
  61
  62 ;;; The potential conflict with search lists requires isolating the
  63 ;;; printed representation to use the i/o macro #.(logical-pathname
  64 ;;; <path-designator>).
  65 ;;;
  66 ;;; FIXME: We don't use search lists any more, so that comment is
  67 ;;; stale, right?
  68 (def!method print-object ((pathname logical-pathname) stream)
  69   (let ((namestring (handler-case (namestring pathname)
  70                       (error nil))))
  71     (if namestring
  72         (format stream "#.(CL:LOGICAL-PATHNAME ~S)" namestring)
  73         (print-unreadable-object (pathname stream :type t)
  74           (format
  75            stream
  76            "~_:HOST ~S ~_:DIRECTORY ~S ~_:FILE ~S ~_:NAME ~S ~_:VERSION ~S"
  77            (%pathname-host pathname)
  78            (%pathname-directory pathname)
  79            (%pathname-name pathname)
  80            (%pathname-type pathname)
  81            (%pathname-version pathname))))))
  82 \f
  83 ;;; A pathname is logical if the host component is a logical host.
  84 ;;; This constructor is used to make an instance of the correct type
  85 ;;; from parsed arguments.
  86 (defun %make-maybe-logical-pathname (host device directory name type version)
  87   ;; We canonicalize logical pathname components to uppercase. ANSI
  88   ;; doesn't strictly require this, leaving it up to the implementor;
  89   ;; but the arguments given in the X3J13 cleanup issue
  90   ;; PATHNAME-LOGICAL:ADD seem compelling: we should canonicalize the
  91   ;; case, and uppercase is the ordinary way to do that.
  92   (flet ((upcase-maybe (x) (typecase x (string (logical-word-or-lose x)) (t x))))
  93     (if (typep host 'logical-host)
  94         (%make-logical-pathname host
  95                                 :unspecific
  96                                 (mapcar #'upcase-maybe directory)
  97                                 (upcase-maybe name)
  98                                 (upcase-maybe type)
  99                                 version)
 100         (%make-pathname host device directory name type version))))
 101
 102 ;;; Hash table searching maps a logical pathname's host to its
 103 ;;; physical pathname translation.
 104 (defvar *logical-hosts* (make-hash-table :test 'equal))
 105 \f
 106 ;;;; patterns
 107
 108 (def!method make-load-form ((pattern pattern) &optional environment)
 109   (make-load-form-saving-slots pattern :environment environment))
 110
 111 (def!method print-object ((pattern pattern) stream)
 112   (print-unreadable-object (pattern stream :type t)
 113     (if *print-pretty*
 114         (let ((*print-escape* t))
 115           (pprint-fill stream (pattern-pieces pattern) nil))
 116         (prin1 (pattern-pieces pattern) stream))))
 117
 118 (defun pattern= (pattern1 pattern2)
 119   (declare (type pattern pattern1 pattern2))
 120   (let ((pieces1 (pattern-pieces pattern1))
 121         (pieces2 (pattern-pieces pattern2)))
 122     (and (= (length pieces1) (length pieces2))
 123          (every (lambda (piece1 piece2)
 124                   (typecase piece1
 125                     (simple-string
 126                      (and (simple-string-p piece2)
 127                           (string= piece1 piece2)))
 128                     (cons
 129                      (and (consp piece2)
 130                           (eq (car piece1) (car piece2))
 131                           (string= (cdr piece1) (cdr piece2))))
 132                     (t
 133                      (eq piece1 piece2))))
 134                 pieces1
 135                 pieces2))))
 136
 137 ;;; If the string matches the pattern returns the multiple values T
 138 ;;; and a list of the matched strings.
 139 (defun pattern-matches (pattern string)
 140   (declare (type pattern pattern)
 141            (type simple-string string))
 142   (let ((len (length string)))
 143     (labels ((maybe-prepend (subs cur-sub chars)
 144                (if cur-sub
 145                    (let* ((len (length chars))
 146                           (new (make-string len))
 147                           (index len))
 148                      (dolist (char chars)
 149                        (setf (schar new (decf index)) char))
 150                      (cons new subs))
 151                    subs))
 152              (matches (pieces start subs cur-sub chars)
 153                (if (null pieces)
 154                    (if (= start len)
 155                        (values t (maybe-prepend subs cur-sub chars))
 156                        (values nil nil))
 157                    (let ((piece (car pieces)))
 158                      (etypecase piece
 159                        (simple-string
 160                         (let ((end (+ start (length piece))))
 161                           (and (<= end len)
 162                                (string= piece string
 163                                         :start2 start :end2 end)
 164                                (matches (cdr pieces) end
 165                                         (maybe-prepend subs cur-sub chars)
 166                                         nil nil))))
 167                        (list
 168                         (ecase (car piece)
 169                           (:character-set
 170                            (and (< start len)
 171                                 (let ((char (schar string start)))
 172                                   (if (find char (cdr piece) :test #'char=)
 173                                       (matches (cdr pieces) (1+ start) subs t
 174                                                (cons char chars))))))))
 175                        ((member :single-char-wild)
 176                         (and (< start len)
 177                              (matches (cdr pieces) (1+ start) subs t
 178                                       (cons (schar string start) chars))))
 179                        ((member :multi-char-wild)
 180                         (multiple-value-bind (won new-subs)
 181                             (matches (cdr pieces) start subs t chars)
 182                           (if won
 183                               (values t new-subs)
 184                               (and (< start len)
 185                                    (matches pieces (1+ start) subs t
 186                                             (cons (schar string start)
 187                                                   chars)))))))))))
 188       (multiple-value-bind (won subs)
 189           (matches (pattern-pieces pattern) 0 nil nil nil)
 190         (values won (reverse subs))))))
 191
 192 ;;; PATHNAME-MATCH-P for directory components
 193 (defun directory-components-match (thing wild)
 194   (or (eq thing wild)
 195       (eq wild :wild)
 196       ;; If THING has a null directory, assume that it matches
 197       ;; (:ABSOLUTE :WILD-INFERIORS) or (:RELATIVE :WILD-INFERIORS).
 198       (and (consp wild)
 199            (null thing)
 200            (member (first wild) '(:absolute :relative))
 201            (eq (second wild) :wild-inferiors))
 202       (and (consp wild)
 203            (let ((wild1 (first wild)))
 204              (if (eq wild1 :wild-inferiors)
 205                  (let ((wild-subdirs (rest wild)))
 206                    (or (null wild-subdirs)
 207                        (loop
 208                          (when (directory-components-match thing wild-subdirs)
 209                            (return t))
 210                          (pop thing)
 211                          (unless thing (return nil)))))
 212                  (and (consp thing)
 213                       (components-match (first thing) wild1)
 214                       (directory-components-match (rest thing)
 215                                                   (rest wild))))))))
 216
 217 ;;; Return true if pathname component THING is matched by WILD. (not
 218 ;;; commutative)
 219 (defun components-match (thing wild)
 220   (declare (type (or pattern symbol simple-string integer) thing wild))
 221   (or (eq thing wild)
 222       (eq wild :wild)
 223       (typecase thing
 224         (simple-base-string
 225          ;; String is matched by itself, a matching pattern or :WILD.
 226          (typecase wild
 227            (pattern
 228             (values (pattern-matches wild thing)))
 229            (simple-base-string
 230             (string= thing wild))))
 231         (pattern
 232          ;; A pattern is only matched by an identical pattern.
 233          (and (pattern-p wild) (pattern= thing wild)))
 234         (integer
 235          ;; An integer (version number) is matched by :WILD or the
 236          ;; same integer. This branch will actually always be NIL as
 237          ;; long as the version is a fixnum.
 238          (eql thing wild)))))
 239
 240 ;;; a predicate for comparing two pathname slot component sub-entries
 241 (defun compare-component (this that)
 242   (or (eql this that)
 243       (typecase this
 244         (simple-string
 245          (and (simple-string-p that)
 246               (string= this that)))
 247         (pattern
 248          (and (pattern-p that)
 249               (pattern= this that)))
 250         (cons
 251          (and (consp that)
 252               (compare-component (car this) (car that))
 253               (compare-component (cdr this) (cdr that)))))))
 254 \f
 255 ;;;; pathname functions
 256
 257 (defun pathname= (pathname1 pathname2)
 258   (declare (type pathname pathname1)
 259            (type pathname pathname2))
 260   (and (eq (%pathname-host pathname1)
 261            (%pathname-host pathname2))
 262        (compare-component (%pathname-device pathname1)
 263                           (%pathname-device pathname2))
 264        (compare-component (%pathname-directory pathname1)
 265                           (%pathname-directory pathname2))
 266        (compare-component (%pathname-name pathname1)
 267                           (%pathname-name pathname2))
 268        (compare-component (%pathname-type pathname1)
 269                           (%pathname-type pathname2))
 270        (compare-component (%pathname-version pathname1)
 271                           (%pathname-version pathname2))))
 272
 273 ;;; Convert PATHNAME-DESIGNATOR (a pathname, or string, or
 274 ;;; stream), into a pathname in pathname.
 275 ;;;
 276 ;;; FIXME: was rewritten, should be tested (or rewritten again, this
 277 ;;; time using ONCE-ONLY, *then* tested)
 278 ;;; FIXME: become SB!XC:DEFMACRO inside EVAL-WHEN (COMPILE EVAL)?
 279 (defmacro with-pathname ((pathname pathname-designator) &body body)
 280   (let ((pd0 (gensym)))
 281     `(let* ((,pd0 ,pathname-designator)
 282             (,pathname (etypecase ,pd0
 283                          (pathname ,pd0)
 284                          (string (parse-namestring ,pd0))
 285                          (stream (file-name ,pd0)))))
 286        ,@body)))
 287
 288 ;;; Convert the var, a host or string name for a host, into a
 289 ;;; LOGICAL-HOST structure or nil if not defined.
 290 ;;;
 291 ;;; pw notes 1/12/97 this potentially useful macro is not used anywhere
 292 ;;; and 'find-host' is not defined. 'find-logical-host' seems to be needed.
 293 #|
 294 (defmacro with-host ((var expr) &body body)
 295   `(let ((,var (let ((,var ,expr))
 296                  (typecase ,var
 297                    (logical-host ,var)
 298                    (string (find-logical-host ,var nil))
 299                    (t nil)))))
 300      ,@body))
 301 |#
 302
 303 (defun pathname (thing)
 304   #!+sb-doc
 305   "Convert thing (a pathname, string or stream) into a pathname."
 306   (declare (type pathname-designator thing))
 307   (with-pathname (pathname thing)
 308     pathname))
 309
 310 ;;; Change the case of thing if DIDDLE-P.
 311 (defun maybe-diddle-case (thing diddle-p)
 312   (if (and diddle-p (not (or (symbolp thing) (integerp thing))))
 313       (labels ((check-for (pred in)
 314                  (typecase in
 315                    (pattern
 316                     (dolist (piece (pattern-pieces in))
 317                       (when (typecase piece
 318                               (simple-string
 319                                (check-for pred piece))
 320                               (cons
 321                                (case (car in)
 322                                  (:character-set
 323                                   (check-for pred (cdr in))))))
 324                         (return t))))
 325                    (list
 326                     (dolist (x in)
 327                       (when (check-for pred x)
 328                         (return t))))
 329                    (simple-base-string
 330                     (dotimes (i (length in))
 331                       (when (funcall pred (schar in i))
 332                         (return t))))
 333                    (t nil)))
 334                (diddle-with (fun thing)
 335                  (typecase thing
 336                    (pattern
 337                     (make-pattern
 338                      (mapcar (lambda (piece)
 339                                (typecase piece
 340                                  (simple-base-string
 341                                   (funcall fun piece))
 342                                  (cons
 343                                   (case (car piece)
 344                                     (:character-set
 345                                      (cons :character-set
 346                                            (funcall fun (cdr piece))))
 347                                     (t
 348                                      piece)))
 349                                  (t
 350                                   piece)))
 351                              (pattern-pieces thing))))
 352                    (list
 353                     (mapcar fun thing))
 354                    (simple-base-string
 355                     (funcall fun thing))
 356                    (t
 357                     thing))))
 358         (let ((any-uppers (check-for #'upper-case-p thing))
 359               (any-lowers (check-for #'lower-case-p thing)))
 360           (cond ((and any-uppers any-lowers)
 361                  ;; mixed case, stays the same
 362                  thing)
 363                 (any-uppers
 364                  ;; all uppercase, becomes all lower case
 365                  (diddle-with (lambda (x) (if (stringp x)
 366                                               (string-downcase x)
 367                                               x)) thing))
 368                 (any-lowers
 369                  ;; all lowercase, becomes all upper case
 370                  (diddle-with #'(lambda (x) (if (stringp x)
 371                                                 (string-upcase x)
 372                                                 x)) thing))
 373                 (t
 374                  ;; no letters?  I guess just leave it.
 375                  thing))))
 376       thing))
 377
 378 (defun merge-directories (dir1 dir2 diddle-case)
 379   (if (or (eq (car dir1) :absolute)
 380           (null dir2))
 381       dir1
 382       (let ((results nil))
 383         (flet ((add (dir)
 384                  (if (and (eq dir :back)
 385                           results
 386                           (not (eq (car results) :back)))
 387                      (pop results)
 388                      (push dir results))))
 389           (dolist (dir (maybe-diddle-case dir2 diddle-case))
 390             (add dir))
 391           (dolist (dir (cdr dir1))
 392             (add dir)))
 393         (reverse results))))
 394
 395 (defun merge-pathnames (pathname
 396                         &optional
 397                         (defaults *default-pathname-defaults*)
 398                         (default-version :newest))
 399   #!+sb-doc
 400   "Construct a filled in pathname by completing the unspecified components
 401    from the defaults."
 402   (declare (type pathname-designator pathname)
 403            (type pathname-designator defaults)
 404            (values pathname))
 405   (with-pathname (defaults defaults)
 406     (let ((pathname (let ((*default-pathname-defaults* defaults))
 407                       (pathname pathname))))
 408       (let* ((default-host (%pathname-host defaults))
 409              (pathname-host (%pathname-host pathname))
 410              (diddle-case
 411               (and default-host pathname-host
 412                    (not (eq (host-customary-case default-host)
 413                             (host-customary-case pathname-host))))))
 414         (%make-maybe-logical-pathname
 415          (or pathname-host default-host)
 416          (or (%pathname-device pathname)
 417              (maybe-diddle-case (%pathname-device defaults)
 418                                 diddle-case))
 419          (merge-directories (%pathname-directory pathname)
 420                             (%pathname-directory defaults)
 421                             diddle-case)
 422          (or (%pathname-name pathname)
 423              (maybe-diddle-case (%pathname-name defaults)
 424                                 diddle-case))
 425          (or (%pathname-type pathname)
 426              (maybe-diddle-case (%pathname-type defaults)
 427                                 diddle-case))
 428          (or (%pathname-version pathname)
 429              default-version))))))
 430
 431 (defun import-directory (directory diddle-case)
 432   (etypecase directory
 433     (null nil)
 434     ((member :wild) '(:absolute :wild-inferiors))
 435     ((member :unspecific) '(:relative))
 436     (list
 437      (collect ((results))
 438        (results (pop directory))
 439        (dolist (piece directory)
 440          (cond ((member piece '(:wild :wild-inferiors :up :back))
 441                 (results piece))
 442                ((or (simple-string-p piece) (pattern-p piece))
 443                 (results (maybe-diddle-case piece diddle-case)))
 444                ((stringp piece)
 445                 (results (maybe-diddle-case (coerce piece 'simple-string)
 446                                             diddle-case)))
 447                (t
 448                 (error "~S is not allowed as a directory component." piece))))
 449        (results)))
 450     (simple-string
 451      `(:absolute
 452        ,(maybe-diddle-case directory diddle-case)))
 453     (string
 454      `(:absolute
 455        ,(maybe-diddle-case (coerce directory 'simple-string)
 456                            diddle-case)))))
 457
 458 (defun make-pathname (&key host
 459                            (device nil devp)
 460                            (directory nil dirp)
 461                            (name nil namep)
 462                            (type nil typep)
 463                            (version nil versionp)
 464                            defaults
 465                            (case :local))
 466   #!+sb-doc
 467   "Makes a new pathname from the component arguments. Note that host is
 468 a host-structure or string."
 469   (declare (type (or string host pathname-component-tokens) host)
 470            (type (or string pathname-component-tokens) device)
 471            (type (or list string pattern pathname-component-tokens) directory)
 472            (type (or string pattern pathname-component-tokens) name type)
 473            (type (or integer pathname-component-tokens (member :newest))
 474                  version)
 475            (type (or pathname-designator null) defaults)
 476            (type (member :common :local) case))
 477   (let* ((defaults (when defaults
 478                      (with-pathname (defaults defaults) defaults)))
 479          (default-host (if defaults
 480                            (%pathname-host defaults)
 481                            (pathname-host *default-pathname-defaults*)))
 482          ;; toy@rtp.ericsson.se: CLHS says make-pathname can take a
 483          ;; string (as a logical-host) for the host part. We map that
 484          ;; string into the corresponding logical host structure.
 485          ;;
 486          ;; pw@snoopy.mv.com:
 487          ;; HyperSpec says for the arg to MAKE-PATHNAME;
 488          ;; "host---a valid physical pathname host. ..."
 489          ;; where it probably means -- a valid pathname host.
 490          ;; "valid pathname host n. a valid physical pathname host or
 491          ;; a valid logical pathname host."
 492          ;; and defines
 493          ;; "valid physical pathname host n. any of a string,
 494          ;; a list of strings, or the symbol :unspecific,
 495          ;; that is recognized by the implementation as the name of a host."
 496          ;; "valid logical pathname host n. a string that has been defined
 497          ;; as the name of a logical host. ..."
 498          ;; HS is silent on what happens if the :HOST arg is NOT one of these.
 499          ;; It seems an error message is appropriate.
 500          (host (typecase host
 501                  (host host)            ; A valid host, use it.
 502                  (string (find-logical-host host t)) ; logical-host or lose.
 503                  (t default-host)))     ; unix-host
 504          (diddle-args (and (eq (host-customary-case host) :lower)
 505                            (eq case :common)))
 506          (diddle-defaults
 507           (not (eq (host-customary-case host)
 508                    (host-customary-case default-host))))
 509          (dev (if devp device (if defaults (%pathname-device defaults))))
 510          (dir (import-directory directory diddle-args))
 511          (ver (cond
 512                (versionp version)
 513                (defaults (%pathname-version defaults))
 514                (t nil))))
 515     (when (and defaults (not dirp))
 516       (setf dir
 517             (merge-directories dir
 518                                (%pathname-directory defaults)
 519                                diddle-defaults)))
 520
 521     (macrolet ((pick (var varp field)
 522                  `(cond ((or (simple-string-p ,var)
 523                              (pattern-p ,var))
 524                          (maybe-diddle-case ,var diddle-args))
 525                         ((stringp ,var)
 526                          (maybe-diddle-case (coerce ,var 'simple-string)
 527                                             diddle-args))
 528                         (,varp
 529                          (maybe-diddle-case ,var diddle-args))
 530                         (defaults
 531                          (maybe-diddle-case (,field defaults)
 532                                             diddle-defaults))
 533                         (t
 534                          nil))))
 535       (%make-maybe-logical-pathname host
 536                                     dev ; forced to :UNSPECIFIC when logical
 537                                     dir
 538                                     (pick name namep %pathname-name)
 539                                     (pick type typep %pathname-type)
 540                                     ver))))
 541
 542 (defun pathname-host (pathname &key (case :local))
 543   #!+sb-doc
 544   "Return PATHNAME's host."
 545   (declare (type pathname-designator pathname)
 546            (type (member :local :common) case)
 547            (values host)
 548            (ignore case))
 549   (with-pathname (pathname pathname)
 550     (%pathname-host pathname)))
 551
 552 (defun pathname-device (pathname &key (case :local))
 553   #!+sb-doc
 554   "Return PATHNAME's device."
 555   (declare (type pathname-designator pathname)
 556            (type (member :local :common) case))
 557   (with-pathname (pathname pathname)
 558     (maybe-diddle-case (%pathname-device pathname)
 559                        (and (eq case :common)
 560                             (eq (host-customary-case
 561                                  (%pathname-host pathname))
 562                                 :lower)))))
 563
 564 (defun pathname-directory (pathname &key (case :local))
 565   #!+sb-doc
 566   "Return PATHNAME's directory."
 567   (declare (type pathname-designator pathname)
 568            (type (member :local :common) case))
 569   (with-pathname (pathname pathname)
 570     (maybe-diddle-case (%pathname-directory pathname)
 571                        (and (eq case :common)
 572                             (eq (host-customary-case
 573                                  (%pathname-host pathname))
 574                                 :lower)))))
 575 (defun pathname-name (pathname &key (case :local))
 576   #!+sb-doc
 577   "Return PATHNAME's name."
 578   (declare (type pathname-designator pathname)
 579            (type (member :local :common) case))
 580   (with-pathname (pathname pathname)
 581     (maybe-diddle-case (%pathname-name pathname)
 582                        (and (eq case :common)
 583                             (eq (host-customary-case
 584                                  (%pathname-host pathname))
 585                                 :lower)))))
 586
 587 (defun pathname-type (pathname &key (case :local))
 588   #!+sb-doc
 589   "Return PATHNAME's type."
 590   (declare (type pathname-designator pathname)
 591            (type (member :local :common) case))
 592   (with-pathname (pathname pathname)
 593     (maybe-diddle-case (%pathname-type pathname)
 594                        (and (eq case :common)
 595                             (eq (host-customary-case
 596                                  (%pathname-host pathname))
 597                                 :lower)))))
 598
 599 (defun pathname-version (pathname)
 600   #!+sb-doc
 601   "Return PATHNAME's version."
 602   (declare (type pathname-designator pathname))
 603   (with-pathname (pathname pathname)
 604     (%pathname-version pathname)))
 605 \f
 606 ;;;; namestrings
 607
 608 ;;; Handle the case where PARSE-NAMESTRING is actually parsing a
 609 ;;; namestring. We pick off the :JUNK-ALLOWED case then find a host to
 610 ;;; use for parsing, call the parser, then check whether the host matches.
 611 (defun %parse-namestring (namestr host defaults start end junk-allowed)
 612   (declare (type (or host null) host)
 613            (type string namestr)
 614            (type index start)
 615            (type (or index null) end))
 616   (if junk-allowed
 617       (handler-case
 618           (%parse-namestring namestr host defaults start end nil)
 619         (namestring-parse-error (condition)
 620           (values nil (namestring-parse-error-offset condition))))
 621       (let* ((end (or end (length namestr)))
 622              (parse-host (or host
 623                              (extract-logical-host-prefix namestr start end)
 624                              (pathname-host defaults))))
 625         (unless parse-host
 626           (error "When no HOST argument is supplied, the DEFAULTS argument ~
 627                   must have a non-null PATHNAME-HOST."))
 628
 629         (multiple-value-bind (new-host device directory file type version)
 630             (funcall (host-parse parse-host) namestr start end)
 631           (when (and host new-host (not (eq new-host host)))
 632             (error 'simple-type-error
 633                    :datum new-host
 634                    ;; Note: ANSI requires that this be a TYPE-ERROR,
 635                    ;; but there seems to be no completely correct
 636                    ;; value to use for TYPE-ERROR-EXPECTED-TYPE.
 637                    ;; Instead, we return a sort of "type error allowed
 638                    ;; type", trying to say "it would be OK if you
 639                    ;; passed NIL as the host value" but not mentioning
 640                    ;; that a matching string would be OK too.
 641                    :expected-type 'null
 642                    :format-control
 643                    "The host in the namestring, ~S,~@
 644                     does not match the explicit HOST argument, ~S."
 645                    :format-arguments (list new-host host)))
 646           (let ((pn-host (or new-host parse-host)))
 647             (values (%make-maybe-logical-pathname
 648                      pn-host device directory file type version)
 649                     end))))))
 650
 651 ;;; If NAMESTR begins with a colon-terminated, defined, logical host,
 652 ;;; then return that host, otherwise return NIL.
 653 (defun extract-logical-host-prefix (namestr start end)
 654   (declare (type simple-base-string namestr)
 655            (type index start end)
 656            (values (or logical-host null)))
 657   (let ((colon-pos (position #\: namestr :start start :end end)))
 658     (if colon-pos
 659         (values (gethash (nstring-upcase (subseq namestr start colon-pos))
 660                          *logical-hosts*))
 661         nil)))
 662
 663 (defun parse-namestring (thing
 664                          &optional
 665                          host
 666                          (defaults *default-pathname-defaults*)
 667                          &key (start 0) end junk-allowed)
 668   (declare (type pathname-designator thing)
 669            (type (or list host string (member :unspecific)) host)
 670            (type pathname defaults)
 671            (type index start)
 672            (type (or index null) end)
 673            (type (or t null) junk-allowed)
 674            (values (or null pathname) (or null index)))
 675   ;; Generally, redundant specification of information in software,
 676   ;; whether in code or in comments, is bad. However, the ANSI spec
 677   ;; for this is messy enough that it's hard to hold in short-term
 678   ;; memory, so I've recorded these redundant notes on the
 679   ;; implications of the ANSI spec.
 680   ;;
 681   ;; According to the ANSI spec, HOST can be a valid pathname host, or
 682   ;; a logical host, or NIL.
 683   ;;
 684   ;; A valid pathname host can be a valid physical pathname host or a
 685   ;; valid logical pathname host.
 686   ;;
 687   ;; A valid physical pathname host is "any of a string, a list of
 688   ;; strings, or the symbol :UNSPECIFIC, that is recognized by the
 689   ;; implementation as the name of a host". In SBCL as of 0.6.9.8,
 690   ;; that means :UNSPECIFIC: though someday we might want to
 691   ;; generalize it to allow strings like "RTFM.MIT.EDU" or lists like
 692   ;; '("RTFM" "MIT" "EDU"), that's not supported now.
 693   ;;
 694   ;; A valid logical pathname host is a string which has been defined as
 695   ;; the name of a logical host, as with LOAD-LOGICAL-PATHNAME-TRANSLATIONS.
 696   ;;
 697   ;; A logical host is an object of implementation-dependent nature. In
 698   ;; SBCL, it's a member of the HOST class (a subclass of STRUCTURE-OBJECT).
 699   (let ((found-host (etypecase host
 700                       (string
 701                        ;; In general ANSI-compliant Common Lisps, a
 702                        ;; string might also be a physical pathname host,
 703                        ;; but ANSI leaves this up to the implementor,
 704                        ;; and in SBCL we don't do it, so it must be a
 705                        ;; logical host.
 706                        (find-logical-host host))
 707                       ((or null (member :unspecific))
 708                        ;; CLHS says that HOST=:UNSPECIFIC has
 709                        ;; implementation-defined behavior. We
 710                        ;; just turn it into NIL.
 711                        nil)
 712                       (list
 713                        ;; ANSI also allows LISTs to designate hosts,
 714                        ;; but leaves its interpretation
 715                        ;; implementation-defined. Our interpretation
 716                        ;; is that it's unsupported.:-|
 717                        (error "A LIST representing a pathname host is not ~
 718                               supported in this implementation:~%  ~S"
 719                               host))
 720                       (host
 721                        host))))
 722     (declare (type (or null host) found-host))
 723     (etypecase thing
 724       (simple-string
 725        (%parse-namestring thing found-host defaults start end junk-allowed))
 726       (string
 727        (%parse-namestring (coerce thing 'simple-string)
 728                           found-host defaults start end junk-allowed))
 729       (pathname
 730        (let ((defaulted-host (or found-host (%pathname-host defaults))))
 731          (declare (type host defaulted-host))
 732          (unless (eq defaulted-host (%pathname-host thing))
 733            (error "The HOST argument doesn't match the pathname host:~%  ~
 734                   ~S and ~S."
 735                   defaulted-host (%pathname-host thing))))
 736        (values thing start))
 737       (stream
 738        (let ((name (file-name thing)))
 739          (unless name
 740            (error "can't figure out the file associated with stream:~%  ~S"
 741                   thing))
 742          (values name nil))))))
 743
 744 (defun namestring (pathname)
 745   #!+sb-doc
 746   "Construct the full (name)string form of the pathname."
 747   (declare (type pathname-designator pathname)
 748            (values (or null simple-base-string)))
 749   (with-pathname (pathname pathname)
 750     (when pathname
 751       (let ((host (%pathname-host pathname)))
 752         (unless host
 753           (error "can't determine the namestring for pathnames with no ~
 754                   host:~%  ~S" pathname))
 755         (funcall (host-unparse host) pathname)))))
 756
 757 (defun host-namestring (pathname)
 758   #!+sb-doc
 759   "Return a string representation of the name of the host in the pathname."
 760   (declare (type pathname-designator pathname)
 761            (values (or null simple-base-string)))
 762   (with-pathname (pathname pathname)
 763     (let ((host (%pathname-host pathname)))
 764       (if host
 765           (funcall (host-unparse-host host) pathname)
 766           (error
 767            "can't determine the namestring for pathnames with no host:~%  ~S"
 768            pathname)))))
 769
 770 (defun directory-namestring (pathname)
 771   #!+sb-doc
 772   "Return a string representation of the directories used in the pathname."
 773   (declare (type pathname-designator pathname)
 774            (values (or null simple-base-string)))
 775   (with-pathname (pathname pathname)
 776     (let ((host (%pathname-host pathname)))
 777       (if host
 778           (funcall (host-unparse-directory host) pathname)
 779           (error
 780            "can't determine the namestring for pathnames with no host:~%  ~S"
 781            pathname)))))
 782
 783 (defun file-namestring (pathname)
 784   #!+sb-doc
 785   "Return a string representation of the name used in the pathname."
 786   (declare (type pathname-designator pathname)
 787            (values (or null simple-base-string)))
 788   (with-pathname (pathname pathname)
 789     (let ((host (%pathname-host pathname)))
 790       (if host
 791           (funcall (host-unparse-file host) pathname)
 792           (error
 793            "can't determine the namestring for pathnames with no host:~%  ~S"
 794            pathname)))))
 795
 796 (defun enough-namestring (pathname
 797                           &optional
 798                           (defaults *default-pathname-defaults*))
 799   #!+sb-doc
 800   "Return an abbreviated pathname sufficent to identify the pathname relative
 801    to the defaults."
 802   (declare (type pathname-designator pathname))
 803   (with-pathname (pathname pathname)
 804     (let ((host (%pathname-host pathname)))
 805       (if host
 806           (with-pathname (defaults defaults)
 807             (funcall (host-unparse-enough host) pathname defaults))
 808           (error
 809            "can't determine the namestring for pathnames with no host:~%  ~S"
 810            pathname)))))
 811 \f
 812 ;;;; wild pathnames
 813
 814 (defun wild-pathname-p (pathname &optional field-key)
 815   #!+sb-doc
 816   "Predicate for determining whether pathname contains any wildcards."
 817   (declare (type pathname-designator pathname)
 818            (type (member nil :host :device :directory :name :type :version)
 819                  field-key))
 820   (with-pathname (pathname pathname)
 821     (flet ((frob (x)
 822              (or (pattern-p x) (member x '(:wild :wild-inferiors)))))
 823       (ecase field-key
 824         ((nil)
 825          (or (wild-pathname-p pathname :host)
 826              (wild-pathname-p pathname :device)
 827              (wild-pathname-p pathname :directory)
 828              (wild-pathname-p pathname :name)
 829              (wild-pathname-p pathname :type)
 830              (wild-pathname-p pathname :version)))
 831         (:host (frob (%pathname-host pathname)))
 832         (:device (frob (%pathname-host pathname)))
 833         (:directory (some #'frob (%pathname-directory pathname)))
 834         (:name (frob (%pathname-name pathname)))
 835         (:type (frob (%pathname-type pathname)))
 836         (:version (frob (%pathname-version pathname)))))))
 837
 838 (defun pathname-match-p (in-pathname in-wildname)
 839   #!+sb-doc
 840   "Pathname matches the wildname template?"
 841   (declare (type pathname-designator in-pathname))
 842   (with-pathname (pathname in-pathname)
 843     (with-pathname (wildname in-wildname)
 844       (macrolet ((frob (field &optional (op 'components-match ))
 845                    `(or (null (,field wildname))
 846                         (,op (,field pathname) (,field wildname)))))
 847         (and (or (null (%pathname-host wildname))
 848                  (eq (%pathname-host wildname) (%pathname-host pathname)))
 849              (frob %pathname-device)
 850              (frob %pathname-directory directory-components-match)
 851              (frob %pathname-name)
 852              (frob %pathname-type)
 853              (frob %pathname-version))))))
 854
 855 ;;; Place the substitutions into the pattern and return the string or pattern
 856 ;;; that results. If DIDDLE-CASE is true, we diddle the result case as well,
 857 ;;; in case we are translating between hosts with difference conventional case.
 858 ;;; The second value is the tail of subs with all of the values that we used up
 859 ;;; stripped off. Note that PATTERN-MATCHES matches all consecutive wildcards
 860 ;;; as a single string, so we ignore subsequent contiguous wildcards.
 861 (defun substitute-into (pattern subs diddle-case)
 862   (declare (type pattern pattern)
 863            (type list subs)
 864            (values (or simple-base-string pattern) list))
 865   (let ((in-wildcard nil)
 866         (pieces nil)
 867         (strings nil))
 868     (dolist (piece (pattern-pieces pattern))
 869       (cond ((simple-string-p piece)
 870              (push piece strings)
 871              (setf in-wildcard nil))
 872             (in-wildcard)
 873             (t
 874              (setf in-wildcard t)
 875              (unless subs
 876                (error "not enough wildcards in FROM pattern to match ~
 877                        TO pattern:~%  ~S"
 878                       pattern))
 879              (let ((sub (pop subs)))
 880                (typecase sub
 881                  (pattern
 882                   (when strings
 883                     (push (apply #'concatenate 'simple-string
 884                                  (nreverse strings))
 885                           pieces))
 886                   (dolist (piece (pattern-pieces sub))
 887                     (push piece pieces)))
 888                  (simple-string
 889                   (push sub strings))
 890                  (t
 891                   (error "can't substitute this into the middle of a word:~
 892                           ~%  ~S"
 893                          sub)))))))
 894
 895     (when strings
 896       (push (apply #'concatenate 'simple-string (nreverse strings))
 897             pieces))
 898     (values
 899      (maybe-diddle-case
 900       (if (and pieces (simple-string-p (car pieces)) (null (cdr pieces)))
 901           (car pieces)
 902           (make-pattern (nreverse pieces)))
 903       diddle-case)
 904      subs)))
 905
 906 ;;; Called when we can't see how source and from matched.
 907 (defun didnt-match-error (source from)
 908   (error "Pathname components from SOURCE and FROM args to TRANSLATE-PATHNAME~@
 909           did not match:~%  ~S ~S"
 910          source from))
 911
 912 ;;; Do TRANSLATE-COMPONENT for all components except host and directory.
 913 (defun translate-component (source from to diddle-case)
 914   (typecase to
 915     (pattern
 916      (typecase from
 917        (pattern
 918         (typecase source
 919           (pattern
 920            (if (pattern= from source)
 921                source
 922                (didnt-match-error source from)))
 923           (simple-string
 924            (multiple-value-bind (won subs) (pattern-matches from source)
 925              (if won
 926                  (values (substitute-into to subs diddle-case))
 927                  (didnt-match-error source from))))
 928           (t
 929            (maybe-diddle-case source diddle-case))))
 930        ((member :wild)
 931         (values (substitute-into to (list source) diddle-case)))
 932        (t
 933         (if (components-match source from)
 934             (maybe-diddle-case source diddle-case)
 935             (didnt-match-error source from)))))
 936     ((member nil :wild)
 937      (maybe-diddle-case source diddle-case))
 938     (t
 939      (if (components-match source from)
 940          to
 941          (didnt-match-error source from)))))
 942
 943 ;;; Return a list of all the things that we want to substitute into the TO
 944 ;;; pattern (the things matched by from on source.)  When From contains
 945 ;;; :WILD-INFERIORS, the result contains a sublist of the matched source
 946 ;;; subdirectories.
 947 (defun compute-directory-substitutions (orig-source orig-from)
 948   (let ((source orig-source)
 949         (from orig-from))
 950     (collect ((subs))
 951       (loop
 952         (unless source
 953           (unless (every (lambda (x) (eq x :wild-inferiors)) from)
 954             (didnt-match-error orig-source orig-from))
 955           (subs ())
 956           (return))
 957         (unless from (didnt-match-error orig-source orig-from))
 958         (let ((from-part (pop from))
 959               (source-part (pop source)))
 960           (typecase from-part
 961             (pattern
 962              (typecase source-part
 963                (pattern
 964                 (if (pattern= from-part source-part)
 965                     (subs source-part)
 966                     (didnt-match-error orig-source orig-from)))
 967                (simple-string
 968                 (multiple-value-bind (won new-subs)
 969                     (pattern-matches from-part source-part)
 970                   (if won
 971                       (dolist (sub new-subs)
 972                         (subs sub))
 973                       (didnt-match-error orig-source orig-from))))
 974                (t
 975                 (didnt-match-error orig-source orig-from))))
 976             ((member :wild)
 977              (subs source-part))
 978             ((member :wild-inferiors)
 979              (let ((remaining-source (cons source-part source)))
 980                (collect ((res))
 981                  (loop
 982                    (when (directory-components-match remaining-source from)
 983                      (return))
 984                    (unless remaining-source
 985                      (didnt-match-error orig-source orig-from))
 986                    (res (pop remaining-source)))
 987                  (subs (res))
 988                  (setq source remaining-source))))
 989             (simple-string
 990              (unless (and (simple-string-p source-part)
 991                           (string= from-part source-part))
 992                (didnt-match-error orig-source orig-from)))
 993             (t
 994              (didnt-match-error orig-source orig-from)))))
 995       (subs))))
 996
 997 ;;; This is called by TRANSLATE-PATHNAME on the directory components
 998 ;;; of its argument pathnames to produce the result directory
 999 ;;; component. If this leaves the directory NIL, we return the source
1000 ;;; directory. The :RELATIVE or :ABSOLUTE is taken from the source
1001 ;;; directory, except if TO is :ABSOLUTE, in which case the result
1002 ;;; will be :ABSOLUTE.
1003 (defun translate-directories (source from to diddle-case)
1004   (if (not (and source to from))
1005       (or (and to (null source) (remove :wild-inferiors to))
1006           (mapcar (lambda (x) (maybe-diddle-case x diddle-case)) source))
1007       (collect ((res))
1008                ;; If TO is :ABSOLUTE, the result should still be :ABSOLUTE.
1009                (res (if (eq (first to) :absolute)
1010                  :absolute
1011                  (first source)))
1012         (let ((subs-left (compute-directory-substitutions (rest source)
1013                                                           (rest from))))
1014           (dolist (to-part (rest to))
1015             (typecase to-part
1016               ((member :wild)
1017                (aver subs-left)
1018                (let ((match (pop subs-left)))
1019                  (when (listp match)
1020                    (error ":WILD-INFERIORS is not paired in from and to ~
1021                            patterns:~%  ~S ~S" from to))
1022                  (res (maybe-diddle-case match diddle-case))))
1023               ((member :wild-inferiors)
1024                (aver subs-left)
1025                (let ((match (pop subs-left)))
1026                  (unless (listp match)
1027                    (error ":WILD-INFERIORS not paired in from and to ~
1028                            patterns:~%  ~S ~S" from to))
1029                  (dolist (x match)
1030                    (res (maybe-diddle-case x diddle-case)))))
1031               (pattern
1032                (multiple-value-bind
1033                    (new new-subs-left)
1034                    (substitute-into to-part subs-left diddle-case)
1035                  (setf subs-left new-subs-left)
1036                  (res new)))
1037               (t (res to-part)))))
1038         (res))))
1039
1040 (defun translate-pathname (source from-wildname to-wildname &key)
1041   #!+sb-doc
1042   "Use the source pathname to translate the from-wildname's wild and
1043    unspecified elements into a completed to-pathname based on the to-wildname."
1044   (declare (type pathname-designator source from-wildname to-wildname))
1045   (with-pathname (source source)
1046     (with-pathname (from from-wildname)
1047       (with-pathname (to to-wildname)
1048           (let* ((source-host (%pathname-host source))
1049                  (to-host (%pathname-host to))
1050                  (diddle-case
1051                   (and source-host to-host
1052                        (not (eq (host-customary-case source-host)
1053                                 (host-customary-case to-host))))))
1054             (macrolet ((frob (field &optional (op 'translate-component))
1055                          `(let ((result (,op (,field source)
1056                                              (,field from)
1057                                              (,field to)
1058                                              diddle-case)))
1059                             (if (eq result :error)
1060                                 (error "~S doesn't match ~S." source from)
1061                                 result))))
1062               (%make-maybe-logical-pathname
1063                (or to-host source-host)
1064                (frob %pathname-device)
1065                (frob %pathname-directory translate-directories)
1066                (frob %pathname-name)
1067                (frob %pathname-type)
1068                (frob %pathname-version))))))))
1069 \f
1070 ;;;;  logical pathname support. ANSI 92-102 specification.
1071 ;;;;
1072 ;;;;  As logical-pathname translations are loaded they are
1073 ;;;;  canonicalized as patterns to enable rapid efficient translation
1074 ;;;;  into physical pathnames.
1075
1076 ;;;; utilities
1077
1078 ;;; Canonicalize a logical pathname word by uppercasing it checking that it
1079 ;;; contains only legal characters.
1080 (defun logical-word-or-lose (word)
1081   (declare (string word))
1082   (let ((word (string-upcase word)))
1083     (dotimes (i (length word))
1084       (let ((ch (schar word i)))
1085         (unless (or (alpha-char-p ch) (digit-char-p ch) (char= ch #\-))
1086           (error 'namestring-parse-error
1087                  :complaint "logical namestring character which ~
1088                              is not alphanumeric or hyphen:~%  ~S"
1089                  :arguments (list ch)
1090                  :namestring word :offset i))))
1091     word))
1092
1093 ;;; Given a logical host or string, return a logical host. If ERROR-P
1094 ;;; is NIL, then return NIL when no such host exists.
1095 (defun find-logical-host (thing &optional (errorp t))
1096   (etypecase thing
1097     (string
1098      (let ((found (gethash (logical-word-or-lose thing)
1099                            *logical-hosts*)))
1100        (if (or found (not errorp))
1101            found
1102            ;; This is the error signalled from e.g.
1103            ;; LOGICAL-PATHNAME-TRANSLATIONS when host is not a defined
1104            ;; host, and ANSI specifies that that's a TYPE-ERROR.
1105            (error 'simple-type-error
1106                   :datum thing
1107                   ;; God only knows what ANSI expects us to use for
1108                   ;; the EXPECTED-TYPE here. Maybe this will be OK..
1109                   :expected-type
1110                   '(and string (satisfies logical-pathname-translations))
1111                   :format-control "logical host not yet defined: ~S"
1112                   :format-arguments (list thing)))))
1113     (logical-host thing)))
1114
1115 ;;; Given a logical host name or host, return a logical host, creating
1116 ;;; a new one if necessary.
1117 (defun intern-logical-host (thing)
1118   (declare (values logical-host))
1119   (or (find-logical-host thing nil)
1120       (let* ((name (logical-word-or-lose thing))
1121              (new (make-logical-host :name name)))
1122         (setf (gethash name *logical-hosts*) new)
1123         new)))
1124 \f
1125 ;;;; logical pathname parsing
1126
1127 ;;; Deal with multi-char wildcards in a logical pathname token.
1128 (defun maybe-make-logical-pattern (namestring chunks)
1129   (let ((chunk (caar chunks)))
1130     (collect ((pattern))
1131       (let ((last-pos 0)
1132             (len (length chunk)))
1133         (declare (fixnum last-pos))
1134         (loop
1135           (when (= last-pos len) (return))
1136           (let ((pos (or (position #\* chunk :start last-pos) len)))
1137             (if (= pos last-pos)
1138                 (when (pattern)
1139                   (error 'namestring-parse-error
1140                          :complaint "double asterisk inside of logical ~
1141                                      word: ~S"
1142                          :arguments (list chunk)
1143                          :namestring namestring
1144                          :offset (+ (cdar chunks) pos)))
1145                 (pattern (subseq chunk last-pos pos)))
1146             (if (= pos len)
1147                 (return)
1148                 (pattern :multi-char-wild))
1149             (setq last-pos (1+ pos)))))
1150         (aver (pattern))
1151         (if (cdr (pattern))
1152             (make-pattern (pattern))
1153             (let ((x (car (pattern))))
1154               (if (eq x :multi-char-wild)
1155                   :wild
1156                   x))))))
1157
1158 ;;; Return a list of conses where the CDR is the start position and
1159 ;;; the CAR is a string (token) or character (punctuation.)
1160 (defun logical-chunkify (namestr start end)
1161   (collect ((chunks))
1162     (do ((i start (1+ i))
1163          (prev 0))
1164         ((= i end)
1165          (when (> end prev)
1166             (chunks (cons (nstring-upcase (subseq namestr prev end)) prev))))
1167       (let ((ch (schar namestr i)))
1168         (unless (or (alpha-char-p ch) (digit-char-p ch)
1169                     (member ch '(#\- #\*)))
1170           (when (> i prev)
1171             (chunks (cons (nstring-upcase (subseq namestr prev i)) prev)))
1172           (setq prev (1+ i))
1173           (unless (member ch '(#\; #\: #\.))
1174             (error 'namestring-parse-error
1175                    :complaint "illegal character for logical pathname:~%  ~S"
1176                    :arguments (list ch)
1177                    :namestring namestr
1178                    :offset i))
1179           (chunks (cons ch i)))))
1180     (chunks)))
1181
1182 ;;; Break up a logical-namestring, always a string, into its
1183 ;;; constituent parts.
1184 (defun parse-logical-namestring (namestr start end)
1185   (declare (type simple-base-string namestr)
1186            (type index start end))
1187   (collect ((directory))
1188     (let ((host nil)
1189           (name nil)
1190           (type nil)
1191           (version nil))
1192       (labels ((expecting (what chunks)
1193                  (unless (and chunks (simple-string-p (caar chunks)))
1194                    (error 'namestring-parse-error
1195                           :complaint "expecting ~A, got ~:[nothing~;~S~]."
1196                           :arguments (list what (caar chunks) (caar chunks))
1197                           :namestring namestr
1198                           :offset (if chunks (cdar chunks) end)))
1199                  (caar chunks))
1200                (parse-host (chunks)
1201                  (case (caadr chunks)
1202                    (#\:
1203                     (setq host
1204                           (find-logical-host (expecting "a host name" chunks)))
1205                     (parse-relative (cddr chunks)))
1206                    (t
1207                     (parse-relative chunks))))
1208                (parse-relative (chunks)
1209                  (case (caar chunks)
1210                    (#\;
1211                     (directory :relative)
1212                     (parse-directory (cdr chunks)))
1213                    (t
1214                     (directory :absolute) ; Assumption! Maybe revoked later.
1215                     (parse-directory chunks))))
1216                (parse-directory (chunks)
1217                  (case (caadr chunks)
1218                    (#\;
1219                     (directory
1220                      (let ((res (expecting "a directory name" chunks)))
1221                        (cond ((string= res "..") :up)
1222                              ((string= res "**") :wild-inferiors)
1223                              (t
1224                               (maybe-make-logical-pattern namestr chunks)))))
1225                     (parse-directory (cddr chunks)))
1226                    (t
1227                     (parse-name chunks))))
1228                (parse-name (chunks)
1229                  (when chunks
1230                    (expecting "a file name" chunks)
1231                    (setq name (maybe-make-logical-pattern namestr chunks))
1232                    (expecting-dot (cdr chunks))))
1233                (expecting-dot (chunks)
1234                  (when chunks
1235                    (unless (eql (caar chunks) #\.)
1236                      (error 'namestring-parse-error
1237                             :complaint "expecting a dot, got ~S."
1238                             :arguments (list (caar chunks))
1239                             :namestring namestr
1240                             :offset (cdar chunks)))
1241                    (if type
1242                        (parse-version (cdr chunks))
1243                        (parse-type (cdr chunks)))))
1244                (parse-type (chunks)
1245                  (expecting "a file type" chunks)
1246                  (setq type (maybe-make-logical-pattern namestr chunks))
1247                  (expecting-dot (cdr chunks)))
1248                (parse-version (chunks)
1249                  (let ((str (expecting "a positive integer, * or NEWEST"
1250                                        chunks)))
1251                    (cond
1252                     ((string= str "*") (setq version :wild))
1253                     ((string= str "NEWEST") (setq version :newest))
1254                     (t
1255                      (multiple-value-bind (res pos)
1256                          (parse-integer str :junk-allowed t)
1257                        (unless (and res (plusp res))
1258                          (error 'namestring-parse-error
1259                                 :complaint "expected a positive integer, ~
1260                                             got ~S"
1261                                 :arguments (list str)
1262                                 :namestring namestr
1263                                 :offset (+ pos (cdar chunks))))
1264                        (setq version res)))))
1265                  (when (cdr chunks)
1266                    (error 'namestring-parse-error
1267                           :complaint "extra stuff after end of file name"
1268                           :namestring namestr
1269                           :offset (cdadr chunks)))))
1270         (parse-host (logical-chunkify namestr start end)))
1271       (values host :unspecific (directory) name type version))))
1272
1273 ;;; We can't initialize this yet because not all host methods are
1274 ;;; loaded yet.
1275 (defvar *logical-pathname-defaults*)
1276
1277 (defun logical-pathname (pathspec)
1278   #!+sb-doc
1279   "Converts the pathspec argument to a logical-pathname and returns it."
1280   (declare (type (or logical-pathname string stream) pathspec)
1281            (values logical-pathname))
1282   (if (typep pathspec 'logical-pathname)
1283       pathspec
1284       (let ((res (parse-namestring pathspec nil *logical-pathname-defaults*)))
1285         (when (eq (%pathname-host res)
1286                   (%pathname-host *logical-pathname-defaults*))
1287           (error "This logical namestring does not specify a host:~%  ~S"
1288                  pathspec))
1289         res)))
1290 \f
1291 ;;;; logical pathname unparsing
1292
1293 (defun unparse-logical-directory (pathname)
1294   (declare (type pathname pathname))
1295   (collect ((pieces))
1296     (let ((directory (%pathname-directory pathname)))
1297       (when directory
1298         (ecase (pop directory)
1299           (:absolute) ; nothing special
1300           (:relative (pieces ";")))
1301         (dolist (dir directory)
1302           (cond ((or (stringp dir) (pattern-p dir))
1303                  (pieces (unparse-logical-piece dir))
1304                  (pieces ";"))
1305                 ((eq dir :wild)
1306                  (pieces "*;"))
1307                 ((eq dir :wild-inferiors)
1308                  (pieces "**;"))
1309                 (t
1310                  (error "invalid directory component: ~S" dir))))))
1311     (apply #'concatenate 'simple-string (pieces))))
1312
1313 (defun unparse-logical-piece (thing)
1314   (etypecase thing
1315     (simple-string thing)
1316     (pattern
1317      (collect ((strings))
1318        (dolist (piece (pattern-pieces thing))
1319          (etypecase piece
1320            (simple-string (strings piece))
1321            (keyword
1322             (cond ((eq piece :wild-inferiors)
1323                    (strings "**"))
1324                   ((eq piece :multi-char-wild)
1325                    (strings "*"))
1326                   (t (error "invalid keyword: ~S" piece))))))
1327        (apply #'concatenate 'simple-string (strings))))))
1328
1329 ;;; Unparse a logical pathname string.
1330 (defun unparse-enough-namestring (pathname defaults)
1331   (let* ((path-directory (pathname-directory pathname))
1332          (def-directory (pathname-directory defaults))
1333          (enough-directory
1334            ;; Go down the directory lists to see what matches.  What's
1335            ;; left is what we want, more or less.
1336            (cond ((and (eq (first path-directory) (first def-directory))
1337                        (eq (first path-directory) :absolute))
1338                    ;; Both paths are :ABSOLUTE, so find where the
1339                    ;; common parts end and return what's left
1340                    (do* ((p (rest path-directory) (rest p))
1341                          (d (rest def-directory) (rest d)))
1342                         ((or (endp p) (endp d)
1343                              (not (equal (first p) (first d))))
1344                          `(:relative ,@p))))
1345                  (t
1346                    ;; At least one path is :RELATIVE, so just return the
1347                    ;; original path.  If the original path is :RELATIVE,
1348                    ;; then that's the right one.  If PATH-DIRECTORY is
1349                    ;; :ABSOLUTE, we want to return that except when
1350                    ;; DEF-DIRECTORY is :ABSOLUTE, as handled above. so return
1351                    ;; the original directory.
1352                    path-directory))))
1353     (make-pathname :host (pathname-host pathname)
1354                    :directory enough-directory
1355                    :name (pathname-name pathname)
1356                    :type (pathname-type pathname)
1357                    :version (pathname-version pathname))))
1358
1359 (defun unparse-logical-namestring (pathname)
1360   (declare (type logical-pathname pathname))
1361   (concatenate 'simple-string
1362                (logical-host-name (%pathname-host pathname)) ":"
1363                (unparse-logical-directory pathname)
1364                (unparse-unix-file pathname)))
1365 \f
1366 ;;;; logical pathname translations
1367
1368 ;;; Verify that the list of translations consists of lists and prepare
1369 ;;; canonical translations. (Parse pathnames and expand out wildcards
1370 ;;; into patterns.)
1371 (defun canonicalize-logical-pathname-translations (translation-list host)
1372   (declare (type list translation-list) (type host host)
1373            (values list))
1374   (mapcar (lambda (translation)
1375             (destructuring-bind (from to) translation
1376               (list (if (typep from 'logical-pathname)
1377                         from
1378                         (parse-namestring from host))
1379                     (pathname to))))
1380           translation-list))
1381
1382 (defun logical-pathname-translations (host)
1383   #!+sb-doc
1384   "Return the (logical) host object argument's list of translations."
1385   (declare (type (or string logical-host) host)
1386            (values list))
1387   (logical-host-translations (find-logical-host host)))
1388
1389 (defun (setf logical-pathname-translations) (translations host)
1390   #!+sb-doc
1391   "Set the translations list for the logical host argument."
1392   (declare (type (or string logical-host) host)
1393            (type list translations)
1394            (values list))
1395   (let ((host (intern-logical-host host)))
1396     (setf (logical-host-canon-transls host)
1397           (canonicalize-logical-pathname-translations translations host))
1398     (setf (logical-host-translations host) translations)))
1399
1400 ;;; KLUDGE: Ordinarily known functions aren't defined recursively, and
1401 ;;; it's common for compiler problems (e.g. missing/broken
1402 ;;; optimization transforms) to cause them to recurse inadvertently,
1403 ;;; so the compiler should warn about it. But the natural definition
1404 ;;; of TRANSLATE-LOGICAL-PATHNAME *is* recursive; and we don't want
1405 ;;; the warning, so we hide the definition of T-L-P in this
1406 ;;; differently named function so that the compiler won't warn about
1407 ;;; it. -- WHN 2001-09-16
1408 (defun %translate-logical-pathname (pathname)
1409   (declare (type pathname-designator pathname)
1410            (values (or null pathname)))
1411   (typecase pathname
1412     (logical-pathname
1413      (dolist (x (logical-host-canon-transls (%pathname-host pathname))
1414                 (error 'simple-file-error
1415                        :pathname pathname
1416                        :format-control "no translation for ~S"
1417                        :format-arguments (list pathname)))
1418        (destructuring-bind (from to) x
1419          (when (pathname-match-p pathname from)
1420            (return (translate-logical-pathname
1421                     (translate-pathname pathname from to)))))))
1422     (pathname pathname)
1423     (stream (translate-logical-pathname (pathname pathname)))
1424     (t (translate-logical-pathname (logical-pathname pathname)))))
1425
1426 (defun translate-logical-pathname (pathname &key)
1427   #!+sb-doc
1428   "Translate PATHNAME to a physical pathname, which is returned."
1429   (declare (type pathname-designator pathname)
1430            (values (or null pathname)))
1431   (%translate-logical-pathname pathname))
1432
1433 (defvar *logical-pathname-defaults*
1434   (%make-logical-pathname (make-logical-host :name "BOGUS")
1435                           :unspecific
1436                           nil
1437                           nil
1438                           nil
1439                           nil))
1440
1441 (defun load-logical-pathname-translations (host)
1442   #!+sb-doc
1443   (declare (type string host)
1444            (values (member t nil)))
1445   (if (find-logical-host host nil)
1446       ;; This host is already defined, all is well and good.
1447       t
1448       ;; ANSI: "The specific nature of the search is
1449       ;; implementation-defined." SBCL: doesn't search at all
1450       (error "logical host ~S not found" host)))