src/code/toplevel.lisp

   1 ;;;; stuff related to the toplevel read-eval-print loop, plus some
   2 ;;;; other miscellaneous functions that we don't have any better place
   3 ;;;; for
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!IMPL")
  15 \f
  16 ;;;; magic specials initialized by GENESIS
  17
  18 ;;; FIXME: The DEFVAR here is redundant with the (DECLAIM (SPECIAL ..))
  19 ;;; of all static symbols in early-impl.lisp.
  20 (progn
  21   (defvar sb!vm::*current-catch-block*)
  22   (defvar sb!vm::*current-unwind-protect-block*)
  23   (defvar *free-interrupt-context-index*))
  24 \f
  25 ;;; specials initialized by !COLD-INIT
  26
  27 ;;; FIXME: These could be converted to DEFVARs.
  28 (declaim (special #!+(or x86 x86-64) *pseudo-atomic-atomic*
  29                   #!+(or x86 x86-64) *pseudo-atomic-interrupted*
  30                   sb!unix::*interrupts-enabled*
  31                   sb!unix::*interrupt-pending*
  32                   *type-system-initialized*))
  33
  34 (defvar *cold-init-complete-p*)
  35
  36 ;;; counts of nested errors (with internal errors double-counted)
  37 (defvar *maximum-error-depth*)
  38 (defvar *current-error-depth*)
  39
  40 ;;;; stepping control
  41 (defvar *step*)
  42 (defvar *stepping*)
  43 (defvar *step-form-stack* nil
  44   "A place for single steppers to push information about
  45 STEP-FORM-CONDITIONS avaiting the corresponding
  46 STEP-VALUES-CONDITIONS. The system is guaranteed to empty the stack
  47 when stepping terminates, so that it remains in sync, but doesn't
  48 modify it in any other way: it is provided for implmentors of single
  49 steppers to maintain contextual information.")
  50 \f
  51 ;;;; miscellaneous utilities for working with with TOPLEVEL
  52
  53 ;;; Execute BODY in a context where any %END-OF-THE-WORLD (thrown e.g.
  54 ;;; by QUIT) is caught and any final processing and return codes are
  55 ;;; handled appropriately.
  56 (defmacro handling-end-of-the-world (&body body)
  57   (with-unique-names (caught)
  58     `(let ((,caught (catch '%end-of-the-world
  59                       (/show0 "inside CATCH '%END-OF-THE-WORLD")
  60                       ,@body)))
  61       (/show0 "back from CATCH '%END-OF-THE-WORLD, flushing output")
  62       (flush-standard-output-streams)
  63       (sb!thread::terminate-session)
  64       (/show0 "calling UNIX-EXIT")
  65       (sb!unix:unix-exit ,caught))))
  66 \f
  67 ;;;; working with *CURRENT-ERROR-DEPTH* and *MAXIMUM-ERROR-DEPTH*
  68
  69 ;;; INFINITE-ERROR-PROTECT is used by ERROR and friends to keep us out
  70 ;;; of hyperspace.
  71 (defmacro infinite-error-protect (&rest forms)
  72   `(unless (infinite-error-protector)
  73      (/show0 "back from INFINITE-ERROR-PROTECTOR")
  74      (let ((*current-error-depth* (1+ *current-error-depth*)))
  75        (/show0 "in INFINITE-ERROR-PROTECT, incremented error depth")
  76        ;; arbitrary truncation
  77        #!+sb-show (sb!debug:backtrace 8)
  78        ,@forms)))
  79
  80 ;;; a helper function for INFINITE-ERROR-PROTECT
  81 (defun infinite-error-protector ()
  82   (/show0 "entering INFINITE-ERROR-PROTECTOR, *CURRENT-ERROR-DEPTH*=..")
  83   (/hexstr *current-error-depth*)
  84   (cond ((not *cold-init-complete-p*)
  85          (%primitive print "Argh! error in cold init, halting")
  86          (%primitive sb!c:halt))
  87         ((or (not (boundp '*current-error-depth*))
  88              (not (realp   *current-error-depth*))
  89              (not (boundp '*maximum-error-depth*))
  90              (not (realp   *maximum-error-depth*)))
  91          (%primitive print "Argh! corrupted error depth, halting")
  92          (%primitive sb!c:halt))
  93         ((> *current-error-depth* *maximum-error-depth*)
  94          (/show0 "*MAXIMUM-ERROR-DEPTH*=..")
  95          (/hexstr *maximum-error-depth*)
  96          (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
  97          (error-error "Help! "
  98                       *current-error-depth*
  99                       " nested errors. "
 100                       "SB-KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 101          t)
 102         (t
 103          (/show0 "returning normally from INFINITE-ERROR-PROTECTOR")
 104          nil)))
 105
 106 ;;; FIXME: I had a badly broken version of INFINITE-ERROR-PROTECTOR at
 107 ;;; one point (shown below), and SBCL cross-compiled it without
 108 ;;; warning about FORMS being undefined. Check whether that problem
 109 ;;; (missing warning) is repeatable in the final system and if so, fix
 110 ;;; it.
 111 #|
 112 (defun infinite-error-protector ()
 113   `(cond ((not *cold-init-complete-p*)
 114           (%primitive print "Argh! error in cold init, halting")
 115           (%primitive sb!c:halt))
 116          ((or (not (boundp '*current-error-depth*))
 117               (not (realp   *current-error-depth*))
 118               (not (boundp '*maximum-error-depth*))
 119               (not (realp   *maximum-error-depth*)))
 120           (%primitive print "Argh! corrupted error depth, halting")
 121           (%primitive sb!c:halt))
 122          ((> *current-error-depth* *maximum-error-depth*)
 123           (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
 124           (error-error "Help! "
 125                        *current-error-depth*
 126                        " nested errors. "
 127                        "SB-KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 128           (progn ,@forms)
 129           t)
 130          (t
 131           (/show0 "in INFINITE-ERROR-PROTECTOR, returning normally")
 132           nil)))
 133 |#
 134 \f
 135 ;;;; miscellaneous external functions
 136
 137 (defun sleep (n)
 138   #!+sb-doc
 139   "This function causes execution to be suspended for N seconds. N may
 140   be any non-negative, non-complex number."
 141   (when (or (not (realp n))
 142             (minusp n))
 143     (error 'simple-type-error
 144            :format-control "invalid argument to SLEEP: ~S"
 145            :format-arguments (list n)
 146            :datum n
 147            :expected-type '(real 0)))
 148   #!-win32
 149   (multiple-value-bind (sec nsec)
 150       (if (integerp n)
 151           (values n 0)
 152           (multiple-value-bind (sec frac)
 153               (truncate n)
 154             (values sec (truncate frac 1e-9))))
 155     (sb!unix:nanosleep sec nsec))
 156   #!+win32
 157   (sb!win32:millisleep (truncate (* n 1000)))
 158   nil)
 159 \f
 160 ;;;; SCRUB-CONTROL-STACK
 161
 162 (defconstant bytes-per-scrub-unit 2048)
 163
 164 ;;; Zero the unused portion of the control stack so that old objects
 165 ;;; are not kept alive because of uninitialized stack variables.
 166
 167 ;;; "To summarize the problem, since not all allocated stack frame
 168 ;;; slots are guaranteed to be written by the time you call an another
 169 ;;; function or GC, there may be garbage pointers retained in your
 170 ;;; dead stack locations.  The stack scrubbing only affects the part
 171 ;;; of the stack from the SP to the end of the allocated stack."
 172 ;;; - ram, on cmucl-imp, Tue, 25 Sep 2001
 173
 174 ;;; So, as an (admittedly lame) workaround, from time to time we call
 175 ;;; scrub-control-stack to zero out all the unused portion.  This is
 176 ;;; supposed to happen when the stack is mostly empty, so that we have
 177 ;;; a chance of clearing more of it: callers are currently (2002.07.18)
 178 ;;; REPL and SUB-GC
 179
 180 (defun scrub-control-stack ()
 181   (declare (optimize (speed 3) (safety 0))
 182            (values (unsigned-byte 20))) ; FIXME: DECLARE VALUES?
 183
 184   #!-stack-grows-downward-not-upward
 185   (let* ((csp (sap-int (sb!c::control-stack-pointer-sap)))
 186          (initial-offset (logand csp (1- bytes-per-scrub-unit)))
 187          (end-of-stack
 188           (- (sap-int (sb!di::descriptor-sap sb!vm:*control-stack-end*))
 189              sb!c:*backend-page-size*)))
 190     (labels
 191         ((scrub (ptr offset count)
 192            (declare (type system-area-pointer ptr)
 193                     (type (unsigned-byte 16) offset)
 194                     (type (unsigned-byte 20) count)
 195                     (values (unsigned-byte 20)))
 196            (cond ((>= (sap-int ptr) end-of-stack) 0)
 197                  ((= offset bytes-per-scrub-unit)
 198                   (look (sap+ ptr bytes-per-scrub-unit) 0 count))
 199                  (t
 200                   (setf (sap-ref-word ptr offset) 0)
 201                   (scrub ptr (+ offset sb!vm:n-word-bytes) count))))
 202          (look (ptr offset count)
 203            (declare (type system-area-pointer ptr)
 204                     (type (unsigned-byte 16) offset)
 205                     (type (unsigned-byte 20) count)
 206                     (values (unsigned-byte 20)))
 207            (cond ((>= (sap-int ptr) end-of-stack) 0)
 208                  ((= offset bytes-per-scrub-unit)
 209                   count)
 210                  ((zerop (sap-ref-word ptr offset))
 211                   (look ptr (+ offset sb!vm:n-word-bytes) count))
 212                  (t
 213                   (scrub ptr offset (+ count sb!vm:n-word-bytes))))))
 214       (declare (type sb!vm::word csp))
 215       (scrub (int-sap (- csp initial-offset))
 216              (* (floor initial-offset sb!vm:n-word-bytes) sb!vm:n-word-bytes)
 217              0)))
 218
 219   #!+stack-grows-downward-not-upward
 220   (let* ((csp (sap-int (sb!c::control-stack-pointer-sap)))
 221          (end-of-stack (+ (sap-int (sb!di::descriptor-sap sb!vm:*control-stack-start*))
 222                           sb!c:*backend-page-size*))
 223          (initial-offset (logand csp (1- bytes-per-scrub-unit))))
 224     (labels
 225         ((scrub (ptr offset count)
 226            (declare (type system-area-pointer ptr)
 227                     (type (unsigned-byte 16) offset)
 228                     (type (unsigned-byte 20) count)
 229                     (values (unsigned-byte 20)))
 230            (let ((loc (int-sap (- (sap-int ptr) (+ offset sb!vm:n-word-bytes)))))
 231              (cond ((< (sap-int loc) end-of-stack) 0)
 232                    ((= offset bytes-per-scrub-unit)
 233                     (look (int-sap (- (sap-int ptr) bytes-per-scrub-unit))
 234                           0 count))
 235                    (t ;; need to fix bug in %SET-STACK-REF
 236                     (setf (sap-ref-word loc 0) 0)
 237                     (scrub ptr (+ offset sb!vm:n-word-bytes) count)))))
 238          (look (ptr offset count)
 239            (declare (type system-area-pointer ptr)
 240                     (type (unsigned-byte 16) offset)
 241                     (type (unsigned-byte 20) count)
 242                     (values (unsigned-byte 20)))
 243            (let ((loc (int-sap (- (sap-int ptr) offset))))
 244              (cond ((< (sap-int loc) end-of-stack) 0)
 245                    ((= offset bytes-per-scrub-unit)
 246                     count)
 247                    ((zerop (sb!kernel::get-lisp-obj-address (stack-ref loc 0)))
 248                     (look ptr (+ offset sb!vm:n-word-bytes) count))
 249                    (t
 250                     (scrub ptr offset (+ count sb!vm:n-word-bytes)))))))
 251       (declare (type sb!vm::word csp))
 252       (scrub (int-sap (+ csp initial-offset))
 253              (* (floor initial-offset sb!vm:n-word-bytes) sb!vm:n-word-bytes)
 254              0))))
 255 \f
 256 ;;;; the default toplevel function
 257
 258 (defvar / nil
 259   #!+sb-doc
 260   "a list of all the values returned by the most recent top level EVAL")
 261 (defvar //  nil #!+sb-doc "the previous value of /")
 262 (defvar /// nil #!+sb-doc "the previous value of //")
 263 (defvar *   nil #!+sb-doc "the value of the most recent top level EVAL")
 264 (defvar **  nil #!+sb-doc "the previous value of *")
 265 (defvar *** nil #!+sb-doc "the previous value of **")
 266 (defvar +   nil #!+sb-doc "the value of the most recent top level READ")
 267 (defvar ++  nil #!+sb-doc "the previous value of +")
 268 (defvar +++ nil #!+sb-doc "the previous value of ++")
 269 (defvar -   nil #!+sb-doc "the form currently being evaluated")
 270
 271 (defun interactive-eval (form)
 272   "Evaluate FORM, returning whatever it returns and adjusting ***, **, *,
 273    +++, ++, +, ///, //, /, and -."
 274   (setf - form)
 275   (unwind-protect
 276        (let ((results (multiple-value-list (eval form))))
 277          (setf /// //
 278                // /
 279                / results
 280                *** **
 281                ** *
 282                * (car results)))
 283     (setf +++ ++
 284           ++ +
 285           + -))
 286   (unless (boundp '*)
 287     ;; The bogon returned an unbound marker.
 288     ;; FIXME: It would be safer to check every one of the values in RESULTS,
 289     ;; instead of just the first one.
 290     (setf * nil)
 291     (cerror "Go on with * set to NIL."
 292             "EVAL returned an unbound marker."))
 293   (values-list /))
 294
 295 ;;; Flush anything waiting on one of the ANSI Common Lisp standard
 296 ;;; output streams before proceeding.
 297 (defun flush-standard-output-streams ()
 298   (dolist (name '(*debug-io*
 299                   *error-output*
 300                   *query-io*
 301                   *standard-output*
 302                   *trace-output*
 303                   *terminal-io*))
 304     ;; FINISH-OUTPUT may block more easily than FORCE-OUTPUT
 305     (force-output (symbol-value name)))
 306   (values))
 307
 308 (defun process-init-file (truename)
 309   (when truename
 310     (restart-case
 311         (with-open-file (s truename :if-does-not-exist nil)
 312           (flet ((next ()
 313                    (let ((form (read s nil s)))
 314                      (if (eq s form)
 315                          (return-from process-init-file nil)
 316                          (eval form)))))
 317             (loop
 318                (restart-case
 319                    (handler-bind ((error (lambda (e)
 320                                            (error
 321                                             "Error during processing of ~
 322                                             initialization file ~A:~%~%  ~A"
 323                                             truename e))))
 324                      (next))
 325                  (continue ()
 326                    :report "Ignore and continue processing.")))))
 327       (abort ()
 328         :report "Skip rest of initialization file."))))
 329
 330 (defun process-eval-options (eval-strings-or-forms)
 331   (/show0 "handling --eval options")
 332   (flet ((process-1 (string-or-form)
 333            (etypecase string-or-form
 334              (string
 335               (multiple-value-bind (expr pos) (read-from-string string-or-form)
 336                 (unless (eq string-or-form
 337                             (read-from-string string-or-form nil string-or-form
 338                                               :start pos))
 339                   (error "More than one expression in ~S" string-or-form))
 340                 (eval expr)
 341                 (flush-standard-output-streams)))
 342              (cons (eval string-or-form) (flush-standard-output-streams)))))
 343     (restart-case
 344         (dolist (expr-as-string-or-form eval-strings-or-forms)
 345           (/show0 "handling one --eval option")
 346           (restart-case
 347               (handler-bind
 348                   ((error (lambda (e)
 349                             (error "Error during processing of --eval ~
 350                                     option ~S:~%~%  ~A"
 351                                    expr-as-string-or-form e))))
 352                 (process-1 expr-as-string-or-form))
 353             (continue ()
 354               :report "Ignore and continue with next --eval option.")))
 355       (abort ()
 356         :report "Skip rest of --eval options."))))
 357
 358 ;;; the default system top level function
 359 (defun toplevel-init ()
 360   (/show0 "entering TOPLEVEL-INIT")
 361   (let (;; value of --sysinit option
 362         (sysinit nil)
 363         ;; value of --userinit option
 364         (userinit nil)
 365         ;; values of --eval options, in reverse order; and also any
 366         ;; other options (like --load) which're translated into --eval
 367         ;;
 368         ;; The values are stored as strings, so that they can be
 369         ;; passed to READ only after their predecessors have been
 370         ;; EVALed, so that things work when e.g. REQUIRE in one EVAL
 371         ;; form creates a package referred to in the next EVAL form,
 372         ;; except for forms transformed from syntactically-sugary
 373         ;; switches like --load and --disable-debugger.
 374         (reversed-evals nil)
 375         ;; Has a --noprint option been seen?
 376         (noprint nil)
 377         ;; everything in *POSIX-ARGV* except for argv[0]=programname
 378         (options (rest *posix-argv*)))
 379
 380     (declare (type list options))
 381
 382     (/show0 "done with outer LET in TOPLEVEL-INIT")
 383
 384     ;; FIXME: There are lots of ways for errors to happen around here
 385     ;; (e.g. bad command line syntax, or READ-ERROR while trying to
 386     ;; READ an --eval string). Make sure that they're handled
 387     ;; reasonably.
 388
 389     ;; Process command line options.
 390     (flet (;; Errors while processing the command line cause the system
 391            ;; to QUIT, instead of trying to go into the Lisp debugger,
 392            ;; because trying to go into the Lisp debugger would get
 393            ;; into various annoying issues of where we should go after
 394            ;; the user tries to return from the debugger.
 395            (startup-error (control-string &rest args)
 396              (format
 397               *error-output*
 398               "fatal error before reaching READ-EVAL-PRINT loop: ~%  ~?~%"
 399               control-string
 400               args)
 401              (quit :unix-status 1)))
 402       (loop while options do
 403             (/show0 "at head of LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 404             (let ((option (first options)))
 405               (flet ((pop-option ()
 406                        (if options
 407                            (pop options)
 408                            (startup-error
 409                             "unexpected end of command line options"))))
 410                 (cond ((string= option "--sysinit")
 411                        (pop-option)
 412                        (if sysinit
 413                            (startup-error "multiple --sysinit options")
 414                            (setf sysinit (pop-option))))
 415                       ((string= option "--userinit")
 416                        (pop-option)
 417                        (if userinit
 418                            (startup-error "multiple --userinit options")
 419                            (setf userinit (pop-option))))
 420                       ((string= option "--eval")
 421                        (pop-option)
 422                        (push (pop-option) reversed-evals))
 423                       ((string= option "--load")
 424                        (pop-option)
 425                        (push
 426                         (list 'cl:load (native-pathname (pop-option)))
 427                         reversed-evals))
 428                       ((string= option "--noprint")
 429                        (pop-option)
 430                        (setf noprint t))
 431                       ((string= option "--disable-debugger")
 432                        (pop-option)
 433                        (push (list 'sb!ext:disable-debugger) reversed-evals))
 434                       ((string= option "--end-toplevel-options")
 435                        (pop-option)
 436                        (return))
 437                       (t
 438                        ;; Anything we don't recognize as a toplevel
 439                        ;; option must be the start of user-level
 440                        ;; options.. except that if we encounter
 441                        ;; "--end-toplevel-options" after we gave up
 442                        ;; because we didn't recognize an option as a
 443                        ;; toplevel option, then the option we gave up on
 444                        ;; must have been an error. (E.g. in
 445                        ;;  "sbcl --eval '(a)' --eval'(b)' --end-toplevel-options"
 446                        ;; this test will let us detect that the string
 447                        ;; "--eval(b)" is an error.)
 448                        (if (find "--end-toplevel-options" options
 449                                  :test #'string=)
 450                            (startup-error "bad toplevel option: ~S"
 451                                           (first options))
 452                            (return)))))))
 453       (/show0 "done with LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 454
 455       ;; Delete all the options that we processed, so that only
 456       ;; user-level options are left visible to user code.
 457       (setf (rest *posix-argv*) options)
 458
 459       ;; Handle initialization files.
 460       (/show0 "handling initialization files in TOPLEVEL-INIT")
 461       (flet (;; shared idiom for searching for SYSINITish and
 462              ;; USERINITish files
 463              (probe-init-files (explicitly-specified-init-file-name
 464                                 &rest default-init-file-names)
 465                (declare (type list default-init-file-names))
 466                (if explicitly-specified-init-file-name
 467                    (or (probe-file explicitly-specified-init-file-name)
 468                         (startup-error "The file ~S was not found."
 469                                        explicitly-specified-init-file-name))
 470                    (find-if (lambda (x)
 471                               (and (stringp x) (probe-file x)))
 472                             default-init-file-names)))
 473              ;; shared idiom for creating default names for
 474              ;; SYSINITish and USERINITish files
 475              (init-file-name (maybe-dir-name basename)
 476                (and maybe-dir-name
 477                     (concatenate 'string maybe-dir-name "/" basename))))
 478         (let ((sysinit-truename
 479                #!-win32 (probe-init-files sysinit
 480                                           (init-file-name (posix-getenv "SBCL_HOME")
 481                                                           "sbclrc")
 482                                           "/etc/sbclrc"))
 483                (userinit-truename
 484                 #!-win32 (probe-init-files userinit
 485                                            (init-file-name (posix-getenv "HOME")
 486                                                            ".sbclrc"))))
 487
 488           ;; This CATCH is needed for the debugger command TOPLEVEL to
 489           ;; work.
 490           (catch 'toplevel-catcher
 491             ;; We wrap all the pre-REPL user/system customized startup
 492             ;; code in a restart.
 493             ;;
 494             ;; (Why not wrap everything, even the stuff above, in this
 495             ;; restart? Errors above here are basically command line
 496             ;; or Unix environment errors, e.g. a missing file or a
 497             ;; typo on the Unix command line, and you don't need to
 498             ;; get into Lisp to debug them, you should just start over
 499             ;; and do it right at the Unix level. Errors below here
 500             ;; are generally errors in user Lisp code, and it might be
 501             ;; helpful to let the user reach the REPL in order to help
 502             ;; figure out what's going on.)
 503             (restart-case
 504                 (progn
 505                   (process-init-file sysinit-truename)
 506                   (process-init-file userinit-truename)
 507                   (process-eval-options (reverse reversed-evals)))
 508               (abort ()
 509                 :report "Skip to toplevel READ/EVAL/PRINT loop."
 510                 (/show0 "CONTINUEing from pre-REPL RESTART-CASE")
 511                 (values))                 ; (no-op, just fall through)
 512               (quit ()
 513                 :report "Quit SBCL (calling #'QUIT, killing the process)."
 514                 (/show0 "falling through to QUIT from pre-REPL RESTART-CASE")
 515                 (quit)))))
 516
 517         ;; one more time for good measure, in case we fell out of the
 518         ;; RESTART-CASE above before one of the flushes in the ordinary
 519         ;; flow of control had a chance to operate
 520         (flush-standard-output-streams)
 521
 522         (/show0 "falling into TOPLEVEL-REPL from TOPLEVEL-INIT")
 523         (toplevel-repl noprint)
 524         ;; (classic CMU CL error message: "You're certainly a clever child.":-)
 525         (critically-unreachable "after TOPLEVEL-REPL")))))
 526
 527 ;;; hooks to support customized toplevels like ACL-style toplevel from
 528 ;;; KMR on sbcl-devel 2002-12-21.  Altered by CSR 2003-11-16 for
 529 ;;; threaded operation: altered *REPL-FUN* to *REPL-FUN-GENERATOR*.
 530 (defvar *repl-read-form-fun* #'repl-read-form-fun
 531   "a function of two stream arguments IN and OUT for the toplevel REPL to
 532   call: Return the next Lisp form to evaluate (possibly handling other
 533   magic -- like ACL-style keyword commands -- which precede the next
 534   Lisp form). The OUT stream is there to support magic which requires
 535   issuing new prompts.")
 536 (defvar *repl-prompt-fun* #'repl-prompt-fun
 537   "a function of one argument STREAM for the toplevel REPL to call: Prompt
 538   the user for input.")
 539 (defvar *repl-fun-generator* (constantly #'repl-fun)
 540   "a function of no arguments returning a function of one argument
 541   NOPRINT that provides the REPL for the system.  Assumes that
 542   *STANDARD-INPUT* and *STANDARD-OUTPUT* are set up.")
 543
 544 ;;; read-eval-print loop for the default system toplevel
 545 (defun toplevel-repl (noprint)
 546   (/show0 "entering TOPLEVEL-REPL")
 547   (let ((* nil) (** nil) (*** nil)
 548         (- nil)
 549         (+ nil) (++ nil) (+++ nil)
 550         (/// nil) (// nil) (/ nil))
 551     (/show0 "about to funcall *REPL-FUN-GENERATOR*")
 552     (let ((repl-fun (funcall *repl-fun-generator*)))
 553       ;; Each REPL in a multithreaded world should have bindings of
 554       ;; most CL specials (most critically *PACKAGE*).
 555       (with-rebound-io-syntax
 556           (handler-bind ((step-condition 'invoke-stepper))
 557             (let ((*stepping* nil)
 558                   (*step* nil))
 559               (loop
 560                (/show0 "about to set up restarts in TOPLEVEL-REPL")
 561                  ;; CLHS recommends that there should always be an
 562                  ;; ABORT restart; we have this one here, and one per
 563                  ;; debugger level.
 564                  (with-simple-restart
 565                      (abort "~@<Exit debugger, returning to top level.~@:>")
 566                    (catch 'toplevel-catcher
 567                      #!-win32 (sb!unix::reset-signal-mask)
 568                      ;; In the event of a control-stack-exhausted-error, we
 569                      ;; should have unwound enough stack by the time we get
 570                      ;; here that this is now possible.
 571                      (sb!kernel::protect-control-stack-guard-page 1)
 572                      (funcall repl-fun noprint)
 573                      (critically-unreachable "after REPL"))))))))))
 574
 575 ;;; Our default REPL prompt is the minimal traditional one.
 576 (defun repl-prompt-fun (stream)
 577   (fresh-line stream)
 578   (write-string "* " stream)) ; arbitrary but customary REPL prompt
 579
 580 ;;; Our default form reader does relatively little magic, but does
 581 ;;; handle the Unix-style EOF-is-end-of-process convention.
 582 (defun repl-read-form-fun (in out)
 583   (declare (type stream in out) (ignore out))
 584   (let* ((eof-marker (cons nil nil))
 585          (form (read in nil eof-marker)))
 586     (if (eq form eof-marker)
 587         (quit)
 588         form)))
 589
 590 (defun repl-fun (noprint)
 591   (/show0 "entering REPL")
 592   (loop
 593    (unwind-protect
 594         (progn
 595           ;; (See comment preceding the definition of SCRUB-CONTROL-STACK.)
 596           (scrub-control-stack)
 597           (sb!thread::get-foreground)
 598           (unless noprint
 599             (flush-standard-output-streams)
 600             (funcall *repl-prompt-fun* *standard-output*)
 601             ;; (Should *REPL-PROMPT-FUN* be responsible for doing its own
 602             ;; FORCE-OUTPUT? I can't imagine a valid reason for it not to
 603             ;; be done here, so leaving it up to *REPL-PROMPT-FUN* seems
 604             ;; odd. But maybe there *is* a valid reason in some
 605             ;; circumstances? perhaps some deadlock issue when being driven
 606             ;; by another process or something...)
 607             (force-output *standard-output*))
 608           (let* ((form (funcall *repl-read-form-fun*
 609                                 *standard-input*
 610                                 *standard-output*))
 611                  (results (multiple-value-list (interactive-eval form))))
 612             (unless noprint
 613               (dolist (result results)
 614                 (fresh-line)
 615                 (prin1 result)))))
 616      ;; If we started stepping in the debugger we want to stop now.
 617      (setf *stepping* nil
 618            *step* nil))))
 619 \f
 620 ;;; a convenient way to get into the assembly-level debugger
 621 (defun %halt ()
 622   (%primitive sb!c:halt))