src/code/toplevel.lisp

   1 ;;;; stuff related to the toplevel read-eval-print loop, plus some
   2 ;;;; other miscellaneous functions that we don't have any better place
   3 ;;;; for
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!IMPL")
  15 \f
  16 ;;;; magic specials initialized by GENESIS
  17
  18 ;;; FIXME: The DEFVAR here is redundant with the (DECLAIM (SPECIAL ..))
  19 ;;; of all static symbols in early-impl.lisp.
  20 (progn
  21   (defvar sb!vm::*current-catch-block*)
  22   (defvar sb!vm::*current-unwind-protect-block*)
  23   #!+hpux (defvar sb!vm::*c-lra*)
  24   (defvar *free-interrupt-context-index*))
  25 \f
  26 ;;; specials initialized by !COLD-INIT
  27
  28 ;;; FIXME: These could be converted to DEFVARs.
  29 (declaim (special #!+(or x86 x86-64) *pseudo-atomic-bits*
  30                   *allow-with-interrupts*
  31                   *interrupts-enabled*
  32                   *interrupt-pending*
  33                   *type-system-initialized*))
  34
  35 (defvar *cold-init-complete-p*)
  36
  37 ;;; counts of nested errors (with internal errors double-counted)
  38 (defvar *maximum-error-depth*)
  39 (defvar *current-error-depth*)
  40
  41 ;;;; default initfiles
  42
  43 (defun sysinit-pathname ()
  44   (or (let ((sbcl-homedir (sbcl-homedir-pathname)))
  45         (when sbcl-homedir
  46           (probe-file (merge-pathnames "sbclrc" sbcl-homedir))))
  47       #!+win32
  48       (merge-pathnames "sbcl\\sbclrc"
  49                        (sb!win32::get-folder-pathname
  50                         sb!win32::csidl_common_appdata))
  51       #!-win32
  52       "/etc/sbclrc"))
  53
  54 (defun userinit-pathname ()
  55   (merge-pathnames ".sbclrc" (user-homedir-pathname)))
  56
  57 (defvar *sysinit-pathname-function* #'sysinit-pathname
  58   #!+sb-doc
  59   "Designator for a function of zero arguments called to obtain a
  60 pathname designator for the default sysinit file, or NIL. If the
  61 function returns NIL, no sysinit file is used unless one has been
  62 specified on the command-line.")
  63
  64 (defvar *userinit-pathname-function* #'userinit-pathname
  65   #!+sb-doc
  66   "Designator for a function of zero arguments called to obtain a
  67 pathname designator or a stream for the default userinit file, or NIL.
  68 If the function returns NIL, no userinit file is used unless one has
  69 been specified on the command-line.")
  70
  71 \f
  72 ;;;; miscellaneous utilities for working with with TOPLEVEL
  73
  74 ;;; Execute BODY in a context where any %END-OF-THE-WORLD (thrown e.g.
  75 ;;; by QUIT) is caught and any final processing and return codes are
  76 ;;; handled appropriately.
  77 (defmacro handling-end-of-the-world (&body body)
  78   (with-unique-names (caught)
  79     `(without-interrupts
  80        (let ((,caught
  81                (catch '%end-of-the-world
  82                  (unwind-protect
  83                       (with-local-interrupts ,@body (quit))
  84                    (handler-case
  85                        (with-local-interrupts
  86                          (call-hooks "exit" *exit-hooks* :on-error :warn))
  87                      (serious-condition ()
  88                        1))))))
  89          ;; If user called QUIT and exit hooks were OK, the status is what it
  90          ;; is -- even eg. streams cannot be flushed anymore. Even if
  91          ;; something goes wrong now, we still report what was asked. We still
  92          ;; want to have %END-OF-THE-WORLD visible, though.
  93          (catch '%end-of-the-world
  94            (handler-case
  95                (unwind-protect
  96                     (progn
  97                       (flush-standard-output-streams)
  98                       (sb!thread::terminate-session))
  99                  (sb!unix:unix-exit ,caught))
 100              (serious-condition ())))))))
 101 \f
 102 ;;;; working with *CURRENT-ERROR-DEPTH* and *MAXIMUM-ERROR-DEPTH*
 103
 104 ;;; INFINITE-ERROR-PROTECT is used by ERROR and friends to keep us out
 105 ;;; of hyperspace.
 106 (defmacro infinite-error-protect (&rest forms)
 107   `(unless (infinite-error-protector)
 108      (/show0 "back from INFINITE-ERROR-PROTECTOR")
 109      (let ((*current-error-depth* (1+ *current-error-depth*)))
 110        (/show0 "in INFINITE-ERROR-PROTECT, incremented error depth")
 111        ;; arbitrary truncation
 112        #!+sb-show (sb!debug:backtrace 8)
 113        ,@forms)))
 114
 115 ;;; a helper function for INFINITE-ERROR-PROTECT
 116 (defun infinite-error-protector ()
 117   (/show0 "entering INFINITE-ERROR-PROTECTOR, *CURRENT-ERROR-DEPTH*=..")
 118   (/hexstr *current-error-depth*)
 119   (cond ((not *cold-init-complete-p*)
 120          (%primitive print "Argh! error in cold init, halting")
 121          (%primitive sb!c:halt))
 122         ((or (not (boundp '*current-error-depth*))
 123              (not (realp   *current-error-depth*))
 124              (not (boundp '*maximum-error-depth*))
 125              (not (realp   *maximum-error-depth*)))
 126          (%primitive print "Argh! corrupted error depth, halting")
 127          (%primitive sb!c:halt))
 128         ((> *current-error-depth* *maximum-error-depth*)
 129          (/show0 "*MAXIMUM-ERROR-DEPTH*=..")
 130          (/hexstr *maximum-error-depth*)
 131          (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
 132          (error-error "Help! "
 133                       *current-error-depth*
 134                       " nested errors. "
 135                       "SB-KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 136          t)
 137         (t
 138          (/show0 "returning normally from INFINITE-ERROR-PROTECTOR")
 139          nil)))
 140
 141 ;;; FIXME: I had a badly broken version of INFINITE-ERROR-PROTECTOR at
 142 ;;; one point (shown below), and SBCL cross-compiled it without
 143 ;;; warning about FORMS being undefined. Check whether that problem
 144 ;;; (missing warning) is repeatable in the final system and if so, fix
 145 ;;; it.
 146 #|
 147 (defun infinite-error-protector ()
 148   `(cond ((not *cold-init-complete-p*)
 149           (%primitive print "Argh! error in cold init, halting")
 150           (%primitive sb!c:halt))
 151          ((or (not (boundp '*current-error-depth*))
 152               (not (realp   *current-error-depth*))
 153               (not (boundp '*maximum-error-depth*))
 154               (not (realp   *maximum-error-depth*)))
 155           (%primitive print "Argh! corrupted error depth, halting")
 156           (%primitive sb!c:halt))
 157          ((> *current-error-depth* *maximum-error-depth*)
 158           (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
 159           (error-error "Help! "
 160                        *current-error-depth*
 161                        " nested errors. "
 162                        "SB-KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 163           (progn ,@forms)
 164           t)
 165          (t
 166           (/show0 "in INFINITE-ERROR-PROTECTOR, returning normally")
 167           nil)))
 168 |#
 169 \f
 170 ;;;; miscellaneous external functions
 171
 172 (defun sleep (seconds)
 173   #!+sb-doc
 174   "This function causes execution to be suspended for SECONDS. SECONDS may be
 175 any non-negative real number."
 176   (when (or (not (realp seconds))
 177             (minusp seconds))
 178     (error 'simple-type-error
 179            :format-control "invalid argument to SLEEP: ~S"
 180            :format-arguments (list seconds)
 181            :datum seconds
 182            :expected-type '(real 0)))
 183   #!-win32
 184   (multiple-value-bind (sec nsec)
 185       (if (integerp seconds)
 186           (values seconds 0)
 187           (multiple-value-bind (sec frac)
 188               (truncate seconds)
 189             (values sec (truncate frac 1e-9))))
 190     ;; nanosleep() accepts time_t as the first argument, but on some platforms
 191     ;; it is restricted to 100 million seconds. Maybe someone can actually
 192     ;; have a reason to sleep for over 3 years?
 193     (loop while (> sec (expt 10 8))
 194           do (decf sec (expt 10 8))
 195              (sb!unix:nanosleep (expt 10 8) 0))
 196     (sb!unix:nanosleep sec nsec))
 197   #!+win32
 198   (sb!win32:millisleep (truncate (* seconds 1000)))
 199   nil)
 200 \f
 201 ;;;; the default toplevel function
 202
 203 (defvar / nil
 204   #!+sb-doc
 205   "a list of all the values returned by the most recent top level EVAL")
 206 (defvar //  nil #!+sb-doc "the previous value of /")
 207 (defvar /// nil #!+sb-doc "the previous value of //")
 208 (defvar *   nil #!+sb-doc "the value of the most recent top level EVAL")
 209 (defvar **  nil #!+sb-doc "the previous value of *")
 210 (defvar *** nil #!+sb-doc "the previous value of **")
 211 (defvar +   nil #!+sb-doc "the value of the most recent top level READ")
 212 (defvar ++  nil #!+sb-doc "the previous value of +")
 213 (defvar +++ nil #!+sb-doc "the previous value of ++")
 214 (defvar -   nil #!+sb-doc "the form currently being evaluated")
 215
 216 (defun interactive-eval (form &key (eval #'eval))
 217   #!+sb-doc
 218   "Evaluate FORM, returning whatever it returns and adjusting ***, **, *,
 219 +++, ++, +, ///, //, /, and -."
 220   (setf - form)
 221   (unwind-protect
 222        (let ((results (multiple-value-list (funcall eval form))))
 223          (setf /// //
 224                // /
 225                / results
 226                *** **
 227                ** *
 228                * (car results)))
 229     (setf +++ ++
 230           ++ +
 231           + -))
 232   (unless (boundp '*)
 233     ;; The bogon returned an unbound marker.
 234     ;; FIXME: It would be safer to check every one of the values in RESULTS,
 235     ;; instead of just the first one.
 236     (setf * nil)
 237     (cerror "Go on with * set to NIL."
 238             "EVAL returned an unbound marker."))
 239   (values-list /))
 240
 241 ;;; Flush anything waiting on one of the ANSI Common Lisp standard
 242 ;;; output streams before proceeding.
 243 (defun flush-standard-output-streams ()
 244   (dolist (name '(*debug-io*
 245                   *error-output*
 246                   *query-io*
 247                   *standard-output*
 248                   *trace-output*
 249                   *terminal-io*))
 250     ;; FINISH-OUTPUT may block more easily than FORCE-OUTPUT
 251     (force-output (symbol-value name)))
 252   (values))
 253
 254 (defun process-init-file (specified-pathname kind)
 255   (multiple-value-bind (context default-function)
 256       (ecase kind
 257         (:system
 258          (values "sysinit" *sysinit-pathname-function*))
 259         (:user
 260          (values "userinit" *userinit-pathname-function*)))
 261     (if specified-pathname
 262         (with-open-file (stream (parse-native-namestring specified-pathname)
 263                                 :if-does-not-exist nil)
 264           (if stream
 265               (load-as-source stream :context context)
 266               (cerror "Ignore missing init file"
 267                       "The specified ~A file ~A was not found."
 268                       context specified-pathname)))
 269         (let ((default (funcall default-function)))
 270           (when default
 271             (with-open-file (stream (pathname default) :if-does-not-exist nil)
 272               (when stream
 273                 (load-as-source stream :context context))))))))
 274
 275 (defun process-eval/load-options (options)
 276   (/show0 "handling --eval and --load options")
 277   (flet ((process-1 (cons)
 278            (destructuring-bind (opt . value) cons
 279              (ecase opt
 280                (:eval
 281                 (with-simple-restart (continue "Ignore runtime option --eval ~S."
 282                                                value)
 283                   (multiple-value-bind (expr pos) (read-from-string value)
 284                     (if (eq value (read-from-string value nil value :start pos))
 285                         (eval expr)
 286                         (error "Multiple expressions in --eval option: ~S"
 287                                value)))))
 288                (:load
 289                 (with-simple-restart (continue "Ignore runtime option --load ~S."
 290                                                value)
 291                   (load (native-pathname value))))))
 292            (flush-standard-output-streams)))
 293     (with-simple-restart (abort "Skip rest of --eval and --load options.")
 294       (dolist (option options)
 295         (process-1 option)))))
 296
 297 (defun process-script (script)
 298   (flet ((load-script (stream)
 299            ;; Scripts don't need to be stylish or fast, but silence is usually a
 300            ;; desirable quality...
 301            (handler-bind (((or style-warning compiler-note) #'muffle-warning)
 302                           (stream-error (lambda (e)
 303                                           ;; Shell-style.
 304                                           (when (member (stream-error-stream e)
 305                                                         (list *stdout* *stdin* *stderr*))
 306                                             (quit)))))
 307              ;; Let's not use the *TTY* for scripts, ok? Also, normally we use
 308              ;; synonym streams, but in order to have the broken pipe/eof error
 309              ;; handling right we want to bind them for scripts.
 310              (let ((*terminal-io* (make-two-way-stream *stdin* *stdout*))
 311                    (*debug-io* (make-two-way-stream *stdin* *stderr*))
 312                    (*standard-input* *stdin*)
 313                    (*standard-output* *stdout*)
 314                    (*error-output* *stderr*))
 315                (load stream :verbose nil :print nil)))))
 316     (handling-end-of-the-world
 317       (if (eq t script)
 318           (load-script *stdin*)
 319           (with-open-file (f (native-pathname script) :element-type :default)
 320             (sb!fasl::maybe-skip-shebang-line f)
 321             (load-script f))))))
 322
 323 ;; Errors while processing the command line cause the system to QUIT,
 324 ;; instead of trying to go into the Lisp debugger, because trying to
 325 ;; go into the Lisp debugger would get into various annoying issues of
 326 ;; where we should go after the user tries to return from the
 327 ;; debugger.
 328 (defun startup-error (control-string &rest args)
 329   (format *error-output*
 330           "fatal error before reaching READ-EVAL-PRINT loop: ~%  ~?~%"
 331           control-string
 332           args)
 333   (quit :unix-status 1))
 334
 335 ;;; the default system top level function
 336 (defun toplevel-init ()
 337   (/show0 "entering TOPLEVEL-INIT")
 338   (let ( ;; value of --sysinit option
 339         (sysinit nil)
 340         ;; t if --no-sysinit option given
 341         (no-sysinit nil)
 342         ;; value of --userinit option
 343         (userinit nil)
 344         ;; t if --no-userinit option given
 345         (no-userinit nil)
 346         ;; t if --disable-debugger option given
 347         (disable-debugger nil)
 348         ;; list of (<kind> . <string>) conses representing --eval and --load
 349         ;; options. options. --eval options are stored as strings, so that
 350         ;; they can be passed to READ only after their predecessors have been
 351         ;; EVALed, so that things work when e.g. REQUIRE in one EVAL form
 352         ;; creates a package referred to in the next EVAL form. Storing the
 353         ;; original string also makes for easier debugging.
 354         (reversed-options nil)
 355         ;; Has a --noprint option been seen?
 356         (noprint nil)
 357         ;; Has a --script option been seen?
 358         (script nil)
 359         ;; everything in *POSIX-ARGV* except for argv[0]=programname
 360         (options (rest *posix-argv*)))
 361
 362     (declare (type list options))
 363
 364     (/show0 "done with outer LET in TOPLEVEL-INIT")
 365
 366     ;; FIXME: There are lots of ways for errors to happen around here
 367     ;; (e.g. bad command line syntax, or READ-ERROR while trying to
 368     ;; READ an --eval string). Make sure that they're handled
 369     ;; reasonably.
 370
 371     ;; Process command line options.
 372     (loop while options do
 373          (/show0 "at head of LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 374          (let ((option (first options)))
 375            (flet ((pop-option ()
 376                     (if options
 377                         (pop options)
 378                         (startup-error
 379                          "unexpected end of command line options"))))
 380              (cond ((string= option "--script")
 381                     (pop-option)
 382                     (setf disable-debugger t
 383                           no-userinit t
 384                           no-sysinit t
 385                           script (if options (pop-option) t))
 386                     (return))
 387                    ((string= option "--sysinit")
 388                     (pop-option)
 389                     (if sysinit
 390                         (startup-error "multiple --sysinit options")
 391                         (setf sysinit (pop-option))))
 392                    ((string= option "--no-sysinit")
 393                     (pop-option)
 394                     (setf no-sysinit t))
 395                    ((string= option "--userinit")
 396                     (pop-option)
 397                     (if userinit
 398                         (startup-error "multiple --userinit options")
 399                         (setf userinit (pop-option))))
 400                    ((string= option "--no-userinit")
 401                     (pop-option)
 402                     (setf no-userinit t))
 403                    ((string= option "--eval")
 404                     (pop-option)
 405                     (push (cons :eval (pop-option)) reversed-options))
 406                    ((string= option "--load")
 407                     (pop-option)
 408                     (push (cons :load (pop-option)) reversed-options))
 409                    ((string= option "--noprint")
 410                     (pop-option)
 411                     (setf noprint t))
 412                    ((string= option "--disable-debugger")
 413                     (pop-option)
 414                     (setf disable-debugger t))
 415                    ((string= option "--end-toplevel-options")
 416                     (pop-option)
 417                     (return))
 418                    (t
 419                     ;; Anything we don't recognize as a toplevel
 420                     ;; option must be the start of user-level
 421                     ;; options.. except that if we encounter
 422                     ;; "--end-toplevel-options" after we gave up
 423                     ;; because we didn't recognize an option as a
 424                     ;; toplevel option, then the option we gave up on
 425                     ;; must have been an error. (E.g. in
 426                     ;;  "sbcl --eval '(a)' --eval'(b)' --end-toplevel-options"
 427                     ;; this test will let us detect that the string
 428                     ;; "--eval(b)" is an error.)
 429                     (if (find "--end-toplevel-options" options
 430                               :test #'string=)
 431                         (startup-error "bad toplevel option: ~S"
 432                                        (first options))
 433                         (return)))))))
 434     (/show0 "done with LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 435
 436     ;; Delete all the options that we processed, so that only
 437     ;; user-level options are left visible to user code.
 438     (setf (rest *posix-argv*) options)
 439
 440     ;; Disable debugger before processing initialization files & co.
 441     (when disable-debugger
 442       (sb!ext:disable-debugger))
 443
 444     ;; Handle initialization files.
 445     (/show0 "handling initialization files in TOPLEVEL-INIT")
 446     ;; This CATCH is needed for the debugger command TOPLEVEL to
 447     ;; work.
 448     (catch 'toplevel-catcher
 449       ;; We wrap all the pre-REPL user/system customized startup
 450       ;; code in a restart.
 451       ;;
 452       ;; (Why not wrap everything, even the stuff above, in this
 453       ;; restart? Errors above here are basically command line
 454       ;; or Unix environment errors, e.g. a missing file or a
 455       ;; typo on the Unix command line, and you don't need to
 456       ;; get into Lisp to debug them, you should just start over
 457       ;; and do it right at the Unix level. Errors below here
 458       ;; are generally errors in user Lisp code, and it might be
 459       ;; helpful to let the user reach the REPL in order to help
 460       ;; figure out what's going on.)
 461       (restart-case
 462           (progn
 463             (unless no-sysinit
 464               (process-init-file sysinit :system))
 465             (unless no-userinit
 466               (process-init-file userinit :user))
 467             (process-eval/load-options (nreverse reversed-options))
 468             (when script
 469               (process-script script)
 470               (bug "PROCESS-SCRIPT returned")))
 471         (abort ()
 472           :report (lambda (s)
 473                     (write-string
 474                      (if script
 475                          ;; In case script calls (enable-debugger)!
 476                          "Abort script, exiting lisp."
 477                          "Skip to toplevel READ/EVAL/PRINT loop.")
 478                      s))
 479           (/show0 "CONTINUEing from pre-REPL RESTART-CASE")
 480           (values))                     ; (no-op, just fall through)
 481         (quit ()
 482           :report "Quit SBCL (calling #'QUIT, killing the process)."
 483           :test (lambda (c) (declare (ignore c)) (not script))
 484           (/show0 "falling through to QUIT from pre-REPL RESTART-CASE")
 485           (quit :unix-status 1))))
 486
 487     ;; one more time for good measure, in case we fell out of the
 488     ;; RESTART-CASE above before one of the flushes in the ordinary
 489     ;; flow of control had a chance to operate
 490     (flush-standard-output-streams)
 491
 492     (/show0 "falling into TOPLEVEL-REPL from TOPLEVEL-INIT")
 493     (toplevel-repl noprint)
 494     ;; (classic CMU CL error message: "You're certainly a clever child.":-)
 495     (critically-unreachable "after TOPLEVEL-REPL")))
 496
 497 ;;; hooks to support customized toplevels like ACL-style toplevel from
 498 ;;; KMR on sbcl-devel 2002-12-21.  Altered by CSR 2003-11-16 for
 499 ;;; threaded operation: altered *REPL-FUN* to *REPL-FUN-GENERATOR*.
 500 (defvar *repl-read-form-fun* #'repl-read-form-fun
 501   #!+sb-doc
 502   "A function of two stream arguments IN and OUT for the toplevel REPL to
 503 call: Return the next Lisp form to evaluate (possibly handling other magic --
 504 like ACL-style keyword commands -- which precede the next Lisp form). The OUT
 505 stream is there to support magic which requires issuing new prompts.")
 506 (defvar *repl-prompt-fun* #'repl-prompt-fun
 507   #!+sb-doc
 508   "A function of one argument STREAM for the toplevel REPL to call: Prompt
 509 the user for input.")
 510 (defvar *repl-fun-generator* (constantly #'repl-fun)
 511   #!+sb-doc
 512   "A function of no arguments returning a function of one argument NOPRINT
 513 that provides the REPL for the system. Assumes that *STANDARD-INPUT* and
 514 *STANDARD-OUTPUT* are set up.")
 515
 516 ;;; read-eval-print loop for the default system toplevel
 517 (defun toplevel-repl (noprint)
 518   (/show0 "entering TOPLEVEL-REPL")
 519   (let ((* nil) (** nil) (*** nil)
 520         (- nil)
 521         (+ nil) (++ nil) (+++ nil)
 522         (/// nil) (// nil) (/ nil))
 523     (/show0 "about to funcall *REPL-FUN-GENERATOR*")
 524     (let ((repl-fun (funcall *repl-fun-generator*)))
 525       ;; Each REPL in a multithreaded world should have bindings of
 526       ;; most CL specials (most critically *PACKAGE*).
 527       (with-rebound-io-syntax
 528           (handler-bind ((step-condition 'invoke-stepper))
 529             (loop
 530                (/show0 "about to set up restarts in TOPLEVEL-REPL")
 531                ;; CLHS recommends that there should always be an
 532                ;; ABORT restart; we have this one here, and one per
 533                ;; debugger level.
 534                (with-simple-restart
 535                    (abort "~@<Exit debugger, returning to top level.~@:>")
 536                  (catch 'toplevel-catcher
 537                    ;; In the event of a control-stack-exhausted-error, we
 538                    ;; should have unwound enough stack by the time we get
 539                    ;; here that this is now possible.
 540                    #!-win32
 541                    (sb!kernel::reset-control-stack-guard-page)
 542                    (funcall repl-fun noprint)
 543                    (critically-unreachable "after REPL")))))))))
 544
 545 ;;; Our default REPL prompt is the minimal traditional one.
 546 (defun repl-prompt-fun (stream)
 547   (fresh-line stream)
 548   (write-string "* " stream)) ; arbitrary but customary REPL prompt
 549
 550 ;;; Our default form reader does relatively little magic, but does
 551 ;;; handle the Unix-style EOF-is-end-of-process convention.
 552 (defun repl-read-form-fun (in out)
 553   (declare (type stream in out) (ignore out))
 554   ;; KLUDGE: *READ-SUPPRESS* makes the REPL useless, and cannot be
 555   ;; recovered from -- flip it here.
 556   (when *read-suppress*
 557     (warn "Setting *READ-SUPPRESS* to NIL to restore toplevel usability.")
 558     (setf *read-suppress* nil))
 559   (let* ((eof-marker (cons nil nil))
 560          (form (read in nil eof-marker)))
 561     (if (eq form eof-marker)
 562         (quit)
 563         form)))
 564
 565 (defun repl-fun (noprint)
 566   (/show0 "entering REPL")
 567   (loop
 568    (unwind-protect
 569         (progn
 570           ;; (See comment preceding the definition of SCRUB-CONTROL-STACK.)
 571           (scrub-control-stack)
 572           (sb!thread::get-foreground)
 573           (unless noprint
 574             (flush-standard-output-streams)
 575             (funcall *repl-prompt-fun* *standard-output*)
 576             ;; (Should *REPL-PROMPT-FUN* be responsible for doing its own
 577             ;; FORCE-OUTPUT? I can't imagine a valid reason for it not to
 578             ;; be done here, so leaving it up to *REPL-PROMPT-FUN* seems
 579             ;; odd. But maybe there *is* a valid reason in some
 580             ;; circumstances? perhaps some deadlock issue when being driven
 581             ;; by another process or something...)
 582             (force-output *standard-output*))
 583           (let* ((form (funcall *repl-read-form-fun*
 584                                 *standard-input*
 585                                 *standard-output*))
 586                  (results (multiple-value-list (interactive-eval form))))
 587             (unless noprint
 588               (dolist (result results)
 589                 (fresh-line)
 590                 (prin1 result)))))
 591      ;; If we started stepping in the debugger we want to stop now.
 592      (disable-stepping))))
 593 \f
 594 ;;; a convenient way to get into the assembly-level debugger
 595 (defun %halt ()
 596   (%primitive sb!c:halt))