src/code/target-type.lisp

   1 ;;;; type-related stuff which exists only in the target SBCL runtime
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!KERNEL")
  13
  14 (!begin-collecting-cold-init-forms)
  15 \f
  16 ;;; If TYPE is a type that we can do a compile-time test on, then
  17 ;;; return whether the object is of that type as the first value and
  18 ;;; second value true. Otherwise return NIL, NIL.
  19 ;;;
  20 ;;; We give up on unknown types and pick off FUNCTION- and COMPOUND-
  21 ;;; types. For STRUCTURE- types, we require that the type be defined
  22 ;;; in both the current and compiler environments, and that the
  23 ;;; INCLUDES be the same.
  24 ;;;
  25 ;;; KLUDGE: This should probably be a type method instead of a big
  26 ;;; ETYPECASE. But then the type method system should probably be CLOS
  27 ;;; too, and until that happens wedging more stuff into it might be
  28 ;;; messy. So I've left it a big ETYPECASE. -- 2001-03-16
  29 (defun ctypep (obj type)
  30   (declare (type ctype type))
  31   (etypecase type
  32     ((or numeric-type
  33          named-type
  34          member-type
  35          array-type
  36          character-set-type
  37          built-in-classoid
  38          cons-type)
  39      (values (%typep obj type) t))
  40     (classoid
  41      (if (if (csubtypep type (specifier-type 'function))
  42              (funcallable-instance-p obj)
  43              (%instancep obj))
  44          (if (eq (classoid-layout type)
  45                  (info :type :compiler-layout (classoid-name type)))
  46              (values (sb!xc:typep obj type) t)
  47              (values nil nil))
  48          (values nil t)))
  49     (compound-type
  50      (funcall (etypecase type
  51                 (intersection-type #'every/type)
  52                 (union-type #'any/type))
  53               #'ctypep
  54               obj
  55               (compound-type-types type)))
  56     (fun-type
  57      (values (functionp obj) t))
  58     (unknown-type
  59      (values nil nil))
  60     (alien-type-type
  61      (values (alien-typep obj (alien-type-type-alien-type type)) t))
  62     (negation-type
  63      (multiple-value-bind (res win)
  64          (ctypep obj (negation-type-type type))
  65        (if win
  66            (values (not res) t)
  67            (values nil nil))))
  68     (hairy-type
  69      ;; Now the tricky stuff.
  70      (let* ((hairy-spec (hairy-type-specifier type))
  71             (symbol (if (consp hairy-spec) (car hairy-spec) hairy-spec)))
  72        (ecase symbol
  73          (and
  74           (if (atom hairy-spec)
  75               (values t t)
  76               (dolist (spec (cdr hairy-spec) (values t t))
  77                 (multiple-value-bind (res win)
  78                     (ctypep obj (specifier-type spec))
  79                   (unless win (return (values nil nil)))
  80                   (unless res (return (values nil t)))))))
  81          (not
  82           (multiple-value-bind (res win)
  83               (ctypep obj (specifier-type (cadr hairy-spec)))
  84             (if win
  85                 (values (not res) t)
  86                 (values nil nil))))
  87          (satisfies
  88           ;; If the SATISFIES function is not foldable, we cannot answer!
  89           (let* ((form `(,(second hairy-spec) ',obj)))
  90             (multiple-value-bind (ok result)
  91                 (sb!c::constant-function-call-p form nil nil)
  92               (values (not (null result)) ok)))))))))
  93 \f
  94 ;;; Return the layout for an object. This is the basic operation for
  95 ;;; finding out the "type" of an object, and is used for generic
  96 ;;; function dispatch. The standard doesn't seem to say as much as it
  97 ;;; should about what this returns for built-in objects. For example,
  98 ;;; it seems that we must return NULL rather than LIST when X is NIL
  99 ;;; so that GF's can specialize on NULL.
 100 #!-sb-fluid (declaim (inline layout-of))
 101 (defun layout-of (x)
 102   (declare (optimize (speed 3) (safety 0)))
 103   (cond ((%instancep x) (%instance-layout x))
 104         ((funcallable-instance-p x) (%funcallable-instance-layout x))
 105         ((null x)
 106          ;; Note: was #.((CLASS-LAYOUT (SB!XC:FIND-CLASS 'NULL))).
 107          ;; I (WHN 19990209) replaced this with an expression evaluated at
 108          ;; run time in order to make it easier to build the cross-compiler.
 109          ;;
 110          ;; KLUDGE: Since there's a DEFTRANSFORM for FIND-CLASSOID on
 111          ;; constant names which creates non-cold-loadable code, we
 112          ;; can't just use (CLASSOID-LAYOUT (FIND-CLASSOID 'NULL))
 113          ;; here. The original (WHN 19991004) solution was to locally
 114          ;; notinline FIND-CLASSOID. However, the full call to
 115          ;; FIND-CLASSOID caused suboptimal register allocation in PCL
 116          ;; dfuns. So instead we now use a special variable which is
 117          ;; initialized during cold init. -- JES, 2006-07-04
 118          *null-classoid-layout*)
 119         (t (svref *built-in-class-codes* (widetag-of x)))))
 120
 121 #!-sb-fluid (declaim (inline classoid-of))
 122 (defun classoid-of (object)
 123   #!+sb-doc
 124   "Return the class of the supplied object, which may be any Lisp object, not
 125    just a CLOS STANDARD-OBJECT."
 126   (layout-classoid (layout-of object)))
 127 \f
 128 ;;;; miscellaneous interfaces
 129
 130 ;;; Clear memoization of all type system operations that can be
 131 ;;; altered by type definition/redefinition.
 132 ;;;
 133 (defun clear-type-caches ()
 134   ;; FIXME: We would like to differentiate between different cache
 135   ;; kinds, but at the moment all our caches pretty much are type
 136   ;; caches.
 137   (drop-all-hash-caches)
 138   (values))
 139
 140 ;;; This is like TYPE-OF, only we return a CTYPE structure instead of
 141 ;;; a type specifier, and we try to return the type most useful for
 142 ;;; type checking, rather than trying to come up with the one that the
 143 ;;; user might find most informative.
 144 (declaim (ftype (function (t) ctype) ctype-of))
 145 (defun-cached (ctype-of
 146                :hash-function (lambda (x) (logand (sxhash x) #x1FF))
 147                :hash-bits 9
 148                :init-wrapper !cold-init-forms)
 149               ((x eq))
 150   (typecase x
 151     (function
 152      (if (funcallable-instance-p x)
 153          (classoid-of x)
 154          (specifier-type (sb!impl::%fun-type x))))
 155     (symbol
 156      (make-member-type :members (list x)))
 157     (number
 158      (ctype-of-number x))
 159     (array
 160      (let ((etype (specifier-type (array-element-type x))))
 161        (make-array-type :dimensions (array-dimensions x)
 162                         :complexp (not (typep x 'simple-array))
 163                         :element-type etype
 164                         :specialized-element-type etype)))
 165     (cons
 166      (make-cons-type *universal-type* *universal-type*))
 167     (character
 168      (specifier-type 'character))
 169     (t
 170      (classoid-of x))))
 171 \f
 172 (!defun-from-collected-cold-init-forms !target-type-cold-init)