src/code/toplevel.lisp

   1 ;;;; stuff related to the toplevel read-eval-print loop, plus some
   2 ;;;; other miscellaneous functions that we don't have any better place
   3 ;;;; for
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!IMPL")
  15 \f
  16 ;;;; magic specials initialized by GENESIS
  17
  18 ;;; FIXME: The DEFVAR here is redundant with the (DECLAIM (SPECIAL ..))
  19 ;;; of all static symbols in early-impl.lisp.
  20 (progn
  21   (defvar *current-catch-block*)
  22   (defvar *current-unwind-protect-block*)
  23   (defvar *free-interrupt-context-index*))
  24 \f
  25 ;;; specials initialized by !COLD-INIT
  26
  27 ;;; FIXME: These could be converted to DEFVARs.
  28 (declaim (special *gc-inhibit* *already-maybe-gcing*
  29                   *need-to-collect-garbage*
  30                   *gc-notify-stream*
  31                   *before-gc-hooks* *after-gc-hooks*
  32                   #!+x86 *pseudo-atomic-atomic*
  33                   #!+x86 *pseudo-atomic-interrupted*
  34                   sb!unix::*interrupts-enabled*
  35                   sb!unix::*interrupt-pending*
  36                   *type-system-initialized*))
  37
  38 (defvar *cold-init-complete-p*)
  39
  40 ;;; counts of nested errors (with internal errors double-counted)
  41 (defvar *maximum-error-depth*)
  42 (defvar *current-error-depth*)
  43 \f
  44 ;;;; miscellaneous utilities for working with with TOPLEVEL
  45
  46 ;;; Execute BODY in a context where any %END-OF-THE-WORLD (thrown e.g.
  47 ;;; by QUIT) is caught and any final processing and return codes are
  48 ;;; handled appropriately.
  49 (defmacro handling-end-of-the-world (&body body)
  50   (let ((caught (gensym "CAUGHT")))
  51     `(let ((,caught (catch '%end-of-the-world
  52                       (/show0 "inside CATCH '%END-OF-THE-WORLD")
  53                       ,@body)))
  54        (/show0 "back from CATCH '%END-OF-THE-WORLD, flushing output")
  55        (flush-standard-output-streams)
  56        (/show0 "calling UNIX-EXIT")
  57        (sb!unix:unix-exit ,caught))))
  58 \f
  59 ;;;; working with *CURRENT-ERROR-DEPTH* and *MAXIMUM-ERROR-DEPTH*
  60
  61 ;;; INFINITE-ERROR-PROTECT is used by ERROR and friends to keep us out
  62 ;;; of hyperspace.
  63 (defmacro infinite-error-protect (&rest forms)
  64   `(unless (infinite-error-protector)
  65      (/show0 "back from INFINITE-ERROR-PROTECTOR")
  66      (let ((*current-error-depth* (1+ *current-error-depth*)))
  67        (/show0 "in INFINITE-ERROR-PROTECT, incremented error depth")
  68        ;; arbitrary truncation
  69        #!+sb-show (sb!debug:backtrace 8)
  70        ,@forms)))
  71
  72 ;;; a helper function for INFINITE-ERROR-PROTECT
  73 (defun infinite-error-protector ()
  74   (/show0 "entering INFINITE-ERROR-PROTECTOR, *CURRENT-ERROR-DEPTH*=..")
  75   (/hexstr *current-error-depth*)
  76   (cond ((not *cold-init-complete-p*)
  77          (%primitive print "Argh! error in cold init, halting")
  78          (%primitive sb!c:halt))
  79         ((or (not (boundp '*current-error-depth*))
  80              (not (realp   *current-error-depth*))
  81              (not (boundp '*maximum-error-depth*))
  82              (not (realp   *maximum-error-depth*)))
  83          (%primitive print "Argh! corrupted error depth, halting")
  84          (%primitive sb!c:halt))
  85         ((> *current-error-depth* *maximum-error-depth*)
  86          (/show0 "*MAXIMUM-ERROR-DEPTH*=..")
  87          (/hexstr *maximum-error-depth*)
  88          (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
  89          (error-error "Help! "
  90                       *current-error-depth*
  91                       " nested errors. "
  92                       "KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
  93          t)
  94         (t
  95          (/show0 "returning normally from INFINITE-ERROR-PROTECTOR")
  96          nil)))
  97
  98 ;;; FIXME: I had a badly broken version of INFINITE-ERROR-PROTECTOR at
  99 ;;; one point (shown below), and SBCL cross-compiled it without
 100 ;;; warning about FORMS being undefined. Check whether that problem
 101 ;;; (missing warning) is repeatable in the final system and if so, fix
 102 ;;; it.
 103 #|
 104 (defun infinite-error-protector ()
 105   `(cond ((not *cold-init-complete-p*)
 106           (%primitive print "Argh! error in cold init, halting")
 107           (%primitive sb!c:halt))
 108          ((or (not (boundp '*current-error-depth*))
 109               (not (realp   *current-error-depth*))
 110               (not (boundp '*maximum-error-depth*))
 111               (not (realp   *maximum-error-depth*)))
 112           (%primitive print "Argh! corrupted error depth, halting")
 113           (%primitive sb!c:halt))
 114          ((> *current-error-depth* *maximum-error-depth*)
 115           (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
 116           (error-error "Help! "
 117                        *current-error-depth*
 118                        " nested errors. "
 119                        "KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 120           (progn ,@forms)
 121           t)
 122          (t
 123           (/show0 "in INFINITE-ERROR-PROTECTOR, returning normally")
 124           nil)))
 125 |#
 126 \f
 127 ;;;; miscellaneous external functions
 128
 129 (defun sleep (n)
 130   #!+sb-doc
 131   "This function causes execution to be suspended for N seconds. N may
 132   be any non-negative, non-complex number."
 133   (when (or (not (realp n))
 134             (minusp n))
 135     (error 'simple-type-error
 136            :format-control "invalid argument to SLEEP: ~S"
 137            :format-arguments (list n)
 138            :datum n
 139            :expected-type '(real 0)))
 140   (multiple-value-bind (sec usec)
 141       (if (integerp n)
 142           (values n 0)
 143           (multiple-value-bind (sec frac)
 144               (truncate n)
 145             (values sec (truncate frac 1e-6))))
 146     (sb!unix:unix-select 0 0 0 0 sec usec))
 147   nil)
 148 \f
 149 ;;;; SCRUB-CONTROL-STACK
 150
 151 (defconstant bytes-per-scrub-unit 2048)
 152
 153 ;;; Zero the unused portion of the control stack so that old objects
 154 ;;; are not kept alive because of uninitialized stack variables.
 155
 156 ;;; "To summarize the problem, since not all allocated stack frame
 157 ;;; slots are guaranteed to be written by the time you call an another
 158 ;;; function or GC, there may be garbage pointers retained in your
 159 ;;; dead stack locations.  The stack scrubbing only affects the part
 160 ;;; of the stack from the SP to the end of the allocated stack."
 161 ;;; - ram, on cmucl-imp, Tue, 25 Sep 2001
 162
 163 ;;; So, as an (admittedly lame) workaround, from time to time we call
 164 ;;; scrub-control-stack to zero out all the unused portion.  This is
 165 ;;; supposed to happen when the stack is mostly empty, so that we have
 166 ;;; a chance of clearing more of it: callers are currently (2002.07.18)
 167 ;;; REPL and SUB-GC
 168
 169 (defun scrub-control-stack ()
 170   (declare (optimize (speed 3) (safety 0))
 171            (values (unsigned-byte 20))) ; FIXME: DECLARE VALUES?
 172
 173   #!-stack-grows-downward-not-upward
 174   (let* ((csp (sap-int (sb!c::control-stack-pointer-sap)))
 175          (initial-offset (logand csp (1- bytes-per-scrub-unit)))
 176          (end-of-stack
 177           (- sb!vm:control-stack-end sb!c:*backend-page-size*)))
 178     (labels
 179         ((scrub (ptr offset count)
 180            (declare (type system-area-pointer ptr)
 181                     (type (unsigned-byte 16) offset)
 182                     (type (unsigned-byte 20) count)
 183                     (values (unsigned-byte 20)))
 184            (cond ((>= (sap-int ptr) end-of-stack) 0)
 185                  ((= offset bytes-per-scrub-unit)
 186                   (look (sap+ ptr bytes-per-scrub-unit) 0 count))
 187                  (t
 188                   (setf (sap-ref-32 ptr offset) 0)
 189                   (scrub ptr (+ offset sb!vm:n-word-bytes) count))))
 190          (look (ptr offset count)
 191            (declare (type system-area-pointer ptr)
 192                     (type (unsigned-byte 16) offset)
 193                     (type (unsigned-byte 20) count)
 194                     (values (unsigned-byte 20)))
 195            (cond ((>= (sap-int ptr) end-of-stack) 0)
 196                  ((= offset bytes-per-scrub-unit)
 197                   count)
 198                  ((zerop (sap-ref-32 ptr offset))
 199                   (look ptr (+ offset sb!vm:n-word-bytes) count))
 200                  (t
 201                   (scrub ptr offset (+ count sb!vm:n-word-bytes))))))
 202       (declare (type (unsigned-byte 32) csp))
 203       (scrub (int-sap (- csp initial-offset))
 204              (* (floor initial-offset sb!vm:n-word-bytes) sb!vm:n-word-bytes)
 205              0)))
 206
 207   #!+stack-grows-downward-not-upward
 208   (let* ((csp (sap-int (sb!c::control-stack-pointer-sap)))
 209          (end-of-stack (+ sb!vm:control-stack-start sb!c:*backend-page-size*))
 210          (initial-offset (logand csp (1- bytes-per-scrub-unit))))
 211     (labels
 212         ((scrub (ptr offset count)
 213            (declare (type system-area-pointer ptr)
 214                     (type (unsigned-byte 16) offset)
 215                     (type (unsigned-byte 20) count)
 216                     (values (unsigned-byte 20)))
 217            (let ((loc (int-sap (- (sap-int ptr) (+ offset sb!vm:n-word-bytes)))))
 218              (cond ((< (sap-int loc) end-of-stack) 0)
 219                    ((= offset bytes-per-scrub-unit)
 220                     (look (int-sap (- (sap-int ptr) bytes-per-scrub-unit))
 221                           0 count))
 222                    (t ;; need to fix bug in %SET-STACK-REF
 223                     (setf (sap-ref-32 loc 0) 0)
 224                     (scrub ptr (+ offset sb!vm:n-word-bytes) count)))))
 225          (look (ptr offset count)
 226            (declare (type system-area-pointer ptr)
 227                     (type (unsigned-byte 16) offset)
 228                     (type (unsigned-byte 20) count)
 229                     (values (unsigned-byte 20)))
 230            (let ((loc (int-sap (- (sap-int ptr) offset))))
 231              (cond ((< (sap-int loc) end-of-stack) 0)
 232                    ((= offset bytes-per-scrub-unit)
 233                     count)
 234                    ((zerop (sb!kernel::get-lisp-obj-address (stack-ref loc 0)))
 235                     (look ptr (+ offset sb!vm:n-word-bytes) count))
 236                    (t
 237                     (scrub ptr offset (+ count sb!vm:n-word-bytes)))))))
 238       (declare (type (unsigned-byte 32) csp))
 239       (scrub (int-sap (+ csp initial-offset))
 240              (* (floor initial-offset sb!vm:n-word-bytes) sb!vm:n-word-bytes)
 241              0))))
 242 \f
 243 ;;;; the default toplevel function
 244
 245 (defvar / nil
 246   #!+sb-doc
 247   "a list of all the values returned by the most recent top level EVAL")
 248 (defvar //  nil #!+sb-doc "the previous value of /")
 249 (defvar /// nil #!+sb-doc "the previous value of //")
 250 (defvar *   nil #!+sb-doc "the value of the most recent top level EVAL")
 251 (defvar **  nil #!+sb-doc "the previous value of *")
 252 (defvar *** nil #!+sb-doc "the previous value of **")
 253 (defvar +   nil #!+sb-doc "the value of the most recent top level READ")
 254 (defvar ++  nil #!+sb-doc "the previous value of +")
 255 (defvar +++ nil #!+sb-doc "the previous value of ++")
 256 (defvar -   nil #!+sb-doc "the form currently being evaluated")
 257
 258 (defun interactive-eval (form)
 259   "Evaluate FORM, returning whatever it returns and adjusting ***, **, *,
 260    +++, ++, +, ///, //, /, and -."
 261   (setf - form)
 262   (let ((results
 263          (multiple-value-list
 264           (eval-in-lexenv form
 265                           (make-null-interactive-lexenv)))))
 266     (setf /// //
 267           // /
 268           / results
 269           *** **
 270           ** *
 271           * (car results)))
 272   (setf +++ ++
 273         ++ +
 274         + -)
 275   (unless (boundp '*)
 276     ;; The bogon returned an unbound marker.
 277     ;; FIXME: It would be safer to check every one of the values in RESULTS,
 278     ;; instead of just the first one.
 279     (setf * nil)
 280     (cerror "Go on with * set to NIL."
 281             "EVAL returned an unbound marker."))
 282   (values-list /))
 283
 284 ;;; Flush anything waiting on one of the ANSI Common Lisp standard
 285 ;;; output streams before proceeding.
 286 (defun flush-standard-output-streams ()
 287   (dolist (name '(*debug-io*
 288                   *error-output*
 289                   *query-io*
 290                   *standard-output*
 291                   *trace-output*))
 292     (finish-output (symbol-value name)))
 293   (values))
 294
 295 ;;; the default system top level function
 296 (defun toplevel-init ()
 297
 298   (/show0 "entering TOPLEVEL-INIT")
 299
 300   (let ((sysinit nil)        ; value of --sysinit option
 301         (userinit nil)       ; value of --userinit option
 302         (reversed-evals nil) ; values of --eval options, in reverse order; and
 303                              ; also --load options, translated into --eval
 304         (noprint nil)        ; Has a --noprint option been seen?
 305         (options (rest *posix-argv*))) ; skipping program name
 306
 307     (declare (type list options))
 308
 309     (/show0 "done with outer LET in TOPLEVEL-INIT")
 310
 311     ;; FIXME: There are lots of ways for errors to happen around here
 312     ;; (e.g. bad command line syntax, or READ-ERROR while trying to
 313     ;; READ an --eval string). Make sure that they're handled
 314     ;; reasonably. Also, perhaps all errors while parsing the command
 315     ;; line should cause the system to QUIT, instead of trying to go
 316     ;; into the Lisp debugger, since trying to go into the debugger
 317     ;; gets into various annoying issues of where we should go after
 318     ;; the user tries to return from the debugger.
 319
 320     ;; Parse command line options.
 321     (loop while options do
 322           (/show0 "at head of LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 323           (let ((option (first options)))
 324             (flet ((pop-option ()
 325                      (if options
 326                          (pop options)
 327                          (error "unexpected end of command line options"))))
 328               (cond ((string= option "--sysinit")
 329                      (pop-option)
 330                      (if sysinit
 331                          (error "multiple --sysinit options")
 332                          (setf sysinit (pop-option))))
 333                     ((string= option "--userinit")
 334                      (pop-option)
 335                      (if userinit
 336                          (error "multiple --userinit options")
 337                          (setf userinit (pop-option))))
 338                     ((string= option "--eval")
 339                      (pop-option)
 340                      (let ((eval-as-string (pop-option)))
 341                        (with-input-from-string (eval-stream eval-as-string)
 342                          (let* ((eof-marker (cons :eof :eof))
 343                                 (eval (read eval-stream nil eof-marker))
 344                                 (eof (read eval-stream nil eof-marker)))
 345                            (cond ((eq eval eof-marker)
 346                                   (error "unable to parse ~S"
 347                                          eval-as-string))
 348                                  ((not (eq eof eof-marker))
 349                                   (error "more than one expression in ~S"
 350                                          eval-as-string))
 351                                  (t
 352                                   (push eval reversed-evals)))))))
 353                     ((string= option "--load")
 354                      (pop-option)
 355                      (push `(load ,(pop-option)) reversed-evals))
 356                     ((string= option "--noprint")
 357                      (pop-option)
 358                      (setf noprint t))
 359                     ;; FIXME: --noprogrammer was deprecated in 0.7.5, and
 360                     ;; in a year or so this backwards compatibility can
 361                     ;; go away.
 362                     ((string= option "--noprogrammer")
 363                      (warn "treating deprecated --noprogrammer as --disable-debugger")
 364                      (pop-option)
 365                      (push '(disable-debugger) reversed-evals))
 366                     ((string= option "--disable-debugger")
 367                      (pop-option)
 368                      (push '(disable-debugger) reversed-evals))
 369                     ((string= option "--end-toplevel-options")
 370                      (pop-option)
 371                      (return))
 372                     (t
 373                      ;; Anything we don't recognize as a toplevel
 374                      ;; option must be the start of user-level
 375                      ;; options.. except that if we encounter
 376                      ;; "--end-toplevel-options" after we gave up
 377                      ;; because we didn't recognize an option as a
 378                      ;; toplevel option, then the option we gave up on
 379                      ;; must have been an error. (E.g. in
 380                      ;;  "sbcl --eval '(a)' --eval'(b)' --end-toplevel-options"
 381                      ;; this test will let us detect that the string
 382                      ;; "--eval(b)" is an error.)
 383                      (if (find "--end-toplevel-options" options
 384                                :test #'string=)
 385                          (error "bad toplevel option: ~S" (first options))
 386                          (return)))))))
 387     (/show0 "done with LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 388
 389     ;; Excise all the options that we processed, so that only
 390     ;; user-level options are left visible to user code.
 391     (setf (rest *posix-argv*) options)
 392
 393     ;; Handle initialization files.
 394     (/show0 "handling initialization files in TOPLEVEL-INIT")
 395     (flet (;; If any of POSSIBLE-INIT-FILE-NAMES names a real file,
 396            ;; return its truename.
 397            (probe-init-files (&rest possible-init-file-names)
 398              (declare (type list possible-init-file-names))
 399              (/show0 "entering PROBE-INIT-FILES")
 400              (prog1
 401                  (find-if (lambda (x)
 402                             (and (stringp x) (probe-file x)))
 403                           possible-init-file-names)
 404                (/show0 "leaving PROBE-INIT-FILES"))))
 405       (let* ((sbcl-home (posix-getenv "SBCL_HOME"))
 406              (sysinit-truename (if sbcl-home
 407                                    (probe-init-files sysinit
 408                                                      (concatenate 'string
 409                                                                   sbcl-home
 410                                                                   "/sbclrc"))
 411                                    (probe-init-files sysinit
 412                                                      "/etc/sbclrc"
 413                                                      "/usr/local/etc/sbclrc")))
 414              (user-home (or (posix-getenv "HOME")
 415                             (error "The HOME environment variable is unbound, ~
 416                                     so user init file can't be found.")))
 417              (userinit-truename (probe-init-files userinit
 418                                                   (concatenate 'string
 419                                                                user-home
 420                                                                "/.sbclrc"))))
 421
 422         ;; We wrap all the pre-REPL user/system customized startup code
 423         ;; in a restart.
 424         ;;
 425         ;; (Why not wrap everything, even the stuff above, in this
 426         ;; restart? Errors above here are basically command line or
 427         ;; Unix environment errors, e.g. a missing file or a typo on
 428         ;; the Unix command line, and you don't need to get into Lisp
 429         ;; to debug them, you should just start over and do it right
 430         ;; at the Unix level. Errors below here are generally errors
 431         ;; in user Lisp code, and it might be helpful to let the user
 432         ;; reach the REPL in order to help figure out what's going
 433         ;; on.)
 434         (restart-case
 435             (progn
 436               (flet ((process-init-file (truename)
 437                        (when truename
 438                          (unless (load truename)
 439                            (error "~S was not successfully loaded." truename))
 440                          (flush-standard-output-streams))))
 441                 (process-init-file sysinit-truename)
 442                 (process-init-file userinit-truename))
 443
 444               ;; Process --eval options.
 445               (/show0 "handling --eval options in TOPLEVEL-INIT")
 446               (dolist (eval (reverse reversed-evals))
 447                 (/show0 "handling one --eval option in TOPLEVEL-INIT")
 448                 (eval eval)
 449                 (flush-standard-output-streams)))
 450           (continue ()
 451             :report
 452             "Continue anyway (skipping to toplevel read/eval/print loop)."
 453             (/show0 "CONTINUEing from pre-REPL RESTART-CASE")
 454             (values)) ; (no-op, just fall through)
 455           (quit ()
 456             :report "Quit SBCL (calling #'QUIT, killing the process)."
 457             (/show0 "falling through to QUIT from pre-REPL RESTART-CASE")
 458             (quit))))
 459
 460       ;; one more time for good measure, in case we fell out of the
 461       ;; RESTART-CASE above before one of the flushes in the ordinary
 462       ;; flow of control had a chance to operate
 463       (flush-standard-output-streams)
 464
 465       (/show0 "falling into TOPLEVEL-REPL from TOPLEVEL-INIT")
 466       (toplevel-repl noprint)
 467       ;; (classic CMU CL error message: "You're certainly a clever child.":-)
 468       (critically-unreachable "after TOPLEVEL-REPL"))))
 469
 470 ;;; halt-on-failures and prompt-on-failures modes, suitable for
 471 ;;; noninteractive and interactive use respectively
 472 (defun disable-debugger ()
 473   (setf *debugger-hook* 'noprogrammer-debugger-hook-fun
 474         *debug-io* *error-output*))
 475 (defun enable-debugger ()
 476   (setf *debugger-hook* nil
 477         *debug-io* *query-io*))
 478
 479 ;;; read-eval-print loop for the default system toplevel
 480 (defun toplevel-repl (noprint)
 481   (/show0 "entering TOPLEVEL-REPL")
 482   (let ((* nil) (** nil) (*** nil)
 483         (- nil)
 484         (+ nil) (++ nil) (+++ nil)
 485         (/// nil) (// nil) (/ nil))
 486     ;; WITH-SIMPLE-RESTART doesn't actually restart its body as some
 487     ;; (like WHN for an embarrassingly long time ca. 2001-12-07) might
 488     ;; think, but instead drops control back out at the end. So when a
 489     ;; TOPLEVEL or outermost-ABORT restart happens, we need this outer
 490     ;; LOOP wrapper to grab control and start over again. (And it also
 491     ;; wraps CATCH 'TOPLEVEL-CATCHER for similar reasons.)
 492     (loop
 493      (/show0 "about to set up restarts in TOPLEVEL-REPL")
 494      ;; There should only be one TOPLEVEL restart, and it's here, so
 495      ;; restarting at TOPLEVEL always bounces you all the way out here.
 496      (with-simple-restart (toplevel
 497                            "Restart at toplevel READ/EVAL/PRINT loop.")
 498        ;; We add a new ABORT restart for every debugger level, so
 499        ;; restarting at ABORT in a nested debugger gets you out to the
 500        ;; innermost enclosing debugger, and only when you're in the
 501        ;; outermost, unnested debugger level does restarting at ABORT
 502        ;; get you out to here.
 503        (with-simple-restart
 504            (abort
 505             "~@<Reduce debugger level (leaving debugger, returning to toplevel).~@:>")
 506          (catch 'toplevel-catcher
 507            #!-sunos (sb!unix:unix-sigsetmask 0) ; FIXME: What is this for?
 508            ;; in the event of a control-stack-exhausted-error, we should
 509            ;; have unwound enough stack by the time we get here that this
 510            ;; is now possible
 511            (sb!kernel::protect-control-stack-guard-page 1)
 512            (repl noprint)
 513            (critically-unreachable "after REPL")))))))
 514
 515 ;;; Our default REPL prompt is the minimal traditional one.
 516 (defun repl-prompt-fun (stream)
 517   (fresh-line stream)
 518   (write-string "* " stream)) ; arbitrary but customary REPL prompt
 519
 520 ;;; Our default form reader does relatively little magic, but does
 521 ;;; handle the Unix-style EOF-is-end-of-process convention.
 522 (defun repl-read-form-fun (in out)
 523   (declare (type stream in out) (ignore out))
 524   (let* ((eof-marker (cons nil nil))
 525          (form (read in nil eof-marker)))
 526     (if (eq form eof-marker)
 527         (quit)
 528         form)))
 529
 530 ;;; hooks to support customized toplevels like ACL-style toplevel
 531 ;;; from KMR on sbcl-devel 2002-12-21
 532 (defvar *repl-read-form-fun* #'repl-read-form-fun
 533   "a function of two stream arguments IN and OUT for the toplevel REPL to
 534   call: Return the next Lisp form to evaluate (possibly handling other
 535   magic -- like ACL-style keyword commands -- which precede the next
 536   Lisp form). The OUT stream is there to support magic which requires
 537   issuing new prompts.")
 538 (defvar *repl-prompt-fun* #'repl-prompt-fun
 539   "a function of one argument STREAM for the toplevel REPL to call: Prompt
 540   the user for input.")
 541
 542 (defun repl (noprint)
 543   (/show0 "entering REPL")
 544   (let ((eof-marker (cons :eof nil)))
 545     (loop
 546      ;; (See comment preceding the definition of SCRUB-CONTROL-STACK.)
 547      (scrub-control-stack)
 548      (unless noprint
 549        (funcall *repl-prompt-fun* *standard-output*)
 550        ;; (Should *REPL-PROMPT-FUN* be responsible for doing its own
 551        ;; FORCE-OUTPUT? I can't imagine a valid reason for it not to
 552        ;; be done here, so leaving it up to *REPL-PROMPT-FUN* seems
 553        ;; odd. But maybe there *is* a valid reason in some
 554        ;; circumstances? perhaps some deadlock issue when being driven
 555        ;; by another process or something...)
 556        (force-output *standard-output*))
 557      (let* ((form (funcall *repl-read-form-fun*
 558                            *standard-input*
 559                            *standard-output*))
 560             (results (multiple-value-list (interactive-eval form))))
 561        (unless noprint
 562          (dolist (result results)
 563            (fresh-line)
 564            (prin1 result)))))))
 565
 566 ;;; suitable value for *DEBUGGER-HOOK* for a noninteractive Unix-y program
 567 (defun noprogrammer-debugger-hook-fun (condition old-debugger-hook)
 568   (declare (ignore old-debugger-hook))
 569   (flet ((failure-quit (&key recklessly-p)
 570            (/show0 "in FAILURE-QUIT (in --disable-debugger debugger hook)")
 571            (quit :unix-status 1 :recklessly-p recklessly-p)))
 572     ;; This HANDLER-CASE is here mostly to stop output immediately
 573     ;; (and fall through to QUIT) when there's an I/O error. Thus,
 574     ;; when we're run under a shell script or something, we can die
 575     ;; cleanly when the script dies (and our pipes are cut), instead
 576     ;; of falling into ldb or something messy like that.
 577     (handler-case
 578         (progn
 579           (format *error-output*
 580                   "~&~@<unhandled condition (of type ~S): ~2I~_~A~:>~2%"
 581                   (type-of condition)
 582                   condition)
 583           ;; Flush *ERROR-OUTPUT* even before the BACKTRACE, so that
 584           ;; even if we hit an error within BACKTRACE (e.g. a bug in
 585           ;; the debugger's own frame-walking code, or a bug in a user
 586           ;; PRINT-OBJECT method) we'll at least have the CONDITION
 587           ;; printed out before we die.
 588           (finish-output *error-output*)
 589           ;; (Where to truncate the BACKTRACE is of course arbitrary, but
 590           ;; it seems as though we should at least truncate it somewhere.)
 591           (sb!debug:backtrace 128 *error-output*)
 592           (format
 593            *error-output*
 594            "~%unhandled condition in --disable-debugger mode, quitting~%")
 595           (finish-output *error-output*)
 596           (failure-quit))
 597       (condition ()
 598         ;; We IGNORE-ERRORS here because even %PRIMITIVE PRINT can
 599         ;; fail when our output streams are blown away, as e.g. when
 600         ;; we're running under a Unix shell script and it dies somehow
 601         ;; (e.g. because of a SIGINT). In that case, we might as well
 602         ;; just give it up for a bad job, and stop trying to notify
 603         ;; the user of anything.
 604         ;;
 605         ;; Actually, the only way I've run across to exercise the
 606         ;; problem is to have more than one layer of shell script.
 607         ;; I have a shell script which does
 608         ;;   time nice -10 sh make.sh "$1" 2>&1 | tee make.tmp
 609         ;; and the problem occurs when I interrupt this with Ctrl-C
 610         ;; under Linux 2.2.14-5.0 and GNU bash, version 1.14.7(1).
 611         ;; I haven't figured out whether it's bash, time, tee, Linux, or
 612         ;; what that is responsible, but that it's possible at all
 613         ;; means that we should IGNORE-ERRORS here. -- WHN 2001-04-24
 614         (ignore-errors
 615          (%primitive print
 616                      "Argh! error within --disable-debugger error handling"))
 617         (failure-quit :recklessly-p t)))))
 618 \f
 619 ;;; a convenient way to get into the assembly-level debugger
 620 (defun %halt ()
 621   (%primitive sb!c:halt))