src/code/toplevel.lisp

   1 ;;;; stuff related to the toplevel read-eval-print loop, plus some
   2 ;;;; other miscellaneous functions that we don't have any better place
   3 ;;;; for
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!IMPL")
  15 \f
  16 (defconstant most-positive-fixnum #.sb!vm:*target-most-positive-fixnum*
  17   #!+sb-doc
  18   "the fixnum closest in value to positive infinity")
  19
  20 (defconstant most-negative-fixnum #.sb!vm:*target-most-negative-fixnum*
  21   #!+sb-doc
  22   "the fixnum closest in value to negative infinity")
  23 \f
  24 ;;;; magic specials initialized by GENESIS
  25
  26 ;;; FIXME: The DEFVAR here is redundant with the (DECLAIM (SPECIAL ..))
  27 ;;; of all static symbols in early-impl.lisp.
  28 (progn
  29   (defvar *current-catch-block*)
  30   (defvar *current-unwind-protect-block*)
  31   (defvar *free-interrupt-context-index*))
  32 \f
  33 ;;; specials initialized by !COLD-INIT
  34
  35 ;;; FIXME: These could be converted to DEFVARs.
  36 (declaim (special *gc-inhibit* *already-maybe-gcing*
  37                   *need-to-collect-garbage*
  38                   *gc-notify-stream*
  39                   *before-gc-hooks* *after-gc-hooks*
  40                   #!+x86 *pseudo-atomic-atomic*
  41                   #!+x86 *pseudo-atomic-interrupted*
  42                   sb!unix::*interrupts-enabled*
  43                   sb!unix::*interrupt-pending*
  44                   *type-system-initialized*))
  45
  46 (defvar *cold-init-complete-p*)
  47
  48 ;;; counts of nested errors (with internal errors double-counted)
  49 (defvar *maximum-error-depth*)
  50 (defvar *current-error-depth*)
  51 \f
  52 ;;;; miscellaneous utilities for working with with TOPLEVEL
  53
  54 ;;; Execute BODY in a context where any %END-OF-THE-WORLD (thrown e.g.
  55 ;;; by QUIT) is caught and any final processing and return codes are
  56 ;;; handled appropriately.
  57 (defmacro handling-end-of-the-world (&body body)
  58   (let ((caught (gensym "CAUGHT")))
  59     `(let ((,caught (catch '%end-of-the-world
  60                       (/show0 "inside CATCH '%END-OF-THE-WORLD")
  61                       ,@body)))
  62        (/show0 "back from CATCH '%END-OF-THE-WORLD, flushing output")
  63        (flush-standard-output-streams)
  64        (/show0 "calling UNIX-EXIT")
  65        (sb!unix:unix-exit ,caught))))
  66 \f
  67 ;;;; working with *CURRENT-ERROR-DEPTH* and *MAXIMUM-ERROR-DEPTH*
  68
  69 ;;; INFINITE-ERROR-PROTECT is used by ERROR and friends to keep us out
  70 ;;; of hyperspace.
  71 (defmacro infinite-error-protect (&rest forms)
  72   `(unless (infinite-error-protector)
  73      (/show0 "back from INFINITE-ERROR-PROTECTOR")
  74      (let ((*current-error-depth* (1+ *current-error-depth*)))
  75        (/show0 "in INFINITE-ERROR-PROTECT, incremented error depth")
  76        #+sb-show (sb-debug:backtrace)
  77        ,@forms)))
  78
  79 ;;; a helper function for INFINITE-ERROR-PROTECT
  80 (defun infinite-error-protector ()
  81   (/show0 "entering INFINITE-ERROR-PROTECTOR, *CURRENT-ERROR-DEPTH*=..")
  82   (/hexstr *current-error-depth*)
  83   (cond ((not *cold-init-complete-p*)
  84          (%primitive print "Argh! error in cold init, halting")
  85          (%primitive sb!c:halt))
  86         ((or (not (boundp '*current-error-depth*))
  87              (not (realp   *current-error-depth*))
  88              (not (boundp '*maximum-error-depth*))
  89              (not (realp   *maximum-error-depth*)))
  90          (%primitive print "Argh! corrupted error depth, halting")
  91          (%primitive sb!c:halt))
  92         ((> *current-error-depth* *maximum-error-depth*)
  93          (/show0 "*MAXIMUM-ERROR-DEPTH*=..")
  94          (/hexstr *maximum-error-depth*)
  95          (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
  96          (error-error "Help! "
  97                       *current-error-depth*
  98                       " nested errors. "
  99                       "KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 100          t)
 101         (t
 102          (/show0 "returning normally from INFINITE-ERROR-PROTECTOR")
 103          nil)))
 104
 105 ;;; FIXME: I had a badly broken version of INFINITE-ERROR-PROTECTOR at
 106 ;;; one point (shown below), and SBCL cross-compiled it without
 107 ;;; warning about FORMS being undefined. Check whether that problem
 108 ;;; (missing warning) is repeatable in the final system and if so, fix
 109 ;;; it.
 110 #|
 111 (defun infinite-error-protector ()
 112   `(cond ((not *cold-init-complete-p*)
 113           (%primitive print "Argh! error in cold init, halting")
 114           (%primitive sb!c:halt))
 115          ((or (not (boundp '*current-error-depth*))
 116               (not (realp   *current-error-depth*))
 117               (not (boundp '*maximum-error-depth*))
 118               (not (realp   *maximum-error-depth*)))
 119           (%primitive print "Argh! corrupted error depth, halting")
 120           (%primitive sb!c:halt))
 121          ((> *current-error-depth* *maximum-error-depth*)
 122           (/show0 "in INFINITE-ERROR-PROTECTOR, calling ERROR-ERROR")
 123           (error-error "Help! "
 124                        *current-error-depth*
 125                        " nested errors. "
 126                        "KERNEL:*MAXIMUM-ERROR-DEPTH* exceeded.")
 127           (progn ,@forms)
 128           t)
 129          (t
 130           (/show0 "in INFINITE-ERROR-PROTECTOR, returning normally")
 131           nil)))
 132 |#
 133 \f
 134 ;;;; miscellaneous external functions
 135
 136 #!-mp ; The multi-processing version is defined in multi-proc.lisp.
 137 (defun sleep (n)
 138   #!+sb-doc
 139   "This function causes execution to be suspended for N seconds. N may
 140   be any non-negative, non-complex number."
 141   (when (or (not (realp n))
 142             (minusp n))
 143     (error "Invalid argument to SLEEP: ~S.~%~
 144             Must be a non-negative, non-complex number."
 145            n))
 146   (multiple-value-bind (sec usec)
 147       (if (integerp n)
 148           (values n 0)
 149           (multiple-value-bind (sec frac)
 150               (truncate n)
 151             (values sec(truncate frac 1e-6))))
 152     (sb!unix:unix-select 0 0 0 0 sec usec))
 153   nil)
 154 \f
 155 ;;;; SCRUB-CONTROL-STACK
 156
 157 (defconstant bytes-per-scrub-unit 2048)
 158
 159 ;;; Zero the unused portion of the control stack so that old objects
 160 ;;; are not kept alive because of uninitialized stack variables.
 161 ;;;
 162 ;;; FIXME: Why do we need to do this instead of just letting GC read
 163 ;;; the stack pointer and avoid messing with the unused portion of
 164 ;;; the control stack? (Is this a multithreading thing where there's
 165 ;;; one control stack and stack pointer per thread, and it might not
 166 ;;; be easy to tell what a thread's stack pointer value is when
 167 ;;; looking in from another thread?)
 168 (defun scrub-control-stack ()
 169   (declare (optimize (speed 3) (safety 0))
 170            (values (unsigned-byte 20))) ; FIXME: DECLARE VALUES?
 171
 172   #!-x86 ; machines where stack grows upwards (I guess) -- WHN 19990906
 173   (labels
 174       ((scrub (ptr offset count)
 175          (declare (type system-area-pointer ptr)
 176                   (type (unsigned-byte 16) offset)
 177                   (type (unsigned-byte 20) count)
 178                   (values (unsigned-byte 20)))
 179          (cond ((= offset bytes-per-scrub-unit)
 180                 (look (sap+ ptr bytes-per-scrub-unit) 0 count))
 181                (t
 182                 (setf (sap-ref-32 ptr offset) 0)
 183                 (scrub ptr (+ offset sb!vm:n-word-bytes) count))))
 184        (look (ptr offset count)
 185          (declare (type system-area-pointer ptr)
 186                   (type (unsigned-byte 16) offset)
 187                   (type (unsigned-byte 20) count)
 188                   (values (unsigned-byte 20)))
 189          (cond ((= offset bytes-per-scrub-unit)
 190                 count)
 191                ((zerop (sap-ref-32 ptr offset))
 192                 (look ptr (+ offset sb!vm:n-word-bytes) count))
 193                (t
 194                 (scrub ptr offset (+ count sb!vm:n-word-bytes))))))
 195     (let* ((csp (sap-int (sb!c::control-stack-pointer-sap)))
 196            (initial-offset (logand csp (1- bytes-per-scrub-unit))))
 197       (declare (type (unsigned-byte 32) csp))
 198       (scrub (int-sap (- csp initial-offset))
 199              (* (floor initial-offset sb!vm:n-word-bytes) sb!vm:n-word-bytes)
 200              0)))
 201
 202   #!+x86 ;; (Stack grows downwards.)
 203   (labels
 204       ((scrub (ptr offset count)
 205          (declare (type system-area-pointer ptr)
 206                   (type (unsigned-byte 16) offset)
 207                   (type (unsigned-byte 20) count)
 208                   (values (unsigned-byte 20)))
 209          (let ((loc (int-sap (- (sap-int ptr) (+ offset sb!vm:n-word-bytes)))))
 210            (cond ((= offset bytes-per-scrub-unit)
 211                   (look (int-sap (- (sap-int ptr) bytes-per-scrub-unit))
 212                         0 count))
 213                  (t ;; need to fix bug in %SET-STACK-REF
 214                   (setf (sap-ref-32 loc 0) 0)
 215                   (scrub ptr (+ offset sb!vm:n-word-bytes) count)))))
 216        (look (ptr offset count)
 217          (declare (type system-area-pointer ptr)
 218                   (type (unsigned-byte 16) offset)
 219                   (type (unsigned-byte 20) count)
 220                   (values (unsigned-byte 20)))
 221          (let ((loc (int-sap (- (sap-int ptr) offset))))
 222            (cond ((= offset bytes-per-scrub-unit)
 223                   count)
 224                  ((zerop (sb!kernel::get-lisp-obj-address (stack-ref loc 0)))
 225                   (look ptr (+ offset sb!vm:n-word-bytes) count))
 226                  (t
 227                   (scrub ptr offset (+ count sb!vm:n-word-bytes)))))))
 228     (let* ((csp (sap-int (sb!c::control-stack-pointer-sap)))
 229            (initial-offset (logand csp (1- bytes-per-scrub-unit))))
 230       (declare (type (unsigned-byte 32) csp))
 231       (scrub (int-sap (+ csp initial-offset))
 232              (* (floor initial-offset sb!vm:n-word-bytes) sb!vm:n-word-bytes)
 233              0))))
 234 \f
 235 ;;;; the default toplevel function
 236
 237 (defvar / nil
 238   #!+sb-doc
 239   "a list of all the values returned by the most recent top level EVAL")
 240 (defvar //  nil #!+sb-doc "the previous value of /")
 241 (defvar /// nil #!+sb-doc "the previous value of //")
 242 (defvar *   nil #!+sb-doc "the value of the most recent top level EVAL")
 243 (defvar **  nil #!+sb-doc "the previous value of *")
 244 (defvar *** nil #!+sb-doc "the previous value of **")
 245 (defvar +   nil #!+sb-doc "the value of the most recent top level READ")
 246 (defvar ++  nil #!+sb-doc "the previous value of +")
 247 (defvar +++ nil #!+sb-doc "the previous value of ++")
 248 (defvar -   nil #!+sb-doc "the form currently being evaluated")
 249
 250 (defun interactive-eval (form)
 251   "Evaluate FORM, returning whatever it returns and adjusting ***, **, *,
 252    +++, ++, +, ///, //, /, and -."
 253   (setf - form)
 254   (let ((results (multiple-value-list (eval form))))
 255     (setf /// //
 256           // /
 257           / results
 258           *** **
 259           ** *
 260           * (car results)))
 261   (setf +++ ++
 262         ++ +
 263         + -)
 264   (unless (boundp '*)
 265     ;; The bogon returned an unbound marker.
 266     ;; FIXME: It would be safer to check every one of the values in RESULTS,
 267     ;; instead of just the first one.
 268     (setf * nil)
 269     (cerror "Go on with * set to NIL."
 270             "EVAL returned an unbound marker."))
 271   (values-list /))
 272
 273 ;;; Flush anything waiting on one of the ANSI Common Lisp standard
 274 ;;; output streams before proceeding.
 275 (defun flush-standard-output-streams ()
 276   (dolist (name '(*debug-io*
 277                   *error-output*
 278                   *query-io*
 279                   *standard-output*
 280                   *trace-output*))
 281     (finish-output (symbol-value name)))
 282   (values))
 283
 284 ;;; the default system top level function
 285 (defun toplevel-init ()
 286
 287   (/show0 "entering TOPLEVEL-INIT")
 288
 289   (let ((sysinit nil)        ; value of --sysinit option
 290         (userinit nil)       ; value of --userinit option
 291         (reversed-evals nil) ; values of --eval options, in reverse order
 292         (noprint nil)        ; Has a --noprint option been seen?
 293         (noprogrammer nil)   ; Has a --noprogammer option been seen?
 294         (options (rest *posix-argv*))) ; skipping program name
 295
 296     (/show0 "done with outer LET in TOPLEVEL-INIT")
 297
 298     ;; FIXME: There are lots of ways for errors to happen around here
 299     ;; (e.g. bad command line syntax, or READ-ERROR while trying to
 300     ;; READ an --eval string). Make sure that they're handled
 301     ;; reasonably. Also, perhaps all errors while parsing the command
 302     ;; line should cause the system to QUIT, instead of trying to go
 303     ;; into the Lisp debugger.
 304
 305     ;; Parse command line options.
 306     (loop while options do
 307           (/show0 "at head of LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 308           (let ((option (first options)))
 309             (flet ((pop-option ()
 310                      (if options
 311                          (pop options)
 312                          (error "unexpected end of command line options"))))
 313               (cond ((string= option "--sysinit")
 314                      (pop-option)
 315                      (if sysinit
 316                          (error "multiple --sysinit options")
 317                          (setf sysinit (pop-option))))
 318                     ((string= option "--userinit")
 319                      (pop-option)
 320                      (if userinit
 321                          (error "multiple --userinit options")
 322                          (setf userinit (pop-option))))
 323                     ((string= option "--eval")
 324                      (pop-option)
 325                      (let ((eval-as-string (pop-option)))
 326                        (with-input-from-string (eval-stream eval-as-string)
 327                          (let* ((eof-marker (cons :eof :eof))
 328                                 (eval (read eval-stream nil eof-marker))
 329                                 (eof (read eval-stream nil eof-marker)))
 330                            (cond ((eq eval eof-marker)
 331                                   (error "unable to parse ~S"
 332                                          eval-as-string))
 333                                  ((not (eq eof eof-marker))
 334                                   (error "more than one expression in ~S"
 335                                          eval-as-string))
 336                                  (t
 337                                   (push eval reversed-evals)))))))
 338                     ((string= option "--noprint")
 339                      (pop-option)
 340                      (setf noprint t))
 341                     ((string= option "--noprogrammer")
 342                      (pop-option)
 343                      (setf noprogrammer t))
 344                     ((string= option "--end-toplevel-options")
 345                      (pop-option)
 346                      (return))
 347                     (t
 348                      ;; Anything we don't recognize as a toplevel
 349                      ;; option must be the start of user-level
 350                      ;; options.. except that if we encounter
 351                      ;; "--end-toplevel-options" after we gave up
 352                      ;; because we didn't recognize an option as a
 353                      ;; toplevel option, then the option we gave up on
 354                      ;; must have been an error. (E.g. in
 355                      ;;  "sbcl --eval '(a)' --eval'(b)' --end-toplevel-options"
 356                      ;; this test will let us detect that the string
 357                      ;; "--eval(b)" is an error.)
 358                      (if (find "--end-toplevel-options" options
 359                                :test #'string=)
 360                          (error "bad toplevel option: ~S" (first options))
 361                          (return)))))))
 362     (/show0 "done with LOOP WHILE OPTIONS DO in TOPLEVEL-INIT")
 363
 364     ;; Excise all the options that we processed, so that only
 365     ;; user-level options are left visible to user code.
 366     (setf (rest *posix-argv*) options)
 367
 368     ;; Handle --noprogrammer option. We intentionally do this
 369     ;; early so that it will affect the handling of initialization
 370     ;; files and --eval options.
 371     (/show0 "handling --noprogrammer option in TOPLEVEL-INIT")
 372     (when noprogrammer
 373       (setf *debugger-hook* 'noprogrammer-debugger-hook-fun
 374             *debug-io* *error-output*))
 375
 376     ;; FIXME: Verify that errors in init files and/or --eval operations
 377     ;; lead to reasonable behavior.
 378
 379     ;; Handle initialization files.
 380     (/show0 "handling initialization files in TOPLEVEL-INIT")
 381     (flet (;; If any of POSSIBLE-INIT-FILE-NAMES names a real file,
 382            ;; return its truename.
 383            (probe-init-files (&rest possible-init-file-names)
 384              (/show0 "entering PROBE-INIT-FILES")
 385              (prog1
 386                  (find-if (lambda (x)
 387                             (and (stringp x) (probe-file x)))
 388                           possible-init-file-names)
 389                (/show0 "leaving PROBE-INIT-FILES"))))
 390       (let* ((sbcl-home (posix-getenv "SBCL_HOME"))
 391              (sysinit-truename (if sbcl-home
 392                                    (probe-init-files sysinit
 393                                                      (concatenate
 394                                                       'string
 395                                                       sbcl-home
 396                                                       "/sbclrc"))
 397                                    (probe-init-files sysinit
 398                                                      "/etc/sbclrc"
 399                                                      "/usr/local/etc/sbclrc")))
 400              (user-home (or (posix-getenv "HOME")
 401                             (error "The HOME environment variable is unbound, ~
 402                                     so user init file can't be found.")))
 403              (userinit-truename (probe-init-files userinit
 404                                                   (concatenate
 405                                                    'string
 406                                                    user-home
 407                                                    "/.sbclrc"))))
 408
 409         ;; We wrap all the pre-REPL user/system customized startup code
 410         ;; in a restart.
 411         ;;
 412         ;; (Why not wrap everything, even the stuff above, in this
 413         ;; restart? Errors above here are basically command line or
 414         ;; Unix environment errors, e.g. a missing file or a typo on
 415         ;; the Unix command line, and you don't need to get into Lisp
 416         ;; to debug them, you should just start over and do it right
 417         ;; at the Unix level. Errors below here are usually errors in
 418         ;; user Lisp code, and it might be helpful to let the user
 419         ;; reach the REPL in order to help figure out what's going on.)
 420         (restart-case
 421             (flet ((process-init-file (truename)
 422                      (when truename
 423                        (unless (load truename)
 424                          (error "~S was not successfully loaded." truename))
 425                        (flush-standard-output-streams))))
 426               (process-init-file sysinit-truename)
 427               (process-init-file userinit-truename)
 428
 429               ;; Process --eval options.
 430               (/show0 "handling --eval options in TOPLEVEL-INIT")
 431               (dolist (eval (reverse reversed-evals))
 432                 (/show0 "handling one --eval option in TOPLEVEL-INIT")
 433                 (eval eval)
 434                 (flush-standard-output-streams)))
 435           (continue ()
 436             :report
 437             "Continue anyway (skipping to toplevel read/eval/print loop)."
 438             (/show0 "CONTINUEing from pre-REPL RESTART-CASE")
 439             (values)) ; (no-op, just fall through)
 440           (quit ()
 441             :report "Quit SBCL (calling #'QUIT, killing the process)."
 442             (/show0 "falling through to QUIT from pre-REPL RESTART-CASE")
 443             (quit))))
 444
 445       ;; one more time for good measure, in case we fell out of the
 446       ;; RESTART-CASE above before one of the flushes in the ordinary
 447       ;; flow of control had a chance to operate
 448       (flush-standard-output-streams)
 449
 450       (/show0 "falling into TOPLEVEL-REPL from TOPLEVEL-INIT")
 451       (toplevel-repl noprint)
 452       ;; (classic CMU CL error message: "You're certainly a clever child.":-)
 453       (critically-unreachable "after TOPLEVEL-REPL"))))
 454
 455 ;;; read-eval-print loop for the default system toplevel
 456 (defun toplevel-repl (noprint)
 457   (/show0 "entering TOPLEVEL-REPL")
 458   (let ((* nil) (** nil) (*** nil)
 459         (- nil)
 460         (+ nil) (++ nil) (+++ nil)
 461         (/// nil) (// nil) (/ nil))
 462     ;; WITH-SIMPLE-RESTART doesn't actually restart its body as some
 463     ;; (like WHN for an embarrassingly long time ca. 2001-12-07) might
 464     ;; think, but instead drops control back out at the end. So when a
 465     ;; TOPLEVEL or outermost-ABORT restart happens, we need this outer
 466     ;; LOOP wrapper to grab control and start over again. (And it also
 467     ;; wraps CATCH 'TOPLEVEL-CATCHER for similar reasons.)
 468     (loop
 469      (/show0 "about to set up restarts in TOPLEVEL-REPL")
 470      ;; There should only be one TOPLEVEL restart, and it's here, so
 471      ;; restarting at TOPLEVEL always bounces you all the way out here.
 472      (with-simple-restart (toplevel
 473                            "Restart at toplevel READ/EVAL/PRINT loop.")
 474        ;; We add a new ABORT restart for every debugger level, so
 475        ;; restarting at ABORT in a nested debugger gets you out to the
 476        ;; innermost enclosing debugger, and only when you're in the
 477        ;; outermost, unnested debugger level does restarting at ABORT
 478        ;; get you out to here.
 479        (with-simple-restart
 480            (abort
 481             "Reduce debugger level (leaving debugger, returning to toplevel).")
 482          (catch 'toplevel-catcher
 483            (sb!unix:unix-sigsetmask 0)  ; FIXME: What is this for?
 484            (repl noprint)
 485            (critically-unreachable "after REPL")))))))
 486
 487 (defun repl (noprint)
 488   (/show0 "entering REPL")
 489   (let ((eof-marker (cons :eof nil)))
 490     (loop
 491      ;; FIXME: It seems bad to have GC behavior depend on scrubbing the
 492      ;; control stack before each interactive command. Isn't there some
 493      ;; way we can convince the GC to just ignore dead areas of the
 494      ;; control stack, so that we don't need to rely on this half-measure?
 495      (scrub-control-stack)
 496      (unless noprint
 497        (fresh-line)
 498        (write-string "* ") ; arbitrary but customary REPL prompt
 499        (flush-standard-output-streams))
 500      (let ((form (read *standard-input* nil eof-marker)))
 501        (cond ((eq form eof-marker)
 502               (/show0 "doing QUIT for EOF in REPL")
 503               (quit))
 504              (t
 505               (let ((results (multiple-value-list (interactive-eval form))))
 506                 (unless noprint
 507                   (dolist (result results)
 508                     (fresh-line)
 509                     (prin1 result))))))))))
 510
 511 (defun noprogrammer-debugger-hook-fun (condition old-debugger-hook)
 512   (declare (ignore old-debugger-hook))
 513   (flet ((failure-quit (&key recklessly-p)
 514            (/show0 "in FAILURE-QUIT (in noprogrammer debugger hook)")
 515            (quit :unix-status 1 :recklessly-p recklessly-p)))
 516     ;; This HANDLER-CASE is here mostly to stop output immediately
 517     ;; (and fall through to QUIT) when there's an I/O error. Thus,
 518     ;; when we're run under a shell script or something, we can die
 519     ;; cleanly when the script dies (and our pipes are cut), instead
 520     ;; of falling into ldb or something messy like that.
 521     (handler-case
 522         (progn
 523           (format *error-output*
 524                   "~&~@<unhandled condition (of type ~S): ~2I~_~A~:>~2%"
 525                   (type-of condition)
 526                   condition)
 527           ;; Flush *ERROR-OUTPUT* even before the BACKTRACE, so that
 528           ;; even if we hit an error within BACKTRACE (e.g. a bug in
 529           ;; the debugger's own frame-walking code, or a bug in a user
 530           ;; PRINT-OBJECT method) we'll at least have the CONDITION
 531           ;; printed out before we die.
 532           (finish-output *error-output*)
 533           ;; (Where to truncate the BACKTRACE is of course arbitrary, but
 534           ;; it seems as though we should at least truncate it somewhere.)
 535           (sb!debug:backtrace 128 *error-output*)
 536           (format *error-output*
 537                   "~%unhandled condition in --noprogrammer mode, quitting~%")
 538           (finish-output *error-output*)
 539           (failure-quit))
 540       (condition ()
 541         ;; We IGNORE-ERRORS here because even %PRIMITIVE PRINT can
 542         ;; fail when our output streams are blown away, as e.g. when
 543         ;; we're running under a Unix shell script and it dies somehow
 544         ;; (e.g. because of a SIGINT). In that case, we might as well
 545         ;; just give it up for a bad job, and stop trying to notify
 546         ;; the user of anything.
 547         ;;
 548         ;; Actually, the only way I've run across to exercise the
 549         ;; problem is to have more than one layer of shell script.
 550         ;; I have a shell script which does
 551         ;;   time nice -10 sh make.sh "$1" 2>&1 | tee make.tmp
 552         ;; and the problem occurs when I interrupt this with Ctrl-C
 553         ;; under Linux 2.2.14-5.0 and GNU bash, version 1.14.7(1).
 554         ;; I haven't figured out whether it's bash, time, tee, Linux, or
 555         ;; what that is responsible, but that it's possible at all
 556         ;; means that we should IGNORE-ERRORS here. -- WHN 2001-04-24
 557         (ignore-errors
 558          (%primitive print "Argh! error within --noprogrammer error handling"))
 559         (failure-quit :recklessly-p t)))))
 560 \f
 561 ;;; a convenient way to get into the assembly-level debugger
 562 (defun %halt ()
 563   (%primitive sb!c:halt))