src/code/toplevel.lisp

   1 ;;;; stuff related to the toplevel read-eval-print loop, plus some
   2 ;;;; other miscellaneous functions that we don't have any better place
   3 ;;;; for
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!IMPL")
  15 \f
  16 (defconstant most-positive-fixnum #.sb!vm:*target-most-positive-fixnum*
  17   #!+sb-doc
  18   "The fixnum closest in value to positive infinity.")
  19
  20 (defconstant most-negative-fixnum #.sb!vm:*target-most-negative-fixnum*
  21   #!+sb-doc
  22   "The fixnum closest in value to negative infinity.")
  23 \f
  24 ;;;; magic specials initialized by genesis
  25
  26 #!-gengc
  27 (progn
  28   (defvar *current-catch-block*)
  29   (defvar *current-unwind-protect-block*)
  30   (defvar *free-interrupt-context-index*))
  31 \f
  32 ;;; specials initialized by !COLD-INIT
  33
  34 ;;; FIXME: These could be converted to DEFVARs, and the stuff shared
  35 ;;; in both #!+GENGC and #!-GENGC (actually everything in #!+GENGC)
  36 ;;; could be made non-conditional.
  37 (declaim
  38   #!-gengc
  39   (special *gc-inhibit* *already-maybe-gcing*
  40            *need-to-collect-garbage*
  41            *gc-notify-stream*
  42            *before-gc-hooks* *after-gc-hooks*
  43            #!+x86 *pseudo-atomic-atomic*
  44            #!+x86 *pseudo-atomic-interrupted*
  45            sb!unix::*interrupts-enabled*
  46            sb!unix::*interrupt-pending*
  47            *type-system-initialized*)
  48   #!+gengc
  49   (special *before-gc-hooks* *after-gc-hooks*
  50            *gc-notify-stream*
  51            *type-system-initialized*))
  52
  53 (defvar *cold-init-complete-p*)
  54
  55 ;;; counts of nested errors (with internal errors double-counted)
  56 (defvar *maximum-error-depth*)
  57 (defvar *current-error-depth*)
  58 \f
  59 ;;;; miscellaneous utilities for working with with TOPLEVEL
  60
  61 ;;; Execute BODY in a context where any %END-OF-THE-WORLD (thrown e.g.
  62 ;;; by QUIT) is caught and any final processing and return codes are
  63 ;;; handled appropriately.
  64 (defmacro handling-end-of-the-world (&body body)
  65   (let ((caught (gensym "CAUGHT")))
  66     `(let ((,caught (catch '%end-of-the-world
  67                       (/show0 "inside CATCH '%END-OF-THE-WORLD")
  68                       ,@body)))
  69        (/show0 "back from CATCH '%END-OF-THE-WORLD, flushing output")
  70        (flush-standard-output-streams)
  71        (/show0 "calling UNIX-EXIT")
  72        (sb!unix:unix-exit ,caught))))
  73 \f
  74 ;;;; working with *CURRENT-ERROR-DEPTH* and *MAXIMUM-ERROR-DEPTH*
  75
  76 ;;; INFINITE-ERROR-PROTECT is used by ERROR and friends to keep us out of
  77 ;;; hyperspace.
  78 (defmacro infinite-error-protect (&rest forms)
  79   `(unless (infinite-error-protector)
  80      (let ((*current-error-depth* (1+ *current-error-depth*)))
  81        ,@forms)))
  82
  83 ;;; a helper function for INFINITE-ERROR-PROTECT
  84 (defun infinite-error-protector ()
  85   (cond ((not *cold-init-complete-p*)
  86          (%primitive print "Argh! error in cold init, halting")
  87          (%primitive sb!c:halt))
  88         ((or (not (boundp '*current-error-depth*))
  89              (not (realp   *current-error-depth*))
  90              (not (boundp '*maximum-error-depth*))
  91              (not (realp   *maximum-error-depth*)))
  92          (%primitive print "Argh! corrupted error depth, halting")
  93          (%primitive sb!c:halt))
  94         ((> *current-error-depth* *maximum-error-depth*)
  95          (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
  96          (error-error "Help! "
  97                       *current-error-depth*
  98                       " nested errors. "
  99                       "KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 100          t)
 101         (t
 102          nil)))
 103
 104 ;;; FIXME: I had a badly broken version of INFINITE-ERROR-PROTECTOR at
 105 ;;; one point (shown below), and SBCL cross-compiled it without
 106 ;;; warning about FORMS being undefined. Check whether that problem
 107 ;;; (missing warning) is repeatable in the final system and if so, fix
 108 ;;; it.
 109 #|
 110 (defun infinite-error-protector ()
 111   `(cond ((not *cold-init-complete-p*)
 112           (%primitive print "Argh! error in cold init, halting")
 113           (%primitive sb!c:halt))
 114          ((or (not (boundp '*current-error-depth*))
 115               (not (realp   *current-error-depth*))
 116               (not (boundp '*maximum-error-depth*))
 117               (not (realp   *maximum-error-depth*)))
 118           (%primitive print "Argh! corrupted error depth, halting")
 119           (%primitive sb!c:halt))
 120          ((> *current-error-depth* *maximum-error-depth*)
 121           (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
 122           (error-error "Help! "
 123                        *current-error-depth*
 124                        " nested errors. "
 125                        "KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 126           (progn ,@forms)
 127           t)
 128          (t
 129           (/show0 "in INFINITE-ERROR-PROTECTOR, returning normally")
 130           nil)))
 131 |#
 132 \f
 133 ;;;; miscellaneous external functions
 134
 135 #!-mp ; The multi-processing version is defined in multi-proc.lisp.
 136 (defun sleep (n)
 137   #!+sb-doc
 138   "This function causes execution to be suspended for N seconds. N may
 139   be any non-negative, non-complex number."
 140   (when (or (not (realp n))
 141             (minusp n))
 142     (error "Invalid argument to SLEEP: ~S.~%~
 143             Must be a non-negative, non-complex number."
 144            n))
 145   (multiple-value-bind (sec usec)
 146       (if (integerp n)
 147           (values n 0)
 148           (multiple-value-bind (sec frac)
 149               (truncate n)
 150             (values sec(truncate frac 1e-6))))
 151     (sb!unix:unix-select 0 0 0 0 sec usec))
 152   nil)
 153 \f
 154 ;;;; SCRUB-CONTROL-STACK
 155
 156 (defconstant bytes-per-scrub-unit 2048)
 157
 158 (defun scrub-control-stack ()
 159   #!+sb-doc
 160   "Zero the unused portion of the control stack so that old objects are not
 161    kept alive because of uninitialized stack variables."
 162   ;; FIXME: Why do we need to do this instead of just letting GC read
 163   ;; the stack pointer and avoid messing with the unused portion of
 164   ;; the control stack? (Is this a multithreading thing where there's
 165   ;; one control stack and stack pointer per thread, and it might not
 166   ;; be easy to tell what a thread's stack pointer value is when
 167   ;; looking in from another thread?)
 168   (declare (optimize (speed 3) (safety 0))
 169            (values (unsigned-byte 20))) ; FIXME: DECLARE VALUES?
 170
 171   #!-x86 ; machines where stack grows upwards (I guess) -- WHN 19990906
 172   (labels
 173       ((scrub (ptr offset count)
 174          (declare (type system-area-pointer ptr)
 175                   (type (unsigned-byte 16) offset)
 176                   (type (unsigned-byte 20) count)
 177                   (values (unsigned-byte 20)))
 178          (cond ((= offset bytes-per-scrub-unit)
 179                 (look (sap+ ptr bytes-per-scrub-unit) 0 count))
 180                (t
 181                 (setf (sap-ref-32 ptr offset) 0)
 182                 (scrub ptr (+ offset sb!vm:word-bytes) count))))
 183        (look (ptr offset count)
 184          (declare (type system-area-pointer ptr)
 185                   (type (unsigned-byte 16) offset)
 186                   (type (unsigned-byte 20) count)
 187                   (values (unsigned-byte 20)))
 188          (cond ((= offset bytes-per-scrub-unit)
 189                 count)
 190                ((zerop (sap-ref-32 ptr offset))
 191                 (look ptr (+ offset sb!vm:word-bytes) count))
 192                (t
 193                 (scrub ptr offset (+ count sb!vm:word-bytes))))))
 194     (let* ((csp (sap-int (sb!c::control-stack-pointer-sap)))
 195            (initial-offset (logand csp (1- bytes-per-scrub-unit))))
 196       (declare (type (unsigned-byte 32) csp))
 197       (scrub (int-sap (- csp initial-offset))
 198              (* (floor initial-offset sb!vm:word-bytes) sb!vm:word-bytes)
 199              0)))
 200
 201   #!+x86 ;; (Stack grows downwards.)
 202   (labels
 203       ((scrub (ptr offset count)
 204          (declare (type system-area-pointer ptr)
 205                   (type (unsigned-byte 16) offset)
 206                   (type (unsigned-byte 20) count)
 207                   (values (unsigned-byte 20)))
 208          (let ((loc (int-sap (- (sap-int ptr) (+ offset sb!vm:word-bytes)))))
 209            (cond ((= offset bytes-per-scrub-unit)
 210                   (look (int-sap (- (sap-int ptr) bytes-per-scrub-unit))
 211                         0 count))
 212                  (t ;; need to fix bug in %SET-STACK-REF
 213                   (setf (sap-ref-32 loc 0) 0)
 214                   (scrub ptr (+ offset sb!vm:word-bytes) count)))))
 215        (look (ptr offset count)
 216          (declare (type system-area-pointer ptr)
 217                   (type (unsigned-byte 16) offset)
 218                   (type (unsigned-byte 20) count)
 219                   (values (unsigned-byte 20)))
 220          (let ((loc (int-sap (- (sap-int ptr) offset))))
 221            (cond ((= offset bytes-per-scrub-unit)
 222                   count)
 223                  ((zerop (sb!kernel::get-lisp-obj-address (stack-ref loc 0)))
 224                   (look ptr (+ offset sb!vm:word-bytes) count))
 225                  (t
 226                   (scrub ptr offset (+ count sb!vm:word-bytes)))))))
 227     (let* ((csp (sap-int (sb!c::control-stack-pointer-sap)))
 228            (initial-offset (logand csp (1- bytes-per-scrub-unit))))
 229       (declare (type (unsigned-byte 32) csp))
 230       (scrub (int-sap (+ csp initial-offset))
 231              (* (floor initial-offset sb!vm:word-bytes) sb!vm:word-bytes)
 232              0))))
 233 \f
 234 ;;;; the default toplevel function
 235
 236 ;;; FIXME: Most stuff below here can probably be byte-compiled.
 237
 238 (defvar / nil
 239   #!+sb-doc
 240   "a list of all the values returned by the most recent top-level EVAL")
 241 (defvar //  nil #!+sb-doc "the previous value of /")
 242 (defvar /// nil #!+sb-doc "the previous value of //")
 243 (defvar *   nil #!+sb-doc "the value of the most recent top-level EVAL")
 244 (defvar **  nil #!+sb-doc "the previous value of *")
 245 (defvar *** nil #!+sb-doc "the previous value of **")
 246 (defvar +   nil #!+sb-doc "the value of the most recent top-level READ")
 247 (defvar ++  nil #!+sb-doc "the previous value of +")
 248 (defvar +++ nil #!+sb-doc "the previous value of ++")
 249 (defvar -   nil #!+sb-doc "the form currently being evaluated")
 250 (defvar *prompt* "* "
 251   #!+sb-doc
 252   "The top-level prompt string. This also may be a function of no arguments
 253    that returns a simple-string.")
 254
 255 (defun interactive-eval (form)
 256   "Evaluate FORM, returning whatever it returns and adjusting ***, **, *,
 257    +++, ++, +, ///, //, /, and -."
 258   (setf - form)
 259   (let ((results (multiple-value-list (eval form))))
 260     (setf /// //
 261           // /
 262           / results
 263           *** **
 264           ** *
 265           * (car results)))
 266   (setf +++ ++
 267         ++ +
 268         + -)
 269   (unless (boundp '*)
 270     ;; The bogon returned an unbound marker.
 271     ;; FIXME: It would be safer to check every one of the values in RESULTS,
 272     ;; instead of just the first one.
 273     (setf * nil)
 274     (cerror "Go on with * set to NIL."
 275             "EVAL returned an unbound marker."))
 276   (values-list /))
 277
 278 ;;; Flush anything waiting on one of the ANSI Common Lisp standard
 279 ;;; output streams before proceeding.
 280 (defun flush-standard-output-streams ()
 281   (dolist (name '(*debug-io*
 282                   *error-output*
 283                   *query-io*
 284                   *standard-output*
 285                   *trace-output*))
 286     (finish-output (symbol-value name)))
 287   (values))
 288
 289 ;;; the default system top-level function
 290 (defun toplevel-init ()
 291
 292   (/show0 "entering TOPLEVEL-INIT")
 293
 294   (let ((sysinit nil)      ; value of --sysinit option
 295         (userinit nil)     ; value of --userinit option
 296         (evals nil)        ; values of --eval options (in reverse order)
 297         (noprint nil)      ; Has a --noprint option been seen?
 298         (noprogrammer nil) ; Has a --noprogammer option been seen?
 299         (options (rest *posix-argv*))) ; skipping program name
 300
 301     (/show0 "done with outer LET in TOPLEVEL-INIT")
 302
 303     ;; FIXME: There are lots of ways for errors to happen around here
 304     ;; (e.g. bad command line syntax, or READ-ERROR while trying to
 305     ;; READ an --eval string). Make sure that they're handled
 306     ;; reasonably. Also, perhaps all errors while parsing the command
 307     ;; line should cause the system to QUIT, instead of trying to go
 308     ;; into the Lisp debugger.
 309
 310     ;; Parse command line options.
 311     (loop while options do
 312           (/show0 "at head of LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 313           (let ((option (first options)))
 314             (flet ((pop-option ()
 315                      (if options
 316                          (pop options)
 317                          (error "unexpected end of command line options"))))
 318               (cond ((string= option "--sysinit")
 319                      (pop-option)
 320                      (if sysinit
 321                          (error "multiple --sysinit options")
 322                          (setf sysinit (pop-option))))
 323                     ((string= option "--userinit")
 324                      (pop-option)
 325                      (if userinit
 326                          (error "multiple --userinit options")
 327                          (setf userinit (pop-option))))
 328                     ((string= option "--eval")
 329                      (pop-option)
 330                      (let ((eval-as-string (pop-option)))
 331                        (with-input-from-string (eval-stream eval-as-string)
 332                          (let* ((eof-marker (cons :eof :eof))
 333                                 (eval (read eval-stream nil eof-marker))
 334                                 (eof (read eval-stream nil eof-marker)))
 335                            (cond ((eq eval eof-marker)
 336                                   (error "unable to parse ~S"
 337                                          eval-as-string))
 338                                  ((not (eq eof eof-marker))
 339                                   (error "more than one expression in ~S"
 340                                          eval-as-string))
 341                                  (t
 342                                   (push eval evals)))))))
 343                     ((string= option "--noprint")
 344                      (pop-option)
 345                      (setf noprint t))
 346                     ((string= option "--noprogrammer")
 347                      (pop-option)
 348                      (setf noprogrammer t))
 349                     ((string= option "--end-toplevel-options")
 350                      (pop-option)
 351                      (return))
 352                     (t
 353                      ;; Anything we don't recognize as a toplevel
 354                      ;; option must be the start of user-level
 355                      ;; options.. except that if we encounter
 356                      ;; "--end-toplevel-options" after we gave up
 357                      ;; because we didn't recognize an option as a
 358                      ;; toplevel option, then the option we gave up on
 359                      ;; must have been an error. (E.g. in
 360                      ;;  "sbcl --eval '(a)' --eval'(b)' --end-toplevel-options"
 361                      ;; this test will let us detect that the string
 362                      ;; "--eval(b)" is an error.)
 363                      (if (find "--end-toplevel-options" options
 364                                :test #'string=)
 365                          (error "bad toplevel option: ~S" (first options))
 366                          (return)))))))
 367     (/show0 "done with LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 368
 369     ;; Excise all the options that we processed, so that only
 370     ;; user-level options are left visible to user code.
 371     (setf (rest *posix-argv*) options)
 372
 373     ;; Handle --noprogrammer option. We intentionally do this
 374     ;; early so that it will affect the handling of initialization
 375     ;; files and --eval options.
 376     (/show0 "handling --noprogrammer option in TOPLEVEL-INIT")
 377     (when noprogrammer
 378       (setf *debugger-hook* 'noprogrammer-debugger-hook-fun
 379             *debug-io* *error-output*))
 380
 381     ;; FIXME: Verify that errors in init files and/or --eval operations
 382     ;; lead to reasonable behavior.
 383
 384     ;; Handle initialization files.
 385     (/show0 "handling initialization files in TOPLEVEL-INIT")
 386     (flet (;; If any of POSSIBLE-INIT-FILE-NAMES names a real file,
 387            ;; return its truename.
 388            (probe-init-files (&rest possible-init-file-names)
 389              (/show0 "entering PROBE-INIT-FILES")
 390              (prog1
 391                  (find-if (lambda (x)
 392                             (and (stringp x) (probe-file x)))
 393                           possible-init-file-names)
 394                (/show0 "leaving PROBE-INIT-FILES"))))
 395       (let* ((sbcl-home (posix-getenv "SBCL_HOME"))
 396              (sysinit-truename (if sbcl-home
 397                                    (probe-init-files sysinit
 398                                                      (concatenate
 399                                                       'string
 400                                                       sbcl-home
 401                                                       "/sbclrc"))
 402                                    (probe-init-files sysinit
 403                                                      "/etc/sbclrc"
 404                                                      "/usr/local/etc/sbclrc")))
 405              (user-home (or (posix-getenv "HOME")
 406                             (error "The HOME environment variable is unbound, ~
 407                                     so user init file can't be found.")))
 408              (userinit-truename (probe-init-files userinit
 409                                                   (concatenate
 410                                                    'string
 411                                                    user-home
 412                                                    "/.sbclrc"))))
 413         (/show0 "assigned SYSINIT-TRUENAME and USERINIT-TRUENAME")
 414         (when sysinit-truename
 415           (unless (load sysinit-truename)
 416             (error "~S was not successfully loaded." sysinit-truename))
 417           (flush-standard-output-streams))
 418         (/show0 "loaded SYSINIT-TRUENAME")
 419         (when userinit-truename
 420           (unless (load userinit-truename)
 421             (error "~S was not successfully loaded." userinit-truename))
 422           (flush-standard-output-streams))
 423         (/show0 "loaded USERINIT-TRUENAME"))
 424
 425       ;; Handle --eval options.
 426       (/show0 "handling --eval options in TOPLEVEL-INIT")
 427       (dolist (eval (reverse evals))
 428         (/show0 "handling one --eval option in TOPLEVEL-INIT")
 429         (eval eval)
 430         (flush-standard-output-streams))
 431
 432       (/show0 "falling into TOPLEVEL-REPL from TOPLEVEL-INIT")
 433       (toplevel-repl noprint))))
 434
 435 ;;; read-eval-print loop for the default system toplevel
 436 (defun toplevel-repl (noprint)
 437   (/show0 "entering TOPLEVEL-REPL")
 438   (let ((* nil) (** nil) (*** nil)
 439         (- nil)
 440         (+ nil) (++ nil) (+++ nil)
 441         (/// nil) (// nil) (/ nil)
 442         (eof-marker (cons :eof nil)))
 443     (loop
 444       (/show0 "at head of outer LOOP in TOPLEVEL-REPL")
 445       ;; There should only be one TOPLEVEL restart, and it's here, so
 446       ;; restarting at TOPLEVEL always bounces you all the way out here.
 447       (with-simple-restart (toplevel
 448                             "Restart at toplevel READ/EVAL/PRINT loop.")
 449         ;; We add a new ABORT restart for every debugger level, so
 450         ;; restarting at ABORT in a nested debugger gets you out to the
 451         ;; innermost enclosing debugger, and only when you're in the
 452         ;; outermost, unnested debugger level does restarting at ABORT
 453         ;; get you out to here.
 454         (with-simple-restart (abort
 455                               "Reduce debugger level (leaving debugger).")
 456           (catch 'top-level-catcher
 457           (sb!unix:unix-sigsetmask 0)   ; FIXME: What is this for?
 458           (/show0 "about to enter inner LOOP in TOPLEVEL-REPL")
 459           (loop                         ; FIXME: Do we need this inner LOOP?
 460            ;; FIXME: It seems bad to have GC behavior depend on scrubbing
 461            ;; the control stack before each interactive command. Isn't
 462            ;; there some way we can convince the GC to just ignore
 463            ;; dead areas of the control stack, so that we don't need to
 464            ;; rely on this half-measure?
 465            (scrub-control-stack)
 466            (unless noprint
 467              (fresh-line)
 468              (princ (if (functionp *prompt*)
 469                         (funcall *prompt*)
 470                         *prompt*))
 471              (flush-standard-output-streams))
 472            (let ((form (read *standard-input* nil eof-marker)))
 473              (if (eq form eof-marker)
 474                  (quit)
 475                  (let ((results
 476                         (multiple-value-list (interactive-eval form))))
 477                    (unless noprint
 478                      (dolist (result results)
 479                        (fresh-line)
 480                        (prin1 result)))))))))))))
 481
 482 (defun noprogrammer-debugger-hook-fun (condition old-debugger-hook)
 483   (declare (ignore old-debugger-hook))
 484   (flet ((failure-quit (&key recklessly-p)
 485            (quit :unix-status 1 :recklessly-p recklessly-p)))
 486     ;; This HANDLER-CASE is here mostly to stop output immediately
 487     ;; (and fall through to QUIT) when there's an I/O error. Thus,
 488     ;; when we're run under a Perl script or something, we can die
 489     ;; cleanly when the script dies (and our pipes are cut), instead
 490     ;; of falling into ldb or something messy like that.
 491     (handler-case
 492         (progn
 493           (format *error-output*
 494                   "~@<unhandled CONDITION (of type ~S): ~2I~_~A~:>~2%"
 495                   (type-of condition)
 496                   condition)
 497           ;; Flush *ERROR-OUTPUT* even before the BACKTRACE, so that
 498           ;; even if we hit an error within BACKTRACE we'll at least
 499           ;; have the CONDITION printed out before we die.
 500           (finish-output *error-output*)
 501           ;; (Where to truncate the BACKTRACE is of course arbitrary, but
 502           ;; it seems as though we should at least truncate it somewhere.)
 503           (sb!debug:backtrace 128 *error-output*)
 504           (finish-output *error-output*)
 505           (format *error-output*
 506                   "~%unhandled CONDITION in --noprogrammer mode, quitting~%")
 507           (failure-quit))
 508       (condition ()
 509         (%primitive print "Argh! error within --noprogrammer error handling")
 510         (failure-quit :recklessly-p t)))))
 511 \f
 512 ;;; a convenient way to get into the assembly-level debugger
 513 (defun %halt ()
 514   (%primitive sb!c:halt))