src/code/target-thread.lisp

   1 ;;;; support for threads in the target machine
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!THREAD")
  13
  14 ;;; Conditions
  15
  16 (define-condition thread-error (error)
  17   ((thread :reader thread-error-thread :initarg :thread))
  18   #!+sb-doc
  19   (:documentation
  20    "Conditions of type THREAD-ERROR are signalled when thread operations fail.
  21 The offending thread is initialized by the :THREAD initialization argument and
  22 read by the function THREAD-ERROR-THREAD."))
  23
  24 #!+sb-doc
  25 (setf
  26  (fdocumentation 'thread-error-thread 'function)
  27  "Return the offending thread that the THREAD-ERROR pertains to.")
  28
  29 (define-condition symbol-value-in-thread-error (cell-error thread-error)
  30   ((info :reader symbol-value-in-thread-error-info :initarg :info))
  31   (:report
  32    (lambda (condition stream)
  33      (destructuring-bind (op problem)
  34          (symbol-value-in-thread-error-info condition)
  35        (format stream "Cannot ~(~A~) value of ~S in ~S: ~S"
  36                op
  37                (cell-error-name condition)
  38                (thread-error-thread condition)
  39                (ecase problem
  40                  (:unbound-in-thread "the symbol is unbound in thread.")
  41                  (:no-tls-value "the symbol has no thread-local value.")
  42                  (:thread-dead "the thread has exited.")
  43                  (:invalid-tls-value "the thread-local value is not valid."))))))
  44   #!+sb-doc
  45   (:documentation
  46    "Signalled when SYMBOL-VALUE-IN-THREAD or its SETF version fails due to eg.
  47 the symbol not having a thread-local value, or the target thread having
  48 exited. The offending symbol can be accessed using CELL-ERROR-NAME, and the
  49 offending thread using THREAD-ERROR-THREAD."))
  50
  51 (define-condition join-thread-error (thread-error) ()
  52   (:report (lambda (c s)
  53              (format s "Joining thread failed: thread ~A ~
  54                         did not return normally."
  55                      (thread-error-thread c))))
  56   #!+sb-doc
  57   (:documentation
  58    "Signalled when joining a thread fails due to abnormal exit of the thread
  59 to be joined. The offending thread can be accessed using
  60 THREAD-ERROR-THREAD."))
  61
  62 (defun join-thread-error-thread (condition)
  63   (thread-error-thread condition))
  64 (define-compiler-macro join-thread-error-thread (condition)
  65   (deprecation-warning 'join-thread-error-thread 'thread-error-thread)
  66   `(thread-error-thread ,condition))
  67
  68 #!+sb-doc
  69 (setf
  70  (fdocumentation 'join-thread-error-thread 'function)
  71  "The thread that we failed to join. Deprecated, use THREAD-ERROR-THREAD
  72 instead.")
  73
  74 (define-condition interrupt-thread-error (thread-error) ()
  75   (:report (lambda (c s)
  76              (format s "Interrupt thread failed: thread ~A has exited."
  77                      (thread-error-thread c))))
  78   #!+sb-doc
  79   (:documentation
  80    "Signalled when interrupting a thread fails because the thread has already
  81 exited. The offending thread can be accessed using THREAD-ERROR-THREAD."))
  82
  83 (defun interrupt-thread-error-thread (condition)
  84   (thread-error-thread condition))
  85 (define-compiler-macro interrupt-thread-error-thread (condition)
  86   (deprecation-warning 'join-thread-error-thread 'thread-error-thread)
  87   `(thread-error-thread ,condition))
  88
  89 #!+sb-doc
  90 (setf
  91  (fdocumentation 'interrupt-thread-error-thread 'function)
  92  "The thread that was not interrupted. Deprecated, use THREAD-ERROR-THREAD
  93 instead.")
  94
  95 ;;; Of the WITH-PINNED-OBJECTS in this file, not every single one is
  96 ;;; necessary because threads are only supported with the conservative
  97 ;;; gencgc and numbers on the stack (returned by GET-LISP-OBJ-ADDRESS)
  98 ;;; are treated as references.
  99
 100 ;;; set the doc here because in early-thread FDOCUMENTATION is not
 101 ;;; available, yet
 102 #!+sb-doc
 103 (setf (fdocumentation '*current-thread* 'variable)
 104       "Bound in each thread to the thread itself.")
 105
 106 #!+sb-doc
 107 (setf
 108  (fdocumentation 'thread-name 'function)
 109  "Name of the thread. Can be assigned to using SETF. Thread names can be
 110 arbitrary printable objects, and need not be unique.")
 111
 112 (def!method print-object ((thread thread) stream)
 113   (print-unreadable-object (thread stream :type t :identity t)
 114     (let* ((cookie (list thread))
 115            (info (if (thread-alive-p thread)
 116                      :running
 117                      (multiple-value-list
 118                       (join-thread thread :default cookie))))
 119            (state (if (eq :running info)
 120                       info
 121                       (if (eq cookie (car info))
 122                           :aborted
 123                           :finished)))
 124            (values (when (eq :finished state) info)))
 125       (format stream
 126               "~@[~S ~]~:[~A~;~A~:[ no values~; values: ~:*~{~S~^, ~}~]~]"
 127               (thread-name thread)
 128               (eq :finished state)
 129               state
 130               values))))
 131
 132 (defun thread-alive-p (thread)
 133   #!+sb-doc
 134   "Return T if THREAD is still alive. Note that the return value is
 135 potentially stale even before the function returns, as the thread may exit at
 136 any time."
 137   (thread-%alive-p thread))
 138
 139 ;; A thread is eligible for gc iff it has finished and there are no
 140 ;; more references to it. This list is supposed to keep a reference to
 141 ;; all running threads.
 142 (defvar *all-threads* ())
 143 (defvar *all-threads-lock* (make-mutex :name "all threads lock"))
 144
 145 (defvar *default-alloc-signal* nil)
 146
 147 (defmacro with-all-threads-lock (&body body)
 148   `(with-system-mutex (*all-threads-lock*)
 149      ,@body))
 150
 151 (defun list-all-threads ()
 152   #!+sb-doc
 153   "Return a list of the live threads. Note that the return value is
 154 potentially stale even before the function returns, as new threads may be
 155 created and old ones may exit at any time."
 156   (with-all-threads-lock
 157     (copy-list *all-threads*)))
 158
 159 (declaim (inline current-thread-sap))
 160 (defun current-thread-sap ()
 161   (sb!vm::current-thread-offset-sap sb!vm::thread-this-slot))
 162
 163 (declaim (inline current-thread-os-thread))
 164 (defun current-thread-os-thread ()
 165   #!+sb-thread
 166   (sap-int (sb!vm::current-thread-offset-sap sb!vm::thread-os-thread-slot))
 167   #!-sb-thread
 168   0)
 169
 170 (defun init-initial-thread ()
 171   (/show0 "Entering INIT-INITIAL-THREAD")
 172   (let ((initial-thread (%make-thread :name "initial thread"
 173                                       :%alive-p t
 174                                       :os-thread (current-thread-os-thread))))
 175     (setq *current-thread* initial-thread)
 176     ;; Either *all-threads* is empty or it contains exactly one thread
 177     ;; in case we are in reinit since saving core with multiple
 178     ;; threads doesn't work.
 179     (setq *all-threads* (list initial-thread))))
 180 \f
 181
 182 ;;;; Aliens, low level stuff
 183
 184 (define-alien-routine "kill_safely"
 185     integer
 186   (os-thread #!-alpha unsigned-long #!+alpha unsigned-int)
 187   (signal int))
 188
 189 #!+sb-thread
 190 (progn
 191   ;; FIXME it would be good to define what a thread id is or isn't
 192   ;; (our current assumption is that it's a fixnum).  It so happens
 193   ;; that on Linux it's a pid, but it might not be on posix thread
 194   ;; implementations.
 195   (define-alien-routine ("create_thread" %create-thread)
 196       unsigned-long (lisp-fun-address unsigned-long))
 197
 198   (declaim (inline %block-deferrable-signals))
 199   (define-alien-routine ("block_deferrable_signals" %block-deferrable-signals)
 200       void
 201     (where sb!alien:unsigned-long)
 202     (old sb!alien:unsigned-long))
 203
 204   (defun block-deferrable-signals ()
 205     (%block-deferrable-signals 0 0))
 206
 207   #!+sb-lutex
 208   (progn
 209     (declaim (inline %lutex-init %lutex-wait %lutex-wake
 210                      %lutex-lock %lutex-unlock))
 211
 212     (define-alien-routine ("lutex_init" %lutex-init)
 213         int (lutex unsigned-long))
 214
 215     (define-alien-routine ("lutex_wait" %lutex-wait)
 216         int (queue-lutex unsigned-long) (mutex-lutex unsigned-long))
 217
 218     (define-alien-routine ("lutex_wake" %lutex-wake)
 219         int (lutex unsigned-long) (n int))
 220
 221     (define-alien-routine ("lutex_lock" %lutex-lock)
 222         int (lutex unsigned-long))
 223
 224     (define-alien-routine ("lutex_trylock" %lutex-trylock)
 225         int (lutex unsigned-long))
 226
 227     (define-alien-routine ("lutex_unlock" %lutex-unlock)
 228         int (lutex unsigned-long))
 229
 230     (define-alien-routine ("lutex_destroy" %lutex-destroy)
 231         int (lutex unsigned-long))
 232
 233     ;; FIXME: Defining a whole bunch of alien-type machinery just for
 234     ;; passing primitive lutex objects directly to foreign functions
 235     ;; doesn't seem like fun right now. So instead we just manually
 236     ;; pin the lutex, get its address, and let the callee untag it.
 237     (defmacro with-lutex-address ((name lutex) &body body)
 238       `(let ((,name ,lutex))
 239          (with-pinned-objects (,name)
 240            (let ((,name (get-lisp-obj-address ,name)))
 241              ,@body))))
 242
 243     (defun make-lutex ()
 244       (/show0 "Entering MAKE-LUTEX")
 245       ;; Suppress GC until the lutex has been properly registered with
 246       ;; the GC.
 247       (without-gcing
 248         (let ((lutex (sb!vm::%make-lutex)))
 249           (/show0 "LUTEX=..")
 250           (/hexstr lutex)
 251           (with-lutex-address (lutex lutex)
 252             (%lutex-init lutex))
 253           lutex))))
 254
 255   #!-sb-lutex
 256   (progn
 257     (declaim (inline futex-wait %futex-wait futex-wake))
 258
 259     (define-alien-routine ("futex_wait" %futex-wait)
 260         int (word unsigned-long) (old-value unsigned-long)
 261         (to-sec long) (to-usec unsigned-long))
 262
 263     (defun futex-wait (word old to-sec to-usec)
 264       (with-interrupts
 265         (%futex-wait word old to-sec to-usec)))
 266
 267     (define-alien-routine "futex_wake"
 268         int (word unsigned-long) (n unsigned-long))))
 269
 270 ;;; used by debug-int.lisp to access interrupt contexts
 271 #!-(or sb-fluid sb-thread) (declaim (inline sb!vm::current-thread-offset-sap))
 272 #!-sb-thread
 273 (defun sb!vm::current-thread-offset-sap (n)
 274   (declare (type (unsigned-byte 27) n))
 275   (sap-ref-sap (alien-sap (extern-alien "all_threads" (* t)))
 276                (* n sb!vm:n-word-bytes)))
 277
 278 #!+sb-thread
 279 (defun sb!vm::current-thread-offset-sap (n)
 280   (declare (type (unsigned-byte 27) n))
 281   (sb!vm::current-thread-offset-sap n))
 282 \f
 283
 284 ;;;; Spinlocks
 285
 286 (declaim (inline get-spinlock release-spinlock))
 287
 288 ;;; Should always be called with interrupts disabled.
 289 (defun get-spinlock (spinlock)
 290   (declare (optimize (speed 3) (safety 0)))
 291   (let* ((new *current-thread*)
 292          (old (sb!ext:compare-and-swap (spinlock-value spinlock) nil new)))
 293     (when old
 294       (when (eq old new)
 295         (error "Recursive lock attempt on ~S." spinlock))
 296       #!+sb-thread
 297       (flet ((cas ()
 298                (if (sb!ext:compare-and-swap (spinlock-value spinlock) nil new)
 299                    (thread-yield)
 300                    (return-from get-spinlock t))))
 301         (if (and (not *interrupts-enabled*) *allow-with-interrupts*)
 302             ;; If interrupts are disabled, but we are allowed to
 303             ;; enabled them, check for pending interrupts every once
 304             ;; in a while. %CHECK-INTERRUPTS is taking shortcuts, make
 305             ;; sure that deferrables are unblocked by doing an empty
 306             ;; WITH-INTERRUPTS once.
 307             (progn
 308               (with-interrupts)
 309               (loop
 310                (loop repeat 128 do (cas)) ; 128 is arbitrary here
 311                (sb!unix::%check-interrupts)))
 312             (loop (cas)))))
 313     t))
 314
 315 (defun release-spinlock (spinlock)
 316   (declare (optimize (speed 3) (safety 0)))
 317   ;; On x86 and x86-64 we can get away with no memory barriers, (see
 318   ;; Linux kernel mailing list "spin_unlock optimization(i386)"
 319   ;; thread, summary at
 320   ;; http://kt.iserv.nl/kernel-traffic/kt19991220_47.html#1.
 321   ;;
 322   ;; If the compiler may reorder this with other instructions, insert
 323   ;; compiler barrier here.
 324   ;;
 325   ;; FIXME: this does not work on SMP Pentium Pro and OOSTORE systems,
 326   ;; neither on most non-x86 architectures (but we don't have threads
 327   ;; on those).
 328   (setf (spinlock-value spinlock) nil))
 329 \f
 330
 331 ;;;; Mutexes
 332
 333 #!+sb-doc
 334 (setf (fdocumentation 'make-mutex 'function)
 335       "Create a mutex."
 336       (fdocumentation 'mutex-name 'function)
 337       "The name of the mutex. Setfable.")
 338
 339 #!+(and sb-thread (not sb-lutex))
 340 (progn
 341   (define-structure-slot-addressor mutex-state-address
 342       :structure mutex
 343       :slot state)
 344   ;; Important: current code assumes these are fixnums or other
 345   ;; lisp objects that don't need pinning.
 346   (defconstant +lock-free+ 0)
 347   (defconstant +lock-taken+ 1)
 348   (defconstant +lock-contested+ 2))
 349
 350 (defun mutex-owner (mutex)
 351   "Current owner of the mutex, NIL if the mutex is free. Naturally,
 352 this is racy by design (another thread may acquire the mutex after
 353 this function returns), it is intended for informative purposes. For
 354 testing whether the current thread is holding a mutex see
 355 HOLDING-MUTEX-P."
 356   ;; Make sure to get the current value.
 357   (sb!ext:compare-and-swap (mutex-%owner mutex) nil nil))
 358
 359 (defun get-mutex (mutex &optional (new-owner *current-thread*) (waitp t))
 360   #!+sb-doc
 361   "Acquire MUTEX for NEW-OWNER, which must be a thread or NIL. If
 362 NEW-OWNER is NIL, it defaults to the current thread. If WAITP is
 363 non-NIL and the mutex is in use, sleep until it is available.
 364
 365 Note: using GET-MUTEX to assign a MUTEX to another thread then the
 366 current one is not recommended, and liable to be deprecated.
 367
 368 GET-MUTEX is not interrupt safe. The correct way to call it is:
 369
 370  (WITHOUT-INTERRUPTS
 371    ...
 372    (ALLOW-WITH-INTERRUPTS (GET-MUTEX ...))
 373    ...)
 374
 375 WITHOUT-INTERRUPTS is necessary to avoid an interrupt unwinding the
 376 call while the mutex is in an inconsistent state while
 377 ALLOW-WITH-INTERRUPTS allows the call to be interrupted from sleep.
 378
 379 It is recommended that you use WITH-MUTEX instead of calling GET-MUTEX
 380 directly."
 381   (declare (type mutex mutex) (optimize (speed 3))
 382            #!-sb-thread (ignore waitp))
 383   (unless new-owner
 384     (setq new-owner *current-thread*))
 385   (let ((old (mutex-%owner mutex)))
 386     (when (eq new-owner old)
 387       (error "Recursive lock attempt ~S." mutex))
 388     #!-sb-thread
 389     (when old
 390       (error "Strange deadlock on ~S in an unithreaded build?" mutex)))
 391   #!-sb-thread
 392   (setf (mutex-%owner mutex) new-owner)
 393   #!+sb-thread
 394   (progn
 395     ;; FIXME: Lutexes do not currently support deadlines, as at least
 396     ;; on Darwin pthread_foo_timedbar functions are not supported:
 397     ;; this means that we probably need to use the Carbon multiprocessing
 398     ;; functions on Darwin.
 399     ;;
 400     ;; FIXME: This is definitely not interrupt safe: what happens if
 401     ;; we get hit (1) during the lutex calls (ok, they may be safe,
 402     ;; but has that been checked?) (2) after the lutex call, but
 403     ;; before setting the mutex owner.
 404     #!+sb-lutex
 405     (when (zerop (with-lutex-address (lutex (mutex-lutex mutex))
 406                    (if waitp
 407                        (with-interrupts (%lutex-lock lutex))
 408                        (%lutex-trylock lutex))))
 409       (setf (mutex-%owner mutex) new-owner)
 410       t)
 411     #!-sb-lutex
 412     ;; This is a direct translation of the Mutex 2 algorithm from
 413     ;; "Futexes are Tricky" by Ulrich Drepper.
 414     (let ((old (sb!ext:compare-and-swap (mutex-state mutex)
 415                                         +lock-free+
 416                                         +lock-taken+)))
 417       (unless (or (eql +lock-free+ old) (not waitp))
 418         (tagbody
 419          :retry
 420            (when (or (eql +lock-contested+ old)
 421                      (not (eql +lock-free+
 422                                (sb!ext:compare-and-swap (mutex-state mutex)
 423                                                         +lock-taken+
 424                                                         +lock-contested+))))
 425              ;; Wait on the contested lock.
 426              (loop
 427               (multiple-value-bind (to-sec to-usec) (decode-timeout nil)
 428                 (case (with-pinned-objects (mutex)
 429                         (futex-wait (mutex-state-address mutex)
 430                                     (get-lisp-obj-address +lock-contested+)
 431                                     (or to-sec -1)
 432                                     (or to-usec 0)))
 433                   ((1) (signal-deadline))
 434                   ((2))
 435                   (otherwise (return))))))
 436            (setf old (sb!ext:compare-and-swap (mutex-state mutex)
 437                                               +lock-free+
 438                                               +lock-contested+))
 439            ;; Did we get it?
 440            (unless (eql +lock-free+ old)
 441              (go :retry))))
 442       (cond ((eql +lock-free+ old)
 443              (let ((prev (sb!ext:compare-and-swap (mutex-%owner mutex)
 444                                                   nil new-owner)))
 445                (when prev
 446                  (bug "Old owner in free mutex: ~S" prev))
 447                t))
 448             (waitp
 449              (bug "Failed to acquire lock with WAITP."))))))
 450
 451 (defun release-mutex (mutex &key (if-not-owner :punt))
 452   #!+sb-doc
 453   "Release MUTEX by setting it to NIL. Wake up threads waiting for
 454 this mutex.
 455
 456 RELEASE-MUTEX is not interrupt safe: interrupts should be disabled
 457 around calls to it.
 458
 459 If the current thread is not the owner of the mutex then it silently
 460 returns without doing anything (if IF-NOT-OWNER is :PUNT), signals a
 461 WARNING (if IF-NOT-OWNER is :WARN), or releases the mutex anyway (if
 462 IF-NOT-OWNER is :FORCE)."
 463   (declare (type mutex mutex))
 464   ;; Order matters: set owner to NIL before releasing state.
 465   (let* ((self *current-thread*)
 466          (old-owner (sb!ext:compare-and-swap (mutex-%owner mutex) self nil)))
 467     (unless (eql self old-owner)
 468       (ecase if-not-owner
 469         ((:punt) (return-from release-mutex nil))
 470         ((:warn)
 471          (warn "Releasing ~S, owned by another thread: ~S" mutex old-owner))
 472         ((:force))))
 473     #!+sb-thread
 474     (when old-owner
 475       (setf (mutex-%owner mutex) nil)
 476       #!+sb-lutex
 477       (with-lutex-address (lutex (mutex-lutex mutex))
 478         (%lutex-unlock lutex))
 479       #!-sb-lutex
 480       ;; FIXME: once ATOMIC-INCF supports struct slots with word sized
 481       ;; unsigned-byte type this can be used:
 482       ;;
 483       ;;     (let ((old (sb!ext:atomic-incf (mutex-state mutex) -1)))
 484       ;;       (unless (eql old +lock-free+)
 485       ;;         (setf (mutex-state mutex) +lock-free+)
 486       ;;         (with-pinned-objects (mutex)
 487       ;;           (futex-wake (mutex-state-address mutex) 1))))
 488       (let ((old (sb!ext:compare-and-swap (mutex-state mutex)
 489                                           +lock-taken+ +lock-free+)))
 490         (when (eql old +lock-contested+)
 491           (sb!ext:compare-and-swap (mutex-state mutex)
 492                                    +lock-contested+ +lock-free+)
 493           (with-pinned-objects (mutex)
 494             (futex-wake (mutex-state-address mutex) 1))))
 495       nil)))
 496 \f
 497
 498 ;;;; Waitqueues/condition variables
 499
 500 (defstruct (waitqueue (:constructor %make-waitqueue))
 501   #!+sb-doc
 502   "Waitqueue type."
 503   (name nil :type (or null simple-string))
 504   #!+(and sb-lutex sb-thread)
 505   (lutex (make-lutex))
 506   #!-sb-lutex
 507   (data nil))
 508
 509 (defun make-waitqueue (&key name)
 510   #!+sb-doc
 511   "Create a waitqueue."
 512   (%make-waitqueue :name name))
 513
 514 #!+sb-doc
 515 (setf (fdocumentation 'waitqueue-name 'function)
 516       "The name of the waitqueue. Setfable.")
 517
 518 #!+(and sb-thread (not sb-lutex))
 519 (define-structure-slot-addressor waitqueue-data-address
 520     :structure waitqueue
 521     :slot data)
 522
 523 (defun condition-wait (queue mutex)
 524   #!+sb-doc
 525   "Atomically release MUTEX and enqueue ourselves on QUEUE.  Another
 526 thread may subsequently notify us using CONDITION-NOTIFY, at which
 527 time we reacquire MUTEX and return to the caller."
 528   #!-sb-thread (declare (ignore queue))
 529   (assert mutex)
 530   #!-sb-thread (error "Not supported in unithread builds.")
 531   #!+sb-thread
 532   (let ((me *current-thread*))
 533     (assert (eq me (mutex-%owner mutex)))
 534     (/show0 "CONDITION-WAITing")
 535     #!+sb-lutex
 536     ;; Need to disable interrupts so that we don't miss setting the
 537     ;; owner on our way out. (pthread_cond_wait handles the actual
 538     ;; re-acquisition.)
 539     (without-interrupts
 540       (unwind-protect
 541            (progn
 542              (setf (mutex-%owner mutex) nil)
 543              (with-lutex-address (queue-lutex-address (waitqueue-lutex queue))
 544                (with-lutex-address (mutex-lutex-address (mutex-lutex mutex))
 545                  (with-local-interrupts
 546                    (%lutex-wait queue-lutex-address mutex-lutex-address)))))
 547         (setf (mutex-%owner mutex) me)))
 548     #!-sb-lutex
 549     ;; Need to disable interrupts so that we don't miss grabbing the
 550     ;; mutex on our way out.
 551     (without-interrupts
 552       (let ((me nil))
 553         ;; This setf becomes visible to other CPUS due to the usual
 554         ;; memory barrier semantics of lock acquire/release. This must
 555         ;; not be moved into the loop else wakeups may be lost upon
 556         ;; continuing after a deadline or EINTR.
 557         (setf (waitqueue-data queue) me)
 558         (loop
 559          (multiple-value-bind (to-sec to-usec)
 560              (allow-with-interrupts (decode-timeout nil))
 561            (case (unwind-protect
 562                       (with-pinned-objects (queue me)
 563                         ;; RELEASE-MUTEX is purposefully as close to
 564                         ;; FUTEX-WAIT as possible to reduce the size
 565                         ;; of the window where WAITQUEUE-DATA may be
 566                         ;; set by a notifier.
 567                         (release-mutex mutex)
 568                         ;; Now we go to sleep using futex-wait. If
 569                         ;; anyone else manages to grab MUTEX and call
 570                         ;; CONDITION-NOTIFY during this comment, it
 571                         ;; will change queue->data, and so futex-wait
 572                         ;; returns immediately instead of sleeping.
 573                         ;; Ergo, no lost wakeup. We may get spurious
 574                         ;; wakeups, but that's ok.
 575                         (allow-with-interrupts
 576                           (futex-wait (waitqueue-data-address queue)
 577                                       (get-lisp-obj-address me)
 578                                       ;; our way of saying "no
 579                                       ;; timeout":
 580                                       (or to-sec -1)
 581                                       (or to-usec 0))))
 582                    ;; If we are interrupted while waiting, we should
 583                    ;; do these things before returning. Ideally, in
 584                    ;; the case of an unhandled signal, we should do
 585                    ;; them before entering the debugger, but this is
 586                    ;; better than nothing.
 587                    (allow-with-interrupts (get-mutex mutex)))
 588              ;; ETIMEDOUT; we know it was a timeout, yet we cannot
 589              ;; signal a deadline unconditionally here because the
 590              ;; call to GET-MUTEX may already have signaled it.
 591              ((1))
 592              ;; EINTR
 593              ((2))
 594              ;; EWOULDBLOCK, -1 here, is the possible spurious wakeup
 595              ;; case. 0 is the normal wakeup.
 596              (otherwise (return)))))))))
 597
 598 (defun condition-notify (queue &optional (n 1))
 599   #!+sb-doc
 600   "Notify N threads waiting on QUEUE. The same mutex that is used in
 601 the corresponding CONDITION-WAIT must be held by this thread during
 602 this call."
 603   #!-sb-thread (declare (ignore queue n))
 604   #!-sb-thread (error "Not supported in unithread builds.")
 605   #!+sb-thread
 606   (declare (type (and fixnum (integer 1)) n))
 607   (/show0 "Entering CONDITION-NOTIFY")
 608   #!+sb-thread
 609   (progn
 610     #!+sb-lutex
 611     (with-lutex-address (lutex (waitqueue-lutex queue))
 612       (%lutex-wake lutex n))
 613     ;; no problem if >1 thread notifies during the comment in
 614     ;; condition-wait: as long as the value in queue-data isn't the
 615     ;; waiting thread's id, it matters not what it is
 616     ;; XXX we should do something to ensure that the result of this setf
 617     ;; is visible to all CPUs
 618     #!-sb-lutex
 619     (let ((me *current-thread*))
 620       (progn
 621         (setf (waitqueue-data queue) me)
 622         (with-pinned-objects (queue)
 623           (futex-wake (waitqueue-data-address queue) n))))))
 624
 625 (defun condition-broadcast (queue)
 626   #!+sb-doc
 627   "Notify all threads waiting on QUEUE."
 628   (condition-notify queue
 629                     ;; On a 64-bit platform truncating M-P-F to an int
 630                     ;; results in -1, which wakes up only one thread.
 631                     (ldb (byte 29 0)
 632                          most-positive-fixnum)))
 633 \f
 634
 635 ;;;; Semaphores
 636
 637 (defstruct (semaphore (:constructor %make-semaphore (name %count)))
 638   #!+sb-doc
 639   "Semaphore type. The fact that a SEMAPHORE is a STRUCTURE-OBJECT
 640 should be considered an implementation detail, and may change in the
 641 future."
 642   (name nil :type (or null simple-string))
 643   (%count 0 :type (integer 0))
 644   (waitcount 0 :type (integer 0))
 645   (mutex (make-mutex))
 646   (queue (make-waitqueue)))
 647
 648 (setf (fdocumentation 'semaphore-name 'function)
 649       "The name of the semaphore INSTANCE. Setfable.")
 650
 651 (declaim (inline semaphore-count))
 652 (defun semaphore-count (instance)
 653   "Returns the current count of the semaphore INSTANCE."
 654   (semaphore-%count instance))
 655
 656 (defun make-semaphore (&key name (count 0))
 657   #!+sb-doc
 658   "Create a semaphore with the supplied COUNT and NAME."
 659   (%make-semaphore name count))
 660
 661 (defun wait-on-semaphore (semaphore)
 662   #!+sb-doc
 663   "Decrement the count of SEMAPHORE if the count would not be
 664 negative. Else blocks until the semaphore can be decremented."
 665   ;; A more direct implementation based directly on futexes should be
 666   ;; possible.
 667   ;;
 668   ;; We need to disable interrupts so that we don't forget to
 669   ;; decrement the waitcount (which would happen if an asynch
 670   ;; interrupt should catch us on our way out from the loop.)
 671   (with-system-mutex ((semaphore-mutex semaphore) :allow-with-interrupts t)
 672     ;; Quick check: is it positive? If not, enter the wait loop.
 673     (let ((count (semaphore-%count semaphore)))
 674       (if (plusp count)
 675           (setf (semaphore-%count semaphore) (1- count))
 676           (unwind-protect
 677                (progn
 678                  (incf (semaphore-waitcount semaphore))
 679                  (loop until (plusp (setf count (semaphore-%count semaphore)))
 680                        do (condition-wait (semaphore-queue semaphore)
 681                                           (semaphore-mutex semaphore)))
 682                  (setf (semaphore-%count semaphore) (1- count)))
 683             ;; Even safe when CONDITION-WAIT is unwinded without
 684             ;; having reacquired the lock: a) we know at this point
 685             ;; that an INCF must have happened before, b) the DECF
 686             ;; will become visible to other CPUs as the implicit
 687             ;; RELEASE-MUTEX involves a CAS and hence a memory
 688             ;; barrier.
 689             (decf (semaphore-waitcount semaphore)))))))
 690
 691 (defun try-semaphore (semaphore)
 692   #!+sb-doc
 693   "Try to decrement the count of SEMAPHORE if the count would not be
 694 negative. Else return NIL."
 695   ;; No need for disabling interrupts; the mutex prevents interleaved
 696   ;; modifications, and we don't leave temporarily inconsistent state
 697   ;; around.
 698   (with-mutex ((semaphore-mutex semaphore))
 699     (let ((count (semaphore-%count semaphore)))
 700       (when (plusp count)
 701         (setf (semaphore-%count semaphore) (1- count))))))
 702
 703 (defun signal-semaphore (semaphore &optional (n 1))
 704   #!+sb-doc
 705   "Increment the count of SEMAPHORE by N. If there are threads waiting
 706 on this semaphore, then N of them is woken up."
 707   (declare (type (integer 1) n))
 708   ;; Need to disable interrupts so that we don't lose a wakeup after
 709   ;; we have incremented the count.
 710   (with-system-mutex ((semaphore-mutex semaphore))
 711     (let ((waitcount (semaphore-waitcount semaphore))
 712           (count (incf (semaphore-%count semaphore) n)))
 713       (when (plusp waitcount)
 714         (condition-notify (semaphore-queue semaphore) (min waitcount count))))))
 715 \f
 716
 717 ;;;; Job control, independent listeners
 718
 719 (defstruct session
 720   (lock (make-mutex :name "session lock"))
 721   (threads nil)
 722   (interactive-threads nil)
 723   (interactive-threads-queue (make-waitqueue)))
 724
 725 (defvar *session* nil)
 726
 727 ;;; The debugger itself tries to acquire the session lock, don't let
 728 ;;; funny situations (like getting a sigint while holding the session
 729 ;;; lock) occur. At the same time we need to allow interrupts while
 730 ;;; *waiting* for the session lock for things like GET-FOREGROUND to
 731 ;;; be interruptible.
 732 ;;;
 733 ;;; Take care: we sometimes need to obtain the session lock while
 734 ;;; holding on to *ALL-THREADS-LOCK*, so we must _never_ obtain it
 735 ;;; _after_ getting a session lock! (Deadlock risk.)
 736 ;;;
 737 ;;; FIXME: It would be good to have ordered locks to ensure invariants
 738 ;;; like the above.
 739 (defmacro with-session-lock ((session) &body body)
 740   `(with-system-mutex ((session-lock ,session) :allow-with-interrupts t)
 741      ,@body))
 742
 743 (defun new-session ()
 744   (make-session :threads (list *current-thread*)
 745                 :interactive-threads (list *current-thread*)))
 746
 747 (defun init-job-control ()
 748   (/show0 "Entering INIT-JOB-CONTROL")
 749   (setf *session* (new-session))
 750   (/show0 "Exiting INIT-JOB-CONTROL"))
 751
 752 (defun %delete-thread-from-session (thread session)
 753   (with-session-lock (session)
 754     (setf (session-threads session)
 755           (delete thread (session-threads session))
 756           (session-interactive-threads session)
 757           (delete thread (session-interactive-threads session)))))
 758
 759 (defun call-with-new-session (fn)
 760   (%delete-thread-from-session *current-thread* *session*)
 761   (let ((*session* (new-session)))
 762     (funcall fn)))
 763
 764 (defmacro with-new-session (args &body forms)
 765   (declare (ignore args))               ;for extensibility
 766   (sb!int:with-unique-names (fb-name)
 767     `(labels ((,fb-name () ,@forms))
 768       (call-with-new-session (function ,fb-name)))))
 769
 770 ;;; Remove thread from its session, if it has one.
 771 #!+sb-thread
 772 (defun handle-thread-exit (thread)
 773   (/show0 "HANDLING THREAD EXIT")
 774   ;; Lisp-side cleanup
 775   (with-all-threads-lock
 776     (setf (thread-%alive-p thread) nil)
 777     (setf (thread-os-thread thread) nil)
 778     (setq *all-threads* (delete thread *all-threads*))
 779     (when *session*
 780       (%delete-thread-from-session thread *session*)))
 781   #!+sb-lutex
 782   (without-gcing
 783     (/show0 "FREEING MUTEX LUTEX")
 784     (with-lutex-address (lutex (mutex-lutex (thread-interruptions-lock thread)))
 785       (%lutex-destroy lutex))))
 786
 787 (defun terminate-session ()
 788   #!+sb-doc
 789   "Kill all threads in session except for this one.  Does nothing if current
 790 thread is not the foreground thread."
 791   ;; FIXME: threads created in other threads may escape termination
 792   (let ((to-kill
 793          (with-session-lock (*session*)
 794            (and (eq *current-thread*
 795                     (car (session-interactive-threads *session*)))
 796                 (session-threads *session*)))))
 797     ;; do the kill after dropping the mutex; unwind forms in dying
 798     ;; threads may want to do session things
 799     (dolist (thread to-kill)
 800       (unless (eq thread *current-thread*)
 801         ;; terminate the thread but don't be surprised if it has
 802         ;; exited in the meantime
 803         (handler-case (terminate-thread thread)
 804           (interrupt-thread-error ()))))))
 805
 806 ;;; called from top of invoke-debugger
 807 (defun debugger-wait-until-foreground-thread (stream)
 808   "Returns T if thread had been running in background, NIL if it was
 809 interactive."
 810   (declare (ignore stream))
 811   #!-sb-thread nil
 812   #!+sb-thread
 813   (prog1
 814       (with-session-lock (*session*)
 815         (not (member *current-thread*
 816                      (session-interactive-threads *session*))))
 817     (get-foreground)))
 818
 819 (defun get-foreground ()
 820   #!-sb-thread t
 821   #!+sb-thread
 822   (let ((was-foreground t))
 823     (loop
 824      (/show0 "Looping in GET-FOREGROUND")
 825      (with-session-lock (*session*)
 826        (let ((int-t (session-interactive-threads *session*)))
 827          (when (eq (car int-t) *current-thread*)
 828            (unless was-foreground
 829              (format *query-io* "Resuming thread ~A~%" *current-thread*))
 830            (return-from get-foreground t))
 831          (setf was-foreground nil)
 832          (unless (member *current-thread* int-t)
 833            (setf (cdr (last int-t))
 834                  (list *current-thread*)))
 835          (condition-wait
 836           (session-interactive-threads-queue *session*)
 837           (session-lock *session*)))))))
 838
 839 (defun release-foreground (&optional next)
 840   #!+sb-doc
 841   "Background this thread.  If NEXT is supplied, arrange for it to
 842 have the foreground next."
 843   #!-sb-thread (declare (ignore next))
 844   #!-sb-thread nil
 845   #!+sb-thread
 846   (with-session-lock (*session*)
 847     (when (rest (session-interactive-threads *session*))
 848       (setf (session-interactive-threads *session*)
 849             (delete *current-thread* (session-interactive-threads *session*))))
 850     (when next
 851       (setf (session-interactive-threads *session*)
 852             (list* next
 853                    (delete next (session-interactive-threads *session*)))))
 854     (condition-broadcast (session-interactive-threads-queue *session*))))
 855
 856 (defun foreground-thread ()
 857   (car (session-interactive-threads *session*)))
 858
 859 (defun make-listener-thread (tty-name)
 860   (assert (probe-file tty-name))
 861   (let* ((in (sb!unix:unix-open (namestring tty-name) sb!unix:o_rdwr #o666))
 862          (out (sb!unix:unix-dup in))
 863          (err (sb!unix:unix-dup in)))
 864     (labels ((thread-repl ()
 865                (sb!unix::unix-setsid)
 866                (let* ((sb!impl::*stdin*
 867                        (make-fd-stream in :input t :buffering :line
 868                                        :dual-channel-p t))
 869                       (sb!impl::*stdout*
 870                        (make-fd-stream out :output t :buffering :line
 871                                               :dual-channel-p t))
 872                       (sb!impl::*stderr*
 873                        (make-fd-stream err :output t :buffering :line
 874                                               :dual-channel-p t))
 875                       (sb!impl::*tty*
 876                        (make-fd-stream err :input t :output t
 877                                               :buffering :line
 878                                               :dual-channel-p t))
 879                       (sb!impl::*descriptor-handlers* nil))
 880                  (with-new-session ()
 881                    (unwind-protect
 882                         (sb!impl::toplevel-repl nil)
 883                      (sb!int:flush-standard-output-streams))))))
 884       (make-thread #'thread-repl))))
 885 \f
 886
 887 ;;;; The beef
 888
 889 (defun make-thread (function &key name)
 890   #!+sb-doc
 891   "Create a new thread of NAME that runs FUNCTION. When the function
 892 returns the thread exits. The return values of FUNCTION are kept
 893 around and can be retrieved by JOIN-THREAD."
 894   #!-sb-thread (declare (ignore function name))
 895   #!-sb-thread (error "Not supported in unithread builds.")
 896   #!+sb-thread
 897   (let* ((thread (%make-thread :name name))
 898          (setup-sem (make-semaphore :name "Thread setup semaphore"))
 899          (real-function (coerce function 'function))
 900          (initial-function
 901           (named-lambda initial-thread-function ()
 902             ;; In time we'll move some of the binding presently done in C
 903             ;; here too.
 904             ;;
 905             ;; KLUDGE: Here we have a magic list of variables that are
 906             ;; not thread-safe for one reason or another.  As people
 907             ;; report problems with the thread safety of certain
 908             ;; variables, (e.g. "*print-case* in multiple threads
 909             ;; broken", sbcl-devel 2006-07-14), we add a few more
 910             ;; bindings here.  The Right Thing is probably some variant
 911             ;; of Allegro's *cl-default-special-bindings*, as that is at
 912             ;; least accessible to users to secure their own libraries.
 913             ;;   --njf, 2006-07-15
 914             ;;
 915             ;; As it is, this lambda must not cons until we are ready
 916             ;; to run GC. Be very careful.
 917             (let* ((*current-thread* thread)
 918                    (*restart-clusters* nil)
 919                    (*handler-clusters* (sb!kernel::initial-handler-clusters))
 920                    (*condition-restarts* nil)
 921                    (sb!impl::*deadline* nil)
 922                    (sb!impl::*step-out* nil)
 923                    ;; internal printer variables
 924                    (sb!impl::*previous-case* nil)
 925                    (sb!impl::*previous-readtable-case* nil)
 926                    (sb!impl::*internal-symbol-output-fun* nil)
 927                    (sb!impl::*descriptor-handlers* nil)) ; serve-event
 928               ;; Binding from C
 929               (setf sb!vm:*alloc-signal* *default-alloc-signal*)
 930               (setf (thread-os-thread thread) (current-thread-os-thread))
 931               (with-mutex ((thread-result-lock thread))
 932                 (with-all-threads-lock
 933                   (push thread *all-threads*))
 934                 (with-session-lock (*session*)
 935                   (push thread (session-threads *session*)))
 936                 (setf (thread-%alive-p thread) t)
 937                 (signal-semaphore setup-sem)
 938                 ;; can't use handling-end-of-the-world, because that flushes
 939                 ;; output streams, and we don't necessarily have any (or we
 940                 ;; could be sharing them)
 941                 (catch 'sb!impl::toplevel-catcher
 942                   (catch 'sb!impl::%end-of-the-world
 943                     (with-simple-restart
 944                         (terminate-thread
 945                          (format nil
 946                                  "~~@<Terminate this thread (~A)~~@:>"
 947                                  *current-thread*))
 948                       (without-interrupts
 949                         (unwind-protect
 950                              (with-local-interrupts
 951                                ;; Now that most things have a chance
 952                                ;; to work properly without messing up
 953                                ;; other threads, it's time to enable
 954                                ;; signals.
 955                                (sb!unix::unblock-deferrable-signals)
 956                                (setf (thread-result thread)
 957                                      (cons t
 958                                            (multiple-value-list
 959                                             (funcall real-function))))
 960                                ;; Try to block deferrables. An
 961                                ;; interrupt may unwind it, but for a
 962                                ;; normal exit it prevents interrupt
 963                                ;; loss.
 964                                (block-deferrable-signals))
 965                           ;; We're going down, can't handle interrupts
 966                           ;; sanely anymore. GC remains enabled.
 967                           (block-deferrable-signals)
 968                           ;; We don't want to run interrupts in a dead
 969                           ;; thread when we leave WITHOUT-INTERRUPTS.
 970                           ;; This potentially causes important
 971                           ;; interupts to be lost: SIGINT comes to
 972                           ;; mind.
 973                           (setq *interrupt-pending* nil)
 974                           (handle-thread-exit thread))))))))
 975             (values))))
 976     ;; If the starting thread is stopped for gc before it signals the
 977     ;; semaphore then we'd be stuck.
 978     (assert (not *gc-inhibit*))
 979     ;; Keep INITIAL-FUNCTION pinned until the child thread is
 980     ;; initialized properly. Wrap the whole thing in
 981     ;; WITHOUT-INTERRUPTS because we pass INITIAL-FUNCTION to another
 982     ;; thread.
 983     (without-interrupts
 984       (with-pinned-objects (initial-function)
 985         (let ((os-thread
 986                (%create-thread
 987                 (get-lisp-obj-address initial-function))))
 988           (when (zerop os-thread)
 989             (error "Can't create a new thread"))
 990           (wait-on-semaphore setup-sem)
 991           thread)))))
 992
 993 (defun join-thread (thread &key (default nil defaultp))
 994   #!+sb-doc
 995   "Suspend current thread until THREAD exits. Returns the result
 996 values of the thread function. If the thread does not exit normally,
 997 return DEFAULT if given or else signal JOIN-THREAD-ERROR."
 998   (with-system-mutex ((thread-result-lock thread) :allow-with-interrupts t)
 999     (cond ((car (thread-result thread))
1000            (return-from join-thread
1001              (values-list (cdr (thread-result thread)))))
1002           (defaultp
1003            (return-from join-thread default))))
1004   (error 'join-thread-error :thread thread))
1005
1006 (defun destroy-thread (thread)
1007   #!+sb-doc
1008   "Deprecated. Same as TERMINATE-THREAD."
1009   (terminate-thread thread))
1010
1011 (defmacro with-interruptions-lock ((thread) &body body)
1012   `(with-system-mutex ((thread-interruptions-lock ,thread))
1013      ,@body))
1014
1015 ;;; Called from the signal handler.
1016 #!-win32
1017 (defun run-interruption ()
1018   (let ((interruption (with-interruptions-lock (*current-thread*)
1019                         (pop (thread-interruptions *current-thread*)))))
1020     ;; If there is more to do, then resignal and let the normal
1021     ;; interrupt deferral mechanism take care of the rest. From the
1022     ;; OS's point of view the signal we are in the handler for is no
1023     ;; longer pending, so the signal will not be lost.
1024     (when (thread-interruptions *current-thread*)
1025       (kill-safely (thread-os-thread *current-thread*) sb!unix:sigpipe))
1026     (when interruption
1027       (funcall interruption))))
1028
1029 (defun interrupt-thread (thread function)
1030   #!+sb-doc
1031   "Interrupt the live THREAD and make it run FUNCTION. A moderate
1032 degree of care is expected for use of INTERRUPT-THREAD, due to its
1033 nature: if you interrupt a thread that was holding important locks
1034 then do something that turns out to need those locks, you probably
1035 won't like the effect. FUNCTION runs with interrupts disabled, but
1036 WITH-INTERRUPTS is allowed in it. Keep in mind that many things may
1037 enable interrupts (GET-MUTEX when contended, for instance) so the
1038 first thing to do is usually a WITH-INTERRUPTS or a
1039 WITHOUT-INTERRUPTS. Within a thread interrupts are queued, they are
1040 run in same the order they were sent."
1041   #!+win32
1042   (declare (ignore thread))
1043   #!+win32
1044   (with-interrupt-bindings
1045     (with-interrupts (funcall function)))
1046   #!-win32
1047   (let ((os-thread (thread-os-thread thread)))
1048     (cond ((not os-thread)
1049            (error 'interrupt-thread-error :thread thread))
1050           (t
1051            (with-interruptions-lock (thread)
1052              ;; Append to the end of the interruptions queue. It's
1053              ;; O(N), but it does not hurt to slow interruptors down a
1054              ;; bit when the queue gets long.
1055              (setf (thread-interruptions thread)
1056                    (append (thread-interruptions thread)
1057                            (list (lambda ()
1058                                    (without-interrupts
1059                                      (allow-with-interrupts
1060                                        (funcall function))))))))
1061            (when (minusp (kill-safely os-thread sb!unix:sigpipe))
1062              (error 'interrupt-thread-error :thread thread))))))
1063
1064 (defun terminate-thread (thread)
1065   #!+sb-doc
1066   "Terminate the thread identified by THREAD, by causing it to run
1067 SB-EXT:QUIT - the usual cleanup forms will be evaluated"
1068   (interrupt-thread thread 'sb!ext:quit))
1069
1070 (define-alien-routine "thread_yield" int)
1071
1072 #!+sb-doc
1073 (setf (fdocumentation 'thread-yield 'function)
1074       "Yield the processor to other threads.")
1075
1076 ;;; internal use only.  If you think you need to use these, either you
1077 ;;; are an SBCL developer, are doing something that you should discuss
1078 ;;; with an SBCL developer first, or are doing something that you
1079 ;;; should probably discuss with a professional psychiatrist first
1080 #!+sb-thread
1081 (progn
1082   (defun %thread-sap (thread)
1083     (let ((thread-sap (alien-sap (extern-alien "all_threads" (* t))))
1084           (target (thread-os-thread thread)))
1085       (loop
1086         (when (sap= thread-sap (int-sap 0)) (return nil))
1087         (let ((os-thread (sap-ref-word thread-sap
1088                                        (* sb!vm:n-word-bytes
1089                                           sb!vm::thread-os-thread-slot))))
1090           (when (= os-thread target) (return thread-sap))
1091           (setf thread-sap
1092                 (sap-ref-sap thread-sap (* sb!vm:n-word-bytes
1093                                            sb!vm::thread-next-slot)))))))
1094
1095   (defun %symbol-value-in-thread (symbol thread)
1096     ;; Prevent the thread from dying completely while we look for the TLS
1097     ;; area...
1098     (with-all-threads-lock
1099       (loop
1100         (if (thread-alive-p thread)
1101             (let* ((epoch sb!kernel::*gc-epoch*)
1102                    (offset (* sb!vm:n-word-bytes
1103                               (sb!vm::symbol-tls-index symbol)))
1104                    (tl-val (sap-ref-word (%thread-sap thread) offset)))
1105               (cond ((zerop offset)
1106                      (return (values nil :no-tls-value)))
1107                     ((or (eql tl-val sb!vm:no-tls-value-marker-widetag)
1108                          (eql tl-val sb!vm:unbound-marker-widetag))
1109                      (return (values nil :unbound-in-thread)))
1110                     (t
1111                      (multiple-value-bind (obj ok) (make-lisp-obj tl-val nil)
1112                        ;; The value we constructed may be invalid if a GC has
1113                        ;; occurred. That is harmless, though, since OBJ is
1114                        ;; either in a register or on stack, and we are
1115                        ;; conservative on both on GENCGC -- so a bogus object
1116                        ;; is safe here as long as we don't return it. If we
1117                        ;; ever port threads to a non-conservative GC we must
1118                        ;; pin the TL-VAL address before constructing OBJ, or
1119                        ;; make WITH-ALL-THREADS-LOCK imply WITHOUT-GCING.
1120                        ;;
1121                        ;; The reason we don't just rely on TL-VAL pinning the
1122                        ;; object is that the call to MAKE-LISP-OBJ may cause
1123                        ;; bignum allocation, at which point TL-VAL might not
1124                        ;; be alive anymore -- hence the epoch check.
1125                        (when (eq epoch sb!kernel::*gc-epoch*)
1126                          (if ok
1127                              (return (values obj :ok))
1128                              (return (values obj :invalid-tls-value))))))))
1129             (return (values nil :thread-dead))))))
1130
1131   (defun %set-symbol-value-in-thread (symbol thread value)
1132     (with-pinned-objects (value)
1133       ;; Prevent the thread from dying completely while we look for the TLS
1134       ;; area...
1135       (with-all-threads-lock
1136         (if (thread-alive-p thread)
1137             (let ((offset (* sb!vm:n-word-bytes
1138                              (sb!vm::symbol-tls-index symbol))))
1139               (cond ((zerop offset)
1140                      (values nil :no-tls-value))
1141                     (t
1142                      (setf (sap-ref-word (%thread-sap thread) offset)
1143                            (get-lisp-obj-address value))
1144                      (values value :ok))))
1145             (values nil :thread-dead))))))
1146
1147 (defun symbol-value-in-thread (symbol thread &optional (errorp t))
1148   "Return the local value of SYMBOL in THREAD, and a secondary value of T
1149 on success.
1150
1151 If the value cannot be retrieved (because the thread has exited or because it
1152 has no local binding for NAME) and ERRORP is true signals an error of type
1153 SYMBOL-VALUE-IN-THREAD-ERROR; if ERRORP is false returns a primary value of
1154 NIL, and a secondary value of NIL.
1155
1156 Can also be used with SETF to change the thread-local value of SYMBOL.
1157
1158 SYMBOL-VALUE-IN-THREAD is primarily intended as a debugging tool, and not as a
1159 mechanism for inter-thread communication."
1160   (declare (symbol symbol) (thread thread))
1161   #!+sb-thread
1162   (multiple-value-bind (res status) (%symbol-value-in-thread symbol thread)
1163     (if (eq :ok status)
1164         (values res t)
1165         (if errorp
1166             (error 'symbol-value-in-thread-error
1167                    :name symbol
1168                    :thread thread
1169                    :info (list :read status))
1170             (values nil nil))))
1171   #!-sb-thread
1172   (if (boundp symbol)
1173       (values (symbol-value symbol) t)
1174       (if errorp
1175           (error 'symbol-value-in-thread-error
1176                  :name symbol
1177                  :thread thread
1178                  :info (list :read :unbound-in-thread))
1179           (values nil nil))))
1180
1181 (defun (setf symbol-value-in-thread) (value symbol thread &optional (errorp t))
1182   (declare (symbol symbol) (thread thread))
1183   #!+sb-thread
1184   (multiple-value-bind (res status) (%set-symbol-value-in-thread symbol thread value)
1185     (if (eq :ok status)
1186         (values res t)
1187         (if errorp
1188             (error 'symbol-value-in-thread-error
1189                    :name symbol
1190                    :thread thread
1191                    :info (list :write status))
1192             (values nil nil))))
1193   #!-sb-thread
1194   (if (boundp symbol)
1195       (values (setf (symbol-value symbol) value) t)
1196       (if errorp
1197           (error 'symbol-value-in-thread-error
1198                  :name symbol
1199                  :thread thread
1200                  :info (list :write :unbound-in-thread))
1201           (values nil nil))))
1202
1203 (defun sb!vm::locked-symbol-global-value-add (symbol-name delta)
1204   (sb!vm::locked-symbol-global-value-add symbol-name delta))
1205 \f
1206
1207 ;;;; Stepping
1208
1209 (defun thread-stepping ()
1210   (make-lisp-obj
1211    (sap-ref-word (current-thread-sap)
1212                  (* sb!vm::thread-stepping-slot sb!vm:n-word-bytes))))
1213
1214 (defun (setf thread-stepping) (value)
1215   (setf (sap-ref-word (current-thread-sap)
1216                       (* sb!vm::thread-stepping-slot sb!vm:n-word-bytes))
1217         (get-lisp-obj-address value)))