src/code/target-sxhash.lisp

   1 ;;;; hashing functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 ;;; the depthoid explored when calculating hash values
  15 ;;;
  16 ;;; "Depthoid" here is a sort of mixture of what Common Lisp ordinarily calls
  17 ;;; depth and what Common Lisp ordinarily calls length; it's incremented either
  18 ;;; when we descend into a compound object or when we step through elements of
  19 ;;; a compound object.
  20 (defconstant +max-hash-depthoid+ 4)
  21 \f
  22 ;;;; mixing hash values
  23
  24 ;;; a function for mixing hash values
  25 ;;;
  26 ;;; desiderata:
  27 ;;;   * Non-commutativity keeps us from hashing e.g. #(1 5) to the
  28 ;;;     same value as #(5 1), and ending up in real trouble in some
  29 ;;;     special cases like bit vectors the way that CMUCL 18b SXHASH
  30 ;;;     does. (Under CMUCL 18b, SXHASH of any bit vector is 1..)
  31 ;;;   * We'd like to scatter our hash values over the entire possible range
  32 ;;;     of values instead of hashing small or common key values (like
  33 ;;;     2 and NIL and #\a) to small FIXNUMs the way that the CMUCL 18b
  34 ;;;     SXHASH function does, again helping to avoid pathologies like
  35 ;;;     hashing all bit vectors to 1.
  36 ;;;   * We'd like this to be simple and fast, too.
  37 ;;;
  38 ;;; FIXME: Should this be INLINE?
  39 (declaim (ftype (sfunction ((and fixnum unsigned-byte)
  40                             (and fixnum unsigned-byte))
  41                            (and fixnum unsigned-byte))
  42                 mix))
  43 (defun mix (x y)
  44   ;; FIXME: We wouldn't need the nasty (SAFETY 0) here if the compiler
  45   ;; were smarter about optimizing ASH. (Without the THE FIXNUM below,
  46   ;; and the (SAFETY 0) declaration here to get the compiler to trust
  47   ;; it, the sbcl-0.5.0m cross-compiler running under Debian
  48   ;; cmucl-2.4.17 turns the ASH into a full call, requiring the
  49   ;; UNSIGNED-BYTE 32 argument to be coerced to a bignum, requiring
  50   ;; consing, and thus generally obliterating performance.)
  51   (declare (optimize (speed 3) (safety 0)))
  52   (declare (type (and fixnum unsigned-byte) x y))
  53   ;; the ideas here:
  54   ;;   * Bits diffuse in both directions (shifted left by up to 2 places
  55   ;;     in the calculation of XY, and shifted right by up to 5 places
  56   ;;     by the ASH).
  57   ;;   * The #'+ and #'LOGXOR operations don't commute with each other,
  58   ;;     so different bit patterns are mixed together as they shift
  59   ;;     past each other.
  60   ;;   * The arbitrary constant in the #'LOGXOR expression is intended
  61   ;;     to help break up any weird anomalies we might otherwise get
  62   ;;     when hashing highly regular patterns.
  63   ;; (These are vaguely like the ideas used in many cryptographic
  64   ;; algorithms, but we're not pushing them hard enough here for them
  65   ;; to be cryptographically strong.)
  66   (let* ((xy (+ (* x 3) y)))
  67     (logand most-positive-fixnum
  68             (logxor 441516657
  69                     xy
  70                     (ash xy -5)))))
  71 \f
  72 ;;;; hashing strings
  73 ;;;;
  74 ;;;; Note that this operation is used in compiler symbol table
  75 ;;;; lookups, so we'd like it to be fast.
  76 ;;;;
  77 ;;;; As of 2004-03-10, we implement the one-at-a-time algorithm
  78 ;;;; designed by Bob Jenkins (see
  79 ;;;; <http://burtleburtle.net/bob/hash/doobs.html> for some more
  80 ;;;; information).
  81
  82 #!-sb-fluid (declaim (inline %sxhash-substring))
  83 (defun %sxhash-substring (string &optional (count (length string)))
  84   ;; FIXME: As in MIX above, we wouldn't need (SAFETY 0) here if the
  85   ;; cross-compiler were smarter about ASH, but we need it for
  86   ;; sbcl-0.5.0m.  (probably no longer true?  We might need SAFETY 0
  87   ;; to elide some type checks, but then again if this is inlined in
  88   ;; all the critical places, we might not -- CSR, 2004-03-10)
  89   (declare (optimize (speed 3) (safety 0)))
  90   (declare (type string string))
  91   (declare (type index count))
  92   (macrolet ((set-result (form)
  93                `(setf result (ldb (byte #.sb!vm:n-word-bits 0) ,form))))
  94     (let ((result 0))
  95       (declare (type (unsigned-byte #.sb!vm:n-word-bits) result))
  96       (unless (typep string '(vector nil))
  97         (dotimes (i count)
  98           (declare (type index i))
  99           (set-result (+ result (char-code (aref string i))))
 100           (set-result (+ result (ash result 10)))
 101           (set-result (logxor result (ash result -6)))))
 102       (set-result (+ result (ash result 3)))
 103       (set-result (logxor result (ash result -11)))
 104       (set-result (logxor result (ash result 15)))
 105       (logand result most-positive-fixnum))))
 106 ;;; test:
 107 ;;;   (let ((ht (make-hash-table :test 'equal)))
 108 ;;;     (do-all-symbols (symbol)
 109 ;;;       (let* ((string (symbol-name symbol))
 110 ;;;           (hash (%sxhash-substring string)))
 111 ;;;      (if (gethash hash ht)
 112 ;;;          (unless (string= (gethash hash ht) string)
 113 ;;;            (format t "collision: ~S ~S~%" string (gethash hash ht)))
 114 ;;;          (setf (gethash hash ht) string))))
 115 ;;;     (format t "final count=~W~%" (hash-table-count ht)))
 116
 117 (defun %sxhash-simple-string (x)
 118   (declare (optimize speed))
 119   (declare (type simple-string x))
 120   ;; KLUDGE: this FLET is a workaround (suggested by APD) for presence
 121   ;; of let conversion in the cross compiler, which otherwise causes
 122   ;; strongly suboptimal register allocation.
 123   (flet ((trick (x)
 124            (%sxhash-substring x)))
 125     (declare (notinline trick))
 126     (trick x)))
 127
 128 (defun %sxhash-simple-substring (x count)
 129   (declare (optimize speed))
 130   (declare (type simple-string x))
 131   (declare (type index count))
 132   ;; see comment in %SXHASH-SIMPLE-STRING
 133   (flet ((trick (x count)
 134            (%sxhash-substring x count)))
 135     (declare (notinline trick))
 136     (trick x count)))
 137 \f
 138 ;;;; the SXHASH function
 139
 140 ;; simple cases
 141 (declaim (ftype (sfunction (integer) (integer 0 #.sb!xc:most-positive-fixnum))
 142                 sxhash-bignum))
 143 (declaim (ftype (sfunction (t) (integer 0 #.sb!xc:most-positive-fixnum))
 144                 sxhash-instance))
 145
 146 (defun sxhash (x)
 147   ;; profiling SXHASH is hard, but we might as well try to make it go
 148   ;; fast, in case it is the bottleneck somwhere.  -- CSR, 2003-03-14
 149   (declare (optimize speed))
 150   (labels ((sxhash-number (x)
 151              (etypecase x
 152                (fixnum (sxhash x))      ; through DEFTRANSFORM
 153                (integer (sb!bignum:sxhash-bignum x))
 154                (single-float (sxhash x)) ; through DEFTRANSFORM
 155                (double-float (sxhash x)) ; through DEFTRANSFORM
 156                #!+long-float (long-float (error "stub: no LONG-FLOAT"))
 157                (ratio (let ((result 127810327))
 158                         (declare (type fixnum result))
 159                         (mixf result (sxhash-number (numerator x)))
 160                         (mixf result (sxhash-number (denominator x)))
 161                         result))
 162                (complex (let ((result 535698211))
 163                           (declare (type fixnum result))
 164                           (mixf result (sxhash-number (realpart x)))
 165                           (mixf result (sxhash-number (imagpart x)))
 166                           result))))
 167            (sxhash-recurse (x depthoid)
 168              (declare (type index depthoid))
 169              (typecase x
 170                ;; we test for LIST here, rather than CONS, because the
 171                ;; type test for CONS is in fact the test for
 172                ;; LIST-POINTER-LOWTAG followed by a negated test for
 173                ;; NIL.  If we're going to have to test for NIL anyway,
 174                ;; we might as well do it explicitly and pick off the
 175                ;; answer.  -- CSR, 2004-07-14
 176                (list
 177                 (if (null x)
 178                     (sxhash x) ; through DEFTRANSFORM
 179                     (if (plusp depthoid)
 180                         (mix (sxhash-recurse (car x) (1- depthoid))
 181                              (sxhash-recurse (cdr x) (1- depthoid)))
 182                         261835505)))
 183                (instance
 184                 (if (or (typep x 'structure-object) (typep x 'condition))
 185                     (logxor 422371266
 186                             (sxhash ; through DEFTRANSFORM
 187                              (classoid-name
 188                               (layout-classoid (%instance-layout x)))))
 189                     (sxhash-instance x)))
 190                (symbol (sxhash x)) ; through DEFTRANSFORM
 191                (array
 192                 (typecase x
 193                   (simple-string (sxhash x)) ; through DEFTRANSFORM
 194                   (string (%sxhash-substring x))
 195                   (simple-bit-vector (sxhash x)) ; through DEFTRANSFORM
 196                   (bit-vector
 197                    ;; FIXME: It must surely be possible to do better
 198                    ;; than this.  The problem is that a non-SIMPLE
 199                    ;; BIT-VECTOR could be displaced to another, with a
 200                    ;; non-zero offset -- so that significantly more
 201                    ;; work needs to be done using the %RAW-BITS
 202                    ;; approach.  This will probably do for now.
 203                    (sxhash-recurse (copy-seq x) depthoid))
 204                   (t (logxor 191020317 (sxhash (array-rank x))))))
 205                (character
 206                 (logxor 72185131
 207                         (sxhash (char-code x)))) ; through DEFTRANSFORM
 208                ;; general, inefficient case of NUMBER
 209                (number (sxhash-number x))
 210                (generic-function (sxhash-instance x))
 211                (t 42))))
 212     (sxhash-recurse x +max-hash-depthoid+)))
 213 \f
 214 ;;;; the PSXHASH function
 215
 216 ;;;; FIXME: This code does a lot of unnecessary full calls. It could be made
 217 ;;;; more efficient (in both time and space) by rewriting it along the lines
 218 ;;;; of the SXHASH code above.
 219
 220 ;;; like SXHASH, but for EQUALP hashing instead of EQUAL hashing
 221 (defun psxhash (key &optional (depthoid +max-hash-depthoid+))
 222   (declare (optimize speed))
 223   (declare (type (integer 0 #.+max-hash-depthoid+) depthoid))
 224   ;; Note: You might think it would be cleaner to use the ordering given in the
 225   ;; table from Figure 5-13 in the EQUALP section of the ANSI specification
 226   ;; here. So did I, but that is a snare for the unwary! Nothing in the ANSI
 227   ;; spec says that HASH-TABLE can't be a STRUCTURE-OBJECT, and in fact our
 228   ;; HASH-TABLEs *are* STRUCTURE-OBJECTs, so we need to pick off the special
 229   ;; HASH-TABLE behavior before we fall through to the generic STRUCTURE-OBJECT
 230   ;; comparison behavior.
 231   (typecase key
 232     (array (array-psxhash key depthoid))
 233     (hash-table (hash-table-psxhash key))
 234     (structure-object (structure-object-psxhash key depthoid))
 235     (cons (list-psxhash key depthoid))
 236     (number (number-psxhash key))
 237     (character (sxhash (char-upcase key)))
 238     (t (sxhash key))))
 239
 240 (defun array-psxhash (key depthoid)
 241   (declare (optimize speed))
 242   (declare (type array key))
 243   (declare (type (integer 0 #.+max-hash-depthoid+) depthoid))
 244   (typecase key
 245     ;; VECTORs have to be treated specially because ANSI specifies
 246     ;; that we must respect fill pointers.
 247     (vector
 248      (macrolet ((frob ()
 249                   '(let ((result 572539))
 250                      (declare (type fixnum result))
 251                      (mixf result (length key))
 252                      (dotimes (i (min depthoid (length key)))
 253                        (declare (type fixnum i))
 254                        (mixf result
 255                              (psxhash (aref key i)
 256                                       (- depthoid 1 i))))
 257                      result)))
 258        ;; CMU can compile SIMPLE-ARRAY operations so much more efficiently
 259        ;; than the general case that it's probably worth picking off the
 260        ;; common special cases.
 261        (typecase key
 262          (simple-string
 263           ;;(format t "~&SIMPLE-STRING special case~%")
 264           (frob))
 265          (simple-vector
 266           ;;(format t "~&SIMPLE-VECTOR special case~%")
 267           (frob))
 268          (t (frob)))))
 269     ;; Any other array can be hashed by working with its underlying
 270     ;; one-dimensional physical representation.
 271     (t
 272      (let ((result 60828))
 273        (declare (type fixnum result))
 274        (dotimes (i (min depthoid (array-rank key)))
 275          (mixf result (array-dimension key i)))
 276        (dotimes (i (min depthoid (array-total-size key)))
 277          (mixf result
 278                (psxhash (row-major-aref key i)
 279                         (- depthoid 1 i))))
 280        result))))
 281
 282 (defun structure-object-psxhash (key depthoid)
 283   (declare (optimize speed))
 284   (declare (type structure-object key))
 285   (declare (type (integer 0 #.+max-hash-depthoid+) depthoid))
 286   (let* ((layout (%instance-layout key)) ; i.e. slot #0
 287          (length (layout-length layout))
 288          (classoid (layout-classoid layout))
 289          (name (classoid-name classoid))
 290          (result (mix (sxhash name) (the fixnum 79867))))
 291     (declare (type fixnum result))
 292     (dotimes (i (min depthoid (- length 1 (layout-n-untagged-slots layout))))
 293       (declare (type fixnum i))
 294       (let ((j (1+ i))) ; skipping slot #0, which is for LAYOUT
 295         (declare (type fixnum j))
 296         (mixf result
 297               (psxhash (%instance-ref key j)
 298                        (1- depthoid)))))
 299     ;; KLUDGE: Should hash untagged slots, too.  (Although +max-hash-depthoid+
 300     ;; is pretty low currently, so they might not make it into the hash
 301     ;; value anyway.)
 302     result))
 303
 304 (defun list-psxhash (key depthoid)
 305   (declare (optimize speed))
 306   (declare (type list key))
 307   (declare (type (integer 0 #.+max-hash-depthoid+) depthoid))
 308   (cond ((null key)
 309          (the fixnum 480929))
 310         ((zerop depthoid)
 311          (the fixnum 779578))
 312         (t
 313          (mix (psxhash (car key) (1- depthoid))
 314               (psxhash (cdr key) (1- depthoid))))))
 315
 316 (defun hash-table-psxhash (key)
 317   (declare (optimize speed))
 318   (declare (type hash-table key))
 319   (let ((result 103924836))
 320     (declare (type fixnum result))
 321     (mixf result (hash-table-count key))
 322     (mixf result (sxhash (hash-table-test key)))
 323     result))
 324
 325 (defun number-psxhash (key)
 326   (declare (optimize speed))
 327   (declare (type number key))
 328   (flet ((sxhash-double-float (val)
 329            (declare (type double-float val))
 330            ;; FIXME: Check to make sure that the DEFTRANSFORM kicks in and the
 331            ;; resulting code works without consing. (In Debian cmucl 2.4.17,
 332            ;; it didn't.)
 333            (sxhash val)))
 334     (etypecase key
 335       (integer (sxhash key))
 336       (float (macrolet ((frob (type)
 337                           (let ((lo (coerce most-negative-fixnum type))
 338                                 (hi (coerce most-positive-fixnum type)))
 339                             `(cond (;; This clause allows FIXNUM-sized integer
 340                                     ;; values to be handled without consing.
 341                                     (<= ,lo key ,hi)
 342                                     (multiple-value-bind (q r)
 343                                         (floor (the (,type ,lo ,hi) key))
 344                                       (if (zerop (the ,type r))
 345                                           (sxhash q)
 346                                           (sxhash-double-float
 347                                            (coerce key 'double-float)))))
 348                                    (t
 349                                     (multiple-value-bind (q r) (floor key)
 350                                       (if (zerop (the ,type r))
 351                                           (sxhash q)
 352                                           (sxhash-double-float
 353                                            (coerce key 'double-float)))))))))
 354                (etypecase key
 355                  (single-float (frob single-float))
 356                  (double-float (frob double-float))
 357                  #!+long-float
 358                  (long-float (error "LONG-FLOAT not currently supported")))))
 359       (rational (if (and (<= most-negative-double-float
 360                              key
 361                              most-positive-double-float)
 362                          (= (coerce key 'double-float) key))
 363                     (sxhash-double-float (coerce key 'double-float))
 364                     (sxhash key)))
 365       (complex (if (zerop (imagpart key))
 366                    (number-psxhash (realpart key))
 367                    (let ((result 330231))
 368                      (declare (type fixnum result))
 369                      (mixf result (number-psxhash (realpart key)))
 370                      (mixf result (number-psxhash (imagpart key)))
 371                      result))))))