src/code/toplevel.lisp

   1 ;;;; stuff related to the toplevel read-eval-print loop, plus some
   2 ;;;; other miscellaneous functions that we don't have any better place
   3 ;;;; for
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!IMPL")
  15 \f
  16 ;;;; magic specials initialized by GENESIS
  17
  18 ;;; FIXME: The DEFVAR here is redundant with the (DECLAIM (SPECIAL ..))
  19 ;;; of all static symbols in early-impl.lisp.
  20 (progn
  21   (defvar sb!vm::*current-catch-block*)
  22   (defvar sb!vm::*current-unwind-protect-block*)
  23   (defvar *free-interrupt-context-index*))
  24 \f
  25 ;;; specials initialized by !COLD-INIT
  26
  27 ;;; FIXME: These could be converted to DEFVARs.
  28 (declaim (special *gc-inhibit* *need-to-collect-garbage*
  29                   *before-gc-hooks* *after-gc-hooks*
  30                   #!+x86 *pseudo-atomic-atomic*
  31                   #!+x86 *pseudo-atomic-interrupted*
  32                   sb!unix::*interrupts-enabled*
  33                   sb!unix::*interrupt-pending*
  34                   *type-system-initialized*))
  35
  36 (defvar *cold-init-complete-p*)
  37
  38 ;;; counts of nested errors (with internal errors double-counted)
  39 (defvar *maximum-error-depth*)
  40 (defvar *current-error-depth*)
  41
  42 ;;;; stepping control
  43 (defvar *step*)
  44 (defvar *stepping*)
  45 (defvar *step-form-stack* nil
  46   "A place for single steppers to push information about
  47 STEP-FORM-CONDITIONS avaiting the corresponding
  48 STEP-VALUES-CONDITIONS. The system is guaranteed to empty the stack
  49 when stepping terminates, so that it remains in sync, but doesn't
  50 modify it in any other way: it is provided for implmentors of single
  51 steppers to maintain contextual information.")
  52 \f
  53 ;;;; miscellaneous utilities for working with with TOPLEVEL
  54
  55 ;;; Execute BODY in a context where any %END-OF-THE-WORLD (thrown e.g.
  56 ;;; by QUIT) is caught and any final processing and return codes are
  57 ;;; handled appropriately.
  58 (defmacro handling-end-of-the-world (&body body)
  59   (with-unique-names (caught)
  60     `(let ((,caught (catch '%end-of-the-world
  61                       (/show0 "inside CATCH '%END-OF-THE-WORLD")
  62                       ,@body)))
  63       (/show0 "back from CATCH '%END-OF-THE-WORLD, flushing output")
  64       (flush-standard-output-streams)
  65       (sb!thread::terminate-session)
  66       (/show0 "calling UNIX-EXIT")
  67       (sb!unix:unix-exit ,caught))))
  68 \f
  69 ;;;; working with *CURRENT-ERROR-DEPTH* and *MAXIMUM-ERROR-DEPTH*
  70
  71 ;;; INFINITE-ERROR-PROTECT is used by ERROR and friends to keep us out
  72 ;;; of hyperspace.
  73 (defmacro infinite-error-protect (&rest forms)
  74   `(unless (infinite-error-protector)
  75      (/show0 "back from INFINITE-ERROR-PROTECTOR")
  76      (let ((*current-error-depth* (1+ *current-error-depth*)))
  77        (/show0 "in INFINITE-ERROR-PROTECT, incremented error depth")
  78        ;; arbitrary truncation
  79        #!+sb-show (sb!debug:backtrace 8)
  80        ,@forms)))
  81
  82 ;;; a helper function for INFINITE-ERROR-PROTECT
  83 (defun infinite-error-protector ()
  84   (/show0 "entering INFINITE-ERROR-PROTECTOR, *CURRENT-ERROR-DEPTH*=..")
  85   (/hexstr *current-error-depth*)
  86   (cond ((not *cold-init-complete-p*)
  87          (%primitive print "Argh! error in cold init, halting")
  88          (%primitive sb!c:halt))
  89         ((or (not (boundp '*current-error-depth*))
  90              (not (realp   *current-error-depth*))
  91              (not (boundp '*maximum-error-depth*))
  92              (not (realp   *maximum-error-depth*)))
  93          (%primitive print "Argh! corrupted error depth, halting")
  94          (%primitive sb!c:halt))
  95         ((> *current-error-depth* *maximum-error-depth*)
  96          (/show0 "*MAXIMUM-ERROR-DEPTH*=..")
  97          (/hexstr *maximum-error-depth*)
  98          (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
  99          (error-error "Help! "
 100                       *current-error-depth*
 101                       " nested errors. "
 102                       "SB-KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 103          t)
 104         (t
 105          (/show0 "returning normally from INFINITE-ERROR-PROTECTOR")
 106          nil)))
 107
 108 ;;; FIXME: I had a badly broken version of INFINITE-ERROR-PROTECTOR at
 109 ;;; one point (shown below), and SBCL cross-compiled it without
 110 ;;; warning about FORMS being undefined. Check whether that problem
 111 ;;; (missing warning) is repeatable in the final system and if so, fix
 112 ;;; it.
 113 #|
 114 (defun infinite-error-protector ()
 115   `(cond ((not *cold-init-complete-p*)
 116           (%primitive print "Argh! error in cold init, halting")
 117           (%primitive sb!c:halt))
 118          ((or (not (boundp '*current-error-depth*))
 119               (not (realp   *current-error-depth*))
 120               (not (boundp '*maximum-error-depth*))
 121               (not (realp   *maximum-error-depth*)))
 122           (%primitive print "Argh! corrupted error depth, halting")
 123           (%primitive sb!c:halt))
 124          ((> *current-error-depth* *maximum-error-depth*)
 125           (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
 126           (error-error "Help! "
 127                        *current-error-depth*
 128                        " nested errors. "
 129                        "SB-KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 130           (progn ,@forms)
 131           t)
 132          (t
 133           (/show0 "in INFINITE-ERROR-PROTECTOR, returning normally")
 134           nil)))
 135 |#
 136 \f
 137 ;;;; miscellaneous external functions
 138
 139 (defun sleep (n)
 140   #!+sb-doc
 141   "This function causes execution to be suspended for N seconds. N may
 142   be any non-negative, non-complex number."
 143   (when (or (not (realp n))
 144             (minusp n))
 145     (error 'simple-type-error
 146            :format-control "invalid argument to SLEEP: ~S"
 147            :format-arguments (list n)
 148            :datum n
 149            :expected-type '(real 0)))
 150   (multiple-value-bind (sec usec)
 151       (if (integerp n)
 152           (values n 0)
 153           (multiple-value-bind (sec frac)
 154               (truncate n)
 155             (values sec (truncate frac 1e-6))))
 156     (sb!unix:unix-select 0 0 0 0 sec usec))
 157   nil)
 158 \f
 159 ;;;; SCRUB-CONTROL-STACK
 160
 161 (defconstant bytes-per-scrub-unit 2048)
 162
 163 ;;; Zero the unused portion of the control stack so that old objects
 164 ;;; are not kept alive because of uninitialized stack variables.
 165
 166 ;;; "To summarize the problem, since not all allocated stack frame
 167 ;;; slots are guaranteed to be written by the time you call an another
 168 ;;; function or GC, there may be garbage pointers retained in your
 169 ;;; dead stack locations.  The stack scrubbing only affects the part
 170 ;;; of the stack from the SP to the end of the allocated stack."
 171 ;;; - ram, on cmucl-imp, Tue, 25 Sep 2001
 172
 173 ;;; So, as an (admittedly lame) workaround, from time to time we call
 174 ;;; scrub-control-stack to zero out all the unused portion.  This is
 175 ;;; supposed to happen when the stack is mostly empty, so that we have
 176 ;;; a chance of clearing more of it: callers are currently (2002.07.18)
 177 ;;; REPL and SUB-GC
 178
 179 (defun scrub-control-stack ()
 180   (declare (optimize (speed 3) (safety 0))
 181            (values (unsigned-byte 20))) ; FIXME: DECLARE VALUES?
 182
 183   #!-stack-grows-downward-not-upward
 184   (let* ((csp (sap-int (sb!c::control-stack-pointer-sap)))
 185          (initial-offset (logand csp (1- bytes-per-scrub-unit)))
 186          (end-of-stack
 187           (- (sb!vm:fixnumize sb!vm:*control-stack-end*)
 188              sb!c:*backend-page-size*)))
 189     (labels
 190         ((scrub (ptr offset count)
 191            (declare (type system-area-pointer ptr)
 192                     (type (unsigned-byte 16) offset)
 193                     (type (unsigned-byte 20) count)
 194                     (values (unsigned-byte 20)))
 195            (cond ((>= (sap-int ptr) end-of-stack) 0)
 196                  ((= offset bytes-per-scrub-unit)
 197                   (look (sap+ ptr bytes-per-scrub-unit) 0 count))
 198                  (t
 199                   (setf (sap-ref-word ptr offset) 0)
 200                   (scrub ptr (+ offset sb!vm:n-word-bytes) count))))
 201          (look (ptr offset count)
 202            (declare (type system-area-pointer ptr)
 203                     (type (unsigned-byte 16) offset)
 204                     (type (unsigned-byte 20) count)
 205                     (values (unsigned-byte 20)))
 206            (cond ((>= (sap-int ptr) end-of-stack) 0)
 207                  ((= offset bytes-per-scrub-unit)
 208                   count)
 209                  ((zerop (sap-ref-word ptr offset))
 210                   (look ptr (+ offset sb!vm:n-word-bytes) count))
 211                  (t
 212                   (scrub ptr offset (+ count sb!vm:n-word-bytes))))))
 213       (declare (type sb!vm::word csp))
 214       (scrub (int-sap (- csp initial-offset))
 215              (* (floor initial-offset sb!vm:n-word-bytes) sb!vm:n-word-bytes)
 216              0)))
 217
 218   #!+stack-grows-downward-not-upward
 219   (let* ((csp (sap-int (sb!c::control-stack-pointer-sap)))
 220          (end-of-stack (+ (sb!vm:fixnumize sb!vm:*control-stack-start*)
 221                           sb!c:*backend-page-size*))
 222          (initial-offset (logand csp (1- bytes-per-scrub-unit))))
 223     (labels
 224         ((scrub (ptr offset count)
 225            (declare (type system-area-pointer ptr)
 226                     (type (unsigned-byte 16) offset)
 227                     (type (unsigned-byte 20) count)
 228                     (values (unsigned-byte 20)))
 229            (let ((loc (int-sap (- (sap-int ptr) (+ offset sb!vm:n-word-bytes)))))
 230              (cond ((< (sap-int loc) end-of-stack) 0)
 231                    ((= offset bytes-per-scrub-unit)
 232                     (look (int-sap (- (sap-int ptr) bytes-per-scrub-unit))
 233                           0 count))
 234                    (t ;; need to fix bug in %SET-STACK-REF
 235                     (setf (sap-ref-word loc 0) 0)
 236                     (scrub ptr (+ offset sb!vm:n-word-bytes) count)))))
 237          (look (ptr offset count)
 238            (declare (type system-area-pointer ptr)
 239                     (type (unsigned-byte 16) offset)
 240                     (type (unsigned-byte 20) count)
 241                     (values (unsigned-byte 20)))
 242            (let ((loc (int-sap (- (sap-int ptr) offset))))
 243              (cond ((< (sap-int loc) end-of-stack) 0)
 244                    ((= offset bytes-per-scrub-unit)
 245                     count)
 246                    ((zerop (sb!kernel::get-lisp-obj-address (stack-ref loc 0)))
 247                     (look ptr (+ offset sb!vm:n-word-bytes) count))
 248                    (t
 249                     (scrub ptr offset (+ count sb!vm:n-word-bytes)))))))
 250       (declare (type sb!vm::word csp))
 251       (scrub (int-sap (+ csp initial-offset))
 252              (* (floor initial-offset sb!vm:n-word-bytes) sb!vm:n-word-bytes)
 253              0))))
 254 \f
 255 ;;;; the default toplevel function
 256
 257 (defvar / nil
 258   #!+sb-doc
 259   "a list of all the values returned by the most recent top level EVAL")
 260 (defvar //  nil #!+sb-doc "the previous value of /")
 261 (defvar /// nil #!+sb-doc "the previous value of //")
 262 (defvar *   nil #!+sb-doc "the value of the most recent top level EVAL")
 263 (defvar **  nil #!+sb-doc "the previous value of *")
 264 (defvar *** nil #!+sb-doc "the previous value of **")
 265 (defvar +   nil #!+sb-doc "the value of the most recent top level READ")
 266 (defvar ++  nil #!+sb-doc "the previous value of +")
 267 (defvar +++ nil #!+sb-doc "the previous value of ++")
 268 (defvar -   nil #!+sb-doc "the form currently being evaluated")
 269
 270 (defun interactive-eval (form)
 271   "Evaluate FORM, returning whatever it returns and adjusting ***, **, *,
 272    +++, ++, +, ///, //, /, and -."
 273   (setf - form)
 274   (let ((results (multiple-value-list (eval form))))
 275     (setf /// //
 276           // /
 277           / results
 278           *** **
 279           ** *
 280           * (car results)))
 281   (setf +++ ++
 282         ++ +
 283         + -)
 284   (unless (boundp '*)
 285     ;; The bogon returned an unbound marker.
 286     ;; FIXME: It would be safer to check every one of the values in RESULTS,
 287     ;; instead of just the first one.
 288     (setf * nil)
 289     (cerror "Go on with * set to NIL."
 290             "EVAL returned an unbound marker."))
 291   (values-list /))
 292
 293 ;;; Flush anything waiting on one of the ANSI Common Lisp standard
 294 ;;; output streams before proceeding.
 295 (defun flush-standard-output-streams ()
 296   (dolist (name '(*debug-io*
 297                   *error-output*
 298                   *query-io*
 299                   *standard-output*
 300                   *trace-output*))
 301     (finish-output (symbol-value name)))
 302   (values))
 303
 304 (defun process-init-file (truename)
 305   (when truename
 306     (restart-case
 307         (with-open-file (s truename :if-does-not-exist nil)
 308           (flet ((next ()
 309                    (let ((form (read s nil s)))
 310                      (if (eq s form)
 311                          (return-from process-init-file nil)
 312                          (eval form)))))
 313             (loop
 314                (restart-case
 315                    (handler-bind ((error (lambda (e)
 316                                            (error
 317                                             "Error during processing of ~
 318                                             initialization file ~A:~%~%  ~A"
 319                                             truename e))))
 320                      (next))
 321                  (continue ()
 322                    :report "Ignore and continue processing.")))))
 323       (abort ()
 324         :report "Skip rest of initialization file."))))
 325
 326 (defun process-eval-options (eval-strings)
 327   (/show0 "handling --eval options")
 328   (flet ((process-1 (string)
 329            (multiple-value-bind (expr pos) (read-from-string string)
 330              (unless (eq string (read-from-string string nil string :start pos))
 331                (error "More the one expression in ~S" string))
 332              (eval expr)
 333              (flush-standard-output-streams))))
 334     (restart-case
 335         (dolist (expr-as-string eval-strings)
 336           (/show0 "handling one --eval option")
 337           (restart-case
 338               (handler-bind ((error (lambda (e)
 339                                       (error "Error during processing of --eval ~
 340                                               option ~S:~%~%  ~A"
 341                                              expr-as-string e))))
 342                 (process-1 expr-as-string))
 343             (continue ()
 344               :report "Ignore and continue with next --eval option.")))
 345       (abort ()
 346         :report "Skip rest of --eval options."))))
 347
 348 ;;; the default system top level function
 349 (defun toplevel-init ()
 350   (/show0 "entering TOPLEVEL-INIT")
 351   (let (;; value of --sysinit option
 352         (sysinit nil)
 353         ;; value of --userinit option
 354         (userinit nil)
 355         ;; values of --eval options, in reverse order; and also any
 356         ;; other options (like --load) which're translated into --eval
 357         ;;
 358         ;; The values are stored as strings, so that they can be
 359         ;; passed to READ only after their predecessors have been
 360         ;; EVALed, so that things work when e.g. REQUIRE in one EVAL
 361         ;; form creates a package referred to in the next EVAL form.
 362         (reversed-evals nil)
 363         ;; Has a --noprint option been seen?
 364         (noprint nil)
 365         ;; everything in *POSIX-ARGV* except for argv[0]=programname
 366         (options (rest *posix-argv*)))
 367
 368     (declare (type list options))
 369
 370     (/show0 "done with outer LET in TOPLEVEL-INIT")
 371
 372     ;; FIXME: There are lots of ways for errors to happen around here
 373     ;; (e.g. bad command line syntax, or READ-ERROR while trying to
 374     ;; READ an --eval string). Make sure that they're handled
 375     ;; reasonably.
 376
 377     ;; Process command line options.
 378     (flet (;; Errors while processing the command line cause the system
 379            ;; to QUIT, instead of trying to go into the Lisp debugger,
 380            ;; because trying to go into the Lisp debugger would get
 381            ;; into various annoying issues of where we should go after
 382            ;; the user tries to return from the debugger.
 383            (startup-error (control-string &rest args)
 384              (format
 385               *error-output*
 386               "fatal error before reaching READ-EVAL-PRINT loop: ~%  ~?~%"
 387               control-string
 388               args)
 389              (quit :unix-status 1)))
 390       (loop while options do
 391             (/show0 "at head of LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 392             (let ((option (first options)))
 393               (flet ((pop-option ()
 394                        (if options
 395                            (pop options)
 396                            (startup-error
 397                             "unexpected end of command line options"))))
 398                 (cond ((string= option "--sysinit")
 399                        (pop-option)
 400                        (if sysinit
 401                            (startup-error "multiple --sysinit options")
 402                            (setf sysinit (pop-option))))
 403                       ((string= option "--userinit")
 404                        (pop-option)
 405                        (if userinit
 406                            (startup-error "multiple --userinit options")
 407                            (setf userinit (pop-option))))
 408                       ((string= option "--eval")
 409                        (pop-option)
 410                        (push (pop-option) reversed-evals))
 411                       ((string= option "--load")
 412                        (pop-option)
 413                        (push
 414                         ;; FIXME: see BUG 296
 415                         (concatenate 'string "(|LOAD| \"" (pop-option) "\")")
 416                         reversed-evals))
 417                       ((string= option "--noprint")
 418                        (pop-option)
 419                        (setf noprint t))
 420                       ((string= option "--disable-debugger")
 421                        (pop-option)
 422                        (push "(|DISABLE-DEBUGGER|)" reversed-evals))
 423                       ((string= option "--end-toplevel-options")
 424                        (pop-option)
 425                        (return))
 426                       (t
 427                        ;; Anything we don't recognize as a toplevel
 428                        ;; option must be the start of user-level
 429                        ;; options.. except that if we encounter
 430                        ;; "--end-toplevel-options" after we gave up
 431                        ;; because we didn't recognize an option as a
 432                        ;; toplevel option, then the option we gave up on
 433                        ;; must have been an error. (E.g. in
 434                        ;;  "sbcl --eval '(a)' --eval'(b)' --end-toplevel-options"
 435                        ;; this test will let us detect that the string
 436                        ;; "--eval(b)" is an error.)
 437                        (if (find "--end-toplevel-options" options
 438                                  :test #'string=)
 439                            (startup-error "bad toplevel option: ~S"
 440                                           (first options))
 441                            (return)))))))
 442       (/show0 "done with LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 443
 444       ;; Delete all the options that we processed, so that only
 445       ;; user-level options are left visible to user code.
 446       (setf (rest *posix-argv*) options)
 447
 448       ;; Handle initialization files.
 449       (/show0 "handling initialization files in TOPLEVEL-INIT")
 450       (flet (;; shared idiom for searching for SYSINITish and
 451              ;; USERINITish files
 452              (probe-init-files (explicitly-specified-init-file-name
 453                                 &rest default-init-file-names)
 454                (declare (type list default-init-file-names))
 455                (if explicitly-specified-init-file-name
 456                    (or (probe-file explicitly-specified-init-file-name)
 457                         (startup-error "The file ~S was not found."
 458                                        explicitly-specified-init-file-name))
 459                    (find-if (lambda (x)
 460                               (and (stringp x) (probe-file x)))
 461                             default-init-file-names)))
 462              ;; shared idiom for creating default names for
 463              ;; SYSINITish and USERINITish files
 464              (init-file-name (maybe-dir-name basename)
 465                (and maybe-dir-name
 466                     (concatenate 'string maybe-dir-name "/" basename))))
 467         (let ((sysinit-truename
 468                (probe-init-files sysinit
 469                                  (init-file-name (posix-getenv "SBCL_HOME")
 470                                                  "sbclrc")
 471                                  "/etc/sbclrc"))
 472                (userinit-truename
 473                 (probe-init-files userinit
 474                                   (init-file-name (posix-getenv "HOME")
 475                                                   ".sbclrc"))))
 476
 477           ;; This CATCH is needed for the debugger command TOPLEVEL to
 478           ;; work.
 479           (catch 'toplevel-catcher
 480             ;; We wrap all the pre-REPL user/system customized startup
 481             ;; code in a restart.
 482             ;;
 483             ;; (Why not wrap everything, even the stuff above, in this
 484             ;; restart? Errors above here are basically command line
 485             ;; or Unix environment errors, e.g. a missing file or a
 486             ;; typo on the Unix command line, and you don't need to
 487             ;; get into Lisp to debug them, you should just start over
 488             ;; and do it right at the Unix level. Errors below here
 489             ;; are generally errors in user Lisp code, and it might be
 490             ;; helpful to let the user reach the REPL in order to help
 491             ;; figure out what's going on.)
 492             (restart-case
 493                 (progn
 494                   (process-init-file sysinit-truename)
 495                   (process-init-file userinit-truename)
 496                   (process-eval-options (reverse reversed-evals)))
 497               (abort ()
 498                 :report "Skip to toplevel READ/EVAL/PRINT loop."
 499                 (/show0 "CONTINUEing from pre-REPL RESTART-CASE")
 500                 (values))                 ; (no-op, just fall through)
 501               (quit ()
 502                 :report "Quit SBCL (calling #'QUIT, killing the process)."
 503                 (/show0 "falling through to QUIT from pre-REPL RESTART-CASE")
 504                 (quit)))))
 505
 506         ;; one more time for good measure, in case we fell out of the
 507         ;; RESTART-CASE above before one of the flushes in the ordinary
 508         ;; flow of control had a chance to operate
 509         (flush-standard-output-streams)
 510
 511         (/show0 "falling into TOPLEVEL-REPL from TOPLEVEL-INIT")
 512         (toplevel-repl noprint)
 513         ;; (classic CMU CL error message: "You're certainly a clever child.":-)
 514         (critically-unreachable "after TOPLEVEL-REPL")))))
 515
 516 ;;; hooks to support customized toplevels like ACL-style toplevel from
 517 ;;; KMR on sbcl-devel 2002-12-21.  Altered by CSR 2003-11-16 for
 518 ;;; threaded operation: altered *REPL-FUN* to *REPL-FUN-GENERATOR*.
 519 (defvar *repl-read-form-fun* #'repl-read-form-fun
 520   "a function of two stream arguments IN and OUT for the toplevel REPL to
 521   call: Return the next Lisp form to evaluate (possibly handling other
 522   magic -- like ACL-style keyword commands -- which precede the next
 523   Lisp form). The OUT stream is there to support magic which requires
 524   issuing new prompts.")
 525 (defvar *repl-prompt-fun* #'repl-prompt-fun
 526   "a function of one argument STREAM for the toplevel REPL to call: Prompt
 527   the user for input.")
 528 (defvar *repl-fun-generator* (constantly #'repl-fun)
 529   "a function of no arguments returning a function of one argument
 530   NOPRINT that provides the REPL for the system.  Assumes that
 531   *STANDARD-INPUT* and *STANDARD-OUTPUT* are set up.")
 532
 533 ;;; read-eval-print loop for the default system toplevel
 534 (defun toplevel-repl (noprint)
 535   (/show0 "entering TOPLEVEL-REPL")
 536   (let ((* nil) (** nil) (*** nil)
 537         (- nil)
 538         (+ nil) (++ nil) (+++ nil)
 539         (/// nil) (// nil) (/ nil))
 540     (/show0 "about to funcall *REPL-FUN-GENERATOR*")
 541     (let ((repl-fun (funcall *repl-fun-generator*)))
 542       ;; Each REPL in a multithreaded world should have bindings of
 543       ;; most CL specials (most critically *PACKAGE*).
 544       (with-rebound-io-syntax
 545           (handler-bind ((step-condition 'invoke-stepper))
 546             (let ((*stepping* nil)
 547                   (*step* nil))
 548               (loop
 549                (/show0 "about to set up restarts in TOPLEVEL-REPL")
 550                  ;; CLHS recommends that there should always be an
 551                  ;; ABORT restart; we have this one here, and one per
 552                  ;; debugger level.
 553                  (with-simple-restart
 554                      (abort "~@<Exit debugger, returning to top level.~@:>")
 555                    (catch 'toplevel-catcher
 556                      (sb!unix::reset-signal-mask)
 557                      ;; In the event of a control-stack-exhausted-error, we
 558                      ;; should have unwound enough stack by the time we get
 559                      ;; here that this is now possible.
 560                      (sb!kernel::protect-control-stack-guard-page 1)
 561                      (funcall repl-fun noprint)
 562                      (critically-unreachable "after REPL"))))))))))
 563
 564 ;;; Our default REPL prompt is the minimal traditional one.
 565 (defun repl-prompt-fun (stream)
 566   (fresh-line stream)
 567   (write-string "* " stream)) ; arbitrary but customary REPL prompt
 568
 569 ;;; Our default form reader does relatively little magic, but does
 570 ;;; handle the Unix-style EOF-is-end-of-process convention.
 571 (defun repl-read-form-fun (in out)
 572   (declare (type stream in out) (ignore out))
 573   (let* ((eof-marker (cons nil nil))
 574          (form (read in nil eof-marker)))
 575     (if (eq form eof-marker)
 576         (quit)
 577         form)))
 578
 579 (defun repl-fun (noprint)
 580   (/show0 "entering REPL")
 581   (loop
 582    (unwind-protect
 583         (progn
 584           ;; (See comment preceding the definition of SCRUB-CONTROL-STACK.)
 585           (scrub-control-stack)
 586           (sb!thread::get-foreground)
 587           (unless noprint
 588             (funcall *repl-prompt-fun* *standard-output*)
 589             ;; (Should *REPL-PROMPT-FUN* be responsible for doing its own
 590             ;; FORCE-OUTPUT? I can't imagine a valid reason for it not to
 591             ;; be done here, so leaving it up to *REPL-PROMPT-FUN* seems
 592             ;; odd. But maybe there *is* a valid reason in some
 593             ;; circumstances? perhaps some deadlock issue when being driven
 594             ;; by another process or something...)
 595             (force-output *standard-output*))
 596           (let* ((form (funcall *repl-read-form-fun*
 597                                 *standard-input*
 598                                 *standard-output*))
 599                  (results (multiple-value-list (interactive-eval form))))
 600             (unless noprint
 601               (dolist (result results)
 602                 (fresh-line)
 603                 (prin1 result)))))
 604      ;; If we started stepping in the debugger we want to stop now.
 605      (setf *stepping* nil
 606            *step* nil))))
 607 \f
 608 ;;; a convenient way to get into the assembly-level debugger
 609 (defun %halt ()
 610   (%primitive sb!c:halt))