src/code/target-sxhash.lisp

   1 ;;;; hashing functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 ;;; the depthoid explored when calculating hash values
  15 ;;;
  16 ;;; "Depthoid" here is a sort of mixture of what Common Lisp ordinarily calls
  17 ;;; depth and what Common Lisp ordinarily calls length; it's incremented either
  18 ;;; when we descend into a compound object or when we step through elements of
  19 ;;; a compound object.
  20 (defconstant +max-hash-depthoid+ 4)
  21 \f
  22 ;;;; mixing hash values
  23
  24 ;;; a function for mixing hash values
  25 ;;;
  26 ;;; desiderata:
  27 ;;;   * Non-commutativity keeps us from hashing e.g. #(1 5) to the
  28 ;;;     same value as #(5 1), and ending up in real trouble in some
  29 ;;;     special cases like bit vectors the way that CMUCL 18b SXHASH
  30 ;;;     does. (Under CMUCL 18b, SXHASH of any bit vector is 1..)
  31 ;;;   * We'd like to scatter our hash values over the entire possible range
  32 ;;;     of values instead of hashing small or common key values (like
  33 ;;;     2 and NIL and #\a) to small FIXNUMs the way that the CMUCL 18b
  34 ;;;     SXHASH function does, again helping to avoid pathologies like
  35 ;;;     hashing all bit vectors to 1.
  36 ;;;   * We'd like this to be simple and fast, too.
  37 ;;;
  38 ;;; FIXME: Should this be INLINE?
  39 (declaim (ftype (function ((and fixnum unsigned-byte)
  40                            (and fixnum unsigned-byte))
  41                           (and fixnum unsigned-byte)) mix))
  42 (defun mix (x y)
  43   ;; FIXME: We wouldn't need the nasty (SAFETY 0) here if the compiler
  44   ;; were smarter about optimizing ASH. (Without the THE FIXNUM below,
  45   ;; and the (SAFETY 0) declaration here to get the compiler to trust
  46   ;; it, the sbcl-0.5.0m cross-compiler running under Debian
  47   ;; cmucl-2.4.17 turns the ASH into a full call, requiring the
  48   ;; UNSIGNED-BYTE 32 argument to be coerced to a bignum, requiring
  49   ;; consing, and thus generally obliterating performance.)
  50   (declare (optimize (speed 3) (safety 0)))
  51   (declare (type (and fixnum unsigned-byte) x y))
  52   ;; the ideas here:
  53   ;;   * Bits diffuse in both directions (shifted left by up to 2 places
  54   ;;     in the calculation of XY, and shifted right by up to 5 places
  55   ;;     by the ASH).
  56   ;;   * The #'+ and #'LOGXOR operations don't commute with each other,
  57   ;;     so different bit patterns are mixed together as they shift
  58   ;;     past each other.
  59   ;;   * The arbitrary constant in the #'LOGXOR expression is intended
  60   ;;     to help break up any weird anomalies we might otherwise get
  61   ;;     when hashing highly regular patterns.
  62   ;; (These are vaguely like the ideas used in many cryptographic
  63   ;; algorithms, but we're not pushing them hard enough here for them
  64   ;; to be cryptographically strong.)
  65   (let* ((xy (+ (* x 3) y)))
  66     (declare (type (unsigned-byte 32) xy))
  67     (the (and fixnum unsigned-byte)
  68          (logand most-positive-fixnum
  69                  (logxor 441516657
  70                          xy
  71                          (the fixnum (ash xy -5)))))))
  72 \f
  73 ;;;; hashing strings
  74 ;;;;
  75 ;;;; Note that this operation is used in compiler symbol table lookups, so we'd
  76 ;;;; like it to be fast.
  77
  78 #!-sb-fluid (declaim (inline %sxhash-substring))
  79 (defun %sxhash-substring (string &optional (count (length string)))
  80   ;; FIXME: As in MIX above, we wouldn't need (SAFETY 0) here if the
  81   ;; cross-compiler were smarter about ASH, but we need it for sbcl-0.5.0m.
  82   (declare (optimize (speed 3) (safety 0)))
  83   (declare (type string string))
  84   (declare (type index count))
  85   (let ((result 408967240))
  86     (declare (type fixnum result))
  87     (dotimes (i count)
  88       (declare (type index i))
  89       (mixf result
  90             (the fixnum
  91                  (ash (char-code (aref string i)) 5))))
  92     result))
  93 ;;; test:
  94 ;;;   (let ((ht (make-hash-table :test 'equal)))
  95 ;;;     (do-all-symbols (symbol)
  96 ;;;       (let* ((string (symbol-name symbol))
  97 ;;;           (hash (%sxhash-substring string)))
  98 ;;;      (if (gethash hash ht)
  99 ;;;          (unless (string= (gethash hash ht) string)
 100 ;;;            (format t "collision: ~S ~S~%" string (gethash hash ht)))
 101 ;;;          (setf (gethash hash ht) string))))
 102 ;;;     (format t "final count=~W~%" (hash-table-count ht)))
 103
 104 (defun %sxhash-simple-string (x)
 105   (declare (optimize speed))
 106   (declare (type simple-string x))
 107   (%sxhash-substring x))
 108
 109 (defun %sxhash-simple-substring (x count)
 110   (declare (optimize speed))
 111   (declare (type simple-string x))
 112   (declare (type index count))
 113   (%sxhash-substring x count))
 114 \f
 115 ;;;; the SXHASH function
 116
 117 (defun sxhash (x)
 118   ;; profiling SXHASH is hard, but we might as well try to make it go
 119   ;; fast, in case it is the bottleneck somwhere.  -- CSR, 2003-03-14
 120   (declare (optimize speed))
 121   (labels ((sxhash-number (x)
 122              (etypecase x
 123                (fixnum (sxhash x))      ; through DEFTRANSFORM
 124                (integer (sb!bignum:sxhash-bignum x))
 125                (single-float (sxhash x)) ; through DEFTRANSFORM
 126                (double-float (sxhash x)) ; through DEFTRANSFORM
 127                #!+long-float (long-float (error "stub: no LONG-FLOAT"))
 128                (ratio (let ((result 127810327))
 129                         (declare (type fixnum result))
 130                         (mixf result (sxhash-number (numerator x)))
 131                         (mixf result (sxhash-number (denominator x)))
 132                         result))
 133                (complex (let ((result 535698211))
 134                           (declare (type fixnum result))
 135                           (mixf result (sxhash-number (realpart x)))
 136                           (mixf result (sxhash-number (imagpart x)))
 137                           result))))
 138            (sxhash-recurse (x &optional (depthoid +max-hash-depthoid+))
 139              (declare (type index depthoid))
 140              (typecase x
 141                (cons
 142                 (if (plusp depthoid)
 143                     (mix (sxhash-recurse (car x) (1- depthoid))
 144                          (sxhash-recurse (cdr x) (1- depthoid)))
 145                     261835505))
 146                (instance
 147                 (if (typep x 'structure-object)
 148                     (logxor 422371266
 149                             (sxhash ; through DEFTRANSFORM
 150                              (classoid-name
 151                               (layout-classoid (%instance-layout x)))))
 152                     (sxhash-instance x)))
 153                (symbol (sxhash x)) ; through DEFTRANSFORM
 154                (array
 155                 (typecase x
 156                   (simple-string (sxhash x)) ; through DEFTRANSFORM
 157                   (string (%sxhash-substring x))
 158                   (simple-bit-vector (sxhash x)) ; through DEFTRANSFORM
 159                   (bit-vector
 160                    ;; FIXME: It must surely be possible to do better
 161                    ;; than this.  The problem is that a non-SIMPLE
 162                    ;; BIT-VECTOR could be displaced to another, with a
 163                    ;; non-zero offset -- so that significantly more
 164                    ;; work needs to be done using the %RAW-BITS
 165                    ;; approach.  This will probably do for now.
 166                    (sxhash-recurse (copy-seq x) depthoid))
 167                   (t (logxor 191020317 (sxhash (array-rank x))))))
 168                (character
 169                 (logxor 72185131
 170                         (sxhash (char-code x)))) ; through DEFTRANSFORM
 171                ;; general, inefficient case of NUMBER
 172                (number (sxhash-number x))
 173                (generic-function (sxhash-instance x))
 174                (t 42))))
 175     (sxhash-recurse x)))
 176 \f
 177 ;;;; the PSXHASH function
 178
 179 ;;;; FIXME: This code does a lot of unnecessary full calls. It could be made
 180 ;;;; more efficient (in both time and space) by rewriting it along the lines
 181 ;;;; of the SXHASH code above.
 182
 183 ;;; like SXHASH, but for EQUALP hashing instead of EQUAL hashing
 184 (defun psxhash (key &optional (depthoid +max-hash-depthoid+))
 185   (declare (optimize speed))
 186   (declare (type (integer 0 #.+max-hash-depthoid+) depthoid))
 187   ;; Note: You might think it would be cleaner to use the ordering given in the
 188   ;; table from Figure 5-13 in the EQUALP section of the ANSI specification
 189   ;; here. So did I, but that is a snare for the unwary! Nothing in the ANSI
 190   ;; spec says that HASH-TABLE can't be a STRUCTURE-OBJECT, and in fact our
 191   ;; HASH-TABLEs *are* STRUCTURE-OBJECTs, so we need to pick off the special
 192   ;; HASH-TABLE behavior before we fall through to the generic STRUCTURE-OBJECT
 193   ;; comparison behavior.
 194   (typecase key
 195     (array (array-psxhash key depthoid))
 196     (hash-table (hash-table-psxhash key))
 197     (structure-object (structure-object-psxhash key depthoid))
 198     (cons (list-psxhash key depthoid))
 199     (number (number-psxhash key))
 200     (character (sxhash (char-upcase key)))
 201     (t (sxhash key))))
 202
 203 (defun array-psxhash (key depthoid)
 204   (declare (optimize speed))
 205   (declare (type array key))
 206   (declare (type (integer 0 #.+max-hash-depthoid+) depthoid))
 207   (typecase key
 208     ;; VECTORs have to be treated specially because ANSI specifies
 209     ;; that we must respect fill pointers.
 210     (vector
 211      (macrolet ((frob ()
 212                   '(let ((result 572539))
 213                      (declare (type fixnum result))
 214                      (mixf result (length key))
 215                      (dotimes (i (min depthoid (length key)))
 216                        (declare (type fixnum i))
 217                        (mixf result
 218                              (psxhash (aref key i)
 219                                       (- depthoid 1 i))))
 220                      result)))
 221        ;; CMU can compile SIMPLE-ARRAY operations so much more efficiently
 222        ;; than the general case that it's probably worth picking off the
 223        ;; common special cases.
 224        (typecase key
 225          (simple-string
 226           ;;(format t "~&SIMPLE-STRING special case~%")
 227           (frob))
 228          (simple-vector
 229           ;;(format t "~&SIMPLE-VECTOR special case~%")
 230           (frob))
 231          (t (frob)))))
 232     ;; Any other array can be hashed by working with its underlying
 233     ;; one-dimensional physical representation.
 234     (t
 235      (let ((result 60828))
 236        (declare (type fixnum result))
 237        (dotimes (i (min depthoid (array-rank key)))
 238          (mixf result (array-dimension key i)))
 239        (dotimes (i (min depthoid (array-total-size key)))
 240          (mixf result
 241                (psxhash (row-major-aref key i)
 242                         (- depthoid 1 i))))
 243        result))))
 244
 245 (defun structure-object-psxhash (key depthoid)
 246   (declare (optimize speed))
 247   (declare (type structure-object key))
 248   (declare (type (integer 0 #.+max-hash-depthoid+) depthoid))
 249   (let* ((layout (%instance-layout key)) ; i.e. slot #0
 250          (length (layout-length layout))
 251          (classoid (layout-classoid layout))
 252          (name (classoid-name classoid))
 253          (result (mix (sxhash name) (the fixnum 79867))))
 254     (declare (type fixnum result))
 255     (dotimes (i (min depthoid (1- length)))
 256       (declare (type fixnum i))
 257       (let ((j (1+ i))) ; skipping slot #0, which is for LAYOUT
 258         (declare (type fixnum j))
 259         (mixf result
 260               (psxhash (%instance-ref key j)
 261                        (1- depthoid)))))
 262     result))
 263
 264 (defun list-psxhash (key depthoid)
 265   (declare (optimize speed))
 266   (declare (type list key))
 267   (declare (type (integer 0 #.+max-hash-depthoid+) depthoid))
 268   (cond ((null key)
 269          (the fixnum 480929))
 270         ((zerop depthoid)
 271          (the fixnum 779578))
 272         (t
 273          (mix (psxhash (car key) (1- depthoid))
 274               (psxhash (cdr key) (1- depthoid))))))
 275
 276 (defun hash-table-psxhash (key)
 277   (declare (optimize speed))
 278   (declare (type hash-table key))
 279   (let ((result 103924836))
 280     (declare (type fixnum result))
 281     (mixf result (hash-table-count key))
 282     (mixf result (sxhash (hash-table-test key)))
 283     result))
 284
 285 (defun number-psxhash (key)
 286   (declare (optimize speed))
 287   (declare (type number key))
 288   (flet ((sxhash-double-float (val)
 289            (declare (type double-float val))
 290            ;; FIXME: Check to make sure that the DEFTRANSFORM kicks in and the
 291            ;; resulting code works without consing. (In Debian cmucl 2.4.17,
 292            ;; it didn't.)
 293            (sxhash val)))
 294     (etypecase key
 295       (integer (sxhash key))
 296       (float (macrolet ((frob (type)
 297                           (let ((lo (coerce most-negative-fixnum type))
 298                                 (hi (coerce most-positive-fixnum type)))
 299                             `(cond (;; This clause allows FIXNUM-sized integer
 300                                     ;; values to be handled without consing.
 301                                     (<= ,lo key ,hi)
 302                                     (multiple-value-bind (q r)
 303                                         (floor (the (,type ,lo ,hi) key))
 304                                       (if (zerop (the ,type r))
 305                                           (sxhash q)
 306                                           (sxhash-double-float
 307                                            (coerce key 'double-float)))))
 308                                    (t
 309                                     (multiple-value-bind (q r) (floor key)
 310                                       (if (zerop (the ,type r))
 311                                           (sxhash q)
 312                                           (sxhash-double-float
 313                                            (coerce key 'double-float)))))))))
 314                (etypecase key
 315                  (single-float (frob single-float))
 316                  (double-float (frob double-float))
 317                  (short-float (frob short-float))
 318                  (long-float (error "LONG-FLOAT not currently supported")))))
 319       (rational (if (and (<= most-negative-double-float
 320                              key
 321                              most-positive-double-float)
 322                          (= (coerce key 'double-float) key))
 323                     (sxhash-double-float (coerce key 'double-float))
 324                     (sxhash key)))
 325       (complex (if (zerop (imagpart key))
 326                    (number-psxhash (realpart key))
 327                    (let ((result 330231))
 328                      (declare (type fixnum result))
 329                      (mixf result (number-psxhash (realpart key)))
 330                      (mixf result (number-psxhash (imagpart key)))
 331                      result))))))