src/code/toplevel.lisp

   1 ;;;; stuff related to the toplevel read-eval-print loop, plus some
   2 ;;;; other miscellaneous functions that we don't have any better place
   3 ;;;; for
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!IMPL")
  15 \f
  16 ;;;; magic specials initialized by GENESIS
  17
  18 ;;; FIXME: The DEFVAR here is redundant with the (DECLAIM (SPECIAL ..))
  19 ;;; of all static symbols in early-impl.lisp.
  20 (progn
  21   (defvar sb!vm::*current-catch-block*)
  22   (defvar sb!vm::*current-unwind-protect-block*)
  23   #!+hpux (defvar sb!vm::*c-lra*)
  24   (defvar *free-interrupt-context-index*))
  25 \f
  26 ;;; specials initialized by !COLD-INIT
  27
  28 ;;; FIXME: These could be converted to DEFVARs.
  29 (declaim (special #!+(or x86 x86-64) *pseudo-atomic-bits*
  30                   *allow-with-interrupts*
  31                   *interrupts-enabled*
  32                   *interrupt-pending*
  33                   *type-system-initialized*))
  34
  35 (defvar *cold-init-complete-p*)
  36
  37 ;;; counts of nested errors (with internal errors double-counted)
  38 (defvar *maximum-error-depth*)
  39 (defvar *current-error-depth*)
  40
  41 ;;;; default initfiles
  42
  43 (defun sysinit-pathname ()
  44   (or (let ((sbcl-homedir (sbcl-homedir-pathname)))
  45         (when sbcl-homedir
  46           (probe-file (merge-pathnames "sbclrc" sbcl-homedir))))
  47       #!+win32
  48       (merge-pathnames "sbcl\\sbclrc"
  49                        (sb!win32::get-folder-pathname
  50                         sb!win32::csidl_common_appdata))
  51       #!-win32
  52       "/etc/sbclrc"))
  53
  54 (defun userinit-pathname ()
  55   (merge-pathnames ".sbclrc" (user-homedir-pathname)))
  56
  57 (defvar *sysinit-pathname-function* #'sysinit-pathname
  58   #!+sb-doc
  59   "Designator for a function of zero arguments called to obtain a pathname
  60 designator for the default sysinit file, or NIL. If the function returns NIL,
  61 no sysinit file is used unless one has been specified on the command-line.")
  62
  63 (defvar *userinit-pathname-function* #'userinit-pathname
  64   #!+sb-doc
  65   "Designator for a function of zero arguments called to obtain a pathname
  66 designator or a stream for the default userinit file, or NIL. If the function
  67 returns NIL, no userinit file is used unless one has been specified on the
  68 command-line.")
  69
  70 \f
  71 ;;;; miscellaneous utilities for working with with TOPLEVEL
  72
  73 ;;; Execute BODY in a context where any %END-OF-THE-WORLD (thrown e.g.
  74 ;;; by QUIT) is caught and any final processing and return codes are
  75 ;;; handled appropriately.
  76 (defmacro handling-end-of-the-world (&body body)
  77   (with-unique-names (caught)
  78     `(let ((,caught (catch '%end-of-the-world
  79                       (/show0 "inside CATCH '%END-OF-THE-WORLD")
  80                       (unwind-protect
  81                            (progn ,@body)
  82                         (call-hooks "exit" *exit-hooks*)))))
  83       (/show0 "back from CATCH '%END-OF-THE-WORLD, flushing output")
  84       (flush-standard-output-streams)
  85       (sb!thread::terminate-session)
  86       (/show0 "calling UNIX-EXIT")
  87       (sb!unix:unix-exit ,caught))))
  88 \f
  89 ;;;; working with *CURRENT-ERROR-DEPTH* and *MAXIMUM-ERROR-DEPTH*
  90
  91 ;;; INFINITE-ERROR-PROTECT is used by ERROR and friends to keep us out
  92 ;;; of hyperspace.
  93 (defmacro infinite-error-protect (&rest forms)
  94   `(unless (infinite-error-protector)
  95      (/show0 "back from INFINITE-ERROR-PROTECTOR")
  96      (let ((*current-error-depth* (1+ *current-error-depth*)))
  97        (/show0 "in INFINITE-ERROR-PROTECT, incremented error depth")
  98        ;; arbitrary truncation
  99        #!+sb-show (sb!debug:backtrace 8)
 100        ,@forms)))
 101
 102 ;;; a helper function for INFINITE-ERROR-PROTECT
 103 (defun infinite-error-protector ()
 104   (/show0 "entering INFINITE-ERROR-PROTECTOR, *CURRENT-ERROR-DEPTH*=..")
 105   (/hexstr *current-error-depth*)
 106   (cond ((not *cold-init-complete-p*)
 107          (%primitive print "Argh! error in cold init, halting")
 108          (%primitive sb!c:halt))
 109         ((or (not (boundp '*current-error-depth*))
 110              (not (realp   *current-error-depth*))
 111              (not (boundp '*maximum-error-depth*))
 112              (not (realp   *maximum-error-depth*)))
 113          (%primitive print "Argh! corrupted error depth, halting")
 114          (%primitive sb!c:halt))
 115         ((> *current-error-depth* *maximum-error-depth*)
 116          (/show0 "*MAXIMUM-ERROR-DEPTH*=..")
 117          (/hexstr *maximum-error-depth*)
 118          (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
 119          (error-error "Help! "
 120                       *current-error-depth*
 121                       " nested errors. "
 122                       "SB-KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 123          t)
 124         (t
 125          (/show0 "returning normally from INFINITE-ERROR-PROTECTOR")
 126          nil)))
 127
 128 ;;; FIXME: I had a badly broken version of INFINITE-ERROR-PROTECTOR at
 129 ;;; one point (shown below), and SBCL cross-compiled it without
 130 ;;; warning about FORMS being undefined. Check whether that problem
 131 ;;; (missing warning) is repeatable in the final system and if so, fix
 132 ;;; it.
 133 #|
 134 (defun infinite-error-protector ()
 135   `(cond ((not *cold-init-complete-p*)
 136           (%primitive print "Argh! error in cold init, halting")
 137           (%primitive sb!c:halt))
 138          ((or (not (boundp '*current-error-depth*))
 139               (not (realp   *current-error-depth*))
 140               (not (boundp '*maximum-error-depth*))
 141               (not (realp   *maximum-error-depth*)))
 142           (%primitive print "Argh! corrupted error depth, halting")
 143           (%primitive sb!c:halt))
 144          ((> *current-error-depth* *maximum-error-depth*)
 145           (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
 146           (error-error "Help! "
 147                        *current-error-depth*
 148                        " nested errors. "
 149                        "SB-KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 150           (progn ,@forms)
 151           t)
 152          (t
 153           (/show0 "in INFINITE-ERROR-PROTECTOR, returning normally")
 154           nil)))
 155 |#
 156 \f
 157 ;;;; miscellaneous external functions
 158
 159 (defun sleep (seconds)
 160   #!+sb-doc
 161   "This function causes execution to be suspended for SECONDS. SECONDS may be
 162 any non-negative real number."
 163   (when (or (not (realp seconds))
 164             (minusp seconds))
 165     (error 'simple-type-error
 166            :format-control "invalid argument to SLEEP: ~S"
 167            :format-arguments (list seconds)
 168            :datum seconds
 169            :expected-type '(real 0)))
 170   #!-win32
 171   (multiple-value-bind (sec nsec)
 172       (if (integerp seconds)
 173           (values seconds 0)
 174           (multiple-value-bind (sec frac)
 175               (truncate seconds)
 176             (values sec (truncate frac 1e-9))))
 177     ;; nanosleep() accepts time_t as the first argument, but on some platforms
 178     ;; it is restricted to 100 million seconds. Maybe someone can actually
 179     ;; have a reason to sleep for over 3 years?
 180     (loop while (> sec (expt 10 8))
 181           do (decf sec (expt 10 8))
 182              (sb!unix:nanosleep (expt 10 8) 0))
 183     (sb!unix:nanosleep sec nsec))
 184   #!+win32
 185   (sb!win32:millisleep (truncate (* seconds 1000)))
 186   nil)
 187 \f
 188 ;;;; the default toplevel function
 189
 190 (defvar / nil
 191   #!+sb-doc
 192   "a list of all the values returned by the most recent top level EVAL")
 193 (defvar //  nil #!+sb-doc "the previous value of /")
 194 (defvar /// nil #!+sb-doc "the previous value of //")
 195 (defvar *   nil #!+sb-doc "the value of the most recent top level EVAL")
 196 (defvar **  nil #!+sb-doc "the previous value of *")
 197 (defvar *** nil #!+sb-doc "the previous value of **")
 198 (defvar +   nil #!+sb-doc "the value of the most recent top level READ")
 199 (defvar ++  nil #!+sb-doc "the previous value of +")
 200 (defvar +++ nil #!+sb-doc "the previous value of ++")
 201 (defvar -   nil #!+sb-doc "the form currently being evaluated")
 202
 203 (defun interactive-eval (form &key (eval #'eval))
 204   #!+sb-doc
 205   "Evaluate FORM, returning whatever it returns and adjusting ***, **, *,
 206 +++, ++, +, ///, //, /, and -."
 207   (setf - form)
 208   (unwind-protect
 209        (let ((results (multiple-value-list (funcall eval form))))
 210          (setf /// //
 211                // /
 212                / results
 213                *** **
 214                ** *
 215                * (car results)))
 216     (setf +++ ++
 217           ++ +
 218           + -))
 219   (unless (boundp '*)
 220     ;; The bogon returned an unbound marker.
 221     ;; FIXME: It would be safer to check every one of the values in RESULTS,
 222     ;; instead of just the first one.
 223     (setf * nil)
 224     (cerror "Go on with * set to NIL."
 225             "EVAL returned an unbound marker."))
 226   (values-list /))
 227
 228 ;;; Flush anything waiting on one of the ANSI Common Lisp standard
 229 ;;; output streams before proceeding.
 230 (defun flush-standard-output-streams ()
 231   (dolist (name '(*debug-io*
 232                   *error-output*
 233                   *query-io*
 234                   *standard-output*
 235                   *trace-output*
 236                   *terminal-io*))
 237     ;; FINISH-OUTPUT may block more easily than FORCE-OUTPUT
 238     (force-output (symbol-value name)))
 239   (values))
 240
 241 (defun process-init-file (specified-pathname kind)
 242   (multiple-value-bind (context default-function)
 243       (ecase kind
 244         (:system
 245          (values "sysinit" *sysinit-pathname-function*))
 246         (:user
 247          (values "userinit" *userinit-pathname-function*)))
 248     (if specified-pathname
 249         (with-open-file (stream (parse-native-namestring specified-pathname)
 250                                 :if-does-not-exist nil)
 251           (if stream
 252               (load-as-source stream :context context)
 253               (cerror "Ignore missing init file"
 254                       "The specified ~A file ~A was not found."
 255                       context specified-pathname)))
 256         (let ((default (funcall default-function)))
 257           (when default
 258             (with-open-file (stream (pathname default) :if-does-not-exist nil)
 259               (when stream
 260                 (load-as-source stream :context context))))))))
 261
 262 (defun process-eval/load-options (options)
 263   (/show0 "handling --eval and --load options")
 264   (flet ((process-1 (cons)
 265            (destructuring-bind (opt . value) cons
 266              (ecase opt
 267                (:eval
 268                 (with-simple-restart (continue "Ignore runtime option --eval ~S."
 269                                                value)
 270                   (multiple-value-bind (expr pos) (read-from-string value)
 271                     (if (eq value (read-from-string value nil value :start pos))
 272                         (eval expr)
 273                         (error "Multiple expressions in --eval option: ~S"
 274                                value)))))
 275                (:load
 276                 (with-simple-restart (continue "Ignore runtime option --load ~S."
 277                                                value)
 278                   (load (native-pathname value))))))
 279            (flush-standard-output-streams)))
 280     (with-simple-restart (abort "Skip rest of --eval and --load options.")
 281       (dolist (option options)
 282         (process-1 option)))))
 283
 284 (defun process-script (script)
 285   (let ((pathname (native-pathname script)))
 286     (handling-end-of-the-world
 287       (with-open-file (f pathname :element-type :default)
 288         (sb!fasl::maybe-skip-shebang-line f)
 289         ;; Scripts don't need to be stylish or fast, but silence is usually a
 290         ;; desirable quality...
 291         (handler-bind (((or style-warning compiler-note) #'muffle-warning))
 292           (load f :verbose nil :print nil))
 293         (quit)))))
 294
 295 ;; Errors while processing the command line cause the system to QUIT,
 296 ;; instead of trying to go into the Lisp debugger, because trying to
 297 ;; go into the Lisp debugger would get into various annoying issues of
 298 ;; where we should go after the user tries to return from the
 299 ;; debugger.
 300 (defun startup-error (control-string &rest args)
 301   (format *error-output*
 302           "fatal error before reaching READ-EVAL-PRINT loop: ~%  ~?~%"
 303           control-string
 304           args)
 305   (quit :unix-status 1))
 306
 307 ;;; the default system top level function
 308 (defun toplevel-init ()
 309   (/show0 "entering TOPLEVEL-INIT")
 310   (let ( ;; value of --sysinit option
 311         (sysinit nil)
 312         ;; t if --no-sysinit option given
 313         (no-sysinit nil)
 314         ;; value of --userinit option
 315         (userinit nil)
 316         ;; t if --no-userinit option given
 317         (no-userinit nil)
 318         ;; t if --disable-debugger option given
 319         (disable-debugger nil)
 320         ;; list of (<kind> . <string>) conses representing --eval and --load
 321         ;; options. options. --eval options are stored as strings, so that
 322         ;; they can be passed to READ only after their predecessors have been
 323         ;; EVALed, so that things work when e.g. REQUIRE in one EVAL form
 324         ;; creates a package referred to in the next EVAL form. Storing the
 325         ;; original string also makes for easier debugging.
 326         (reversed-options nil)
 327         ;; Has a --noprint option been seen?
 328         (noprint nil)
 329         ;; Has a --script option been seen?
 330         (script nil)
 331         ;; everything in *POSIX-ARGV* except for argv[0]=programname
 332         (options (rest *posix-argv*)))
 333
 334     (declare (type list options))
 335
 336     (/show0 "done with outer LET in TOPLEVEL-INIT")
 337
 338     ;; FIXME: There are lots of ways for errors to happen around here
 339     ;; (e.g. bad command line syntax, or READ-ERROR while trying to
 340     ;; READ an --eval string). Make sure that they're handled
 341     ;; reasonably.
 342
 343     ;; Process command line options.
 344     (loop while options do
 345          (/show0 "at head of LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 346          (let ((option (first options)))
 347            (flet ((pop-option ()
 348                     (if options
 349                         (pop options)
 350                         (startup-error
 351                          "unexpected end of command line options"))))
 352              (cond ((string= option "--script")
 353                     (pop-option)
 354                     (setf disable-debugger t
 355                           no-userinit t
 356                           no-sysinit t
 357                           script (pop-option))
 358                     (return))
 359                    ((string= option "--sysinit")
 360                     (pop-option)
 361                     (if sysinit
 362                         (startup-error "multiple --sysinit options")
 363                         (setf sysinit (pop-option))))
 364                    ((string= option "--no-sysinit")
 365                     (pop-option)
 366                     (setf no-sysinit t))
 367                    ((string= option "--userinit")
 368                     (pop-option)
 369                     (if userinit
 370                         (startup-error "multiple --userinit options")
 371                         (setf userinit (pop-option))))
 372                    ((string= option "--no-userinit")
 373                     (pop-option)
 374                     (setf no-userinit t))
 375                    ((string= option "--eval")
 376                     (pop-option)
 377                     (push (cons :eval (pop-option)) reversed-options))
 378                    ((string= option "--load")
 379                     (pop-option)
 380                     (push (cons :load (pop-option)) reversed-options))
 381                    ((string= option "--noprint")
 382                     (pop-option)
 383                     (setf noprint t))
 384                    ((string= option "--disable-debugger")
 385                     (pop-option)
 386                     (setf disable-debugger t))
 387                    ((string= option "--end-toplevel-options")
 388                     (pop-option)
 389                     (return))
 390                    (t
 391                     ;; Anything we don't recognize as a toplevel
 392                     ;; option must be the start of user-level
 393                     ;; options.. except that if we encounter
 394                     ;; "--end-toplevel-options" after we gave up
 395                     ;; because we didn't recognize an option as a
 396                     ;; toplevel option, then the option we gave up on
 397                     ;; must have been an error. (E.g. in
 398                     ;;  "sbcl --eval '(a)' --eval'(b)' --end-toplevel-options"
 399                     ;; this test will let us detect that the string
 400                     ;; "--eval(b)" is an error.)
 401                     (if (find "--end-toplevel-options" options
 402                               :test #'string=)
 403                         (startup-error "bad toplevel option: ~S"
 404                                        (first options))
 405                         (return)))))))
 406     (/show0 "done with LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 407
 408     ;; Delete all the options that we processed, so that only
 409     ;; user-level options are left visible to user code.
 410     (setf (rest *posix-argv*) options)
 411
 412     ;; Disable debugger before processing initialization files & co.
 413     (when disable-debugger
 414       (sb!ext:disable-debugger))
 415
 416     ;; Handle initialization files.
 417     (/show0 "handling initialization files in TOPLEVEL-INIT")
 418     ;; This CATCH is needed for the debugger command TOPLEVEL to
 419     ;; work.
 420     (catch 'toplevel-catcher
 421       ;; We wrap all the pre-REPL user/system customized startup
 422       ;; code in a restart.
 423       ;;
 424       ;; (Why not wrap everything, even the stuff above, in this
 425       ;; restart? Errors above here are basically command line
 426       ;; or Unix environment errors, e.g. a missing file or a
 427       ;; typo on the Unix command line, and you don't need to
 428       ;; get into Lisp to debug them, you should just start over
 429       ;; and do it right at the Unix level. Errors below here
 430       ;; are generally errors in user Lisp code, and it might be
 431       ;; helpful to let the user reach the REPL in order to help
 432       ;; figure out what's going on.)
 433       (restart-case
 434           (progn
 435             (unless no-sysinit
 436               (process-init-file sysinit :system))
 437             (unless no-userinit
 438               (process-init-file userinit :user))
 439             (process-eval/load-options (nreverse reversed-options))
 440             (when script
 441               (process-script script)
 442               (bug "PROCESS-SCRIPT returned")))
 443         (abort ()
 444           :report (lambda (s)
 445                     (write-string
 446                      (if script
 447                          ;; In case script calls (enable-debugger)!
 448                          "Abort script, exiting lisp."
 449                          "Skip to toplevel READ/EVAL/PRINT loop.")
 450                      s))
 451           (/show0 "CONTINUEing from pre-REPL RESTART-CASE")
 452           (values))                     ; (no-op, just fall through)
 453         (quit ()
 454           :report "Quit SBCL (calling #'QUIT, killing the process)."
 455           :test (lambda (c) (declare (ignore c)) (not script))
 456           (/show0 "falling through to QUIT from pre-REPL RESTART-CASE")
 457           (quit :unix-status 1))))
 458
 459     ;; one more time for good measure, in case we fell out of the
 460     ;; RESTART-CASE above before one of the flushes in the ordinary
 461     ;; flow of control had a chance to operate
 462     (flush-standard-output-streams)
 463
 464     (/show0 "falling into TOPLEVEL-REPL from TOPLEVEL-INIT")
 465     (toplevel-repl noprint)
 466     ;; (classic CMU CL error message: "You're certainly a clever child.":-)
 467     (critically-unreachable "after TOPLEVEL-REPL")))
 468
 469 ;;; hooks to support customized toplevels like ACL-style toplevel from
 470 ;;; KMR on sbcl-devel 2002-12-21.  Altered by CSR 2003-11-16 for
 471 ;;; threaded operation: altered *REPL-FUN* to *REPL-FUN-GENERATOR*.
 472 (defvar *repl-read-form-fun* #'repl-read-form-fun
 473   #!+sb-doc
 474   "A function of two stream arguments IN and OUT for the toplevel REPL to
 475 call: Return the next Lisp form to evaluate (possibly handling other magic --
 476 like ACL-style keyword commands -- which precede the next Lisp form). The OUT
 477 stream is there to support magic which requires issuing new prompts.")
 478 (defvar *repl-prompt-fun* #'repl-prompt-fun
 479   #!+sb-doc
 480   "A function of one argument STREAM for the toplevel REPL to call: Prompt
 481 the user for input.")
 482 (defvar *repl-fun-generator* (constantly #'repl-fun)
 483   #!+sb-doc
 484   "A function of no arguments returning a function of one argument NOPRINT
 485 that provides the REPL for the system. Assumes that *STANDARD-INPUT* and
 486 *STANDARD-OUTPUT* are set up.")
 487
 488 ;;; read-eval-print loop for the default system toplevel
 489 (defun toplevel-repl (noprint)
 490   (/show0 "entering TOPLEVEL-REPL")
 491   (let ((* nil) (** nil) (*** nil)
 492         (- nil)
 493         (+ nil) (++ nil) (+++ nil)
 494         (/// nil) (// nil) (/ nil))
 495     (/show0 "about to funcall *REPL-FUN-GENERATOR*")
 496     (let ((repl-fun (funcall *repl-fun-generator*)))
 497       ;; Each REPL in a multithreaded world should have bindings of
 498       ;; most CL specials (most critically *PACKAGE*).
 499       (with-rebound-io-syntax
 500           (handler-bind ((step-condition 'invoke-stepper))
 501             (loop
 502                (/show0 "about to set up restarts in TOPLEVEL-REPL")
 503                ;; CLHS recommends that there should always be an
 504                ;; ABORT restart; we have this one here, and one per
 505                ;; debugger level.
 506                (with-simple-restart
 507                    (abort "~@<Exit debugger, returning to top level.~@:>")
 508                  (catch 'toplevel-catcher
 509                    ;; In the event of a control-stack-exhausted-error, we
 510                    ;; should have unwound enough stack by the time we get
 511                    ;; here that this is now possible.
 512                    #!-win32
 513                    (sb!kernel::reset-control-stack-guard-page)
 514                    (funcall repl-fun noprint)
 515                    (critically-unreachable "after REPL")))))))))
 516
 517 ;;; Our default REPL prompt is the minimal traditional one.
 518 (defun repl-prompt-fun (stream)
 519   (fresh-line stream)
 520   (write-string "* " stream)) ; arbitrary but customary REPL prompt
 521
 522 ;;; Our default form reader does relatively little magic, but does
 523 ;;; handle the Unix-style EOF-is-end-of-process convention.
 524 (defun repl-read-form-fun (in out)
 525   (declare (type stream in out) (ignore out))
 526   ;; KLUDGE: *READ-SUPPRESS* makes the REPL useless, and cannot be
 527   ;; recovered from -- flip it here.
 528   (when *read-suppress*
 529     (warn "Setting *READ-SUPPRESS* to NIL to restore toplevel usability.")
 530     (setf *read-suppress* nil))
 531   (let* ((eof-marker (cons nil nil))
 532          (form (read in nil eof-marker)))
 533     (if (eq form eof-marker)
 534         (quit)
 535         form)))
 536
 537 (defun repl-fun (noprint)
 538   (/show0 "entering REPL")
 539   (loop
 540    (unwind-protect
 541         (progn
 542           ;; (See comment preceding the definition of SCRUB-CONTROL-STACK.)
 543           (scrub-control-stack)
 544           (sb!thread::get-foreground)
 545           (unless noprint
 546             (flush-standard-output-streams)
 547             (funcall *repl-prompt-fun* *standard-output*)
 548             ;; (Should *REPL-PROMPT-FUN* be responsible for doing its own
 549             ;; FORCE-OUTPUT? I can't imagine a valid reason for it not to
 550             ;; be done here, so leaving it up to *REPL-PROMPT-FUN* seems
 551             ;; odd. But maybe there *is* a valid reason in some
 552             ;; circumstances? perhaps some deadlock issue when being driven
 553             ;; by another process or something...)
 554             (force-output *standard-output*))
 555           (let* ((form (funcall *repl-read-form-fun*
 556                                 *standard-input*
 557                                 *standard-output*))
 558                  (results (multiple-value-list (interactive-eval form))))
 559             (unless noprint
 560               (dolist (result results)
 561                 (fresh-line)
 562                 (prin1 result)))))
 563      ;; If we started stepping in the debugger we want to stop now.
 564      (disable-stepping))))
 565 \f
 566 ;;; a convenient way to get into the assembly-level debugger
 567 (defun %halt ()
 568   (%primitive sb!c:halt))