src/code/timer.lisp

   1 ;;;; a timer facility based heavily on the timer package by Zach Beane
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 ;;; Heap (for the priority queue)
  15
  16 (declaim (inline heap-parent heap-left heap-right))
  17
  18 (defun heap-parent (i)
  19   (ash i -1))
  20
  21 (defun heap-left (i)
  22   (1+ (ash i 1)))
  23
  24 (defun heap-right (i)
  25   (+ 2 (ash i 1)))
  26
  27 (defun heapify (heap start &key (key #'identity) (test #'>=))
  28   (declare (function key test))
  29   (flet ((key (obj) (funcall key obj))
  30          (ge (i j) (funcall test i j)))
  31     (let ((l (heap-left start))
  32           (r (heap-right start))
  33           (size (length heap))
  34           largest)
  35       (setf largest (if (and (< l size)
  36                              (not (ge (key (aref heap start))
  37                                       (key (aref heap l)))))
  38                         l
  39                         start))
  40       (when (and (< r size)
  41                  (not (ge (key (aref heap largest))
  42                           (key (aref heap r)))))
  43         (setf largest r))
  44       (when (/= largest start)
  45         (rotatef (aref heap largest) (aref heap start))
  46         (heapify heap largest :key key :test test)))
  47     heap))
  48
  49 (defun heap-insert (heap new-item &key (key #'identity) (test #'>=))
  50   (declare (function key test))
  51   (flet ((key (obj) (funcall key obj))
  52          (ge (i j) (funcall test i j)))
  53     (vector-push-extend nil heap)
  54     (loop for i = (1- (length heap)) then parent-i
  55           for parent-i = (heap-parent i)
  56           while (and (> i 0)
  57                      (not (ge (key (aref heap parent-i))
  58                               (key new-item))))
  59           do (setf (aref heap i) (aref heap parent-i))
  60           finally (setf (aref heap i) new-item)
  61           (return-from heap-insert i))))
  62
  63 (defun heap-maximum (heap)
  64   (unless (zerop (length heap))
  65     (aref heap 0)))
  66
  67 (defun heap-extract (heap i &key (key #'identity) (test #'>=))
  68   (unless (> (length heap) i)
  69     (error "Heap underflow"))
  70   (prog1
  71       (aref heap i)
  72     (setf (aref heap i) (aref heap (1- (length heap))))
  73     (decf (fill-pointer heap))
  74     (heapify heap i :key key :test test)))
  75
  76 (defun heap-extract-maximum (heap &key (key #'identity) (test #'>=))
  77   (heap-extract heap 0 :key key :test test))
  78
  79 ;;; Priority queue
  80
  81 (defstruct (priority-queue
  82              (:conc-name %pqueue-)
  83              (:constructor %make-priority-queue))
  84   contents
  85   keyfun)
  86
  87 (defun make-priority-queue (&key (key #'identity) (element-type t))
  88   (let ((contents (make-array 100
  89                               :adjustable t
  90                               :fill-pointer 0
  91                               :element-type element-type)))
  92     (%make-priority-queue :keyfun key
  93                           :contents contents)))
  94
  95 (def!method print-object ((object priority-queue) stream)
  96   (print-unreadable-object (object stream :type t :identity t)
  97     (format stream "~[empty~:;~:*~D item~:P~]"
  98             (length (%pqueue-contents object)))))
  99
 100 (defun priority-queue-maximum (priority-queue)
 101   "Return the item in PRIORITY-QUEUE with the largest key."
 102   (symbol-macrolet ((contents (%pqueue-contents priority-queue)))
 103     (unless (zerop (length contents))
 104       (heap-maximum contents))))
 105
 106 (defun priority-queue-extract-maximum (priority-queue)
 107   "Remove and return the item in PRIORITY-QUEUE with the largest key."
 108   (symbol-macrolet ((contents (%pqueue-contents priority-queue))
 109                     (keyfun (%pqueue-keyfun priority-queue)))
 110     (unless (zerop (length contents))
 111       (heap-extract-maximum contents :key keyfun :test #'<=))))
 112
 113 (defun priority-queue-insert (priority-queue new-item)
 114   "Add NEW-ITEM to PRIOIRITY-QUEUE."
 115   (symbol-macrolet ((contents (%pqueue-contents priority-queue))
 116                     (keyfun (%pqueue-keyfun priority-queue)))
 117     (heap-insert contents new-item :key keyfun :test #'<=)))
 118
 119 (defun priority-queue-empty-p (priority-queue)
 120   (zerop (length (%pqueue-contents priority-queue))))
 121
 122 (defun priority-queue-remove (priority-queue item &key (test #'eq))
 123   "Remove and return ITEM from PRIORITY-QUEUE."
 124   (symbol-macrolet ((contents (%pqueue-contents priority-queue))
 125                     (keyfun (%pqueue-keyfun priority-queue)))
 126     (let ((i (position item contents :test test)))
 127       (when i
 128         (heap-extract contents i :key keyfun :test #'<=)
 129         i))))
 130
 131 ;;; thread utility
 132
 133 (defun make-cancellable-interruptor (function)
 134   ;; return a list of two functions: one that does the same as
 135   ;; FUNCTION until the other is called, from when it does nothing.
 136   (let ((mutex (sb!thread:make-mutex))
 137         (cancelled-p nil))
 138     (list
 139      #'(lambda ()
 140          (sb!thread:with-recursive-lock (mutex)
 141            (unless cancelled-p
 142              (funcall function))))
 143      #'(lambda ()
 144          (sb!thread:with-recursive-lock (mutex)
 145            (setq cancelled-p t))))))
 146
 147 ;;; timers
 148
 149 (defstruct (timer
 150              (:conc-name %timer-)
 151              (:constructor %make-timer))
 152   #!+sb-doc
 153   "Timer type. Do not rely on timers being structs as it may change in
 154 future versions."
 155   name
 156   function
 157   expire-time
 158   repeat-interval
 159   (thread nil :type (or sb!thread:thread (member t nil)))
 160   interrupt-function
 161   cancel-function)
 162
 163 (def!method print-object ((timer timer) stream)
 164   (let ((name (%timer-name timer)))
 165     (if name
 166         (print-unreadable-object (timer stream :type t :identity t)
 167           (prin1 name stream))
 168         (print-unreadable-object (timer stream :type t :identity t)
 169           ;; body is empty => there is only one space between type and
 170           ;; identity
 171           ))))
 172
 173 (defun make-timer (function &key name (thread sb!thread:*current-thread*))
 174   #!+sb-doc
 175   "Create a timer object that's when scheduled runs FUNCTION. If
 176 THREAD is a thread then that thread is to be interrupted with
 177 FUNCTION. If THREAD is T then a new thread is created each timer
 178 FUNCTION is run. If THREAD is NIL then FUNCTION can be run in any
 179 thread."
 180   (%make-timer :name name :function function :thread thread))
 181
 182 (defun timer-name (timer)
 183   #!+sb-doc
 184   "Return the name of TIMER."
 185   (%timer-name timer))
 186
 187 (defun timer-scheduled-p (timer &key (delta 0))
 188   #!+sb-doc
 189   "See if TIMER will still need to be triggered after DELTA seconds
 190 from now. For timers with a repeat interval it returns true."
 191   (symbol-macrolet ((expire-time (%timer-expire-time timer))
 192                     (repeat-interval (%timer-repeat-interval timer)))
 193       (or (and repeat-interval (plusp repeat-interval))
 194           (and expire-time
 195                (<= (+ (get-internal-real-time) delta)
 196                    expire-time)))))
 197
 198 ;;; The scheduler
 199
 200 (defvar *scheduler-lock* (sb!thread:make-mutex :name "Scheduler lock"))
 201
 202 (defmacro with-scheduler-lock ((&optional) &body body)
 203   ;; Don't let the SIGALRM handler mess things up.
 204   `(sb!thread::with-system-mutex (*scheduler-lock*)
 205      ,@body))
 206
 207 (defun under-scheduler-lock-p ()
 208   (sb!thread:holding-mutex-p *scheduler-lock*))
 209
 210 (defparameter *schedule* (make-priority-queue :key #'%timer-expire-time))
 211
 212 (defun peek-schedule ()
 213   (priority-queue-maximum *schedule*))
 214
 215 (defun time-left (timer)
 216   (- (%timer-expire-time timer) (get-internal-real-time)))
 217
 218 ;;; real time conversion
 219
 220 (defun delta->real (delta)
 221   (floor (* delta internal-time-units-per-second)))
 222
 223 ;;; Public interface
 224
 225 (defun %schedule-timer (timer)
 226   (let ((changed-p nil)
 227         (old-position (priority-queue-remove *schedule* timer)))
 228     ;; Make sure interruptors are cancelled even if this timer was
 229     ;; scheduled again since our last attempt.
 230     (when old-position
 231       (funcall (%timer-cancel-function timer)))
 232     (when (eql 0 old-position)
 233       (setq changed-p t))
 234     (when (zerop (priority-queue-insert *schedule* timer))
 235       (setq changed-p t))
 236     (setf (values (%timer-interrupt-function timer)
 237                   (%timer-cancel-function timer))
 238           (values-list (make-cancellable-interruptor
 239                         (%timer-function timer))))
 240     (when changed-p
 241       (set-system-timer)))
 242   (values))
 243
 244 (defun schedule-timer (timer time &key repeat-interval absolute-p)
 245   #!+sb-doc
 246   "Schedule TIMER to be triggered at TIME. If ABSOLUTE-P then TIME is
 247 universal time, but non-integral values are also allowed, else TIME is
 248 measured as the number of seconds from the current time. If
 249 REPEAT-INTERVAL is given, TIMER is automatically rescheduled upon
 250 expiry."
 251   ;; CANCEL-FUNCTION may block until all interruptors finish, let's
 252   ;; try to cancel without the scheduler lock first.
 253   (when (%timer-cancel-function timer)
 254     (funcall (%timer-cancel-function timer)))
 255   (with-scheduler-lock ()
 256     (setf (%timer-expire-time timer) (+ (get-internal-real-time)
 257                                         (delta->real
 258                                          (if absolute-p
 259                                              (- time (get-universal-time))
 260                                              time)))
 261           (%timer-repeat-interval timer) (if repeat-interval
 262                                              (delta->real repeat-interval)
 263                                              nil))
 264     (%schedule-timer timer)))
 265
 266 (defun unschedule-timer (timer)
 267   #!+sb-doc
 268   "Cancel TIMER. Once this function returns it is guaranteed that
 269 TIMER shall not be triggered again and there are no unfinished
 270 triggers."
 271   (let ((cancel-function (%timer-cancel-function timer)))
 272     (when cancel-function
 273       (funcall cancel-function)))
 274   (with-scheduler-lock ()
 275     (setf (%timer-expire-time timer) nil
 276           (%timer-repeat-interval timer) nil)
 277     (let ((old-position (priority-queue-remove *schedule* timer)))
 278       (when old-position
 279         (funcall (%timer-cancel-function timer)))
 280       (when (eql 0 old-position)
 281         (set-system-timer))))
 282   (values))
 283
 284 (defun list-all-timers ()
 285   #!+sb-doc
 286   "Return a list of all timers in the system."
 287   (with-scheduler-lock ()
 288     (concatenate 'list (%pqueue-contents *schedule*))))
 289
 290 ;;; Not public, but related
 291
 292 (defun reschedule-timer (timer)
 293   (let ((thread (%timer-thread timer)))
 294     (if (and (sb!thread::thread-p thread) (not (sb!thread:thread-alive-p thread)))
 295         (unschedule-timer timer)
 296         (with-scheduler-lock ()
 297           (setf (%timer-expire-time timer) (+ (get-internal-real-time)
 298                                               (%timer-repeat-interval timer)))
 299           (%schedule-timer timer)))))
 300
 301 ;;; Expiring timers
 302
 303 (defun real-time->sec-and-usec(time)
 304   (if (minusp time)
 305       (list 0 1)
 306       (multiple-value-bind (s u) (floor time internal-time-units-per-second)
 307         (setf u (floor (* (/ u internal-time-units-per-second) 1000000)))
 308         (if (= 0 s u)
 309             ;; 0 0 means "shut down the timer" for setitimer
 310             (list 0 1)
 311             (list s u)))))
 312
 313 (defun set-system-timer ()
 314   (assert (under-scheduler-lock-p))
 315   (let ((next-timer (peek-schedule)))
 316     (if next-timer
 317         (let ((delta (- (%timer-expire-time next-timer)
 318                         (get-internal-real-time))))
 319           (apply #'sb!unix:unix-setitimer
 320                  :real 0 0 (real-time->sec-and-usec delta)))
 321         (sb!unix:unix-setitimer :real 0 0 0 0))))
 322
 323 (defun run-timer (timer)
 324   (symbol-macrolet ((function (%timer-function timer))
 325                     (repeat-interval (%timer-repeat-interval timer))
 326                     (thread (%timer-thread timer)))
 327     (when repeat-interval
 328       (reschedule-timer timer))
 329     (cond ((null thread)
 330            (funcall function))
 331           ((eq t thread)
 332            (sb!thread:make-thread function))
 333           (t
 334            (handler-case
 335                (sb!thread:interrupt-thread thread function)
 336              (sb!thread:interrupt-thread-error (c)
 337                (declare (ignore c))
 338                (warn "Timer ~S failed to interrupt thread ~S."
 339                      timer thread)))))))
 340
 341 ;; Called from the signal handler.
 342 (defun run-expired-timers ()
 343   (unwind-protect
 344        (with-interrupts
 345          (let (timer)
 346            (loop
 347             (with-scheduler-lock ()
 348               (setq timer (peek-schedule))
 349               (unless (and timer
 350                            (> (get-internal-real-time)
 351                               (%timer-expire-time timer)))
 352                 (return-from run-expired-timers nil))
 353               (assert (eq timer (priority-queue-extract-maximum *schedule*))))
 354             ;; run the timer without the lock
 355             (run-timer timer))))
 356     (with-scheduler-lock ()
 357       (set-system-timer))))
 358
 359 (defmacro sb!ext:with-timeout (expires &body body)
 360   #!+sb-doc
 361   "Execute the body, asynchronously interrupting it and signalling a TIMEOUT
 362 condition after at least EXPIRES seconds have passed.
 363
 364 Note that it is never safe to unwind from an asynchronous condition. Consider:
 365
 366   (defun call-with-foo (function)
 367     (let (foo)
 368       (unwind-protect
 369          (progn
 370            (setf foo (get-foo))
 371            (funcall function foo))
 372        (when foo
 373          (release-foo foo)))))
 374
 375 If TIMEOUT occurs after GET-FOO has executed, but before the assignment, then
 376 RELEASE-FOO will be missed. While individual sites like this can be made proof
 377 against asynchronous unwinds, this doesn't solve the fundamental issue, as all
 378 the frames potentially unwound through need to be proofed, which includes both
 379 system and application code -- and in essence proofing everything will make
 380 the system uninterruptible."
 381   (with-unique-names (timer)
 382     ;; FIXME: a temporary compatibility workaround for CLX, if unsafe
 383     ;; unwinds are handled revisit it.
 384     `(if (> ,expires 0)
 385          (let ((,timer (make-timer (lambda ()
 386                                      (cerror "Continue" 'sb!ext::timeout)))))
 387            (schedule-timer ,timer ,expires)
 388            (unwind-protect
 389                 (progn ,@body)
 390              (unschedule-timer ,timer)))
 391          (progn ,@body))))