src/code/toplevel.lisp

   1 ;;;; stuff related to the toplevel read-eval-print loop, plus some
   2 ;;;; other miscellaneous functions that we don't have any better place
   3 ;;;; for
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!IMPL")
  15 \f
  16 ;;;; magic specials initialized by GENESIS
  17
  18 ;;; FIXME: The DEFVAR here is redundant with the (DECLAIM (SPECIAL ..))
  19 ;;; of all static symbols in early-impl.lisp.
  20 (progn
  21   (defvar sb!vm::*current-catch-block*)
  22   (defvar sb!vm::*current-unwind-protect-block*)
  23   (defvar *free-interrupt-context-index*))
  24 \f
  25 ;;; specials initialized by !COLD-INIT
  26
  27 ;;; FIXME: These could be converted to DEFVARs.
  28 (declaim (special *gc-inhibit* *need-to-collect-garbage*
  29                   *after-gc-hooks*
  30                   #!+(or x86 x86-64) *pseudo-atomic-atomic*
  31                   #!+(or x86 x86-64) *pseudo-atomic-interrupted*
  32                   sb!unix::*interrupts-enabled*
  33                   sb!unix::*interrupt-pending*
  34                   *type-system-initialized*))
  35
  36 (defvar *cold-init-complete-p*)
  37
  38 ;;; counts of nested errors (with internal errors double-counted)
  39 (defvar *maximum-error-depth*)
  40 (defvar *current-error-depth*)
  41
  42 ;;;; stepping control
  43 (defvar *step*)
  44 (defvar *stepping*)
  45 (defvar *step-form-stack* nil
  46   "A place for single steppers to push information about
  47 STEP-FORM-CONDITIONS avaiting the corresponding
  48 STEP-VALUES-CONDITIONS. The system is guaranteed to empty the stack
  49 when stepping terminates, so that it remains in sync, but doesn't
  50 modify it in any other way: it is provided for implmentors of single
  51 steppers to maintain contextual information.")
  52 \f
  53 ;;;; miscellaneous utilities for working with with TOPLEVEL
  54
  55 ;;; Execute BODY in a context where any %END-OF-THE-WORLD (thrown e.g.
  56 ;;; by QUIT) is caught and any final processing and return codes are
  57 ;;; handled appropriately.
  58 (defmacro handling-end-of-the-world (&body body)
  59   (with-unique-names (caught)
  60     `(let ((,caught (catch '%end-of-the-world
  61                       (/show0 "inside CATCH '%END-OF-THE-WORLD")
  62                       ,@body)))
  63       (/show0 "back from CATCH '%END-OF-THE-WORLD, flushing output")
  64       (flush-standard-output-streams)
  65       (sb!thread::terminate-session)
  66       (/show0 "calling UNIX-EXIT")
  67       (sb!unix:unix-exit ,caught))))
  68 \f
  69 ;;;; working with *CURRENT-ERROR-DEPTH* and *MAXIMUM-ERROR-DEPTH*
  70
  71 ;;; INFINITE-ERROR-PROTECT is used by ERROR and friends to keep us out
  72 ;;; of hyperspace.
  73 (defmacro infinite-error-protect (&rest forms)
  74   `(unless (infinite-error-protector)
  75      (/show0 "back from INFINITE-ERROR-PROTECTOR")
  76      (let ((*current-error-depth* (1+ *current-error-depth*)))
  77        (/show0 "in INFINITE-ERROR-PROTECT, incremented error depth")
  78        ;; arbitrary truncation
  79        #!+sb-show (sb!debug:backtrace 8)
  80        ,@forms)))
  81
  82 ;;; a helper function for INFINITE-ERROR-PROTECT
  83 (defun infinite-error-protector ()
  84   (/show0 "entering INFINITE-ERROR-PROTECTOR, *CURRENT-ERROR-DEPTH*=..")
  85   (/hexstr *current-error-depth*)
  86   (cond ((not *cold-init-complete-p*)
  87          (%primitive print "Argh! error in cold init, halting")
  88          (%primitive sb!c:halt))
  89         ((or (not (boundp '*current-error-depth*))
  90              (not (realp   *current-error-depth*))
  91              (not (boundp '*maximum-error-depth*))
  92              (not (realp   *maximum-error-depth*)))
  93          (%primitive print "Argh! corrupted error depth, halting")
  94          (%primitive sb!c:halt))
  95         ((> *current-error-depth* *maximum-error-depth*)
  96          (/show0 "*MAXIMUM-ERROR-DEPTH*=..")
  97          (/hexstr *maximum-error-depth*)
  98          (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
  99          (error-error "Help! "
 100                       *current-error-depth*
 101                       " nested errors. "
 102                       "SB-KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 103          t)
 104         (t
 105          (/show0 "returning normally from INFINITE-ERROR-PROTECTOR")
 106          nil)))
 107
 108 ;;; FIXME: I had a badly broken version of INFINITE-ERROR-PROTECTOR at
 109 ;;; one point (shown below), and SBCL cross-compiled it without
 110 ;;; warning about FORMS being undefined. Check whether that problem
 111 ;;; (missing warning) is repeatable in the final system and if so, fix
 112 ;;; it.
 113 #|
 114 (defun infinite-error-protector ()
 115   `(cond ((not *cold-init-complete-p*)
 116           (%primitive print "Argh! error in cold init, halting")
 117           (%primitive sb!c:halt))
 118          ((or (not (boundp '*current-error-depth*))
 119               (not (realp   *current-error-depth*))
 120               (not (boundp '*maximum-error-depth*))
 121               (not (realp   *maximum-error-depth*)))
 122           (%primitive print "Argh! corrupted error depth, halting")
 123           (%primitive sb!c:halt))
 124          ((> *current-error-depth* *maximum-error-depth*)
 125           (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
 126           (error-error "Help! "
 127                        *current-error-depth*
 128                        " nested errors. "
 129                        "SB-KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 130           (progn ,@forms)
 131           t)
 132          (t
 133           (/show0 "in INFINITE-ERROR-PROTECTOR, returning normally")
 134           nil)))
 135 |#
 136 \f
 137 ;;;; miscellaneous external functions
 138
 139 (defun sleep (n)
 140   #!+sb-doc
 141   "This function causes execution to be suspended for N seconds. N may
 142   be any non-negative, non-complex number."
 143   (when (or (not (realp n))
 144             (minusp n))
 145     (error 'simple-type-error
 146            :format-control "invalid argument to SLEEP: ~S"
 147            :format-arguments (list n)
 148            :datum n
 149            :expected-type '(real 0)))
 150   (multiple-value-bind (sec nsec)
 151       (if (integerp n)
 152           (values n 0)
 153           (multiple-value-bind (sec frac)
 154               (truncate n)
 155             (values sec (truncate frac 1e-9))))
 156     (sb!unix:nanosleep sec nsec))
 157   nil)
 158 \f
 159 ;;;; SCRUB-CONTROL-STACK
 160
 161 (defconstant bytes-per-scrub-unit 2048)
 162
 163 ;;; Zero the unused portion of the control stack so that old objects
 164 ;;; are not kept alive because of uninitialized stack variables.
 165
 166 ;;; "To summarize the problem, since not all allocated stack frame
 167 ;;; slots are guaranteed to be written by the time you call an another
 168 ;;; function or GC, there may be garbage pointers retained in your
 169 ;;; dead stack locations.  The stack scrubbing only affects the part
 170 ;;; of the stack from the SP to the end of the allocated stack."
 171 ;;; - ram, on cmucl-imp, Tue, 25 Sep 2001
 172
 173 ;;; So, as an (admittedly lame) workaround, from time to time we call
 174 ;;; scrub-control-stack to zero out all the unused portion.  This is
 175 ;;; supposed to happen when the stack is mostly empty, so that we have
 176 ;;; a chance of clearing more of it: callers are currently (2002.07.18)
 177 ;;; REPL and SUB-GC
 178
 179 (defun scrub-control-stack ()
 180   (declare (optimize (speed 3) (safety 0))
 181            (values (unsigned-byte 20))) ; FIXME: DECLARE VALUES?
 182
 183   #!-stack-grows-downward-not-upward
 184   (let* ((csp (sap-int (sb!c::control-stack-pointer-sap)))
 185          (initial-offset (logand csp (1- bytes-per-scrub-unit)))
 186          (end-of-stack
 187           (- (sb!vm:fixnumize sb!vm:*control-stack-end*)
 188              sb!c:*backend-page-size*)))
 189     (labels
 190         ((scrub (ptr offset count)
 191            (declare (type system-area-pointer ptr)
 192                     (type (unsigned-byte 16) offset)
 193                     (type (unsigned-byte 20) count)
 194                     (values (unsigned-byte 20)))
 195            (cond ((>= (sap-int ptr) end-of-stack) 0)
 196                  ((= offset bytes-per-scrub-unit)
 197                   (look (sap+ ptr bytes-per-scrub-unit) 0 count))
 198                  (t
 199                   (setf (sap-ref-word ptr offset) 0)
 200                   (scrub ptr (+ offset sb!vm:n-word-bytes) count))))
 201          (look (ptr offset count)
 202            (declare (type system-area-pointer ptr)
 203                     (type (unsigned-byte 16) offset)
 204                     (type (unsigned-byte 20) count)
 205                     (values (unsigned-byte 20)))
 206            (cond ((>= (sap-int ptr) end-of-stack) 0)
 207                  ((= offset bytes-per-scrub-unit)
 208                   count)
 209                  ((zerop (sap-ref-word ptr offset))
 210                   (look ptr (+ offset sb!vm:n-word-bytes) count))
 211                  (t
 212                   (scrub ptr offset (+ count sb!vm:n-word-bytes))))))
 213       (declare (type sb!vm::word csp))
 214       (scrub (int-sap (- csp initial-offset))
 215              (* (floor initial-offset sb!vm:n-word-bytes) sb!vm:n-word-bytes)
 216              0)))
 217
 218   #!+stack-grows-downward-not-upward
 219   (let* ((csp (sap-int (sb!c::control-stack-pointer-sap)))
 220          (end-of-stack (+ (sb!vm:fixnumize sb!vm:*control-stack-start*)
 221                           sb!c:*backend-page-size*))
 222          (initial-offset (logand csp (1- bytes-per-scrub-unit))))
 223     (labels
 224         ((scrub (ptr offset count)
 225            (declare (type system-area-pointer ptr)
 226                     (type (unsigned-byte 16) offset)
 227                     (type (unsigned-byte 20) count)
 228                     (values (unsigned-byte 20)))
 229            (let ((loc (int-sap (- (sap-int ptr) (+ offset sb!vm:n-word-bytes)))))
 230              (cond ((< (sap-int loc) end-of-stack) 0)
 231                    ((= offset bytes-per-scrub-unit)
 232                     (look (int-sap (- (sap-int ptr) bytes-per-scrub-unit))
 233                           0 count))
 234                    (t ;; need to fix bug in %SET-STACK-REF
 235                     (setf (sap-ref-word loc 0) 0)
 236                     (scrub ptr (+ offset sb!vm:n-word-bytes) count)))))
 237          (look (ptr offset count)
 238            (declare (type system-area-pointer ptr)
 239                     (type (unsigned-byte 16) offset)
 240                     (type (unsigned-byte 20) count)
 241                     (values (unsigned-byte 20)))
 242            (let ((loc (int-sap (- (sap-int ptr) offset))))
 243              (cond ((< (sap-int loc) end-of-stack) 0)
 244                    ((= offset bytes-per-scrub-unit)
 245                     count)
 246                    ((zerop (sb!kernel::get-lisp-obj-address (stack-ref loc 0)))
 247                     (look ptr (+ offset sb!vm:n-word-bytes) count))
 248                    (t
 249                     (scrub ptr offset (+ count sb!vm:n-word-bytes)))))))
 250       (declare (type sb!vm::word csp))
 251       (scrub (int-sap (+ csp initial-offset))
 252              (* (floor initial-offset sb!vm:n-word-bytes) sb!vm:n-word-bytes)
 253              0))))
 254 \f
 255 ;;;; the default toplevel function
 256
 257 (defvar / nil
 258   #!+sb-doc
 259   "a list of all the values returned by the most recent top level EVAL")
 260 (defvar //  nil #!+sb-doc "the previous value of /")
 261 (defvar /// nil #!+sb-doc "the previous value of //")
 262 (defvar *   nil #!+sb-doc "the value of the most recent top level EVAL")
 263 (defvar **  nil #!+sb-doc "the previous value of *")
 264 (defvar *** nil #!+sb-doc "the previous value of **")
 265 (defvar +   nil #!+sb-doc "the value of the most recent top level READ")
 266 (defvar ++  nil #!+sb-doc "the previous value of +")
 267 (defvar +++ nil #!+sb-doc "the previous value of ++")
 268 (defvar -   nil #!+sb-doc "the form currently being evaluated")
 269
 270 (defun interactive-eval (form)
 271   "Evaluate FORM, returning whatever it returns and adjusting ***, **, *,
 272    +++, ++, +, ///, //, /, and -."
 273   (setf - form)
 274   (unwind-protect
 275        (let ((results (multiple-value-list (eval form))))
 276          (setf /// //
 277                // /
 278                / results
 279                *** **
 280                ** *
 281                * (car results)))
 282     (setf +++ ++
 283           ++ +
 284           + -))
 285   (unless (boundp '*)
 286     ;; The bogon returned an unbound marker.
 287     ;; FIXME: It would be safer to check every one of the values in RESULTS,
 288     ;; instead of just the first one.
 289     (setf * nil)
 290     (cerror "Go on with * set to NIL."
 291             "EVAL returned an unbound marker."))
 292   (values-list /))
 293
 294 ;;; Flush anything waiting on one of the ANSI Common Lisp standard
 295 ;;; output streams before proceeding.
 296 (defun flush-standard-output-streams ()
 297   (dolist (name '(*debug-io*
 298                   *error-output*
 299                   *query-io*
 300                   *standard-output*
 301                   *trace-output*))
 302     (finish-output (symbol-value name)))
 303   (values))
 304
 305 (defun process-init-file (truename)
 306   (when truename
 307     (restart-case
 308         (with-open-file (s truename :if-does-not-exist nil)
 309           (flet ((next ()
 310                    (let ((form (read s nil s)))
 311                      (if (eq s form)
 312                          (return-from process-init-file nil)
 313                          (eval form)))))
 314             (loop
 315                (restart-case
 316                    (handler-bind ((error (lambda (e)
 317                                            (error
 318                                             "Error during processing of ~
 319                                             initialization file ~A:~%~%  ~A"
 320                                             truename e))))
 321                      (next))
 322                  (continue ()
 323                    :report "Ignore and continue processing.")))))
 324       (abort ()
 325         :report "Skip rest of initialization file."))))
 326
 327 (defun process-eval-options (eval-strings)
 328   (/show0 "handling --eval options")
 329   (flet ((process-1 (string)
 330            (multiple-value-bind (expr pos) (read-from-string string)
 331              (unless (eq string (read-from-string string nil string :start pos))
 332                (error "More the one expression in ~S" string))
 333              (eval expr)
 334              (flush-standard-output-streams))))
 335     (restart-case
 336         (dolist (expr-as-string eval-strings)
 337           (/show0 "handling one --eval option")
 338           (restart-case
 339               (handler-bind ((error (lambda (e)
 340                                       (error "Error during processing of --eval ~
 341                                               option ~S:~%~%  ~A"
 342                                              expr-as-string e))))
 343                 (process-1 expr-as-string))
 344             (continue ()
 345               :report "Ignore and continue with next --eval option.")))
 346       (abort ()
 347         :report "Skip rest of --eval options."))))
 348
 349 ;;; the default system top level function
 350 (defun toplevel-init ()
 351   (/show0 "entering TOPLEVEL-INIT")
 352   (let (;; value of --sysinit option
 353         (sysinit nil)
 354         ;; value of --userinit option
 355         (userinit nil)
 356         ;; values of --eval options, in reverse order; and also any
 357         ;; other options (like --load) which're translated into --eval
 358         ;;
 359         ;; The values are stored as strings, so that they can be
 360         ;; passed to READ only after their predecessors have been
 361         ;; EVALed, so that things work when e.g. REQUIRE in one EVAL
 362         ;; form creates a package referred to in the next EVAL form.
 363         (reversed-evals nil)
 364         ;; Has a --noprint option been seen?
 365         (noprint nil)
 366         ;; everything in *POSIX-ARGV* except for argv[0]=programname
 367         (options (rest *posix-argv*)))
 368
 369     (declare (type list options))
 370
 371     (/show0 "done with outer LET in TOPLEVEL-INIT")
 372
 373     ;; FIXME: There are lots of ways for errors to happen around here
 374     ;; (e.g. bad command line syntax, or READ-ERROR while trying to
 375     ;; READ an --eval string). Make sure that they're handled
 376     ;; reasonably.
 377
 378     ;; Process command line options.
 379     (flet (;; Errors while processing the command line cause the system
 380            ;; to QUIT, instead of trying to go into the Lisp debugger,
 381            ;; because trying to go into the Lisp debugger would get
 382            ;; into various annoying issues of where we should go after
 383            ;; the user tries to return from the debugger.
 384            (startup-error (control-string &rest args)
 385              (format
 386               *error-output*
 387               "fatal error before reaching READ-EVAL-PRINT loop: ~%  ~?~%"
 388               control-string
 389               args)
 390              (quit :unix-status 1)))
 391       (loop while options do
 392             (/show0 "at head of LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 393             (let ((option (first options)))
 394               (flet ((pop-option ()
 395                        (if options
 396                            (pop options)
 397                            (startup-error
 398                             "unexpected end of command line options"))))
 399                 (cond ((string= option "--sysinit")
 400                        (pop-option)
 401                        (if sysinit
 402                            (startup-error "multiple --sysinit options")
 403                            (setf sysinit (pop-option))))
 404                       ((string= option "--userinit")
 405                        (pop-option)
 406                        (if userinit
 407                            (startup-error "multiple --userinit options")
 408                            (setf userinit (pop-option))))
 409                       ((string= option "--eval")
 410                        (pop-option)
 411                        (push (pop-option) reversed-evals))
 412                       ((string= option "--load")
 413                        (pop-option)
 414                        (push
 415                         ;; FIXME: see BUG 296
 416                         (concatenate 'string "(|LOAD| \"" (pop-option) "\")")
 417                         reversed-evals))
 418                       ((string= option "--noprint")
 419                        (pop-option)
 420                        (setf noprint t))
 421                       ((string= option "--disable-debugger")
 422                        (pop-option)
 423                        (push "(|DISABLE-DEBUGGER|)" reversed-evals))
 424                       ((string= option "--end-toplevel-options")
 425                        (pop-option)
 426                        (return))
 427                       (t
 428                        ;; Anything we don't recognize as a toplevel
 429                        ;; option must be the start of user-level
 430                        ;; options.. except that if we encounter
 431                        ;; "--end-toplevel-options" after we gave up
 432                        ;; because we didn't recognize an option as a
 433                        ;; toplevel option, then the option we gave up on
 434                        ;; must have been an error. (E.g. in
 435                        ;;  "sbcl --eval '(a)' --eval'(b)' --end-toplevel-options"
 436                        ;; this test will let us detect that the string
 437                        ;; "--eval(b)" is an error.)
 438                        (if (find "--end-toplevel-options" options
 439                                  :test #'string=)
 440                            (startup-error "bad toplevel option: ~S"
 441                                           (first options))
 442                            (return)))))))
 443       (/show0 "done with LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 444
 445       ;; Delete all the options that we processed, so that only
 446       ;; user-level options are left visible to user code.
 447       (setf (rest *posix-argv*) options)
 448
 449       ;; Handle initialization files.
 450       (/show0 "handling initialization files in TOPLEVEL-INIT")
 451       (flet (;; shared idiom for searching for SYSINITish and
 452              ;; USERINITish files
 453              (probe-init-files (explicitly-specified-init-file-name
 454                                 &rest default-init-file-names)
 455                (declare (type list default-init-file-names))
 456                (if explicitly-specified-init-file-name
 457                    (or (probe-file explicitly-specified-init-file-name)
 458                         (startup-error "The file ~S was not found."
 459                                        explicitly-specified-init-file-name))
 460                    (find-if (lambda (x)
 461                               (and (stringp x) (probe-file x)))
 462                             default-init-file-names)))
 463              ;; shared idiom for creating default names for
 464              ;; SYSINITish and USERINITish files
 465              (init-file-name (maybe-dir-name basename)
 466                (and maybe-dir-name
 467                     (concatenate 'string maybe-dir-name "/" basename))))
 468         (let ((sysinit-truename
 469                (probe-init-files sysinit
 470                                  (init-file-name (posix-getenv "SBCL_HOME")
 471                                                  "sbclrc")
 472                                  "/etc/sbclrc"))
 473                (userinit-truename
 474                 (probe-init-files userinit
 475                                   (init-file-name (posix-getenv "HOME")
 476                                                   ".sbclrc"))))
 477
 478           ;; This CATCH is needed for the debugger command TOPLEVEL to
 479           ;; work.
 480           (catch 'toplevel-catcher
 481             ;; We wrap all the pre-REPL user/system customized startup
 482             ;; code in a restart.
 483             ;;
 484             ;; (Why not wrap everything, even the stuff above, in this
 485             ;; restart? Errors above here are basically command line
 486             ;; or Unix environment errors, e.g. a missing file or a
 487             ;; typo on the Unix command line, and you don't need to
 488             ;; get into Lisp to debug them, you should just start over
 489             ;; and do it right at the Unix level. Errors below here
 490             ;; are generally errors in user Lisp code, and it might be
 491             ;; helpful to let the user reach the REPL in order to help
 492             ;; figure out what's going on.)
 493             (restart-case
 494                 (progn
 495                   (process-init-file sysinit-truename)
 496                   (process-init-file userinit-truename)
 497                   (process-eval-options (reverse reversed-evals)))
 498               (abort ()
 499                 :report "Skip to toplevel READ/EVAL/PRINT loop."
 500                 (/show0 "CONTINUEing from pre-REPL RESTART-CASE")
 501                 (values))                 ; (no-op, just fall through)
 502               (quit ()
 503                 :report "Quit SBCL (calling #'QUIT, killing the process)."
 504                 (/show0 "falling through to QUIT from pre-REPL RESTART-CASE")
 505                 (quit)))))
 506
 507         ;; one more time for good measure, in case we fell out of the
 508         ;; RESTART-CASE above before one of the flushes in the ordinary
 509         ;; flow of control had a chance to operate
 510         (flush-standard-output-streams)
 511
 512         (/show0 "falling into TOPLEVEL-REPL from TOPLEVEL-INIT")
 513         (toplevel-repl noprint)
 514         ;; (classic CMU CL error message: "You're certainly a clever child.":-)
 515         (critically-unreachable "after TOPLEVEL-REPL")))))
 516
 517 ;;; hooks to support customized toplevels like ACL-style toplevel from
 518 ;;; KMR on sbcl-devel 2002-12-21.  Altered by CSR 2003-11-16 for
 519 ;;; threaded operation: altered *REPL-FUN* to *REPL-FUN-GENERATOR*.
 520 (defvar *repl-read-form-fun* #'repl-read-form-fun
 521   "a function of two stream arguments IN and OUT for the toplevel REPL to
 522   call: Return the next Lisp form to evaluate (possibly handling other
 523   magic -- like ACL-style keyword commands -- which precede the next
 524   Lisp form). The OUT stream is there to support magic which requires
 525   issuing new prompts.")
 526 (defvar *repl-prompt-fun* #'repl-prompt-fun
 527   "a function of one argument STREAM for the toplevel REPL to call: Prompt
 528   the user for input.")
 529 (defvar *repl-fun-generator* (constantly #'repl-fun)
 530   "a function of no arguments returning a function of one argument
 531   NOPRINT that provides the REPL for the system.  Assumes that
 532   *STANDARD-INPUT* and *STANDARD-OUTPUT* are set up.")
 533
 534 ;;; read-eval-print loop for the default system toplevel
 535 (defun toplevel-repl (noprint)
 536   (/show0 "entering TOPLEVEL-REPL")
 537   (let ((* nil) (** nil) (*** nil)
 538         (- nil)
 539         (+ nil) (++ nil) (+++ nil)
 540         (/// nil) (// nil) (/ nil))
 541     (/show0 "about to funcall *REPL-FUN-GENERATOR*")
 542     (let ((repl-fun (funcall *repl-fun-generator*)))
 543       ;; Each REPL in a multithreaded world should have bindings of
 544       ;; most CL specials (most critically *PACKAGE*).
 545       (with-rebound-io-syntax
 546           (handler-bind ((step-condition 'invoke-stepper))
 547             (let ((*stepping* nil)
 548                   (*step* nil))
 549               (loop
 550                (/show0 "about to set up restarts in TOPLEVEL-REPL")
 551                  ;; CLHS recommends that there should always be an
 552                  ;; ABORT restart; we have this one here, and one per
 553                  ;; debugger level.
 554                  (with-simple-restart
 555                      (abort "~@<Exit debugger, returning to top level.~@:>")
 556                    (catch 'toplevel-catcher
 557                      (sb!unix::reset-signal-mask)
 558                      ;; In the event of a control-stack-exhausted-error, we
 559                      ;; should have unwound enough stack by the time we get
 560                      ;; here that this is now possible.
 561                      (sb!kernel::protect-control-stack-guard-page 1)
 562                      (funcall repl-fun noprint)
 563                      (critically-unreachable "after REPL"))))))))))
 564
 565 ;;; Our default REPL prompt is the minimal traditional one.
 566 (defun repl-prompt-fun (stream)
 567   (fresh-line stream)
 568   (write-string "* " stream)) ; arbitrary but customary REPL prompt
 569
 570 ;;; Our default form reader does relatively little magic, but does
 571 ;;; handle the Unix-style EOF-is-end-of-process convention.
 572 (defun repl-read-form-fun (in out)
 573   (declare (type stream in out) (ignore out))
 574   (let* ((eof-marker (cons nil nil))
 575          (form (read in nil eof-marker)))
 576     (if (eq form eof-marker)
 577         (quit)
 578         form)))
 579
 580 (defun repl-fun (noprint)
 581   (/show0 "entering REPL")
 582   (loop
 583    (unwind-protect
 584         (progn
 585           ;; (See comment preceding the definition of SCRUB-CONTROL-STACK.)
 586           (scrub-control-stack)
 587           (sb!thread::get-foreground)
 588           (unless noprint
 589             (funcall *repl-prompt-fun* *standard-output*)
 590             ;; (Should *REPL-PROMPT-FUN* be responsible for doing its own
 591             ;; FORCE-OUTPUT? I can't imagine a valid reason for it not to
 592             ;; be done here, so leaving it up to *REPL-PROMPT-FUN* seems
 593             ;; odd. But maybe there *is* a valid reason in some
 594             ;; circumstances? perhaps some deadlock issue when being driven
 595             ;; by another process or something...)
 596             (force-output *standard-output*))
 597           (let* ((form (funcall *repl-read-form-fun*
 598                                 *standard-input*
 599                                 *standard-output*))
 600                  (results (multiple-value-list (interactive-eval form))))
 601             (unless noprint
 602               (dolist (result results)
 603                 (fresh-line)
 604                 (prin1 result)))))
 605      ;; If we started stepping in the debugger we want to stop now.
 606      (setf *stepping* nil
 607            *step* nil))))
 608 \f
 609 ;;; a convenient way to get into the assembly-level debugger
 610 (defun %halt ()
 611   (%primitive sb!c:halt))